ghc/compiler/simplCore/SimplUtils.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[SimplUtils]{The simplifier utilities}
   5
   6 \begin{code}
   7 module SimplUtils (
   8         mkLam, prepareAlts, mkCase,
   9
  10         -- Inlining,
  11         preInlineUnconditionally, postInlineUnconditionally, activeInline, activeRule,
  12         inlineMode,
  13
  14         -- The continuation type
  15         SimplCont(..), DupFlag(..), LetRhsFlag(..),
  16         contIsDupable, contResultType,
  17         countValArgs, countArgs, pushContArgs,
  18         mkBoringStop, mkRhsStop, contIsRhs, contIsRhsOrArg,
  19         getContArgs, interestingCallContext, interestingArg, isStrictType
  20
  21     ) where
  22
  23 #include "HsVersions.h"
  24
  25 import SimplEnv
  26 import CmdLineOpts      ( SimplifierSwitch(..), SimplifierMode(..), opt_UF_UpdateInPlace,
  27                           opt_SimplNoPreInlining, opt_RulesOff,
  28                           DynFlag(..), dopt )
  29 import CoreSyn
  30 import CoreFVs          ( exprFreeVars )
  31 import CoreUtils        ( cheapEqExpr, exprType, exprIsTrivial,
  32                           etaExpand, exprEtaExpandArity, bindNonRec, mkCoerce2,
  33                           findDefault, exprOkForSpeculation, exprIsValue
  34                         )
  35 import Id               ( Id, idType, idInfo, isDataConWorkId, idOccInfo,
  36                           mkSysLocal, isDeadBinder, idNewDemandInfo, isExportedId,
  37                           idUnfolding, idNewStrictness, idInlinePragma,
  38                         )
  39 import NewDemand        ( isStrictDmd, isBotRes, splitStrictSig )
  40 import SimplMonad
  41 import Type             ( Type, seqType, splitFunTys, dropForAlls, isStrictType,
  42                           splitTyConApp_maybe, tyConAppArgs, mkTyVarTys
  43                         )
  44 import TcType           ( isDictTy )
  45 import Name             ( mkSysTvName )
  46 import OccName          ( EncodedFS )
  47 import TyCon            ( tyConDataCons_maybe, isAlgTyCon, isNewTyCon )
  48 import DataCon          ( dataConRepArity, dataConTyVars, dataConArgTys, isVanillaDataCon )
  49 import Var              ( tyVarKind, mkTyVar )
  50 import VarSet
  51 import BasicTypes       ( TopLevelFlag(..), isTopLevel, OccInfo(..), isLoopBreaker, isOneOcc,
  52                           Activation, isAlwaysActive, isActive )
  53 import Util             ( lengthExceeds, mapAccumL )
  54 import Outputable
  55 \end{code}
  56
  57
  58 %************************************************************************
  59 %*                                                                      *
  60 \subsection{The continuation data type}
  61 %*                                                                      *
  62 %************************************************************************
  63
  64 \begin{code}
  65 data SimplCont          -- Strict contexts
  66   = Stop     OutType            -- Type of the result
  67              LetRhsFlag
  68              Bool               -- True <=> This is the RHS of a thunk whose type suggests
  69                                 --          that update-in-place would be possible
  70                                 --          (This makes the inliner a little keener.)
  71
  72   | CoerceIt OutType                    -- The To-type, simplified
  73              SimplCont
  74
  75   | InlinePlease                        -- This continuation makes a function very
  76              SimplCont                  -- keen to inline itelf
  77
  78   | ApplyTo  DupFlag
  79              InExpr SimplEnv            -- The argument, as yet unsimplified,
  80              SimplCont                  -- and its environment
  81
  82   | Select   DupFlag
  83              InId [InAlt] SimplEnv      -- The case binder, alts, and subst-env
  84              SimplCont
  85
  86   | ArgOf    LetRhsFlag         -- An arbitrary strict context: the argument
  87                                 --      of a strict function, or a primitive-arg fn
  88                                 --      or a PrimOp
  89                                 -- No DupFlag because we never duplicate it
  90              OutType            -- arg_ty: type of the argument itself
  91              OutType            -- cont_ty: the type of the expression being sought by the context
  92                                 --      f (error "foo") ==> coerce t (error "foo")
  93                                 -- when f is strict
  94                                 -- We need to know the type t, to which to coerce.
  95
  96              (SimplEnv -> OutExpr -> SimplM FloatsWithExpr)     -- What to do with the result
  97                                 -- The result expression in the OutExprStuff has type cont_ty
  98
  99 data LetRhsFlag = AnArg         -- It's just an argument not a let RHS
 100                 | AnRhs         -- It's the RHS of a let (so please float lets out of big lambdas)
 101
 102 instance Outputable LetRhsFlag where
 103   ppr AnArg = ptext SLIT("arg")
 104   ppr AnRhs = ptext SLIT("rhs")
 105
 106 instance Outputable SimplCont where
 107   ppr (Stop _ is_rhs _)              = ptext SLIT("Stop") <> brackets (ppr is_rhs)
 108   ppr (ApplyTo dup arg se cont)      = (ptext SLIT("ApplyTo") <+> ppr dup <+> ppr arg) $$ ppr cont
 109   ppr (ArgOf _ _ _ _)                = ptext SLIT("ArgOf...")
 110   ppr (Select dup bndr alts se cont) = (ptext SLIT("Select") <+> ppr dup <+> ppr bndr) $$
 111                                        (nest 4 (ppr alts)) $$ ppr cont
 112   ppr (CoerceIt ty cont)             = (ptext SLIT("CoerceIt") <+> ppr ty) $$ ppr cont
 113   ppr (InlinePlease cont)            = ptext SLIT("InlinePlease") $$ ppr cont
 114
 115 data DupFlag = OkToDup | NoDup
 116
 117 instance Outputable DupFlag where
 118   ppr OkToDup = ptext SLIT("ok")
 119   ppr NoDup   = ptext SLIT("nodup")
 120
 121
 122 -------------------
 123 mkBoringStop, mkRhsStop :: OutType -> SimplCont
 124 mkBoringStop ty = Stop ty AnArg (canUpdateInPlace ty)
 125 mkRhsStop    ty = Stop ty AnRhs (canUpdateInPlace ty)
 126
 127 contIsRhs :: SimplCont -> Bool
 128 contIsRhs (Stop _ AnRhs _)    = True
 129 contIsRhs (ArgOf AnRhs _ _ _) = True
 130 contIsRhs other               = False
 131
 132 contIsRhsOrArg (Stop _ _ _)    = True
 133 contIsRhsOrArg (ArgOf _ _ _ _) = True
 134 contIsRhsOrArg other           = False
 135
 136 -------------------
 137 contIsDupable :: SimplCont -> Bool
 138 contIsDupable (Stop _ _ _)               = True
 139 contIsDupable (ApplyTo  OkToDup _ _ _)   = True
 140 contIsDupable (Select   OkToDup _ _ _ _) = True
 141 contIsDupable (CoerceIt _ cont)          = contIsDupable cont
 142 contIsDupable (InlinePlease cont)        = contIsDupable cont
 143 contIsDupable other                      = False
 144
 145 -------------------
 146 discardableCont :: SimplCont -> Bool
 147 discardableCont (Stop _ _ _)        = False
 148 discardableCont (CoerceIt _ cont)   = discardableCont cont
 149 discardableCont (InlinePlease cont) = discardableCont cont
 150 discardableCont other               = True
 151
 152 discardCont :: SimplCont        -- A continuation, expecting
 153             -> SimplCont        -- Replace the continuation with a suitable coerce
 154 discardCont cont = case cont of
 155                      Stop to_ty is_rhs _ -> cont
 156                      other               -> CoerceIt to_ty (mkBoringStop to_ty)
 157                  where
 158                    to_ty = contResultType cont
 159
 160 -------------------
 161 contResultType :: SimplCont -> OutType
 162 contResultType (Stop to_ty _ _)      = to_ty
 163 contResultType (ArgOf _ _ to_ty _)   = to_ty
 164 contResultType (ApplyTo _ _ _ cont)  = contResultType cont
 165 contResultType (CoerceIt _ cont)     = contResultType cont
 166 contResultType (InlinePlease cont)   = contResultType cont
 167 contResultType (Select _ _ _ _ cont) = contResultType cont
 168
 169 -------------------
 170 countValArgs :: SimplCont -> Int
 171 countValArgs (ApplyTo _ (Type ty) se cont) = countValArgs cont
 172 countValArgs (ApplyTo _ val_arg   se cont) = 1 + countValArgs cont
 173 countValArgs other                         = 0
 174
 175 countArgs :: SimplCont -> Int
 176 countArgs (ApplyTo _ arg se cont) = 1 + countArgs cont
 177 countArgs other                   = 0
 178
 179 -------------------
 180 pushContArgs :: SimplEnv -> [OutArg] -> SimplCont -> SimplCont
 181 -- Pushes args with the specified environment
 182 pushContArgs env []           cont = cont
 183 pushContArgs env (arg : args) cont = ApplyTo NoDup arg env (pushContArgs env args cont)
 184 \end{code}
 185
 186
 187 \begin{code}
 188 getContArgs :: SwitchChecker
 189             -> OutId -> SimplCont
 190             -> ([(InExpr, SimplEnv, Bool)],     -- Arguments; the Bool is true for strict args
 191                 SimplCont,                      -- Remaining continuation
 192                 Bool)                           -- Whether we came across an InlineCall
 193 -- getContArgs id k = (args, k', inl)
 194 --      args are the leading ApplyTo items in k
 195 --      (i.e. outermost comes first)
 196 --      augmented with demand info from the functionn
 197 getContArgs chkr fun orig_cont
 198   = let
 199                 -- Ignore strictness info if the no-case-of-case
 200                 -- flag is on.  Strictness changes evaluation order
 201                 -- and that can change full laziness
 202         stricts | switchIsOn chkr NoCaseOfCase = vanilla_stricts
 203                 | otherwise                    = computed_stricts
 204     in
 205     go [] stricts False orig_cont
 206   where
 207     ----------------------------
 208
 209         -- Type argument
 210     go acc ss inl (ApplyTo _ arg@(Type _) se cont)
 211         = go ((arg,se,False) : acc) ss inl cont
 212                 -- NB: don't bother to instantiate the function type
 213
 214         -- Value argument
 215     go acc (s:ss) inl (ApplyTo _ arg se cont)
 216         = go ((arg,se,s) : acc) ss inl cont
 217
 218         -- An Inline continuation
 219     go acc ss inl (InlinePlease cont)
 220         = go acc ss True cont
 221
 222         -- We're run out of arguments, or else we've run out of demands
 223         -- The latter only happens if the result is guaranteed bottom
 224         -- This is the case for
 225         --      * case (error "hello") of { ... }
 226         --      * (error "Hello") arg
 227         --      * f (error "Hello") where f is strict
 228         --      etc
 229         -- Then, especially in the first of these cases, we'd like to discard
 230         -- the continuation, leaving just the bottoming expression.  But the
 231         -- type might not be right, so we may have to add a coerce.
 232     go acc ss inl cont
 233         | null ss && discardableCont cont = (reverse acc, discardCont cont, inl)
 234         | otherwise                       = (reverse acc, cont,             inl)
 235
 236     ----------------------------
 237     vanilla_stricts, computed_stricts :: [Bool]
 238     vanilla_stricts  = repeat False
 239     computed_stricts = zipWith (||) fun_stricts arg_stricts
 240
 241     ----------------------------
 242     (val_arg_tys, _) = splitFunTys (dropForAlls (idType fun))
 243     arg_stricts      = map isStrictType val_arg_tys ++ repeat False
 244         -- These argument types are used as a cheap and cheerful way to find
 245         -- unboxed arguments, which must be strict.  But it's an InType
 246         -- and so there might be a type variable where we expect a function
 247         -- type (the substitution hasn't happened yet).  And we don't bother
 248         -- doing the type applications for a polymorphic function.
 249         -- Hence the splitFunTys*IgnoringForAlls*
 250
 251     ----------------------------
 252         -- If fun_stricts is finite, it means the function returns bottom
 253         -- after that number of value args have been consumed
 254         -- Otherwise it's infinite, extended with False
 255     fun_stricts
 256       = case splitStrictSig (idNewStrictness fun) of
 257           (demands, result_info)
 258                 | not (demands `lengthExceeds` countValArgs orig_cont)
 259                 ->      -- Enough args, use the strictness given.
 260                         -- For bottoming functions we used to pretend that the arg
 261                         -- is lazy, so that we don't treat the arg as an
 262                         -- interesting context.  This avoids substituting
 263                         -- top-level bindings for (say) strings into
 264                         -- calls to error.  But now we are more careful about
 265                         -- inlining lone variables, so its ok (see SimplUtils.analyseCont)
 266                    if isBotRes result_info then
 267                         map isStrictDmd demands         -- Finite => result is bottom
 268                    else
 269                         map isStrictDmd demands ++ vanilla_stricts
 270
 271           other -> vanilla_stricts      -- Not enough args, or no strictness
 272
 273 -------------------
 274 interestingArg :: OutExpr -> Bool
 275         -- An argument is interesting if it has *some* structure
 276         -- We are here trying to avoid unfolding a function that
 277         -- is applied only to variables that have no unfolding
 278         -- (i.e. they are probably lambda bound): f x y z
 279         -- There is little point in inlining f here.
 280 interestingArg (Var v)           = hasSomeUnfolding (idUnfolding v)
 281                                         -- Was: isValueUnfolding (idUnfolding v')
 282                                         -- But that seems over-pessimistic
 283                                  || isDataConWorkId v
 284                                         -- This accounts for an argument like
 285                                         -- () or [], which is definitely interesting
 286 interestingArg (Type _)          = False
 287 interestingArg (App fn (Type _)) = interestingArg fn
 288 interestingArg (Note _ a)        = interestingArg a
 289 interestingArg other             = True
 290         -- Consider     let x = 3 in f x
 291         -- The substitution will contain (x -> ContEx 3), and we want to
 292         -- to say that x is an interesting argument.
 293         -- But consider also (\x. f x y) y
 294         -- The substitution will contain (x -> ContEx y), and we want to say
 295         -- that x is not interesting (assuming y has no unfolding)
 296 \end{code}
 297
 298 Comment about interestingCallContext
 299 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 300 We want to avoid inlining an expression where there can't possibly be
 301 any gain, such as in an argument position.  Hence, if the continuation
 302 is interesting (eg. a case scrutinee, application etc.) then we
 303 inline, otherwise we don't.
 304
 305 Previously some_benefit used to return True only if the variable was
 306 applied to some value arguments.  This didn't work:
 307
 308         let x = _coerce_ (T Int) Int (I# 3) in
 309         case _coerce_ Int (T Int) x of
 310                 I# y -> ....
 311
 312 we want to inline x, but can't see that it's a constructor in a case
 313 scrutinee position, and some_benefit is False.
 314
 315 Another example:
 316
 317 dMonadST = _/\_ t -> :Monad (g1 _@_ t, g2 _@_ t, g3 _@_ t)
 318
 319 ....  case dMonadST _@_ x0 of (a,b,c) -> ....
 320
 321 we'd really like to inline dMonadST here, but we *don't* want to
 322 inline if the case expression is just
 323
 324         case x of y { DEFAULT -> ... }
 325
 326 since we can just eliminate this case instead (x is in WHNF).  Similar
 327 applies when x is bound to a lambda expression.  Hence
 328 contIsInteresting looks for case expressions with just a single
 329 default case.
 330
 331 \begin{code}
 332 interestingCallContext :: Bool          -- False <=> no args at all
 333                        -> Bool          -- False <=> no value args
 334                        -> SimplCont -> Bool
 335         -- The "lone-variable" case is important.  I spent ages
 336         -- messing about with unsatisfactory varaints, but this is nice.
 337         -- The idea is that if a variable appear all alone
 338         --      as an arg of lazy fn, or rhs    Stop
 339         --      as scrutinee of a case          Select
 340         --      as arg of a strict fn           ArgOf
 341         -- then we should not inline it (unless there is some other reason,
 342         -- e.g. is is the sole occurrence).  We achieve this by making
 343         -- interestingCallContext return False for a lone variable.
 344         --
 345         -- Why?  At least in the case-scrutinee situation, turning
 346         --      let x = (a,b) in case x of y -> ...
 347         -- into
 348         --      let x = (a,b) in case (a,b) of y -> ...
 349         -- and thence to
 350         --      let x = (a,b) in let y = (a,b) in ...
 351         -- is bad if the binding for x will remain.
 352         --
 353         -- Another example: I discovered that strings
 354         -- were getting inlined straight back into applications of 'error'
 355         -- because the latter is strict.
 356         --      s = "foo"
 357         --      f = \x -> ...(error s)...
 358
 359         -- Fundamentally such contexts should not ecourage inlining because
 360         -- the context can ``see'' the unfolding of the variable (e.g. case or a RULE)
 361         -- so there's no gain.
 362         --
 363         -- However, even a type application or coercion isn't a lone variable.
 364         -- Consider
 365         --      case $fMonadST @ RealWorld of { :DMonad a b c -> c }
 366         -- We had better inline that sucker!  The case won't see through it.
 367         --
 368         -- For now, I'm treating treating a variable applied to types
 369         -- in a *lazy* context "lone". The motivating example was
 370         --      f = /\a. \x. BIG
 371         --      g = /\a. \y.  h (f a)
 372         -- There's no advantage in inlining f here, and perhaps
 373         -- a significant disadvantage.  Hence some_val_args in the Stop case
 374
 375 interestingCallContext some_args some_val_args cont
 376   = interesting cont
 377   where
 378     interesting (InlinePlease _)         = True
 379     interesting (Select _ _ _ _ _)       = some_args
 380     interesting (ApplyTo _ _ _ _)        = True -- Can happen if we have (coerce t (f x)) y
 381                                                 -- Perhaps True is a bit over-keen, but I've
 382                                                 -- seen (coerce f) x, where f has an INLINE prag,
 383                                                 -- So we have to give some motivaiton for inlining it
 384     interesting (ArgOf _ _ _ _)          = some_val_args
 385     interesting (Stop ty _ upd_in_place) = some_val_args && upd_in_place
 386     interesting (CoerceIt _ cont)        = interesting cont
 387         -- If this call is the arg of a strict function, the context
 388         -- is a bit interesting.  If we inline here, we may get useful
 389         -- evaluation information to avoid repeated evals: e.g.
 390         --      x + (y * z)
 391         -- Here the contIsInteresting makes the '*' keener to inline,
 392         -- which in turn exposes a constructor which makes the '+' inline.
 393         -- Assuming that +,* aren't small enough to inline regardless.
 394         --
 395         -- It's also very important to inline in a strict context for things
 396         -- like
 397         --              foldr k z (f x)
 398         -- Here, the context of (f x) is strict, and if f's unfolding is
 399         -- a build it's *great* to inline it here.  So we must ensure that
 400         -- the context for (f x) is not totally uninteresting.
 401
 402
 403 -------------------
 404 canUpdateInPlace :: Type -> Bool
 405 -- Consider   let x = <wurble> in ...
 406 -- If <wurble> returns an explicit constructor, we might be able
 407 -- to do update in place.  So we treat even a thunk RHS context
 408 -- as interesting if update in place is possible.  We approximate
 409 -- this by seeing if the type has a single constructor with a
 410 -- small arity.  But arity zero isn't good -- we share the single copy
 411 -- for that case, so no point in sharing.
 412
 413 canUpdateInPlace ty
 414   | not opt_UF_UpdateInPlace = False
 415   | otherwise
 416   = case splitTyConApp_maybe ty of
 417         Nothing         -> False
 418         Just (tycon, _) -> case tyConDataCons_maybe tycon of
 419                                 Just [dc]  -> arity == 1 || arity == 2
 420                                            where
 421                                               arity = dataConRepArity dc
 422                                 other -> False
 423 \end{code}
 424
 425
 426
 427 %************************************************************************
 428 %*                                                                      *
 429 \subsection{Decisions about inlining}
 430 %*                                                                      *
 431 %************************************************************************
 432
 433 Inlining is controlled partly by the SimplifierMode switch.  This has two
 434 settings:
 435
 436         SimplGently     (a) Simplifying before specialiser/full laziness
 437                         (b) Simplifiying inside INLINE pragma
 438                         (c) Simplifying the LHS of a rule
 439                         (d) Simplifying a GHCi expression or Template
 440                                 Haskell splice
 441
 442         SimplPhase n    Used at all other times
 443
 444 The key thing about SimplGently is that it does no call-site inlining.
 445 Before full laziness we must be careful not to inline wrappers,
 446 because doing so inhibits floating
 447     e.g. ...(case f x of ...)...
 448     ==> ...(case (case x of I# x# -> fw x#) of ...)...
 449     ==> ...(case x of I# x# -> case fw x# of ...)...
 450 and now the redex (f x) isn't floatable any more.
 451
 452 The no-inling thing is also important for Template Haskell.  You might be
 453 compiling in one-shot mode with -O2; but when TH compiles a splice before
 454 running it, we don't want to use -O2.  Indeed, we don't want to inline
 455 anything, because the byte-code interpreter might get confused about
 456 unboxed tuples and suchlike.
 457
 458 INLINE pragmas
 459 ~~~~~~~~~~~~~~
 460 SimplGently is also used as the mode to simplify inside an InlineMe note.
 461
 462 \begin{code}
 463 inlineMode :: SimplifierMode
 464 inlineMode = SimplGently
 465 \end{code}
 466
 467 It really is important to switch off inlinings inside such
 468 expressions.  Consider the following example
 469
 470         let f = \pq -> BIG
 471         in
 472         let g = \y -> f y y
 473             {-# INLINE g #-}
 474         in ...g...g...g...g...g...
 475
 476 Now, if that's the ONLY occurrence of f, it will be inlined inside g,
 477 and thence copied multiple times when g is inlined.
 478
 479
 480 This function may be inlinined in other modules, so we
 481 don't want to remove (by inlining) calls to functions that have
 482 specialisations, or that may have transformation rules in an importing
 483 scope.
 484
 485 E.g.    {-# INLINE f #-}
 486                 f x = ...g...
 487
 488 and suppose that g is strict *and* has specialisations.  If we inline
 489 g's wrapper, we deny f the chance of getting the specialised version
 490 of g when f is inlined at some call site (perhaps in some other
 491 module).
 492
 493 It's also important not to inline a worker back into a wrapper.
 494 A wrapper looks like
 495         wraper = inline_me (\x -> ...worker... )
 496 Normally, the inline_me prevents the worker getting inlined into
 497 the wrapper (initially, the worker's only call site!).  But,
 498 if the wrapper is sure to be called, the strictness analyser will
 499 mark it 'demanded', so when the RHS is simplified, it'll get an ArgOf
 500 continuation.  That's why the keep_inline predicate returns True for
 501 ArgOf continuations.  It shouldn't do any harm not to dissolve the
 502 inline-me note under these circumstances.
 503
 504 Note that the result is that we do very little simplification
 505 inside an InlineMe.
 506
 507         all xs = foldr (&&) True xs
 508         any p = all . map p  {-# INLINE any #-}
 509
 510 Problem: any won't get deforested, and so if it's exported and the
 511 importer doesn't use the inlining, (eg passes it as an arg) then we
 512 won't get deforestation at all.  We havn't solved this problem yet!
 513
 514
 515 preInlineUnconditionally
 516 ~~~~~~~~~~~~~~~~~~~~~~~~
 517 @preInlineUnconditionally@ examines a bndr to see if it is used just
 518 once in a completely safe way, so that it is safe to discard the
 519 binding inline its RHS at the (unique) usage site, REGARDLESS of how
 520 big the RHS might be.  If this is the case we don't simplify the RHS
 521 first, but just inline it un-simplified.
 522
 523 This is much better than first simplifying a perhaps-huge RHS and then
 524 inlining and re-simplifying it.  Indeed, it can be at least quadratically
 525 better.  Consider
 526
 527         x1 = e1
 528         x2 = e2[x1]
 529         x3 = e3[x2]
 530         ...etc...
 531         xN = eN[xN-1]
 532
 533 We may end up simplifying e1 N times, e2 N-1 times, e3 N-3 times etc.
 534
 535 NB: we don't even look at the RHS to see if it's trivial
 536 We might have
 537                         x = y
 538 where x is used many times, but this is the unique occurrence of y.
 539 We should NOT inline x at all its uses, because then we'd do the same
 540 for y -- aargh!  So we must base this pre-rhs-simplification decision
 541 solely on x's occurrences, not on its rhs.
 542
 543 Evne RHSs labelled InlineMe aren't caught here, because there might be
 544 no benefit from inlining at the call site.
 545
 546 [Sept 01] Don't unconditionally inline a top-level thing, because that
 547 can simply make a static thing into something built dynamically.  E.g.
 548         x = (a,b)
 549         main = \s -> h x
 550
 551 [Remember that we treat \s as a one-shot lambda.]  No point in
 552 inlining x unless there is something interesting about the call site.
 553
 554 But watch out: if you aren't careful, some useful foldr/build fusion
 555 can be lost (most notably in spectral/hartel/parstof) because the
 556 foldr didn't see the build.  Doing the dynamic allocation isn't a big
 557 deal, in fact, but losing the fusion can be.  But the right thing here
 558 seems to be to do a callSiteInline based on the fact that there is
 559 something interesting about the call site (it's strict).  Hmm.  That
 560 seems a bit fragile.
 561
 562 Conclusion: inline top level things gaily until Phase 0 (the last
 563 phase), at which point don't.
 564
 565 \begin{code}
 566 preInlineUnconditionally :: SimplEnv -> TopLevelFlag -> InId -> Bool
 567 preInlineUnconditionally env top_lvl bndr
 568   | isTopLevel top_lvl, SimplPhase 0 <- phase = False
 569 -- If we don't have this test, consider
 570 --      x = length [1,2,3]
 571 -- The full laziness pass carefully floats all the cons cells to
 572 -- top level, and preInlineUnconditionally floats them all back in.
 573 -- Result is (a) static allocation replaced by dynamic allocation
 574 --           (b) many simplifier iterations because this tickles
 575 --               a related problem; only one inlining per pass
 576 --
 577 -- On the other hand, I have seen cases where top-level fusion is
 578 -- lost if we don't inline top level thing (e.g. string constants)
 579 -- Hence the test for phase zero (which is the phase for all the final
 580 -- simplifications).  Until phase zero we take no special notice of
 581 -- top level things, but then we become more leery about inlining
 582 -- them.
 583
 584   | not active             = False
 585   | opt_SimplNoPreInlining = False
 586   | otherwise = case idOccInfo bndr of
 587                   IAmDead            -> True    -- Happens in ((\x.1) v)
 588                   OneOcc in_lam once -> not in_lam && once
 589                         -- Not inside a lambda, one occurrence ==> safe!
 590                   other              -> False
 591   where
 592     phase = getMode env
 593     active = case phase of
 594                    SimplGently  -> isAlwaysActive prag
 595                    SimplPhase n -> isActive n prag
 596     prag = idInlinePragma bndr
 597 \end{code}
 598
 599 postInlineUnconditionally
 600 ~~~~~~~~~~~~~~~~~~~~~~~~~
 601 @postInlineUnconditionally@ decides whether to unconditionally inline
 602 a thing based on the form of its RHS; in particular if it has a
 603 trivial RHS.  If so, we can inline and discard the binding altogether.
 604
 605 NB: a loop breaker has must_keep_binding = True and non-loop-breakers
 606 only have *forward* references Hence, it's safe to discard the binding
 607
 608 NOTE: This isn't our last opportunity to inline.  We're at the binding
 609 site right now, and we'll get another opportunity when we get to the
 610 ocurrence(s)
 611
 612 Note that we do this unconditional inlining only for trival RHSs.
 613 Don't inline even WHNFs inside lambdas; doing so may simply increase
 614 allocation when the function is called. This isn't the last chance; see
 615 NOTE above.
 616
 617 NB: Even inline pragmas (e.g. IMustBeINLINEd) are ignored here Why?
 618 Because we don't even want to inline them into the RHS of constructor
 619 arguments. See NOTE above
 620
 621 NB: At one time even NOINLINE was ignored here: if the rhs is trivial
 622 it's best to inline it anyway.  We often get a=E; b=a from desugaring,
 623 with both a and b marked NOINLINE.  But that seems incompatible with
 624 our new view that inlining is like a RULE, so I'm sticking to the 'active'
 625 story for now.
 626
 627 \begin{code}
 628 postInlineUnconditionally :: SimplEnv -> OutId -> OccInfo -> OutExpr -> Bool
 629 postInlineUnconditionally env bndr occ_info rhs
 630   =  exprIsTrivial rhs
 631   && active
 632   && not (isLoopBreaker occ_info)
 633   && not (isExportedId bndr)
 634         -- We used to have (isOneOcc occ_info) instead of
 635         -- not (isLoopBreaker occ_info) && not (isExportedId bndr)
 636         -- That was because a rather fragile use of rules got confused
 637         -- if you inlined even a binding f=g  e.g. We used to have
 638         --      map = mapList
 639         -- But now a more precise use of phases has eliminated this problem,
 640         -- so the is_active test will do the job.  I think.
 641         --
 642         -- OLD COMMENT: (delete soon)
 643         -- Indeed, you might suppose that
 644         -- there is nothing wrong with substituting for a trivial RHS, even
 645         -- if it occurs many times.  But consider
 646         --      x = y
 647         --      h = _inline_me_ (...x...)
 648         -- Here we do *not* want to have x inlined, even though the RHS is
 649         -- trivial, becuase the contract for an INLINE pragma is "no inlining".
 650         -- This is important in the rules for the Prelude
 651   where
 652     active = case getMode env of
 653                    SimplGently  -> isAlwaysActive prag
 654                    SimplPhase n -> isActive n prag
 655     prag = idInlinePragma bndr
 656
 657 activeInline :: SimplEnv -> OutId -> OccInfo -> Bool
 658 activeInline env id occ
 659   = case getMode env of
 660       SimplGently -> isOneOcc occ && isAlwaysActive prag
 661         -- No inlining at all when doing gentle stuff,
 662         -- except for local things that occur once
 663         -- The reason is that too little clean-up happens if you
 664         -- don't inline use-once things.   Also a bit of inlining is *good* for
 665         -- full laziness; it can expose constant sub-expressions.
 666         -- Example in spectral/mandel/Mandel.hs, where the mandelset
 667         -- function gets a useful let-float if you inline windowToViewport
 668
 669         -- NB: we used to have a second exception, for data con wrappers.
 670         -- On the grounds that we use gentle mode for rule LHSs, and
 671         -- they match better when data con wrappers are inlined.
 672         -- But that only really applies to the trivial wrappers (like (:)),
 673         -- and they are now constructed as Compulsory unfoldings (in MkId)
 674         -- so they'll happen anyway.
 675
 676       SimplPhase n -> isActive n prag
 677   where
 678     prag = idInlinePragma id
 679
 680 activeRule :: SimplEnv -> Maybe (Activation -> Bool)
 681 -- Nothing => No rules at all
 682 activeRule env
 683   | opt_RulesOff = Nothing
 684   | otherwise
 685   = case getMode env of
 686         SimplGently  -> Just isAlwaysActive
 687                         -- Used to be Nothing (no rules in gentle mode)
 688                         -- Main motivation for changing is that I wanted
 689                         --      lift String ===> ...
 690                         -- to work in Template Haskell when simplifying
 691                         -- splices, so we get simpler code for literal strings
 692         SimplPhase n -> Just (isActive n)
 693 \end{code}
 694
 695
 696 %************************************************************************
 697 %*                                                                      *
 698 \subsection{Rebuilding a lambda}
 699 %*                                                                      *
 700 %************************************************************************
 701
 702 \begin{code}
 703 mkLam :: SimplEnv -> [OutBinder] -> OutExpr -> SimplCont -> SimplM FloatsWithExpr
 704 \end{code}
 705
 706 Try three things
 707         a) eta reduction, if that gives a trivial expression
 708         b) eta expansion [only if there are some value lambdas]
 709         c) floating lets out through big lambdas
 710                 [only if all tyvar lambdas, and only if this lambda
 711                  is the RHS of a let]
 712
 713 \begin{code}
 714 mkLam env bndrs body cont
 715  = getDOptsSmpl  `thenSmpl` \dflags ->
 716    mkLam' dflags env bndrs body cont
 717  where
 718  mkLam' dflags env bndrs body cont
 719    | dopt Opt_DoEtaReduction dflags,
 720      Just etad_lam <- tryEtaReduce bndrs body
 721    = tick (EtaReduction (head bndrs))   `thenSmpl_`
 722      returnSmpl (emptyFloats env, etad_lam)
 723
 724    | dopt Opt_DoLambdaEtaExpansion dflags,
 725      any isRuntimeVar bndrs
 726    = tryEtaExpansion body               `thenSmpl` \ body' ->
 727      returnSmpl (emptyFloats env, mkLams bndrs body')
 728
 729 {-      Sept 01: I'm experimenting with getting the
 730         full laziness pass to float out past big lambdsa
 731  | all isTyVar bndrs,   -- Only for big lambdas
 732    contIsRhs cont       -- Only try the rhs type-lambda floating
 733                         -- if this is indeed a right-hand side; otherwise
 734                         -- we end up floating the thing out, only for float-in
 735                         -- to float it right back in again!
 736  = tryRhsTyLam env bndrs body           `thenSmpl` \ (floats, body') ->
 737    returnSmpl (floats, mkLams bndrs body')
 738 -}
 739
 740    | otherwise
 741    = returnSmpl (emptyFloats env, mkLams bndrs body)
 742 \end{code}
 743
 744
 745 %************************************************************************
 746 %*                                                                      *
 747 \subsection{Eta expansion and reduction}
 748 %*                                                                      *
 749 %************************************************************************
 750
 751 We try for eta reduction here, but *only* if we get all the
 752 way to an exprIsTrivial expression.
 753 We don't want to remove extra lambdas unless we are going
 754 to avoid allocating this thing altogether
 755
 756 \begin{code}
 757 tryEtaReduce :: [OutBinder] -> OutExpr -> Maybe OutExpr
 758 tryEtaReduce bndrs body
 759         -- We don't use CoreUtils.etaReduce, because we can be more
 760         -- efficient here:
 761         --  (a) we already have the binders
 762         --  (b) we can do the triviality test before computing the free vars
 763   = go (reverse bndrs) body
 764   where
 765     go (b : bs) (App fun arg) | ok_arg b arg = go bs fun        -- Loop round
 766     go []       fun           | ok_fun fun   = Just fun         -- Success!
 767     go _        _                            = Nothing          -- Failure!
 768
 769     ok_fun fun =  exprIsTrivial fun
 770                && not (any (`elemVarSet` (exprFreeVars fun)) bndrs)
 771                && (exprIsValue fun || all ok_lam bndrs)
 772     ok_lam v = isTyVar v || isDictTy (idType v)
 773         -- The exprIsValue is because eta reduction is not
 774         -- valid in general:  \x. bot  /=  bot
 775         -- So we need to be sure that the "fun" is a value.
 776         --
 777         -- However, we always want to reduce (/\a -> f a) to f
 778         -- This came up in a RULE: foldr (build (/\a -> g a))
 779         --      did not match      foldr (build (/\b -> ...something complex...))
 780         -- The type checker can insert these eta-expanded versions,
 781         -- with both type and dictionary lambdas; hence the slightly
 782         -- ad-hoc isDictTy
 783
 784     ok_arg b arg = varToCoreExpr b `cheapEqExpr` arg
 785 \end{code}
 786
 787
 788         Try eta expansion for RHSs
 789
 790 We go for:
 791    f = \x1..xn -> N  ==>   f = \x1..xn y1..ym -> N y1..ym
 792                                  (n >= 0)
 793
 794 where (in both cases)
 795
 796         * The xi can include type variables
 797
 798         * The yi are all value variables
 799
 800         * N is a NORMAL FORM (i.e. no redexes anywhere)
 801           wanting a suitable number of extra args.
 802
 803 We may have to sandwich some coerces between the lambdas
 804 to make the types work.   exprEtaExpandArity looks through coerces
 805 when computing arity; and etaExpand adds the coerces as necessary when
 806 actually computing the expansion.
 807
 808 \begin{code}
 809 tryEtaExpansion :: OutExpr -> SimplM OutExpr
 810 -- There is at least one runtime binder in the binders
 811 tryEtaExpansion body
 812   = getUniquesSmpl                      `thenSmpl` \ us ->
 813     returnSmpl (etaExpand fun_arity us body (exprType body))
 814   where
 815     fun_arity = exprEtaExpandArity body
 816 \end{code}
 817
 818
 819 %************************************************************************
 820 %*                                                                      *
 821 \subsection{Floating lets out of big lambdas}
 822 %*                                                                      *
 823 %************************************************************************
 824
 825 tryRhsTyLam tries this transformation, when the big lambda appears as
 826 the RHS of a let(rec) binding:
 827
 828         /\abc -> let(rec) x = e in b
 829    ==>
 830         let(rec) x' = /\abc -> let x = x' a b c in e
 831         in
 832         /\abc -> let x = x' a b c in b
 833
 834 This is good because it can turn things like:
 835
 836         let f = /\a -> letrec g = ... g ... in g
 837 into
 838         letrec g' = /\a -> ... g' a ...
 839         in
 840         let f = /\ a -> g' a
 841
 842 which is better.  In effect, it means that big lambdas don't impede
 843 let-floating.
 844
 845 This optimisation is CRUCIAL in eliminating the junk introduced by
 846 desugaring mutually recursive definitions.  Don't eliminate it lightly!
 847
 848 So far as the implementation is concerned:
 849
 850         Invariant: go F e = /\tvs -> F e
 851
 852         Equalities:
 853                 go F (Let x=e in b)
 854                 = Let x' = /\tvs -> F e
 855                   in
 856                   go G b
 857                 where
 858                     G = F . Let x = x' tvs
 859
 860                 go F (Letrec xi=ei in b)
 861                 = Letrec {xi' = /\tvs -> G ei}
 862                   in
 863                   go G b
 864                 where
 865                   G = F . Let {xi = xi' tvs}
 866
 867 [May 1999]  If we do this transformation *regardless* then we can
 868 end up with some pretty silly stuff.  For example,
 869
 870         let
 871             st = /\ s -> let { x1=r1 ; x2=r2 } in ...
 872         in ..
 873 becomes
 874         let y1 = /\s -> r1
 875             y2 = /\s -> r2
 876             st = /\s -> ...[y1 s/x1, y2 s/x2]
 877         in ..
 878
 879 Unless the "..." is a WHNF there is really no point in doing this.
 880 Indeed it can make things worse.  Suppose x1 is used strictly,
 881 and is of the form
 882
 883         x1* = case f y of { (a,b) -> e }
 884
 885 If we abstract this wrt the tyvar we then can't do the case inline
 886 as we would normally do.
 887
 888
 889 \begin{code}
 890 {-      Trying to do this in full laziness
 891
 892 tryRhsTyLam :: SimplEnv -> [OutTyVar] -> OutExpr -> SimplM FloatsWithExpr
 893 -- Call ensures that all the binders are type variables
 894
 895 tryRhsTyLam env tyvars body             -- Only does something if there's a let
 896   |  not (all isTyVar tyvars)
 897   || not (worth_it body)                -- inside a type lambda,
 898   = returnSmpl (emptyFloats env, body)  -- and a WHNF inside that
 899
 900   | otherwise
 901   = go env (\x -> x) body
 902
 903   where
 904     worth_it e@(Let _ _) = whnf_in_middle e
 905     worth_it e           = False
 906
 907     whnf_in_middle (Let (NonRec x rhs) e) | isUnLiftedType (idType x) = False
 908     whnf_in_middle (Let _ e) = whnf_in_middle e
 909     whnf_in_middle e         = exprIsCheap e
 910
 911     main_tyvar_set = mkVarSet tyvars
 912
 913     go env fn (Let bind@(NonRec var rhs) body)
 914       | exprIsTrivial rhs
 915       = go env (fn . Let bind) body
 916
 917     go env fn (Let (NonRec var rhs) body)
 918       = mk_poly tyvars_here var                                                 `thenSmpl` \ (var', rhs') ->
 919         addAuxiliaryBind env (NonRec var' (mkLams tyvars_here (fn rhs)))        $ \ env ->
 920         go env (fn . Let (mk_silly_bind var rhs')) body
 921
 922       where
 923
 924         tyvars_here = varSetElems (main_tyvar_set `intersectVarSet` exprSomeFreeVars isTyVar rhs)
 925                 -- Abstract only over the type variables free in the rhs
 926                 -- wrt which the new binding is abstracted.  But the naive
 927                 -- approach of abstract wrt the tyvars free in the Id's type
 928                 -- fails. Consider:
 929                 --      /\ a b -> let t :: (a,b) = (e1, e2)
 930                 --                    x :: a     = fst t
 931                 --                in ...
 932                 -- Here, b isn't free in x's type, but we must nevertheless
 933                 -- abstract wrt b as well, because t's type mentions b.
 934                 -- Since t is floated too, we'd end up with the bogus:
 935                 --      poly_t = /\ a b -> (e1, e2)
 936                 --      poly_x = /\ a   -> fst (poly_t a *b*)
 937                 -- So for now we adopt the even more naive approach of
 938                 -- abstracting wrt *all* the tyvars.  We'll see if that
 939                 -- gives rise to problems.   SLPJ June 98
 940
 941     go env fn (Let (Rec prs) body)
 942        = mapAndUnzipSmpl (mk_poly tyvars_here) vars     `thenSmpl` \ (vars', rhss') ->
 943          let
 944             gn body = fn (foldr Let body (zipWith mk_silly_bind vars rhss'))
 945             pairs   = vars' `zip` [mkLams tyvars_here (gn rhs) | rhs <- rhss]
 946          in
 947          addAuxiliaryBind env (Rec pairs)               $ \ env ->
 948          go env gn body
 949        where
 950          (vars,rhss) = unzip prs
 951          tyvars_here = varSetElems (main_tyvar_set `intersectVarSet` exprsSomeFreeVars isTyVar (map snd prs))
 952                 -- See notes with tyvars_here above
 953
 954     go env fn body = returnSmpl (emptyFloats env, fn body)
 955
 956     mk_poly tyvars_here var
 957       = getUniqueSmpl           `thenSmpl` \ uniq ->
 958         let
 959             poly_name = setNameUnique (idName var) uniq         -- Keep same name
 960             poly_ty   = mkForAllTys tyvars_here (idType var)    -- But new type of course
 961             poly_id   = mkLocalId poly_name poly_ty
 962
 963                 -- In the olden days, it was crucial to copy the occInfo of the original var,
 964                 -- because we were looking at occurrence-analysed but as yet unsimplified code!
 965                 -- In particular, we mustn't lose the loop breakers.  BUT NOW we are looking
 966                 -- at already simplified code, so it doesn't matter
 967                 --
 968                 -- It's even right to retain single-occurrence or dead-var info:
 969                 -- Suppose we started with  /\a -> let x = E in B
 970                 -- where x occurs once in B. Then we transform to:
 971                 --      let x' = /\a -> E in /\a -> let x* = x' a in B
 972                 -- where x* has an INLINE prag on it.  Now, once x* is inlined,
 973                 -- the occurrences of x' will be just the occurrences originally
 974                 -- pinned on x.
 975         in
 976         returnSmpl (poly_id, mkTyApps (Var poly_id) (mkTyVarTys tyvars_here))
 977
 978     mk_silly_bind var rhs = NonRec var (Note InlineMe rhs)
 979                 -- Suppose we start with:
 980                 --
 981                 --      x = /\ a -> let g = G in E
 982                 --
 983                 -- Then we'll float to get
 984                 --
 985                 --      x = let poly_g = /\ a -> G
 986                 --          in /\ a -> let g = poly_g a in E
 987                 --
 988                 -- But now the occurrence analyser will see just one occurrence
 989                 -- of poly_g, not inside a lambda, so the simplifier will
 990                 -- PreInlineUnconditionally poly_g back into g!  Badk to square 1!
 991                 -- (I used to think that the "don't inline lone occurrences" stuff
 992                 --  would stop this happening, but since it's the *only* occurrence,
 993                 --  PreInlineUnconditionally kicks in first!)
 994                 --
 995                 -- Solution: put an INLINE note on g's RHS, so that poly_g seems
 996                 --           to appear many times.  (NB: mkInlineMe eliminates
 997                 --           such notes on trivial RHSs, so do it manually.)
 998 -}
 999 \end{code}
1000
1001 %************************************************************************
1002 %*                                                                      *
1003 \subsection{Case alternative filtering
1004 %*                                                                      *
1005 %************************************************************************
1006
1007 prepareAlts does two things:
1008
1009 1.  Eliminate alternatives that cannot match, including the
1010     DEFAULT alternative.
1011
1012 2.  If the DEFAULT alternative can match only one possible constructor,
1013     then make that constructor explicit.
1014     e.g.
1015         case e of x { DEFAULT -> rhs }
1016      ===>
1017         case e of x { (a,b) -> rhs }
1018     where the type is a single constructor type.  This gives better code
1019     when rhs also scrutinises x or e.
1020
1021 It's a good idea do do this stuff before simplifying the alternatives, to
1022 avoid simplifying alternatives we know can't happen, and to come up with
1023 the list of constructors that are handled, to put into the IdInfo of the
1024 case binder, for use when simplifying the alternatives.
1025
1026 Eliminating the default alternative in (1) isn't so obvious, but it can
1027 happen:
1028
1029 data Colour = Red | Green | Blue
1030
1031 f x = case x of
1032         Red -> ..
1033         Green -> ..
1034         DEFAULT -> h x
1035
1036 h y = case y of
1037         Blue -> ..
1038         DEFAULT -> [ case y of ... ]
1039
1040 If we inline h into f, the default case of the inlined h can't happen.
1041 If we don't notice this, we may end up filtering out *all* the cases
1042 of the inner case y, which give us nowhere to go!
1043
1044
1045 \begin{code}
1046 prepareAlts :: OutExpr          -- Scrutinee
1047             -> InId             -- Case binder
1048             -> [InAlt]          -- Increasing order
1049             -> SimplM ([InAlt],         -- Better alternatives, still incresaing order
1050                         [AltCon])       -- These cases are handled
1051
1052 prepareAlts scrut case_bndr alts
1053   = let
1054         (alts_wo_default, maybe_deflt) = findDefault alts
1055
1056         impossible_cons = case scrut of
1057                             Var v -> otherCons (idUnfolding v)
1058                             other -> []
1059
1060         -- Filter out alternatives that can't possibly match
1061         better_alts | null impossible_cons = alts_wo_default
1062                     | otherwise            = [alt | alt@(con,_,_) <- alts_wo_default,
1063                                                     not (con `elem` impossible_cons)]
1064
1065         -- "handled_cons" are handled either by the context,
1066         -- or by a branch in this case expression
1067         -- (Don't add DEFAULT to the handled_cons!!)
1068         handled_cons = impossible_cons ++ [con | (con,_,_) <- better_alts]
1069     in
1070         -- Filter out the default, if it can't happen,
1071         -- or replace it with "proper" alternative if there
1072         -- is only one constructor left
1073     prepareDefault case_bndr handled_cons maybe_deflt   `thenSmpl` \ deflt_alt ->
1074
1075     returnSmpl (mergeAlts better_alts deflt_alt, handled_cons)
1076         -- We need the mergeAlts in case the new default_alt
1077         -- has turned into a constructor alternative.
1078
1079 prepareDefault case_bndr handled_cons (Just rhs)
1080   | Just (tycon, inst_tys) <- splitTyConApp_maybe (idType case_bndr),
1081     isAlgTyCon tycon,           -- It's a data type, tuple, or unboxed tuples.
1082     not (isNewTyCon tycon),     -- We can have a newtype, if we are just doing an eval:
1083                                 --      case x of { DEFAULT -> e }
1084                                 -- and we don't want to fill in a default for them!
1085     Just all_cons <- tyConDataCons_maybe tycon,
1086     not (null all_cons),        -- This is a tricky corner case.  If the data type has no constructors,
1087                                 -- which GHC allows, then the case expression will have at most a default
1088                                 -- alternative.  We don't want to eliminate that alternative, because the
1089                                 -- invariant is that there's always one alternative.  It's more convenient
1090                                 -- to leave
1091                                 --      case x of { DEFAULT -> e }
1092                                 -- as it is, rather than transform it to
1093                                 --      error "case cant match"
1094                                 -- which would be quite legitmate.  But it's a really obscure corner, and
1095                                 -- not worth wasting code on.
1096     let handled_data_cons = [data_con | DataAlt data_con <- handled_cons],
1097     let missing_cons      = [con | con <- all_cons,
1098                                    not (con `elem` handled_data_cons)]
1099   = case missing_cons of
1100         []          -> returnSmpl []    -- Eliminate the default alternative
1101                                         -- if it can't match
1102
1103         [con]       ->  -- It matches exactly one constructor, so fill it in
1104                        tick (FillInCaseDefault case_bndr)       `thenSmpl_`
1105                        mk_args con inst_tys                     `thenSmpl` \ args ->
1106                        returnSmpl [(DataAlt con, args, rhs)]
1107
1108         two_or_more -> returnSmpl [(DEFAULT, [], rhs)]
1109
1110   | otherwise
1111   = returnSmpl [(DEFAULT, [], rhs)]
1112
1113 prepareDefault case_bndr handled_cons Nothing
1114   = returnSmpl []
1115
1116 mk_args missing_con inst_tys
1117   = mk_tv_bndrs missing_con inst_tys    `thenSmpl` \ (tv_bndrs, inst_tys') ->
1118     getUniquesSmpl                      `thenSmpl` \ id_uniqs ->
1119     let arg_tys = dataConArgTys missing_con inst_tys'
1120         arg_ids = zipWith (mkSysLocal FSLIT("a")) id_uniqs arg_tys
1121     in
1122     returnSmpl (tv_bndrs ++ arg_ids)
1123
1124 mk_tv_bndrs missing_con inst_tys
1125   | isVanillaDataCon missing_con
1126   = returnSmpl ([], inst_tys)
1127   | otherwise
1128   = getUniquesSmpl              `thenSmpl` \ tv_uniqs ->
1129     let new_tvs    = zipWith mk tv_uniqs (dataConTyVars missing_con)
1130         mk uniq tv = mkTyVar (mkSysTvName uniq FSLIT("t")) (tyVarKind tv)
1131     in
1132     returnSmpl (new_tvs, mkTyVarTys new_tvs)
1133 \end{code}
1134
1135
1136 %************************************************************************
1137 %*                                                                      *
1138 \subsection{Case absorption and identity-case elimination}
1139 %*                                                                      *
1140 %************************************************************************
1141
1142 mkCase puts a case expression back together, trying various transformations first.
1143
1144 \begin{code}
1145 mkCase :: OutExpr -> OutId -> OutType
1146        -> [OutAlt]              -- Increasing order
1147        -> SimplM OutExpr
1148
1149 mkCase scrut case_bndr ty alts
1150   = getDOptsSmpl                        `thenSmpl` \dflags ->
1151     mkAlts dflags scrut case_bndr alts  `thenSmpl` \ better_alts ->
1152     mkCase1 scrut case_bndr ty better_alts
1153 \end{code}
1154
1155
1156 mkAlts tries these things:
1157
1158 1.  If several alternatives are identical, merge them into
1159     a single DEFAULT alternative.  I've occasionally seen this
1160     making a big difference:
1161
1162         case e of               =====>     case e of
1163           C _ -> f x                         D v -> ....v....
1164           D v -> ....v....                   DEFAULT -> f x
1165           DEFAULT -> f x
1166
1167    The point is that we merge common RHSs, at least for the DEFAULT case.
1168    [One could do something more elaborate but I've never seen it needed.]
1169    To avoid an expensive test, we just merge branches equal to the *first*
1170    alternative; this picks up the common cases
1171         a) all branches equal
1172         b) some branches equal to the DEFAULT (which occurs first)
1173
1174 2.  Case merging:
1175        case e of b {             ==>   case e of b {
1176          p1 -> rhs1                      p1 -> rhs1
1177          ...                             ...
1178          pm -> rhsm                      pm -> rhsm
1179          _  -> case b of b' {            pn -> let b'=b in rhsn
1180                      pn -> rhsn          ...
1181                      ...                 po -> let b'=b in rhso
1182                      po -> rhso          _  -> let b'=b in rhsd
1183                      _  -> rhsd
1184        }
1185
1186     which merges two cases in one case when -- the default alternative of
1187     the outer case scrutises the same variable as the outer case This
1188     transformation is called Case Merging.  It avoids that the same
1189     variable is scrutinised multiple times.
1190
1191
1192 The case where transformation (1) showed up was like this (lib/std/PrelCError.lhs):
1193
1194         x | p `is` 1 -> e1
1195           | p `is` 2 -> e2
1196         ...etc...
1197
1198 where @is@ was something like
1199
1200         p `is` n = p /= (-1) && p == n
1201
1202 This gave rise to a horrible sequence of cases
1203
1204         case p of
1205           (-1) -> $j p
1206           1    -> e1
1207           DEFAULT -> $j p
1208
1209 and similarly in cascade for all the join points!
1210
1211
1212
1213 \begin{code}
1214 --------------------------------------------------
1215 --      1. Merge identical branches
1216 --------------------------------------------------
1217 mkAlts dflags scrut case_bndr alts@((con1,bndrs1,rhs1) : con_alts)
1218   | all isDeadBinder bndrs1,                    -- Remember the default
1219     length filtered_alts < length con_alts      -- alternative comes first
1220   = tick (AltMerge case_bndr)                   `thenSmpl_`
1221     returnSmpl better_alts
1222   where
1223     filtered_alts        = filter keep con_alts
1224     keep (con,bndrs,rhs) = not (all isDeadBinder bndrs && rhs `cheapEqExpr` rhs1)
1225     better_alts          = (DEFAULT, [], rhs1) : filtered_alts
1226
1227
1228 --------------------------------------------------
1229 --      2.  Merge nested cases
1230 --------------------------------------------------
1231
1232 mkAlts dflags scrut outer_bndr outer_alts
1233   | dopt Opt_CaseMerge dflags,
1234     (outer_alts_without_deflt, maybe_outer_deflt)   <- findDefault outer_alts,
1235     Just (Case (Var scrut_var) inner_bndr _ inner_alts) <- maybe_outer_deflt,
1236     scruting_same_var scrut_var
1237   = let
1238         munged_inner_alts = [(con, args, munge_rhs rhs) | (con, args, rhs) <- inner_alts]
1239         munge_rhs rhs = bindCaseBndr inner_bndr (Var outer_bndr) rhs
1240
1241         new_alts = mergeAlts outer_alts_without_deflt munged_inner_alts
1242                 -- The merge keeps the inner DEFAULT at the front, if there is one
1243                 -- and eliminates any inner_alts that are shadowed by the outer_alts
1244     in
1245     tick (CaseMerge outer_bndr)                         `thenSmpl_`
1246     returnSmpl new_alts
1247         -- Warning: don't call mkAlts recursively!
1248         -- Firstly, there's no point, because inner alts have already had
1249         -- mkCase applied to them, so they won't have a case in their default
1250         -- Secondly, if you do, you get an infinite loop, because the bindCaseBndr
1251         -- in munge_rhs may put a case into the DEFAULT branch!
1252   where
1253         -- We are scrutinising the same variable if it's
1254         -- the outer case-binder, or if the outer case scrutinises a variable
1255         -- (and it's the same).  Testing both allows us not to replace the
1256         -- outer scrut-var with the outer case-binder (Simplify.simplCaseBinder).
1257     scruting_same_var = case scrut of
1258                           Var outer_scrut -> \ v -> v == outer_bndr || v == outer_scrut
1259                           other           -> \ v -> v == outer_bndr
1260
1261 ------------------------------------------------
1262 --      Catch-all
1263 ------------------------------------------------
1264
1265 mkAlts dflags scrut case_bndr other_alts = returnSmpl other_alts
1266
1267
1268 ---------------------------------
1269 mergeAlts :: [OutAlt] -> [OutAlt] -> [OutAlt]
1270 -- Merge preserving order; alternatives in the first arg
1271 -- shadow ones in the second
1272 mergeAlts [] as2 = as2
1273 mergeAlts as1 [] = as1
1274 mergeAlts (a1:as1) (a2:as2)
1275   = case a1 `cmpAlt` a2 of
1276         LT -> a1 : mergeAlts as1      (a2:as2)
1277         EQ -> a1 : mergeAlts as1      as2       -- Discard a2
1278         GT -> a2 : mergeAlts (a1:as1) as2
1279 \end{code}
1280
1281
1282
1283 =================================================================================
1284
1285 mkCase1 tries these things
1286
1287 1.  Eliminate the case altogether if possible
1288
1289 2.  Case-identity:
1290
1291         case e of               ===> e
1292                 True  -> True;
1293                 False -> False
1294
1295     and similar friends.
1296
1297
1298 Start with a simple situation:
1299
1300         case x# of      ===>   e[x#/y#]
1301           y# -> e
1302
1303 (when x#, y# are of primitive type, of course).  We can't (in general)
1304 do this for algebraic cases, because we might turn bottom into
1305 non-bottom!
1306
1307 Actually, we generalise this idea to look for a case where we're
1308 scrutinising a variable, and we know that only the default case can
1309 match.  For example:
1310 \begin{verbatim}
1311         case x of
1312           0#    -> ...
1313           other -> ...(case x of
1314                          0#    -> ...
1315                          other -> ...) ...
1316 \end{code}
1317 Here the inner case can be eliminated.  This really only shows up in
1318 eliminating error-checking code.
1319
1320 We also make sure that we deal with this very common case:
1321
1322         case e of
1323           x -> ...x...
1324
1325 Here we are using the case as a strict let; if x is used only once
1326 then we want to inline it.  We have to be careful that this doesn't
1327 make the program terminate when it would have diverged before, so we
1328 check that
1329         - x is used strictly, or
1330         - e is already evaluated (it may so if e is a variable)
1331
1332 Lastly, we generalise the transformation to handle this:
1333
1334         case e of       ===> r
1335            True  -> r
1336            False -> r
1337
1338 We only do this for very cheaply compared r's (constructors, literals
1339 and variables).  If pedantic bottoms is on, we only do it when the
1340 scrutinee is a PrimOp which can't fail.
1341
1342 We do it *here*, looking at un-simplified alternatives, because we
1343 have to check that r doesn't mention the variables bound by the
1344 pattern in each alternative, so the binder-info is rather useful.
1345
1346 So the case-elimination algorithm is:
1347
1348         1. Eliminate alternatives which can't match
1349
1350         2. Check whether all the remaining alternatives
1351                 (a) do not mention in their rhs any of the variables bound in their pattern
1352            and  (b) have equal rhss
1353
1354         3. Check we can safely ditch the case:
1355                    * PedanticBottoms is off,
1356                 or * the scrutinee is an already-evaluated variable
1357                 or * the scrutinee is a primop which is ok for speculation
1358                         -- ie we want to preserve divide-by-zero errors, and
1359                         -- calls to error itself!
1360
1361                 or * [Prim cases] the scrutinee is a primitive variable
1362
1363                 or * [Alg cases] the scrutinee is a variable and
1364                      either * the rhs is the same variable
1365                         (eg case x of C a b -> x  ===>   x)
1366                      or     * there is only one alternative, the default alternative,
1367                                 and the binder is used strictly in its scope.
1368                                 [NB this is helped by the "use default binder where
1369                                  possible" transformation; see below.]
1370
1371
1372 If so, then we can replace the case with one of the rhss.
1373
1374 Further notes about case elimination
1375 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1376 Consider:       test :: Integer -> IO ()
1377                 test = print
1378
1379 Turns out that this compiles to:
1380     Print.test
1381       = \ eta :: Integer
1382           eta1 :: State# RealWorld ->
1383           case PrelNum.< eta PrelNum.zeroInteger of wild { __DEFAULT ->
1384           case hPutStr stdout
1385                  (PrelNum.jtos eta ($w[] @ Char))
1386                  eta1
1387           of wild1 { (# new_s, a4 #) -> PrelIO.lvl23 new_s  }}
1388
1389 Notice the strange '<' which has no effect at all. This is a funny one.
1390 It started like this:
1391
1392 f x y = if x < 0 then jtos x
1393           else if y==0 then "" else jtos x
1394
1395 At a particular call site we have (f v 1).  So we inline to get
1396
1397         if v < 0 then jtos x
1398         else if 1==0 then "" else jtos x
1399
1400 Now simplify the 1==0 conditional:
1401
1402         if v<0 then jtos v else jtos v
1403
1404 Now common-up the two branches of the case:
1405
1406         case (v<0) of DEFAULT -> jtos v
1407
1408 Why don't we drop the case?  Because it's strict in v.  It's technically
1409 wrong to drop even unnecessary evaluations, and in practice they
1410 may be a result of 'seq' so we *definitely* don't want to drop those.
1411 I don't really know how to improve this situation.
1412
1413
1414 \begin{code}
1415 --------------------------------------------------
1416 --      0. Check for empty alternatives
1417 --------------------------------------------------
1418
1419 #ifdef DEBUG
1420 mkCase1 scrut case_bndr ty []
1421   = pprTrace "mkCase1: null alts" (ppr case_bndr <+> ppr scrut) $
1422     returnSmpl scrut
1423 #endif
1424
1425 --------------------------------------------------
1426 --      1. Eliminate the case altogether if poss
1427 --------------------------------------------------
1428
1429 mkCase1 scrut case_bndr ty [(con,bndrs,rhs)]
1430   -- See if we can get rid of the case altogether
1431   -- See the extensive notes on case-elimination above
1432   -- mkCase made sure that if all the alternatives are equal,
1433   -- then there is now only one (DEFAULT) rhs
1434  |  all isDeadBinder bndrs,
1435
1436         -- Check that the scrutinee can be let-bound instead of case-bound
1437     exprOkForSpeculation scrut
1438                 -- OK not to evaluate it
1439                 -- This includes things like (==# a# b#)::Bool
1440                 -- so that we simplify
1441                 --      case ==# a# b# of { True -> x; False -> x }
1442                 -- to just
1443                 --      x
1444                 -- This particular example shows up in default methods for
1445                 -- comparision operations (e.g. in (>=) for Int.Int32)
1446         || exprIsValue scrut                    -- It's already evaluated
1447         || var_demanded_later scrut             -- It'll be demanded later
1448
1449 --      || not opt_SimplPedanticBottoms)        -- Or we don't care!
1450 --      We used to allow improving termination by discarding cases, unless -fpedantic-bottoms was on,
1451 --      but that breaks badly for the dataToTag# primop, which relies on a case to evaluate
1452 --      its argument:  case x of { y -> dataToTag# y }
1453 --      Here we must *not* discard the case, because dataToTag# just fetches the tag from
1454 --      the info pointer.  So we'll be pedantic all the time, and see if that gives any
1455 --      other problems
1456 --      Also we don't want to discard 'seq's
1457   = tick (CaseElim case_bndr)                   `thenSmpl_`
1458     returnSmpl (bindCaseBndr case_bndr scrut rhs)
1459
1460   where
1461         -- The case binder is going to be evaluated later,
1462         -- and the scrutinee is a simple variable
1463     var_demanded_later (Var v) = isStrictDmd (idNewDemandInfo case_bndr)
1464     var_demanded_later other   = False
1465
1466
1467 --------------------------------------------------
1468 --      2. Identity case
1469 --------------------------------------------------
1470
1471 mkCase1 scrut case_bndr ty alts -- Identity case
1472   | all identity_alt alts
1473   = tick (CaseIdentity case_bndr)               `thenSmpl_`
1474     returnSmpl (re_note scrut)
1475   where
1476     identity_alt (con, args, rhs) = de_note rhs `cheapEqExpr` identity_rhs con args
1477
1478     identity_rhs (DataAlt con) args = mkConApp con (arg_tys ++ map varToCoreExpr args)
1479     identity_rhs (LitAlt lit)  _    = Lit lit
1480     identity_rhs DEFAULT       _    = Var case_bndr
1481
1482     arg_tys = map Type (tyConAppArgs (idType case_bndr))
1483
1484         -- We've seen this:
1485         --      case coerce T e of x { _ -> coerce T' x }
1486         -- And we definitely want to eliminate this case!
1487         -- So we throw away notes from the RHS, and reconstruct
1488         -- (at least an approximation) at the other end
1489     de_note (Note _ e) = de_note e
1490     de_note e          = e
1491
1492         -- re_note wraps a coerce if it might be necessary
1493     re_note scrut = case head alts of
1494                         (_,_,rhs1@(Note _ _)) -> mkCoerce2 (exprType rhs1) (idType case_bndr) scrut
1495                         other                 -> scrut
1496
1497
1498 --------------------------------------------------
1499 --      Catch-all
1500 --------------------------------------------------
1501 mkCase1 scrut bndr ty alts = returnSmpl (Case scrut bndr ty alts)
1502 \end{code}
1503
1504
1505 When adding auxiliary bindings for the case binder, it's worth checking if
1506 its dead, because it often is, and occasionally these mkCase transformations
1507 cascade rather nicely.
1508
1509 \begin{code}
1510 bindCaseBndr bndr rhs body
1511   | isDeadBinder bndr = body
1512   | otherwise         = bindNonRec bndr rhs body
1513 \end{code}