ghc/compiler/simplCore/SetLevels.lhs

   1 %\r
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998\r
   3 %\r
   4 \section{SetLevels}\r
   5 \r
   6                 ***************************\r
   7                         Overview\r
   8                 ***************************\r
   9 \r
  10 1. We attach binding levels to Core bindings, in preparation for floating\r
  11    outwards (@FloatOut@).\r
  12 \r
  13 2. We also let-ify many expressions (notably case scrutinees), so they\r
  14    will have a fighting chance of being floated sensible.\r
  15 \r
  16 3. We clone the binders of any floatable let-binding, so that when it is\r
  17    floated out it will be unique.  (This used to be done by the simplifier\r
  18    but the latter now only ensures that there's no shadowing; indeed, even \r
  19    that may not be true.)\r
  20 \r
  21    NOTE: this can't be done using the uniqAway idea, because the variable\r
  22          must be unique in the whole program, not just its current scope,\r
  23          because two variables in different scopes may float out to the\r
  24          same top level place\r
  25 \r
  26    NOTE: Very tiresomely, we must apply this substitution to\r
  27          the rules stored inside a variable too.\r
  28 \r
  29    We do *not* clone top-level bindings, because some of them must not change,\r
  30    but we *do* clone bindings that are heading for the top level\r
  31 \r
  32 4. In the expression\r
  33         case x of wild { p -> ...wild... }\r
  34    we substitute x for wild in the RHS of the case alternatives:\r
  35         case x of wild { p -> ...x... }\r
  36    This means that a sub-expression involving x is not "trapped" inside the RHS.\r
  37    And it's not inconvenient because we already have a substitution.\r
  38 \r
  39   Note that this is EXACTLY BACKWARDS from the what the simplifier does.\r
  40   The simplifier tries to get rid of occurrences of x, in favour of wild,\r
  41   in the hope that there will only be one remaining occurrence of x, namely\r
  42   the scrutinee of the case, and we can inline it.  \r
  43 \r
  44 \begin{code}\r
  45 module SetLevels (\r
  46         setLevels,\r
  47 \r
  48         Level(..), tOP_LEVEL,\r
  49 \r
  50         incMinorLvl, ltMajLvl, ltLvl, isTopLvl\r
  51     ) where\r
  52 \r
  53 #include "HsVersions.h"\r
  54 \r
  55 import CoreSyn\r
  56 \r
  57 import CoreUtils        ( exprType, exprIsTrivial, exprIsBottom, mkPiType )\r
  58 import CoreFVs          -- all of it\r
  59 import Subst\r
  60 import Id               ( Id, idType, mkSysLocal, isOneShotLambda, zapDemandIdInfo,\r
  61                           idSpecialisation, idWorkerInfo, setIdInfo\r
  62                         )\r
  63 import IdInfo           ( workerExists, vanillaIdInfo, )\r
  64 import Var              ( Var )\r
  65 import VarSet\r
  66 import VarEnv\r
  67 import Name             ( getOccName )\r
  68 import OccName          ( occNameUserString )\r
  69 import Type             ( isUnLiftedType, Type )\r
  70 import BasicTypes       ( TopLevelFlag(..) )\r
  71 import UniqSupply\r
  72 import Util             ( sortLt, isSingleton, count )\r
  73 import Outputable\r
  74 \end{code}\r
  75 \r
  76 %************************************************************************\r
  77 %*                                                                      *\r
  78 \subsection{Level numbers}\r
  79 %*                                                                      *\r
  80 %************************************************************************\r
  81 \r
  82 \begin{code}\r
  83 data Level = Level Int  -- Level number of enclosing lambdas\r
  84                    Int  -- Number of big-lambda and/or case expressions between\r
  85                         -- here and the nearest enclosing lambda\r
  86 \end{code}\r
  87 \r
  88 The {\em level number} on a (type-)lambda-bound variable is the\r
  89 nesting depth of the (type-)lambda which binds it.  The outermost lambda\r
  90 has level 1, so (Level 0 0) means that the variable is bound outside any lambda.\r
  91 \r
  92 On an expression, it's the maximum level number of its free\r
  93 (type-)variables.  On a let(rec)-bound variable, it's the level of its\r
  94 RHS.  On a case-bound variable, it's the number of enclosing lambdas.\r
  95 \r
  96 Top-level variables: level~0.  Those bound on the RHS of a top-level\r
  97 definition but ``before'' a lambda; e.g., the \tr{x} in (levels shown\r
  98 as ``subscripts'')...\r
  99 \begin{verbatim}\r
 100 a_0 = let  b_? = ...  in\r
 101            x_1 = ... b ... in ...\r
 102 \end{verbatim}\r
 103 \r
 104 The main function @lvlExpr@ carries a ``context level'' (@ctxt_lvl@).\r
 105 That's meant to be the level number of the enclosing binder in the\r
 106 final (floated) program.  If the level number of a sub-expression is\r
 107 less than that of the context, then it might be worth let-binding the\r
 108 sub-expression so that it will indeed float. This context level starts\r
 109 at @Level 0 0@.\r
 110 \r
 111 \begin{code}\r
 112 type LevelledExpr  = TaggedExpr Level\r
 113 type LevelledBind  = TaggedBind Level\r
 114 \r
 115 tOP_LEVEL = Level 0 0\r
 116 \r
 117 incMajorLvl :: Level -> Level\r
 118 incMajorLvl (Level major minor) = Level (major+1) 0\r
 119 \r
 120 incMinorLvl :: Level -> Level\r
 121 incMinorLvl (Level major minor) = Level major (minor+1)\r
 122 \r
 123 maxLvl :: Level -> Level -> Level\r
 124 maxLvl l1@(Level maj1 min1) l2@(Level maj2 min2)\r
 125   | (maj1 > maj2) || (maj1 == maj2 && min1 > min2) = l1\r
 126   | otherwise                                      = l2\r
 127 \r
 128 ltLvl :: Level -> Level -> Bool\r
 129 ltLvl (Level maj1 min1) (Level maj2 min2)\r
 130   = (maj1 < maj2) || (maj1 == maj2 && min1 < min2)\r
 131 \r
 132 ltMajLvl :: Level -> Level -> Bool\r
 133     -- Tells if one level belongs to a difft *lambda* level to another\r
 134 ltMajLvl (Level maj1 _) (Level maj2 _) = maj1 < maj2\r
 135 \r
 136 isTopLvl :: Level -> Bool\r
 137 isTopLvl (Level 0 0) = True\r
 138 isTopLvl other       = False\r
 139 \r
 140 instance Outputable Level where\r
 141   ppr (Level maj min) = hcat [ char '<', int maj, char ',', int min, char '>' ]\r
 142 \r
 143 instance Eq Level where\r
 144   (Level maj1 min1) == (Level maj2 min2) = maj1==maj2 && min1==min2\r
 145 \end{code}\r
 146 \r
 147 %************************************************************************\r
 148 %*                                                                      *\r
 149 \subsection{Main level-setting code}\r
 150 %*                                                                      *\r
 151 %************************************************************************\r
 152 \r
 153 \begin{code}\r
 154 setLevels :: Bool               -- True <=> float lambdas to top level\r
 155           -> [CoreBind]\r
 156           -> UniqSupply\r
 157           -> [LevelledBind]\r
 158 \r
 159 setLevels float_lams binds us\r
 160   = initLvl us (do_them binds)\r
 161   where\r
 162     -- "do_them"'s main business is to thread the monad along\r
 163     -- It gives each top binding the same empty envt, because\r
 164     -- things unbound in the envt have level number zero implicitly\r
 165     do_them :: [CoreBind] -> LvlM [LevelledBind]\r
 166 \r
 167     do_them [] = returnLvl []\r
 168     do_them (b:bs)\r
 169       = lvlTopBind init_env b   `thenLvl` \ (lvld_bind, _) ->\r
 170         do_them bs              `thenLvl` \ lvld_binds ->\r
 171         returnLvl (lvld_bind : lvld_binds)\r
 172 \r
 173     init_env = initialEnv float_lams\r
 174 \r
 175 lvlTopBind env (NonRec binder rhs)\r
 176   = lvlBind TopLevel tOP_LEVEL env (AnnNonRec binder (freeVars rhs))\r
 177                                         -- Rhs can have no free vars!\r
 178 \r
 179 lvlTopBind env (Rec pairs)\r
 180   = lvlBind TopLevel tOP_LEVEL env (AnnRec [(b,freeVars rhs) | (b,rhs) <- pairs])\r
 181 \end{code}\r
 182 \r
 183 %************************************************************************\r
 184 %*                                                                      *\r
 185 \subsection{Setting expression levels}\r
 186 %*                                                                      *\r
 187 %************************************************************************\r
 188 \r
 189 \begin{code}\r
 190 lvlExpr :: Level                -- ctxt_lvl: Level of enclosing expression\r
 191         -> LevelEnv             -- Level of in-scope names/tyvars\r
 192         -> CoreExprWithFVs      -- input expression\r
 193         -> LvlM LevelledExpr    -- Result expression\r
 194 \end{code}\r
 195 \r
 196 The @ctxt_lvl@ is, roughly, the level of the innermost enclosing\r
 197 binder.  Here's an example\r
 198 \r
 199         v = \x -> ...\y -> let r = case (..x..) of\r
 200                                         ..x..\r
 201                            in ..\r
 202 \r
 203 When looking at the rhs of @r@, @ctxt_lvl@ will be 1 because that's\r
 204 the level of @r@, even though it's inside a level-2 @\y@.  It's\r
 205 important that @ctxt_lvl@ is 1 and not 2 in @r@'s rhs, because we\r
 206 don't want @lvlExpr@ to turn the scrutinee of the @case@ into an MFE\r
 207 --- because it isn't a *maximal* free expression.\r
 208 \r
 209 If there were another lambda in @r@'s rhs, it would get level-2 as well.\r
 210 \r
 211 \begin{code}\r
 212 lvlExpr _ _ (_, AnnType ty)   = returnLvl (Type ty)\r
 213 lvlExpr _ env (_, AnnVar v)   = returnLvl (lookupVar env v)\r
 214 lvlExpr _ env (_, AnnLit lit) = returnLvl (Lit lit)\r
 215 \r
 216 lvlExpr ctxt_lvl env (_, AnnApp fun arg)\r
 217   = lvl_fun fun                         `thenLvl` \ fun' ->\r
 218     lvlMFE  False ctxt_lvl env arg      `thenLvl` \ arg' ->\r
 219     returnLvl (App fun' arg')\r
 220   where\r
 221     lvl_fun (_, AnnCase _ _ _) = lvlMFE True ctxt_lvl env fun\r
 222     lvl_fun other              = lvlExpr ctxt_lvl env fun\r
 223         -- We don't do MFE on partial applications generally,\r
 224         -- but we do if the function is big and hairy, like a case\r
 225 \r
 226 lvlExpr ctxt_lvl env (_, AnnNote InlineMe expr)\r
 227 -- Don't float anything out of an InlineMe; hence the tOP_LEVEL\r
 228   = lvlExpr tOP_LEVEL env expr  `thenLvl` \ expr' ->\r
 229     returnLvl (Note InlineMe expr')\r
 230 \r
 231 lvlExpr ctxt_lvl env (_, AnnNote note expr)\r
 232   = lvlExpr ctxt_lvl env expr           `thenLvl` \ expr' ->\r
 233     returnLvl (Note note expr')\r
 234 \r
 235 -- We don't split adjacent lambdas.  That is, given\r
 236 --      \x y -> (x+1,y)\r
 237 -- we don't float to give \r
 238 --      \x -> let v = x+y in \y -> (v,y)\r
 239 -- Why not?  Because partial applications are fairly rare, and splitting\r
 240 -- lambdas makes them more expensive.\r
 241 \r
 242 lvlExpr ctxt_lvl env expr@(_, AnnLam bndr rhs)\r
 243   = lvlMFE True new_lvl new_env body    `thenLvl` \ new_body ->\r
 244     returnLvl (glue_binders new_bndrs expr new_body)\r
 245   where \r
 246     (bndrs, body)        = collect_binders expr\r
 247     (new_lvl, new_bndrs) = lvlLamBndrs ctxt_lvl bndrs\r
 248     new_env              = extendLvlEnv env new_bndrs\r
 249 \r
 250 lvlExpr ctxt_lvl env (_, AnnLet bind body)\r
 251   = lvlBind NotTopLevel ctxt_lvl env bind       `thenLvl` \ (bind', new_env) ->\r
 252     lvlExpr ctxt_lvl new_env body               `thenLvl` \ body' ->\r
 253     returnLvl (Let bind' body')\r
 254 \r
 255 lvlExpr ctxt_lvl env (_, AnnCase expr case_bndr alts)\r
 256   = lvlMFE True ctxt_lvl env expr       `thenLvl` \ expr' ->\r
 257     let\r
 258         alts_env = extendCaseBndrLvlEnv env expr' case_bndr incd_lvl\r
 259     in\r
 260     mapLvl (lvl_alt alts_env) alts      `thenLvl` \ alts' ->\r
 261     returnLvl (Case expr' (case_bndr, incd_lvl) alts')\r
 262   where\r
 263       incd_lvl  = incMinorLvl ctxt_lvl\r
 264 \r
 265       lvl_alt alts_env (con, bs, rhs)\r
 266         = lvlMFE True incd_lvl new_env rhs      `thenLvl` \ rhs' ->\r
 267           returnLvl (con, bs', rhs')\r
 268         where\r
 269           bs'     = [ (b, incd_lvl) | b <- bs ]\r
 270           new_env = extendLvlEnv alts_env bs'\r
 271 \r
 272 collect_binders lam\r
 273   = go [] lam\r
 274   where\r
 275     go rev_bndrs (_, AnnLam b e)  = go (b:rev_bndrs) e\r
 276     go rev_bndrs (_, AnnNote n e) = go rev_bndrs e\r
 277     go rev_bndrs rhs              = (reverse rev_bndrs, rhs)\r
 278         -- Ignore notes, because we don't want to split\r
 279         -- a lambda like this (\x -> coerce t (\s -> ...))\r
 280         -- This happens quite a bit in state-transformer programs\r
 281 \r
 282         -- glue_binders puts the lambda back together\r
 283 glue_binders (b:bs) (_, AnnLam _ e)  body = Lam b (glue_binders bs e body)\r
 284 glue_binders bs     (_, AnnNote n e) body = Note n (glue_binders bs e body)\r
 285 glue_binders []     e                body = body\r
 286 \end{code}\r
 287 \r
 288 @lvlMFE@ is just like @lvlExpr@, except that it might let-bind\r
 289 the expression, so that it can itself be floated.\r
 290 \r
 291 \begin{code}\r
 292 lvlMFE ::  Bool                 -- True <=> strict context [body of case or let]\r
 293         -> Level                -- Level of innermost enclosing lambda/tylam\r
 294         -> LevelEnv             -- Level of in-scope names/tyvars\r
 295         -> CoreExprWithFVs      -- input expression\r
 296         -> LvlM LevelledExpr    -- Result expression\r
 297 \r
 298 lvlMFE strict_ctxt ctxt_lvl env (_, AnnType ty)\r
 299   = returnLvl (Type ty)\r
 300 \r
 301 lvlMFE strict_ctxt ctxt_lvl env ann_expr@(fvs, _)\r
 302   |  isUnLiftedType ty                          -- Can't let-bind it\r
 303   || not good_destination\r
 304   || exprIsTrivial expr                         -- Is trivial\r
 305   || (strict_ctxt && exprIsBottom expr)         -- Strict context and is bottom\r
 306                                                 --  e.g. \x -> error "foo"\r
 307                                                 -- No gain from floating this\r
 308   =     -- Don't float it out\r
 309     lvlExpr ctxt_lvl env ann_expr\r
 310 \r
 311   | otherwise   -- Float it out!\r
 312   = lvlFloatRhs abs_vars dest_lvl env ann_expr  `thenLvl` \ expr' ->\r
 313     newLvlVar "lvl" abs_vars ty                 `thenLvl` \ var ->\r
 314     returnLvl (Let (NonRec (var,dest_lvl) expr') \r
 315                    (mkVarApps (Var var) abs_vars))\r
 316   where\r
 317     expr     = deAnnotate ann_expr\r
 318     ty       = exprType expr\r
 319     dest_lvl = destLevel env fvs (isFunction ann_expr)\r
 320     abs_vars = abstractVars dest_lvl env fvs\r
 321 \r
 322     good_destination =  dest_lvl `ltMajLvl` ctxt_lvl            -- Escapes a value lambda\r
 323                      || (isTopLvl dest_lvl && not strict_ctxt)  -- Goes to the top\r
 324         -- A decision to float entails let-binding this thing, and we only do \r
 325         -- that if we'll escape a value lambda, or will go to the top level.\r
 326         -- But beware\r
 327         --      concat = /\ a -> foldr ..a.. (++) []\r
 328         -- was getting turned into\r
 329         --      concat = /\ a -> lvl a\r
 330         --      lvl    = /\ a -> foldr ..a.. (++) []\r
 331         -- which is pretty stupid.  Hence the strict_ctxt test\r
 332 \end{code}\r
 333 \r
 334 \r
 335 %************************************************************************\r
 336 %*                                                                      *\r
 337 \subsection{Bindings}\r
 338 %*                                                                      *\r
 339 %************************************************************************\r
 340 \r
 341 The binding stuff works for top level too.\r
 342 \r
 343 \begin{code}\r
 344 lvlBind :: TopLevelFlag         -- Used solely to decide whether to clone\r
 345         -> Level                -- Context level; might be Top even for bindings nested in the RHS\r
 346                                 -- of a top level binding\r
 347         -> LevelEnv\r
 348         -> CoreBindWithFVs\r
 349         -> LvlM (LevelledBind, LevelEnv)\r
 350 \r
 351 lvlBind top_lvl ctxt_lvl env (AnnNonRec bndr rhs@(rhs_fvs,_))\r
 352   | null abs_vars\r
 353   =     -- No type abstraction; clone existing binder\r
 354     lvlExpr dest_lvl env rhs                    `thenLvl` \ rhs' ->\r
 355     cloneVar top_lvl env bndr ctxt_lvl dest_lvl `thenLvl` \ (env', bndr') ->\r
 356     returnLvl (NonRec (bndr', dest_lvl) rhs', env') \r
 357 \r
 358   | otherwise\r
 359   = -- Yes, type abstraction; create a new binder, extend substitution, etc\r
 360     lvlFloatRhs abs_vars dest_lvl env rhs       `thenLvl` \ rhs' ->\r
 361     newPolyBndrs dest_lvl env abs_vars [bndr]   `thenLvl` \ (env', [bndr']) ->\r
 362     returnLvl (NonRec (bndr', dest_lvl) rhs', env')\r
 363 \r
 364   where\r
 365     bind_fvs = rhs_fvs `unionVarSet` idFreeVars bndr\r
 366     abs_vars = abstractVars dest_lvl env bind_fvs\r
 367 \r
 368     dest_lvl | isUnLiftedType (idType bndr) = destLevel env bind_fvs False `maxLvl` Level 1 0\r
 369              | otherwise                    = destLevel env bind_fvs (isFunction rhs)\r
 370         -- Hack alert!  We do have some unlifted bindings, for cheap primops, and \r
 371         -- it is ok to float them out; but not to the top level.  If they would otherwise\r
 372         -- go to the top level, we pin them inside the topmost lambda\r
 373 \end{code}\r
 374 \r
 375 \r
 376 \begin{code}\r
 377 lvlBind top_lvl ctxt_lvl env (AnnRec pairs)\r
 378   | null abs_vars\r
 379   = cloneRecVars top_lvl env bndrs ctxt_lvl dest_lvl    `thenLvl` \ (new_env, new_bndrs) ->\r
 380     mapLvl (lvlExpr ctxt_lvl new_env) rhss              `thenLvl` \ new_rhss ->\r
 381     returnLvl (Rec ((new_bndrs `zip` repeat dest_lvl) `zip` new_rhss), new_env)\r
 382 \r
 383   | isSingleton pairs && count isId abs_vars > 1\r
 384   =     -- Special case for self recursion where there are\r
 385         -- several variables carried around: build a local loop:        \r
 386         --      poly_f = \abs_vars. \lam_vars . letrec f = \lam_vars. rhs in f lam_vars\r
 387         -- This just makes the closures a bit smaller.  If we don't do\r
 388         -- this, allocation rises significantly on some programs\r
 389         --\r
 390         -- We could elaborate it for the case where there are several\r
 391         -- mutually functions, but it's quite a bit more complicated\r
 392         -- \r
 393         -- This all seems a bit ad hoc -- sigh\r
 394     let\r
 395         (bndr,rhs) = head pairs\r
 396         (rhs_lvl, abs_vars_w_lvls) = lvlLamBndrs dest_lvl abs_vars\r
 397         rhs_env = extendLvlEnv env abs_vars_w_lvls\r
 398     in\r
 399     cloneVar NotTopLevel rhs_env bndr rhs_lvl rhs_lvl   `thenLvl` \ (rhs_env', new_bndr) ->\r
 400     let\r
 401         (lam_bndrs, rhs_body)     = collect_binders rhs\r
 402         (body_lvl, new_lam_bndrs) = lvlLamBndrs rhs_lvl lam_bndrs\r
 403         body_env                  = extendLvlEnv rhs_env' new_lam_bndrs\r
 404     in\r
 405     lvlExpr body_lvl body_env rhs_body          `thenLvl` \ new_rhs_body ->\r
 406     newPolyBndrs dest_lvl env abs_vars [bndr]   `thenLvl` \ (poly_env, [poly_bndr]) ->\r
 407     returnLvl (Rec [((poly_bndr,dest_lvl), mkLams abs_vars_w_lvls $\r
 408                                            glue_binders new_lam_bndrs rhs $\r
 409                                            Let (Rec [((new_bndr,rhs_lvl), mkLams new_lam_bndrs new_rhs_body)]) \r
 410                                                 (mkVarApps (Var new_bndr) lam_bndrs))],\r
 411                poly_env)\r
 412 \r
 413   | otherwise\r
 414   = newPolyBndrs dest_lvl env abs_vars bndrs            `thenLvl` \ (new_env, new_bndrs) ->\r
 415     mapLvl (lvlFloatRhs abs_vars dest_lvl new_env) rhss `thenLvl` \ new_rhss ->\r
 416     returnLvl (Rec ((new_bndrs `zip` repeat dest_lvl) `zip` new_rhss), new_env)\r
 417 \r
 418   where\r
 419     (bndrs,rhss) = unzip pairs\r
 420 \r
 421         -- Finding the free vars of the binding group is annoying\r
 422     bind_fvs        = (unionVarSets [ idFreeVars bndr `unionVarSet` rhs_fvs\r
 423                                     | (bndr, (rhs_fvs,_)) <- pairs])\r
 424                       `minusVarSet`\r
 425                       mkVarSet bndrs\r
 426 \r
 427     dest_lvl = destLevel env bind_fvs (all isFunction rhss)\r
 428     abs_vars = abstractVars dest_lvl env bind_fvs\r
 429 \r
 430 ----------------------------------------------------\r
 431 -- Three help functons for the type-abstraction case\r
 432 \r
 433 lvlFloatRhs abs_vars dest_lvl env rhs\r
 434   = lvlExpr rhs_lvl rhs_env rhs `thenLvl` \ rhs' ->\r
 435     returnLvl (mkLams abs_vars_w_lvls rhs')\r
 436   where\r
 437     (rhs_lvl, abs_vars_w_lvls) = lvlLamBndrs dest_lvl abs_vars\r
 438     rhs_env = extendLvlEnv env abs_vars_w_lvls\r
 439 \end{code}\r
 440 \r
 441 \r
 442 %************************************************************************\r
 443 %*                                                                      *\r
 444 \subsection{Deciding floatability}\r
 445 %*                                                                      *\r
 446 %************************************************************************\r
 447 \r
 448 \begin{code}\r
 449 lvlLamBndrs :: Level -> [CoreBndr] -> (Level, [(CoreBndr, Level)])\r
 450 -- Compute the levels for the binders of a lambda group\r
 451 -- The binders returned are exactly the same as the ones passed,\r
 452 -- but they are now paired with a level\r
 453 lvlLamBndrs lvl [] \r
 454   = (lvl, [])\r
 455 \r
 456 lvlLamBndrs lvl bndrs\r
 457   = go  (incMinorLvl lvl)\r
 458         False   -- Havn't bumped major level in this group\r
 459         [] bndrs\r
 460   where\r
 461     go old_lvl bumped_major rev_lvld_bndrs (bndr:bndrs)\r
 462         | isId bndr &&                  -- Go to the next major level if this is a value binder,\r
 463           not bumped_major &&           -- and we havn't already gone to the next level (one jump per group)\r
 464           not (isOneShotLambda bndr)    -- and it isn't a one-shot lambda\r
 465         = go new_lvl True ((bndr,new_lvl) : rev_lvld_bndrs) bndrs\r
 466 \r
 467         | otherwise\r
 468         = go old_lvl bumped_major ((bndr,old_lvl) : rev_lvld_bndrs) bndrs\r
 469 \r
 470         where\r
 471           new_lvl = incMajorLvl old_lvl\r
 472 \r
 473     go old_lvl _ rev_lvld_bndrs []\r
 474         = (old_lvl, reverse rev_lvld_bndrs)\r
 475         -- a lambda like this (\x -> coerce t (\s -> ...))\r
 476         -- This happens quite a bit in state-transformer programs\r
 477 \end{code}\r
 478 \r
 479 \begin{code}\r
 480 abstractVars :: Level -> LevelEnv -> VarSet -> [Var]\r
 481         -- Find the variables in fvs, free vars of the target expresion,\r
 482         -- whose level is less than than the supplied level\r
 483         -- These are the ones we are going to abstract out\r
 484 abstractVars dest_lvl env fvs\r
 485   = uniq (sortLt lt [var | fv <- varSetElems fvs, var <- absVarsOf dest_lvl env fv])\r
 486   where\r
 487         -- Sort the variables so we don't get \r
 488         -- mixed-up tyvars and Ids; it's just messy\r
 489     v1 `lt` v2 = case (isId v1, isId v2) of\r
 490                    (True, False) -> False\r
 491                    (False, True) -> True\r
 492                    other         -> v1 < v2     -- Same family\r
 493     uniq :: [Var] -> [Var]\r
 494         -- Remove adjacent duplicates; the sort will have brought them together\r
 495     uniq (v1:v2:vs) | v1 == v2  = uniq (v2:vs)\r
 496                     | otherwise = v1 : uniq (v2:vs)\r
 497     uniq vs = vs\r
 498 \r
 499   -- Destintion level is the max Id level of the expression\r
 500   -- (We'll abstract the type variables, if any.)\r
 501 destLevel :: LevelEnv -> VarSet -> Bool -> Level\r
 502 destLevel env fvs is_function\r
 503   |  floatLams env\r
 504   && is_function = tOP_LEVEL            -- Send functions to top level; see\r
 505                                         -- the comments with isFunction\r
 506   | otherwise    = maxIdLevel env fvs\r
 507 \r
 508 isFunction :: CoreExprWithFVs -> Bool\r
 509 -- The idea here is that we want to float *functions* to\r
 510 -- the top level.  This saves no work, but \r
 511 --      (a) it can make the host function body a lot smaller, \r
 512 --              and hence inlinable.  \r
 513 --      (b) it can also save allocation when the function is recursive:\r
 514 --          h = \x -> letrec f = \y -> ...f...y...x...\r
 515 --                    in f x\r
 516 --     becomes\r
 517 --          f = \x y -> ...(f x)...y...x...\r
 518 --          h = \x -> f x x\r
 519 --     No allocation for f now.\r
 520 -- We may only want to do this if there are sufficiently few free \r
 521 -- variables.  We certainly only want to do it for values, and not for\r
 522 -- constructors.  So the simple thing is just to look for lambdas\r
 523 isFunction (_, AnnLam b e) | isId b    = True\r
 524                            | otherwise = isFunction e\r
 525 isFunction (_, AnnNote n e)            = isFunction e\r
 526 isFunction other                       = False\r
 527 \end{code}\r
 528 \r
 529 \r
 530 %************************************************************************\r
 531 %*                                                                      *\r
 532 \subsection{Free-To-Level Monad}\r
 533 %*                                                                      *\r
 534 %************************************************************************\r
 535 \r
 536 \begin{code}\r
 537 type LevelEnv = (Bool,                          -- True <=> Float lambdas too\r
 538                  VarEnv Level,                  -- Domain is *post-cloned* TyVars and Ids\r
 539                  Subst,                         -- Domain is pre-cloned Ids; tracks the in-scope set\r
 540                                                 --      so that subtitution is capture-avoiding\r
 541                  IdEnv ([Var], LevelledExpr))   -- Domain is pre-cloned Ids\r
 542         -- We clone let-bound variables so that they are still\r
 543         -- distinct when floated out; hence the SubstEnv/IdEnv.\r
 544         -- (see point 3 of the module overview comment).\r
 545         -- We also use these envs when making a variable polymorphic\r
 546         -- because we want to float it out past a big lambda.\r
 547         --\r
 548         -- The SubstEnv and IdEnv always implement the same mapping, but the\r
 549         -- SubstEnv maps to CoreExpr and the IdEnv to LevelledExpr\r
 550         -- Since the range is always a variable or type application,\r
 551         -- there is never any difference between the two, but sadly\r
 552         -- the types differ.  The SubstEnv is used when substituting in\r
 553         -- a variable's IdInfo; the IdEnv when we find a Var.\r
 554         --\r
 555         -- In addition the IdEnv records a list of tyvars free in the\r
 556         -- type application, just so we don't have to call freeVars on\r
 557         -- the type application repeatedly.\r
 558         --\r
 559         -- The domain of the both envs is *pre-cloned* Ids, though\r
 560         --\r
 561         -- The domain of the VarEnv Level is the *post-cloned* Ids\r
 562 \r
 563 initialEnv :: Bool -> LevelEnv\r
 564 initialEnv float_lams = (float_lams, emptyVarEnv, emptySubst, emptyVarEnv)\r
 565 \r
 566 floatLams :: LevelEnv -> Bool\r
 567 floatLams (float_lams, _, _, _) = float_lams\r
 568 \r
 569 extendLvlEnv :: LevelEnv -> [(Var,Level)] -> LevelEnv\r
 570 -- Used when *not* cloning\r
 571 extendLvlEnv (float_lams, lvl_env, subst, id_env) prs\r
 572   = (float_lams,\r
 573      foldl add_lvl lvl_env prs,\r
 574      foldl del_subst subst prs,\r
 575      foldl del_id id_env prs)\r
 576   where\r
 577     add_lvl   env (v,l) = extendVarEnv env v l\r
 578     del_subst env (v,_) = extendInScope env v\r
 579     del_id    env (v,_) = delVarEnv env v\r
 580   -- We must remove any clone for this variable name in case of\r
 581   -- shadowing.  This bit me in the following case\r
 582   -- (in nofib/real/gg/Spark.hs):\r
 583   -- \r
 584   --   case ds of wild {\r
 585   --     ... -> case e of wild {\r
 586   --              ... -> ... wild ...\r
 587   --            }\r
 588   --   }\r
 589   -- \r
 590   -- The inside occurrence of @wild@ was being replaced with @ds@,\r
 591   -- incorrectly, because the SubstEnv was still lying around.  Ouch!\r
 592   -- KSW 2000-07.\r
 593 \r
 594 -- extendCaseBndrLvlEnv adds the mapping case-bndr->scrut-var if it can\r
 595 -- (see point 4 of the module overview comment)\r
 596 extendCaseBndrLvlEnv (float_lams, lvl_env, subst, id_env) (Var scrut_var) case_bndr lvl\r
 597   = (float_lams,\r
 598      extendVarEnv lvl_env case_bndr lvl,\r
 599      extendSubst subst case_bndr (DoneEx (Var scrut_var)),\r
 600      extendVarEnv id_env case_bndr ([scrut_var], Var scrut_var))\r
 601      \r
 602 extendCaseBndrLvlEnv env scrut case_bndr lvl\r
 603   = extendLvlEnv          env [(case_bndr,lvl)]\r
 604 \r
 605 extendPolyLvlEnv dest_lvl (float_lams, lvl_env, subst, id_env) abs_vars bndr_pairs\r
 606   = (float_lams,\r
 607      foldl add_lvl   lvl_env bndr_pairs,\r
 608      foldl add_subst subst   bndr_pairs,\r
 609      foldl add_id    id_env  bndr_pairs)\r
 610   where\r
 611      add_lvl   env (v,v') = extendVarEnv env v' dest_lvl\r
 612      add_subst env (v,v') = extendSubst  env v (DoneEx (mkVarApps (Var v') abs_vars))\r
 613      add_id    env (v,v') = extendVarEnv env v ((v':abs_vars), mkVarApps (Var v') abs_vars)\r
 614 \r
 615 extendCloneLvlEnv lvl (float_lams, lvl_env, _, id_env) new_subst bndr_pairs\r
 616   = (float_lams,\r
 617      foldl add_lvl   lvl_env bndr_pairs,\r
 618      new_subst,\r
 619      foldl add_id    id_env  bndr_pairs)\r
 620   where\r
 621      add_lvl   env (v,v') = extendVarEnv env v' lvl\r
 622      add_id    env (v,v') = extendVarEnv env v ([v'], Var v')\r
 623 \r
 624 \r
 625 maxIdLevel :: LevelEnv -> VarSet -> Level\r
 626 maxIdLevel (_, lvl_env,_,id_env) var_set\r
 627   = foldVarSet max_in tOP_LEVEL var_set\r
 628   where\r
 629     max_in in_var lvl = foldr max_out lvl (case lookupVarEnv id_env in_var of\r
 630                                                 Just (abs_vars, _) -> abs_vars\r
 631                                                 Nothing            -> [in_var])\r
 632 \r
 633     max_out out_var lvl \r
 634         | isId out_var = case lookupVarEnv lvl_env out_var of\r
 635                                 Just lvl' -> maxLvl lvl' lvl\r
 636                                 Nothing   -> lvl \r
 637         | otherwise    = lvl    -- Ignore tyvars in *maxIdLevel*\r
 638 \r
 639 lookupVar :: LevelEnv -> Id -> LevelledExpr\r
 640 lookupVar (_, _, _, id_env) v = case lookupVarEnv id_env v of\r
 641                                        Just (_, expr) -> expr\r
 642                                        other          -> Var v\r
 643 \r
 644 absVarsOf :: Level -> LevelEnv -> Var -> [Var]\r
 645         -- If f is free in the exression, and f maps to poly_f a b c in the\r
 646         -- current substitution, then we must report a b c as candidate type\r
 647         -- variables\r
 648 absVarsOf dest_lvl (_, lvl_env, _, id_env) v \r
 649   | isId v\r
 650   = [final_av | av <- lookup_avs v, abstract_me av, final_av <- add_tyvars av]\r
 651 \r
 652   | otherwise\r
 653   = if abstract_me v then [v] else []\r
 654 \r
 655   where\r
 656     abstract_me v = case lookupVarEnv lvl_env v of\r
 657                         Just lvl -> dest_lvl `ltLvl` lvl\r
 658                         Nothing  -> False\r
 659 \r
 660     lookup_avs v = case lookupVarEnv id_env v of\r
 661                         Just (abs_vars, _) -> abs_vars\r
 662                         Nothing            -> [v]\r
 663 \r
 664         -- We are going to lambda-abstract, so nuke any IdInfo,\r
 665         -- and add the tyvars of the Id\r
 666     add_tyvars v | isId v    =  zap v  : varSetElems (idFreeTyVars v)\r
 667                  | otherwise = [v]\r
 668 \r
 669     zap v = WARN( workerExists (idWorkerInfo v)\r
 670                   || not (isEmptyCoreRules (idSpecialisation v)),\r
 671                   text "absVarsOf: discarding info on" <+> ppr v )\r
 672             setIdInfo v vanillaIdInfo\r
 673 \end{code}\r
 674 \r
 675 \begin{code}\r
 676 type LvlM result = UniqSM result\r
 677 \r
 678 initLvl         = initUs_\r
 679 thenLvl         = thenUs\r
 680 returnLvl       = returnUs\r
 681 mapLvl          = mapUs\r
 682 \end{code}\r
 683 \r
 684 \begin{code}\r
 685 newPolyBndrs dest_lvl env abs_vars bndrs\r
 686   = getUniquesUs (length bndrs)         `thenLvl` \ uniqs ->\r
 687     let\r
 688         new_bndrs = zipWith mk_poly_bndr bndrs uniqs\r
 689     in\r
 690     returnLvl (extendPolyLvlEnv dest_lvl env abs_vars (bndrs `zip` new_bndrs), new_bndrs)\r
 691   where\r
 692     mk_poly_bndr bndr uniq = mkSysLocal (_PK_ str) uniq poly_ty\r
 693                            where\r
 694                              str     = "poly_" ++ occNameUserString (getOccName bndr)\r
 695                              poly_ty = foldr mkPiType (idType bndr) abs_vars\r
 696         \r
 697 \r
 698 newLvlVar :: String \r
 699           -> [CoreBndr] -> Type         -- Abstract wrt these bndrs\r
 700           -> LvlM Id\r
 701 newLvlVar str vars body_ty      \r
 702   = getUniqueUs `thenLvl` \ uniq ->\r
 703     returnUs (mkSysLocal (_PK_ str) uniq (foldr mkPiType body_ty vars))\r
 704     \r
 705 -- The deeply tiresome thing is that we have to apply the substitution\r
 706 -- to the rules inside each Id.  Grr.  But it matters.\r
 707 \r
 708 cloneVar :: TopLevelFlag -> LevelEnv -> Id -> Level -> Level -> LvlM (LevelEnv, Id)\r
 709 cloneVar TopLevel env v ctxt_lvl dest_lvl\r
 710   = returnUs (env, v)   -- Don't clone top level things\r
 711 cloneVar NotTopLevel env@(_,_,subst,_) v ctxt_lvl dest_lvl\r
 712   = ASSERT( isId v )\r
 713     getUs       `thenLvl` \ us ->\r
 714     let\r
 715       (subst', v1) = substAndCloneId subst us v\r
 716       v2           = zap_demand ctxt_lvl dest_lvl v1\r
 717       env'         = extendCloneLvlEnv dest_lvl env subst' [(v,v2)]\r
 718     in\r
 719     returnUs (env', v2)\r
 720 \r
 721 cloneRecVars :: TopLevelFlag -> LevelEnv -> [Id] -> Level -> Level -> LvlM (LevelEnv, [Id])\r
 722 cloneRecVars TopLevel env vs ctxt_lvl dest_lvl \r
 723   = returnUs (env, vs)  -- Don't clone top level things\r
 724 cloneRecVars NotTopLevel env@(_,_,subst,_) vs ctxt_lvl dest_lvl\r
 725   = ASSERT( all isId vs )\r
 726     getUs                       `thenLvl` \ us ->\r
 727     let\r
 728       (subst', vs1) = substAndCloneRecIds subst us vs\r
 729       vs2           = map (zap_demand ctxt_lvl dest_lvl) vs1\r
 730       env'          = extendCloneLvlEnv dest_lvl env subst' (vs `zip` vs2)\r
 731     in\r
 732     returnUs (env', vs2)\r
 733 \r
 734         -- VERY IMPORTANT: we must zap the demand info \r
 735         -- if the thing is going to float out past a lambda\r
 736 zap_demand dest_lvl ctxt_lvl id\r
 737   | ctxt_lvl == dest_lvl = id                   -- Stays put\r
 738   | otherwise            = zapDemandIdInfo id   -- Floats out\r
 739 \end{code}\r
 740         \r