ghc/compiler/simplCore/SimplUtils.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[SimplUtils]{The simplifier utilities}
   5
   6 \begin{code}
   7 module SimplUtils (
   8         mkLam, prepareAlts, mkCase,
   9
  10         -- Inlining,
  11         preInlineUnconditionally, postInlineUnconditionally, activeInline, activeRule,
  12         inlineMode,
  13
  14         -- The continuation type
  15         SimplCont(..), DupFlag(..), LetRhsFlag(..),
  16         contIsDupable, contResultType,
  17         countValArgs, countArgs, pushContArgs,
  18         mkBoringStop, mkRhsStop, contIsRhs, contIsRhsOrArg,
  19         getContArgs, interestingCallContext, interestingArg, isStrictType
  20
  21     ) where
  22
  23 #include "HsVersions.h"
  24
  25 import SimplEnv
  26 import DynFlags         ( SimplifierSwitch(..), SimplifierMode(..),
  27                           DynFlag(..), dopt )
  28 import StaticFlags      ( opt_UF_UpdateInPlace, opt_SimplNoPreInlining,
  29                           opt_RulesOff )
  30
  31 import CoreSyn
  32 import CoreFVs          ( exprFreeVars )
  33 import CoreUtils        ( cheapEqExpr, exprType, exprIsTrivial,
  34                           etaExpand, exprEtaExpandArity, bindNonRec, mkCoerce2,
  35                           findDefault, exprOkForSpeculation, exprIsValue
  36                         )
  37 import Id               ( idType, isDataConWorkId, idOccInfo, isDictId, idArity,
  38                           mkSysLocal, isDeadBinder, idNewDemandInfo, isExportedId,
  39                           idUnfolding, idNewStrictness, idInlinePragma,
  40                         )
  41 import NewDemand        ( isStrictDmd, isBotRes, splitStrictSig )
  42 import SimplMonad
  43 import Type             ( Type, splitFunTys, dropForAlls, isStrictType,
  44                           splitTyConApp_maybe, tyConAppArgs, mkTyVarTys
  45                         )
  46 import Name             ( mkSysTvName )
  47 import TyCon            ( tyConDataCons_maybe, isAlgTyCon, isNewTyCon )
  48 import DataCon          ( dataConRepArity, dataConTyVars, dataConArgTys, isVanillaDataCon )
  49 import Var              ( tyVarKind, mkTyVar )
  50 import VarSet
  51 import BasicTypes       ( TopLevelFlag(..), isTopLevel, isNotTopLevel, OccInfo(..), isLoopBreaker, isOneOcc,
  52                           Activation, isAlwaysActive, isActive )
  53 import Util             ( lengthExceeds )
  54 import Outputable
  55 \end{code}
  56
  57
  58 %************************************************************************
  59 %*                                                                      *
  60 \subsection{The continuation data type}
  61 %*                                                                      *
  62 %************************************************************************
  63
  64 \begin{code}
  65 data SimplCont          -- Strict contexts
  66   = Stop     OutType            -- Type of the result
  67              LetRhsFlag
  68              Bool               -- True <=> This is the RHS of a thunk whose type suggests
  69                                 --          that update-in-place would be possible
  70                                 --          (This makes the inliner a little keener.)
  71
  72   | CoerceIt OutType                    -- The To-type, simplified
  73              SimplCont
  74
  75   | InlinePlease                        -- This continuation makes a function very
  76              SimplCont                  -- keen to inline itelf
  77
  78   | ApplyTo  DupFlag
  79              InExpr SimplEnv            -- The argument, as yet unsimplified,
  80              SimplCont                  -- and its environment
  81
  82   | Select   DupFlag
  83              InId [InAlt] SimplEnv      -- The case binder, alts, and subst-env
  84              SimplCont
  85
  86   | ArgOf    LetRhsFlag         -- An arbitrary strict context: the argument
  87                                 --      of a strict function, or a primitive-arg fn
  88                                 --      or a PrimOp
  89                                 -- No DupFlag because we never duplicate it
  90              OutType            -- arg_ty: type of the argument itself
  91              OutType            -- cont_ty: the type of the expression being sought by the context
  92                                 --      f (error "foo") ==> coerce t (error "foo")
  93                                 -- when f is strict
  94                                 -- We need to know the type t, to which to coerce.
  95
  96              (SimplEnv -> OutExpr -> SimplM FloatsWithExpr)     -- What to do with the result
  97                                 -- The result expression in the OutExprStuff has type cont_ty
  98
  99 data LetRhsFlag = AnArg         -- It's just an argument not a let RHS
 100                 | AnRhs         -- It's the RHS of a let (so please float lets out of big lambdas)
 101
 102 instance Outputable LetRhsFlag where
 103   ppr AnArg = ptext SLIT("arg")
 104   ppr AnRhs = ptext SLIT("rhs")
 105
 106 instance Outputable SimplCont where
 107   ppr (Stop _ is_rhs _)              = ptext SLIT("Stop") <> brackets (ppr is_rhs)
 108   ppr (ApplyTo dup arg se cont)      = (ptext SLIT("ApplyTo") <+> ppr dup <+> ppr arg) $$ ppr cont
 109   ppr (ArgOf _ _ _ _)                = ptext SLIT("ArgOf...")
 110   ppr (Select dup bndr alts se cont) = (ptext SLIT("Select") <+> ppr dup <+> ppr bndr) $$
 111                                        (nest 4 (ppr alts)) $$ ppr cont
 112   ppr (CoerceIt ty cont)             = (ptext SLIT("CoerceIt") <+> ppr ty) $$ ppr cont
 113   ppr (InlinePlease cont)            = ptext SLIT("InlinePlease") $$ ppr cont
 114
 115 data DupFlag = OkToDup | NoDup
 116
 117 instance Outputable DupFlag where
 118   ppr OkToDup = ptext SLIT("ok")
 119   ppr NoDup   = ptext SLIT("nodup")
 120
 121
 122 -------------------
 123 mkBoringStop, mkRhsStop :: OutType -> SimplCont
 124 mkBoringStop ty = Stop ty AnArg (canUpdateInPlace ty)
 125 mkRhsStop    ty = Stop ty AnRhs (canUpdateInPlace ty)
 126
 127 contIsRhs :: SimplCont -> Bool
 128 contIsRhs (Stop _ AnRhs _)    = True
 129 contIsRhs (ArgOf AnRhs _ _ _) = True
 130 contIsRhs other               = False
 131
 132 contIsRhsOrArg (Stop _ _ _)    = True
 133 contIsRhsOrArg (ArgOf _ _ _ _) = True
 134 contIsRhsOrArg other           = False
 135
 136 -------------------
 137 contIsDupable :: SimplCont -> Bool
 138 contIsDupable (Stop _ _ _)               = True
 139 contIsDupable (ApplyTo  OkToDup _ _ _)   = True
 140 contIsDupable (Select   OkToDup _ _ _ _) = True
 141 contIsDupable (CoerceIt _ cont)          = contIsDupable cont
 142 contIsDupable (InlinePlease cont)        = contIsDupable cont
 143 contIsDupable other                      = False
 144
 145 -------------------
 146 discardableCont :: SimplCont -> Bool
 147 discardableCont (Stop _ _ _)        = False
 148 discardableCont (CoerceIt _ cont)   = discardableCont cont
 149 discardableCont (InlinePlease cont) = discardableCont cont
 150 discardableCont other               = True
 151
 152 discardCont :: SimplCont        -- A continuation, expecting
 153             -> SimplCont        -- Replace the continuation with a suitable coerce
 154 discardCont cont = case cont of
 155                      Stop to_ty is_rhs _ -> cont
 156                      other               -> CoerceIt to_ty (mkBoringStop to_ty)
 157                  where
 158                    to_ty = contResultType cont
 159
 160 -------------------
 161 contResultType :: SimplCont -> OutType
 162 contResultType (Stop to_ty _ _)      = to_ty
 163 contResultType (ArgOf _ _ to_ty _)   = to_ty
 164 contResultType (ApplyTo _ _ _ cont)  = contResultType cont
 165 contResultType (CoerceIt _ cont)     = contResultType cont
 166 contResultType (InlinePlease cont)   = contResultType cont
 167 contResultType (Select _ _ _ _ cont) = contResultType cont
 168
 169 -------------------
 170 countValArgs :: SimplCont -> Int
 171 countValArgs (ApplyTo _ (Type ty) se cont) = countValArgs cont
 172 countValArgs (ApplyTo _ val_arg   se cont) = 1 + countValArgs cont
 173 countValArgs other                         = 0
 174
 175 countArgs :: SimplCont -> Int
 176 countArgs (ApplyTo _ arg se cont) = 1 + countArgs cont
 177 countArgs other                   = 0
 178
 179 -------------------
 180 pushContArgs :: SimplEnv -> [OutArg] -> SimplCont -> SimplCont
 181 -- Pushes args with the specified environment
 182 pushContArgs env []           cont = cont
 183 pushContArgs env (arg : args) cont = ApplyTo NoDup arg env (pushContArgs env args cont)
 184 \end{code}
 185
 186
 187 \begin{code}
 188 getContArgs :: SwitchChecker
 189             -> OutId -> SimplCont
 190             -> ([(InExpr, SimplEnv, Bool)],     -- Arguments; the Bool is true for strict args
 191                 SimplCont,                      -- Remaining continuation
 192                 Bool)                           -- Whether we came across an InlineCall
 193 -- getContArgs id k = (args, k', inl)
 194 --      args are the leading ApplyTo items in k
 195 --      (i.e. outermost comes first)
 196 --      augmented with demand info from the functionn
 197 getContArgs chkr fun orig_cont
 198   = let
 199                 -- Ignore strictness info if the no-case-of-case
 200                 -- flag is on.  Strictness changes evaluation order
 201                 -- and that can change full laziness
 202         stricts | switchIsOn chkr NoCaseOfCase = vanilla_stricts
 203                 | otherwise                    = computed_stricts
 204     in
 205     go [] stricts False orig_cont
 206   where
 207     ----------------------------
 208
 209         -- Type argument
 210     go acc ss inl (ApplyTo _ arg@(Type _) se cont)
 211         = go ((arg,se,False) : acc) ss inl cont
 212                 -- NB: don't bother to instantiate the function type
 213
 214         -- Value argument
 215     go acc (s:ss) inl (ApplyTo _ arg se cont)
 216         = go ((arg,se,s) : acc) ss inl cont
 217
 218         -- An Inline continuation
 219     go acc ss inl (InlinePlease cont)
 220         = go acc ss True cont
 221
 222         -- We're run out of arguments, or else we've run out of demands
 223         -- The latter only happens if the result is guaranteed bottom
 224         -- This is the case for
 225         --      * case (error "hello") of { ... }
 226         --      * (error "Hello") arg
 227         --      * f (error "Hello") where f is strict
 228         --      etc
 229         -- Then, especially in the first of these cases, we'd like to discard
 230         -- the continuation, leaving just the bottoming expression.  But the
 231         -- type might not be right, so we may have to add a coerce.
 232     go acc ss inl cont
 233         | null ss && discardableCont cont = (reverse acc, discardCont cont, inl)
 234         | otherwise                       = (reverse acc, cont,             inl)
 235
 236     ----------------------------
 237     vanilla_stricts, computed_stricts :: [Bool]
 238     vanilla_stricts  = repeat False
 239     computed_stricts = zipWith (||) fun_stricts arg_stricts
 240
 241     ----------------------------
 242     (val_arg_tys, _) = splitFunTys (dropForAlls (idType fun))
 243     arg_stricts      = map isStrictType val_arg_tys ++ repeat False
 244         -- These argument types are used as a cheap and cheerful way to find
 245         -- unboxed arguments, which must be strict.  But it's an InType
 246         -- and so there might be a type variable where we expect a function
 247         -- type (the substitution hasn't happened yet).  And we don't bother
 248         -- doing the type applications for a polymorphic function.
 249         -- Hence the splitFunTys*IgnoringForAlls*
 250
 251     ----------------------------
 252         -- If fun_stricts is finite, it means the function returns bottom
 253         -- after that number of value args have been consumed
 254         -- Otherwise it's infinite, extended with False
 255     fun_stricts
 256       = case splitStrictSig (idNewStrictness fun) of
 257           (demands, result_info)
 258                 | not (demands `lengthExceeds` countValArgs orig_cont)
 259                 ->      -- Enough args, use the strictness given.
 260                         -- For bottoming functions we used to pretend that the arg
 261                         -- is lazy, so that we don't treat the arg as an
 262                         -- interesting context.  This avoids substituting
 263                         -- top-level bindings for (say) strings into
 264                         -- calls to error.  But now we are more careful about
 265                         -- inlining lone variables, so its ok (see SimplUtils.analyseCont)
 266                    if isBotRes result_info then
 267                         map isStrictDmd demands         -- Finite => result is bottom
 268                    else
 269                         map isStrictDmd demands ++ vanilla_stricts
 270
 271           other -> vanilla_stricts      -- Not enough args, or no strictness
 272
 273 -------------------
 274 interestingArg :: OutExpr -> Bool
 275         -- An argument is interesting if it has *some* structure
 276         -- We are here trying to avoid unfolding a function that
 277         -- is applied only to variables that have no unfolding
 278         -- (i.e. they are probably lambda bound): f x y z
 279         -- There is little point in inlining f here.
 280 interestingArg (Var v)           = hasSomeUnfolding (idUnfolding v)
 281                                         -- Was: isValueUnfolding (idUnfolding v')
 282                                         -- But that seems over-pessimistic
 283                                  || isDataConWorkId v
 284                                         -- This accounts for an argument like
 285                                         -- () or [], which is definitely interesting
 286 interestingArg (Type _)          = False
 287 interestingArg (App fn (Type _)) = interestingArg fn
 288 interestingArg (Note _ a)        = interestingArg a
 289 interestingArg other             = True
 290         -- Consider     let x = 3 in f x
 291         -- The substitution will contain (x -> ContEx 3), and we want to
 292         -- to say that x is an interesting argument.
 293         -- But consider also (\x. f x y) y
 294         -- The substitution will contain (x -> ContEx y), and we want to say
 295         -- that x is not interesting (assuming y has no unfolding)
 296 \end{code}
 297
 298 Comment about interestingCallContext
 299 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 300 We want to avoid inlining an expression where there can't possibly be
 301 any gain, such as in an argument position.  Hence, if the continuation
 302 is interesting (eg. a case scrutinee, application etc.) then we
 303 inline, otherwise we don't.
 304
 305 Previously some_benefit used to return True only if the variable was
 306 applied to some value arguments.  This didn't work:
 307
 308         let x = _coerce_ (T Int) Int (I# 3) in
 309         case _coerce_ Int (T Int) x of
 310                 I# y -> ....
 311
 312 we want to inline x, but can't see that it's a constructor in a case
 313 scrutinee position, and some_benefit is False.
 314
 315 Another example:
 316
 317 dMonadST = _/\_ t -> :Monad (g1 _@_ t, g2 _@_ t, g3 _@_ t)
 318
 319 ....  case dMonadST _@_ x0 of (a,b,c) -> ....
 320
 321 we'd really like to inline dMonadST here, but we *don't* want to
 322 inline if the case expression is just
 323
 324         case x of y { DEFAULT -> ... }
 325
 326 since we can just eliminate this case instead (x is in WHNF).  Similar
 327 applies when x is bound to a lambda expression.  Hence
 328 contIsInteresting looks for case expressions with just a single
 329 default case.
 330
 331 \begin{code}
 332 interestingCallContext :: Bool          -- False <=> no args at all
 333                        -> Bool          -- False <=> no value args
 334                        -> SimplCont -> Bool
 335         -- The "lone-variable" case is important.  I spent ages
 336         -- messing about with unsatisfactory varaints, but this is nice.
 337         -- The idea is that if a variable appear all alone
 338         --      as an arg of lazy fn, or rhs    Stop
 339         --      as scrutinee of a case          Select
 340         --      as arg of a strict fn           ArgOf
 341         -- then we should not inline it (unless there is some other reason,
 342         -- e.g. is is the sole occurrence).  We achieve this by making
 343         -- interestingCallContext return False for a lone variable.
 344         --
 345         -- Why?  At least in the case-scrutinee situation, turning
 346         --      let x = (a,b) in case x of y -> ...
 347         -- into
 348         --      let x = (a,b) in case (a,b) of y -> ...
 349         -- and thence to
 350         --      let x = (a,b) in let y = (a,b) in ...
 351         -- is bad if the binding for x will remain.
 352         --
 353         -- Another example: I discovered that strings
 354         -- were getting inlined straight back into applications of 'error'
 355         -- because the latter is strict.
 356         --      s = "foo"
 357         --      f = \x -> ...(error s)...
 358
 359         -- Fundamentally such contexts should not ecourage inlining because
 360         -- the context can ``see'' the unfolding of the variable (e.g. case or a RULE)
 361         -- so there's no gain.
 362         --
 363         -- However, even a type application or coercion isn't a lone variable.
 364         -- Consider
 365         --      case $fMonadST @ RealWorld of { :DMonad a b c -> c }
 366         -- We had better inline that sucker!  The case won't see through it.
 367         --
 368         -- For now, I'm treating treating a variable applied to types
 369         -- in a *lazy* context "lone". The motivating example was
 370         --      f = /\a. \x. BIG
 371         --      g = /\a. \y.  h (f a)
 372         -- There's no advantage in inlining f here, and perhaps
 373         -- a significant disadvantage.  Hence some_val_args in the Stop case
 374
 375 interestingCallContext some_args some_val_args cont
 376   = interesting cont
 377   where
 378     interesting (InlinePlease _)         = True
 379     interesting (Select _ _ _ _ _)       = some_args
 380     interesting (ApplyTo _ _ _ _)        = True -- Can happen if we have (coerce t (f x)) y
 381                                                 -- Perhaps True is a bit over-keen, but I've
 382                                                 -- seen (coerce f) x, where f has an INLINE prag,
 383                                                 -- So we have to give some motivaiton for inlining it
 384     interesting (ArgOf _ _ _ _)          = some_val_args
 385     interesting (Stop ty _ upd_in_place) = some_val_args && upd_in_place
 386     interesting (CoerceIt _ cont)        = interesting cont
 387         -- If this call is the arg of a strict function, the context
 388         -- is a bit interesting.  If we inline here, we may get useful
 389         -- evaluation information to avoid repeated evals: e.g.
 390         --      x + (y * z)
 391         -- Here the contIsInteresting makes the '*' keener to inline,
 392         -- which in turn exposes a constructor which makes the '+' inline.
 393         -- Assuming that +,* aren't small enough to inline regardless.
 394         --
 395         -- It's also very important to inline in a strict context for things
 396         -- like
 397         --              foldr k z (f x)
 398         -- Here, the context of (f x) is strict, and if f's unfolding is
 399         -- a build it's *great* to inline it here.  So we must ensure that
 400         -- the context for (f x) is not totally uninteresting.
 401
 402
 403 -------------------
 404 canUpdateInPlace :: Type -> Bool
 405 -- Consider   let x = <wurble> in ...
 406 -- If <wurble> returns an explicit constructor, we might be able
 407 -- to do update in place.  So we treat even a thunk RHS context
 408 -- as interesting if update in place is possible.  We approximate
 409 -- this by seeing if the type has a single constructor with a
 410 -- small arity.  But arity zero isn't good -- we share the single copy
 411 -- for that case, so no point in sharing.
 412
 413 canUpdateInPlace ty
 414   | not opt_UF_UpdateInPlace = False
 415   | otherwise
 416   = case splitTyConApp_maybe ty of
 417         Nothing         -> False
 418         Just (tycon, _) -> case tyConDataCons_maybe tycon of
 419                                 Just [dc]  -> arity == 1 || arity == 2
 420                                            where
 421                                               arity = dataConRepArity dc
 422                                 other -> False
 423 \end{code}
 424
 425
 426
 427 %************************************************************************
 428 %*                                                                      *
 429 \subsection{Decisions about inlining}
 430 %*                                                                      *
 431 %************************************************************************
 432
 433 Inlining is controlled partly by the SimplifierMode switch.  This has two
 434 settings:
 435
 436         SimplGently     (a) Simplifying before specialiser/full laziness
 437                         (b) Simplifiying inside INLINE pragma
 438                         (c) Simplifying the LHS of a rule
 439                         (d) Simplifying a GHCi expression or Template
 440                                 Haskell splice
 441
 442         SimplPhase n    Used at all other times
 443
 444 The key thing about SimplGently is that it does no call-site inlining.
 445 Before full laziness we must be careful not to inline wrappers,
 446 because doing so inhibits floating
 447     e.g. ...(case f x of ...)...
 448     ==> ...(case (case x of I# x# -> fw x#) of ...)...
 449     ==> ...(case x of I# x# -> case fw x# of ...)...
 450 and now the redex (f x) isn't floatable any more.
 451
 452 The no-inling thing is also important for Template Haskell.  You might be
 453 compiling in one-shot mode with -O2; but when TH compiles a splice before
 454 running it, we don't want to use -O2.  Indeed, we don't want to inline
 455 anything, because the byte-code interpreter might get confused about
 456 unboxed tuples and suchlike.
 457
 458 INLINE pragmas
 459 ~~~~~~~~~~~~~~
 460 SimplGently is also used as the mode to simplify inside an InlineMe note.
 461
 462 \begin{code}
 463 inlineMode :: SimplifierMode
 464 inlineMode = SimplGently
 465 \end{code}
 466
 467 It really is important to switch off inlinings inside such
 468 expressions.  Consider the following example
 469
 470         let f = \pq -> BIG
 471         in
 472         let g = \y -> f y y
 473             {-# INLINE g #-}
 474         in ...g...g...g...g...g...
 475
 476 Now, if that's the ONLY occurrence of f, it will be inlined inside g,
 477 and thence copied multiple times when g is inlined.
 478
 479
 480 This function may be inlinined in other modules, so we
 481 don't want to remove (by inlining) calls to functions that have
 482 specialisations, or that may have transformation rules in an importing
 483 scope.
 484
 485 E.g.    {-# INLINE f #-}
 486                 f x = ...g...
 487
 488 and suppose that g is strict *and* has specialisations.  If we inline
 489 g's wrapper, we deny f the chance of getting the specialised version
 490 of g when f is inlined at some call site (perhaps in some other
 491 module).
 492
 493 It's also important not to inline a worker back into a wrapper.
 494 A wrapper looks like
 495         wraper = inline_me (\x -> ...worker... )
 496 Normally, the inline_me prevents the worker getting inlined into
 497 the wrapper (initially, the worker's only call site!).  But,
 498 if the wrapper is sure to be called, the strictness analyser will
 499 mark it 'demanded', so when the RHS is simplified, it'll get an ArgOf
 500 continuation.  That's why the keep_inline predicate returns True for
 501 ArgOf continuations.  It shouldn't do any harm not to dissolve the
 502 inline-me note under these circumstances.
 503
 504 Note that the result is that we do very little simplification
 505 inside an InlineMe.
 506
 507         all xs = foldr (&&) True xs
 508         any p = all . map p  {-# INLINE any #-}
 509
 510 Problem: any won't get deforested, and so if it's exported and the
 511 importer doesn't use the inlining, (eg passes it as an arg) then we
 512 won't get deforestation at all.  We havn't solved this problem yet!
 513
 514
 515 preInlineUnconditionally
 516 ~~~~~~~~~~~~~~~~~~~~~~~~
 517 @preInlineUnconditionally@ examines a bndr to see if it is used just
 518 once in a completely safe way, so that it is safe to discard the
 519 binding inline its RHS at the (unique) usage site, REGARDLESS of how
 520 big the RHS might be.  If this is the case we don't simplify the RHS
 521 first, but just inline it un-simplified.
 522
 523 This is much better than first simplifying a perhaps-huge RHS and then
 524 inlining and re-simplifying it.  Indeed, it can be at least quadratically
 525 better.  Consider
 526
 527         x1 = e1
 528         x2 = e2[x1]
 529         x3 = e3[x2]
 530         ...etc...
 531         xN = eN[xN-1]
 532
 533 We may end up simplifying e1 N times, e2 N-1 times, e3 N-3 times etc.
 534 This can happen with cascades of functions too:
 535
 536         f1 = \x1.e1
 537         f2 = \xs.e2[f1]
 538         f3 = \xs.e3[f3]
 539         ...etc...
 540
 541 THE MAIN INVARIANT is this:
 542
 543         ----  preInlineUnconditionally invariant -----
 544    IF preInlineUnconditionally chooses to inline x = <rhs>
 545    THEN doing the inlining should not change the occurrence
 546         info for the free vars of <rhs>
 547         ----------------------------------------------
 548
 549 For example, it's tempting to look at trivial binding like
 550         x = y
 551 and inline it unconditionally.  But suppose x is used many times,
 552 but this is the unique occurrence of y.  Then inlining x would change
 553 y's occurrence info, which breaks the invariant.  It matters: y
 554 might have a BIG rhs, which will now be dup'd at every occurrenc of x.
 555
 556
 557 Evne RHSs labelled InlineMe aren't caught here, because there might be
 558 no benefit from inlining at the call site.
 559
 560 [Sept 01] Don't unconditionally inline a top-level thing, because that
 561 can simply make a static thing into something built dynamically.  E.g.
 562         x = (a,b)
 563         main = \s -> h x
 564
 565 [Remember that we treat \s as a one-shot lambda.]  No point in
 566 inlining x unless there is something interesting about the call site.
 567
 568 But watch out: if you aren't careful, some useful foldr/build fusion
 569 can be lost (most notably in spectral/hartel/parstof) because the
 570 foldr didn't see the build.  Doing the dynamic allocation isn't a big
 571 deal, in fact, but losing the fusion can be.  But the right thing here
 572 seems to be to do a callSiteInline based on the fact that there is
 573 something interesting about the call site (it's strict).  Hmm.  That
 574 seems a bit fragile.
 575
 576 Conclusion: inline top level things gaily until Phase 0 (the last
 577 phase), at which point don't.
 578
 579 \begin{code}
 580 preInlineUnconditionally :: SimplEnv -> TopLevelFlag -> InId -> InExpr -> Bool
 581 preInlineUnconditionally env top_lvl bndr rhs
 582   | not active             = False
 583   | opt_SimplNoPreInlining = False
 584   | otherwise = case idOccInfo bndr of
 585                   IAmDead                    -> True    -- Happens in ((\x.1) v)
 586                   OneOcc in_lam True int_cxt -> try_once in_lam int_cxt
 587                   other                      -> False
 588   where
 589     phase = getMode env
 590     active = case phase of
 591                    SimplGently  -> isAlwaysActive prag
 592                    SimplPhase n -> isActive n prag
 593     prag = idInlinePragma bndr
 594
 595     try_once in_lam int_cxt     -- There's one textual occurrence
 596         = not in_lam && (isNotTopLevel top_lvl || early_phase)
 597         || (exprIsValue rhs && int_cxt)
 598         -- exprIsValue => free vars of rhs are (Once in_lam) or Many,
 599         -- so substituting rhs inside a lambda doesn't change the occ info
 600         -- Caveat: except the fn of a PAP, but since it has arity > 0, it
 601         --         must be a HNF, so it doesn't matter if we push it inside
 602         --         a lambda
 603         --
 604         --      int_cxt         The context isn't totally boring
 605         -- E.g. let f = \ab.BIG in \y. map f xs
 606         --      Don't want to substitute for f, because then we allocate
 607         --      its closure every time the \y is called
 608         -- But: let f = \ab.BIG in \y. map (f y) xs
 609         --      Now we do want to substitute for f, even though it's not
 610         --      saturated, because we're going to allocate a closure for
 611         --      (f y) every time round the loop anyhow.
 612
 613     early_phase = case phase of
 614                         SimplPhase 0 -> False
 615                         other        -> True
 616 -- If we don't have this early_phase test, consider
 617 --      x = length [1,2,3]
 618 -- The full laziness pass carefully floats all the cons cells to
 619 -- top level, and preInlineUnconditionally floats them all back in.
 620 -- Result is (a) static allocation replaced by dynamic allocation
 621 --           (b) many simplifier iterations because this tickles
 622 --               a related problem; only one inlining per pass
 623 --
 624 -- On the other hand, I have seen cases where top-level fusion is
 625 -- lost if we don't inline top level thing (e.g. string constants)
 626 -- Hence the test for phase zero (which is the phase for all the final
 627 -- simplifications).  Until phase zero we take no special notice of
 628 -- top level things, but then we become more leery about inlining
 629 -- them.
 630
 631 \end{code}
 632
 633 postInlineUnconditionally
 634 ~~~~~~~~~~~~~~~~~~~~~~~~~
 635 @postInlineUnconditionally@ decides whether to unconditionally inline
 636 a thing based on the form of its RHS; in particular if it has a
 637 trivial RHS.  If so, we can inline and discard the binding altogether.
 638
 639 NB: a loop breaker has must_keep_binding = True and non-loop-breakers
 640 only have *forward* references Hence, it's safe to discard the binding
 641
 642 NOTE: This isn't our last opportunity to inline.  We're at the binding
 643 site right now, and we'll get another opportunity when we get to the
 644 ocurrence(s)
 645
 646 Note that we do this unconditional inlining only for trival RHSs.
 647 Don't inline even WHNFs inside lambdas; doing so may simply increase
 648 allocation when the function is called. This isn't the last chance; see
 649 NOTE above.
 650
 651 NB: Even inline pragmas (e.g. IMustBeINLINEd) are ignored here Why?
 652 Because we don't even want to inline them into the RHS of constructor
 653 arguments. See NOTE above
 654
 655 NB: At one time even NOINLINE was ignored here: if the rhs is trivial
 656 it's best to inline it anyway.  We often get a=E; b=a from desugaring,
 657 with both a and b marked NOINLINE.  But that seems incompatible with
 658 our new view that inlining is like a RULE, so I'm sticking to the 'active'
 659 story for now.
 660
 661 \begin{code}
 662 postInlineUnconditionally :: SimplEnv -> OutId -> OccInfo -> OutExpr -> Bool
 663 postInlineUnconditionally env bndr occ_info rhs
 664   | not active             = False
 665   | isLoopBreaker occ_info = False
 666   | isExportedId bndr      = False
 667   | exprIsTrivial rhs      = True
 668   | otherwise              = False
 669   where
 670     active = case getMode env of
 671                    SimplGently  -> isAlwaysActive prag
 672                    SimplPhase n -> isActive n prag
 673     prag = idInlinePragma bndr
 674
 675 activeInline :: SimplEnv -> OutId -> OccInfo -> Bool
 676 activeInline env id occ
 677   = case getMode env of
 678       SimplGently -> isOneOcc occ && isAlwaysActive prag
 679         -- No inlining at all when doing gentle stuff,
 680         -- except for local things that occur once
 681         -- The reason is that too little clean-up happens if you
 682         -- don't inline use-once things.   Also a bit of inlining is *good* for
 683         -- full laziness; it can expose constant sub-expressions.
 684         -- Example in spectral/mandel/Mandel.hs, where the mandelset
 685         -- function gets a useful let-float if you inline windowToViewport
 686
 687         -- NB: we used to have a second exception, for data con wrappers.
 688         -- On the grounds that we use gentle mode for rule LHSs, and
 689         -- they match better when data con wrappers are inlined.
 690         -- But that only really applies to the trivial wrappers (like (:)),
 691         -- and they are now constructed as Compulsory unfoldings (in MkId)
 692         -- so they'll happen anyway.
 693
 694       SimplPhase n -> isActive n prag
 695   where
 696     prag = idInlinePragma id
 697
 698 activeRule :: SimplEnv -> Maybe (Activation -> Bool)
 699 -- Nothing => No rules at all
 700 activeRule env
 701   | opt_RulesOff = Nothing
 702   | otherwise
 703   = case getMode env of
 704         SimplGently  -> Just isAlwaysActive
 705                         -- Used to be Nothing (no rules in gentle mode)
 706                         -- Main motivation for changing is that I wanted
 707                         --      lift String ===> ...
 708                         -- to work in Template Haskell when simplifying
 709                         -- splices, so we get simpler code for literal strings
 710         SimplPhase n -> Just (isActive n)
 711 \end{code}
 712
 713
 714 %************************************************************************
 715 %*                                                                      *
 716 \subsection{Rebuilding a lambda}
 717 %*                                                                      *
 718 %************************************************************************
 719
 720 \begin{code}
 721 mkLam :: SimplEnv -> [OutBinder] -> OutExpr -> SimplCont -> SimplM FloatsWithExpr
 722 \end{code}
 723
 724 Try three things
 725         a) eta reduction, if that gives a trivial expression
 726         b) eta expansion [only if there are some value lambdas]
 727         c) floating lets out through big lambdas
 728                 [only if all tyvar lambdas, and only if this lambda
 729                  is the RHS of a let]
 730
 731 \begin{code}
 732 mkLam env bndrs body cont
 733  = getDOptsSmpl  `thenSmpl` \dflags ->
 734    mkLam' dflags env bndrs body cont
 735  where
 736  mkLam' dflags env bndrs body cont
 737    | dopt Opt_DoEtaReduction dflags,
 738      Just etad_lam <- tryEtaReduce bndrs body
 739    = tick (EtaReduction (head bndrs))   `thenSmpl_`
 740      returnSmpl (emptyFloats env, etad_lam)
 741
 742    | dopt Opt_DoLambdaEtaExpansion dflags,
 743      any isRuntimeVar bndrs
 744    = tryEtaExpansion body               `thenSmpl` \ body' ->
 745      returnSmpl (emptyFloats env, mkLams bndrs body')
 746
 747 {-      Sept 01: I'm experimenting with getting the
 748         full laziness pass to float out past big lambdsa
 749  | all isTyVar bndrs,   -- Only for big lambdas
 750    contIsRhs cont       -- Only try the rhs type-lambda floating
 751                         -- if this is indeed a right-hand side; otherwise
 752                         -- we end up floating the thing out, only for float-in
 753                         -- to float it right back in again!
 754  = tryRhsTyLam env bndrs body           `thenSmpl` \ (floats, body') ->
 755    returnSmpl (floats, mkLams bndrs body')
 756 -}
 757
 758    | otherwise
 759    = returnSmpl (emptyFloats env, mkLams bndrs body)
 760 \end{code}
 761
 762
 763 %************************************************************************
 764 %*                                                                      *
 765 \subsection{Eta expansion and reduction}
 766 %*                                                                      *
 767 %************************************************************************
 768
 769 We try for eta reduction here, but *only* if we get all the
 770 way to an exprIsTrivial expression.
 771 We don't want to remove extra lambdas unless we are going
 772 to avoid allocating this thing altogether
 773
 774 \begin{code}
 775 tryEtaReduce :: [OutBinder] -> OutExpr -> Maybe OutExpr
 776 tryEtaReduce bndrs body
 777         -- We don't use CoreUtils.etaReduce, because we can be more
 778         -- efficient here:
 779         --  (a) we already have the binders
 780         --  (b) we can do the triviality test before computing the free vars
 781   = go (reverse bndrs) body
 782   where
 783     go (b : bs) (App fun arg) | ok_arg b arg = go bs fun        -- Loop round
 784     go []       fun           | ok_fun fun   = Just fun         -- Success!
 785     go _        _                            = Nothing          -- Failure!
 786
 787     ok_fun fun =  exprIsTrivial fun
 788                && not (any (`elemVarSet` (exprFreeVars fun)) bndrs)
 789                && (exprIsValue fun || all ok_lam bndrs)
 790     ok_lam v = isTyVar v || isDictId v
 791         -- The exprIsValue is because eta reduction is not
 792         -- valid in general:  \x. bot  /=  bot
 793         -- So we need to be sure that the "fun" is a value.
 794         --
 795         -- However, we always want to reduce (/\a -> f a) to f
 796         -- This came up in a RULE: foldr (build (/\a -> g a))
 797         --      did not match      foldr (build (/\b -> ...something complex...))
 798         -- The type checker can insert these eta-expanded versions,
 799         -- with both type and dictionary lambdas; hence the slightly
 800         -- ad-hoc isDictTy
 801
 802     ok_arg b arg = varToCoreExpr b `cheapEqExpr` arg
 803 \end{code}
 804
 805
 806         Try eta expansion for RHSs
 807
 808 We go for:
 809    f = \x1..xn -> N  ==>   f = \x1..xn y1..ym -> N y1..ym
 810                                  (n >= 0)
 811
 812 where (in both cases)
 813
 814         * The xi can include type variables
 815
 816         * The yi are all value variables
 817
 818         * N is a NORMAL FORM (i.e. no redexes anywhere)
 819           wanting a suitable number of extra args.
 820
 821 We may have to sandwich some coerces between the lambdas
 822 to make the types work.   exprEtaExpandArity looks through coerces
 823 when computing arity; and etaExpand adds the coerces as necessary when
 824 actually computing the expansion.
 825
 826 \begin{code}
 827 tryEtaExpansion :: OutExpr -> SimplM OutExpr
 828 -- There is at least one runtime binder in the binders
 829 tryEtaExpansion body
 830   = getUniquesSmpl                      `thenSmpl` \ us ->
 831     returnSmpl (etaExpand fun_arity us body (exprType body))
 832   where
 833     fun_arity = exprEtaExpandArity body
 834 \end{code}
 835
 836
 837 %************************************************************************
 838 %*                                                                      *
 839 \subsection{Floating lets out of big lambdas}
 840 %*                                                                      *
 841 %************************************************************************
 842
 843 tryRhsTyLam tries this transformation, when the big lambda appears as
 844 the RHS of a let(rec) binding:
 845
 846         /\abc -> let(rec) x = e in b
 847    ==>
 848         let(rec) x' = /\abc -> let x = x' a b c in e
 849         in
 850         /\abc -> let x = x' a b c in b
 851
 852 This is good because it can turn things like:
 853
 854         let f = /\a -> letrec g = ... g ... in g
 855 into
 856         letrec g' = /\a -> ... g' a ...
 857         in
 858         let f = /\ a -> g' a
 859
 860 which is better.  In effect, it means that big lambdas don't impede
 861 let-floating.
 862
 863 This optimisation is CRUCIAL in eliminating the junk introduced by
 864 desugaring mutually recursive definitions.  Don't eliminate it lightly!
 865
 866 So far as the implementation is concerned:
 867
 868         Invariant: go F e = /\tvs -> F e
 869
 870         Equalities:
 871                 go F (Let x=e in b)
 872                 = Let x' = /\tvs -> F e
 873                   in
 874                   go G b
 875                 where
 876                     G = F . Let x = x' tvs
 877
 878                 go F (Letrec xi=ei in b)
 879                 = Letrec {xi' = /\tvs -> G ei}
 880                   in
 881                   go G b
 882                 where
 883                   G = F . Let {xi = xi' tvs}
 884
 885 [May 1999]  If we do this transformation *regardless* then we can
 886 end up with some pretty silly stuff.  For example,
 887
 888         let
 889             st = /\ s -> let { x1=r1 ; x2=r2 } in ...
 890         in ..
 891 becomes
 892         let y1 = /\s -> r1
 893             y2 = /\s -> r2
 894             st = /\s -> ...[y1 s/x1, y2 s/x2]
 895         in ..
 896
 897 Unless the "..." is a WHNF there is really no point in doing this.
 898 Indeed it can make things worse.  Suppose x1 is used strictly,
 899 and is of the form
 900
 901         x1* = case f y of { (a,b) -> e }
 902
 903 If we abstract this wrt the tyvar we then can't do the case inline
 904 as we would normally do.
 905
 906
 907 \begin{code}
 908 {-      Trying to do this in full laziness
 909
 910 tryRhsTyLam :: SimplEnv -> [OutTyVar] -> OutExpr -> SimplM FloatsWithExpr
 911 -- Call ensures that all the binders are type variables
 912
 913 tryRhsTyLam env tyvars body             -- Only does something if there's a let
 914   |  not (all isTyVar tyvars)
 915   || not (worth_it body)                -- inside a type lambda,
 916   = returnSmpl (emptyFloats env, body)  -- and a WHNF inside that
 917
 918   | otherwise
 919   = go env (\x -> x) body
 920
 921   where
 922     worth_it e@(Let _ _) = whnf_in_middle e
 923     worth_it e           = False
 924
 925     whnf_in_middle (Let (NonRec x rhs) e) | isUnLiftedType (idType x) = False
 926     whnf_in_middle (Let _ e) = whnf_in_middle e
 927     whnf_in_middle e         = exprIsCheap e
 928
 929     main_tyvar_set = mkVarSet tyvars
 930
 931     go env fn (Let bind@(NonRec var rhs) body)
 932       | exprIsTrivial rhs
 933       = go env (fn . Let bind) body
 934
 935     go env fn (Let (NonRec var rhs) body)
 936       = mk_poly tyvars_here var                                                 `thenSmpl` \ (var', rhs') ->
 937         addAuxiliaryBind env (NonRec var' (mkLams tyvars_here (fn rhs)))        $ \ env ->
 938         go env (fn . Let (mk_silly_bind var rhs')) body
 939
 940       where
 941
 942         tyvars_here = varSetElems (main_tyvar_set `intersectVarSet` exprSomeFreeVars isTyVar rhs)
 943                 -- Abstract only over the type variables free in the rhs
 944                 -- wrt which the new binding is abstracted.  But the naive
 945                 -- approach of abstract wrt the tyvars free in the Id's type
 946                 -- fails. Consider:
 947                 --      /\ a b -> let t :: (a,b) = (e1, e2)
 948                 --                    x :: a     = fst t
 949                 --                in ...
 950                 -- Here, b isn't free in x's type, but we must nevertheless
 951                 -- abstract wrt b as well, because t's type mentions b.
 952                 -- Since t is floated too, we'd end up with the bogus:
 953                 --      poly_t = /\ a b -> (e1, e2)
 954                 --      poly_x = /\ a   -> fst (poly_t a *b*)
 955                 -- So for now we adopt the even more naive approach of
 956                 -- abstracting wrt *all* the tyvars.  We'll see if that
 957                 -- gives rise to problems.   SLPJ June 98
 958
 959     go env fn (Let (Rec prs) body)
 960        = mapAndUnzipSmpl (mk_poly tyvars_here) vars     `thenSmpl` \ (vars', rhss') ->
 961          let
 962             gn body = fn (foldr Let body (zipWith mk_silly_bind vars rhss'))
 963             pairs   = vars' `zip` [mkLams tyvars_here (gn rhs) | rhs <- rhss]
 964          in
 965          addAuxiliaryBind env (Rec pairs)               $ \ env ->
 966          go env gn body
 967        where
 968          (vars,rhss) = unzip prs
 969          tyvars_here = varSetElems (main_tyvar_set `intersectVarSet` exprsSomeFreeVars isTyVar (map snd prs))
 970                 -- See notes with tyvars_here above
 971
 972     go env fn body = returnSmpl (emptyFloats env, fn body)
 973
 974     mk_poly tyvars_here var
 975       = getUniqueSmpl           `thenSmpl` \ uniq ->
 976         let
 977             poly_name = setNameUnique (idName var) uniq         -- Keep same name
 978             poly_ty   = mkForAllTys tyvars_here (idType var)    -- But new type of course
 979             poly_id   = mkLocalId poly_name poly_ty
 980
 981                 -- In the olden days, it was crucial to copy the occInfo of the original var,
 982                 -- because we were looking at occurrence-analysed but as yet unsimplified code!
 983                 -- In particular, we mustn't lose the loop breakers.  BUT NOW we are looking
 984                 -- at already simplified code, so it doesn't matter
 985                 --
 986                 -- It's even right to retain single-occurrence or dead-var info:
 987                 -- Suppose we started with  /\a -> let x = E in B
 988                 -- where x occurs once in B. Then we transform to:
 989                 --      let x' = /\a -> E in /\a -> let x* = x' a in B
 990                 -- where x* has an INLINE prag on it.  Now, once x* is inlined,
 991                 -- the occurrences of x' will be just the occurrences originally
 992                 -- pinned on x.
 993         in
 994         returnSmpl (poly_id, mkTyApps (Var poly_id) (mkTyVarTys tyvars_here))
 995
 996     mk_silly_bind var rhs = NonRec var (Note InlineMe rhs)
 997                 -- Suppose we start with:
 998                 --
 999                 --      x = /\ a -> let g = G in E
1000                 --
1001                 -- Then we'll float to get
1002                 --
1003                 --      x = let poly_g = /\ a -> G
1004                 --          in /\ a -> let g = poly_g a in E
1005                 --
1006                 -- But now the occurrence analyser will see just one occurrence
1007                 -- of poly_g, not inside a lambda, so the simplifier will
1008                 -- PreInlineUnconditionally poly_g back into g!  Badk to square 1!
1009                 -- (I used to think that the "don't inline lone occurrences" stuff
1010                 --  would stop this happening, but since it's the *only* occurrence,
1011                 --  PreInlineUnconditionally kicks in first!)
1012                 --
1013                 -- Solution: put an INLINE note on g's RHS, so that poly_g seems
1014                 --           to appear many times.  (NB: mkInlineMe eliminates
1015                 --           such notes on trivial RHSs, so do it manually.)
1016 -}
1017 \end{code}
1018
1019 %************************************************************************
1020 %*                                                                      *
1021 \subsection{Case alternative filtering
1022 %*                                                                      *
1023 %************************************************************************
1024
1025 prepareAlts does two things:
1026
1027 1.  Eliminate alternatives that cannot match, including the
1028     DEFAULT alternative.
1029
1030 2.  If the DEFAULT alternative can match only one possible constructor,
1031     then make that constructor explicit.
1032     e.g.
1033         case e of x { DEFAULT -> rhs }
1034      ===>
1035         case e of x { (a,b) -> rhs }
1036     where the type is a single constructor type.  This gives better code
1037     when rhs also scrutinises x or e.
1038
1039 It's a good idea do do this stuff before simplifying the alternatives, to
1040 avoid simplifying alternatives we know can't happen, and to come up with
1041 the list of constructors that are handled, to put into the IdInfo of the
1042 case binder, for use when simplifying the alternatives.
1043
1044 Eliminating the default alternative in (1) isn't so obvious, but it can
1045 happen:
1046
1047 data Colour = Red | Green | Blue
1048
1049 f x = case x of
1050         Red -> ..
1051         Green -> ..
1052         DEFAULT -> h x
1053
1054 h y = case y of
1055         Blue -> ..
1056         DEFAULT -> [ case y of ... ]
1057
1058 If we inline h into f, the default case of the inlined h can't happen.
1059 If we don't notice this, we may end up filtering out *all* the cases
1060 of the inner case y, which give us nowhere to go!
1061
1062
1063 \begin{code}
1064 prepareAlts :: OutExpr          -- Scrutinee
1065             -> InId             -- Case binder
1066             -> [InAlt]          -- Increasing order
1067             -> SimplM ([InAlt],         -- Better alternatives, still incresaing order
1068                         [AltCon])       -- These cases are handled
1069
1070 prepareAlts scrut case_bndr alts
1071   = let
1072         (alts_wo_default, maybe_deflt) = findDefault alts
1073
1074         impossible_cons = case scrut of
1075                             Var v -> otherCons (idUnfolding v)
1076                             other -> []
1077
1078         -- Filter out alternatives that can't possibly match
1079         better_alts | null impossible_cons = alts_wo_default
1080                     | otherwise            = [alt | alt@(con,_,_) <- alts_wo_default,
1081                                                     not (con `elem` impossible_cons)]
1082
1083         -- "handled_cons" are handled either by the context,
1084         -- or by a branch in this case expression
1085         -- (Don't add DEFAULT to the handled_cons!!)
1086         handled_cons = impossible_cons ++ [con | (con,_,_) <- better_alts]
1087     in
1088         -- Filter out the default, if it can't happen,
1089         -- or replace it with "proper" alternative if there
1090         -- is only one constructor left
1091     prepareDefault case_bndr handled_cons maybe_deflt   `thenSmpl` \ deflt_alt ->
1092
1093     returnSmpl (mergeAlts better_alts deflt_alt, handled_cons)
1094         -- We need the mergeAlts in case the new default_alt
1095         -- has turned into a constructor alternative.
1096
1097 prepareDefault case_bndr handled_cons (Just rhs)
1098   | Just (tycon, inst_tys) <- splitTyConApp_maybe (idType case_bndr),
1099     isAlgTyCon tycon,           -- It's a data type, tuple, or unboxed tuples.
1100     not (isNewTyCon tycon),     -- We can have a newtype, if we are just doing an eval:
1101                                 --      case x of { DEFAULT -> e }
1102                                 -- and we don't want to fill in a default for them!
1103     Just all_cons <- tyConDataCons_maybe tycon,
1104     not (null all_cons),        -- This is a tricky corner case.  If the data type has no constructors,
1105                                 -- which GHC allows, then the case expression will have at most a default
1106                                 -- alternative.  We don't want to eliminate that alternative, because the
1107                                 -- invariant is that there's always one alternative.  It's more convenient
1108                                 -- to leave
1109                                 --      case x of { DEFAULT -> e }
1110                                 -- as it is, rather than transform it to
1111                                 --      error "case cant match"
1112                                 -- which would be quite legitmate.  But it's a really obscure corner, and
1113                                 -- not worth wasting code on.
1114     let handled_data_cons = [data_con | DataAlt data_con <- handled_cons],
1115     let missing_cons      = [con | con <- all_cons,
1116                                    not (con `elem` handled_data_cons)]
1117   = case missing_cons of
1118         []          -> returnSmpl []    -- Eliminate the default alternative
1119                                         -- if it can't match
1120
1121         [con]       ->  -- It matches exactly one constructor, so fill it in
1122                        tick (FillInCaseDefault case_bndr)       `thenSmpl_`
1123                        mk_args con inst_tys                     `thenSmpl` \ args ->
1124                        returnSmpl [(DataAlt con, args, rhs)]
1125
1126         two_or_more -> returnSmpl [(DEFAULT, [], rhs)]
1127
1128   | otherwise
1129   = returnSmpl [(DEFAULT, [], rhs)]
1130
1131 prepareDefault case_bndr handled_cons Nothing
1132   = returnSmpl []
1133
1134 mk_args missing_con inst_tys
1135   = mk_tv_bndrs missing_con inst_tys    `thenSmpl` \ (tv_bndrs, inst_tys') ->
1136     getUniquesSmpl                      `thenSmpl` \ id_uniqs ->
1137     let arg_tys = dataConArgTys missing_con inst_tys'
1138         arg_ids = zipWith (mkSysLocal FSLIT("a")) id_uniqs arg_tys
1139     in
1140     returnSmpl (tv_bndrs ++ arg_ids)
1141
1142 mk_tv_bndrs missing_con inst_tys
1143   | isVanillaDataCon missing_con
1144   = returnSmpl ([], inst_tys)
1145   | otherwise
1146   = getUniquesSmpl              `thenSmpl` \ tv_uniqs ->
1147     let new_tvs    = zipWith mk tv_uniqs (dataConTyVars missing_con)
1148         mk uniq tv = mkTyVar (mkSysTvName uniq FSLIT("t")) (tyVarKind tv)
1149     in
1150     returnSmpl (new_tvs, mkTyVarTys new_tvs)
1151 \end{code}
1152
1153
1154 %************************************************************************
1155 %*                                                                      *
1156 \subsection{Case absorption and identity-case elimination}
1157 %*                                                                      *
1158 %************************************************************************
1159
1160 mkCase puts a case expression back together, trying various transformations first.
1161
1162 \begin{code}
1163 mkCase :: OutExpr -> OutId -> OutType
1164        -> [OutAlt]              -- Increasing order
1165        -> SimplM OutExpr
1166
1167 mkCase scrut case_bndr ty alts
1168   = getDOptsSmpl                        `thenSmpl` \dflags ->
1169     mkAlts dflags scrut case_bndr alts  `thenSmpl` \ better_alts ->
1170     mkCase1 scrut case_bndr ty better_alts
1171 \end{code}
1172
1173
1174 mkAlts tries these things:
1175
1176 1.  If several alternatives are identical, merge them into
1177     a single DEFAULT alternative.  I've occasionally seen this
1178     making a big difference:
1179
1180         case e of               =====>     case e of
1181           C _ -> f x                         D v -> ....v....
1182           D v -> ....v....                   DEFAULT -> f x
1183           DEFAULT -> f x
1184
1185    The point is that we merge common RHSs, at least for the DEFAULT case.
1186    [One could do something more elaborate but I've never seen it needed.]
1187    To avoid an expensive test, we just merge branches equal to the *first*
1188    alternative; this picks up the common cases
1189         a) all branches equal
1190         b) some branches equal to the DEFAULT (which occurs first)
1191
1192 2.  Case merging:
1193        case e of b {             ==>   case e of b {
1194          p1 -> rhs1                      p1 -> rhs1
1195          ...                             ...
1196          pm -> rhsm                      pm -> rhsm
1197          _  -> case b of b' {            pn -> let b'=b in rhsn
1198                      pn -> rhsn          ...
1199                      ...                 po -> let b'=b in rhso
1200                      po -> rhso          _  -> let b'=b in rhsd
1201                      _  -> rhsd
1202        }
1203
1204     which merges two cases in one case when -- the default alternative of
1205     the outer case scrutises the same variable as the outer case This
1206     transformation is called Case Merging.  It avoids that the same
1207     variable is scrutinised multiple times.
1208
1209
1210 The case where transformation (1) showed up was like this (lib/std/PrelCError.lhs):
1211
1212         x | p `is` 1 -> e1
1213           | p `is` 2 -> e2
1214         ...etc...
1215
1216 where @is@ was something like
1217
1218         p `is` n = p /= (-1) && p == n
1219
1220 This gave rise to a horrible sequence of cases
1221
1222         case p of
1223           (-1) -> $j p
1224           1    -> e1
1225           DEFAULT -> $j p
1226
1227 and similarly in cascade for all the join points!
1228
1229
1230
1231 \begin{code}
1232 --------------------------------------------------
1233 --      1. Merge identical branches
1234 --------------------------------------------------
1235 mkAlts dflags scrut case_bndr alts@((con1,bndrs1,rhs1) : con_alts)
1236   | all isDeadBinder bndrs1,                    -- Remember the default
1237     length filtered_alts < length con_alts      -- alternative comes first
1238   = tick (AltMerge case_bndr)                   `thenSmpl_`
1239     returnSmpl better_alts
1240   where
1241     filtered_alts        = filter keep con_alts
1242     keep (con,bndrs,rhs) = not (all isDeadBinder bndrs && rhs `cheapEqExpr` rhs1)
1243     better_alts          = (DEFAULT, [], rhs1) : filtered_alts
1244
1245
1246 --------------------------------------------------
1247 --      2.  Merge nested cases
1248 --------------------------------------------------
1249
1250 mkAlts dflags scrut outer_bndr outer_alts
1251   | dopt Opt_CaseMerge dflags,
1252     (outer_alts_without_deflt, maybe_outer_deflt)   <- findDefault outer_alts,
1253     Just (Case (Var scrut_var) inner_bndr _ inner_alts) <- maybe_outer_deflt,
1254     scruting_same_var scrut_var
1255   = let
1256         munged_inner_alts = [(con, args, munge_rhs rhs) | (con, args, rhs) <- inner_alts]
1257         munge_rhs rhs = bindCaseBndr inner_bndr (Var outer_bndr) rhs
1258
1259         new_alts = mergeAlts outer_alts_without_deflt munged_inner_alts
1260                 -- The merge keeps the inner DEFAULT at the front, if there is one
1261                 -- and eliminates any inner_alts that are shadowed by the outer_alts
1262     in
1263     tick (CaseMerge outer_bndr)                         `thenSmpl_`
1264     returnSmpl new_alts
1265         -- Warning: don't call mkAlts recursively!
1266         -- Firstly, there's no point, because inner alts have already had
1267         -- mkCase applied to them, so they won't have a case in their default
1268         -- Secondly, if you do, you get an infinite loop, because the bindCaseBndr
1269         -- in munge_rhs may put a case into the DEFAULT branch!
1270   where
1271         -- We are scrutinising the same variable if it's
1272         -- the outer case-binder, or if the outer case scrutinises a variable
1273         -- (and it's the same).  Testing both allows us not to replace the
1274         -- outer scrut-var with the outer case-binder (Simplify.simplCaseBinder).
1275     scruting_same_var = case scrut of
1276                           Var outer_scrut -> \ v -> v == outer_bndr || v == outer_scrut
1277                           other           -> \ v -> v == outer_bndr
1278
1279 ------------------------------------------------
1280 --      Catch-all
1281 ------------------------------------------------
1282
1283 mkAlts dflags scrut case_bndr other_alts = returnSmpl other_alts
1284
1285
1286 ---------------------------------
1287 mergeAlts :: [OutAlt] -> [OutAlt] -> [OutAlt]
1288 -- Merge preserving order; alternatives in the first arg
1289 -- shadow ones in the second
1290 mergeAlts [] as2 = as2
1291 mergeAlts as1 [] = as1
1292 mergeAlts (a1:as1) (a2:as2)
1293   = case a1 `cmpAlt` a2 of
1294         LT -> a1 : mergeAlts as1      (a2:as2)
1295         EQ -> a1 : mergeAlts as1      as2       -- Discard a2
1296         GT -> a2 : mergeAlts (a1:as1) as2
1297 \end{code}
1298
1299
1300
1301 =================================================================================
1302
1303 mkCase1 tries these things
1304
1305 1.  Eliminate the case altogether if possible
1306
1307 2.  Case-identity:
1308
1309         case e of               ===> e
1310                 True  -> True;
1311                 False -> False
1312
1313     and similar friends.
1314
1315
1316 Start with a simple situation:
1317
1318         case x# of      ===>   e[x#/y#]
1319           y# -> e
1320
1321 (when x#, y# are of primitive type, of course).  We can't (in general)
1322 do this for algebraic cases, because we might turn bottom into
1323 non-bottom!
1324
1325 Actually, we generalise this idea to look for a case where we're
1326 scrutinising a variable, and we know that only the default case can
1327 match.  For example:
1328 \begin{verbatim}
1329         case x of
1330           0#    -> ...
1331           other -> ...(case x of
1332                          0#    -> ...
1333                          other -> ...) ...
1334 \end{code}
1335 Here the inner case can be eliminated.  This really only shows up in
1336 eliminating error-checking code.
1337
1338 We also make sure that we deal with this very common case:
1339
1340         case e of
1341           x -> ...x...
1342
1343 Here we are using the case as a strict let; if x is used only once
1344 then we want to inline it.  We have to be careful that this doesn't
1345 make the program terminate when it would have diverged before, so we
1346 check that
1347         - x is used strictly, or
1348         - e is already evaluated (it may so if e is a variable)
1349
1350 Lastly, we generalise the transformation to handle this:
1351
1352         case e of       ===> r
1353            True  -> r
1354            False -> r
1355
1356 We only do this for very cheaply compared r's (constructors, literals
1357 and variables).  If pedantic bottoms is on, we only do it when the
1358 scrutinee is a PrimOp which can't fail.
1359
1360 We do it *here*, looking at un-simplified alternatives, because we
1361 have to check that r doesn't mention the variables bound by the
1362 pattern in each alternative, so the binder-info is rather useful.
1363
1364 So the case-elimination algorithm is:
1365
1366         1. Eliminate alternatives which can't match
1367
1368         2. Check whether all the remaining alternatives
1369                 (a) do not mention in their rhs any of the variables bound in their pattern
1370            and  (b) have equal rhss
1371
1372         3. Check we can safely ditch the case:
1373                    * PedanticBottoms is off,
1374                 or * the scrutinee is an already-evaluated variable
1375                 or * the scrutinee is a primop which is ok for speculation
1376                         -- ie we want to preserve divide-by-zero errors, and
1377                         -- calls to error itself!
1378
1379                 or * [Prim cases] the scrutinee is a primitive variable
1380
1381                 or * [Alg cases] the scrutinee is a variable and
1382                      either * the rhs is the same variable
1383                         (eg case x of C a b -> x  ===>   x)
1384                      or     * there is only one alternative, the default alternative,
1385                                 and the binder is used strictly in its scope.
1386                                 [NB this is helped by the "use default binder where
1387                                  possible" transformation; see below.]
1388
1389
1390 If so, then we can replace the case with one of the rhss.
1391
1392 Further notes about case elimination
1393 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1394 Consider:       test :: Integer -> IO ()
1395                 test = print
1396
1397 Turns out that this compiles to:
1398     Print.test
1399       = \ eta :: Integer
1400           eta1 :: State# RealWorld ->
1401           case PrelNum.< eta PrelNum.zeroInteger of wild { __DEFAULT ->
1402           case hPutStr stdout
1403                  (PrelNum.jtos eta ($w[] @ Char))
1404                  eta1
1405           of wild1 { (# new_s, a4 #) -> PrelIO.lvl23 new_s  }}
1406
1407 Notice the strange '<' which has no effect at all. This is a funny one.
1408 It started like this:
1409
1410 f x y = if x < 0 then jtos x
1411           else if y==0 then "" else jtos x
1412
1413 At a particular call site we have (f v 1).  So we inline to get
1414
1415         if v < 0 then jtos x
1416         else if 1==0 then "" else jtos x
1417
1418 Now simplify the 1==0 conditional:
1419
1420         if v<0 then jtos v else jtos v
1421
1422 Now common-up the two branches of the case:
1423
1424         case (v<0) of DEFAULT -> jtos v
1425
1426 Why don't we drop the case?  Because it's strict in v.  It's technically
1427 wrong to drop even unnecessary evaluations, and in practice they
1428 may be a result of 'seq' so we *definitely* don't want to drop those.
1429 I don't really know how to improve this situation.
1430
1431
1432 \begin{code}
1433 --------------------------------------------------
1434 --      0. Check for empty alternatives
1435 --------------------------------------------------
1436
1437 #ifdef DEBUG
1438 mkCase1 scrut case_bndr ty []
1439   = pprTrace "mkCase1: null alts" (ppr case_bndr <+> ppr scrut) $
1440     returnSmpl scrut
1441 #endif
1442
1443 --------------------------------------------------
1444 --      1. Eliminate the case altogether if poss
1445 --------------------------------------------------
1446
1447 mkCase1 scrut case_bndr ty [(con,bndrs,rhs)]
1448   -- See if we can get rid of the case altogether
1449   -- See the extensive notes on case-elimination above
1450   -- mkCase made sure that if all the alternatives are equal,
1451   -- then there is now only one (DEFAULT) rhs
1452  |  all isDeadBinder bndrs,
1453
1454         -- Check that the scrutinee can be let-bound instead of case-bound
1455     exprOkForSpeculation scrut
1456                 -- OK not to evaluate it
1457                 -- This includes things like (==# a# b#)::Bool
1458                 -- so that we simplify
1459                 --      case ==# a# b# of { True -> x; False -> x }
1460                 -- to just
1461                 --      x
1462                 -- This particular example shows up in default methods for
1463                 -- comparision operations (e.g. in (>=) for Int.Int32)
1464         || exprIsValue scrut                    -- It's already evaluated
1465         || var_demanded_later scrut             -- It'll be demanded later
1466
1467 --      || not opt_SimplPedanticBottoms)        -- Or we don't care!
1468 --      We used to allow improving termination by discarding cases, unless -fpedantic-bottoms was on,
1469 --      but that breaks badly for the dataToTag# primop, which relies on a case to evaluate
1470 --      its argument:  case x of { y -> dataToTag# y }
1471 --      Here we must *not* discard the case, because dataToTag# just fetches the tag from
1472 --      the info pointer.  So we'll be pedantic all the time, and see if that gives any
1473 --      other problems
1474 --      Also we don't want to discard 'seq's
1475   = tick (CaseElim case_bndr)                   `thenSmpl_`
1476     returnSmpl (bindCaseBndr case_bndr scrut rhs)
1477
1478   where
1479         -- The case binder is going to be evaluated later,
1480         -- and the scrutinee is a simple variable
1481     var_demanded_later (Var v) = isStrictDmd (idNewDemandInfo case_bndr)
1482     var_demanded_later other   = False
1483
1484
1485 --------------------------------------------------
1486 --      2. Identity case
1487 --------------------------------------------------
1488
1489 mkCase1 scrut case_bndr ty alts -- Identity case
1490   | all identity_alt alts
1491   = tick (CaseIdentity case_bndr)               `thenSmpl_`
1492     returnSmpl (re_note scrut)
1493   where
1494     identity_alt (con, args, rhs) = de_note rhs `cheapEqExpr` identity_rhs con args
1495
1496     identity_rhs (DataAlt con) args = mkConApp con (arg_tys ++ map varToCoreExpr args)
1497     identity_rhs (LitAlt lit)  _    = Lit lit
1498     identity_rhs DEFAULT       _    = Var case_bndr
1499
1500     arg_tys = map Type (tyConAppArgs (idType case_bndr))
1501
1502         -- We've seen this:
1503         --      case coerce T e of x { _ -> coerce T' x }
1504         -- And we definitely want to eliminate this case!
1505         -- So we throw away notes from the RHS, and reconstruct
1506         -- (at least an approximation) at the other end
1507     de_note (Note _ e) = de_note e
1508     de_note e          = e
1509
1510         -- re_note wraps a coerce if it might be necessary
1511     re_note scrut = case head alts of
1512                         (_,_,rhs1@(Note _ _)) -> mkCoerce2 (exprType rhs1) (idType case_bndr) scrut
1513                         other                 -> scrut
1514
1515
1516 --------------------------------------------------
1517 --      Catch-all
1518 --------------------------------------------------
1519 mkCase1 scrut bndr ty alts = returnSmpl (Case scrut bndr ty alts)
1520 \end{code}
1521
1522
1523 When adding auxiliary bindings for the case binder, it's worth checking if
1524 its dead, because it often is, and occasionally these mkCase transformations
1525 cascade rather nicely.
1526
1527 \begin{code}
1528 bindCaseBndr bndr rhs body
1529   | isDeadBinder bndr = body
1530   | otherwise         = bindNonRec bndr rhs body
1531 \end{code}