ghc/compiler/simplCore/SimplUtils.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[SimplUtils]{The simplifier utilities}
   5
   6 \begin{code}
   7 module SimplUtils (
   8         simplBinder, simplBinders, simplRecIds, simplLetId, simplLamBinders,
   9         tryEtaExpansion,
  10         newId, mkLam, mkCase,
  11
  12         -- The continuation type
  13         SimplCont(..), DupFlag(..), LetRhsFlag(..),
  14         contIsDupable, contResultType,
  15         countValArgs, countArgs, pushContArgs,
  16         mkBoringStop, mkStop, contIsRhs, contIsRhsOrArg,
  17         getContArgs, interestingCallContext, interestingArg, isStrictType
  18
  19     ) where
  20
  21 #include "HsVersions.h"
  22
  23 import CmdLineOpts      ( SimplifierSwitch(..),
  24                           opt_SimplDoLambdaEtaExpansion, opt_SimplDoEtaReduction,
  25                           opt_SimplCaseMerge, opt_UF_UpdateInPlace
  26                         )
  27 import CoreSyn
  28 import CoreUtils        ( cheapEqExpr, exprType,
  29                           etaExpand, exprEtaExpandArity, bindNonRec, mkCoerce,
  30                           findDefault, exprOkForSpeculation, exprIsValue
  31                         )
  32 import qualified Subst  ( simplBndrs, simplBndr, simplLetId, simplLamBndr )
  33 import Id               ( Id, idType, idInfo,
  34                           mkSysLocal, hasNoBinding, isDeadBinder, idNewDemandInfo,
  35                           idUnfolding, idNewStrictness
  36                         )
  37 import NewDemand        ( isStrictDmd, isBotRes, splitStrictSig )
  38 import SimplMonad
  39 import Type             ( Type, seqType,
  40                           splitTyConApp_maybe, tyConAppArgs, mkTyVarTys,
  41                           splitRepFunTys, isStrictType
  42                         )
  43 import OccName          ( UserFS )
  44 import TyCon            ( tyConDataConsIfAvailable, isDataTyCon )
  45 import DataCon          ( dataConRepArity, dataConSig, dataConArgTys )
  46 import Var              ( mkSysTyVar, tyVarKind )
  47 import Util             ( lengthExceeds, mapAccumL )
  48 import Outputable
  49 \end{code}
  50
  51
  52 %************************************************************************
  53 %*                                                                      *
  54 \subsection{The continuation data type}
  55 %*                                                                      *
  56 %************************************************************************
  57
  58 \begin{code}
  59 data SimplCont          -- Strict contexts
  60   = Stop     OutType            -- Type of the result
  61              LetRhsFlag
  62              Bool               -- True <=> This is the RHS of a thunk whose type suggests
  63                                 --          that update-in-place would be possible
  64                                 --          (This makes the inliner a little keener.)
  65
  66   | CoerceIt OutType                    -- The To-type, simplified
  67              SimplCont
  68
  69   | InlinePlease                        -- This continuation makes a function very
  70              SimplCont                  -- keen to inline itelf
  71
  72   | ApplyTo  DupFlag
  73              InExpr SimplEnv            -- The argument, as yet unsimplified,
  74              SimplCont                  -- and its environment
  75
  76   | Select   DupFlag
  77              InId [InAlt] SimplEnv      -- The case binder, alts, and subst-env
  78              SimplCont
  79
  80   | ArgOf    DupFlag            -- An arbitrary strict context: the argument
  81                                 --      of a strict function, or a primitive-arg fn
  82                                 --      or a PrimOp
  83              LetRhsFlag
  84              OutType            -- cont_ty: the type of the expression being sought by the context
  85                                 --      f (error "foo") ==> coerce t (error "foo")
  86                                 -- when f is strict
  87                                 -- We need to know the type t, to which to coerce.
  88              (SimplEnv -> OutExpr -> SimplM FloatsWithExpr)     -- What to do with the result
  89                                 -- The result expression in the OutExprStuff has type cont_ty
  90
  91 data LetRhsFlag = AnArg         -- It's just an argument not a let RHS
  92                 | AnRhs         -- It's the RHS of a let (so please float lets out of big lambdas)
  93
  94 instance Outputable LetRhsFlag where
  95   ppr AnArg = ptext SLIT("arg")
  96   ppr AnRhs = ptext SLIT("rhs")
  97
  98 instance Outputable SimplCont where
  99   ppr (Stop _ is_rhs _)              = ptext SLIT("Stop") <> brackets (ppr is_rhs)
 100   ppr (ApplyTo dup arg se cont)      = (ptext SLIT("ApplyTo") <+> ppr dup <+> ppr arg) $$ ppr cont
 101   ppr (ArgOf   dup _ _ _)            = ptext SLIT("ArgOf...") <+> ppr dup
 102   ppr (Select dup bndr alts se cont) = (ptext SLIT("Select") <+> ppr dup <+> ppr bndr) $$
 103                                        (nest 4 (ppr alts)) $$ ppr cont
 104   ppr (CoerceIt ty cont)             = (ptext SLIT("CoerceIt") <+> ppr ty) $$ ppr cont
 105   ppr (InlinePlease cont)            = ptext SLIT("InlinePlease") $$ ppr cont
 106
 107 data DupFlag = OkToDup | NoDup
 108
 109 instance Outputable DupFlag where
 110   ppr OkToDup = ptext SLIT("ok")
 111   ppr NoDup   = ptext SLIT("nodup")
 112
 113
 114 -------------------
 115 mkBoringStop :: OutType -> SimplCont
 116 mkBoringStop ty = Stop ty AnArg (canUpdateInPlace ty)
 117
 118 mkStop :: OutType -> LetRhsFlag -> SimplCont
 119 mkStop ty is_rhs = Stop ty is_rhs (canUpdateInPlace ty)
 120
 121 contIsRhs :: SimplCont -> Bool
 122 contIsRhs (Stop _ AnRhs _)    = True
 123 contIsRhs (ArgOf _ AnRhs _ _) = True
 124 contIsRhs other               = False
 125
 126 contIsRhsOrArg (Stop _ _ _)    = True
 127 contIsRhsOrArg (ArgOf _ _ _ _) = True
 128 contIsRhsOrArg other           = False
 129
 130 -------------------
 131 contIsDupable :: SimplCont -> Bool
 132 contIsDupable (Stop _ _ _)               = True
 133 contIsDupable (ApplyTo  OkToDup _ _ _)   = True
 134 contIsDupable (ArgOf    OkToDup _ _ _)   = True
 135 contIsDupable (Select   OkToDup _ _ _ _) = True
 136 contIsDupable (CoerceIt _ cont)          = contIsDupable cont
 137 contIsDupable (InlinePlease cont)        = contIsDupable cont
 138 contIsDupable other                      = False
 139
 140 -------------------
 141 discardableCont :: SimplCont -> Bool
 142 discardableCont (Stop _ _ _)        = False
 143 discardableCont (CoerceIt _ cont)   = discardableCont cont
 144 discardableCont (InlinePlease cont) = discardableCont cont
 145 discardableCont other               = True
 146
 147 discardCont :: SimplCont        -- A continuation, expecting
 148             -> SimplCont        -- Replace the continuation with a suitable coerce
 149 discardCont cont = case cont of
 150                      Stop to_ty is_rhs _ -> cont
 151                      other               -> CoerceIt to_ty (mkBoringStop to_ty)
 152                  where
 153                    to_ty = contResultType cont
 154
 155 -------------------
 156 contResultType :: SimplCont -> OutType
 157 contResultType (Stop to_ty _ _)      = to_ty
 158 contResultType (ArgOf _ _ to_ty _)   = to_ty
 159 contResultType (ApplyTo _ _ _ cont)  = contResultType cont
 160 contResultType (CoerceIt _ cont)     = contResultType cont
 161 contResultType (InlinePlease cont)   = contResultType cont
 162 contResultType (Select _ _ _ _ cont) = contResultType cont
 163
 164 -------------------
 165 countValArgs :: SimplCont -> Int
 166 countValArgs (ApplyTo _ (Type ty) se cont) = countValArgs cont
 167 countValArgs (ApplyTo _ val_arg   se cont) = 1 + countValArgs cont
 168 countValArgs other                         = 0
 169
 170 countArgs :: SimplCont -> Int
 171 countArgs (ApplyTo _ arg se cont) = 1 + countArgs cont
 172 countArgs other                   = 0
 173
 174 -------------------
 175 pushContArgs :: SimplEnv -> [OutArg] -> SimplCont -> SimplCont
 176 -- Pushes args with the specified environment
 177 pushContArgs env []           cont = cont
 178 pushContArgs env (arg : args) cont = ApplyTo NoDup arg env (pushContArgs env args cont)
 179 \end{code}
 180
 181
 182 \begin{code}
 183 getContArgs :: SwitchChecker
 184             -> OutId -> SimplCont
 185             -> ([(InExpr, SimplEnv, Bool)],     -- Arguments; the Bool is true for strict args
 186                 SimplCont,                      -- Remaining continuation
 187                 Bool)                           -- Whether we came across an InlineCall
 188 -- getContArgs id k = (args, k', inl)
 189 --      args are the leading ApplyTo items in k
 190 --      (i.e. outermost comes first)
 191 --      augmented with demand info from the functionn
 192 getContArgs chkr fun orig_cont
 193   = let
 194                 -- Ignore strictness info if the no-case-of-case
 195                 -- flag is on.  Strictness changes evaluation order
 196                 -- and that can change full laziness
 197         stricts | switchIsOn chkr NoCaseOfCase = vanilla_stricts
 198                 | otherwise                    = computed_stricts
 199     in
 200     go [] stricts False orig_cont
 201   where
 202     ----------------------------
 203
 204         -- Type argument
 205     go acc ss inl (ApplyTo _ arg@(Type _) se cont)
 206         = go ((arg,se,False) : acc) ss inl cont
 207                 -- NB: don't bother to instantiate the function type
 208
 209         -- Value argument
 210     go acc (s:ss) inl (ApplyTo _ arg se cont)
 211         = go ((arg,se,s) : acc) ss inl cont
 212
 213         -- An Inline continuation
 214     go acc ss inl (InlinePlease cont)
 215         = go acc ss True cont
 216
 217         -- We're run out of arguments, or else we've run out of demands
 218         -- The latter only happens if the result is guaranteed bottom
 219         -- This is the case for
 220         --      * case (error "hello") of { ... }
 221         --      * (error "Hello") arg
 222         --      * f (error "Hello") where f is strict
 223         --      etc
 224     go acc ss inl cont
 225         | null ss && discardableCont cont = (reverse acc, discardCont cont, inl)
 226         | otherwise                       = (reverse acc, cont,             inl)
 227
 228     ----------------------------
 229     vanilla_stricts, computed_stricts :: [Bool]
 230     vanilla_stricts  = repeat False
 231     computed_stricts = zipWith (||) fun_stricts arg_stricts
 232
 233     ----------------------------
 234     (val_arg_tys, _) = splitRepFunTys (idType fun)
 235     arg_stricts      = map isStrictType val_arg_tys ++ repeat False
 236         -- These argument types are used as a cheap and cheerful way to find
 237         -- unboxed arguments, which must be strict.  But it's an InType
 238         -- and so there might be a type variable where we expect a function
 239         -- type (the substitution hasn't happened yet).  And we don't bother
 240         -- doing the type applications for a polymorphic function.
 241         -- Hence the split*Rep*FunTys
 242
 243     ----------------------------
 244         -- If fun_stricts is finite, it means the function returns bottom
 245         -- after that number of value args have been consumed
 246         -- Otherwise it's infinite, extended with False
 247     fun_stricts
 248       = case splitStrictSig (idNewStrictness fun) of
 249           (demands, result_info)
 250                 | not (demands `lengthExceeds` countValArgs orig_cont)
 251                 ->      -- Enough args, use the strictness given.
 252                         -- For bottoming functions we used to pretend that the arg
 253                         -- is lazy, so that we don't treat the arg as an
 254                         -- interesting context.  This avoids substituting
 255                         -- top-level bindings for (say) strings into
 256                         -- calls to error.  But now we are more careful about
 257                         -- inlining lone variables, so its ok (see SimplUtils.analyseCont)
 258                    if isBotRes result_info then
 259                         map isStrictDmd demands         -- Finite => result is bottom
 260                    else
 261                         map isStrictDmd demands ++ vanilla_stricts
 262
 263           other -> vanilla_stricts      -- Not enough args, or no strictness
 264
 265 -------------------
 266 interestingArg :: OutExpr -> Bool
 267         -- An argument is interesting if it has *some* structure
 268         -- We are here trying to avoid unfolding a function that
 269         -- is applied only to variables that have no unfolding
 270         -- (i.e. they are probably lambda bound): f x y z
 271         -- There is little point in inlining f here.
 272 interestingArg (Var v)           = hasSomeUnfolding (idUnfolding v)
 273                                         -- Was: isValueUnfolding (idUnfolding v')
 274                                         -- But that seems over-pessimistic
 275 interestingArg (Type _)          = False
 276 interestingArg (App fn (Type _)) = interestingArg fn
 277 interestingArg (Note _ a)        = interestingArg a
 278 interestingArg other             = True
 279         -- Consider     let x = 3 in f x
 280         -- The substitution will contain (x -> ContEx 3), and we want to
 281         -- to say that x is an interesting argument.
 282         -- But consider also (\x. f x y) y
 283         -- The substitution will contain (x -> ContEx y), and we want to say
 284         -- that x is not interesting (assuming y has no unfolding)
 285 \end{code}
 286
 287 Comment about interestingCallContext
 288 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 289 We want to avoid inlining an expression where there can't possibly be
 290 any gain, such as in an argument position.  Hence, if the continuation
 291 is interesting (eg. a case scrutinee, application etc.) then we
 292 inline, otherwise we don't.
 293
 294 Previously some_benefit used to return True only if the variable was
 295 applied to some value arguments.  This didn't work:
 296
 297         let x = _coerce_ (T Int) Int (I# 3) in
 298         case _coerce_ Int (T Int) x of
 299                 I# y -> ....
 300
 301 we want to inline x, but can't see that it's a constructor in a case
 302 scrutinee position, and some_benefit is False.
 303
 304 Another example:
 305
 306 dMonadST = _/\_ t -> :Monad (g1 _@_ t, g2 _@_ t, g3 _@_ t)
 307
 308 ....  case dMonadST _@_ x0 of (a,b,c) -> ....
 309
 310 we'd really like to inline dMonadST here, but we *don't* want to
 311 inline if the case expression is just
 312
 313         case x of y { DEFAULT -> ... }
 314
 315 since we can just eliminate this case instead (x is in WHNF).  Similar
 316 applies when x is bound to a lambda expression.  Hence
 317 contIsInteresting looks for case expressions with just a single
 318 default case.
 319
 320 \begin{code}
 321 interestingCallContext :: Bool          -- False <=> no args at all
 322                        -> Bool          -- False <=> no value args
 323                        -> SimplCont -> Bool
 324         -- The "lone-variable" case is important.  I spent ages
 325         -- messing about with unsatisfactory varaints, but this is nice.
 326         -- The idea is that if a variable appear all alone
 327         --      as an arg of lazy fn, or rhs    Stop
 328         --      as scrutinee of a case          Select
 329         --      as arg of a strict fn           ArgOf
 330         -- then we should not inline it (unless there is some other reason,
 331         -- e.g. is is the sole occurrence).  We achieve this by making
 332         -- interestingCallContext return False for a lone variable.
 333         --
 334         -- Why?  At least in the case-scrutinee situation, turning
 335         --      let x = (a,b) in case x of y -> ...
 336         -- into
 337         --      let x = (a,b) in case (a,b) of y -> ...
 338         -- and thence to
 339         --      let x = (a,b) in let y = (a,b) in ...
 340         -- is bad if the binding for x will remain.
 341         --
 342         -- Another example: I discovered that strings
 343         -- were getting inlined straight back into applications of 'error'
 344         -- because the latter is strict.
 345         --      s = "foo"
 346         --      f = \x -> ...(error s)...
 347
 348         -- Fundamentally such contexts should not ecourage inlining because
 349         -- the context can ``see'' the unfolding of the variable (e.g. case or a RULE)
 350         -- so there's no gain.
 351         --
 352         -- However, even a type application or coercion isn't a lone variable.
 353         -- Consider
 354         --      case $fMonadST @ RealWorld of { :DMonad a b c -> c }
 355         -- We had better inline that sucker!  The case won't see through it.
 356         --
 357         -- For now, I'm treating treating a variable applied to types
 358         -- in a *lazy* context "lone". The motivating example was
 359         --      f = /\a. \x. BIG
 360         --      g = /\a. \y.  h (f a)
 361         -- There's no advantage in inlining f here, and perhaps
 362         -- a significant disadvantage.  Hence some_val_args in the Stop case
 363
 364 interestingCallContext some_args some_val_args cont
 365   = interesting cont
 366   where
 367     interesting (InlinePlease _)       = True
 368     interesting (Select _ _ _ _ _)     = some_args
 369     interesting (ApplyTo _ _ _ _)      = True   -- Can happen if we have (coerce t (f x)) y
 370                                                 -- Perhaps True is a bit over-keen, but I've
 371                                                 -- seen (coerce f) x, where f has an INLINE prag,
 372                                                 -- So we have to give some motivaiton for inlining it
 373     interesting (ArgOf _ _ _ _)          = some_val_args
 374     interesting (Stop ty _ upd_in_place) = some_val_args && upd_in_place
 375     interesting (CoerceIt _ cont)        = interesting cont
 376         -- If this call is the arg of a strict function, the context
 377         -- is a bit interesting.  If we inline here, we may get useful
 378         -- evaluation information to avoid repeated evals: e.g.
 379         --      x + (y * z)
 380         -- Here the contIsInteresting makes the '*' keener to inline,
 381         -- which in turn exposes a constructor which makes the '+' inline.
 382         -- Assuming that +,* aren't small enough to inline regardless.
 383         --
 384         -- It's also very important to inline in a strict context for things
 385         -- like
 386         --              foldr k z (f x)
 387         -- Here, the context of (f x) is strict, and if f's unfolding is
 388         -- a build it's *great* to inline it here.  So we must ensure that
 389         -- the context for (f x) is not totally uninteresting.
 390
 391
 392 -------------------
 393 canUpdateInPlace :: Type -> Bool
 394 -- Consider   let x = <wurble> in ...
 395 -- If <wurble> returns an explicit constructor, we might be able
 396 -- to do update in place.  So we treat even a thunk RHS context
 397 -- as interesting if update in place is possible.  We approximate
 398 -- this by seeing if the type has a single constructor with a
 399 -- small arity.  But arity zero isn't good -- we share the single copy
 400 -- for that case, so no point in sharing.
 401
 402 canUpdateInPlace ty
 403   | not opt_UF_UpdateInPlace = False
 404   | otherwise
 405   = case splitTyConApp_maybe ty of
 406         Nothing         -> False
 407         Just (tycon, _) -> case tyConDataConsIfAvailable tycon of
 408                                 [dc]  -> arity == 1 || arity == 2
 409                                       where
 410                                          arity = dataConRepArity dc
 411                                 other -> False
 412 \end{code}
 413
 414
 415
 416 %************************************************************************
 417 %*                                                                      *
 418 \section{Dealing with a single binder}
 419 %*                                                                      *
 420 %************************************************************************
 421
 422 These functions are in the monad only so that they can be made strict via seq.
 423
 424 \begin{code}
 425 simplBinders :: SimplEnv -> [InBinder] -> SimplM (SimplEnv, [OutBinder])
 426 simplBinders env bndrs
 427   = let
 428         (subst', bndrs') = Subst.simplBndrs (getSubst env) bndrs
 429     in
 430     seqBndrs bndrs'     `seq`
 431     returnSmpl (setSubst env subst', bndrs')
 432
 433 simplBinder :: SimplEnv -> InBinder -> SimplM (SimplEnv, OutBinder)
 434 simplBinder env bndr
 435   = let
 436         (subst', bndr') = Subst.simplBndr (getSubst env) bndr
 437     in
 438     seqBndr bndr'       `seq`
 439     returnSmpl (setSubst env subst', bndr')
 440
 441
 442 simplLamBinders :: SimplEnv -> [InBinder] -> SimplM (SimplEnv, [OutBinder])
 443 simplLamBinders env bndrs
 444   = let
 445         (subst', bndrs') = mapAccumL Subst.simplLamBndr (getSubst env) bndrs
 446     in
 447     seqBndrs bndrs'     `seq`
 448     returnSmpl (setSubst env subst', bndrs')
 449
 450 simplRecIds :: SimplEnv -> [InBinder] -> SimplM (SimplEnv, [OutBinder])
 451 simplRecIds env ids
 452   = let
 453         (subst', ids') = mapAccumL Subst.simplLetId (getSubst env) ids
 454     in
 455     seqBndrs ids'       `seq`
 456     returnSmpl (setSubst env subst', ids')
 457
 458 simplLetId :: SimplEnv -> InBinder -> SimplM (SimplEnv, OutBinder)
 459 simplLetId env id
 460   = let
 461         (subst', id') = Subst.simplLetId (getSubst env) id
 462     in
 463     seqBndr id'         `seq`
 464     returnSmpl (setSubst env subst', id')
 465
 466 seqBndrs [] = ()
 467 seqBndrs (b:bs) = seqBndr b `seq` seqBndrs bs
 468
 469 seqBndr b | isTyVar b = b `seq` ()
 470           | otherwise = seqType (idType b)      `seq`
 471                         idInfo b                `seq`
 472                         ()
 473 \end{code}
 474
 475
 476 \begin{code}
 477 newId :: UserFS -> Type -> SimplM Id
 478 newId fs ty = getUniqueSmpl     `thenSmpl` \ uniq ->
 479               returnSmpl (mkSysLocal fs uniq ty)
 480 \end{code}
 481
 482
 483 %************************************************************************
 484 %*                                                                      *
 485 \subsection{Rebuilding a lambda}
 486 %*                                                                      *
 487 %************************************************************************
 488
 489 \begin{code}
 490 mkLam :: SimplEnv -> [OutBinder] -> OutExpr -> SimplCont -> SimplM FloatsWithExpr
 491 \end{code}
 492
 493 Try three things
 494         a) eta reduction, if that gives a trivial expression
 495         b) eta expansion [only if there are some value lambdas]
 496         c) floating lets out through big lambdas
 497                 [only if all tyvar lambdas, and only if this lambda
 498                  is the RHS of a let]
 499
 500 \begin{code}
 501 mkLam env bndrs body cont
 502  | opt_SimplDoEtaReduction,
 503    Just etad_lam <- tryEtaReduce bndrs body
 504  = tick (EtaReduction (head bndrs))     `thenSmpl_`
 505    returnSmpl (emptyFloats env, etad_lam)
 506
 507  | opt_SimplDoLambdaEtaExpansion,
 508    any isRuntimeVar bndrs
 509  = tryEtaExpansion body         `thenSmpl` \ body' ->
 510    returnSmpl (emptyFloats env, mkLams bndrs body')
 511
 512 {-      Sept 01: I'm experimenting with getting the
 513         full laziness pass to float out past big lambdsa
 514  | all isTyVar bndrs,   -- Only for big lambdas
 515    contIsRhs cont       -- Only try the rhs type-lambda floating
 516                         -- if this is indeed a right-hand side; otherwise
 517                         -- we end up floating the thing out, only for float-in
 518                         -- to float it right back in again!
 519  = tryRhsTyLam env bndrs body           `thenSmpl` \ (floats, body') ->
 520    returnSmpl (floats, mkLams bndrs body')
 521 -}
 522
 523  | otherwise
 524  = returnSmpl (emptyFloats env, mkLams bndrs body)
 525 \end{code}
 526
 527
 528 %************************************************************************
 529 %*                                                                      *
 530 \subsection{Eta expansion and reduction}
 531 %*                                                                      *
 532 %************************************************************************
 533
 534 We try for eta reduction here, but *only* if we get all the
 535 way to an exprIsTrivial expression.
 536 We don't want to remove extra lambdas unless we are going
 537 to avoid allocating this thing altogether
 538
 539 \begin{code}
 540 tryEtaReduce :: [OutBinder] -> OutExpr -> Maybe OutExpr
 541 tryEtaReduce bndrs body
 542         -- We don't use CoreUtils.etaReduce, because we can be more
 543         -- efficient here:
 544         --  (a) we already have the binders
 545         --  (b) we can do the triviality test before computing the free vars
 546         --      [in fact I take the simple path and look for just a variable]
 547   = go (reverse bndrs) body
 548   where
 549     go (b : bs) (App fun arg) | ok_arg b arg = go bs fun        -- Loop round
 550     go []       (Var fun)     | ok_fun fun   = Just (Var fun)   -- Success!
 551     go _        _                            = Nothing          -- Failure!
 552
 553     ok_fun fun   = not (fun `elem` bndrs) && not (hasNoBinding fun)
 554     ok_arg b arg = varToCoreExpr b `cheapEqExpr` arg
 555 \end{code}
 556
 557
 558         Try eta expansion for RHSs
 559
 560 We go for:
 561    f = \x1..xn -> N  ==>   f = \x1..xn y1..ym -> N y1..ym
 562                                  (n >= 0)
 563
 564 where (in both cases)
 565
 566         * The xi can include type variables
 567
 568         * The yi are all value variables
 569
 570         * N is a NORMAL FORM (i.e. no redexes anywhere)
 571           wanting a suitable number of extra args.
 572
 573 We may have to sandwich some coerces between the lambdas
 574 to make the types work.   exprEtaExpandArity looks through coerces
 575 when computing arity; and etaExpand adds the coerces as necessary when
 576 actually computing the expansion.
 577
 578 \begin{code}
 579 tryEtaExpansion :: OutExpr -> SimplM OutExpr
 580 -- There is at least one runtime binder in the binders
 581 tryEtaExpansion body
 582   | arity_is_manifest           -- Some lambdas but not enough
 583   = returnSmpl body
 584
 585   | otherwise
 586   = getUniquesSmpl                      `thenSmpl` \ us ->
 587     returnSmpl (etaExpand fun_arity us body (exprType body))
 588   where
 589     (fun_arity, arity_is_manifest) = exprEtaExpandArity body
 590 \end{code}
 591
 592
 593 %************************************************************************
 594 %*                                                                      *
 595 \subsection{Floating lets out of big lambdas}
 596 %*                                                                      *
 597 %************************************************************************
 598
 599 tryRhsTyLam tries this transformation, when the big lambda appears as
 600 the RHS of a let(rec) binding:
 601
 602         /\abc -> let(rec) x = e in b
 603    ==>
 604         let(rec) x' = /\abc -> let x = x' a b c in e
 605         in
 606         /\abc -> let x = x' a b c in b
 607
 608 This is good because it can turn things like:
 609
 610         let f = /\a -> letrec g = ... g ... in g
 611 into
 612         letrec g' = /\a -> ... g' a ...
 613         in
 614         let f = /\ a -> g' a
 615
 616 which is better.  In effect, it means that big lambdas don't impede
 617 let-floating.
 618
 619 This optimisation is CRUCIAL in eliminating the junk introduced by
 620 desugaring mutually recursive definitions.  Don't eliminate it lightly!
 621
 622 So far as the implementation is concerned:
 623
 624         Invariant: go F e = /\tvs -> F e
 625
 626         Equalities:
 627                 go F (Let x=e in b)
 628                 = Let x' = /\tvs -> F e
 629                   in
 630                   go G b
 631                 where
 632                     G = F . Let x = x' tvs
 633
 634                 go F (Letrec xi=ei in b)
 635                 = Letrec {xi' = /\tvs -> G ei}
 636                   in
 637                   go G b
 638                 where
 639                   G = F . Let {xi = xi' tvs}
 640
 641 [May 1999]  If we do this transformation *regardless* then we can
 642 end up with some pretty silly stuff.  For example,
 643
 644         let
 645             st = /\ s -> let { x1=r1 ; x2=r2 } in ...
 646         in ..
 647 becomes
 648         let y1 = /\s -> r1
 649             y2 = /\s -> r2
 650             st = /\s -> ...[y1 s/x1, y2 s/x2]
 651         in ..
 652
 653 Unless the "..." is a WHNF there is really no point in doing this.
 654 Indeed it can make things worse.  Suppose x1 is used strictly,
 655 and is of the form
 656
 657         x1* = case f y of { (a,b) -> e }
 658
 659 If we abstract this wrt the tyvar we then can't do the case inline
 660 as we would normally do.
 661
 662
 663 \begin{code}
 664 {-      Trying to do this in full laziness
 665
 666 tryRhsTyLam :: SimplEnv -> [OutTyVar] -> OutExpr -> SimplM FloatsWithExpr
 667 -- Call ensures that all the binders are type variables
 668
 669 tryRhsTyLam env tyvars body             -- Only does something if there's a let
 670   |  not (all isTyVar tyvars)
 671   || not (worth_it body)                -- inside a type lambda,
 672   = returnSmpl (emptyFloats env, body)  -- and a WHNF inside that
 673
 674   | otherwise
 675   = go env (\x -> x) body
 676
 677   where
 678     worth_it e@(Let _ _) = whnf_in_middle e
 679     worth_it e           = False
 680
 681     whnf_in_middle (Let (NonRec x rhs) e) | isUnLiftedType (idType x) = False
 682     whnf_in_middle (Let _ e) = whnf_in_middle e
 683     whnf_in_middle e         = exprIsCheap e
 684
 685     main_tyvar_set = mkVarSet tyvars
 686
 687     go env fn (Let bind@(NonRec var rhs) body)
 688       | exprIsTrivial rhs
 689       = go env (fn . Let bind) body
 690
 691     go env fn (Let (NonRec var rhs) body)
 692       = mk_poly tyvars_here var                                                 `thenSmpl` \ (var', rhs') ->
 693         addAuxiliaryBind env (NonRec var' (mkLams tyvars_here (fn rhs)))        $ \ env ->
 694         go env (fn . Let (mk_silly_bind var rhs')) body
 695
 696       where
 697
 698         tyvars_here = varSetElems (main_tyvar_set `intersectVarSet` exprSomeFreeVars isTyVar rhs)
 699                 -- Abstract only over the type variables free in the rhs
 700                 -- wrt which the new binding is abstracted.  But the naive
 701                 -- approach of abstract wrt the tyvars free in the Id's type
 702                 -- fails. Consider:
 703                 --      /\ a b -> let t :: (a,b) = (e1, e2)
 704                 --                    x :: a     = fst t
 705                 --                in ...
 706                 -- Here, b isn't free in x's type, but we must nevertheless
 707                 -- abstract wrt b as well, because t's type mentions b.
 708                 -- Since t is floated too, we'd end up with the bogus:
 709                 --      poly_t = /\ a b -> (e1, e2)
 710                 --      poly_x = /\ a   -> fst (poly_t a *b*)
 711                 -- So for now we adopt the even more naive approach of
 712                 -- abstracting wrt *all* the tyvars.  We'll see if that
 713                 -- gives rise to problems.   SLPJ June 98
 714
 715     go env fn (Let (Rec prs) body)
 716        = mapAndUnzipSmpl (mk_poly tyvars_here) vars     `thenSmpl` \ (vars', rhss') ->
 717          let
 718             gn body = fn (foldr Let body (zipWith mk_silly_bind vars rhss'))
 719             pairs   = vars' `zip` [mkLams tyvars_here (gn rhs) | rhs <- rhss]
 720          in
 721          addAuxiliaryBind env (Rec pairs)               $ \ env ->
 722          go env gn body
 723        where
 724          (vars,rhss) = unzip prs
 725          tyvars_here = varSetElems (main_tyvar_set `intersectVarSet` exprsSomeFreeVars isTyVar (map snd prs))
 726                 -- See notes with tyvars_here above
 727
 728     go env fn body = returnSmpl (emptyFloats env, fn body)
 729
 730     mk_poly tyvars_here var
 731       = getUniqueSmpl           `thenSmpl` \ uniq ->
 732         let
 733             poly_name = setNameUnique (idName var) uniq         -- Keep same name
 734             poly_ty   = mkForAllTys tyvars_here (idType var)    -- But new type of course
 735             poly_id   = mkLocalId poly_name poly_ty
 736
 737                 -- In the olden days, it was crucial to copy the occInfo of the original var,
 738                 -- because we were looking at occurrence-analysed but as yet unsimplified code!
 739                 -- In particular, we mustn't lose the loop breakers.  BUT NOW we are looking
 740                 -- at already simplified code, so it doesn't matter
 741                 --
 742                 -- It's even right to retain single-occurrence or dead-var info:
 743                 -- Suppose we started with  /\a -> let x = E in B
 744                 -- where x occurs once in B. Then we transform to:
 745                 --      let x' = /\a -> E in /\a -> let x* = x' a in B
 746                 -- where x* has an INLINE prag on it.  Now, once x* is inlined,
 747                 -- the occurrences of x' will be just the occurrences originally
 748                 -- pinned on x.
 749         in
 750         returnSmpl (poly_id, mkTyApps (Var poly_id) (mkTyVarTys tyvars_here))
 751
 752     mk_silly_bind var rhs = NonRec var (Note InlineMe rhs)
 753                 -- Suppose we start with:
 754                 --
 755                 --      x = /\ a -> let g = G in E
 756                 --
 757                 -- Then we'll float to get
 758                 --
 759                 --      x = let poly_g = /\ a -> G
 760                 --          in /\ a -> let g = poly_g a in E
 761                 --
 762                 -- But now the occurrence analyser will see just one occurrence
 763                 -- of poly_g, not inside a lambda, so the simplifier will
 764                 -- PreInlineUnconditionally poly_g back into g!  Badk to square 1!
 765                 -- (I used to think that the "don't inline lone occurrences" stuff
 766                 --  would stop this happening, but since it's the *only* occurrence,
 767                 --  PreInlineUnconditionally kicks in first!)
 768                 --
 769                 -- Solution: put an INLINE note on g's RHS, so that poly_g seems
 770                 --           to appear many times.  (NB: mkInlineMe eliminates
 771                 --           such notes on trivial RHSs, so do it manually.)
 772 -}
 773 \end{code}
 774
 775
 776 %************************************************************************
 777 %*                                                                      *
 778 \subsection{Case absorption and identity-case elimination}
 779 %*                                                                      *
 780 %************************************************************************
 781
 782 mkCase puts a case expression back together, trying various transformations first.
 783
 784 \begin{code}
 785 mkCase :: OutExpr -> OutId -> [OutAlt] -> SimplM OutExpr
 786
 787 mkCase scrut case_bndr alts
 788   = mkAlts scrut case_bndr alts `thenSmpl` \ better_alts ->
 789     mkCase1 scrut case_bndr better_alts
 790 \end{code}
 791
 792
 793 mkAlts tries these things:
 794
 795 1.  If several alternatives are identical, merge them into
 796     a single DEFAULT alternative.  I've occasionally seen this
 797     making a big difference:
 798
 799         case e of               =====>     case e of
 800           C _ -> f x                         D v -> ....v....
 801           D v -> ....v....                   DEFAULT -> f x
 802           DEFAULT -> f x
 803
 804    The point is that we merge common RHSs, at least for the DEFAULT case.
 805    [One could do something more elaborate but I've never seen it needed.]
 806    To avoid an expensive test, we just merge branches equal to the *first*
 807    alternative; this picks up the common cases
 808         a) all branches equal
 809         b) some branches equal to the DEFAULT (which occurs first)
 810
 811 2.  If the DEFAULT alternative can match only one possible constructor,
 812     then make that constructor explicit.
 813     e.g.
 814         case e of x { DEFAULT -> rhs }
 815      ===>
 816         case e of x { (a,b) -> rhs }
 817     where the type is a single constructor type.  This gives better code
 818     when rhs also scrutinises x or e.
 819
 820 3.  Case merging:
 821        case e of b {             ==>   case e of b {
 822          p1 -> rhs1                      p1 -> rhs1
 823          ...                             ...
 824          pm -> rhsm                      pm -> rhsm
 825          _  -> case b of b' {            pn -> let b'=b in rhsn
 826                      pn -> rhsn          ...
 827                      ...                 po -> let b'=b in rhso
 828                      po -> rhso          _  -> let b'=b in rhsd
 829                      _  -> rhsd
 830        }
 831
 832     which merges two cases in one case when -- the default alternative of
 833     the outer case scrutises the same variable as the outer case This
 834     transformation is called Case Merging.  It avoids that the same
 835     variable is scrutinised multiple times.
 836
 837
 838 The case where transformation (1) showed up was like this (lib/std/PrelCError.lhs):
 839
 840         x | p `is` 1 -> e1
 841           | p `is` 2 -> e2
 842         ...etc...
 843
 844 where @is@ was something like
 845
 846         p `is` n = p /= (-1) && p == n
 847
 848 This gave rise to a horrible sequence of cases
 849
 850         case p of
 851           (-1) -> $j p
 852           1    -> e1
 853           DEFAULT -> $j p
 854
 855 and similarly in cascade for all the join points!
 856
 857
 858
 859 \begin{code}
 860 --------------------------------------------------
 861 --      1. Merge identical branches
 862 --------------------------------------------------
 863 mkAlts scrut case_bndr alts@((con1,bndrs1,rhs1) : con_alts)
 864   | all isDeadBinder bndrs1,                    -- Remember the default
 865     length filtered_alts < length con_alts      -- alternative comes first
 866   = tick (AltMerge case_bndr)                   `thenSmpl_`
 867     returnSmpl better_alts
 868   where
 869     filtered_alts        = filter keep con_alts
 870     keep (con,bndrs,rhs) = not (all isDeadBinder bndrs && rhs `cheapEqExpr` rhs1)
 871     better_alts          = (DEFAULT, [], rhs1) : filtered_alts
 872
 873
 874 --------------------------------------------------
 875 --      2. Fill in missing constructor
 876 --------------------------------------------------
 877
 878 mkAlts scrut case_bndr alts
 879   | Just (tycon, inst_tys) <- splitTyConApp_maybe (idType case_bndr),
 880     isDataTyCon tycon,                  -- It's a data type
 881     (alts_no_deflt, Just rhs) <- findDefault alts,
 882                 -- There is a DEFAULT case
 883     [missing_con] <- filter is_missing (tyConDataConsIfAvailable tycon)
 884                 -- There is just one missing constructor!
 885   = tick (FillInCaseDefault case_bndr)  `thenSmpl_`
 886     getUniquesSmpl                      `thenSmpl` \ tv_uniqs ->
 887     getUniquesSmpl                      `thenSmpl` \ id_uniqs ->
 888     let
 889         (_,_,ex_tyvars,_,_,_) = dataConSig missing_con
 890         ex_tyvars'  = zipWith mk tv_uniqs ex_tyvars
 891         mk uniq tv  = mkSysTyVar uniq (tyVarKind tv)
 892         arg_ids     = zipWith (mkSysLocal SLIT("a")) id_uniqs arg_tys
 893         arg_tys     = dataConArgTys missing_con (inst_tys ++ mkTyVarTys ex_tyvars')
 894         better_alts = (DataAlt missing_con, ex_tyvars' ++ arg_ids, rhs) : alts_no_deflt
 895     in
 896     returnSmpl better_alts
 897   where
 898     impossible_cons   = otherCons (idUnfolding case_bndr)
 899     handled_data_cons = [data_con | DataAlt data_con         <- impossible_cons] ++
 900                         [data_con | (DataAlt data_con, _, _) <- alts]
 901     is_missing con    = not (con `elem` handled_data_cons)
 902
 903 --------------------------------------------------
 904 --      3.  Merge nested cases
 905 --------------------------------------------------
 906
 907 mkAlts scrut outer_bndr outer_alts
 908   | opt_SimplCaseMerge,
 909     (outer_alts_without_deflt, maybe_outer_deflt)   <- findDefault outer_alts,
 910     Just (Case (Var scrut_var) inner_bndr inner_alts) <- maybe_outer_deflt,
 911     scruting_same_var scrut_var
 912
 913   = let     --  Eliminate any inner alts which are shadowed by the outer ones
 914         outer_cons = [con | (con,_,_) <- outer_alts_without_deflt]
 915
 916         munged_inner_alts = [ (con, args, munge_rhs rhs)
 917                             | (con, args, rhs) <- inner_alts,
 918                                not (con `elem` outer_cons)      -- Eliminate shadowed inner alts
 919                             ]
 920         munge_rhs rhs = bindCaseBndr inner_bndr (Var outer_bndr) rhs
 921
 922         (inner_con_alts, maybe_inner_default) = findDefault munged_inner_alts
 923
 924         new_alts = add_default maybe_inner_default
 925                                (outer_alts_without_deflt ++ inner_con_alts)
 926     in
 927     tick (CaseMerge outer_bndr)                         `thenSmpl_`
 928     returnSmpl new_alts
 929         -- Warning: don't call mkAlts recursively!
 930         -- Firstly, there's no point, because inner alts have already had
 931         -- mkCase applied to them, so they won't have a case in their default
 932         -- Secondly, if you do, you get an infinite loop, because the bindCaseBndr
 933         -- in munge_rhs may put a case into the DEFAULT branch!
 934   where
 935         -- We are scrutinising the same variable if it's
 936         -- the outer case-binder, or if the outer case scrutinises a variable
 937         -- (and it's the same).  Testing both allows us not to replace the
 938         -- outer scrut-var with the outer case-binder (Simplify.simplCaseBinder).
 939     scruting_same_var = case scrut of
 940                           Var outer_scrut -> \ v -> v == outer_bndr || v == outer_scrut
 941                           other           -> \ v -> v == outer_bndr
 942
 943     add_default (Just rhs) alts = (DEFAULT,[],rhs) : alts
 944     add_default Nothing    alts = alts
 945
 946
 947 --------------------------------------------------
 948 --      Catch-all
 949 --------------------------------------------------
 950
 951 mkAlts scrut case_bndr other_alts = returnSmpl other_alts
 952 \end{code}
 953
 954
 955
 956 =================================================================================
 957
 958 mkCase1 tries these things
 959
 960 1.  Eliminate the case altogether if possible
 961
 962 2.  Case-identity:
 963
 964         case e of               ===> e
 965                 True  -> True;
 966                 False -> False
 967
 968     and similar friends.
 969
 970
 971 Start with a simple situation:
 972
 973         case x# of      ===>   e[x#/y#]
 974           y# -> e
 975
 976 (when x#, y# are of primitive type, of course).  We can't (in general)
 977 do this for algebraic cases, because we might turn bottom into
 978 non-bottom!
 979
 980 Actually, we generalise this idea to look for a case where we're
 981 scrutinising a variable, and we know that only the default case can
 982 match.  For example:
 983 \begin{verbatim}
 984         case x of
 985           0#    -> ...
 986           other -> ...(case x of
 987                          0#    -> ...
 988                          other -> ...) ...
 989 \end{code}
 990 Here the inner case can be eliminated.  This really only shows up in
 991 eliminating error-checking code.
 992
 993 We also make sure that we deal with this very common case:
 994
 995         case e of
 996           x -> ...x...
 997
 998 Here we are using the case as a strict let; if x is used only once
 999 then we want to inline it.  We have to be careful that this doesn't
1000 make the program terminate when it would have diverged before, so we
1001 check that
1002         - x is used strictly, or
1003         - e is already evaluated (it may so if e is a variable)
1004
1005 Lastly, we generalise the transformation to handle this:
1006
1007         case e of       ===> r
1008            True  -> r
1009            False -> r
1010
1011 We only do this for very cheaply compared r's (constructors, literals
1012 and variables).  If pedantic bottoms is on, we only do it when the
1013 scrutinee is a PrimOp which can't fail.
1014
1015 We do it *here*, looking at un-simplified alternatives, because we
1016 have to check that r doesn't mention the variables bound by the
1017 pattern in each alternative, so the binder-info is rather useful.
1018
1019 So the case-elimination algorithm is:
1020
1021         1. Eliminate alternatives which can't match
1022
1023         2. Check whether all the remaining alternatives
1024                 (a) do not mention in their rhs any of the variables bound in their pattern
1025            and  (b) have equal rhss
1026
1027         3. Check we can safely ditch the case:
1028                    * PedanticBottoms is off,
1029                 or * the scrutinee is an already-evaluated variable
1030                 or * the scrutinee is a primop which is ok for speculation
1031                         -- ie we want to preserve divide-by-zero errors, and
1032                         -- calls to error itself!
1033
1034                 or * [Prim cases] the scrutinee is a primitive variable
1035
1036                 or * [Alg cases] the scrutinee is a variable and
1037                      either * the rhs is the same variable
1038                         (eg case x of C a b -> x  ===>   x)
1039                      or     * there is only one alternative, the default alternative,
1040                                 and the binder is used strictly in its scope.
1041                                 [NB this is helped by the "use default binder where
1042                                  possible" transformation; see below.]
1043
1044
1045 If so, then we can replace the case with one of the rhss.
1046
1047
1048 \begin{code}
1049 --------------------------------------------------
1050 --      1. Eliminate the case altogether if poss
1051 --------------------------------------------------
1052
1053 mkCase1 scrut case_bndr [(con,bndrs,rhs)]
1054   -- See if we can get rid of the case altogether
1055   -- See the extensive notes on case-elimination above
1056   -- mkCase made sure that if all the alternatives are equal,
1057   -- then there is now only one (DEFAULT) rhs
1058  |  all isDeadBinder bndrs,
1059
1060         -- Check that the scrutinee can be let-bound instead of case-bound
1061     exprOkForSpeculation scrut
1062                 -- OK not to evaluate it
1063                 -- This includes things like (==# a# b#)::Bool
1064                 -- so that we simplify
1065                 --      case ==# a# b# of { True -> x; False -> x }
1066                 -- to just
1067                 --      x
1068                 -- This particular example shows up in default methods for
1069                 -- comparision operations (e.g. in (>=) for Int.Int32)
1070         || exprIsValue scrut                    -- It's already evaluated
1071         || var_demanded_later scrut             -- It'll be demanded later
1072
1073 --      || not opt_SimplPedanticBottoms)        -- Or we don't care!
1074 --      We used to allow improving termination by discarding cases, unless -fpedantic-bottoms was on,
1075 --      but that breaks badly for the dataToTag# primop, which relies on a case to evaluate
1076 --      its argument:  case x of { y -> dataToTag# y }
1077 --      Here we must *not* discard the case, because dataToTag# just fetches the tag from
1078 --      the info pointer.  So we'll be pedantic all the time, and see if that gives any
1079 --      other problems
1080   = tick (CaseElim case_bndr)                   `thenSmpl_`
1081     returnSmpl (bindCaseBndr case_bndr scrut rhs)
1082
1083   where
1084         -- The case binder is going to be evaluated later,
1085         -- and the scrutinee is a simple variable
1086     var_demanded_later (Var v) = isStrictDmd (idNewDemandInfo case_bndr)
1087     var_demanded_later other   = False
1088
1089
1090 --------------------------------------------------
1091 --      2. Identity case
1092 --------------------------------------------------
1093
1094 mkCase1 scrut case_bndr alts    -- Identity case
1095   | all identity_alt alts
1096   = tick (CaseIdentity case_bndr)               `thenSmpl_`
1097     returnSmpl (re_note scrut)
1098   where
1099     identity_alt (con, args, rhs) = de_note rhs `cheapEqExpr` identity_rhs con args
1100
1101     identity_rhs (DataAlt con) args = mkConApp con (arg_tys ++ map varToCoreExpr args)
1102     identity_rhs (LitAlt lit)  _    = Lit lit
1103     identity_rhs DEFAULT       _    = Var case_bndr
1104
1105     arg_tys = map Type (tyConAppArgs (idType case_bndr))
1106
1107         -- We've seen this:
1108         --      case coerce T e of x { _ -> coerce T' x }
1109         -- And we definitely want to eliminate this case!
1110         -- So we throw away notes from the RHS, and reconstruct
1111         -- (at least an approximation) at the other end
1112     de_note (Note _ e) = de_note e
1113     de_note e          = e
1114
1115         -- re_note wraps a coerce if it might be necessary
1116     re_note scrut = case head alts of
1117                         (_,_,rhs1@(Note _ _)) -> mkCoerce (exprType rhs1) (idType case_bndr) scrut
1118                         other                 -> scrut
1119
1120
1121 --------------------------------------------------
1122 --      Catch-all
1123 --------------------------------------------------
1124 mkCase1 scrut bndr alts = returnSmpl (Case scrut bndr alts)
1125 \end{code}
1126
1127
1128 When adding auxiliary bindings for the case binder, it's worth checking if
1129 its dead, because it often is, and occasionally these mkCase transformations
1130 cascade rather nicely.
1131
1132 \begin{code}
1133 bindCaseBndr bndr rhs body
1134   | isDeadBinder bndr = body
1135   | otherwise         = bindNonRec bndr rhs body
1136 \end{code}