ghc/compiler/simplCore/Simplify.lhs

   1
   2 % (c) The AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[Simplify]{The main module of the simplifier}
   5
   6 \begin{code}
   7 module Simplify ( simplTopBinds, simplExpr ) where
   8
   9 #include "HsVersions.h"
  10
  11 import CmdLineOpts      ( intSwitchSet,
  12                           opt_SccProfilingOn, opt_PprStyle_Debug, opt_SimplDoEtaReduction,
  13                           opt_SimplNoPreInlining, opt_DictsStrict, opt_SimplPedanticBottoms,
  14                           opt_SimplDoCaseElim,
  15                           SimplifierSwitch(..)
  16                         )
  17 import SimplMonad
  18 import SimplUtils       ( mkCase, transformRhs, findAlt,
  19                           simplBinder, simplBinders, simplIds, findDefault, mkCoerce
  20                         )
  21 import Var              ( TyVar, mkSysTyVar, tyVarKind, maybeModifyIdInfo )
  22 import VarEnv
  23 import VarSet
  24 import Id               ( Id, idType, idInfo, idUnique,
  25                           getIdUnfolding, setIdUnfolding, isExportedId,
  26                           getIdSpecialisation, setIdSpecialisation,
  27                           getIdDemandInfo, setIdDemandInfo,
  28                           getIdArity, setIdArity,
  29                           getIdStrictness,
  30                           setInlinePragma, getInlinePragma, idMustBeINLINEd,
  31                           setOneShotLambda
  32                         )
  33 import IdInfo           ( InlinePragInfo(..), OccInfo(..), StrictnessInfo(..),
  34                           ArityInfo(..), atLeastArity, arityLowerBound, unknownArity,
  35                           specInfo, inlinePragInfo, zapLamIdInfo
  36                         )
  37 import Demand           ( Demand, isStrict, wwLazy )
  38 import Const            ( isWHNFCon, conOkForAlt )
  39 import ConFold          ( tryPrimOp )
  40 import PrimOp           ( PrimOp, primOpStrictness, primOpType )
  41 import DataCon          ( DataCon, dataConNumInstArgs, dataConRepStrictness, dataConSig, dataConArgTys )
  42 import Const            ( Con(..) )
  43 import Name             ( isLocallyDefined )
  44 import CoreSyn
  45 import CoreFVs          ( exprFreeVars )
  46 import CoreUnfold       ( Unfolding(..), mkUnfolding, callSiteInline,
  47                           isEvaldUnfolding, blackListed )
  48 import CoreUtils        ( cheapEqExpr, exprIsDupable, exprIsWHNF, exprIsTrivial,
  49                           coreExprType, coreAltsType, exprArity, exprIsValue,
  50                           exprOkForSpeculation
  51                         )
  52 import Rules            ( lookupRule )
  53 import CostCentre       ( isSubsumedCCS, currentCCS, isEmptyCC )
  54 import Type             ( Type, mkTyVarTy, mkTyVarTys, isUnLiftedType,
  55                           mkFunTy, splitFunTys, splitTyConApp_maybe, splitFunTy_maybe,
  56                           funResultTy, isDictTy, isDataType, applyTy, applyTys, mkFunTys
  57                         )
  58 import Subst            ( Subst, mkSubst, emptySubst, substExpr, substTy,
  59                           substEnv, lookupInScope, lookupSubst, substRules
  60                         )
  61 import TyCon            ( isDataTyCon, tyConDataCons, tyConClass_maybe, tyConArity, isDataTyCon )
  62 import TysPrim          ( realWorldStatePrimTy )
  63 import PrelInfo         ( realWorldPrimId )
  64 import BasicTypes       ( TopLevelFlag(..), isTopLevel )
  65 import Maybes           ( maybeToBool )
  66 import Util             ( zipWithEqual, stretchZipEqual, lengthExceeds )
  67 import PprCore
  68 import Outputable
  69 \end{code}
  70
  71
  72 The guts of the simplifier is in this module, but the driver
  73 loop for the simplifier is in SimplCore.lhs.
  74
  75
  76 %************************************************************************
  77 %*                                                                      *
  78 \subsection{Bindings}
  79 %*                                                                      *
  80 %************************************************************************
  81
  82 \begin{code}
  83 simplTopBinds :: [InBind] -> SimplM [OutBind]
  84
  85 simplTopBinds binds
  86   =     -- Put all the top-level binders into scope at the start
  87         -- so that if a transformation rule has unexpectedly brought
  88         -- anything into scope, then we don't get a complaint about that.
  89         -- It's rather as if the top-level binders were imported.
  90     extendInScopes top_binders  $
  91     simpl_binds binds           `thenSmpl` \ (binds', _) ->
  92     freeTick SimplifierDone     `thenSmpl_`
  93     returnSmpl binds'
  94   where
  95     top_binders = bindersOfBinds binds
  96
  97     simpl_binds []                        = returnSmpl ([], panic "simplTopBinds corner")
  98     simpl_binds (NonRec bndr rhs : binds) = simplLazyBind TopLevel bndr  bndr rhs        (simpl_binds binds)
  99     simpl_binds (Rec pairs       : binds) = simplRecBind  TopLevel pairs (map fst pairs) (simpl_binds binds)
 100
 101
 102 simplRecBind :: TopLevelFlag -> [(InId, InExpr)] -> [OutId]
 103              -> SimplM (OutStuff a) -> SimplM (OutStuff a)
 104 simplRecBind top_lvl pairs bndrs' thing_inside
 105   = go pairs bndrs'             `thenSmpl` \ (binds', stuff) ->
 106     returnSmpl (addBind (Rec (flattenBinds binds')) stuff)
 107   where
 108     go [] _ = thing_inside      `thenSmpl` \ stuff ->
 109               returnSmpl ([], stuff)
 110
 111     go ((bndr, rhs) : pairs) (bndr' : bndrs')
 112         = simplLazyBind top_lvl bndr bndr' rhs (go pairs bndrs')
 113                 -- Don't float unboxed bindings out,
 114                 -- because we can't "rec" them
 115 \end{code}
 116
 117
 118 %************************************************************************
 119 %*                                                                      *
 120 \subsection[Simplify-simplExpr]{The main function: simplExpr}
 121 %*                                                                      *
 122 %************************************************************************
 123
 124 \begin{code}
 125 addBind :: CoreBind -> OutStuff a -> OutStuff a
 126 addBind bind    (binds,  res) = (bind:binds,     res)
 127
 128 addBinds :: [CoreBind] -> OutStuff a -> OutStuff a
 129 addBinds []     stuff         = stuff
 130 addBinds binds1 (binds2, res) = (binds1++binds2, res)
 131 \end{code}
 132
 133 The reason for this OutExprStuff stuff is that we want to float *after*
 134 simplifying a RHS, not before.  If we do so naively we get quadratic
 135 behaviour as things float out.
 136
 137 To see why it's important to do it after, consider this (real) example:
 138
 139         let t = f x
 140         in fst t
 141 ==>
 142         let t = let a = e1
 143                     b = e2
 144                 in (a,b)
 145         in fst t
 146 ==>
 147         let a = e1
 148             b = e2
 149             t = (a,b)
 150         in
 151         a       -- Can't inline a this round, cos it appears twice
 152 ==>
 153         e1
 154
 155 Each of the ==> steps is a round of simplification.  We'd save a
 156 whole round if we float first.  This can cascade.  Consider
 157
 158         let f = g d
 159         in \x -> ...f...
 160 ==>
 161         let f = let d1 = ..d.. in \y -> e
 162         in \x -> ...f...
 163 ==>
 164         let d1 = ..d..
 165         in \x -> ...(\y ->e)...
 166
 167 Only in this second round can the \y be applied, and it
 168 might do the same again.
 169
 170
 171 \begin{code}
 172 simplExpr :: CoreExpr -> SimplM CoreExpr
 173 simplExpr expr = getSubst       `thenSmpl` \ subst ->
 174                  simplExprC expr (Stop (substTy subst (coreExprType expr)))
 175         -- The type in the Stop continuation is usually not used
 176         -- It's only needed when discarding continuations after finding
 177         -- a function that returns bottom
 178
 179 simplExprC :: CoreExpr -> SimplCont -> SimplM CoreExpr
 180         -- Simplify an expression, given a continuation
 181
 182 simplExprC expr cont = simplExprF expr cont     `thenSmpl` \ (floats, (_, body)) ->
 183                        returnSmpl (mkLets floats body)
 184
 185 simplExprF :: InExpr -> SimplCont -> SimplM OutExprStuff
 186         -- Simplify an expression, returning floated binds
 187
 188 simplExprF (Var v) cont
 189   = simplVar v cont
 190
 191 simplExprF expr@(Con (PrimOp op) args) cont
 192   = getSubstEnv                         `thenSmpl` \ se ->
 193     prepareArgs (ppr op)
 194                 (primOpType op)
 195                 (primOpStrictness op)
 196                 (pushArgs se args cont) $ \ args1 cont1 ->
 197
 198     let
 199         -- Boring... we may have too many arguments now, so we push them back
 200         n_args = length args
 201         args2 = ASSERT( length args1 >= n_args )
 202                  take n_args args1
 203         cont2 = pushArgs emptySubstEnv (drop n_args args1) cont1
 204     in
 205         --      Try the prim op simplification
 206         -- It's really worth trying simplExpr again if it succeeds,
 207         -- because you can find
 208         --      case (eqChar# x 'a') of ...
 209         -- ==>
 210         --      case (case x of 'a' -> True; other -> False) of ...
 211      case tryPrimOp op args2 of
 212           Just e' -> zapSubstEnv (simplExprF e' cont2)
 213           Nothing -> rebuild (Con (PrimOp op) args2) cont2
 214
 215 simplExprF (Con con@(DataCon _) args) cont
 216   = freeTick LeafVisit                  `thenSmpl_`
 217     simplConArgs args           ( \ args' ->
 218     rebuild (Con con args') cont)
 219
 220 simplExprF expr@(Con con@(Literal _) args) cont
 221   = ASSERT( null args )
 222     freeTick LeafVisit                  `thenSmpl_`
 223     rebuild expr cont
 224
 225 simplExprF (App fun arg) cont
 226   = getSubstEnv         `thenSmpl` \ se ->
 227     simplExprF fun (ApplyTo NoDup arg se cont)
 228
 229 simplExprF (Case scrut bndr alts) cont
 230   = getSubstEnv         `thenSmpl` \ se ->
 231     simplExprF scrut (Select NoDup bndr alts se cont)
 232
 233
 234 simplExprF (Let (Rec pairs) body) cont
 235   = simplIds (map fst pairs)            $ \ bndrs' ->
 236         -- NB: bndrs' don't have unfoldings or spec-envs
 237         -- We add them as we go down, using simplPrags
 238
 239     simplRecBind NotTopLevel pairs bndrs' (simplExprF body cont)
 240
 241 simplExprF expr@(Lam _ _) cont = simplLam expr cont
 242
 243 simplExprF (Type ty) cont
 244   = ASSERT( case cont of { Stop _ -> True; ArgOf _ _ _ -> True; other -> False } )
 245     simplType ty        `thenSmpl` \ ty' ->
 246     rebuild (Type ty') cont
 247
 248 simplExprF (Note (Coerce to from) e) cont
 249   | to == from = simplExprF e cont
 250   | otherwise  = getSubst               `thenSmpl` \ subst ->
 251                  simplExprF e (CoerceIt (substTy subst to) cont)
 252
 253 -- hack: we only distinguish subsumed cost centre stacks for the purposes of
 254 -- inlining.  All other CCCSs are mapped to currentCCS.
 255 simplExprF (Note (SCC cc) e) cont
 256   = setEnclosingCC currentCCS $
 257     simplExpr e         `thenSmpl` \ e ->
 258     rebuild (mkNote (SCC cc) e) cont
 259
 260 simplExprF (Note InlineCall e) cont
 261   = simplExprF e (InlinePlease cont)
 262
 263 -- Comments about the InlineMe case
 264 -- ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 265 -- Don't inline in the RHS of something that has an
 266 -- inline pragma.  But be careful that the InScopeEnv that
 267 -- we return does still have inlinings on!
 268 --
 269 -- It really is important to switch off inlinings.  This function
 270 -- may be inlinined in other modules, so we don't want to remove
 271 -- (by inlining) calls to functions that have specialisations, or
 272 -- that may have transformation rules in an importing scope.
 273 -- E.g.         {-# INLINE f #-}
 274 --              f x = ...g...
 275 -- and suppose that g is strict *and* has specialisations.
 276 -- If we inline g's wrapper, we deny f the chance of getting
 277 -- the specialised version of g when f is inlined at some call site
 278 -- (perhaps in some other module).
 279
 280 simplExprF (Note InlineMe e) cont
 281   = case cont of
 282         Stop _ ->       -- Totally boring continuation
 283                         -- Don't inline inside an INLINE expression
 284                   switchOffInlining (simplExpr e)       `thenSmpl` \ e' ->
 285                   rebuild (mkNote InlineMe e') cont
 286
 287         other  ->       -- Dissolve the InlineMe note if there's
 288                         -- an interesting context of any kind to combine with
 289                         -- (even a type application -- anything except Stop)
 290                   simplExprF e cont
 291
 292 -- A non-recursive let is dealt with by simplBeta
 293 simplExprF (Let (NonRec bndr rhs) body) cont
 294   = getSubstEnv                 `thenSmpl` \ se ->
 295     simplBeta bndr rhs se (contResultType cont) $
 296     simplExprF body cont
 297 \end{code}
 298
 299
 300 ---------------------------------
 301
 302 \begin{code}
 303 simplLam fun cont
 304   = go fun cont
 305   where
 306     zap_it = mkLamBndrZapper fun (countArgs cont)
 307     cont_ty = contResultType cont
 308
 309         -- Type-beta reduction
 310     go (Lam bndr body) (ApplyTo _ (Type ty_arg) arg_se body_cont)
 311       = ASSERT( isTyVar bndr )
 312         tick (BetaReduction bndr)               `thenSmpl_`
 313         getInScope                              `thenSmpl` \ in_scope ->
 314         let
 315                 ty' = substTy (mkSubst in_scope arg_se) ty_arg
 316         in
 317         extendSubst bndr (DoneTy ty')
 318         (go body body_cont)
 319
 320         -- Ordinary beta reduction
 321     go (Lam bndr body) cont@(ApplyTo _ arg arg_se body_cont)
 322       = tick (BetaReduction bndr)                       `thenSmpl_`
 323         simplBeta zapped_bndr arg arg_se cont_ty
 324         (go body body_cont)
 325       where
 326         zapped_bndr = zap_it bndr
 327
 328         -- Not enough args
 329     go lam@(Lam _ _) cont = completeLam [] lam cont
 330
 331         -- Exactly enough args
 332     go expr cont = simplExprF expr cont
 333
 334
 335 -- completeLam deals with the case where a lambda doesn't have an ApplyTo
 336 -- continuation.  Try for eta reduction, but *only* if we get all
 337 -- the way to an exprIsTrivial expression.
 338 -- 'acc' holds the simplified binders, in reverse order
 339
 340 completeLam acc (Lam bndr body) cont
 341   = simplBinder bndr                    $ \ bndr' ->
 342     completeLam (bndr':acc) body cont
 343
 344 completeLam acc body cont
 345   = simplExpr body                      `thenSmpl` \ body' ->
 346
 347     case (opt_SimplDoEtaReduction, check_eta acc body') of
 348         (True, Just body'')     -- Eta reduce!
 349                 -> tick (EtaReduction (head acc))       `thenSmpl_`
 350                    rebuild body'' cont
 351
 352         other   ->      -- No eta reduction
 353                    rebuild (foldl (flip Lam) body' acc) cont
 354                         -- Remember, acc is the reversed binders
 355   where
 356         -- NB: the binders are reversed
 357     check_eta (b : bs) (App fun arg)
 358         |  (varToCoreExpr b `cheapEqExpr` arg)
 359         = check_eta bs fun
 360
 361     check_eta [] body
 362         | exprIsTrivial body &&                 -- ONLY if the body is trivial
 363           not (any (`elemVarSet` body_fvs) acc)
 364         = Just body             -- Success!
 365         where
 366           body_fvs = exprFreeVars body
 367
 368     check_eta _ _ = Nothing     -- Bale out
 369
 370 mkLamBndrZapper :: CoreExpr     -- Function
 371                 -> Int          -- Number of args
 372                 -> Id -> Id     -- Use this to zap the binders
 373 mkLamBndrZapper fun n_args
 374   | n_args >= n_params fun = \b -> b            -- Enough args
 375   | otherwise              = \b -> maybeModifyIdInfo zapLamIdInfo b
 376   where
 377     n_params (Lam b e) | isId b    = 1 + n_params e
 378                        | otherwise = n_params e
 379     n_params other                 = 0::Int
 380 \end{code}
 381
 382
 383 ---------------------------------
 384 simplConArgs makes sure that the arguments all end up being atomic.
 385 That means it may generate some Lets, hence the strange type
 386
 387 \begin{code}
 388 simplConArgs :: [InArg] -> ([OutArg] -> SimplM OutExprStuff) -> SimplM OutExprStuff
 389 simplConArgs [] thing_inside
 390   = thing_inside []
 391
 392 simplConArgs (arg:args) thing_inside
 393   = switchOffInlining (simplExpr arg)   `thenSmpl` \ arg' ->
 394         -- Simplify the RHS with inlining switched off, so that
 395         -- only absolutely essential things will happen.
 396
 397     simplConArgs args                           $ \ args' ->
 398
 399         -- If the argument ain't trivial, then let-bind it
 400     if exprIsTrivial arg' then
 401         thing_inside (arg' : args')
 402     else
 403         newId (coreExprType arg')               $ \ arg_id ->
 404         thing_inside (Var arg_id : args')       `thenSmpl` \ res ->
 405         returnSmpl (addBind (NonRec arg_id arg') res)
 406 \end{code}
 407
 408
 409 ---------------------------------
 410 \begin{code}
 411 simplType :: InType -> SimplM OutType
 412 simplType ty
 413   = getSubst    `thenSmpl` \ subst ->
 414     returnSmpl (substTy subst ty)
 415 \end{code}
 416
 417
 418 %************************************************************************
 419 %*                                                                      *
 420 \subsection{Binding}
 421 %*                                                                      *
 422 %************************************************************************
 423
 424 @simplBeta@ is used for non-recursive lets in expressions,
 425 as well as true beta reduction.
 426
 427 Very similar to @simplLazyBind@, but not quite the same.
 428
 429 \begin{code}
 430 simplBeta :: InId                       -- Binder
 431           -> InExpr -> SubstEnv         -- Arg, with its subst-env
 432           -> OutType                    -- Type of thing computed by the context
 433           -> SimplM OutExprStuff        -- The body
 434           -> SimplM OutExprStuff
 435 #ifdef DEBUG
 436 simplBeta bndr rhs rhs_se cont_ty thing_inside
 437   | isTyVar bndr
 438   = pprPanic "simplBeta" (ppr bndr <+> ppr rhs)
 439 #endif
 440
 441 simplBeta bndr rhs rhs_se cont_ty thing_inside
 442   | preInlineUnconditionally bndr && not opt_SimplNoPreInlining
 443   = tick (PreInlineUnconditionally bndr)                `thenSmpl_`
 444     extendSubst bndr (ContEx rhs_se rhs) thing_inside
 445
 446   | otherwise
 447   =     -- Simplify the RHS
 448     simplBinder bndr                                    $ \ bndr' ->
 449     simplArg (idType bndr') (getIdDemandInfo bndr)
 450              rhs rhs_se cont_ty                         $ \ rhs' ->
 451
 452         -- Now complete the binding and simplify the body
 453     completeBeta bndr bndr' rhs' thing_inside
 454
 455 completeBeta bndr bndr' rhs' thing_inside
 456   | isUnLiftedType (idType bndr') && not (exprOkForSpeculation rhs')
 457         -- Make a case expression instead of a let
 458         -- These can arise either from the desugarer,
 459         -- or from beta reductions: (\x.e) (x +# y)
 460   = getInScope                  `thenSmpl` \ in_scope ->
 461     thing_inside                `thenSmpl` \ (floats, (_, body)) ->
 462     returnSmpl ([], (in_scope, Case rhs' bndr' [(DEFAULT, [], mkLets floats body)]))
 463
 464   | otherwise
 465   = completeBinding bndr bndr' rhs' thing_inside
 466 \end{code}
 467
 468
 469 \begin{code}
 470 simplArg :: OutType -> Demand
 471          -> InExpr -> SubstEnv
 472          -> OutType             -- Type of thing computed by the context
 473          -> (OutExpr -> SimplM OutExprStuff)
 474          -> SimplM OutExprStuff
 475 simplArg arg_ty demand arg arg_se cont_ty thing_inside
 476   | isStrict demand ||
 477     isUnLiftedType arg_ty ||
 478     (opt_DictsStrict && isDictTy arg_ty && isDataType arg_ty)
 479         -- Return true only for dictionary types where the dictionary
 480         -- has more than one component (else we risk poking on the component
 481         -- of a newtype dictionary)
 482   = getSubstEnv                                 `thenSmpl` \ body_se ->
 483     transformRhs arg                            `thenSmpl` \ t_arg ->
 484     setSubstEnv arg_se (simplExprF t_arg (ArgOf NoDup cont_ty $ \ arg' ->
 485     setSubstEnv body_se (thing_inside arg')
 486     ))  -- NB: we must restore body_se before carrying on with thing_inside!!
 487
 488   | otherwise
 489   = simplRhs NotTopLevel True arg_ty arg arg_se thing_inside
 490 \end{code}
 491
 492
 493 completeBinding
 494         - deals only with Ids, not TyVars
 495         - take an already-simplified RHS
 496
 497 It does *not* attempt to do let-to-case.  Why?  Because they are used for
 498
 499         - top-level bindings
 500                 (when let-to-case is impossible)
 501
 502         - many situations where the "rhs" is known to be a WHNF
 503                 (so let-to-case is inappropriate).
 504
 505 \begin{code}
 506 completeBinding :: InId                 -- Binder
 507                 -> OutId                -- New binder
 508                 -> OutExpr              -- Simplified RHS
 509                 -> SimplM (OutStuff a)  -- Thing inside
 510                 -> SimplM (OutStuff a)
 511
 512 completeBinding old_bndr new_bndr new_rhs thing_inside
 513   |  isDeadBinder old_bndr      -- This happens; for example, the case_bndr during case of
 514                                 -- known constructor:  case (a,b) of x { (p,q) -> ... }
 515                                 -- Here x isn't mentioned in the RHS, so we don't want to
 516                                 -- create the (dead) let-binding  let x = (a,b) in ...
 517   =  thing_inside
 518
 519   |  postInlineUnconditionally old_bndr new_rhs
 520         -- Maybe we don't need a let-binding!  Maybe we can just
 521         -- inline it right away.  Unlike the preInlineUnconditionally case
 522         -- we are allowed to look at the RHS.
 523         --
 524         -- NB: a loop breaker never has postInlineUnconditionally True
 525         -- and non-loop-breakers only have *forward* references
 526         -- Hence, it's safe to discard the binding
 527   =  tick (PostInlineUnconditionally old_bndr)  `thenSmpl_`
 528      extendSubst old_bndr (DoneEx new_rhs)
 529      thing_inside
 530
 531   |  otherwise
 532   =  getSubst                   `thenSmpl` \ subst ->
 533      let
 534         bndr_info = idInfo old_bndr
 535         old_rules = specInfo bndr_info
 536         new_rules = substRules subst old_rules
 537
 538         -- The new binding site Id needs its specialisations re-attached
 539         bndr_w_arity = new_bndr `setIdArity` ArityAtLeast (exprArity new_rhs)
 540
 541         binding_site_id
 542           | isEmptyCoreRules old_rules = bndr_w_arity
 543           | otherwise                  = bndr_w_arity `setIdSpecialisation` new_rules
 544
 545         -- At the occurrence sites we want to know the unfolding,
 546         -- and the occurrence info of the original
 547         -- (simplBinder cleaned up the inline prag of the original
 548         --  to eliminate un-stable info, in case this expression is
 549         --  simplified a second time; hence the need to reattach it)
 550         occ_site_id = binding_site_id
 551                       `setIdUnfolding` mkUnfolding new_rhs
 552                       `setInlinePragma` inlinePragInfo bndr_info
 553      in
 554      modifyInScope occ_site_id thing_inside     `thenSmpl` \ stuff ->
 555      returnSmpl (addBind (NonRec binding_site_id new_rhs) stuff)
 556 \end{code}
 557
 558
 559 %************************************************************************
 560 %*                                                                      *
 561 \subsection{simplLazyBind}
 562 %*                                                                      *
 563 %************************************************************************
 564
 565 simplLazyBind basically just simplifies the RHS of a let(rec).
 566 It does two important optimisations though:
 567
 568         * It floats let(rec)s out of the RHS, even if they
 569           are hidden by big lambdas
 570
 571         * It does eta expansion
 572
 573 \begin{code}
 574 simplLazyBind :: TopLevelFlag
 575               -> InId -> OutId
 576               -> InExpr                 -- The RHS
 577               -> SimplM (OutStuff a)    -- The body of the binding
 578               -> SimplM (OutStuff a)
 579 -- When called, the subst env is correct for the entire let-binding
 580 -- and hence right for the RHS.
 581 -- Also the binder has already been simplified, and hence is in scope
 582
 583 simplLazyBind top_lvl bndr bndr' rhs thing_inside
 584   | preInlineUnconditionally bndr && not opt_SimplNoPreInlining
 585   = tick (PreInlineUnconditionally bndr)                `thenSmpl_`
 586     getSubstEnv                                         `thenSmpl` \ rhs_se ->
 587     (extendSubst bndr (ContEx rhs_se rhs) thing_inside)
 588
 589   | otherwise
 590   =     -- Simplify the RHS
 591     getSubstEnv                                         `thenSmpl` \ rhs_se ->
 592
 593     simplRhs top_lvl False {- Not ok to float unboxed -}
 594              (idType bndr')
 595              rhs rhs_se                                 $ \ rhs' ->
 596
 597         -- Now compete the binding and simplify the body
 598     completeBinding bndr bndr' rhs' thing_inside
 599 \end{code}
 600
 601
 602
 603 \begin{code}
 604 simplRhs :: TopLevelFlag
 605          -> Bool                -- True <=> OK to float unboxed (speculative) bindings
 606          -> OutType -> InExpr -> SubstEnv
 607          -> (OutExpr -> SimplM (OutStuff a))
 608          -> SimplM (OutStuff a)
 609 simplRhs top_lvl float_ubx rhs_ty rhs rhs_se thing_inside
 610   =     -- Swizzle the inner lets past the big lambda (if any)
 611         -- and try eta expansion
 612     transformRhs rhs                                    `thenSmpl` \ t_rhs ->
 613
 614         -- Simplify it
 615     setSubstEnv rhs_se (simplExprF t_rhs (Stop rhs_ty)) `thenSmpl` \ (floats, (in_scope', rhs')) ->
 616
 617         -- Float lets out of RHS
 618     let
 619         (floats_out, rhs'') | float_ubx = (floats, rhs')
 620                             | otherwise = splitFloats floats rhs'
 621     in
 622     if (isTopLevel top_lvl || exprIsWHNF rhs') &&       -- Float lets if (a) we're at the top level
 623         not (null floats_out)                           -- or            (b) it exposes a HNF
 624     then
 625         tickLetFloat floats_out                         `thenSmpl_`
 626                 -- Do the float
 627                 --
 628                 -- There's a subtlety here.  There may be a binding (x* = e) in the
 629                 -- floats, where the '*' means 'will be demanded'.  So is it safe
 630                 -- to float it out?  Answer no, but it won't matter because
 631                 -- we only float if arg' is a WHNF,
 632                 -- and so there can't be any 'will be demanded' bindings in the floats.
 633                 -- Hence the assert
 634         WARN( any demanded_float floats_out, ppr floats_out )
 635         setInScope in_scope' (thing_inside rhs'')       `thenSmpl` \ stuff ->
 636                 -- in_scope' may be excessive, but that's OK;
 637                 -- it's a superset of what's in scope
 638         returnSmpl (addBinds floats_out stuff)
 639     else
 640                 -- Don't do the float
 641         thing_inside (mkLets floats rhs')
 642
 643 -- In a let-from-let float, we just tick once, arbitrarily
 644 -- choosing the first floated binder to identify it
 645 tickLetFloat (NonRec b r      : fs) = tick (LetFloatFromLet b)
 646 tickLetFloat (Rec ((b,r):prs) : fs) = tick (LetFloatFromLet b)
 647
 648 demanded_float (NonRec b r) = isStrict (getIdDemandInfo b) && not (isUnLiftedType (idType b))
 649                 -- Unlifted-type (cheap-eagerness) lets may well have a demanded flag on them
 650 demanded_float (Rec _)      = False
 651
 652 -- Don't float any unlifted bindings out, because the context
 653 -- is either a Rec group, or the top level, neither of which
 654 -- can tolerate them.
 655 splitFloats floats rhs
 656   = go floats
 657   where
 658     go []                   = ([], rhs)
 659     go (f:fs) | must_stay f = ([], mkLets (f:fs) rhs)
 660               | otherwise   = case go fs of
 661                                    (out, rhs') -> (f:out, rhs')
 662
 663     must_stay (Rec prs)    = False      -- No unlifted bindings in here
 664     must_stay (NonRec b r) = isUnLiftedType (idType b)
 665 \end{code}
 666
 667
 668
 669 %************************************************************************
 670 %*                                                                      *
 671 \subsection{Variables}
 672 %*                                                                      *
 673 %************************************************************************
 674
 675 \begin{code}
 676 simplVar var cont
 677   = freeTick LeafVisit  `thenSmpl_`
 678     getSubst            `thenSmpl` \ subst ->
 679     case lookupSubst subst var of
 680         Just (DoneEx (Var v)) -> zapSubstEnv (simplVar v cont)
 681         Just (DoneEx e)       -> zapSubstEnv (simplExprF e cont)
 682         Just (ContEx env' e)  -> setSubstEnv env' (simplExprF e cont)
 683
 684         Nothing -> let
 685                         var' = case lookupInScope subst var of
 686                                  Just v' -> v'
 687                                  Nothing ->
 688 #ifdef DEBUG
 689                                             if isLocallyDefined var && not (idMustBeINLINEd var)
 690                                                 -- The idMustBeINLINEd test accouunts for the fact
 691                                                 -- that class dictionary constructors don't have top level
 692                                                 -- bindings and hence aren't in scope.
 693                                             then
 694                                                 -- Not in scope
 695                                                 pprTrace "simplVar:" (ppr var) var
 696                                             else
 697 #endif
 698                                             var
 699                    in
 700                    getBlackList         `thenSmpl` \ black_list ->
 701                    getInScope           `thenSmpl` \ in_scope ->
 702
 703                    prepareArgs (ppr var') (idType var') (get_str var') cont     $ \ args' cont' ->
 704                    completeCall black_list in_scope var' args' cont'
 705   where
 706     get_str var = case getIdStrictness var of
 707                         NoStrictnessInfo                  -> (repeat wwLazy, False)
 708                         StrictnessInfo demands result_bot -> (demands, result_bot)
 709
 710
 711 ---------------------------------------------------------
 712 --      Preparing arguments for a call
 713
 714 prepareArgs :: SDoc     -- Error message info
 715             -> OutType -> ([Demand],Bool) -> SimplCont
 716             -> ([OutExpr] -> SimplCont -> SimplM OutExprStuff)
 717             -> SimplM OutExprStuff
 718
 719 prepareArgs pp_fun orig_fun_ty (fun_demands, result_bot) orig_cont thing_inside
 720   = go [] demands orig_fun_ty orig_cont
 721   where
 722     not_enough_args = fun_demands `lengthExceeds` countValArgs orig_cont
 723         -- "No strictness info" is signalled by an infinite list of wwLazy
 724
 725     demands | not_enough_args = repeat wwLazy                   -- Not enough args, or no strictness
 726             | result_bot      = fun_demands                     -- Enough args, and function returns bottom
 727             | otherwise       = fun_demands ++ repeat wwLazy    -- Enough args and function does not return bottom
 728         -- NB: demands is finite iff enough args and result_bot is True
 729
 730         -- Main game plan: loop through the arguments, simplifying
 731         -- each of them in turn.  We carry with us a list of demands,
 732         -- and the type of the function-applied-to-earlier-args
 733
 734         -- Type argument
 735     go acc ds fun_ty (ApplyTo _ arg@(Type ty_arg) se cont)
 736         = getInScope            `thenSmpl` \ in_scope ->
 737           let
 738                 ty_arg' = substTy (mkSubst in_scope se) ty_arg
 739                 res_ty  = applyTy fun_ty ty_arg'
 740           in
 741           go (Type ty_arg' : acc) ds res_ty cont
 742
 743         -- Value argument
 744     go acc (d:ds) fun_ty (ApplyTo _ val_arg se cont)
 745         = case splitFunTy_maybe fun_ty of {
 746                 Nothing -> pprTrace "prepareArgs" (pp_fun $$ ppr orig_fun_ty $$ ppr orig_cont)
 747                            (thing_inside (reverse acc) cont) ;
 748                 Just (arg_ty, res_ty) ->
 749           simplArg arg_ty d val_arg se (contResultType cont)    $ \ arg' ->
 750           go (arg':acc) ds res_ty cont }
 751
 752         -- We've run out of demands, which only happens for functions
 753         -- we *know* now return bottom
 754         -- This deals with
 755         --      * case (error "hello") of { ... }
 756         --      * (error "Hello") arg
 757         --      * f (error "Hello") where f is strict
 758         --      etc
 759     go acc [] fun_ty cont = tick_case_of_error cont             `thenSmpl_`
 760                             thing_inside (reverse acc) (discardCont cont)
 761
 762         -- We're run out of arguments
 763     go acc ds fun_ty cont = thing_inside (reverse acc) cont
 764
 765 -- Boring: we must only record a tick if there was an interesting
 766 --         continuation to discard.  If not, we tick forever.
 767 tick_case_of_error (Stop _)              = returnSmpl ()
 768 tick_case_of_error (CoerceIt _ (Stop _)) = returnSmpl ()
 769 tick_case_of_error other                 = tick BottomFound
 770
 771 ---------------------------------------------------------
 772 --      Dealing with a call
 773
 774 completeCall black_list_fn in_scope var args cont
 775         -- Look for rules or specialisations that match
 776         -- Do this *before* trying inlining because some functions
 777         -- have specialisations *and* are strict; we don't want to
 778         -- inline the wrapper of the non-specialised thing... better
 779         -- to call the specialised thing instead.
 780   | maybeToBool maybe_rule_match
 781   = tick (RuleFired rule_name)                  `thenSmpl_`
 782     zapSubstEnv (completeApp rule_rhs rule_args cont)
 783         -- See note below about zapping the substitution here
 784
 785         -- Look for an unfolding. There's a binding for the
 786         -- thing, but perhaps we want to inline it anyway
 787   | maybeToBool maybe_inline
 788   = tick (UnfoldingDone var)            `thenSmpl_`
 789     zapSubstEnv (completeInlining var unf_template args (discardInlineCont cont))
 790                 -- The template is already simplified, so don't re-substitute.
 791                 -- This is VITAL.  Consider
 792                 --      let x = e in
 793                 --      let y = \z -> ...x... in
 794                 --      \ x -> ...y...
 795                 -- We'll clone the inner \x, adding x->x' in the id_subst
 796                 -- Then when we inline y, we must *not* replace x by x' in
 797                 -- the inlined copy!!
 798
 799   | otherwise           -- Neither rule nor inlining
 800   = rebuild (mkApps (Var var) args) cont
 801
 802   where
 803         ---------- Unfolding stuff
 804     maybe_inline  = callSiteInline black_listed inline_call
 805                                    var args interesting_cont
 806     Just unf_template = maybe_inline
 807     interesting_cont  = contIsInteresting cont
 808     inline_call       = contIsInline cont
 809     black_listed      = black_list_fn var
 810
 811         ---------- Specialisation stuff
 812     maybe_rule_match           = lookupRule in_scope var args
 813     Just (rule_name, rule_rhs, rule_args) = maybe_rule_match
 814
 815
 816 -- First a special case
 817 -- Don't actually inline the scrutinee when we see
 818 --      case x of y { .... }
 819 -- and x has unfolding (C a b).  Why not?  Because
 820 -- we get a silly binding y = C a b.  If we don't
 821 -- inline knownCon can directly substitute x for y instead.
 822 completeInlining var (Con con con_args) args (Select _ bndr alts se cont)
 823   | conOkForAlt con
 824   = ASSERT( null args )
 825     knownCon (Var var) con con_args bndr alts se cont
 826
 827 -- Now the normal case
 828 completeInlining var unfolding args cont
 829   = completeApp unfolding args cont
 830
 831 -- completeApp applies a new InExpr (from an unfolding or rule)
 832 -- to an *already simplified* set of arguments
 833 completeApp :: InExpr                   -- (\xs. body)
 834             -> [OutExpr]                -- Args; already simplified
 835             -> SimplCont                -- What to do with result of applicatoin
 836             -> SimplM OutExprStuff
 837 completeApp fun args cont
 838   = go fun args
 839   where
 840     zap_it = mkLamBndrZapper fun (length args)
 841     cont_ty = contResultType cont
 842
 843     -- These equations are very similar to simplLam and simplBeta combined,
 844     -- except that they deal with already-simplified arguments
 845
 846         -- Type argument
 847     go (Lam bndr fun) (Type ty:args) = tick (BetaReduction bndr)        `thenSmpl_`
 848                                        extendSubst bndr (DoneTy ty)
 849                                        (go fun args)
 850
 851         -- Value argument
 852     go (Lam bndr fun) (arg:args)
 853           | preInlineUnconditionally zapped_bndr && not opt_SimplNoPreInlining
 854           = tick (BetaReduction bndr)                   `thenSmpl_`
 855             tick (PreInlineUnconditionally bndr)        `thenSmpl_`
 856             extendSubst zapped_bndr (DoneEx arg)
 857             (go fun args)
 858           | otherwise
 859           = tick (BetaReduction bndr)                   `thenSmpl_`
 860             simplBinder zapped_bndr                     ( \ bndr' ->
 861             completeBeta zapped_bndr bndr' arg          $
 862             go fun args
 863             )
 864          where
 865            zapped_bndr = zap_it bndr
 866
 867         -- Consumed all the lambda binders or args
 868     go fun args = simplExprF fun (pushArgs emptySubstEnv args cont)
 869
 870
 871 ----------- costCentreOk
 872 -- costCentreOk checks that it's ok to inline this thing
 873 -- The time it *isn't* is this:
 874 --
 875 --      f x = let y = E in
 876 --            scc "foo" (...y...)
 877 --
 878 -- Here y has a "current cost centre", and we can't inline it inside "foo",
 879 -- regardless of whether E is a WHNF or not.
 880
 881 costCentreOk ccs_encl cc_rhs
 882   =  not opt_SccProfilingOn
 883   || isSubsumedCCS ccs_encl       -- can unfold anything into a subsumed scope
 884   || not (isEmptyCC cc_rhs)       -- otherwise need a cc on the unfolding
 885 \end{code}
 886
 887
 888 %************************************************************************
 889 %*                                                                      *
 890 \subsection{Decisions about inlining}
 891 %*                                                                      *
 892 %************************************************************************
 893
 894 \begin{code}
 895 preInlineUnconditionally :: InId -> Bool
 896         -- Examines a bndr to see if it is used just once in a
 897         -- completely safe way, so that it is safe to discard the binding
 898         -- inline its RHS at the (unique) usage site, REGARDLESS of how
 899         -- big the RHS might be.  If this is the case we don't simplify
 900         -- the RHS first, but just inline it un-simplified.
 901         --
 902         -- This is much better than first simplifying a perhaps-huge RHS
 903         -- and then inlining and re-simplifying it.
 904         --
 905         -- NB: we don't even look at the RHS to see if it's trivial
 906         -- We might have
 907         --                      x = y
 908         -- where x is used many times, but this is the unique occurrence
 909         -- of y.  We should NOT inline x at all its uses, because then
 910         -- we'd do the same for y -- aargh!  So we must base this
 911         -- pre-rhs-simplification decision solely on x's occurrences, not
 912         -- on its rhs.
 913         --
 914         -- Evne RHSs labelled InlineMe aren't caught here, because
 915         -- there might be no benefit from inlining at the call site.
 916         -- But things labelled 'IMustBeINLINEd' *are* caught.  We use this
 917         -- for the trivial bindings introduced by SimplUtils.mkRhsTyLam
 918 preInlineUnconditionally bndr
 919   = case getInlinePragma bndr of
 920         IMustBeINLINEd                        -> True
 921         ICanSafelyBeINLINEd NotInsideLam True -> True   -- Not inside a lambda,
 922                                                         -- one occurrence ==> safe!
 923         other -> False
 924
 925
 926 postInlineUnconditionally :: InId -> OutExpr -> Bool
 927         -- Examines a (bndr = rhs) binding, AFTER the rhs has been simplified
 928         -- It returns True if it's ok to discard the binding and inline the
 929         -- RHS at every use site.
 930
 931         -- NOTE: This isn't our last opportunity to inline.
 932         -- We're at the binding site right now, and
 933         -- we'll get another opportunity when we get to the ocurrence(s)
 934
 935 postInlineUnconditionally bndr rhs
 936   | isExportedId bndr
 937   = False
 938   | otherwise
 939   = case getInlinePragma bndr of
 940         IAmALoopBreaker                           -> False
 941
 942         ICanSafelyBeINLINEd InsideLam one_branch  -> exprIsTrivial rhs
 943                 -- Don't inline even WHNFs inside lambdas; doing so may
 944                 -- simply increase allocation when the function is called
 945                 -- This isn't the last chance; see NOTE above.
 946
 947         ICanSafelyBeINLINEd not_in_lam one_branch -> one_branch || exprIsTrivial rhs
 948                 -- Was 'exprIsDupable' instead of 'exprIsTrivial' but the
 949                 -- decision about duplicating code is best left to callSiteInline
 950
 951         other                                     -> exprIsTrivial rhs  -- Duplicating is *free*
 952                 -- NB: Even InlineMe and IMustBeINLINEd are ignored here
 953                 -- Why?  Because we don't even want to inline them into the
 954                 -- RHS of constructor arguments. See NOTE above
 955                 -- NB: Even IMustBeINLINEd is ignored here: if the rhs is trivial
 956                 -- it's best to inline it anyway.  We often get a=E; b=a
 957                 -- from desugaring, with both a and b marked NOINLINE.
 958 \end{code}
 959
 960
 961
 962 %************************************************************************
 963 %*                                                                      *
 964 \subsection{The main rebuilder}
 965 %*                                                                      *
 966 %************************************************************************
 967
 968 \begin{code}
 969 -------------------------------------------------------------------
 970 -- Finish rebuilding
 971 rebuild_done expr
 972   = getInScope                  `thenSmpl` \ in_scope ->
 973     returnSmpl ([], (in_scope, expr))
 974
 975 ---------------------------------------------------------
 976 rebuild :: OutExpr -> SimplCont -> SimplM OutExprStuff
 977
 978 --      Stop continuation
 979 rebuild expr (Stop _) = rebuild_done expr
 980
 981 --      ArgOf continuation
 982 rebuild expr (ArgOf _ _ cont_fn) = cont_fn expr
 983
 984 --      ApplyTo continuation
 985 rebuild expr cont@(ApplyTo _ arg se cont')
 986   = setSubstEnv se (simplExpr arg)      `thenSmpl` \ arg' ->
 987     rebuild (App expr arg') cont'
 988
 989 --      Coerce continuation
 990 rebuild expr (CoerceIt to_ty cont)
 991   = rebuild (mkCoerce to_ty expr) cont
 992
 993 --      Inline continuation
 994 rebuild expr (InlinePlease cont)
 995   = rebuild (Note InlineCall expr) cont
 996
 997 --      Case of known constructor or literal
 998 rebuild expr@(Con con args) (Select _ bndr alts se cont)
 999   | conOkForAlt con     -- Knocks out PrimOps and NoRepLits
1000   = knownCon expr con args bndr alts se cont
1001
1002
1003 ---------------------------------------------------------
1004 --      The other Select cases
1005
1006 rebuild scrut (Select _ bndr alts se cont)
1007   |     -- Check that the RHSs are all the same, and
1008         -- don't use the binders in the alternatives
1009         -- This test succeeds rapidly in the common case of
1010         -- a single DEFAULT alternative
1011     all (cheapEqExpr rhs1) other_rhss && all binders_unused alts
1012
1013         -- Check that the scrutinee can be let-bound instead of case-bound
1014     && (   (isUnLiftedType (idType bndr) &&     -- It's unlifted and floatable
1015             exprOkForSpeculation scrut)         -- NB: scrut = an unboxed variable satisfies
1016         || is_a_value scrut                     -- It's a value
1017
1018 --      || not opt_SimplPedanticBottoms)        -- Or we don't care!
1019 --      We used to allow improving termination by discarding cases, unless -fpedantic-bottoms was on,
1020 --      but that breaks badly for the dataToTag# primop, which relies on a case to evaluate
1021 --      its argument:  case x of { y -> dataToTag# y }
1022 --      Here we must *not* discard the case, because dataToTag# just fetches the tag from
1023 --      the info pointer.  So we'll be pedantic all the time, and see if that gives any
1024 --      other problems
1025        )
1026
1027     && opt_SimplDoCaseElim
1028   =     -- Get rid of the case altogether
1029         -- See the extensive notes on case-elimination below
1030         -- Remember to bind the binder though!
1031     tick (CaseElim bndr)                `thenSmpl_` (
1032     setSubstEnv se                      $
1033     simplBinder bndr                    $ \ bndr' ->
1034     completeBinding bndr bndr' scrut    $
1035     simplExprF rhs1 cont)
1036
1037   | otherwise
1038   = rebuild_case scrut bndr alts se cont
1039   where
1040     (rhs1:other_rhss)            = [rhs | (_,_,rhs) <- alts]
1041     binders_unused (_, bndrs, _) = all isDeadBinder bndrs
1042
1043         -- Check whether or not scrut is known to be evaluted
1044     is_a_value (Var v) =    isEvaldUnfolding (getIdUnfolding v) -- It's been evaluated
1045                          || isStrict (getIdDemandInfo bndr)     -- It's going to be evaluated later
1046     is_a_value scrut   = exprIsValue scrut
1047 \end{code}
1048
1049 Case elimination [see the code above]
1050 ~~~~~~~~~~~~~~~~
1051 Start with a simple situation:
1052
1053         case x# of      ===>   e[x#/y#]
1054           y# -> e
1055
1056 (when x#, y# are of primitive type, of course).  We can't (in general)
1057 do this for algebraic cases, because we might turn bottom into
1058 non-bottom!
1059
1060 Actually, we generalise this idea to look for a case where we're
1061 scrutinising a variable, and we know that only the default case can
1062 match.  For example:
1063 \begin{verbatim}
1064         case x of
1065           0#    -> ...
1066           other -> ...(case x of
1067                          0#    -> ...
1068                          other -> ...) ...
1069 \end{code}
1070 Here the inner case can be eliminated.  This really only shows up in
1071 eliminating error-checking code.
1072
1073 We also make sure that we deal with this very common case:
1074
1075         case e of
1076           x -> ...x...
1077
1078 Here we are using the case as a strict let; if x is used only once
1079 then we want to inline it.  We have to be careful that this doesn't
1080 make the program terminate when it would have diverged before, so we
1081 check that
1082         - x is used strictly, or
1083         - e is already evaluated (it may so if e is a variable)
1084
1085 Lastly, we generalise the transformation to handle this:
1086
1087         case e of       ===> r
1088            True  -> r
1089            False -> r
1090
1091 We only do this for very cheaply compared r's (constructors, literals
1092 and variables).  If pedantic bottoms is on, we only do it when the
1093 scrutinee is a PrimOp which can't fail.
1094
1095 We do it *here*, looking at un-simplified alternatives, because we
1096 have to check that r doesn't mention the variables bound by the
1097 pattern in each alternative, so the binder-info is rather useful.
1098
1099 So the case-elimination algorithm is:
1100
1101         1. Eliminate alternatives which can't match
1102
1103         2. Check whether all the remaining alternatives
1104                 (a) do not mention in their rhs any of the variables bound in their pattern
1105            and  (b) have equal rhss
1106
1107         3. Check we can safely ditch the case:
1108                    * PedanticBottoms is off,
1109                 or * the scrutinee is an already-evaluated variable
1110                 or * the scrutinee is a primop which is ok for speculation
1111                         -- ie we want to preserve divide-by-zero errors, and
1112                         -- calls to error itself!
1113
1114                 or * [Prim cases] the scrutinee is a primitive variable
1115
1116                 or * [Alg cases] the scrutinee is a variable and
1117                      either * the rhs is the same variable
1118                         (eg case x of C a b -> x  ===>   x)
1119                      or     * there is only one alternative, the default alternative,
1120                                 and the binder is used strictly in its scope.
1121                                 [NB this is helped by the "use default binder where
1122                                  possible" transformation; see below.]
1123
1124
1125 If so, then we can replace the case with one of the rhss.
1126
1127
1128 Blob of helper functions for the "case-of-something-else" situation.
1129
1130 \begin{code}
1131 ---------------------------------------------------------
1132 --      Case of something else
1133
1134 rebuild_case scrut case_bndr alts se cont
1135   =     -- Prepare case alternatives
1136     prepareCaseAlts case_bndr (splitTyConApp_maybe (idType case_bndr))
1137                     scrut_cons alts             `thenSmpl` \ better_alts ->
1138
1139         -- Set the new subst-env in place (before dealing with the case binder)
1140     setSubstEnv se                              $
1141
1142         -- Deal with the case binder, and prepare the continuation;
1143         -- The new subst_env is in place
1144     prepareCaseCont better_alts cont            $ \ cont' ->
1145
1146
1147         -- Deal with variable scrutinee
1148     (   simplBinder case_bndr                   $ \ case_bndr' ->
1149         substForVarScrut scrut case_bndr'               $ \ zap_occ_info ->
1150         let
1151            case_bndr'' = zap_occ_info case_bndr'
1152         in
1153
1154         -- Deal with the case alternaatives
1155         simplAlts zap_occ_info scrut_cons
1156                   case_bndr'' better_alts cont' `thenSmpl` \ alts' ->
1157
1158         mkCase scrut case_bndr'' alts'
1159     )                                           `thenSmpl` \ case_expr ->
1160
1161         -- Notice that the simplBinder, prepareCaseCont, etc, do *not* scope
1162         -- over the rebuild_done; rebuild_done returns the in-scope set, and
1163         -- that should not include these chaps!
1164     rebuild_done case_expr
1165   where
1166         -- scrut_cons tells what constructors the scrutinee can't possibly match
1167     scrut_cons = case scrut of
1168                    Var v -> case getIdUnfolding v of
1169                                 OtherCon cons -> cons
1170                                 other         -> []
1171                    other -> []
1172
1173
1174 knownCon expr con args bndr alts se cont
1175   = tick (KnownBranch bndr)     `thenSmpl_`
1176     setSubstEnv se              (
1177     simplBinder bndr            $ \ bndr' ->
1178     case findAlt con alts of
1179         (DEFAULT, bs, rhs)     -> ASSERT( null bs )
1180                                   completeBinding bndr bndr' expr $
1181                                         -- Don't use completeBeta here.  The expr might be
1182                                         -- an unboxed literal, like 3, or a variable
1183                                         -- whose unfolding is an unboxed literal... and
1184                                         -- completeBeta will just construct another case
1185                                         -- expression!
1186                                   simplExprF rhs cont
1187
1188         (Literal lit, bs, rhs) -> ASSERT( null bs )
1189                                   extendSubst bndr (DoneEx expr)        $
1190                                         -- Unconditionally substitute, because expr must
1191                                         -- be a variable or a literal.  It can't be a
1192                                         -- NoRep literal because they don't occur in
1193                                         -- case patterns.
1194                                   simplExprF rhs cont
1195
1196         (DataCon dc, bs, rhs)  -> ASSERT( length bs == length real_args )
1197                                   completeBinding bndr bndr' expr       $
1198                                         -- See note above
1199                                   extendSubstList bs (map mk real_args) $
1200                                   simplExprF rhs cont
1201                                where
1202                                   real_args    = drop (dataConNumInstArgs dc) args
1203                                   mk (Type ty) = DoneTy ty
1204                                   mk other     = DoneEx other
1205     )
1206 \end{code}
1207
1208 \begin{code}
1209 prepareCaseCont :: [InAlt] -> SimplCont
1210                 -> (SimplCont -> SimplM (OutStuff a))
1211                 -> SimplM (OutStuff a)
1212         -- Polymorphic recursion here!
1213
1214 prepareCaseCont [alt] cont thing_inside = thing_inside cont
1215 prepareCaseCont alts  cont thing_inside = mkDupableCont (coreAltsType alts) cont thing_inside
1216 \end{code}
1217
1218 substForVarScrut checks whether the scrutinee is a variable, v.
1219 If so, try to eliminate uses of v in the RHSs in favour of case_bndr;
1220 that way, there's a chance that v will now only be used once, and hence inlined.
1221
1222 If we do this, then we have to nuke any occurrence info (eg IAmDead)
1223 in the case binder, because the case-binder now effectively occurs
1224 whenever v does.  AND we have to do the same for the pattern-bound
1225 variables!  Example:
1226
1227         (case x of { (a,b) -> a }) (case x of { (p,q) -> q })
1228
1229 Here, b and p are dead.  But when we move the argment inside the first
1230 case RHS, and eliminate the second case, we get
1231
1232         case x or { (a,b) -> a b }
1233
1234 Urk! b is alive!  Reason: the scrutinee was a variable, and case elimination
1235 happened.  Hence the zap_occ_info function returned by substForVarScrut
1236
1237 \begin{code}
1238 substForVarScrut (Var v) case_bndr' thing_inside
1239   | isLocallyDefined v          -- No point for imported things
1240   = modifyInScope (v `setIdUnfolding` mkUnfolding (Var case_bndr')
1241                      `setInlinePragma` IMustBeINLINEd)                  $
1242         -- We could extend the substitution instead, but it would be
1243         -- a hack because then the substitution wouldn't be idempotent
1244         -- any more.
1245     thing_inside (\ bndr ->  bndr `setInlinePragma` NoInlinePragInfo)
1246
1247 substForVarScrut other_scrut case_bndr' thing_inside
1248   = thing_inside (\ bndr -> bndr)       -- NoOp on bndr
1249 \end{code}
1250
1251 prepareCaseAlts does two things:
1252
1253 1.  Remove impossible alternatives
1254
1255 2.  If the DEFAULT alternative can match only one possible constructor,
1256     then make that constructor explicit.
1257     e.g.
1258         case e of x { DEFAULT -> rhs }
1259      ===>
1260         case e of x { (a,b) -> rhs }
1261     where the type is a single constructor type.  This gives better code
1262     when rhs also scrutinises x or e.
1263
1264 \begin{code}
1265 prepareCaseAlts bndr (Just (tycon, inst_tys)) scrut_cons alts
1266   | isDataTyCon tycon
1267   = case (findDefault filtered_alts, missing_cons) of
1268
1269         ((alts_no_deflt, Just rhs), [data_con])         -- Just one missing constructor!
1270                 -> tick (FillInCaseDefault bndr)        `thenSmpl_`
1271                    let
1272                         (_,_,ex_tyvars,_,_,_) = dataConSig data_con
1273                    in
1274                    getUniquesSmpl (length ex_tyvars)                            `thenSmpl` \ tv_uniqs ->
1275                    let
1276                         ex_tyvars' = zipWithEqual "simpl_alt" mk tv_uniqs ex_tyvars
1277                         mk uniq tv = mkSysTyVar uniq (tyVarKind tv)
1278                    in
1279                    newIds (dataConArgTys
1280                                 data_con
1281                                 (inst_tys ++ mkTyVarTys ex_tyvars'))            $ \ bndrs ->
1282                    returnSmpl ((DataCon data_con, ex_tyvars' ++ bndrs, rhs) : alts_no_deflt)
1283
1284         other -> returnSmpl filtered_alts
1285   where
1286         -- Filter out alternatives that can't possibly match
1287     filtered_alts = case scrut_cons of
1288                         []    -> alts
1289                         other -> [alt | alt@(con,_,_) <- alts, not (con `elem` scrut_cons)]
1290
1291     missing_cons = [data_con | data_con <- tyConDataCons tycon,
1292                                not (data_con `elem` handled_data_cons)]
1293     handled_data_cons = [data_con | DataCon data_con         <- scrut_cons] ++
1294                         [data_con | (DataCon data_con, _, _) <- filtered_alts]
1295
1296 -- The default case
1297 prepareCaseAlts _ _ scrut_cons alts
1298   = returnSmpl alts                     -- Functions
1299
1300
1301 ----------------------
1302 simplAlts zap_occ_info scrut_cons case_bndr'' alts cont'
1303   = mapSmpl simpl_alt alts
1304   where
1305     inst_tys' = case splitTyConApp_maybe (idType case_bndr'') of
1306                         Just (tycon, inst_tys) -> inst_tys
1307
1308         -- handled_cons is all the constructors that are dealt
1309         -- with, either by being impossible, or by there being an alternative
1310     handled_cons = scrut_cons ++ [con | (con,_,_) <- alts, con /= DEFAULT]
1311
1312     simpl_alt (DEFAULT, _, rhs)
1313         =       -- In the default case we record the constructors that the
1314                 -- case-binder *can't* be.
1315                 -- We take advantage of any OtherCon info in the case scrutinee
1316           modifyInScope (case_bndr'' `setIdUnfolding` OtherCon handled_cons)    $
1317           simplExprC rhs cont'                                                  `thenSmpl` \ rhs' ->
1318           returnSmpl (DEFAULT, [], rhs')
1319
1320     simpl_alt (con, vs, rhs)
1321         =       -- Deal with the pattern-bound variables
1322                 -- Mark the ones that are in ! positions in the data constructor
1323                 -- as certainly-evaluated
1324           simplBinders (add_evals con vs)       $ \ vs' ->
1325
1326                 -- Bind the case-binder to (Con args)
1327           let
1328                 con_app = Con con (map Type inst_tys' ++ map varToCoreExpr vs')
1329           in
1330           modifyInScope (case_bndr'' `setIdUnfolding` mkUnfolding con_app)      $
1331           simplExprC rhs cont'          `thenSmpl` \ rhs' ->
1332           returnSmpl (con, vs', rhs')
1333
1334
1335         -- add_evals records the evaluated-ness of the bound variables of
1336         -- a case pattern.  This is *important*.  Consider
1337         --      data T = T !Int !Int
1338         --
1339         --      case x of { T a b -> T (a+1) b }
1340         --
1341         -- We really must record that b is already evaluated so that we don't
1342         -- go and re-evaluate it when constructing the result.
1343
1344     add_evals (DataCon dc) vs = cat_evals vs (dataConRepStrictness dc)
1345     add_evals other_con    vs = vs
1346
1347     cat_evals [] [] = []
1348     cat_evals (v:vs) (str:strs)
1349         | isTyVar v    = v                                 : cat_evals vs (str:strs)
1350         | isStrict str = (v' `setIdUnfolding` OtherCon []) : cat_evals vs strs
1351         | otherwise    = v'                                : cat_evals vs strs
1352         where
1353           v' = zap_occ_info v
1354 \end{code}
1355
1356
1357 %************************************************************************
1358 %*                                                                      *
1359 \subsection{Duplicating continuations}
1360 %*                                                                      *
1361 %************************************************************************
1362
1363 \begin{code}
1364 mkDupableCont :: InType         -- Type of the thing to be given to the continuation
1365               -> SimplCont
1366               -> (SimplCont -> SimplM (OutStuff a))
1367               -> SimplM (OutStuff a)
1368 mkDupableCont ty cont thing_inside
1369   | contIsDupable cont
1370   = thing_inside cont
1371
1372 mkDupableCont _ (CoerceIt ty cont) thing_inside
1373   = mkDupableCont ty cont               $ \ cont' ->
1374     thing_inside (CoerceIt ty cont')
1375
1376 mkDupableCont ty (InlinePlease cont) thing_inside
1377   = mkDupableCont ty cont               $ \ cont' ->
1378     thing_inside (InlinePlease cont')
1379
1380 mkDupableCont join_arg_ty (ArgOf _ cont_ty cont_fn) thing_inside
1381   =     -- Build the RHS of the join point
1382     simplType join_arg_ty                               `thenSmpl` \ join_arg_ty' ->
1383     newId join_arg_ty'                                  ( \ arg_id ->
1384         getSwitchChecker                                `thenSmpl` \ chkr ->
1385         cont_fn (Var arg_id)                            `thenSmpl` \ (binds, (_, rhs)) ->
1386         returnSmpl (Lam arg_id (mkLets binds rhs))
1387     )                                                   `thenSmpl` \ join_rhs ->
1388
1389         -- Build the join Id and continuation
1390     newId (coreExprType join_rhs)               $ \ join_id ->
1391     let
1392         new_cont = ArgOf OkToDup cont_ty
1393                          (\arg' -> rebuild_done (App (Var join_id) arg'))
1394     in
1395
1396         -- Do the thing inside
1397     thing_inside new_cont               `thenSmpl` \ res ->
1398     returnSmpl (addBind (NonRec join_id join_rhs) res)
1399
1400 mkDupableCont ty (ApplyTo _ arg se cont) thing_inside
1401   = mkDupableCont (funResultTy ty) cont                 $ \ cont' ->
1402     setSubstEnv se (simplExpr arg)                      `thenSmpl` \ arg' ->
1403     if exprIsDupable arg' then
1404         thing_inside (ApplyTo OkToDup arg' emptySubstEnv cont')
1405     else
1406     newId (coreExprType arg')                                           $ \ bndr ->
1407     thing_inside (ApplyTo OkToDup (Var bndr) emptySubstEnv cont')       `thenSmpl` \ res ->
1408     returnSmpl (addBind (NonRec bndr arg') res)
1409
1410 mkDupableCont ty (Select _ case_bndr alts se cont) thing_inside
1411   = tick (CaseOfCase case_bndr)                                         `thenSmpl_`
1412     setSubstEnv se (
1413         simplBinder case_bndr                                           $ \ case_bndr' ->
1414         prepareCaseCont alts cont                                       $ \ cont' ->
1415         mapAndUnzipSmpl (mkDupableAlt case_bndr case_bndr' cont') alts  `thenSmpl` \ (alt_binds_s, alts') ->
1416         returnSmpl (concat alt_binds_s, alts')
1417     )                                   `thenSmpl` \ (alt_binds, alts') ->
1418
1419     extendInScopes [b | NonRec b _ <- alt_binds]                $
1420
1421         -- NB that the new alternatives, alts', are still InAlts, using the original
1422         -- binders.  That means we can keep the case_bndr intact. This is important
1423         -- because another case-of-case might strike, and so we want to keep the
1424         -- info that the case_bndr is dead (if it is, which is often the case).
1425         -- This is VITAL when the type of case_bndr is an unboxed pair (often the
1426         -- case in I/O rich code.  We aren't allowed a lambda bound
1427         -- arg of unboxed tuple type, and indeed such a case_bndr is always dead
1428     thing_inside (Select OkToDup case_bndr alts' se (Stop (contResultType cont)))       `thenSmpl` \ res ->
1429
1430     returnSmpl (addBinds alt_binds res)
1431
1432
1433 mkDupableAlt :: InId -> OutId -> SimplCont -> InAlt -> SimplM (OutStuff InAlt)
1434 mkDupableAlt case_bndr case_bndr' cont alt@(con, bndrs, rhs)
1435   =     -- Not worth checking whether the rhs is small; the
1436         -- inliner will inline it if so.
1437     simplBinders bndrs                                  $ \ bndrs' ->
1438     simplExprC rhs cont                                 `thenSmpl` \ rhs' ->
1439     let
1440         rhs_ty' = coreExprType rhs'
1441         (used_bndrs, used_bndrs')
1442            = unzip [pr | pr@(bndr,bndr') <- zip (case_bndr  : bndrs)
1443                                                 (case_bndr' : bndrs'),
1444                          not (isDeadBinder bndr)]
1445                 -- The new binders have lost their occurrence info,
1446                 -- so we have to extract it from the old ones
1447     in
1448     ( if null used_bndrs'
1449         -- If we try to lift a primitive-typed something out
1450         -- for let-binding-purposes, we will *caseify* it (!),
1451         -- with potentially-disastrous strictness results.  So
1452         -- instead we turn it into a function: \v -> e
1453         -- where v::State# RealWorld#.  The value passed to this function
1454         -- is realworld#, which generates (almost) no code.
1455
1456         -- There's a slight infelicity here: we pass the overall
1457         -- case_bndr to all the join points if it's used in *any* RHS,
1458         -- because we don't know its usage in each RHS separately
1459
1460         -- We used to say "&& isUnLiftedType rhs_ty'" here, but now
1461         -- we make the join point into a function whenever used_bndrs'
1462         -- is empty.  This makes the join-point more CPR friendly.
1463         -- Consider:    let j = if .. then I# 3 else I# 4
1464         --              in case .. of { A -> j; B -> j; C -> ... }
1465         --
1466         -- Now CPR should not w/w j because it's a thunk, so
1467         -- that means that the enclosing function can't w/w either,
1468         -- which is a lose.  Here's the example that happened in practice:
1469         --      kgmod :: Int -> Int -> Int
1470         --      kgmod x y = if x > 0 && y < 0 || x < 0 && y > 0
1471         --                  then 78
1472         --                  else 5
1473
1474         then newId realWorldStatePrimTy  $ \ rw_id ->
1475              returnSmpl ([rw_id], [Var realWorldPrimId])
1476         else
1477              returnSmpl (used_bndrs', map varToCoreExpr used_bndrs)
1478     )
1479         `thenSmpl` \ (final_bndrs', final_args) ->
1480
1481     newId (foldr (mkFunTy . idType) rhs_ty' final_bndrs')       $ \ join_bndr ->
1482
1483         -- Notice that we make the lambdas into one-shot-lambdas.  The
1484         -- join point is sure to be applied at most once, and doing so
1485         -- prevents the body of the join point being floated out by
1486         -- the full laziness pass
1487     returnSmpl ([NonRec join_bndr (mkLams (map setOneShotLambda final_bndrs') rhs')],
1488                 (con, bndrs, mkApps (Var join_bndr) final_args))
1489 \end{code}