ghc/compiler/simplCore/SimplCore.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[SimplCore]{Driver for simplifying @Core@ programs}
   5
   6 \begin{code}
   7 module SimplCore ( core2core, simplifyExpr ) where
   8
   9 #include "HsVersions.h"
  10
  11 import CmdLineOpts      ( CoreToDo(..), SimplifierSwitch(..), SimplifierMode(..),
  12                           DynFlags, DynFlag(..), dopt, dopt_CoreToDo
  13                         )
  14 import CoreSyn
  15 import CoreFVs          ( ruleRhsFreeVars )
  16 import HscTypes         ( PersistentCompilerState(..),
  17                           PackageRuleBase, HomeSymbolTable, IsExported, ModDetails(..)
  18                         )
  19 import CSE              ( cseProgram )
  20 import Rules            ( RuleBase, emptyRuleBase, ruleBaseFVs, ruleBaseIds,
  21                           extendRuleBaseList, addRuleBaseFVs, pprRuleBase,
  22                           ruleCheckProgram )
  23 import Module           ( moduleEnvElts )
  24 import PprCore          ( pprCoreBindings, pprCoreExpr )
  25 import OccurAnal        ( occurAnalyseBinds, occurAnalyseGlobalExpr )
  26 import CoreUtils        ( coreBindsSize )
  27 import Simplify         ( simplTopBinds, simplExpr )
  28 import SimplUtils       ( simplBinders )
  29 import SimplMonad
  30 import ErrUtils         ( dumpIfSet, dumpIfSet_dyn, showPass )
  31 import CoreLint         ( endPass )
  32 import FloatIn          ( floatInwards )
  33 import FloatOut         ( floatOutwards )
  34 import Id               ( idName, setIdLocalExported )
  35 import VarSet
  36 import LiberateCase     ( liberateCase )
  37 import SAT              ( doStaticArgs )
  38 import Specialise       ( specProgram)
  39 import SpecConstr       ( specConstrProgram)
  40 import UsageSPInf       ( doUsageSPInf )
  41 import StrictAnal       ( saBinds )
  42 import DmdAnal          ( dmdAnalPgm )
  43 import WorkWrap         ( wwTopBinds )
  44 import CprAnalyse       ( cprAnalyse )
  45
  46 import UniqSupply       ( UniqSupply, mkSplitUniqSupply, splitUniqSupply )
  47 import IO               ( hPutStr, stderr )
  48 import Outputable
  49
  50 import Maybes           ( orElse )
  51 import List             ( partition )
  52 \end{code}
  53
  54 %************************************************************************
  55 %*                                                                      *
  56 \subsection{The driver for the simplifier}
  57 %*                                                                      *
  58 %************************************************************************
  59
  60 \begin{code}
  61 core2core :: DynFlags           -- includes spec of what core-to-core passes to do
  62           -> PersistentCompilerState
  63           -> HomeSymbolTable
  64           -> IsExported
  65           -> ModDetails
  66           -> IO ModDetails
  67
  68 core2core dflags pcs hst is_exported
  69           mod_details@(ModDetails { md_binds = binds_in, md_rules = rules_in })
  70   = do
  71         let core_todos    = dopt_CoreToDo dflags
  72         let pkg_rule_base = pcs_rules pcs               -- Rule-base accumulated from imported packages
  73
  74
  75         us <-  mkSplitUniqSupply 's'
  76         let (cp_us, ru_us) = splitUniqSupply us
  77
  78                 -- COMPUTE THE RULE BASE TO USE
  79         (rule_base, local_rule_ids, orphan_rules, rule_rhs_fvs)
  80                 <- prepareRules dflags pkg_rule_base hst ru_us binds_in rules_in
  81
  82                 -- PREPARE THE BINDINGS
  83         let binds1 = updateBinders local_rule_ids rule_rhs_fvs is_exported binds_in
  84
  85                 -- DO THE BUSINESS
  86         (stats, processed_binds)
  87                 <- doCorePasses dflags rule_base (zeroSimplCount dflags) cp_us binds1 core_todos
  88
  89         dumpIfSet_dyn dflags Opt_D_dump_simpl_stats
  90                   "Grand total simplifier statistics"
  91                   (pprSimplCount stats)
  92
  93         -- Return results
  94         -- We only return local orphan rules, i.e., local rules not attached to an Id
  95         -- The bindings cotain more rules, embedded in the Ids
  96         return (mod_details { md_binds = processed_binds, md_rules = orphan_rules})
  97
  98
  99 simplifyExpr :: DynFlags -- includes spec of what core-to-core passes to do
 100              -> PersistentCompilerState
 101              -> HomeSymbolTable
 102              -> CoreExpr
 103              -> IO CoreExpr
 104 -- simplifyExpr is called by the driver to simplify an
 105 -- expression typed in at the interactive prompt
 106 simplifyExpr dflags pcs hst expr
 107   = do  {
 108         ; showPass dflags "Simplify"
 109
 110         ; us <-  mkSplitUniqSupply 's'
 111
 112         ; let env              = emptySimplEnv (SimplPhase 0) [] emptyVarSet
 113               (expr', _counts) = initSmpl dflags us (simplExprGently env expr)
 114
 115         ; dumpIfSet_dyn dflags Opt_D_dump_simpl "Simplified expression"
 116                         (pprCoreExpr expr')
 117
 118         ; return expr'
 119         }
 120
 121
 122 doCorePasses :: DynFlags
 123              -> RuleBase        -- the main rule base
 124              -> SimplCount      -- simplifier stats
 125              -> UniqSupply      -- uniques
 126              -> [CoreBind]      -- local binds in (with rules attached)
 127              -> [CoreToDo]      -- which passes to do
 128              -> IO (SimplCount, [CoreBind])  -- stats, binds, local orphan rules
 129
 130 doCorePasses dflags rb stats us binds []
 131   = return (stats, binds)
 132
 133 doCorePasses dflags rb stats us binds (to_do : to_dos)
 134   = do
 135         let (us1, us2) = splitUniqSupply us
 136
 137         (stats1, binds1) <- doCorePass dflags rb us1 binds to_do
 138
 139         doCorePasses dflags rb (stats `plusSimplCount` stats1) us2 binds1 to_dos
 140
 141 doCorePass dfs rb us binds (CoreDoSimplify mode switches)
 142    = _scc_ "Simplify"      simplifyPgm dfs rb mode switches us binds
 143 doCorePass dfs rb us binds CoreCSE
 144    = _scc_ "CommonSubExpr" noStats dfs (cseProgram dfs binds)
 145 doCorePass dfs rb us binds CoreLiberateCase
 146    = _scc_ "LiberateCase"  noStats dfs (liberateCase dfs binds)
 147 doCorePass dfs rb us binds CoreDoFloatInwards
 148    = _scc_ "FloatInwards"  noStats dfs (floatInwards dfs binds)
 149 doCorePass dfs rb us binds (CoreDoFloatOutwards f)
 150    = _scc_ "FloatOutwards" noStats dfs (floatOutwards dfs f us binds)
 151 doCorePass dfs rb us binds CoreDoStaticArgs
 152    = _scc_ "StaticArgs"    noStats dfs (doStaticArgs us binds)
 153 doCorePass dfs rb us binds CoreDoStrictness
 154    = _scc_ "Stranal"       noStats dfs (strictAnal dfs binds)
 155 doCorePass dfs rb us binds CoreDoWorkerWrapper
 156    = _scc_ "WorkWrap"      noStats dfs (wwTopBinds dfs us binds)
 157 doCorePass dfs rb us binds CoreDoSpecialising
 158    = _scc_ "Specialise"    noStats dfs (specProgram dfs us binds)
 159 doCorePass dfs rb us binds CoreDoSpecConstr
 160    = _scc_ "SpecConstr"    noStats dfs (specConstrProgram dfs us binds)
 161 #ifdef DEBUG
 162 doCorePass dfs rb us binds CoreDoCPResult
 163    = _scc_ "CPResult"      noStats dfs (cprAnalyse dfs binds)
 164 #endif
 165 doCorePass dfs rb us binds CoreDoPrintCore
 166    = _scc_ "PrintCore"     noStats dfs (printCore binds)
 167 doCorePass dfs rb us binds CoreDoUSPInf
 168    = _scc_ "CoreUsageSPInf" noStats dfs (doUsageSPInf dfs us binds)
 169 doCorePass dfs rb us binds CoreDoGlomBinds
 170    = noStats dfs (glomBinds dfs binds)
 171 doCorePass dfs rb us binds (CoreDoRuleCheck phase pat)
 172    = noStats dfs (ruleCheck dfs phase pat binds)
 173 doCorePass dfs rb us binds CoreDoNothing
 174    = noStats dfs (return binds)
 175
 176 strictAnal dfs binds = do
 177 #ifdef DEBUG
 178      binds <- saBinds dfs binds
 179 #endif
 180      dmdAnalPgm dfs binds
 181
 182 printCore binds = do dumpIfSet True "Print Core"
 183                                (pprCoreBindings binds)
 184                      return binds
 185
 186 ruleCheck dflags phase pat binds = do showPass dflags "RuleCheck"
 187                                       printDump (ruleCheckProgram phase pat binds)
 188                                       return binds
 189
 190 -- most passes return no stats and don't change rules
 191 noStats dfs thing = do { binds <- thing; return (zeroSimplCount dfs, binds) }
 192
 193 \end{code}
 194
 195
 196
 197 %************************************************************************
 198 %*                                                                      *
 199 \subsection{Dealing with rules}
 200 %*                                                                      *
 201 %************************************************************************
 202
 203 -- prepareLocalRuleBase takes the CoreBinds and rules defined in this module.
 204 -- It attaches those rules that are for local Ids to their binders, and
 205 -- returns the remainder attached to Ids in an IdSet.  It also returns
 206 -- Ids mentioned on LHS of some rule; these should be blacklisted.
 207
 208 -- The rule Ids and LHS Ids are black-listed; that is, they aren't inlined
 209 -- so that the opportunity to apply the rule isn't lost too soon
 210
 211 \begin{code}
 212 prepareRules :: DynFlags -> PackageRuleBase -> HomeSymbolTable
 213              -> UniqSupply
 214              -> [CoreBind]
 215              -> [IdCoreRule]            -- Local rules
 216              -> IO (RuleBase,           -- Full rule base
 217                     IdSet,              -- Local rule Ids
 218                     [IdCoreRule],       -- Orphan rules
 219                     IdSet)              -- RHS free vars of all rules
 220
 221 prepareRules dflags pkg_rule_base hst us binds local_rules
 222   = do  { let env              = emptySimplEnv SimplGently [] local_ids
 223               (better_rules,_) = initSmpl dflags us (mapSmpl (simplRule env) local_rules)
 224
 225         ; let (local_rules, orphan_rules) = partition ((`elemVarSet` local_ids) . fst) better_rules
 226                 -- We use (`elemVarSet` local_ids) rather than isLocalId because
 227                 -- isLocalId isn't true of class methods.
 228                 -- If we miss any rules for Ids defined here, then we end up
 229                 -- giving the local decl a new Unique (because the in-scope-set is the
 230                 -- same as the rule-id set), and now the binding for the class method
 231                 -- doesn't have the same Unique as the one in the Class and the tc-env
 232                 --      Example:        class Foo a where
 233                 --                        op :: a -> a
 234                 --                      {-# RULES "op" op x = x #-}
 235
 236               rule_rhs_fvs                = unionVarSets (map (ruleRhsFreeVars . snd) better_rules)
 237               local_rule_base             = extendRuleBaseList emptyRuleBase local_rules
 238               local_rule_ids              = ruleBaseIds local_rule_base -- Local Ids with rules attached
 239               imp_rule_base               = foldl add_rules pkg_rule_base (moduleEnvElts hst)
 240               rule_base                   = extendRuleBaseList imp_rule_base orphan_rules
 241               final_rule_base             = addRuleBaseFVs rule_base (ruleBaseFVs local_rule_base)
 242                 -- The last step black-lists the free vars of local rules too
 243
 244         ; dumpIfSet_dyn dflags Opt_D_dump_rules "Transformation rules"
 245                 (vcat [text "Local rules", pprRuleBase local_rule_base,
 246                        text "",
 247                        text "Imported rules", pprRuleBase final_rule_base])
 248
 249         ; return (final_rule_base, local_rule_ids, orphan_rules, rule_rhs_fvs)
 250     }
 251   where
 252     add_rules rule_base mds = extendRuleBaseList rule_base (md_rules mds)
 253
 254         -- Boringly, we need to gather the in-scope set.
 255     local_ids = foldr (unionVarSet . mkVarSet . bindersOf) emptyVarSet binds
 256
 257
 258 updateBinders :: IdSet                  -- Locally defined ids with their Rules attached
 259               -> IdSet                  -- Ids free in the RHS of local rules
 260               -> IsExported
 261               -> [CoreBind] -> [CoreBind]
 262         -- A horrible function
 263
 264 -- Update the binders of top-level bindings as follows
 265 --      a) Attach the rules for each locally-defined Id to that Id.
 266 --      b) Set the no-discard flag if either the Id is exported,
 267 --         or it's mentoined in the RHS of a rule
 268 --
 269 -- Reason for (a)
 270 --      - It makes the rules easier to look up
 271 --      - It means that transformation rules and specialisations for
 272 --        locally defined Ids are handled uniformly
 273 --      - It keeps alive things that are referred to only from a rule
 274 --        (the occurrence analyser knows about rules attached to Ids)
 275 --      - It makes sure that, when we apply a rule, the free vars
 276 --        of the RHS are more likely to be in scope
 277 --
 278 -- Reason for (b)
 279 --     It means that the binding won't be discarded EVEN if the binding
 280 --     ends up being trivial (v = w) -- the simplifier would usually just
 281 --     substitute w for v throughout, but we don't apply the substitution to
 282 --     the rules (maybe we should?), so this substitution would make the rule
 283 --     bogus.
 284
 285 updateBinders rule_ids rule_rhs_fvs is_exported binds
 286   = map update_bndrs binds
 287   where
 288     update_bndrs (NonRec b r) = NonRec (update_bndr b) r
 289     update_bndrs (Rec prs)    = Rec [(update_bndr b, r) | (b,r) <- prs]
 290
 291     update_bndr bndr
 292         | dont_discard bndr = setIdLocalExported bndr_with_rules
 293         | otherwise         = bndr_with_rules
 294         where
 295           bndr_with_rules = lookupVarSet rule_ids bndr `orElse` bndr
 296
 297     dont_discard bndr =  is_exported (idName bndr)
 298                       || bndr `elemVarSet` rule_rhs_fvs
 299 \end{code}
 300
 301
 302 We must do some gentle simplification on the template (but not the RHS)
 303 of each rule.  The case that forced me to add this was the fold/build rule,
 304 which without simplification looked like:
 305         fold k z (build (/\a. g a))  ==>  ...
 306 This doesn't match unless you do eta reduction on the build argument.
 307
 308 \begin{code}
 309 simplRule env rule@(id, BuiltinRule _ _)
 310   = returnSmpl rule
 311 simplRule env rule@(id, Rule act name bndrs args rhs)
 312   = simplBinders env bndrs              `thenSmpl` \ (env, bndrs') ->
 313     mapSmpl (simplExprGently env) args  `thenSmpl` \ args' ->
 314     simplExprGently env rhs             `thenSmpl` \ rhs' ->
 315     returnSmpl (id, Rule act name bndrs' args' rhs')
 316
 317 -- It's important that simplExprGently does eta reduction.
 318 -- For example, in a rule like:
 319 --      augment g (build h)
 320 -- we do not want to get
 321 --      augment (\a. g a) (build h)
 322 -- otherwise we don't match when given an argument like
 323 --      (\a. h a a)
 324 --
 325 -- The simplifier does indeed do eta reduction (it's in
 326 -- Simplify.completeLam) but only if -O is on.
 327 \end{code}
 328
 329 \begin{code}
 330 simplExprGently :: SimplEnv -> CoreExpr -> SimplM CoreExpr
 331 -- Simplifies an expression
 332 --      does occurrence analysis, then simplification
 333 --      and repeats (twice currently) because one pass
 334 --      alone leaves tons of crud.
 335 -- Used (a) for user expressions typed in at the interactive prompt
 336 --      (b) the LHS and RHS of a RULE
 337 simplExprGently env expr
 338   = simplExpr env (occurAnalyseGlobalExpr expr)         `thenSmpl` \ expr1 ->
 339     simplExpr env (occurAnalyseGlobalExpr expr1)
 340 \end{code}
 341
 342
 343 %************************************************************************
 344 %*                                                                      *
 345 \subsection{Glomming}
 346 %*                                                                      *
 347 %************************************************************************
 348
 349 \begin{code}
 350 glomBinds :: DynFlags -> [CoreBind] -> IO [CoreBind]
 351 -- Glom all binds together in one Rec, in case any
 352 -- transformations have introduced any new dependencies
 353 --
 354 -- NB: the global invariant is this:
 355 --      *** the top level bindings are never cloned, and are always unique ***
 356 --
 357 -- We sort them into dependency order, but applying transformation rules may
 358 -- make something at the top refer to something at the bottom:
 359 --      f = \x -> p (q x)
 360 --      h = \y -> 3
 361 --
 362 --      RULE:  p (q x) = h x
 363 --
 364 -- Applying this rule makes f refer to h,
 365 -- although it doesn't appear to in the source program.
 366 -- This pass lets us control where it happens.
 367 --
 368 -- NOTICE that this cannot happen for rules whose head is a locally-defined
 369 -- function.  It only happens for rules whose head is an imported function
 370 -- (p in the example above).  So, for example, the rule had been
 371 --      RULE: f (p x) = h x
 372 -- then the rule for f would be attached to f itself (in its IdInfo)
 373 -- by prepareLocalRuleBase and h would be regarded by the occurrency
 374 -- analyser as free in f.
 375
 376 glomBinds dflags binds
 377   = do { showPass dflags "GlomBinds" ;
 378          let { recd_binds = [Rec (flattenBinds binds)] } ;
 379          return recd_binds }
 380         -- Not much point in printing the result...
 381         -- just consumes output bandwidth
 382 \end{code}
 383
 384
 385 %************************************************************************
 386 %*                                                                      *
 387 \subsection{The driver for the simplifier}
 388 %*                                                                      *
 389 %************************************************************************
 390
 391 \begin{code}
 392 simplifyPgm :: DynFlags
 393             -> RuleBase
 394             -> SimplifierMode
 395             -> [SimplifierSwitch]
 396             -> UniqSupply
 397             -> [CoreBind]                   -- Input
 398             -> IO (SimplCount, [CoreBind])  -- New bindings
 399
 400 simplifyPgm dflags rule_base
 401             mode switches us binds
 402   = do {
 403         showPass dflags "Simplify";
 404
 405         (termination_msg, it_count, counts_out, binds')
 406            <- iteration us 1 (zeroSimplCount dflags) binds;
 407
 408         dumpIfSet (dopt Opt_D_verbose_core2core dflags
 409                    && dopt Opt_D_dump_simpl_stats dflags)
 410                   "Simplifier statistics"
 411                   (vcat [text termination_msg <+> text "after" <+> ppr it_count <+> text "iterations",
 412                          text "",
 413                          pprSimplCount counts_out]);
 414
 415         endPass dflags "Simplify" Opt_D_verbose_core2core binds';
 416
 417         return (counts_out, binds')
 418     }
 419   where
 420     phase_info        = case mode of
 421                           SimplGently  -> "gentle"
 422                           SimplPhase n -> show n
 423
 424     imported_rule_ids = ruleBaseIds rule_base
 425     simpl_env         = emptySimplEnv mode switches imported_rule_ids
 426     sw_chkr           = getSwitchChecker simpl_env
 427     max_iterations    = intSwitchSet sw_chkr MaxSimplifierIterations `orElse` 2
 428
 429     iteration us iteration_no counts binds
 430       -- Try and force thunks off the binds; significantly reduces
 431       -- space usage, especially with -O.  JRS, 000620.
 432       | let sz = coreBindsSize binds in sz == sz
 433       = do {
 434                 -- Occurrence analysis
 435            let { tagged_binds = _scc_ "OccAnal" occurAnalyseBinds binds } ;
 436
 437            dumpIfSet_dyn dflags Opt_D_dump_occur_anal "Occurrence analysis"
 438                      (pprCoreBindings tagged_binds);
 439
 440                 -- SIMPLIFY
 441                 -- We do this with a *case* not a *let* because lazy pattern
 442                 -- matching bit us with bad space leak!
 443                 -- With a let, we ended up with
 444                 --   let
 445                 --      t = initSmpl ...
 446                 --      counts' = snd t
 447                 --   in
 448                 --      case t of {(_,counts') -> if counts'=0 then ...
 449                 -- So the conditional didn't force counts', because the
 450                 -- selection got duplicated.  Sigh!
 451            case initSmpl dflags us1 (simplTopBinds simpl_env tagged_binds) of {
 452                 (binds', counts') -> do {
 453                         -- The imported_rule_ids are used by initSmpl to initialise
 454                         -- the in-scope set.  That way, the simplifier will change any
 455                         -- occurrences of the imported id to the one in the imported_rule_ids
 456                         -- set, which are decorated with their rules.
 457
 458            let { all_counts = counts `plusSimplCount` counts' ;
 459                  herald     = "Simplifier phase " ++ phase_info ++
 460                               ", iteration " ++ show iteration_no ++
 461                               " out of " ++ show max_iterations
 462                 } ;
 463
 464                 -- Stop if nothing happened; don't dump output
 465            if isZeroSimplCount counts' then
 466                 return ("Simplifier reached fixed point", iteration_no, all_counts, binds')
 467            else do {
 468
 469                 -- Dump the result of this iteration
 470            dumpIfSet_dyn dflags Opt_D_dump_simpl_iterations herald
 471                      (pprSimplCount counts') ;
 472
 473            endPass dflags herald Opt_D_dump_simpl_iterations binds' ;
 474
 475                 -- Stop if we've run out of iterations
 476            if iteration_no == max_iterations then
 477                 do {
 478 #ifdef DEBUG
 479                     if  max_iterations > 2 then
 480                             hPutStr stderr ("NOTE: Simplifier still going after " ++
 481                                     show max_iterations ++
 482                                     " iterations; bailing out.\n")
 483                     else
 484 #endif
 485                         return ();
 486
 487                     return ("Simplifier baled out", iteration_no, all_counts, binds')
 488                 }
 489
 490                 -- Else loop
 491            else iteration us2 (iteration_no + 1) all_counts binds'
 492         }  } } }
 493       where
 494           (us1, us2) = splitUniqSupply us
 495 \end{code}