ghc/compiler/simplCore/SetLevels.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section{SetLevels}
   5
   6                 ***************************
   7                         Overview
   8                 ***************************
   9
  10 1. We attach binding levels to Core bindings, in preparation for floating
  11    outwards (@FloatOut@).
  12
  13 2. We also let-ify many expressions (notably case scrutinees), so they
  14    will have a fighting chance of being floated sensible.
  15
  16 3. We clone the binders of any floatable let-binding, so that when it is
  17    floated out it will be unique.  (This used to be done by the simplifier
  18    but the latter now only ensures that there's no shadowing; indeed, even
  19    that may not be true.)
  20
  21    NOTE: this can't be done using the uniqAway idea, because the variable
  22          must be unique in the whole program, not just its current scope,
  23          because two variables in different scopes may float out to the
  24          same top level place
  25
  26    NOTE: Very tiresomely, we must apply this substitution to
  27          the rules stored inside a variable too.
  28
  29    We do *not* clone top-level bindings, because some of them must not change,
  30    but we *do* clone bindings that are heading for the top level
  31
  32 4. In the expression
  33         case x of wild { p -> ...wild... }
  34    we substitute x for wild in the RHS of the case alternatives:
  35         case x of wild { p -> ...x... }
  36    This means that a sub-expression involving x is not "trapped" inside the RHS.
  37    And it's not inconvenient because we already have a substitution.
  38
  39   Note that this is EXACTLY BACKWARDS from the what the simplifier does.
  40   The simplifier tries to get rid of occurrences of x, in favour of wild,
  41   in the hope that there will only be one remaining occurrence of x, namely
  42   the scrutinee of the case, and we can inline it.
  43
  44 \begin{code}
  45 module SetLevels (
  46         setLevels,
  47
  48         Level(..), tOP_LEVEL,
  49
  50         incMinorLvl, ltMajLvl, ltLvl, isTopLvl, isInlineCtxt
  51     ) where
  52
  53 #include "HsVersions.h"
  54
  55 import CoreSyn
  56
  57 import CoreUtils        ( exprType, exprIsTrivial, exprIsBottom, mkPiTypes )
  58 import CoreFVs          -- all of it
  59 import Subst
  60 import Id               ( Id, idType, mkSysLocal, isOneShotLambda, zapDemandIdInfo,
  61                           idSpecialisation, idWorkerInfo, setIdInfo
  62                         )
  63 import IdInfo           ( workerExists, vanillaIdInfo, )
  64 import Var              ( Var )
  65 import VarSet
  66 import VarEnv
  67 import Name             ( getOccName )
  68 import OccName          ( occNameUserString )
  69 import Type             ( isUnLiftedType, Type )
  70 import BasicTypes       ( TopLevelFlag(..) )
  71 import UniqSupply
  72 import Util             ( sortLt, isSingleton, count )
  73 import Outputable
  74 \end{code}
  75
  76 %************************************************************************
  77 %*                                                                      *
  78 \subsection{Level numbers}
  79 %*                                                                      *
  80 %************************************************************************
  81
  82 \begin{code}
  83 data Level = InlineCtxt -- A level that's used only for
  84                         -- the context parameter ctxt_lvl
  85            | Level Int  -- Level number of enclosing lambdas
  86                    Int  -- Number of big-lambda and/or case expressions between
  87                         -- here and the nearest enclosing lambda
  88 \end{code}
  89
  90 The {\em level number} on a (type-)lambda-bound variable is the
  91 nesting depth of the (type-)lambda which binds it.  The outermost lambda
  92 has level 1, so (Level 0 0) means that the variable is bound outside any lambda.
  93
  94 On an expression, it's the maximum level number of its free
  95 (type-)variables.  On a let(rec)-bound variable, it's the level of its
  96 RHS.  On a case-bound variable, it's the number of enclosing lambdas.
  97
  98 Top-level variables: level~0.  Those bound on the RHS of a top-level
  99 definition but ``before'' a lambda; e.g., the \tr{x} in (levels shown
 100 as ``subscripts'')...
 101 \begin{verbatim}
 102 a_0 = let  b_? = ...  in
 103            x_1 = ... b ... in ...
 104 \end{verbatim}
 105
 106 The main function @lvlExpr@ carries a ``context level'' (@ctxt_lvl@).
 107 That's meant to be the level number of the enclosing binder in the
 108 final (floated) program.  If the level number of a sub-expression is
 109 less than that of the context, then it might be worth let-binding the
 110 sub-expression so that it will indeed float.
 111
 112 If you can float to level @Level 0 0@ worth doing so because then your
 113 allocation becomes static instead of dynamic.  We always start with
 114 context @Level 0 0@.
 115
 116
 117 InlineCtxt
 118 ~~~~~~~~~~
 119 @InlineCtxt@ very similar to @Level 0 0@, but is used for one purpose:
 120 to say "don't float anything out of here".  That's exactly what we
 121 want for the body of an INLINE, where we don't want to float anything
 122 out at all.  See notes with lvlMFE below.
 123
 124 But, check this out:
 125
 126 -- At one time I tried the effect of not float anything out of an InlineMe,
 127 -- but it sometimes works badly.  For example, consider PrelArr.done.  It
 128 -- has the form         __inline (\d. e)
 129 -- where e doesn't mention d.  If we float this to
 130 --      __inline (let x = e in \d. x)
 131 -- things are bad.  The inliner doesn't even inline it because it doesn't look
 132 -- like a head-normal form.  So it seems a lesser evil to let things float.
 133 -- In SetLevels we do set the context to (Level 0 0) when we get to an InlineMe
 134 -- which discourages floating out.
 135
 136 So the conclusion is: don't do any floating at all inside an InlineMe.
 137 (In the above example, don't float the {x=e} out of the \d.)
 138
 139 One particular case is that of workers: we don't want to float the
 140 call to the worker outside the wrapper, otherwise the worker might get
 141 inlined into the floated expression, and an importing module won't see
 142 the worker at all.
 143
 144 \begin{code}
 145 type LevelledExpr  = TaggedExpr Level
 146 type LevelledBind  = TaggedBind Level
 147
 148 tOP_LEVEL   = Level 0 0
 149 iNLINE_CTXT = InlineCtxt
 150
 151 incMajorLvl :: Level -> Level
 152 -- For InlineCtxt we ignore any inc's; we don't want
 153 -- to do any floating at all; see notes above
 154 incMajorLvl InlineCtxt          = InlineCtxt
 155 incMajorLvl (Level major minor) = Level (major+1) 0
 156
 157 incMinorLvl :: Level -> Level
 158 incMinorLvl InlineCtxt          = InlineCtxt
 159 incMinorLvl (Level major minor) = Level major (minor+1)
 160
 161 maxLvl :: Level -> Level -> Level
 162 maxLvl InlineCtxt l2  = l2
 163 maxLvl l1  InlineCtxt = l1
 164 maxLvl l1@(Level maj1 min1) l2@(Level maj2 min2)
 165   | (maj1 > maj2) || (maj1 == maj2 && min1 > min2) = l1
 166   | otherwise                                      = l2
 167
 168 ltLvl :: Level -> Level -> Bool
 169 ltLvl any_lvl    InlineCtxt  = False
 170 ltLvl InlineCtxt (Level _ _) = True
 171 ltLvl (Level maj1 min1) (Level maj2 min2)
 172   = (maj1 < maj2) || (maj1 == maj2 && min1 < min2)
 173
 174 ltMajLvl :: Level -> Level -> Bool
 175     -- Tells if one level belongs to a difft *lambda* level to another
 176 ltMajLvl any_lvl        InlineCtxt     = False
 177 ltMajLvl InlineCtxt     (Level maj2 _) = 0 < maj2
 178 ltMajLvl (Level maj1 _) (Level maj2 _) = maj1 < maj2
 179
 180 isTopLvl :: Level -> Bool
 181 isTopLvl (Level 0 0) = True
 182 isTopLvl other       = False
 183
 184 isInlineCtxt :: Level -> Bool
 185 isInlineCtxt InlineCtxt = True
 186 isInlineCtxt other      = False
 187
 188 instance Outputable Level where
 189   ppr InlineCtxt      = text "<INLINE>"
 190   ppr (Level maj min) = hcat [ char '<', int maj, char ',', int min, char '>' ]
 191
 192 instance Eq Level where
 193   InlineCtxt        == InlineCtxt        = True
 194   (Level maj1 min1) == (Level maj2 min2) = maj1==maj2 && min1==min2
 195   l1                == l2                = False
 196 \end{code}
 197
 198
 199 %************************************************************************
 200 %*                                                                      *
 201 \subsection{Main level-setting code}
 202 %*                                                                      *
 203 %************************************************************************
 204
 205 \begin{code}
 206 setLevels :: Bool               -- True <=> float lambdas to top level
 207           -> [CoreBind]
 208           -> UniqSupply
 209           -> [LevelledBind]
 210
 211 setLevels float_lams binds us
 212   = initLvl us (do_them binds)
 213   where
 214     -- "do_them"'s main business is to thread the monad along
 215     -- It gives each top binding the same empty envt, because
 216     -- things unbound in the envt have level number zero implicitly
 217     do_them :: [CoreBind] -> LvlM [LevelledBind]
 218
 219     do_them [] = returnLvl []
 220     do_them (b:bs)
 221       = lvlTopBind init_env b   `thenLvl` \ (lvld_bind, _) ->
 222         do_them bs              `thenLvl` \ lvld_binds ->
 223         returnLvl (lvld_bind : lvld_binds)
 224
 225     init_env = initialEnv float_lams
 226
 227 lvlTopBind env (NonRec binder rhs)
 228   = lvlBind TopLevel tOP_LEVEL env (AnnNonRec binder (freeVars rhs))
 229                                         -- Rhs can have no free vars!
 230
 231 lvlTopBind env (Rec pairs)
 232   = lvlBind TopLevel tOP_LEVEL env (AnnRec [(b,freeVars rhs) | (b,rhs) <- pairs])
 233 \end{code}
 234
 235 %************************************************************************
 236 %*                                                                      *
 237 \subsection{Setting expression levels}
 238 %*                                                                      *
 239 %************************************************************************
 240
 241 \begin{code}
 242 lvlExpr :: Level                -- ctxt_lvl: Level of enclosing expression
 243         -> LevelEnv             -- Level of in-scope names/tyvars
 244         -> CoreExprWithFVs      -- input expression
 245         -> LvlM LevelledExpr    -- Result expression
 246 \end{code}
 247
 248 The @ctxt_lvl@ is, roughly, the level of the innermost enclosing
 249 binder.  Here's an example
 250
 251         v = \x -> ...\y -> let r = case (..x..) of
 252                                         ..x..
 253                            in ..
 254
 255 When looking at the rhs of @r@, @ctxt_lvl@ will be 1 because that's
 256 the level of @r@, even though it's inside a level-2 @\y@.  It's
 257 important that @ctxt_lvl@ is 1 and not 2 in @r@'s rhs, because we
 258 don't want @lvlExpr@ to turn the scrutinee of the @case@ into an MFE
 259 --- because it isn't a *maximal* free expression.
 260
 261 If there were another lambda in @r@'s rhs, it would get level-2 as well.
 262
 263 \begin{code}
 264 lvlExpr _ _ (_, AnnType ty)   = returnLvl (Type ty)
 265 lvlExpr _ env (_, AnnVar v)   = returnLvl (lookupVar env v)
 266 lvlExpr _ env (_, AnnLit lit) = returnLvl (Lit lit)
 267
 268 lvlExpr ctxt_lvl env (_, AnnApp fun arg)
 269   = lvl_fun fun                         `thenLvl` \ fun' ->
 270     lvlMFE  False ctxt_lvl env arg      `thenLvl` \ arg' ->
 271     returnLvl (App fun' arg')
 272   where
 273     lvl_fun (_, AnnCase _ _ _) = lvlMFE True ctxt_lvl env fun
 274     lvl_fun other              = lvlExpr ctxt_lvl env fun
 275         -- We don't do MFE on partial applications generally,
 276         -- but we do if the function is big and hairy, like a case
 277
 278 lvlExpr ctxt_lvl env (_, AnnNote InlineMe expr)
 279 -- Don't float anything out of an InlineMe; hence the iNLINE_CTXT
 280   = lvlExpr iNLINE_CTXT env expr        `thenLvl` \ expr' ->
 281     returnLvl (Note InlineMe expr')
 282
 283 lvlExpr ctxt_lvl env (_, AnnNote note expr)
 284   = lvlExpr ctxt_lvl env expr           `thenLvl` \ expr' ->
 285     returnLvl (Note note expr')
 286
 287 -- We don't split adjacent lambdas.  That is, given
 288 --      \x y -> (x+1,y)
 289 -- we don't float to give
 290 --      \x -> let v = x+y in \y -> (v,y)
 291 -- Why not?  Because partial applications are fairly rare, and splitting
 292 -- lambdas makes them more expensive.
 293
 294 lvlExpr ctxt_lvl env expr@(_, AnnLam bndr rhs)
 295   = lvlMFE True new_lvl new_env body    `thenLvl` \ new_body ->
 296     returnLvl (mkLams new_bndrs new_body)
 297   where
 298     (bndrs, body)        = collectAnnBndrs expr
 299     (new_lvl, new_bndrs) = lvlLamBndrs ctxt_lvl bndrs
 300     new_env              = extendLvlEnv env new_bndrs
 301         -- At one time we called a special verion of collectBinders,
 302         -- which ignored coercions, because we don't want to split
 303         -- a lambda like this (\x -> coerce t (\s -> ...))
 304         -- This used to happen quite a bit in state-transformer programs,
 305         -- but not nearly so much now non-recursive newtypes are transparent.
 306         -- [See SetLevels rev 1.50 for a version with this approach.]
 307
 308 lvlExpr ctxt_lvl env (_, AnnLet bind body)
 309   = lvlBind NotTopLevel ctxt_lvl env bind       `thenLvl` \ (bind', new_env) ->
 310     lvlExpr ctxt_lvl new_env body               `thenLvl` \ body' ->
 311     returnLvl (Let bind' body')
 312
 313 lvlExpr ctxt_lvl env (_, AnnCase expr case_bndr alts)
 314   = lvlMFE True ctxt_lvl env expr       `thenLvl` \ expr' ->
 315     let
 316         alts_env = extendCaseBndrLvlEnv env expr' case_bndr incd_lvl
 317     in
 318     mapLvl (lvl_alt alts_env) alts      `thenLvl` \ alts' ->
 319     returnLvl (Case expr' (case_bndr, incd_lvl) alts')
 320   where
 321       incd_lvl  = incMinorLvl ctxt_lvl
 322
 323       lvl_alt alts_env (con, bs, rhs)
 324         = lvlMFE True incd_lvl new_env rhs      `thenLvl` \ rhs' ->
 325           returnLvl (con, bs', rhs')
 326         where
 327           bs'     = [ (b, incd_lvl) | b <- bs ]
 328           new_env = extendLvlEnv alts_env bs'
 329 \end{code}
 330
 331 @lvlMFE@ is just like @lvlExpr@, except that it might let-bind
 332 the expression, so that it can itself be floated.
 333
 334 \begin{code}
 335 lvlMFE ::  Bool                 -- True <=> strict context [body of case or let]
 336         -> Level                -- Level of innermost enclosing lambda/tylam
 337         -> LevelEnv             -- Level of in-scope names/tyvars
 338         -> CoreExprWithFVs      -- input expression
 339         -> LvlM LevelledExpr    -- Result expression
 340
 341 lvlMFE strict_ctxt ctxt_lvl env (_, AnnType ty)
 342   = returnLvl (Type ty)
 343
 344 lvlMFE strict_ctxt ctxt_lvl env ann_expr@(fvs, _)
 345   |  isUnLiftedType ty                  -- Can't let-bind it
 346   || isInlineCtxt ctxt_lvl              -- Don't float out of an __inline__ context
 347   || not good_destination
 348   || exprIsTrivial expr                 -- Is trivial
 349   || (strict_ctxt && exprIsBottom expr) -- Strict context and is bottom
 350                                         --  e.g. \x -> error "foo"
 351                                         -- No gain from floating this
 352   =     -- Don't float it out
 353     lvlExpr ctxt_lvl env ann_expr
 354
 355   | otherwise   -- Float it out!
 356   = lvlFloatRhs abs_vars dest_lvl env ann_expr  `thenLvl` \ expr' ->
 357     newLvlVar "lvl" abs_vars ty                 `thenLvl` \ var ->
 358     returnLvl (Let (NonRec (var,dest_lvl) expr')
 359                    (mkVarApps (Var var) abs_vars))
 360   where
 361     expr     = deAnnotate ann_expr
 362     ty       = exprType expr
 363     dest_lvl = destLevel env fvs (isFunction ann_expr)
 364     abs_vars = abstractVars dest_lvl env fvs
 365
 366     good_destination =  dest_lvl `ltMajLvl` ctxt_lvl    -- Escapes a value lambda
 367                      || (isTopLvl dest_lvl              -- Goes to the top
 368                          && not strict_ctxt)            --   or from a strict context
 369         -- A decision to float entails let-binding this thing, and we only do
 370         -- that if we'll escape a value lambda, or will go to the top level.
 371         --
 372         -- Beware:
 373         --      concat = /\ a -> foldr ..a.. (++) []
 374         -- was getting turned into
 375         --      concat = /\ a -> lvl a
 376         --      lvl    = /\ a -> foldr ..a.. (++) []
 377         -- which is pretty stupid.  Hence the strict_ctxt test
 378 \end{code}
 379
 380
 381 %************************************************************************
 382 %*                                                                      *
 383 \subsection{Bindings}
 384 %*                                                                      *
 385 %************************************************************************
 386
 387 The binding stuff works for top level too.
 388
 389 \begin{code}
 390 lvlBind :: TopLevelFlag         -- Used solely to decide whether to clone
 391         -> Level                -- Context level; might be Top even for bindings nested in the RHS
 392                                 -- of a top level binding
 393         -> LevelEnv
 394         -> CoreBindWithFVs
 395         -> LvlM (LevelledBind, LevelEnv)
 396
 397 lvlBind top_lvl ctxt_lvl env (AnnNonRec bndr rhs@(rhs_fvs,_))
 398   | isInlineCtxt ctxt_lvl       -- Don't do anything inside InlineMe
 399   = lvlExpr ctxt_lvl env rhs                    `thenLvl` \ rhs' ->
 400     returnLvl (NonRec (bndr, ctxt_lvl) rhs', env)
 401
 402   | null abs_vars
 403   =     -- No type abstraction; clone existing binder
 404     lvlExpr dest_lvl env rhs                    `thenLvl` \ rhs' ->
 405     cloneVar top_lvl env bndr ctxt_lvl dest_lvl `thenLvl` \ (env', bndr') ->
 406     returnLvl (NonRec (bndr', dest_lvl) rhs', env')
 407
 408   | otherwise
 409   = -- Yes, type abstraction; create a new binder, extend substitution, etc
 410     lvlFloatRhs abs_vars dest_lvl env rhs       `thenLvl` \ rhs' ->
 411     newPolyBndrs dest_lvl env abs_vars [bndr]   `thenLvl` \ (env', [bndr']) ->
 412     returnLvl (NonRec (bndr', dest_lvl) rhs', env')
 413
 414   where
 415     bind_fvs = rhs_fvs `unionVarSet` idFreeVars bndr
 416     abs_vars = abstractVars dest_lvl env bind_fvs
 417
 418     dest_lvl | isUnLiftedType (idType bndr) = destLevel env bind_fvs False `maxLvl` Level 1 0
 419              | otherwise                    = destLevel env bind_fvs (isFunction rhs)
 420         -- Hack alert!  We do have some unlifted bindings, for cheap primops, and
 421         -- it is ok to float them out; but not to the top level.  If they would otherwise
 422         -- go to the top level, we pin them inside the topmost lambda
 423 \end{code}
 424
 425
 426 \begin{code}
 427 lvlBind top_lvl ctxt_lvl env (AnnRec pairs)
 428   | isInlineCtxt ctxt_lvl       -- Don't do anything inside InlineMe
 429   = mapLvl (lvlExpr ctxt_lvl env) rhss                  `thenLvl` \ rhss' ->
 430     returnLvl (Rec ((bndrs `zip` repeat ctxt_lvl) `zip` rhss'), env)
 431
 432   | null abs_vars
 433   = cloneRecVars top_lvl env bndrs ctxt_lvl dest_lvl    `thenLvl` \ (new_env, new_bndrs) ->
 434     mapLvl (lvlExpr ctxt_lvl new_env) rhss              `thenLvl` \ new_rhss ->
 435     returnLvl (Rec ((new_bndrs `zip` repeat dest_lvl) `zip` new_rhss), new_env)
 436
 437   | isSingleton pairs && count isId abs_vars > 1
 438   =     -- Special case for self recursion where there are
 439         -- several variables carried around: build a local loop:
 440         --      poly_f = \abs_vars. \lam_vars . letrec f = \lam_vars. rhs in f lam_vars
 441         -- This just makes the closures a bit smaller.  If we don't do
 442         -- this, allocation rises significantly on some programs
 443         --
 444         -- We could elaborate it for the case where there are several
 445         -- mutually functions, but it's quite a bit more complicated
 446         --
 447         -- This all seems a bit ad hoc -- sigh
 448     let
 449         (bndr,rhs) = head pairs
 450         (rhs_lvl, abs_vars_w_lvls) = lvlLamBndrs dest_lvl abs_vars
 451         rhs_env = extendLvlEnv env abs_vars_w_lvls
 452     in
 453     cloneVar NotTopLevel rhs_env bndr rhs_lvl rhs_lvl   `thenLvl` \ (rhs_env', new_bndr) ->
 454     let
 455         (lam_bndrs, rhs_body)     = collectAnnBndrs rhs
 456         (body_lvl, new_lam_bndrs) = lvlLamBndrs rhs_lvl lam_bndrs
 457         body_env                  = extendLvlEnv rhs_env' new_lam_bndrs
 458     in
 459     lvlExpr body_lvl body_env rhs_body          `thenLvl` \ new_rhs_body ->
 460     newPolyBndrs dest_lvl env abs_vars [bndr]   `thenLvl` \ (poly_env, [poly_bndr]) ->
 461     returnLvl (Rec [((poly_bndr,dest_lvl), mkLams abs_vars_w_lvls $
 462                                            mkLams new_lam_bndrs $
 463                                            Let (Rec [((new_bndr,rhs_lvl), mkLams new_lam_bndrs new_rhs_body)])
 464                                                 (mkVarApps (Var new_bndr) lam_bndrs))],
 465                poly_env)
 466
 467   | otherwise   -- Non-null abs_vars
 468   = newPolyBndrs dest_lvl env abs_vars bndrs            `thenLvl` \ (new_env, new_bndrs) ->
 469     mapLvl (lvlFloatRhs abs_vars dest_lvl new_env) rhss `thenLvl` \ new_rhss ->
 470     returnLvl (Rec ((new_bndrs `zip` repeat dest_lvl) `zip` new_rhss), new_env)
 471
 472   where
 473     (bndrs,rhss) = unzip pairs
 474
 475         -- Finding the free vars of the binding group is annoying
 476     bind_fvs        = (unionVarSets [ idFreeVars bndr `unionVarSet` rhs_fvs
 477                                     | (bndr, (rhs_fvs,_)) <- pairs])
 478                       `minusVarSet`
 479                       mkVarSet bndrs
 480
 481     dest_lvl = destLevel env bind_fvs (all isFunction rhss)
 482     abs_vars = abstractVars dest_lvl env bind_fvs
 483
 484 ----------------------------------------------------
 485 -- Three help functons for the type-abstraction case
 486
 487 lvlFloatRhs abs_vars dest_lvl env rhs
 488   = lvlExpr rhs_lvl rhs_env rhs `thenLvl` \ rhs' ->
 489     returnLvl (mkLams abs_vars_w_lvls rhs')
 490   where
 491     (rhs_lvl, abs_vars_w_lvls) = lvlLamBndrs dest_lvl abs_vars
 492     rhs_env = extendLvlEnv env abs_vars_w_lvls
 493 \end{code}
 494
 495
 496 %************************************************************************
 497 %*                                                                      *
 498 \subsection{Deciding floatability}
 499 %*                                                                      *
 500 %************************************************************************
 501
 502 \begin{code}
 503 collectAnnBndrs :: CoreExprWithFVs -> ([CoreBndr], CoreExprWithFVs)
 504 collectAnnBndrs (_, AnnLam b e) = case collectAnnBndrs e of
 505                                         (bs,e') -> (b:bs, e')
 506 collectAnnBndrs e               = ([], e)
 507
 508 lvlLamBndrs :: Level -> [CoreBndr] -> (Level, [(CoreBndr, Level)])
 509 -- Compute the levels for the binders of a lambda group
 510 -- The binders returned are exactly the same as the ones passed,
 511 -- but they are now paired with a level
 512 lvlLamBndrs lvl []
 513   = (lvl, [])
 514
 515 lvlLamBndrs lvl bndrs
 516   = go  (incMinorLvl lvl)
 517         False   -- Havn't bumped major level in this group
 518         [] bndrs
 519   where
 520     go old_lvl bumped_major rev_lvld_bndrs (bndr:bndrs)
 521         | isId bndr &&                  -- Go to the next major level if this is a value binder,
 522           not bumped_major &&           -- and we havn't already gone to the next level (one jump per group)
 523           not (isOneShotLambda bndr)    -- and it isn't a one-shot lambda
 524         = go new_lvl True ((bndr,new_lvl) : rev_lvld_bndrs) bndrs
 525
 526         | otherwise
 527         = go old_lvl bumped_major ((bndr,old_lvl) : rev_lvld_bndrs) bndrs
 528
 529         where
 530           new_lvl = incMajorLvl old_lvl
 531
 532     go old_lvl _ rev_lvld_bndrs []
 533         = (old_lvl, reverse rev_lvld_bndrs)
 534         -- a lambda like this (\x -> coerce t (\s -> ...))
 535         -- This happens quite a bit in state-transformer programs
 536 \end{code}
 537
 538 \begin{code}
 539   -- Destintion level is the max Id level of the expression
 540   -- (We'll abstract the type variables, if any.)
 541 destLevel :: LevelEnv -> VarSet -> Bool -> Level
 542 destLevel env fvs is_function
 543   |  floatLams env
 544   && is_function = tOP_LEVEL            -- Send functions to top level; see
 545                                         -- the comments with isFunction
 546   | otherwise    = maxIdLevel env fvs
 547
 548 isFunction :: CoreExprWithFVs -> Bool
 549 -- The idea here is that we want to float *functions* to
 550 -- the top level.  This saves no work, but
 551 --      (a) it can make the host function body a lot smaller,
 552 --              and hence inlinable.
 553 --      (b) it can also save allocation when the function is recursive:
 554 --          h = \x -> letrec f = \y -> ...f...y...x...
 555 --                    in f x
 556 --     becomes
 557 --          f = \x y -> ...(f x)...y...x...
 558 --          h = \x -> f x x
 559 --     No allocation for f now.
 560 -- We may only want to do this if there are sufficiently few free
 561 -- variables.  We certainly only want to do it for values, and not for
 562 -- constructors.  So the simple thing is just to look for lambdas
 563 isFunction (_, AnnLam b e) | isId b    = True
 564                            | otherwise = isFunction e
 565 isFunction (_, AnnNote n e)            = isFunction e
 566 isFunction other                       = False
 567 \end{code}
 568
 569
 570 %************************************************************************
 571 %*                                                                      *
 572 \subsection{Free-To-Level Monad}
 573 %*                                                                      *
 574 %************************************************************************
 575
 576 \begin{code}
 577 type LevelEnv = (Bool,                          -- True <=> Float lambdas too
 578                  VarEnv Level,                  -- Domain is *post-cloned* TyVars and Ids
 579                  Subst,                         -- Domain is pre-cloned Ids; tracks the in-scope set
 580                                                 --      so that subtitution is capture-avoiding
 581                  IdEnv ([Var], LevelledExpr))   -- Domain is pre-cloned Ids
 582         -- We clone let-bound variables so that they are still
 583         -- distinct when floated out; hence the SubstEnv/IdEnv.
 584         -- (see point 3 of the module overview comment).
 585         -- We also use these envs when making a variable polymorphic
 586         -- because we want to float it out past a big lambda.
 587         --
 588         -- The SubstEnv and IdEnv always implement the same mapping, but the
 589         -- SubstEnv maps to CoreExpr and the IdEnv to LevelledExpr
 590         -- Since the range is always a variable or type application,
 591         -- there is never any difference between the two, but sadly
 592         -- the types differ.  The SubstEnv is used when substituting in
 593         -- a variable's IdInfo; the IdEnv when we find a Var.
 594         --
 595         -- In addition the IdEnv records a list of tyvars free in the
 596         -- type application, just so we don't have to call freeVars on
 597         -- the type application repeatedly.
 598         --
 599         -- The domain of the both envs is *pre-cloned* Ids, though
 600         --
 601         -- The domain of the VarEnv Level is the *post-cloned* Ids
 602
 603 initialEnv :: Bool -> LevelEnv
 604 initialEnv float_lams = (float_lams, emptyVarEnv, emptySubst, emptyVarEnv)
 605
 606 floatLams :: LevelEnv -> Bool
 607 floatLams (float_lams, _, _, _) = float_lams
 608
 609 extendLvlEnv :: LevelEnv -> [(Var,Level)] -> LevelEnv
 610 -- Used when *not* cloning
 611 extendLvlEnv (float_lams, lvl_env, subst, id_env) prs
 612   = (float_lams,
 613      foldl add_lvl lvl_env prs,
 614      foldl del_subst subst prs,
 615      foldl del_id id_env prs)
 616   where
 617     add_lvl   env (v,l) = extendVarEnv env v l
 618     del_subst env (v,_) = extendInScope env v
 619     del_id    env (v,_) = delVarEnv env v
 620   -- We must remove any clone for this variable name in case of
 621   -- shadowing.  This bit me in the following case
 622   -- (in nofib/real/gg/Spark.hs):
 623   --
 624   --   case ds of wild {
 625   --     ... -> case e of wild {
 626   --              ... -> ... wild ...
 627   --            }
 628   --   }
 629   --
 630   -- The inside occurrence of @wild@ was being replaced with @ds@,
 631   -- incorrectly, because the SubstEnv was still lying around.  Ouch!
 632   -- KSW 2000-07.
 633
 634 -- extendCaseBndrLvlEnv adds the mapping case-bndr->scrut-var if it can
 635 -- (see point 4 of the module overview comment)
 636 extendCaseBndrLvlEnv (float_lams, lvl_env, subst, id_env) (Var scrut_var) case_bndr lvl
 637   = (float_lams,
 638      extendVarEnv lvl_env case_bndr lvl,
 639      extendSubst subst case_bndr (DoneEx (Var scrut_var)),
 640      extendVarEnv id_env case_bndr ([scrut_var], Var scrut_var))
 641
 642 extendCaseBndrLvlEnv env scrut case_bndr lvl
 643   = extendLvlEnv          env [(case_bndr,lvl)]
 644
 645 extendPolyLvlEnv dest_lvl (float_lams, lvl_env, subst, id_env) abs_vars bndr_pairs
 646   = (float_lams,
 647      foldl add_lvl   lvl_env bndr_pairs,
 648      foldl add_subst subst   bndr_pairs,
 649      foldl add_id    id_env  bndr_pairs)
 650   where
 651      add_lvl   env (v,v') = extendVarEnv env v' dest_lvl
 652      add_subst env (v,v') = extendSubst  env v (DoneEx (mkVarApps (Var v') abs_vars))
 653      add_id    env (v,v') = extendVarEnv env v ((v':abs_vars), mkVarApps (Var v') abs_vars)
 654
 655 extendCloneLvlEnv lvl (float_lams, lvl_env, _, id_env) new_subst bndr_pairs
 656   = (float_lams,
 657      foldl add_lvl   lvl_env bndr_pairs,
 658      new_subst,
 659      foldl add_id    id_env  bndr_pairs)
 660   where
 661      add_lvl   env (v,v') = extendVarEnv env v' lvl
 662      add_id    env (v,v') = extendVarEnv env v ([v'], Var v')
 663
 664
 665 maxIdLevel :: LevelEnv -> VarSet -> Level
 666 maxIdLevel (_, lvl_env,_,id_env) var_set
 667   = foldVarSet max_in tOP_LEVEL var_set
 668   where
 669     max_in in_var lvl = foldr max_out lvl (case lookupVarEnv id_env in_var of
 670                                                 Just (abs_vars, _) -> abs_vars
 671                                                 Nothing            -> [in_var])
 672
 673     max_out out_var lvl
 674         | isId out_var = case lookupVarEnv lvl_env out_var of
 675                                 Just lvl' -> maxLvl lvl' lvl
 676                                 Nothing   -> lvl
 677         | otherwise    = lvl    -- Ignore tyvars in *maxIdLevel*
 678
 679 lookupVar :: LevelEnv -> Id -> LevelledExpr
 680 lookupVar (_, _, _, id_env) v = case lookupVarEnv id_env v of
 681                                        Just (_, expr) -> expr
 682                                        other          -> Var v
 683
 684 abstractVars :: Level -> LevelEnv -> VarSet -> [Var]
 685         -- Find the variables in fvs, free vars of the target expresion,
 686         -- whose level is greater than the destination level
 687         -- These are the ones we are going to abstract out
 688 abstractVars dest_lvl env fvs
 689   = uniq (sortLt lt [var | fv <- varSetElems fvs, var <- absVarsOf dest_lvl env fv])
 690   where
 691         -- Sort the variables so we don't get
 692         -- mixed-up tyvars and Ids; it's just messy
 693     v1 `lt` v2 = case (isId v1, isId v2) of
 694                    (True, False) -> False
 695                    (False, True) -> True
 696                    other         -> v1 < v2     -- Same family
 697
 698     uniq :: [Var] -> [Var]
 699         -- Remove adjacent duplicates; the sort will have brought them together
 700     uniq (v1:v2:vs) | v1 == v2  = uniq (v2:vs)
 701                     | otherwise = v1 : uniq (v2:vs)
 702     uniq vs = vs
 703
 704 absVarsOf :: Level -> LevelEnv -> Var -> [Var]
 705         -- If f is free in the expression, and f maps to poly_f a b c in the
 706         -- current substitution, then we must report a b c as candidate type
 707         -- variables
 708 absVarsOf dest_lvl (_, lvl_env, _, id_env) v
 709   | isId v
 710   = [zap av2 | av1 <- lookup_avs v, av2 <- add_tyvars av1, abstract_me av2]
 711
 712   | otherwise
 713   = if abstract_me v then [v] else []
 714
 715   where
 716     abstract_me v = case lookupVarEnv lvl_env v of
 717                         Just lvl -> dest_lvl `ltLvl` lvl
 718                         Nothing  -> False
 719
 720     lookup_avs v = case lookupVarEnv id_env v of
 721                         Just (abs_vars, _) -> abs_vars
 722                         Nothing            -> [v]
 723
 724     add_tyvars v | isId v    = v : varSetElems (idFreeTyVars v)
 725                  | otherwise = [v]
 726
 727         -- We are going to lambda-abstract, so nuke any IdInfo,
 728         -- and add the tyvars of the Id (if necessary)
 729     zap v | isId v = WARN( workerExists (idWorkerInfo v) ||
 730                            not (isEmptyCoreRules (idSpecialisation v)),
 731                            text "absVarsOf: discarding info on" <+> ppr v )
 732                      setIdInfo v vanillaIdInfo
 733           | otherwise = v
 734 \end{code}
 735
 736 \begin{code}
 737 type LvlM result = UniqSM result
 738
 739 initLvl         = initUs_
 740 thenLvl         = thenUs
 741 returnLvl       = returnUs
 742 mapLvl          = mapUs
 743 \end{code}
 744
 745 \begin{code}
 746 newPolyBndrs dest_lvl env abs_vars bndrs
 747   = getUniquesUs                `thenLvl` \ uniqs ->
 748     let
 749         new_bndrs = zipWith mk_poly_bndr bndrs uniqs
 750     in
 751     returnLvl (extendPolyLvlEnv dest_lvl env abs_vars (bndrs `zip` new_bndrs), new_bndrs)
 752   where
 753     mk_poly_bndr bndr uniq = mkSysLocal (_PK_ str) uniq poly_ty
 754                            where
 755                              str     = "poly_" ++ occNameUserString (getOccName bndr)
 756                              poly_ty = mkPiTypes abs_vars (idType bndr)
 757
 758
 759 newLvlVar :: String
 760           -> [CoreBndr] -> Type         -- Abstract wrt these bndrs
 761           -> LvlM Id
 762 newLvlVar str vars body_ty
 763   = getUniqueUs `thenLvl` \ uniq ->
 764     returnUs (mkSysLocal (_PK_ str) uniq (mkPiTypes vars body_ty))
 765
 766 -- The deeply tiresome thing is that we have to apply the substitution
 767 -- to the rules inside each Id.  Grr.  But it matters.
 768
 769 cloneVar :: TopLevelFlag -> LevelEnv -> Id -> Level -> Level -> LvlM (LevelEnv, Id)
 770 cloneVar TopLevel env v ctxt_lvl dest_lvl
 771   = returnUs (env, v)   -- Don't clone top level things
 772 cloneVar NotTopLevel env@(_,_,subst,_) v ctxt_lvl dest_lvl
 773   = ASSERT( isId v )
 774     getUs       `thenLvl` \ us ->
 775     let
 776       (subst', v1) = substAndCloneId subst us v
 777       v2           = zap_demand ctxt_lvl dest_lvl v1
 778       env'         = extendCloneLvlEnv dest_lvl env subst' [(v,v2)]
 779     in
 780     returnUs (env', v2)
 781
 782 cloneRecVars :: TopLevelFlag -> LevelEnv -> [Id] -> Level -> Level -> LvlM (LevelEnv, [Id])
 783 cloneRecVars TopLevel env vs ctxt_lvl dest_lvl
 784   = returnUs (env, vs)  -- Don't clone top level things
 785 cloneRecVars NotTopLevel env@(_,_,subst,_) vs ctxt_lvl dest_lvl
 786   = ASSERT( all isId vs )
 787     getUs                       `thenLvl` \ us ->
 788     let
 789       (subst', vs1) = substAndCloneRecIds subst us vs
 790       vs2           = map (zap_demand ctxt_lvl dest_lvl) vs1
 791       env'          = extendCloneLvlEnv dest_lvl env subst' (vs `zip` vs2)
 792     in
 793     returnUs (env', vs2)
 794
 795         -- VERY IMPORTANT: we must zap the demand info
 796         -- if the thing is going to float out past a lambda
 797 zap_demand dest_lvl ctxt_lvl id
 798   | ctxt_lvl == dest_lvl = id                   -- Stays put
 799   | otherwise            = zapDemandIdInfo id   -- Floats out
 800 \end{code}
 801