ghc/compiler/simplCore/Simplify.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[Simplify]{The main module of the simplifier}
   5
   6 \begin{code}
   7 module Simplify ( simplTopBinds, simplExpr ) where
   8
   9 #include "HsVersions.h"
  10
  11 import CmdLineOpts      ( switchIsOn, opt_SimplDoEtaReduction,
  12                           opt_SimplNoPreInlining,
  13                           dopt, DynFlag(Opt_D_dump_inlinings),
  14                           SimplifierSwitch(..)
  15                         )
  16 import SimplMonad
  17 import SimplUtils       ( mkCase, tryRhsTyLam, tryEtaExpansion, findAlt,
  18                           simplBinder, simplBinders, simplIds, findDefault,
  19                           SimplCont(..), DupFlag(..), mkStop, mkRhsStop,
  20                           contResultType, discardInline, countArgs, contIsDupable,
  21                           getContArgs, interestingCallContext, interestingArg, isStrictType
  22                         )
  23 import Var              ( mkSysTyVar, tyVarKind )
  24 import VarEnv
  25 import Id               ( Id, idType, idInfo, isDataConId, hasNoBinding,
  26                           idUnfolding, setIdUnfolding, isExportedId, isDeadBinder,
  27                           idDemandInfo, setIdInfo,
  28                           idOccInfo, setIdOccInfo,
  29                           zapLamIdInfo, setOneShotLambda,
  30                         )
  31 import IdInfo           ( OccInfo(..), isDeadOcc, isLoopBreaker,
  32                           setArityInfo,
  33                           setUnfoldingInfo, atLeastArity,
  34                           occInfo
  35                         )
  36 import Demand           ( isStrict )
  37 import DataCon          ( dataConNumInstArgs, dataConRepStrictness,
  38                           dataConSig, dataConArgTys
  39                         )
  40 import CoreSyn
  41 import PprCore          ( pprParendExpr, pprCoreExpr )
  42 import CoreFVs          ( mustHaveLocalBinding )
  43 import CoreUnfold       ( mkOtherCon, mkUnfolding, otherCons,
  44                           callSiteInline
  45                         )
  46 import CoreUtils        ( cheapEqExpr, exprIsDupable, exprIsTrivial,
  47                           exprIsConApp_maybe, mkPiType,
  48                           exprType, coreAltsType, exprIsValue,
  49                           exprOkForSpeculation, exprArity, exprIsCheap,
  50                           mkCoerce, mkSCC, mkInlineMe, mkAltExpr
  51                         )
  52 import Rules            ( lookupRule )
  53 import CostCentre       ( currentCCS )
  54 import Type             ( mkTyVarTys, isUnLiftedType, seqType,
  55                           mkFunTy, splitTyConApp_maybe, tyConAppArgs,
  56                           funResultTy
  57                         )
  58 import Subst            ( mkSubst, substTy,
  59                           isInScope, lookupIdSubst, substIdInfo
  60                         )
  61 import TyCon            ( isDataTyCon, tyConDataConsIfAvailable )
  62 import TysPrim          ( realWorldStatePrimTy )
  63 import PrelInfo         ( realWorldPrimId )
  64 import OrdList
  65 import Maybes           ( maybeToBool )
  66 import Util             ( zipWithEqual )
  67 import Outputable
  68 \end{code}
  69
  70
  71 The guts of the simplifier is in this module, but the driver
  72 loop for the simplifier is in SimplCore.lhs.
  73
  74
  75 -----------------------------------------
  76         *** IMPORTANT NOTE ***
  77 -----------------------------------------
  78 The simplifier used to guarantee that the output had no shadowing, but
  79 it does not do so any more.   (Actually, it never did!)  The reason is
  80 documented with simplifyArgs.
  81
  82
  83
  84
  85 %************************************************************************
  86 %*                                                                      *
  87 \subsection{Bindings}
  88 %*                                                                      *
  89 %************************************************************************
  90
  91 \begin{code}
  92 simplTopBinds :: [InBind] -> SimplM [OutBind]
  93
  94 simplTopBinds binds
  95   =     -- Put all the top-level binders into scope at the start
  96         -- so that if a transformation rule has unexpectedly brought
  97         -- anything into scope, then we don't get a complaint about that.
  98         -- It's rather as if the top-level binders were imported.
  99     simplIds (bindersOfBinds binds)     $ \ bndrs' ->
 100     simpl_binds binds bndrs'            `thenSmpl` \ (binds', _) ->
 101     freeTick SimplifierDone             `thenSmpl_`
 102     returnSmpl (fromOL binds')
 103   where
 104
 105         -- We need to track the zapped top-level binders, because
 106         -- they should have their fragile IdInfo zapped (notably occurrence info)
 107     simpl_binds []                        bs     = ASSERT( null bs ) returnSmpl (nilOL, panic "simplTopBinds corner")
 108     simpl_binds (NonRec bndr rhs : binds) (b:bs) = simplLazyBind True bndr  b rhs       (simpl_binds binds bs)
 109     simpl_binds (Rec pairs       : binds) bs     = simplRecBind  True pairs (take n bs) (simpl_binds binds (drop n bs))
 110                                                  where
 111                                                    n = length pairs
 112
 113 simplRecBind :: Bool -> [(InId, InExpr)] -> [OutId]
 114              -> SimplM (OutStuff a) -> SimplM (OutStuff a)
 115 simplRecBind top_lvl pairs bndrs' thing_inside
 116   = go pairs bndrs'             `thenSmpl` \ (binds', (_, (binds'', res))) ->
 117     returnSmpl (unitOL (Rec (flattenBinds (fromOL binds'))) `appOL` binds'', res)
 118   where
 119     go [] _ = thing_inside      `thenSmpl` \ stuff ->
 120               returnOutStuff stuff
 121
 122     go ((bndr, rhs) : pairs) (bndr' : bndrs')
 123         = simplLazyBind top_lvl bndr bndr' rhs (go pairs bndrs')
 124                 -- Don't float unboxed bindings out,
 125                 -- because we can't "rec" them
 126 \end{code}
 127
 128
 129 %************************************************************************
 130 %*                                                                      *
 131 \subsection[Simplify-simplExpr]{The main function: simplExpr}
 132 %*                                                                      *
 133 %************************************************************************
 134
 135 The reason for this OutExprStuff stuff is that we want to float *after*
 136 simplifying a RHS, not before.  If we do so naively we get quadratic
 137 behaviour as things float out.
 138
 139 To see why it's important to do it after, consider this (real) example:
 140
 141         let t = f x
 142         in fst t
 143 ==>
 144         let t = let a = e1
 145                     b = e2
 146                 in (a,b)
 147         in fst t
 148 ==>
 149         let a = e1
 150             b = e2
 151             t = (a,b)
 152         in
 153         a       -- Can't inline a this round, cos it appears twice
 154 ==>
 155         e1
 156
 157 Each of the ==> steps is a round of simplification.  We'd save a
 158 whole round if we float first.  This can cascade.  Consider
 159
 160         let f = g d
 161         in \x -> ...f...
 162 ==>
 163         let f = let d1 = ..d.. in \y -> e
 164         in \x -> ...f...
 165 ==>
 166         let d1 = ..d..
 167         in \x -> ...(\y ->e)...
 168
 169 Only in this second round can the \y be applied, and it
 170 might do the same again.
 171
 172
 173 \begin{code}
 174 simplExpr :: CoreExpr -> SimplM CoreExpr
 175 simplExpr expr = getSubst       `thenSmpl` \ subst ->
 176                  simplExprC expr (mkStop (substTy subst (exprType expr)))
 177         -- The type in the Stop continuation is usually not used
 178         -- It's only needed when discarding continuations after finding
 179         -- a function that returns bottom.
 180         -- Hence the lazy substitution
 181
 182 simplExprC :: CoreExpr -> SimplCont -> SimplM CoreExpr
 183         -- Simplify an expression, given a continuation
 184
 185 simplExprC expr cont = simplExprF expr cont     `thenSmpl` \ (floats, (_, body)) ->
 186                        returnSmpl (wrapFloats floats body)
 187
 188 simplExprF :: InExpr -> SimplCont -> SimplM OutExprStuff
 189         -- Simplify an expression, returning floated binds
 190
 191 simplExprF (Var v) cont
 192   = simplVar v cont
 193
 194 simplExprF (Lit lit) (Select _ bndr alts se cont)
 195   = knownCon (Lit lit) (LitAlt lit) [] bndr alts se cont
 196
 197 simplExprF (Lit lit) cont
 198   = rebuild (Lit lit) cont
 199
 200 simplExprF (App fun arg) cont
 201   = getSubstEnv         `thenSmpl` \ se ->
 202     simplExprF fun (ApplyTo NoDup arg se cont)
 203
 204 simplExprF (Case scrut bndr alts) cont
 205   = getSubstEnv                 `thenSmpl` \ subst_env ->
 206     getSwitchChecker            `thenSmpl` \ chkr ->
 207     if not (switchIsOn chkr NoCaseOfCase) then
 208         -- Simplify the scrutinee with a Select continuation
 209         simplExprF scrut (Select NoDup bndr alts subst_env cont)
 210
 211     else
 212         -- If case-of-case is off, simply simplify the case expression
 213         -- in a vanilla Stop context, and rebuild the result around it
 214         simplExprC scrut (Select NoDup bndr alts subst_env
 215                                  (mkStop (contResultType cont)))        `thenSmpl` \ case_expr' ->
 216         rebuild case_expr' cont
 217
 218
 219 simplExprF (Let (Rec pairs) body) cont
 220   = simplIds (map fst pairs)            $ \ bndrs' ->
 221         -- NB: bndrs' don't have unfoldings or spec-envs
 222         -- We add them as we go down, using simplPrags
 223
 224     simplRecBind False pairs bndrs' (simplExprF body cont)
 225
 226 simplExprF expr@(Lam _ _) cont = simplLam expr cont
 227
 228 simplExprF (Type ty) cont
 229   = ASSERT( case cont of { Stop _ _ -> True; ArgOf _ _ _ -> True; other -> False } )
 230     simplType ty        `thenSmpl` \ ty' ->
 231     rebuild (Type ty') cont
 232
 233 -- Comments about the Coerce case
 234 -- ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 235 -- It's worth checking for a coerce in the continuation,
 236 -- in case we can cancel them.  For example, in the initial form of a worker
 237 -- we may find  (coerce T (coerce S (\x.e))) y
 238 -- and we'd like it to simplify to e[y/x] in one round of simplification
 239
 240 simplExprF (Note (Coerce to from) e) (CoerceIt outer_to cont)
 241   = simplType from              `thenSmpl` \ from' ->
 242     if outer_to == from' then
 243         -- The coerces cancel out
 244         simplExprF e cont
 245     else
 246         -- They don't cancel, but the inner one is redundant
 247         simplExprF e (CoerceIt outer_to cont)
 248
 249 simplExprF (Note (Coerce to from) e) cont
 250   = simplType to                `thenSmpl` \ to' ->
 251     simplExprF e (CoerceIt to' cont)
 252
 253 -- hack: we only distinguish subsumed cost centre stacks for the purposes of
 254 -- inlining.  All other CCCSs are mapped to currentCCS.
 255 simplExprF (Note (SCC cc) e) cont
 256   = setEnclosingCC currentCCS $
 257     simplExpr e         `thenSmpl` \ e ->
 258     rebuild (mkSCC cc e) cont
 259
 260 simplExprF (Note InlineCall e) cont
 261   = simplExprF e (InlinePlease cont)
 262
 263 --       Comments about the InlineMe case
 264 --       ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 265 -- Don't inline in the RHS of something that has an
 266 -- inline pragma.  But be careful that the InScopeEnv that
 267 -- we return does still have inlinings on!
 268 --
 269 -- It really is important to switch off inlinings.  This function
 270 -- may be inlinined in other modules, so we don't want to remove
 271 -- (by inlining) calls to functions that have specialisations, or
 272 -- that may have transformation rules in an importing scope.
 273 -- E.g.         {-# INLINE f #-}
 274 --              f x = ...g...
 275 -- and suppose that g is strict *and* has specialisations.
 276 -- If we inline g's wrapper, we deny f the chance of getting
 277 -- the specialised version of g when f is inlined at some call site
 278 -- (perhaps in some other module).
 279
 280 -- It's also important not to inline a worker back into a wrapper.
 281 -- A wrapper looks like
 282 --      wraper = inline_me (\x -> ...worker... )
 283 -- Normally, the inline_me prevents the worker getting inlined into
 284 -- the wrapper (initially, the worker's only call site!).  But,
 285 -- if the wrapper is sure to be called, the strictness analyser will
 286 -- mark it 'demanded', so when the RHS is simplified, it'll get an ArgOf
 287 -- continuation.  That's why the keep_inline predicate returns True for
 288 -- ArgOf continuations.  It shouldn't do any harm not to dissolve the
 289 -- inline-me note under these circumstances
 290
 291 simplExprF (Note InlineMe e) cont
 292   | keep_inline cont            -- Totally boring continuation
 293   =                             -- Don't inline inside an INLINE expression
 294     setBlackList noInlineBlackList (simplExpr e)        `thenSmpl` \ e' ->
 295     rebuild (mkInlineMe e') cont
 296
 297   | otherwise   -- Dissolve the InlineMe note if there's
 298                 -- an interesting context of any kind to combine with
 299                 -- (even a type application -- anything except Stop)
 300   = simplExprF e cont
 301   where
 302     keep_inline (Stop _ _)    = True            -- See notes above
 303     keep_inline (ArgOf _ _ _) = True            -- about this predicate
 304     keep_inline other         = False
 305
 306 -- A non-recursive let is dealt with by simplBeta
 307 simplExprF (Let (NonRec bndr rhs) body) cont
 308   = getSubstEnv                 `thenSmpl` \ se ->
 309     simplBeta bndr rhs se (contResultType cont) $
 310     simplExprF body cont
 311 \end{code}
 312
 313
 314 ---------------------------------
 315
 316 \begin{code}
 317 simplLam fun cont
 318   = go fun cont
 319   where
 320     zap_it  = mkLamBndrZapper fun cont
 321     cont_ty = contResultType cont
 322
 323         -- Type-beta reduction
 324     go (Lam bndr body) (ApplyTo _ (Type ty_arg) arg_se body_cont)
 325       = ASSERT( isTyVar bndr )
 326         tick (BetaReduction bndr)       `thenSmpl_`
 327         simplTyArg ty_arg arg_se        `thenSmpl` \ ty_arg' ->
 328         extendSubst bndr (DoneTy ty_arg')
 329         (go body body_cont)
 330
 331         -- Ordinary beta reduction
 332     go (Lam bndr body) cont@(ApplyTo _ arg arg_se body_cont)
 333       = tick (BetaReduction bndr)                       `thenSmpl_`
 334         simplBeta zapped_bndr arg arg_se cont_ty
 335         (go body body_cont)
 336       where
 337         zapped_bndr = zap_it bndr
 338
 339         -- Not enough args
 340     go lam@(Lam _ _) cont = completeLam [] lam cont
 341
 342         -- Exactly enough args
 343     go expr cont = simplExprF expr cont
 344
 345 -- completeLam deals with the case where a lambda doesn't have an ApplyTo
 346 -- continuation, so there are real lambdas left to put in the result
 347
 348 -- We try for eta reduction here, but *only* if we get all the
 349 -- way to an exprIsTrivial expression.
 350 -- We don't want to remove extra lambdas unless we are going
 351 -- to avoid allocating this thing altogether
 352
 353 completeLam rev_bndrs (Lam bndr body) cont
 354   = simplBinder bndr                    $ \ bndr' ->
 355     completeLam (bndr':rev_bndrs) body cont
 356
 357 completeLam rev_bndrs body cont
 358   = simplExpr body                      `thenSmpl` \ body' ->
 359     case try_eta body' of
 360         Just etad_lam -> tick (EtaReduction (head rev_bndrs))   `thenSmpl_`
 361                          rebuild etad_lam cont
 362
 363         Nothing       -> rebuild (foldl (flip Lam) body' rev_bndrs) cont
 364   where
 365         -- We don't use CoreUtils.etaReduce, because we can be more
 366         -- efficient here:
 367         --  (a) we already have the binders,
 368         --  (b) we can do the triviality test before computing the free vars
 369         --      [in fact I take the simple path and look for just a variable]
 370         --  (c) we don't want to eta-reduce a data con worker or primop
 371         --      because we only have to eta-expand them later when we saturate
 372     try_eta body | not opt_SimplDoEtaReduction = Nothing
 373                  | otherwise                   = go rev_bndrs body
 374
 375     go (b : bs) (App fun arg) | ok_arg b arg = go bs fun        -- Loop round
 376     go []       body          | ok_body body = Just body        -- Success!
 377     go _        _                            = Nothing          -- Failure!
 378
 379     ok_body (Var v) = not (v `elem` rev_bndrs) && not (hasNoBinding v)
 380     ok_body other   = False
 381     ok_arg b arg    = varToCoreExpr b `cheapEqExpr` arg
 382
 383 mkLamBndrZapper :: CoreExpr     -- Function
 384                 -> SimplCont    -- The context
 385                 -> Id -> Id     -- Use this to zap the binders
 386 mkLamBndrZapper fun cont
 387   | n_args >= n_params fun = \b -> b            -- Enough args
 388   | otherwise              = \b -> zapLamIdInfo b
 389   where
 390         -- NB: we count all the args incl type args
 391         -- so we must count all the binders (incl type lambdas)
 392     n_args = countArgs cont
 393
 394     n_params (Note _ e) = n_params e
 395     n_params (Lam b e)  = 1 + n_params e
 396     n_params other      = 0::Int
 397 \end{code}
 398
 399
 400 ---------------------------------
 401 \begin{code}
 402 simplType :: InType -> SimplM OutType
 403 simplType ty
 404   = getSubst    `thenSmpl` \ subst ->
 405     let
 406         new_ty = substTy subst ty
 407     in
 408     seqType new_ty `seq`
 409     returnSmpl new_ty
 410 \end{code}
 411
 412
 413 %************************************************************************
 414 %*                                                                      *
 415 \subsection{Binding}
 416 %*                                                                      *
 417 %************************************************************************
 418
 419 @simplBeta@ is used for non-recursive lets in expressions,
 420 as well as true beta reduction.
 421
 422 Very similar to @simplLazyBind@, but not quite the same.
 423
 424 \begin{code}
 425 simplBeta :: InId                       -- Binder
 426           -> InExpr -> SubstEnv         -- Arg, with its subst-env
 427           -> OutType                    -- Type of thing computed by the context
 428           -> SimplM OutExprStuff        -- The body
 429           -> SimplM OutExprStuff
 430 #ifdef DEBUG
 431 simplBeta bndr rhs rhs_se cont_ty thing_inside
 432   | isTyVar bndr
 433   = pprPanic "simplBeta" (ppr bndr <+> ppr rhs)
 434 #endif
 435
 436 simplBeta bndr rhs rhs_se cont_ty thing_inside
 437   | preInlineUnconditionally False {- not black listed -} bndr
 438   = tick (PreInlineUnconditionally bndr)                `thenSmpl_`
 439     extendSubst bndr (ContEx rhs_se rhs) thing_inside
 440
 441   | otherwise
 442   =     -- Simplify the RHS
 443     simplBinder bndr                                    $ \ bndr' ->
 444     let
 445         bndr_ty'  = idType bndr'
 446         is_strict = isStrict (idDemandInfo bndr) || isStrictType bndr_ty'
 447     in
 448     simplValArg bndr_ty' is_strict rhs rhs_se cont_ty   $ \ rhs' ->
 449
 450         -- Now complete the binding and simplify the body
 451     if needsCaseBinding bndr_ty' rhs' then
 452         addCaseBind bndr' rhs' thing_inside
 453     else
 454         completeBinding bndr bndr' False False rhs' thing_inside
 455 \end{code}
 456
 457
 458 \begin{code}
 459 simplTyArg :: InType -> SubstEnv -> SimplM OutType
 460 simplTyArg ty_arg se
 461   = getInScope          `thenSmpl` \ in_scope ->
 462     let
 463         ty_arg' = substTy (mkSubst in_scope se) ty_arg
 464     in
 465     seqType ty_arg'     `seq`
 466     returnSmpl ty_arg'
 467
 468 simplValArg :: OutType          -- rhs_ty: Type of arg; used only occasionally
 469             -> Bool             -- True <=> evaluate eagerly
 470             -> InExpr -> SubstEnv
 471             -> OutType          -- cont_ty: Type of thing computed by the context
 472             -> (OutExpr -> SimplM OutExprStuff)
 473                                 -- Takes an expression of type rhs_ty,
 474                                 -- returns an expression of type cont_ty
 475             -> SimplM OutExprStuff      -- An expression of type cont_ty
 476
 477 simplValArg arg_ty is_strict arg arg_se cont_ty thing_inside
 478   | is_strict
 479   = getEnv                              `thenSmpl` \ env ->
 480     setSubstEnv arg_se                          $
 481     simplExprF arg (ArgOf NoDup cont_ty         $ \ rhs' ->
 482     setAllExceptInScope env                     $
 483     thing_inside rhs')
 484
 485   | otherwise
 486   = simplRhs False {- Not top level -}
 487              True {- OK to float unboxed -}
 488              arg_ty arg arg_se
 489              thing_inside
 490 \end{code}
 491
 492
 493 completeBinding
 494         - deals only with Ids, not TyVars
 495         - take an already-simplified RHS
 496
 497 It does *not* attempt to do let-to-case.  Why?  Because they are used for
 498
 499         - top-level bindings
 500                 (when let-to-case is impossible)
 501
 502         - many situations where the "rhs" is known to be a WHNF
 503                 (so let-to-case is inappropriate).
 504
 505 \begin{code}
 506 completeBinding :: InId                 -- Binder
 507                 -> OutId                -- New binder
 508                 -> Bool                 -- True <=> top level
 509                 -> Bool                 -- True <=> black-listed; don't inline
 510                 -> OutExpr              -- Simplified RHS
 511                 -> SimplM (OutStuff a)  -- Thing inside
 512                 -> SimplM (OutStuff a)
 513
 514 completeBinding old_bndr new_bndr top_lvl black_listed new_rhs thing_inside
 515   |  isDeadOcc occ_info         -- This happens; for example, the case_bndr during case of
 516                                 -- known constructor:  case (a,b) of x { (p,q) -> ... }
 517                                 -- Here x isn't mentioned in the RHS, so we don't want to
 518                                 -- create the (dead) let-binding  let x = (a,b) in ...
 519   =  thing_inside
 520
 521   | trivial_rhs && not must_keep_binding
 522         -- We're looking at a binding with a trivial RHS, so
 523         -- perhaps we can discard it altogether!
 524         --
 525         -- NB: a loop breaker has must_keep_binding = True
 526         -- and non-loop-breakers only have *forward* references
 527         -- Hence, it's safe to discard the binding
 528         --
 529         -- NOTE: This isn't our last opportunity to inline.
 530         -- We're at the binding site right now, and
 531         -- we'll get another opportunity when we get to the ocurrence(s)
 532
 533         -- Note that we do this unconditional inlining only for trival RHSs.
 534         -- Don't inline even WHNFs inside lambdas; doing so may
 535         -- simply increase allocation when the function is called
 536         -- This isn't the last chance; see NOTE above.
 537         --
 538         -- NB: Even inline pragmas (e.g. IMustBeINLINEd) are ignored here
 539         -- Why?  Because we don't even want to inline them into the
 540         -- RHS of constructor arguments. See NOTE above
 541         --
 542         -- NB: Even NOINLINEis ignored here: if the rhs is trivial
 543         -- it's best to inline it anyway.  We often get a=E; b=a
 544         -- from desugaring, with both a and b marked NOINLINE.
 545   =             -- Drop the binding
 546     extendSubst old_bndr (DoneEx new_rhs)       $
 547                 -- Use the substitution to make quite, quite sure that the substitution
 548                 -- will happen, since we are going to discard the binding
 549     tick (PostInlineUnconditionally old_bndr)   `thenSmpl_`
 550     thing_inside
 551
 552   | Note coercion@(Coerce _ inner_ty) inner_rhs <- new_rhs,
 553     not trivial_rhs && not (isUnLiftedType inner_ty)
 554         -- x = coerce t e  ==>  c = e; x = inline_me (coerce t c)
 555         -- Now x can get inlined, which moves the coercion
 556         -- to the usage site.  This is a bit like worker/wrapper stuff,
 557         -- but it's useful to do it very promptly, so that
 558         --      x = coerce T (I# 3)
 559         -- get's w/wd to
 560         --      c = I# 3
 561         --      x = coerce T c
 562         -- This in turn means that
 563         --      case (coerce Int x) of ...
 564         -- will inline x.
 565         -- Also the full-blown w/w thing isn't set up for non-functions
 566         --
 567         -- The (not (isUnLiftedType inner_ty)) avoids the nasty case of
 568         --      x::Int = coerce Int Int# (foo y)
 569         -- ==>
 570         --      v::Int# = foo y
 571         --      x::Int  = coerce Int Int# v
 572         -- which would be bogus because then v will be evaluated strictly.
 573         -- How can this arise?  Via
 574         --      x::Int = case (foo y) of { ... }
 575         -- followed by case elimination.
 576         --
 577         -- The inline_me note is so that the simplifier doesn't
 578         -- just substitute c back inside x's rhs!  (Typically, x will
 579         -- get substituted away, but not if it's exported.)
 580   = newId SLIT("c") inner_ty                                    $ \ c_id ->
 581     completeBinding c_id c_id top_lvl False inner_rhs           $
 582     completeBinding old_bndr new_bndr top_lvl black_listed
 583                     (Note InlineMe (Note coercion (Var c_id)))  $
 584     thing_inside
 585
 586   |  otherwise
 587   = getSubst                    `thenSmpl` \ subst ->
 588     let
 589                 -- We make new IdInfo for the new binder by starting from the old binder,
 590                 -- doing appropriate substitutions.
 591                 -- Then we add arity and unfolding info to get the new binder
 592         new_bndr_info = substIdInfo subst old_info (idInfo new_bndr)
 593                         `setArityInfo` arity_info
 594
 595                 -- Add the unfolding *only* for non-loop-breakers
 596                 -- Making loop breakers not have an unfolding at all
 597                 -- means that we can avoid tests in exprIsConApp, for example.
 598                 -- This is important: if exprIsConApp says 'yes' for a recursive
 599                 -- thing, then we can get into an infinite loop
 600         info_w_unf | loop_breaker = new_bndr_info
 601                    | otherwise    = new_bndr_info `setUnfoldingInfo` mkUnfolding top_lvl new_rhs
 602
 603         final_id = new_bndr `setIdInfo` info_w_unf
 604     in
 605                 -- These seqs forces the Id, and hence its IdInfo,
 606                 -- and hence any inner substitutions
 607     final_id                            `seq`
 608     addLetBind (NonRec final_id new_rhs)        $
 609     modifyInScope new_bndr final_id thing_inside
 610
 611   where
 612     old_info          = idInfo old_bndr
 613     occ_info          = occInfo old_info
 614     loop_breaker      = isLoopBreaker occ_info
 615     trivial_rhs       = exprIsTrivial new_rhs
 616     must_keep_binding = black_listed || loop_breaker || isExportedId old_bndr
 617     arity_info        = atLeastArity (exprArity new_rhs)
 618 \end{code}
 619
 620
 621
 622 %************************************************************************
 623 %*                                                                      *
 624 \subsection{simplLazyBind}
 625 %*                                                                      *
 626 %************************************************************************
 627
 628 simplLazyBind basically just simplifies the RHS of a let(rec).
 629 It does two important optimisations though:
 630
 631         * It floats let(rec)s out of the RHS, even if they
 632           are hidden by big lambdas
 633
 634         * It does eta expansion
 635
 636 \begin{code}
 637 simplLazyBind :: Bool                   -- True <=> top level
 638               -> InId -> OutId
 639               -> InExpr                 -- The RHS
 640               -> SimplM (OutStuff a)    -- The body of the binding
 641               -> SimplM (OutStuff a)
 642 -- When called, the subst env is correct for the entire let-binding
 643 -- and hence right for the RHS.
 644 -- Also the binder has already been simplified, and hence is in scope
 645
 646 simplLazyBind top_lvl bndr bndr' rhs thing_inside
 647   = getBlackList                `thenSmpl` \ black_list_fn ->
 648     let
 649         black_listed = black_list_fn bndr
 650     in
 651
 652     if preInlineUnconditionally black_listed bndr then
 653         -- Inline unconditionally
 654         tick (PreInlineUnconditionally bndr)    `thenSmpl_`
 655         getSubstEnv                             `thenSmpl` \ rhs_se ->
 656         (extendSubst bndr (ContEx rhs_se rhs) thing_inside)
 657     else
 658
 659         -- Simplify the RHS
 660     getSubstEnv                                         `thenSmpl` \ rhs_se ->
 661     simplRhs top_lvl False {- Not ok to float unboxed (conservative) -}
 662              (idType bndr')
 663              rhs rhs_se                                 $ \ rhs' ->
 664
 665         -- Now compete the binding and simplify the body
 666     completeBinding bndr bndr' top_lvl black_listed rhs' thing_inside
 667 \end{code}
 668
 669
 670
 671 \begin{code}
 672 simplRhs :: Bool                -- True <=> Top level
 673          -> Bool                -- True <=> OK to float unboxed (speculative) bindings
 674                                 --          False for (a) recursive and (b) top-level bindings
 675          -> OutType             -- Type of RHS; used only occasionally
 676          -> InExpr -> SubstEnv
 677          -> (OutExpr -> SimplM (OutStuff a))
 678          -> SimplM (OutStuff a)
 679 simplRhs top_lvl float_ubx rhs_ty rhs rhs_se thing_inside
 680   =     -- Simplify it
 681     setSubstEnv rhs_se (simplExprF rhs (mkRhsStop rhs_ty))      `thenSmpl` \ (floats1, (rhs_in_scope, rhs1)) ->
 682     let
 683         (floats2, rhs2) = splitFloats float_ubx floats1 rhs1
 684     in
 685                 -- There's a subtlety here.  There may be a binding (x* = e) in the
 686                 -- floats, where the '*' means 'will be demanded'.  So is it safe
 687                 -- to float it out?  Answer no, but it won't matter because
 688                 -- we only float if arg' is a WHNF,
 689                 -- and so there can't be any 'will be demanded' bindings in the floats.
 690                 -- Hence the assert
 691     WARN( any demanded_float (fromOL floats2), ppr (fromOL floats2) )
 692
 693         --                      Transform the RHS
 694         -- It's important that we do eta expansion on function *arguments* (which are
 695         -- simplified with simplRhs), as well as let-bound right-hand sides.
 696         -- Otherwise we find that things like
 697         --      f (\x -> case x of I# x' -> coerce T (\ y -> ...))
 698         -- get right through to the code generator as two separate lambdas,
 699         -- which is a Bad Thing
 700     tryRhsTyLam rhs2            `thenSmpl` \ (floats3, rhs3) ->
 701     tryEtaExpansion rhs3 rhs_ty `thenSmpl` \ (floats4, rhs4) ->
 702
 703         -- Float lets if (a) we're at the top level
 704         -- or            (b) the resulting RHS is one we'd like to expose
 705     if (top_lvl || exprIsCheap rhs4) then
 706         (if (isNilOL floats2 && null floats3 && null floats4) then
 707                 returnSmpl ()
 708          else
 709                 tick LetFloatFromLet)                   `thenSmpl_`
 710
 711         addFloats floats2 rhs_in_scope  $
 712         addAuxiliaryBinds floats3       $
 713         addAuxiliaryBinds floats4       $
 714         thing_inside rhs4
 715     else
 716                 -- Don't do the float
 717         thing_inside (wrapFloats floats1 rhs1)
 718
 719 demanded_float (NonRec b r) = isStrict (idDemandInfo b) && not (isUnLiftedType (idType b))
 720                 -- Unlifted-type (cheap-eagerness) lets may well have a demanded flag on them
 721 demanded_float (Rec _)      = False
 722
 723 -- If float_ubx is true we float all the bindings, otherwise
 724 -- we just float until we come across an unlifted one.
 725 -- Remember that the unlifted bindings in the floats are all for
 726 -- guaranteed-terminating non-exception-raising unlifted things,
 727 -- which we are happy to do speculatively.  However, we may still
 728 -- not be able to float them out, because the context
 729 -- is either a Rec group, or the top level, neither of which
 730 -- can tolerate them.
 731 splitFloats float_ubx floats rhs
 732   | float_ubx = (floats, rhs)           -- Float them all
 733   | otherwise = go (fromOL floats)
 734   where
 735     go []                   = (nilOL, rhs)
 736     go (f:fs) | must_stay f = (nilOL, mkLets (f:fs) rhs)
 737               | otherwise   = case go fs of
 738                                    (out, rhs') -> (f `consOL` out, rhs')
 739
 740     must_stay (Rec prs)    = False      -- No unlifted bindings in here
 741     must_stay (NonRec b r) = isUnLiftedType (idType b)
 742 \end{code}
 743
 744
 745
 746 %************************************************************************
 747 %*                                                                      *
 748 \subsection{Variables}
 749 %*                                                                      *
 750 %************************************************************************
 751
 752 \begin{code}
 753 simplVar var cont
 754   = getSubst            `thenSmpl` \ subst ->
 755     case lookupIdSubst subst var of
 756         DoneEx e        -> zapSubstEnv (simplExprF e cont)
 757         ContEx env1 e   -> setSubstEnv env1 (simplExprF e cont)
 758         DoneId var1 occ -> WARN( not (isInScope var1 subst) && mustHaveLocalBinding var1,
 759                                  text "simplVar:" <+> ppr var )
 760                            zapSubstEnv (completeCall var1 occ cont)
 761                 -- The template is already simplified, so don't re-substitute.
 762                 -- This is VITAL.  Consider
 763                 --      let x = e in
 764                 --      let y = \z -> ...x... in
 765                 --      \ x -> ...y...
 766                 -- We'll clone the inner \x, adding x->x' in the id_subst
 767                 -- Then when we inline y, we must *not* replace x by x' in
 768                 -- the inlined copy!!
 769
 770 ---------------------------------------------------------
 771 --      Dealing with a call
 772
 773 completeCall var occ_info cont
 774   = getBlackList                `thenSmpl` \ black_list_fn ->
 775     getInScope                  `thenSmpl` \ in_scope ->
 776     getContArgs var cont        `thenSmpl` \ (args, call_cont, inline_call) ->
 777     getDOptsSmpl                `thenSmpl` \ dflags ->
 778     let
 779         black_listed       = black_list_fn var
 780         arg_infos          = [ interestingArg in_scope arg subst
 781                              | (arg, subst, _) <- args, isValArg arg]
 782
 783         interesting_cont = interestingCallContext (not (null args))
 784                                                   (not (null arg_infos))
 785                                                   call_cont
 786
 787         inline_cont | inline_call = discardInline cont
 788                     | otherwise   = cont
 789
 790         maybe_inline = callSiteInline dflags black_listed inline_call occ_info
 791                                       var arg_infos interesting_cont
 792     in
 793         -- First, look for an inlining
 794     case maybe_inline of {
 795         Just unfolding          -- There is an inlining!
 796           ->  tick (UnfoldingDone var)          `thenSmpl_`
 797               simplExprF unfolding inline_cont
 798
 799         ;
 800         Nothing ->              -- No inlining!
 801
 802
 803     simplifyArgs (isDataConId var) args (contResultType call_cont)  $ \ args' ->
 804
 805         -- Next, look for rules or specialisations that match
 806         --
 807         -- It's important to simplify the args first, because the rule-matcher
 808         -- doesn't do substitution as it goes.  We don't want to use subst_args
 809         -- (defined in the 'where') because that throws away useful occurrence info,
 810         -- and perhaps-very-important specialisations.
 811         --
 812         -- Some functions have specialisations *and* are strict; in this case,
 813         -- we don't want to inline the wrapper of the non-specialised thing; better
 814         -- to call the specialised thing instead.
 815         -- But the black-listing mechanism means that inlining of the wrapper
 816         -- won't occur for things that have specialisations till a later phase, so
 817         -- it's ok to try for inlining first.
 818         --
 819         -- You might think that we shouldn't apply rules for a loop breaker:
 820         -- doing so might give rise to an infinite loop, because a RULE is
 821         -- rather like an extra equation for the function:
 822         --      RULE:           f (g x) y = x+y
 823         --      Eqn:            f a     y = a-y
 824         --
 825         -- But it's too drastic to disable rules for loop breakers.
 826         -- Even the foldr/build rule would be disabled, because foldr
 827         -- is recursive, and hence a loop breaker:
 828         --      foldr k z (build g) = g k z
 829         -- So it's up to the programmer: rules can cause divergence
 830
 831     getSwitchChecker    `thenSmpl` \ chkr ->
 832     let
 833         maybe_rule | switchIsOn chkr DontApplyRules = Nothing
 834                    | otherwise                      = lookupRule in_scope var args'
 835     in
 836     case maybe_rule of {
 837         Just (rule_name, rule_rhs) ->
 838                 tick (RuleFired rule_name)                      `thenSmpl_`
 839 #ifdef DEBUG
 840                 (if dopt Opt_D_dump_inlinings dflags then
 841                    pprTrace "Rule fired" (vcat [
 842                         text "Rule:" <+> ptext rule_name,
 843                         text "Before:" <+> ppr var <+> sep (map pprParendExpr args'),
 844                         text "After: " <+> pprCoreExpr rule_rhs])
 845                  else
 846                         id)             $
 847 #endif
 848                 simplExprF rule_rhs call_cont ;
 849
 850         Nothing ->              -- No rules
 851
 852         -- Done
 853     rebuild (mkApps (Var var) args') call_cont
 854     }}
 855
 856
 857 ---------------------------------------------------------
 858 --      Simplifying the arguments of a call
 859
 860 simplifyArgs :: Bool                            -- It's a data constructor
 861              -> [(InExpr, SubstEnv, Bool)]      -- Details of the arguments
 862              -> OutType                         -- Type of the continuation
 863              -> ([OutExpr] -> SimplM OutExprStuff)
 864              -> SimplM OutExprStuff
 865
 866 -- Simplify the arguments to a call.
 867 -- This part of the simplifier may break the no-shadowing invariant
 868 -- Consider
 869 --      f (...(\a -> e)...) (case y of (a,b) -> e')
 870 -- where f is strict in its second arg
 871 -- If we simplify the innermost one first we get (...(\a -> e)...)
 872 -- Simplifying the second arg makes us float the case out, so we end up with
 873 --      case y of (a,b) -> f (...(\a -> e)...) e'
 874 -- So the output does not have the no-shadowing invariant.  However, there is
 875 -- no danger of getting name-capture, because when the first arg was simplified
 876 -- we used an in-scope set that at least mentioned all the variables free in its
 877 -- static environment, and that is enough.
 878 --
 879 -- We can't just do innermost first, or we'd end up with a dual problem:
 880 --      case x of (a,b) -> f e (...(\a -> e')...)
 881 --
 882 -- I spent hours trying to recover the no-shadowing invariant, but I just could
 883 -- not think of an elegant way to do it.  The simplifier is already knee-deep in
 884 -- continuations.  We have to keep the right in-scope set around; AND we have
 885 -- to get the effect that finding (error "foo") in a strict arg position will
 886 -- discard the entire application and replace it with (error "foo").  Getting
 887 -- all this at once is TOO HARD!
 888
 889 simplifyArgs is_data_con args cont_ty thing_inside
 890   | not is_data_con
 891   = go args thing_inside
 892
 893   | otherwise   -- It's a data constructor, so we want
 894                 -- to switch off inlining in the arguments
 895                 -- If we don't do this, consider:
 896                 --      let x = +# p q in C {x}
 897                 -- Even though x get's an occurrence of 'many', its RHS looks cheap,
 898                 -- and there's a good chance it'll get inlined back into C's RHS. Urgh!
 899   = getBlackList                                `thenSmpl` \ old_bl ->
 900     setBlackList noInlineBlackList              $
 901     go args                                     $ \ args' ->
 902     setBlackList old_bl                         $
 903     thing_inside args'
 904
 905   where
 906     go []         thing_inside = thing_inside []
 907     go (arg:args) thing_inside = simplifyArg is_data_con arg cont_ty    $ \ arg' ->
 908                                  go args                                $ \ args' ->
 909                                  thing_inside (arg':args')
 910
 911 simplifyArg is_data_con (Type ty_arg, se, _) cont_ty thing_inside
 912   = simplTyArg ty_arg se        `thenSmpl` \ new_ty_arg ->
 913     thing_inside (Type new_ty_arg)
 914
 915 simplifyArg is_data_con (val_arg, se, is_strict) cont_ty thing_inside
 916   = getInScope          `thenSmpl` \ in_scope ->
 917     let
 918         arg_ty = substTy (mkSubst in_scope se) (exprType val_arg)
 919     in
 920     if not is_data_con then
 921         -- An ordinary function
 922         simplValArg arg_ty is_strict val_arg se cont_ty thing_inside
 923     else
 924         -- A data constructor
 925         -- simplifyArgs has already switched off inlining, so
 926         -- all we have to do here is to let-bind any non-trivial argument
 927
 928         -- It's not always the case that new_arg will be trivial
 929         -- Consider             f x
 930         -- where, in one pass, f gets substituted by a constructor,
 931         -- but x gets substituted by an expression (assume this is the
 932         -- unique occurrence of x).  It doesn't really matter -- it'll get
 933         -- fixed up next pass.  And it happens for dictionary construction,
 934         -- which mentions the wrapper constructor to start with.
 935         simplValArg arg_ty is_strict val_arg se cont_ty         $ \ arg' ->
 936
 937         if exprIsTrivial arg' then
 938              thing_inside arg'
 939         else
 940         newId SLIT("a") (exprType arg')         $ \ arg_id ->
 941         addNonRecBind arg_id arg'               $
 942         thing_inside (Var arg_id)
 943 \end{code}
 944
 945
 946 %************************************************************************
 947 %*                                                                      *
 948 \subsection{Decisions about inlining}
 949 %*                                                                      *
 950 %************************************************************************
 951
 952 NB: At one time I tried not pre/post-inlining top-level things,
 953 even if they occur exactly once.  Reason:
 954         (a) some might appear as a function argument, so we simply
 955                 replace static allocation with dynamic allocation:
 956                    l = <...>
 957                    x = f l
 958         becomes
 959                    x = f <...>
 960
 961         (b) some top level things might be black listed
 962
 963 HOWEVER, I found that some useful foldr/build fusion was lost (most
 964 notably in spectral/hartel/parstof) because the foldr didn't see the build.
 965
 966 Doing the dynamic allocation isn't a big deal, in fact, but losing the
 967 fusion can be.
 968
 969 \begin{code}
 970 preInlineUnconditionally :: Bool {- Black listed -} -> InId -> Bool
 971         -- Examines a bndr to see if it is used just once in a
 972         -- completely safe way, so that it is safe to discard the binding
 973         -- inline its RHS at the (unique) usage site, REGARDLESS of how
 974         -- big the RHS might be.  If this is the case we don't simplify
 975         -- the RHS first, but just inline it un-simplified.
 976         --
 977         -- This is much better than first simplifying a perhaps-huge RHS
 978         -- and then inlining and re-simplifying it.
 979         --
 980         -- NB: we don't even look at the RHS to see if it's trivial
 981         -- We might have
 982         --                      x = y
 983         -- where x is used many times, but this is the unique occurrence
 984         -- of y.  We should NOT inline x at all its uses, because then
 985         -- we'd do the same for y -- aargh!  So we must base this
 986         -- pre-rhs-simplification decision solely on x's occurrences, not
 987         -- on its rhs.
 988         --
 989         -- Evne RHSs labelled InlineMe aren't caught here, because
 990         -- there might be no benefit from inlining at the call site.
 991
 992 preInlineUnconditionally black_listed bndr
 993   | black_listed || opt_SimplNoPreInlining = False
 994   | otherwise = case idOccInfo bndr of
 995                   OneOcc in_lam once -> not in_lam && once
 996                         -- Not inside a lambda, one occurrence ==> safe!
 997                   other              -> False
 998 \end{code}
 999
1000
1001
1002 %************************************************************************
1003 %*                                                                      *
1004 \subsection{The main rebuilder}
1005 %*                                                                      *
1006 %************************************************************************
1007
1008 \begin{code}
1009 -------------------------------------------------------------------
1010 -- Finish rebuilding
1011 rebuild_done expr = returnOutStuff expr
1012
1013 ---------------------------------------------------------
1014 rebuild :: OutExpr -> SimplCont -> SimplM OutExprStuff
1015
1016 --      Stop continuation
1017 rebuild expr (Stop _ _) = rebuild_done expr
1018
1019 --      ArgOf continuation
1020 rebuild expr (ArgOf _ _ cont_fn) = cont_fn expr
1021
1022 --      ApplyTo continuation
1023 rebuild expr cont@(ApplyTo _ arg se cont')
1024   = setSubstEnv se (simplExpr arg)      `thenSmpl` \ arg' ->
1025     rebuild (App expr arg') cont'
1026
1027 --      Coerce continuation
1028 rebuild expr (CoerceIt to_ty cont)
1029   = rebuild (mkCoerce to_ty (exprType expr) expr) cont
1030
1031 --      Inline continuation
1032 rebuild expr (InlinePlease cont)
1033   = rebuild (Note InlineCall expr) cont
1034
1035 rebuild scrut (Select _ bndr alts se cont)
1036   = rebuild_case scrut bndr alts se cont
1037 \end{code}
1038
1039 Case elimination [see the code above]
1040 ~~~~~~~~~~~~~~~~
1041 Start with a simple situation:
1042
1043         case x# of      ===>   e[x#/y#]
1044           y# -> e
1045
1046 (when x#, y# are of primitive type, of course).  We can't (in general)
1047 do this for algebraic cases, because we might turn bottom into
1048 non-bottom!
1049
1050 Actually, we generalise this idea to look for a case where we're
1051 scrutinising a variable, and we know that only the default case can
1052 match.  For example:
1053 \begin{verbatim}
1054         case x of
1055           0#    -> ...
1056           other -> ...(case x of
1057                          0#    -> ...
1058                          other -> ...) ...
1059 \end{code}
1060 Here the inner case can be eliminated.  This really only shows up in
1061 eliminating error-checking code.
1062
1063 We also make sure that we deal with this very common case:
1064
1065         case e of
1066           x -> ...x...
1067
1068 Here we are using the case as a strict let; if x is used only once
1069 then we want to inline it.  We have to be careful that this doesn't
1070 make the program terminate when it would have diverged before, so we
1071 check that
1072         - x is used strictly, or
1073         - e is already evaluated (it may so if e is a variable)
1074
1075 Lastly, we generalise the transformation to handle this:
1076
1077         case e of       ===> r
1078            True  -> r
1079            False -> r
1080
1081 We only do this for very cheaply compared r's (constructors, literals
1082 and variables).  If pedantic bottoms is on, we only do it when the
1083 scrutinee is a PrimOp which can't fail.
1084
1085 We do it *here*, looking at un-simplified alternatives, because we
1086 have to check that r doesn't mention the variables bound by the
1087 pattern in each alternative, so the binder-info is rather useful.
1088
1089 So the case-elimination algorithm is:
1090
1091         1. Eliminate alternatives which can't match
1092
1093         2. Check whether all the remaining alternatives
1094                 (a) do not mention in their rhs any of the variables bound in their pattern
1095            and  (b) have equal rhss
1096
1097         3. Check we can safely ditch the case:
1098                    * PedanticBottoms is off,
1099                 or * the scrutinee is an already-evaluated variable
1100                 or * the scrutinee is a primop which is ok for speculation
1101                         -- ie we want to preserve divide-by-zero errors, and
1102                         -- calls to error itself!
1103
1104                 or * [Prim cases] the scrutinee is a primitive variable
1105
1106                 or * [Alg cases] the scrutinee is a variable and
1107                      either * the rhs is the same variable
1108                         (eg case x of C a b -> x  ===>   x)
1109                      or     * there is only one alternative, the default alternative,
1110                                 and the binder is used strictly in its scope.
1111                                 [NB this is helped by the "use default binder where
1112                                  possible" transformation; see below.]
1113
1114
1115 If so, then we can replace the case with one of the rhss.
1116
1117
1118 Blob of helper functions for the "case-of-something-else" situation.
1119
1120 \begin{code}
1121 ---------------------------------------------------------
1122 --      Eliminate the case if possible
1123
1124 rebuild_case scrut bndr alts se cont
1125   | maybeToBool maybe_con_app
1126   = knownCon scrut (DataAlt con) args bndr alts se cont
1127
1128   | canEliminateCase scrut bndr alts
1129   = tick (CaseElim bndr)                        `thenSmpl_` (
1130     setSubstEnv se                              $
1131     simplBinder bndr                            $ \ bndr' ->
1132         -- Remember to bind the case binder!
1133     completeBinding bndr bndr' False False scrut        $
1134     simplExprF (head (rhssOfAlts alts)) cont)
1135
1136   | otherwise
1137   = complete_case scrut bndr alts se cont
1138
1139   where
1140     maybe_con_app    = exprIsConApp_maybe scrut
1141     Just (con, args) = maybe_con_app
1142
1143         -- See if we can get rid of the case altogether
1144         -- See the extensive notes on case-elimination above
1145 canEliminateCase scrut bndr alts
1146   =     -- Check that the RHSs are all the same, and
1147         -- don't use the binders in the alternatives
1148         -- This test succeeds rapidly in the common case of
1149         -- a single DEFAULT alternative
1150     all (cheapEqExpr rhs1) other_rhss && all binders_unused alts
1151
1152         -- Check that the scrutinee can be let-bound instead of case-bound
1153     && (   exprOkForSpeculation scrut
1154                 -- OK not to evaluate it
1155                 -- This includes things like (==# a# b#)::Bool
1156                 -- so that we simplify
1157                 --      case ==# a# b# of { True -> x; False -> x }
1158                 -- to just
1159                 --      x
1160                 -- This particular example shows up in default methods for
1161                 -- comparision operations (e.g. in (>=) for Int.Int32)
1162         || exprIsValue scrut                    -- It's already evaluated
1163         || var_demanded_later scrut             -- It'll be demanded later
1164
1165 --      || not opt_SimplPedanticBottoms)        -- Or we don't care!
1166 --      We used to allow improving termination by discarding cases, unless -fpedantic-bottoms was on,
1167 --      but that breaks badly for the dataToTag# primop, which relies on a case to evaluate
1168 --      its argument:  case x of { y -> dataToTag# y }
1169 --      Here we must *not* discard the case, because dataToTag# just fetches the tag from
1170 --      the info pointer.  So we'll be pedantic all the time, and see if that gives any
1171 --      other problems
1172        )
1173
1174   where
1175     (rhs1:other_rhss)            = rhssOfAlts alts
1176     binders_unused (_, bndrs, _) = all isDeadBinder bndrs
1177
1178     var_demanded_later (Var v) = isStrict (idDemandInfo bndr)   -- It's going to be evaluated later
1179     var_demanded_later other   = False
1180
1181
1182 ---------------------------------------------------------
1183 --      Case of something else
1184
1185 complete_case scrut case_bndr alts se cont
1186   =     -- Prepare case alternatives
1187     prepareCaseAlts case_bndr (splitTyConApp_maybe (idType case_bndr))
1188                     impossible_cons alts                `thenSmpl` \ better_alts ->
1189
1190         -- Set the new subst-env in place (before dealing with the case binder)
1191     setSubstEnv se                              $
1192
1193         -- Deal with the case binder, and prepare the continuation;
1194         -- The new subst_env is in place
1195     prepareCaseCont better_alts cont            $ \ cont' ->
1196
1197
1198         -- Deal with variable scrutinee
1199     (
1200         getSwitchChecker                                `thenSmpl` \ chkr ->
1201         simplCaseBinder (switchIsOn chkr NoCaseOfCase)
1202                         scrut case_bndr                 $ \ case_bndr' zap_occ_info ->
1203
1204         -- Deal with the case alternatives
1205         simplAlts zap_occ_info impossible_cons
1206                   case_bndr' better_alts cont'  `thenSmpl` \ alts' ->
1207
1208         mkCase scrut case_bndr' alts'
1209     )                                           `thenSmpl` \ case_expr ->
1210
1211         -- Notice that the simplBinder, prepareCaseCont, etc, do *not* scope
1212         -- over the rebuild_done; rebuild_done returns the in-scope set, and
1213         -- that should not include these chaps!
1214     rebuild_done case_expr
1215   where
1216     impossible_cons = case scrut of
1217                             Var v -> otherCons (idUnfolding v)
1218                             other -> []
1219
1220
1221 knownCon :: OutExpr -> AltCon -> [OutExpr]
1222          -> InId -> [InAlt] -> SubstEnv -> SimplCont
1223          -> SimplM OutExprStuff
1224
1225 knownCon expr con args bndr alts se cont
1226   =     -- Arguments should be atomic;
1227         -- yell if not
1228     WARN( not (all exprIsTrivial args),
1229           text "knownCon" <+> ppr expr )
1230     tick (KnownBranch bndr)     `thenSmpl_`
1231     setSubstEnv se              (
1232     simplBinder bndr            $ \ bndr' ->
1233     completeBinding bndr bndr' False False expr $
1234         -- Don't use completeBeta here.  The expr might be
1235         -- an unboxed literal, like 3, or a variable
1236         -- whose unfolding is an unboxed literal... and
1237         -- completeBeta will just construct another case
1238                                         -- expression!
1239     case findAlt con alts of
1240         (DEFAULT, bs, rhs)     -> ASSERT( null bs )
1241                                   simplExprF rhs cont
1242
1243         (LitAlt lit, bs, rhs) ->  ASSERT( null bs )
1244                                   simplExprF rhs cont
1245
1246         (DataAlt dc, bs, rhs)  -> ASSERT( length bs == length real_args )
1247                                   extendSubstList bs (map mk real_args) $
1248                                   simplExprF rhs cont
1249                                where
1250                                   real_args    = drop (dataConNumInstArgs dc) args
1251                                   mk (Type ty) = DoneTy ty
1252                                   mk other     = DoneEx other
1253     )
1254 \end{code}
1255
1256 \begin{code}
1257 prepareCaseCont :: [InAlt] -> SimplCont
1258                 -> (SimplCont -> SimplM (OutStuff a))
1259                 -> SimplM (OutStuff a)
1260         -- Polymorphic recursion here!
1261
1262 prepareCaseCont [alt] cont thing_inside = thing_inside cont
1263 prepareCaseCont alts  cont thing_inside = simplType (coreAltsType alts)         `thenSmpl` \ alts_ty ->
1264                                           mkDupableCont alts_ty cont thing_inside
1265         -- At one time I passed in the un-simplified type, and simplified
1266         -- it only if we needed to construct a join binder, but that
1267         -- didn't work because we have to decompse function types
1268         -- (using funResultTy) in mkDupableCont.
1269 \end{code}
1270
1271 simplCaseBinder checks whether the scrutinee is a variable, v.  If so,
1272 try to eliminate uses of v in the RHSs in favour of case_bndr; that
1273 way, there's a chance that v will now only be used once, and hence
1274 inlined.
1275
1276 There is a time we *don't* want to do that, namely when
1277 -fno-case-of-case is on.  This happens in the first simplifier pass,
1278 and enhances full laziness.  Here's the bad case:
1279         f = \ y -> ...(case x of I# v -> ...(case x of ...) ... )
1280 If we eliminate the inner case, we trap it inside the I# v -> arm,
1281 which might prevent some full laziness happening.  I've seen this
1282 in action in spectral/cichelli/Prog.hs:
1283          [(m,n) | m <- [1..max], n <- [1..max]]
1284 Hence the no_case_of_case argument
1285
1286
1287 If we do this, then we have to nuke any occurrence info (eg IAmDead)
1288 in the case binder, because the case-binder now effectively occurs
1289 whenever v does.  AND we have to do the same for the pattern-bound
1290 variables!  Example:
1291
1292         (case x of { (a,b) -> a }) (case x of { (p,q) -> q })
1293
1294 Here, b and p are dead.  But when we move the argment inside the first
1295 case RHS, and eliminate the second case, we get
1296
1297         case x or { (a,b) -> a b }
1298
1299 Urk! b is alive!  Reason: the scrutinee was a variable, and case elimination
1300 happened.  Hence the zap_occ_info function returned by simplCaseBinder
1301
1302 \begin{code}
1303 simplCaseBinder no_case_of_case (Var v) case_bndr thing_inside
1304   | not no_case_of_case
1305   = simplBinder (zap case_bndr)                                 $ \ case_bndr' ->
1306     modifyInScope v case_bndr'                                  $
1307         -- We could extend the substitution instead, but it would be
1308         -- a hack because then the substitution wouldn't be idempotent
1309         -- any more (v is an OutId).  And this just just as well.
1310     thing_inside case_bndr' zap
1311   where
1312     zap b = b `setIdOccInfo` NoOccInfo
1313
1314 simplCaseBinder add_eval_info other_scrut case_bndr thing_inside
1315   = simplBinder case_bndr               $ \ case_bndr' ->
1316     thing_inside case_bndr' (\ bndr -> bndr)    -- NoOp on bndr
1317 \end{code}
1318
1319 prepareCaseAlts does two things:
1320
1321 1.  Remove impossible alternatives
1322
1323 2.  If the DEFAULT alternative can match only one possible constructor,
1324     then make that constructor explicit.
1325     e.g.
1326         case e of x { DEFAULT -> rhs }
1327      ===>
1328         case e of x { (a,b) -> rhs }
1329     where the type is a single constructor type.  This gives better code
1330     when rhs also scrutinises x or e.
1331
1332 \begin{code}
1333 prepareCaseAlts bndr (Just (tycon, inst_tys)) scrut_cons alts
1334   | isDataTyCon tycon
1335   = case (findDefault filtered_alts, missing_cons) of
1336
1337         ((alts_no_deflt, Just rhs), [data_con])         -- Just one missing constructor!
1338                 -> tick (FillInCaseDefault bndr)        `thenSmpl_`
1339                    let
1340                         (_,_,ex_tyvars,_,_,_) = dataConSig data_con
1341                    in
1342                    getUniquesSmpl (length ex_tyvars)                            `thenSmpl` \ tv_uniqs ->
1343                    let
1344                         ex_tyvars' = zipWithEqual "simpl_alt" mk tv_uniqs ex_tyvars
1345                         mk uniq tv = mkSysTyVar uniq (tyVarKind tv)
1346                         arg_tys    = dataConArgTys data_con
1347                                                    (inst_tys ++ mkTyVarTys ex_tyvars')
1348                    in
1349                    newIds SLIT("a") arg_tys             $ \ bndrs ->
1350                    returnSmpl ((DataAlt data_con, ex_tyvars' ++ bndrs, rhs) : alts_no_deflt)
1351
1352         other -> returnSmpl filtered_alts
1353   where
1354         -- Filter out alternatives that can't possibly match
1355     filtered_alts = case scrut_cons of
1356                         []    -> alts
1357                         other -> [alt | alt@(con,_,_) <- alts, not (con `elem` scrut_cons)]
1358
1359     missing_cons = [data_con | data_con <- tyConDataConsIfAvailable tycon,
1360                                not (data_con `elem` handled_data_cons)]
1361     handled_data_cons = [data_con | DataAlt data_con         <- scrut_cons] ++
1362                         [data_con | (DataAlt data_con, _, _) <- filtered_alts]
1363
1364 -- The default case
1365 prepareCaseAlts _ _ scrut_cons alts
1366   = returnSmpl alts                     -- Functions
1367
1368
1369 ----------------------
1370 simplAlts zap_occ_info scrut_cons case_bndr' alts cont'
1371   = mapSmpl simpl_alt alts
1372   where
1373     inst_tys' = tyConAppArgs (idType case_bndr')
1374
1375         -- handled_cons is all the constructors that are dealt
1376         -- with, either by being impossible, or by there being an alternative
1377     handled_cons = scrut_cons ++ [con | (con,_,_) <- alts, con /= DEFAULT]
1378
1379     simpl_alt (DEFAULT, _, rhs)
1380         =       -- In the default case we record the constructors that the
1381                 -- case-binder *can't* be.
1382                 -- We take advantage of any OtherCon info in the case scrutinee
1383           modifyInScope case_bndr' (case_bndr' `setIdUnfolding` mkOtherCon handled_cons)        $
1384           simplExprC rhs cont'                                                  `thenSmpl` \ rhs' ->
1385           returnSmpl (DEFAULT, [], rhs')
1386
1387     simpl_alt (con, vs, rhs)
1388         =       -- Deal with the pattern-bound variables
1389                 -- Mark the ones that are in ! positions in the data constructor
1390                 -- as certainly-evaluated.
1391                 -- NB: it happens that simplBinders does *not* erase the OtherCon
1392                 --     form of unfolding, so it's ok to add this info before
1393                 --     doing simplBinders
1394           simplBinders (add_evals con vs)                                       $ \ vs' ->
1395
1396                 -- Bind the case-binder to (con args)
1397           let
1398                 unfolding = mkUnfolding False (mkAltExpr con vs' inst_tys')
1399           in
1400           modifyInScope case_bndr' (case_bndr' `setIdUnfolding` unfolding)      $
1401           simplExprC rhs cont'          `thenSmpl` \ rhs' ->
1402           returnSmpl (con, vs', rhs')
1403
1404
1405         -- add_evals records the evaluated-ness of the bound variables of
1406         -- a case pattern.  This is *important*.  Consider
1407         --      data T = T !Int !Int
1408         --
1409         --      case x of { T a b -> T (a+1) b }
1410         --
1411         -- We really must record that b is already evaluated so that we don't
1412         -- go and re-evaluate it when constructing the result.
1413
1414     add_evals (DataAlt dc) vs = cat_evals vs (dataConRepStrictness dc)
1415     add_evals other_con    vs = vs
1416
1417     cat_evals [] [] = []
1418     cat_evals (v:vs) (str:strs)
1419         | isTyVar v    = v                                   : cat_evals vs (str:strs)
1420         | isStrict str = (v' `setIdUnfolding` mkOtherCon []) : cat_evals vs strs
1421         | otherwise    = v'                                  : cat_evals vs strs
1422         where
1423           v' = zap_occ_info v
1424 \end{code}
1425
1426
1427 %************************************************************************
1428 %*                                                                      *
1429 \subsection{Duplicating continuations}
1430 %*                                                                      *
1431 %************************************************************************
1432
1433 \begin{code}
1434 mkDupableCont :: OutType                -- Type of the thing to be given to the continuation
1435               -> SimplCont
1436               -> (SimplCont -> SimplM (OutStuff a))
1437               -> SimplM (OutStuff a)
1438 mkDupableCont ty cont thing_inside
1439   | contIsDupable cont
1440   = thing_inside cont
1441
1442 mkDupableCont _ (CoerceIt ty cont) thing_inside
1443   = mkDupableCont ty cont               $ \ cont' ->
1444     thing_inside (CoerceIt ty cont')
1445
1446 mkDupableCont ty (InlinePlease cont) thing_inside
1447   = mkDupableCont ty cont               $ \ cont' ->
1448     thing_inside (InlinePlease cont')
1449
1450 mkDupableCont join_arg_ty (ArgOf _ cont_ty cont_fn) thing_inside
1451   =     -- Build the RHS of the join point
1452     newId SLIT("a") join_arg_ty                         ( \ arg_id ->
1453         cont_fn (Var arg_id)                            `thenSmpl` \ (floats, (_, rhs)) ->
1454         returnSmpl (Lam (setOneShotLambda arg_id) (wrapFloats floats rhs))
1455     )                                                   `thenSmpl` \ join_rhs ->
1456
1457         -- Build the join Id and continuation
1458         -- We give it a "$j" name just so that for later amusement
1459         -- we can identify any join points that don't end up as let-no-escapes
1460         -- [NOTE: the type used to be exprType join_rhs, but this seems more elegant.]
1461     newId SLIT("$j") (mkFunTy join_arg_ty cont_ty)      $ \ join_id ->
1462     let
1463         new_cont = ArgOf OkToDup cont_ty
1464                          (\arg' -> rebuild_done (App (Var join_id) arg'))
1465     in
1466
1467     tick (CaseOfCase join_id)                                           `thenSmpl_`
1468         -- Want to tick here so that we go round again,
1469         -- and maybe copy or inline the code;
1470         -- not strictly CaseOf Case
1471     addLetBind (NonRec join_id join_rhs)        $
1472     thing_inside new_cont
1473
1474 mkDupableCont ty (ApplyTo _ arg se cont) thing_inside
1475   = mkDupableCont (funResultTy ty) cont                 $ \ cont' ->
1476     setSubstEnv se (simplExpr arg)                      `thenSmpl` \ arg' ->
1477     if exprIsDupable arg' then
1478         thing_inside (ApplyTo OkToDup arg' emptySubstEnv cont')
1479     else
1480     newId SLIT("a") (exprType arg')                     $ \ bndr ->
1481
1482     tick (CaseOfCase bndr)                              `thenSmpl_`
1483         -- Want to tick here so that we go round again,
1484         -- and maybe copy or inline the code;
1485         -- not strictly CaseOf Case
1486
1487      addLetBind (NonRec bndr arg')              $
1488         -- But what if the arg should be case-bound?  We can't use
1489         -- addNonRecBind here because its type is too specific.
1490         -- This has been this way for a long time, so I'll leave it,
1491         -- but I can't convince myself that it's right.
1492
1493      thing_inside (ApplyTo OkToDup (Var bndr) emptySubstEnv cont')
1494
1495
1496 mkDupableCont ty (Select _ case_bndr alts se cont) thing_inside
1497   = tick (CaseOfCase case_bndr)                                         `thenSmpl_`
1498     setSubstEnv se (
1499         simplBinder case_bndr                                           $ \ case_bndr' ->
1500         prepareCaseCont alts cont                                       $ \ cont' ->
1501         mkDupableAlts case_bndr case_bndr' cont' alts                   $ \ alts' ->
1502         returnOutStuff alts'
1503     )                                   `thenSmpl` \ (alt_binds, (in_scope, alts')) ->
1504
1505     addFloats alt_binds in_scope                $
1506
1507         -- NB that the new alternatives, alts', are still InAlts, using the original
1508         -- binders.  That means we can keep the case_bndr intact. This is important
1509         -- because another case-of-case might strike, and so we want to keep the
1510         -- info that the case_bndr is dead (if it is, which is often the case).
1511         -- This is VITAL when the type of case_bndr is an unboxed pair (often the
1512         -- case in I/O rich code.  We aren't allowed a lambda bound
1513         -- arg of unboxed tuple type, and indeed such a case_bndr is always dead
1514     thing_inside (Select OkToDup case_bndr alts' se (mkStop (contResultType cont)))
1515
1516 mkDupableAlts :: InId -> OutId -> SimplCont -> [InAlt]
1517              -> ([InAlt] -> SimplM (OutStuff a))
1518              -> SimplM (OutStuff a)
1519 mkDupableAlts case_bndr case_bndr' cont [] thing_inside
1520   = thing_inside []
1521 mkDupableAlts case_bndr case_bndr' cont (alt:alts) thing_inside
1522   = mkDupableAlt  case_bndr case_bndr' cont alt         $ \ alt' ->
1523     mkDupableAlts case_bndr case_bndr' cont alts        $ \ alts' ->
1524     thing_inside (alt' : alts')
1525
1526 mkDupableAlt case_bndr case_bndr' cont alt@(con, bndrs, rhs) thing_inside
1527   = simplBinders bndrs                                  $ \ bndrs' ->
1528     simplExprC rhs cont                                 `thenSmpl` \ rhs' ->
1529
1530     if (case cont of { Stop _ _ -> exprIsDupable rhs'; other -> False}) then
1531         -- It is worth checking for a small RHS because otherwise we
1532         -- get extra let bindings that may cause an extra iteration of the simplifier to
1533         -- inline back in place.  Quite often the rhs is just a variable or constructor.
1534         -- The Ord instance of Maybe in PrelMaybe.lhs, for example, took several extra
1535         -- iterations because the version with the let bindings looked big, and so wasn't
1536         -- inlined, but after the join points had been inlined it looked smaller, and so
1537         -- was inlined.
1538         --
1539         -- But since the continuation is absorbed into the rhs, we only do this
1540         -- for a Stop continuation.
1541         --
1542         -- NB: we have to check the size of rhs', not rhs.
1543         -- Duplicating a small InAlt might invalidate occurrence information
1544         -- However, if it *is* dupable, we return the *un* simplified alternative,
1545         -- because otherwise we'd need to pair it up with an empty subst-env.
1546         -- (Remember we must zap the subst-env before re-simplifying something).
1547         -- Rather than do this we simply agree to re-simplify the original (small) thing later.
1548         thing_inside alt
1549
1550     else
1551     let
1552         rhs_ty' = exprType rhs'
1553         (used_bndrs, used_bndrs')
1554            = unzip [pr | pr@(bndr,bndr') <- zip (case_bndr  : bndrs)
1555                                                 (case_bndr' : bndrs'),
1556                          not (isDeadBinder bndr)]
1557                 -- The new binders have lost their occurrence info,
1558                 -- so we have to extract it from the old ones
1559     in
1560     ( if null used_bndrs'
1561         -- If we try to lift a primitive-typed something out
1562         -- for let-binding-purposes, we will *caseify* it (!),
1563         -- with potentially-disastrous strictness results.  So
1564         -- instead we turn it into a function: \v -> e
1565         -- where v::State# RealWorld#.  The value passed to this function
1566         -- is realworld#, which generates (almost) no code.
1567
1568         -- There's a slight infelicity here: we pass the overall
1569         -- case_bndr to all the join points if it's used in *any* RHS,
1570         -- because we don't know its usage in each RHS separately
1571
1572         -- We used to say "&& isUnLiftedType rhs_ty'" here, but now
1573         -- we make the join point into a function whenever used_bndrs'
1574         -- is empty.  This makes the join-point more CPR friendly.
1575         -- Consider:    let j = if .. then I# 3 else I# 4
1576         --              in case .. of { A -> j; B -> j; C -> ... }
1577         --
1578         -- Now CPR should not w/w j because it's a thunk, so
1579         -- that means that the enclosing function can't w/w either,
1580         -- which is a lose.  Here's the example that happened in practice:
1581         --      kgmod :: Int -> Int -> Int
1582         --      kgmod x y = if x > 0 && y < 0 || x < 0 && y > 0
1583         --                  then 78
1584         --                  else 5
1585
1586         then newId SLIT("w") realWorldStatePrimTy  $ \ rw_id ->
1587              returnSmpl ([rw_id], [Var realWorldPrimId])
1588         else
1589              returnSmpl (used_bndrs', map varToCoreExpr used_bndrs)
1590     )
1591         `thenSmpl` \ (final_bndrs', final_args) ->
1592
1593         -- See comment about "$j" name above
1594     newId SLIT("$j") (foldr mkPiType rhs_ty' final_bndrs')      $ \ join_bndr ->
1595         -- Notice the funky mkPiType.  If the contructor has existentials
1596         -- it's possible that the join point will be abstracted over
1597         -- type varaibles as well as term variables.
1598         --  Example:  Suppose we have
1599         --      data T = forall t.  C [t]
1600         --  Then faced with
1601         --      case (case e of ...) of
1602         --          C t xs::[t] -> rhs
1603         --  We get the join point
1604         --      let j :: forall t. [t] -> ...
1605         --          j = /\t \xs::[t] -> rhs
1606         --      in
1607         --      case (case e of ...) of
1608         --          C t xs::[t] -> j t xs
1609
1610     let
1611         -- We make the lambdas into one-shot-lambdas.  The
1612         -- join point is sure to be applied at most once, and doing so
1613         -- prevents the body of the join point being floated out by
1614         -- the full laziness pass
1615         really_final_bndrs = map one_shot final_bndrs'
1616         one_shot v | isId v    = setOneShotLambda v
1617                    | otherwise = v
1618     in
1619     addLetBind (NonRec join_bndr (mkLams really_final_bndrs rhs'))      $
1620     thing_inside (con, bndrs, mkApps (Var join_bndr) final_args)
1621 \end{code}