ghc/compiler/simplCore/SimplCore.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[SimplCore]{Driver for simplifying @Core@ programs}
   5
   6 \begin{code}
   7 module SimplCore ( core2core, simplifyExpr ) where
   8
   9 #include "HsVersions.h"
  10
  11 import CmdLineOpts      ( CoreToDo(..), SimplifierSwitch(..), SimplifierMode(..),
  12                           DynFlags, DynFlag(..), dopt, dopt_CoreToDo
  13                         )
  14 import CoreSyn
  15 import CoreFVs          ( ruleRhsFreeVars )
  16 import HscTypes         ( PersistentCompilerState(..),
  17                           PackageRuleBase, HomeSymbolTable, IsExported, ModDetails(..)
  18                         )
  19 import CSE              ( cseProgram )
  20 import Rules            ( RuleBase, emptyRuleBase, ruleBaseFVs, ruleBaseIds,
  21                           extendRuleBaseList, addRuleBaseFVs, pprRuleBase,
  22                           ruleCheckProgram )
  23 import Module           ( moduleEnvElts )
  24 import PprCore          ( pprCoreBindings, pprCoreExpr )
  25 import OccurAnal        ( occurAnalyseBinds, occurAnalyseGlobalExpr )
  26 import CoreUtils        ( coreBindsSize )
  27 import Simplify         ( simplTopBinds, simplExpr )
  28 import SimplUtils       ( simplBinders )
  29 import SimplMonad
  30 import ErrUtils         ( dumpIfSet, dumpIfSet_dyn, showPass )
  31 import CoreLint         ( endPass )
  32 import FloatIn          ( floatInwards )
  33 import FloatOut         ( floatOutwards )
  34 import Id               ( idName, setIdLocalExported, isImplicitId )
  35 import VarSet
  36 import LiberateCase     ( liberateCase )
  37 import SAT              ( doStaticArgs )
  38 import Specialise       ( specProgram)
  39 import SpecConstr       ( specConstrProgram)
  40 import UsageSPInf       ( doUsageSPInf )
  41 import StrictAnal       ( saBinds )
  42 import DmdAnal          ( dmdAnalPgm )
  43 import WorkWrap         ( wwTopBinds )
  44 import CprAnalyse       ( cprAnalyse )
  45
  46 import UniqSupply       ( UniqSupply, mkSplitUniqSupply, splitUniqSupply )
  47 import IO               ( hPutStr, stderr )
  48 import Outputable
  49
  50 import Maybes           ( orElse )
  51 import List             ( partition )
  52 \end{code}
  53
  54 %************************************************************************
  55 %*                                                                      *
  56 \subsection{The driver for the simplifier}
  57 %*                                                                      *
  58 %************************************************************************
  59
  60 \begin{code}
  61 core2core :: DynFlags           -- includes spec of what core-to-core passes to do
  62           -> PersistentCompilerState
  63           -> HomeSymbolTable
  64           -> IsExported
  65           -> ModDetails
  66           -> IO ModDetails
  67
  68 core2core dflags pcs hst is_exported
  69           mod_details@(ModDetails { md_binds = binds_in, md_rules = rules_in })
  70   = do
  71         let core_todos    = dopt_CoreToDo dflags
  72         let pkg_rule_base = pcs_rules pcs               -- Rule-base accumulated from imported packages
  73
  74
  75         us <-  mkSplitUniqSupply 's'
  76         let (cp_us, ru_us) = splitUniqSupply us
  77
  78                 -- COMPUTE THE RULE BASE TO USE
  79         (rule_base, local_rule_ids, orphan_rules, rule_rhs_fvs)
  80                 <- prepareRules dflags pkg_rule_base hst ru_us binds_in rules_in
  81
  82                 -- PREPARE THE BINDINGS
  83         let binds1 = updateBinders local_rule_ids rule_rhs_fvs is_exported binds_in
  84
  85                 -- DO THE BUSINESS
  86         (stats, processed_binds)
  87                 <- doCorePasses dflags rule_base (zeroSimplCount dflags) cp_us binds1 core_todos
  88
  89         dumpIfSet_dyn dflags Opt_D_dump_simpl_stats
  90                   "Grand total simplifier statistics"
  91                   (pprSimplCount stats)
  92
  93         -- Return results
  94         -- We only return local orphan rules, i.e., local rules not attached to an Id
  95         -- The bindings cotain more rules, embedded in the Ids
  96         return (mod_details { md_binds = processed_binds, md_rules = orphan_rules})
  97
  98
  99 simplifyExpr :: DynFlags -- includes spec of what core-to-core passes to do
 100              -> PersistentCompilerState
 101              -> HomeSymbolTable
 102              -> CoreExpr
 103              -> IO CoreExpr
 104 -- simplifyExpr is called by the driver to simplify an
 105 -- expression typed in at the interactive prompt
 106 simplifyExpr dflags pcs hst expr
 107   = do  {
 108         ; showPass dflags "Simplify"
 109
 110         ; us <-  mkSplitUniqSupply 's'
 111
 112         ; let env              = emptySimplEnv (SimplPhase 0) [] emptyVarSet
 113               (expr', _counts) = initSmpl dflags us (simplExprGently env expr)
 114
 115         ; dumpIfSet_dyn dflags Opt_D_dump_simpl "Simplified expression"
 116                         (pprCoreExpr expr')
 117
 118         ; return expr'
 119         }
 120
 121
 122 doCorePasses :: DynFlags
 123              -> RuleBase        -- the main rule base
 124              -> SimplCount      -- simplifier stats
 125              -> UniqSupply      -- uniques
 126              -> [CoreBind]      -- local binds in (with rules attached)
 127              -> [CoreToDo]      -- which passes to do
 128              -> IO (SimplCount, [CoreBind])  -- stats, binds, local orphan rules
 129
 130 doCorePasses dflags rb stats us binds []
 131   = return (stats, binds)
 132
 133 doCorePasses dflags rb stats us binds (to_do : to_dos)
 134   = do
 135         let (us1, us2) = splitUniqSupply us
 136
 137         (stats1, binds1) <- doCorePass dflags rb us1 binds to_do
 138
 139         doCorePasses dflags rb (stats `plusSimplCount` stats1) us2 binds1 to_dos
 140
 141 doCorePass dfs rb us binds (CoreDoSimplify mode switches)
 142    = _scc_ "Simplify"      simplifyPgm dfs rb mode switches us binds
 143 doCorePass dfs rb us binds CoreCSE
 144    = _scc_ "CommonSubExpr" noStats dfs (cseProgram dfs binds)
 145 doCorePass dfs rb us binds CoreLiberateCase
 146    = _scc_ "LiberateCase"  noStats dfs (liberateCase dfs binds)
 147 doCorePass dfs rb us binds CoreDoFloatInwards
 148    = _scc_ "FloatInwards"  noStats dfs (floatInwards dfs binds)
 149 doCorePass dfs rb us binds (CoreDoFloatOutwards f)
 150    = _scc_ "FloatOutwards" noStats dfs (floatOutwards dfs f us binds)
 151 doCorePass dfs rb us binds CoreDoStaticArgs
 152    = _scc_ "StaticArgs"    noStats dfs (doStaticArgs us binds)
 153 doCorePass dfs rb us binds CoreDoStrictness
 154    = _scc_ "Stranal"       noStats dfs (do { binds1 <- saBinds dfs binds ;
 155                                              dmdAnalPgm dfs binds1 })
 156 doCorePass dfs rb us binds CoreDoWorkerWrapper
 157    = _scc_ "WorkWrap"      noStats dfs (wwTopBinds dfs us binds)
 158 doCorePass dfs rb us binds CoreDoSpecialising
 159    = _scc_ "Specialise"    noStats dfs (specProgram dfs us binds)
 160 doCorePass dfs rb us binds CoreDoSpecConstr
 161    = _scc_ "SpecConstr"    noStats dfs (specConstrProgram dfs us binds)
 162 doCorePass dfs rb us binds CoreDoCPResult
 163    = _scc_ "CPResult"      noStats dfs (cprAnalyse dfs binds)
 164 doCorePass dfs rb us binds CoreDoPrintCore
 165    = _scc_ "PrintCore"     noStats dfs (printCore binds)
 166 doCorePass dfs rb us binds CoreDoUSPInf
 167    = _scc_ "CoreUsageSPInf" noStats dfs (doUsageSPInf dfs us binds)
 168 doCorePass dfs rb us binds CoreDoGlomBinds
 169    = noStats dfs (glomBinds dfs binds)
 170 doCorePass dfs rb us binds (CoreDoRuleCheck phase pat)
 171    = noStats dfs (ruleCheck dfs phase pat binds)
 172 doCorePass dfs rb us binds CoreDoNothing
 173    = noStats dfs (return binds)
 174
 175 printCore binds = do dumpIfSet True "Print Core"
 176                                (pprCoreBindings binds)
 177                      return binds
 178
 179 ruleCheck dflags phase pat binds = do showPass dflags "RuleCheck"
 180                                       printDump (ruleCheckProgram phase pat binds)
 181                                       return binds
 182
 183 -- most passes return no stats and don't change rules
 184 noStats dfs thing = do { binds <- thing; return (zeroSimplCount dfs, binds) }
 185
 186 \end{code}
 187
 188
 189
 190 %************************************************************************
 191 %*                                                                      *
 192 \subsection{Dealing with rules}
 193 %*                                                                      *
 194 %************************************************************************
 195
 196 -- prepareLocalRuleBase takes the CoreBinds and rules defined in this module.
 197 -- It attaches those rules that are for local Ids to their binders, and
 198 -- returns the remainder attached to Ids in an IdSet.  It also returns
 199 -- Ids mentioned on LHS of some rule; these should be blacklisted.
 200
 201 -- The rule Ids and LHS Ids are black-listed; that is, they aren't inlined
 202 -- so that the opportunity to apply the rule isn't lost too soon
 203
 204 \begin{code}
 205 prepareRules :: DynFlags -> PackageRuleBase -> HomeSymbolTable
 206              -> UniqSupply
 207              -> [CoreBind]
 208              -> [IdCoreRule]            -- Local rules
 209              -> IO (RuleBase,           -- Full rule base
 210                     IdSet,              -- Local rule Ids
 211                     [IdCoreRule],       -- Orphan rules
 212                     IdSet)              -- RHS free vars of all rules
 213
 214 prepareRules dflags pkg_rule_base hst us binds local_rules
 215   = do  { let env              = emptySimplEnv SimplGently [] local_ids
 216               (better_rules,_) = initSmpl dflags us (mapSmpl (simplRule env) local_rules)
 217
 218         ; let (local_rules, orphan_rules) = partition ((`elemVarSet` local_ids) . fst) better_rules
 219                 -- We use (`elemVarSet` local_ids) rather than isLocalId because
 220                 -- isLocalId isn't true of class methods.
 221                 -- If we miss any rules for Ids defined here, then we end up
 222                 -- giving the local decl a new Unique (because the in-scope-set is the
 223                 -- same as the rule-id set), and now the binding for the class method
 224                 -- doesn't have the same Unique as the one in the Class and the tc-env
 225                 --      Example:        class Foo a where
 226                 --                        op :: a -> a
 227                 --                      {-# RULES "op" op x = x #-}
 228
 229               rule_rhs_fvs                = unionVarSets (map (ruleRhsFreeVars . snd) better_rules)
 230               local_rule_base             = extendRuleBaseList emptyRuleBase local_rules
 231               local_rule_ids              = ruleBaseIds local_rule_base -- Local Ids with rules attached
 232               imp_rule_base               = foldl add_rules pkg_rule_base (moduleEnvElts hst)
 233               rule_base                   = extendRuleBaseList imp_rule_base orphan_rules
 234               final_rule_base             = addRuleBaseFVs rule_base (ruleBaseFVs local_rule_base)
 235                 -- The last step black-lists the free vars of local rules too
 236
 237         ; dumpIfSet_dyn dflags Opt_D_dump_rules "Transformation rules"
 238                 (vcat [text "Local rules", pprRuleBase local_rule_base,
 239                        text "",
 240                        text "Imported rules", pprRuleBase final_rule_base])
 241
 242         ; return (final_rule_base, local_rule_ids, orphan_rules, rule_rhs_fvs)
 243     }
 244   where
 245     add_rules rule_base mds = extendRuleBaseList rule_base (md_rules mds)
 246
 247         -- Boringly, we need to gather the in-scope set.
 248     local_ids = foldr (unionVarSet . mkVarSet . bindersOf) emptyVarSet binds
 249
 250
 251 updateBinders :: IdSet                  -- Locally defined ids with their Rules attached
 252               -> IdSet                  -- Ids free in the RHS of local rules
 253               -> IsExported
 254               -> [CoreBind] -> [CoreBind]
 255         -- A horrible function
 256
 257 -- Update the binders of top-level bindings as follows
 258 --      a) Attach the rules for each locally-defined Id to that Id.
 259 --      b) Set the no-discard flag if either the Id is exported,
 260 --         or it's mentoined in the RHS of a rule
 261 --
 262 -- Reason for (a)
 263 --      - It makes the rules easier to look up
 264 --      - It means that transformation rules and specialisations for
 265 --        locally defined Ids are handled uniformly
 266 --      - It keeps alive things that are referred to only from a rule
 267 --        (the occurrence analyser knows about rules attached to Ids)
 268 --      - It makes sure that, when we apply a rule, the free vars
 269 --        of the RHS are more likely to be in scope
 270 --
 271 -- Reason for (b)
 272 --     It means that the binding won't be discarded EVEN if the binding
 273 --     ends up being trivial (v = w) -- the simplifier would usually just
 274 --     substitute w for v throughout, but we don't apply the substitution to
 275 --     the rules (maybe we should?), so this substitution would make the rule
 276 --     bogus.
 277
 278 updateBinders rule_ids rule_rhs_fvs is_exported binds
 279   = map update_bndrs binds
 280   where
 281     update_bndrs (NonRec b r) = NonRec (update_bndr b) r
 282     update_bndrs (Rec prs)    = Rec [(update_bndr b, r) | (b,r) <- prs]
 283
 284     update_bndr bndr
 285         | isImplicitId bndr = bndr      -- Constructors, selectors; doesn't
 286                                         -- make sense to call setIdLocalExported
 287                                         -- Also can't have rules
 288         | dont_discard bndr = setIdLocalExported bndr_with_rules
 289         | otherwise         = bndr_with_rules
 290         where
 291           bndr_with_rules = lookupVarSet rule_ids bndr `orElse` bndr
 292
 293     dont_discard bndr =  is_exported (idName bndr)
 294                       || bndr `elemVarSet` rule_rhs_fvs
 295 \end{code}
 296
 297
 298 We must do some gentle simplification on the template (but not the RHS)
 299 of each rule.  The case that forced me to add this was the fold/build rule,
 300 which without simplification looked like:
 301         fold k z (build (/\a. g a))  ==>  ...
 302 This doesn't match unless you do eta reduction on the build argument.
 303
 304 \begin{code}
 305 simplRule env rule@(id, BuiltinRule _ _)
 306   = returnSmpl rule
 307 simplRule env rule@(id, Rule act name bndrs args rhs)
 308   = simplBinders env bndrs              `thenSmpl` \ (env, bndrs') ->
 309     mapSmpl (simplExprGently env) args  `thenSmpl` \ args' ->
 310     simplExprGently env rhs             `thenSmpl` \ rhs' ->
 311     returnSmpl (id, Rule act name bndrs' args' rhs')
 312
 313 -- It's important that simplExprGently does eta reduction.
 314 -- For example, in a rule like:
 315 --      augment g (build h)
 316 -- we do not want to get
 317 --      augment (\a. g a) (build h)
 318 -- otherwise we don't match when given an argument like
 319 --      (\a. h a a)
 320 --
 321 -- The simplifier does indeed do eta reduction (it's in
 322 -- Simplify.completeLam) but only if -O is on.
 323 \end{code}
 324
 325 \begin{code}
 326 simplExprGently :: SimplEnv -> CoreExpr -> SimplM CoreExpr
 327 -- Simplifies an expression
 328 --      does occurrence analysis, then simplification
 329 --      and repeats (twice currently) because one pass
 330 --      alone leaves tons of crud.
 331 -- Used (a) for user expressions typed in at the interactive prompt
 332 --      (b) the LHS and RHS of a RULE
 333 simplExprGently env expr
 334   = simplExpr env (occurAnalyseGlobalExpr expr)         `thenSmpl` \ expr1 ->
 335     simplExpr env (occurAnalyseGlobalExpr expr1)
 336 \end{code}
 337
 338
 339 %************************************************************************
 340 %*                                                                      *
 341 \subsection{Glomming}
 342 %*                                                                      *
 343 %************************************************************************
 344
 345 \begin{code}
 346 glomBinds :: DynFlags -> [CoreBind] -> IO [CoreBind]
 347 -- Glom all binds together in one Rec, in case any
 348 -- transformations have introduced any new dependencies
 349 --
 350 -- NB: the global invariant is this:
 351 --      *** the top level bindings are never cloned, and are always unique ***
 352 --
 353 -- We sort them into dependency order, but applying transformation rules may
 354 -- make something at the top refer to something at the bottom:
 355 --      f = \x -> p (q x)
 356 --      h = \y -> 3
 357 --
 358 --      RULE:  p (q x) = h x
 359 --
 360 -- Applying this rule makes f refer to h,
 361 -- although it doesn't appear to in the source program.
 362 -- This pass lets us control where it happens.
 363 --
 364 -- NOTICE that this cannot happen for rules whose head is a locally-defined
 365 -- function.  It only happens for rules whose head is an imported function
 366 -- (p in the example above).  So, for example, the rule had been
 367 --      RULE: f (p x) = h x
 368 -- then the rule for f would be attached to f itself (in its IdInfo)
 369 -- by prepareLocalRuleBase and h would be regarded by the occurrency
 370 -- analyser as free in f.
 371
 372 glomBinds dflags binds
 373   = do { showPass dflags "GlomBinds" ;
 374          let { recd_binds = [Rec (flattenBinds binds)] } ;
 375          return recd_binds }
 376         -- Not much point in printing the result...
 377         -- just consumes output bandwidth
 378 \end{code}
 379
 380
 381 %************************************************************************
 382 %*                                                                      *
 383 \subsection{The driver for the simplifier}
 384 %*                                                                      *
 385 %************************************************************************
 386
 387 \begin{code}
 388 simplifyPgm :: DynFlags
 389             -> RuleBase
 390             -> SimplifierMode
 391             -> [SimplifierSwitch]
 392             -> UniqSupply
 393             -> [CoreBind]                   -- Input
 394             -> IO (SimplCount, [CoreBind])  -- New bindings
 395
 396 simplifyPgm dflags rule_base
 397             mode switches us binds
 398   = do {
 399         showPass dflags "Simplify";
 400
 401         (termination_msg, it_count, counts_out, binds')
 402            <- iteration us 1 (zeroSimplCount dflags) binds;
 403
 404         dumpIfSet (dopt Opt_D_verbose_core2core dflags
 405                    && dopt Opt_D_dump_simpl_stats dflags)
 406                   "Simplifier statistics"
 407                   (vcat [text termination_msg <+> text "after" <+> ppr it_count <+> text "iterations",
 408                          text "",
 409                          pprSimplCount counts_out]);
 410
 411         endPass dflags "Simplify" Opt_D_verbose_core2core binds';
 412
 413         return (counts_out, binds')
 414     }
 415   where
 416     phase_info        = case mode of
 417                           SimplGently  -> "gentle"
 418                           SimplPhase n -> show n
 419
 420     imported_rule_ids = ruleBaseIds rule_base
 421     simpl_env         = emptySimplEnv mode switches imported_rule_ids
 422     sw_chkr           = getSwitchChecker simpl_env
 423     max_iterations    = intSwitchSet sw_chkr MaxSimplifierIterations `orElse` 2
 424
 425     iteration us iteration_no counts binds
 426       -- Try and force thunks off the binds; significantly reduces
 427       -- space usage, especially with -O.  JRS, 000620.
 428       | let sz = coreBindsSize binds in sz == sz
 429       = do {
 430                 -- Occurrence analysis
 431            let { tagged_binds = _scc_ "OccAnal" occurAnalyseBinds binds } ;
 432
 433            dumpIfSet_dyn dflags Opt_D_dump_occur_anal "Occurrence analysis"
 434                      (pprCoreBindings tagged_binds);
 435
 436                 -- SIMPLIFY
 437                 -- We do this with a *case* not a *let* because lazy pattern
 438                 -- matching bit us with bad space leak!
 439                 -- With a let, we ended up with
 440                 --   let
 441                 --      t = initSmpl ...
 442                 --      counts' = snd t
 443                 --   in
 444                 --      case t of {(_,counts') -> if counts'=0 then ...
 445                 -- So the conditional didn't force counts', because the
 446                 -- selection got duplicated.  Sigh!
 447            case initSmpl dflags us1 (simplTopBinds simpl_env tagged_binds) of {
 448                 (binds', counts') -> do {
 449                         -- The imported_rule_ids are used by initSmpl to initialise
 450                         -- the in-scope set.  That way, the simplifier will change any
 451                         -- occurrences of the imported id to the one in the imported_rule_ids
 452                         -- set, which are decorated with their rules.
 453
 454            let { all_counts = counts `plusSimplCount` counts' ;
 455                  herald     = "Simplifier phase " ++ phase_info ++
 456                               ", iteration " ++ show iteration_no ++
 457                               " out of " ++ show max_iterations
 458                 } ;
 459
 460                 -- Stop if nothing happened; don't dump output
 461            if isZeroSimplCount counts' then
 462                 return ("Simplifier reached fixed point", iteration_no, all_counts, binds')
 463            else do {
 464
 465                 -- Dump the result of this iteration
 466            dumpIfSet_dyn dflags Opt_D_dump_simpl_iterations herald
 467                      (pprSimplCount counts') ;
 468
 469            endPass dflags herald Opt_D_dump_simpl_iterations binds' ;
 470
 471                 -- Stop if we've run out of iterations
 472            if iteration_no == max_iterations then
 473                 do {
 474 #ifdef DEBUG
 475                     if  max_iterations > 2 then
 476                             hPutStr stderr ("NOTE: Simplifier still going after " ++
 477                                     show max_iterations ++
 478                                     " iterations; bailing out.\n")
 479                     else
 480 #endif
 481                         return ();
 482
 483                     return ("Simplifier baled out", iteration_no, all_counts, binds')
 484                 }
 485
 486                 -- Else loop
 487            else iteration us2 (iteration_no + 1) all_counts binds'
 488         }  } } }
 489       where
 490           (us1, us2) = splitUniqSupply us
 491 \end{code}