ghc/compiler/simplCore/SetLevels.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section{SetLevels}
   5
   6                 ***************************
   7                         Overview
   8                 ***************************
   9
  10 * We attach binding levels to Core bindings, in preparation for floating
  11   outwards (@FloatOut@).
  12
  13 * We also let-ify many expressions (notably case scrutinees), so they
  14   will have a fighting chance of being floated sensible.
  15
  16 * We clone the binders of any floatable let-binding, so that when it is
  17   floated out it will be unique.  (This used to be done by the simplifier
  18   but the latter now only ensures that there's no shadowing.)
  19   NOTE: Very tiresomely, we must apply this substitution to
  20         the rules stored inside a variable too.
  21
  22   We do *not* clone top-level bindings, because some of them must not change,
  23   but we *do* clone bindings that are heading for the top level
  24
  25 * In the expression
  26         case x of wild { p -> ...wild... }
  27   we substitute x for wild in the RHS of the case alternatives:
  28         case x of wild { p -> ...x... }
  29   This means that a sub-expression involving x is not "trapped" inside the RHS.
  30   And it's not inconvenient because we already have a substitution.
  31
  32 \begin{code}
  33 module SetLevels (
  34         setLevels,
  35
  36         Level(..), tOP_LEVEL,
  37
  38         incMinorLvl, ltMajLvl, ltLvl, isTopLvl
  39     ) where
  40
  41 #include "HsVersions.h"
  42
  43 import CoreSyn
  44
  45 import CoreUtils        ( exprType, exprIsTrivial, exprIsBottom )
  46 import CoreFVs          -- all of it
  47 import Id               ( Id, idType, idFreeTyVars, mkSysLocal, isOneShotLambda, modifyIdInfo,
  48                           idSpecialisation, idWorkerInfo, setIdInfo
  49                         )
  50 import IdInfo           ( workerExists, vanillaIdInfo )
  51 import Var              ( Var, TyVar, setVarUnique )
  52 import VarEnv
  53 import Subst
  54 import VarSet
  55 import Name             ( getOccName )
  56 import OccName          ( occNameUserString )
  57 import Type             ( isUnLiftedType, mkPiType, Type )
  58 import BasicTypes       ( TopLevelFlag(..) )
  59 import VarSet
  60 import VarEnv
  61 import UniqSupply
  62 import Util             ( sortLt, isSingleton, count )
  63 import Outputable
  64 \end{code}
  65
  66 %************************************************************************
  67 %*                                                                      *
  68 \subsection{Level numbers}
  69 %*                                                                      *
  70 %************************************************************************
  71
  72 \begin{code}
  73 data Level = Level Int  -- Level number of enclosing lambdas
  74                    Int  -- Number of big-lambda and/or case expressions between
  75                         -- here and the nearest enclosing lambda
  76 \end{code}
  77
  78 The {\em level number} on a (type-)lambda-bound variable is the
  79 nesting depth of the (type-)lambda which binds it.  The outermost lambda
  80 has level 1, so (Level 0 0) means that the variable is bound outside any lambda.
  81
  82 On an expression, it's the maximum level number of its free
  83 (type-)variables.  On a let(rec)-bound variable, it's the level of its
  84 RHS.  On a case-bound variable, it's the number of enclosing lambdas.
  85
  86 Top-level variables: level~0.  Those bound on the RHS of a top-level
  87 definition but ``before'' a lambda; e.g., the \tr{x} in (levels shown
  88 as ``subscripts'')...
  89 \begin{verbatim}
  90 a_0 = let  b_? = ...  in
  91            x_1 = ... b ... in ...
  92 \end{verbatim}
  93
  94 The main function @lvlExpr@ carries a ``context level'' (@ctxt_lvl@).
  95 That's meant to be the level number of the enclosing binder in the
  96 final (floated) program.  If the level number of a sub-expression is
  97 less than that of the context, then it might be worth let-binding the
  98 sub-expression so that it will indeed float. This context level starts
  99 at @Level 0 0@.
 100
 101 \begin{code}
 102 type LevelledExpr  = TaggedExpr Level
 103 type LevelledArg   = TaggedArg  Level
 104 type LevelledBind  = TaggedBind Level
 105
 106 tOP_LEVEL = Level 0 0
 107
 108 incMajorLvl :: Level -> Level
 109 incMajorLvl (Level major minor) = Level (major+1) 0
 110
 111 incMinorLvl :: Level -> Level
 112 incMinorLvl (Level major minor) = Level major (minor+1)
 113
 114 maxLvl :: Level -> Level -> Level
 115 maxLvl l1@(Level maj1 min1) l2@(Level maj2 min2)
 116   | (maj1 > maj2) || (maj1 == maj2 && min1 > min2) = l1
 117   | otherwise                                      = l2
 118
 119 ltLvl :: Level -> Level -> Bool
 120 ltLvl (Level maj1 min1) (Level maj2 min2)
 121   = (maj1 < maj2) || (maj1 == maj2 && min1 < min2)
 122
 123 ltMajLvl :: Level -> Level -> Bool
 124     -- Tells if one level belongs to a difft *lambda* level to another
 125 ltMajLvl (Level maj1 _) (Level maj2 _) = maj1 < maj2
 126
 127 isTopLvl :: Level -> Bool
 128 isTopLvl (Level 0 0) = True
 129 isTopLvl other       = False
 130
 131 instance Outputable Level where
 132   ppr (Level maj min) = hcat [ char '<', int maj, char ',', int min, char '>' ]
 133 \end{code}
 134
 135 %************************************************************************
 136 %*                                                                      *
 137 \subsection{Main level-setting code}
 138 %*                                                                      *
 139 %************************************************************************
 140
 141 \begin{code}
 142 setLevels :: Bool               -- True <=> float lambdas to top level
 143           -> [CoreBind]
 144           -> UniqSupply
 145           -> [LevelledBind]
 146
 147 setLevels float_lams binds us
 148   = initLvl us (do_them binds)
 149   where
 150     -- "do_them"'s main business is to thread the monad along
 151     -- It gives each top binding the same empty envt, because
 152     -- things unbound in the envt have level number zero implicitly
 153     do_them :: [CoreBind] -> LvlM [LevelledBind]
 154
 155     do_them [] = returnLvl []
 156     do_them (b:bs)
 157       = lvlTopBind init_env b   `thenLvl` \ (lvld_bind, _) ->
 158         do_them bs              `thenLvl` \ lvld_binds ->
 159         returnLvl (lvld_bind : lvld_binds)
 160
 161     init_env = initialEnv float_lams
 162
 163 lvlTopBind env (NonRec binder rhs)
 164   = lvlBind TopLevel tOP_LEVEL env (AnnNonRec binder (freeVars rhs))
 165                                         -- Rhs can have no free vars!
 166
 167 lvlTopBind env (Rec pairs)
 168   = lvlBind TopLevel tOP_LEVEL env (AnnRec [(b,freeVars rhs) | (b,rhs) <- pairs])
 169 \end{code}
 170
 171 %************************************************************************
 172 %*                                                                      *
 173 \subsection{Setting expression levels}
 174 %*                                                                      *
 175 %************************************************************************
 176
 177 \begin{code}
 178 lvlExpr :: Level                -- ctxt_lvl: Level of enclosing expression
 179         -> LevelEnv             -- Level of in-scope names/tyvars
 180         -> CoreExprWithFVs      -- input expression
 181         -> LvlM LevelledExpr    -- Result expression
 182 \end{code}
 183
 184 The @ctxt_lvl@ is, roughly, the level of the innermost enclosing
 185 binder.  Here's an example
 186
 187         v = \x -> ...\y -> let r = case (..x..) of
 188                                         ..x..
 189                            in ..
 190
 191 When looking at the rhs of @r@, @ctxt_lvl@ will be 1 because that's
 192 the level of @r@, even though it's inside a level-2 @\y@.  It's
 193 important that @ctxt_lvl@ is 1 and not 2 in @r@'s rhs, because we
 194 don't want @lvlExpr@ to turn the scrutinee of the @case@ into an MFE
 195 --- because it isn't a *maximal* free expression.
 196
 197 If there were another lambda in @r@'s rhs, it would get level-2 as well.
 198
 199 \begin{code}
 200 lvlExpr _ _ (_, AnnType ty)   = returnLvl (Type ty)
 201 lvlExpr _ env (_, AnnVar v)   = returnLvl (lookupVar env v)
 202 lvlExpr _ env (_, AnnLit lit) = returnLvl (Lit lit)
 203
 204 lvlExpr ctxt_lvl env (_, AnnApp fun arg)
 205   = lvlExpr ctxt_lvl env fun            `thenLvl` \ fun' ->
 206     lvlMFE  False ctxt_lvl env arg      `thenLvl` \ arg' ->
 207     returnLvl (App fun' arg')
 208
 209 lvlExpr ctxt_lvl env (_, AnnNote InlineMe expr)
 210         -- Don't float anything out of an InlineMe
 211   = lvlExpr tOP_LEVEL env expr          `thenLvl` \ expr' ->
 212     returnLvl (Note InlineMe expr')
 213
 214 lvlExpr ctxt_lvl env (_, AnnNote note expr)
 215   = lvlExpr ctxt_lvl env expr           `thenLvl` \ expr' ->
 216     returnLvl (Note note expr')
 217
 218 -- We don't split adjacent lambdas.  That is, given
 219 --      \x y -> (x+1,y)
 220 -- we don't float to give
 221 --      \x -> let v = x+y in \y -> (v,y)
 222 -- Why not?  Because partial applications are fairly rare, and splitting
 223 -- lambdas makes them more expensive.
 224
 225 lvlExpr ctxt_lvl env expr@(_, AnnLam bndr rhs)
 226   = lvlMFE True new_lvl new_env body    `thenLvl` \ new_body ->
 227     returnLvl (glue_binders new_bndrs expr new_body)
 228   where
 229     (bndrs, body)        = collect_binders expr
 230     (new_lvl, new_bndrs) = lvlLamBndrs ctxt_lvl bndrs
 231     new_env              = extendLvlEnv env new_bndrs
 232
 233 lvlExpr ctxt_lvl env (_, AnnLet bind body)
 234   = lvlBind NotTopLevel ctxt_lvl env bind       `thenLvl` \ (bind', new_env) ->
 235     lvlExpr ctxt_lvl new_env body               `thenLvl` \ body' ->
 236     returnLvl (Let bind' body')
 237
 238 lvlExpr ctxt_lvl env (_, AnnCase expr case_bndr alts)
 239   = lvlMFE True ctxt_lvl env expr       `thenLvl` \ expr' ->
 240     let
 241         alts_env = extendCaseBndrLvlEnv env expr' case_bndr incd_lvl
 242     in
 243     mapLvl (lvl_alt alts_env) alts      `thenLvl` \ alts' ->
 244     returnLvl (Case expr' (case_bndr, incd_lvl) alts')
 245   where
 246       expr_type = exprType (deAnnotate expr)
 247       incd_lvl  = incMinorLvl ctxt_lvl
 248
 249       lvl_alt alts_env (con, bs, rhs)
 250         = lvlMFE True incd_lvl new_env rhs      `thenLvl` \ rhs' ->
 251           returnLvl (con, bs', rhs')
 252         where
 253           bs'     = [ (b, incd_lvl) | b <- bs ]
 254           new_env = extendLvlEnv alts_env bs'
 255
 256 collect_binders lam
 257   = go [] lam
 258   where
 259     go rev_bndrs (_, AnnLam b e)  = go (b:rev_bndrs) e
 260     go rev_bndrs (_, AnnNote n e) = go rev_bndrs e
 261     go rev_bndrs rhs              = (reverse rev_bndrs, rhs)
 262         -- Ignore notes, because we don't want to split
 263         -- a lambda like this (\x -> coerce t (\s -> ...))
 264         -- This happens quite a bit in state-transformer programs
 265
 266         -- glue_binders puts the lambda back together
 267 glue_binders (b:bs) (_, AnnLam _ e)  body = Lam b (glue_binders bs e body)
 268 glue_binders bs     (_, AnnNote n e) body = Note n (glue_binders bs e body)
 269 glue_binders []     e                body = body
 270 \end{code}
 271
 272 @lvlMFE@ is just like @lvlExpr@, except that it might let-bind
 273 the expression, so that it can itself be floated.
 274
 275 \begin{code}
 276 lvlMFE ::  Bool                 -- True <=> strict context [body of case or let]
 277         -> Level                -- Level of innermost enclosing lambda/tylam
 278         -> LevelEnv             -- Level of in-scope names/tyvars
 279         -> CoreExprWithFVs      -- input expression
 280         -> LvlM LevelledExpr    -- Result expression
 281
 282 lvlMFE strict_ctxt ctxt_lvl env (_, AnnType ty)
 283   = returnLvl (Type ty)
 284
 285 lvlMFE strict_ctxt ctxt_lvl env ann_expr@(fvs, _)
 286   |  isUnLiftedType ty                          -- Can't let-bind it
 287   || not (dest_lvl `ltMajLvl` ctxt_lvl)         -- Does not escape a value lambda
 288         -- A decision to float entails let-binding this thing, and we only do
 289         -- that if we'll escape a value lambda.  I considered doing it if it
 290         -- would make the thing go to top level, but I found things like
 291         --      concat = /\ a -> foldr ..a.. (++) []
 292         -- was getting turned into
 293         --      concat = /\ a -> lvl a
 294         --      lvl    = /\ a -> foldr ..a.. (++) []
 295         -- which is pretty stupid.  So for now at least, I don't let-bind things
 296         -- simply because they could go to top level.
 297   || exprIsTrivial expr                         -- Is trivial
 298   || (strict_ctxt && exprIsBottom expr)         -- Strict context and is bottom
 299   =     -- Don't float it out
 300     lvlExpr ctxt_lvl env ann_expr
 301
 302   | otherwise   -- Float it out!
 303   = lvlFloatRhs abs_vars dest_lvl env ann_expr  `thenLvl` \ expr' ->
 304     newLvlVar "lvl" abs_vars ty                 `thenLvl` \ var ->
 305     returnLvl (Let (NonRec (var,dest_lvl) expr')
 306                    (mkVarApps (Var var) abs_vars))
 307   where
 308     expr     = deAnnotate ann_expr
 309     ty       = exprType expr
 310     dest_lvl = destLevel env fvs (isFunction ann_expr)
 311     abs_vars = abstractVars dest_lvl env fvs
 312 \end{code}
 313
 314
 315 %************************************************************************
 316 %*                                                                      *
 317 \subsection{Bindings}
 318 %*                                                                      *
 319 %************************************************************************
 320
 321 The binding stuff works for top level too.
 322
 323 \begin{code}
 324 lvlBind :: TopLevelFlag         -- Used solely to decide whether to clone
 325         -> Level                -- Context level; might be Top even for bindings nested in the RHS
 326                                 -- of a top level binding
 327         -> LevelEnv
 328         -> CoreBindWithFVs
 329         -> LvlM (LevelledBind, LevelEnv)
 330
 331 lvlBind top_lvl ctxt_lvl env (AnnNonRec bndr rhs@(rhs_fvs,_))
 332   | null abs_vars
 333   =     -- No type abstraction; clone existing binder
 334     lvlExpr ctxt_lvl env rhs                    `thenLvl` \ rhs' ->
 335     cloneVar top_lvl env bndr dest_lvl          `thenLvl` \ (env', bndr') ->
 336     returnLvl (NonRec (bndr', dest_lvl) rhs', env')
 337
 338   | otherwise
 339   = -- Yes, type abstraction; create a new binder, extend substitution, etc
 340     lvlFloatRhs abs_vars dest_lvl env rhs       `thenLvl` \ rhs' ->
 341     newPolyBndrs dest_lvl env abs_vars [bndr]   `thenLvl` \ (env', [bndr']) ->
 342     returnLvl (NonRec (bndr', dest_lvl) rhs', env')
 343
 344   where
 345     bind_fvs = rhs_fvs `unionVarSet` idFreeVars bndr
 346     abs_vars = abstractVars dest_lvl env bind_fvs
 347
 348     dest_lvl | isUnLiftedType (idType bndr) = destLevel env bind_fvs False `maxLvl` Level 1 0
 349              | otherwise                    = destLevel env bind_fvs (isFunction rhs)
 350         -- Hack alert!  We do have some unlifted bindings, for cheap primops, and
 351         -- it is ok to float them out; but not to the top level.  If they would otherwise
 352         -- go to the top level, we pin them inside the topmost lambda
 353 \end{code}
 354
 355
 356 \begin{code}
 357 lvlBind top_lvl ctxt_lvl env (AnnRec pairs)
 358   | null abs_vars
 359   = cloneVars top_lvl env bndrs dest_lvl        `thenLvl` \ (new_env, new_bndrs) ->
 360     mapLvl (lvlExpr ctxt_lvl new_env) rhss      `thenLvl` \ new_rhss ->
 361     returnLvl (Rec ((new_bndrs `zip` repeat dest_lvl) `zip` new_rhss), new_env)
 362
 363   | isSingleton pairs && count isId abs_vars > 1
 364   =     -- Special case for self recursion where there are
 365         -- several variables carried around: build a local loop:
 366         --      poly_f = \abs_vars. \lam_vars . letrec f = \lam_vars. rhs in f lam_vars
 367         -- This just makes the closures a bit smaller.  If we don't do
 368         -- this, allocation rises significantly on some programs
 369         --
 370         -- We could elaborate it for the case where there are several
 371         -- mutually functions, but it's quite a bit more complicated
 372         --
 373         -- This all seems a bit ad hoc -- sigh
 374     let
 375         (bndr,rhs) = head pairs
 376         (rhs_lvl, abs_vars_w_lvls) = lvlLamBndrs dest_lvl abs_vars
 377         rhs_env = extendLvlEnv env abs_vars_w_lvls
 378     in
 379     cloneVar NotTopLevel rhs_env bndr rhs_lvl   `thenLvl` \ (rhs_env', new_bndr) ->
 380     let
 381         (lam_bndrs, rhs_body)     = collect_binders rhs
 382         (body_lvl, new_lam_bndrs) = lvlLamBndrs rhs_lvl lam_bndrs
 383         body_env                  = extendLvlEnv rhs_env' new_lam_bndrs
 384     in
 385     lvlExpr body_lvl body_env rhs_body          `thenLvl` \ new_rhs_body ->
 386     newPolyBndrs dest_lvl env abs_vars [bndr]   `thenLvl` \ (poly_env, [poly_bndr]) ->
 387     returnLvl (Rec [((poly_bndr,dest_lvl), mkLams abs_vars_w_lvls $
 388                                            glue_binders new_lam_bndrs rhs $
 389                                            Let (Rec [((new_bndr,rhs_lvl), mkLams new_lam_bndrs new_rhs_body)])
 390                                                 (mkVarApps (Var new_bndr) lam_bndrs))],
 391                poly_env)
 392
 393   | otherwise
 394   = newPolyBndrs dest_lvl env abs_vars bndrs    `thenLvl` \ (new_env, new_bndrs) ->
 395     mapLvl (lvlFloatRhs abs_vars dest_lvl new_env) rhss         `thenLvl` \ new_rhss ->
 396     returnLvl (Rec ((new_bndrs `zip` repeat dest_lvl) `zip` new_rhss), new_env)
 397
 398   where
 399     (bndrs,rhss) = unzip pairs
 400
 401         -- Finding the free vars of the binding group is annoying
 402     bind_fvs        = (unionVarSets [ idFreeVars bndr `unionVarSet` rhs_fvs
 403                                     | (bndr, (rhs_fvs,_)) <- pairs])
 404                       `minusVarSet`
 405                       mkVarSet bndrs
 406
 407     dest_lvl = destLevel env bind_fvs (all isFunction rhss)
 408     abs_vars = abstractVars dest_lvl env bind_fvs
 409
 410 ----------------------------------------------------
 411 -- Three help functons for the type-abstraction case
 412
 413 lvlFloatRhs abs_vars dest_lvl env rhs
 414   = lvlExpr rhs_lvl rhs_env rhs `thenLvl` \ rhs' ->
 415     returnLvl (mkLams abs_vars_w_lvls rhs')
 416   where
 417     (rhs_lvl, abs_vars_w_lvls) = lvlLamBndrs dest_lvl abs_vars
 418     rhs_env = extendLvlEnv env abs_vars_w_lvls
 419 \end{code}
 420
 421
 422 %************************************************************************
 423 %*                                                                      *
 424 \subsection{Deciding floatability}
 425 %*                                                                      *
 426 %************************************************************************
 427
 428 \begin{code}
 429 lvlLamBndrs :: Level -> [CoreBndr] -> (Level, [(CoreBndr, Level)])
 430 -- Compute the levels for the binders of a lambda group
 431 lvlLamBndrs lvl []
 432   = (lvl, [])
 433
 434 lvlLamBndrs lvl bndrs
 435   = go  (incMinorLvl lvl)
 436         False   -- Havn't bumped major level in this group
 437         [] bndrs
 438   where
 439     go old_lvl bumped_major rev_lvld_bndrs (bndr:bndrs)
 440         | isId bndr &&                  -- Go to the next major level if this is a value binder,
 441           not bumped_major &&           -- and we havn't already gone to the next level (one jump per group)
 442           not (isOneShotLambda bndr)    -- and it isn't a one-shot lambda
 443         = go new_lvl True ((bndr,new_lvl) : rev_lvld_bndrs) bndrs
 444
 445         | otherwise
 446         = go old_lvl bumped_major ((bndr,old_lvl) : rev_lvld_bndrs) bndrs
 447
 448         where
 449           new_lvl = incMajorLvl old_lvl
 450
 451     go old_lvl _ rev_lvld_bndrs []
 452         = (old_lvl, reverse rev_lvld_bndrs)
 453         -- a lambda like this (\x -> coerce t (\s -> ...))
 454         -- This happens quite a bit in state-transformer programs
 455 \end{code}
 456
 457 \begin{code}
 458 abstractVars :: Level -> LevelEnv -> VarSet -> [Var]
 459         -- Find the variables in fvs, free vars of the target expresion,
 460         -- whose level is less than than the supplied level
 461         -- These are the ones we are going to abstract out
 462 abstractVars dest_lvl env fvs
 463   = uniq (sortLt lt [var | fv <- varSetElems fvs, var <- absVarsOf dest_lvl env fv])
 464   where
 465         -- Sort the variables so we don't get
 466         -- mixed-up tyvars and Ids; it's just messy
 467     v1 `lt` v2 = case (isId v1, isId v2) of
 468                    (True, False) -> False
 469                    (False, True) -> True
 470                    other         -> v1 < v2     -- Same family
 471     uniq :: [Var] -> [Var]
 472         -- Remove adjacent duplicates; the sort will have brought them together
 473     uniq (v1:v2:vs) | v1 == v2  = uniq (v2:vs)
 474                     | otherwise = v1 : uniq (v2:vs)
 475     uniq vs = vs
 476
 477   -- Destintion level is the max Id level of the expression
 478   -- (We'll abstract the type variables, if any.)
 479 destLevel :: LevelEnv -> VarSet -> Bool -> Level
 480 destLevel env fvs is_function
 481   |  floatLams env
 482   && is_function = tOP_LEVEL            -- Send functions to top level; see
 483                                         -- the comments with isFunction
 484   | otherwise    = maxIdLevel env fvs
 485
 486 isFunction :: CoreExprWithFVs -> Bool
 487 -- The idea here is that we want to float *functions* to
 488 -- the top level.  This saves no work, but
 489 --      (a) it can make the host function body a lot smaller,
 490 --              and hence inlinable.
 491 --      (b) it can also save allocation when the function is recursive:
 492 --          h = \x -> letrec f = \y -> ...f...y...x...
 493 --                    in f x
 494 --     becomes
 495 --          f = \x y -> ...(f x)...y...x...
 496 --          h = \x -> f x x
 497 --     No allocation for f now.
 498 -- We may only want to do this if there are sufficiently few free
 499 -- variables.  We certainly only want to do it for values, and not for
 500 -- constructors.  So the simple thing is just to look for lambdas
 501 isFunction (_, AnnLam b e) | isId b    = True
 502                            | otherwise = isFunction e
 503 isFunction (_, AnnNote n e)            = isFunction e
 504 isFunction other                       = False
 505 \end{code}
 506
 507
 508 %************************************************************************
 509 %*                                                                      *
 510 \subsection{Free-To-Level Monad}
 511 %*                                                                      *
 512 %************************************************************************
 513
 514 \begin{code}
 515 type LevelEnv = (Bool,                          -- True <=> Float lambdas too
 516                  VarEnv Level,                  -- Domain is *post-cloned* TyVars and Ids
 517                  SubstEnv,                      -- Domain is pre-cloned Ids
 518                  IdEnv ([Var], LevelledExpr))   -- Domain is pre-cloned Ids
 519         -- We clone let-bound variables so that they are still
 520         -- distinct when floated out; hence the SubstEnv/IdEnv.
 521         -- We also use these envs when making a variable polymorphic
 522         -- because we want to float it out past a big lambda.
 523         --
 524         -- The two Envs always implement the same mapping, but the
 525         -- SubstEnv maps to CoreExpr and the IdEnv to LevelledExpr
 526         -- Since the range is always a variable or type application,
 527         -- there is never any difference between the two, but sadly
 528         -- the types differ.  The SubstEnv is used when substituting in
 529         -- a variable's IdInfo; the IdEnv when we find a Var.
 530         --
 531         -- In addition the IdEnv records a list of tyvars free in the
 532         -- type application, just so we don't have to call freeVars on
 533         -- the type application repeatedly.
 534         --
 535         -- The domain of the both envs is *pre-cloned* Ids, though
 536         --
 537         -- The domain of the VarEnv Level is the *post-cloned* Ids
 538
 539 initialEnv :: Bool -> LevelEnv
 540 initialEnv float_lams = (float_lams, emptyVarEnv, emptySubstEnv, emptyVarEnv)
 541
 542 floatLams :: LevelEnv -> Bool
 543 floatLams (float_lams, _, _, _) = float_lams
 544
 545 extendLvlEnv :: LevelEnv -> [(Var,Level)] -> LevelEnv
 546         -- Used when *not* cloning
 547 extendLvlEnv (float_lams, lvl_env, subst_env, id_env) prs
 548   = (float_lams, foldl add lvl_env prs, subst_env, id_env)
 549   where
 550     add env (v,l) = extendVarEnv env v l
 551
 552 -- extendCaseBndrLvlEnv adds the mapping case-bndr->scrut-var if it can
 553 extendCaseBndrLvlEnv env scrut case_bndr lvl
 554   = case scrut of
 555         Var v -> extendCloneLvlEnv lvl env [(case_bndr, v)]
 556         other -> extendLvlEnv          env [(case_bndr,lvl)]
 557
 558 extendPolyLvlEnv dest_lvl (float_lams, lvl_env, subst_env, id_env) abs_vars bndr_pairs
 559   = (float_lams,
 560      foldl add_lvl   lvl_env   bndr_pairs,
 561      foldl add_subst subst_env bndr_pairs,
 562      foldl add_id    id_env    bndr_pairs)
 563   where
 564      add_lvl   env (v,v') = extendVarEnv   env v' dest_lvl
 565      add_subst env (v,v') = extendSubstEnv env v (DoneEx (mkVarApps (Var v') abs_vars))
 566      add_id    env (v,v') = extendVarEnv   env v ((v':abs_vars), mkVarApps (Var v') abs_vars)
 567
 568 extendCloneLvlEnv lvl (float_lams, lvl_env, subst_env, id_env) bndr_pairs
 569   = (float_lams,
 570      foldl add_lvl lvl_env bndr_pairs,
 571      foldl add_subst subst_env bndr_pairs,
 572      foldl add_id    id_env    bndr_pairs)
 573   where
 574      add_lvl   env (v,v') = extendVarEnv   env v' lvl
 575      add_subst env (v,v') = extendSubstEnv env v (DoneEx (Var v'))
 576      add_id    env (v,v') = extendVarEnv   env v ([v'], Var v')
 577
 578
 579 maxIdLevel :: LevelEnv -> VarSet -> Level
 580 maxIdLevel (_, lvl_env,_,id_env) var_set
 581   = foldVarSet max_in tOP_LEVEL var_set
 582   where
 583     max_in in_var lvl = foldr max_out lvl (case lookupVarEnv id_env in_var of
 584                                                 Just (abs_vars, _) -> abs_vars
 585                                                 Nothing            -> [in_var])
 586
 587     max_out out_var lvl
 588         | isId out_var = case lookupVarEnv lvl_env out_var of
 589                                 Just lvl' -> maxLvl lvl' lvl
 590                                 Nothing   -> lvl
 591         | otherwise    = lvl    -- Ignore tyvars in *maxIdLevel*
 592
 593 lookupVar :: LevelEnv -> Id -> LevelledExpr
 594 lookupVar (_, _, _, id_env) v = case lookupVarEnv id_env v of
 595                                        Just (_, expr) -> expr
 596                                        other          -> Var v
 597
 598 absVarsOf :: Level -> LevelEnv -> Var -> [Var]
 599         -- If f is free in the exression, and f maps to poly_f a b c in the
 600         -- current substitution, then we must report a b c as candidate type
 601         -- variables
 602 absVarsOf dest_lvl (_, lvl_env, _, id_env) v
 603   | isId v
 604   = [final_av | av <- lookup_avs v, abstract_me av, final_av <- add_tyvars av]
 605
 606   | otherwise
 607   = if abstract_me v then [v] else []
 608
 609   where
 610     abstract_me v = case lookupVarEnv lvl_env v of
 611                         Just lvl -> dest_lvl `ltLvl` lvl
 612                         Nothing  -> False
 613
 614     lookup_avs v = case lookupVarEnv id_env v of
 615                         Just (abs_vars, _) -> abs_vars
 616                         Nothing            -> [v]
 617
 618         -- We are going to lambda-abstract, so nuke any IdInfo,
 619         -- and add the tyvars of the Id
 620     add_tyvars v | isId v    =  zap v  : varSetElems (idFreeTyVars v)
 621                  | otherwise = [v]
 622
 623     zap v = WARN( workerExists (idWorkerInfo v)
 624                   || not (isEmptyCoreRules (idSpecialisation v)),
 625                   text "absVarsOf: discarding info on" <+> ppr v )
 626             setIdInfo v vanillaIdInfo
 627 \end{code}
 628
 629 \begin{code}
 630 type LvlM result = UniqSM result
 631
 632 initLvl         = initUs_
 633 thenLvl         = thenUs
 634 returnLvl       = returnUs
 635 mapLvl          = mapUs
 636 \end{code}
 637
 638 \begin{code}
 639 newPolyBndrs dest_lvl env abs_vars bndrs
 640   = getUniquesUs (length bndrs)         `thenLvl` \ uniqs ->
 641     let
 642         new_bndrs = zipWith mk_poly_bndr bndrs uniqs
 643     in
 644     returnLvl (extendPolyLvlEnv dest_lvl env abs_vars (bndrs `zip` new_bndrs), new_bndrs)
 645   where
 646     mk_poly_bndr bndr uniq = mkSysLocal (_PK_ str) uniq poly_ty
 647                            where
 648                              str     = "poly_" ++ occNameUserString (getOccName bndr)
 649                              poly_ty = foldr mkPiType (idType bndr) abs_vars
 650
 651
 652 newLvlVar :: String
 653           -> [CoreBndr] -> Type         -- Abstract wrt these bndrs
 654           -> LvlM Id
 655 newLvlVar str vars body_ty
 656   = getUniqueUs `thenLvl` \ uniq ->
 657     returnUs (mkSysLocal (_PK_ str) uniq (foldr mkPiType body_ty vars))
 658
 659 -- The deeply tiresome thing is that we have to apply the substitution
 660 -- to the rules inside each Id.  Grr.  But it matters.
 661
 662 cloneVar :: TopLevelFlag -> LevelEnv -> Id -> Level -> LvlM (LevelEnv, Id)
 663 cloneVar TopLevel env v lvl
 664   = returnUs (env, v)   -- Don't clone top level things
 665 cloneVar NotTopLevel env v lvl
 666   = getUniqueUs `thenLvl` \ uniq ->
 667     let
 668       v'         = setVarUnique v uniq
 669       v''        = subst_id_info env v'
 670       env'       = extendCloneLvlEnv lvl env [(v,v'')]
 671     in
 672     returnUs (env', v'')
 673
 674 cloneVars :: TopLevelFlag -> LevelEnv -> [Id] -> Level -> LvlM (LevelEnv, [Id])
 675 cloneVars TopLevel env vs lvl
 676   = returnUs (env, vs)  -- Don't clone top level things
 677 cloneVars NotTopLevel env vs lvl
 678   = getUniquesUs (length vs)    `thenLvl` \ uniqs ->
 679     let
 680       vs'        = zipWith setVarUnique vs uniqs
 681       vs''       = map (subst_id_info env') vs'
 682       env'       = extendCloneLvlEnv lvl env (vs `zip` vs'')
 683     in
 684     returnUs (env', vs'')
 685
 686 subst_id_info (_, _, subst_env, _) v
 687     = modifyIdInfo (\info -> substIdInfo subst info info) v
 688   where
 689     subst = mkSubst emptyVarSet subst_env
 690 \end{code}
 691