ghc/compiler/simplCore/Simplify.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[Simplify]{The main module of the simplifier}
   5
   6 \begin{code}
   7 module Simplify ( simplTopBinds, simplExpr ) where
   8
   9 #include "HsVersions.h"
  10
  11 import CmdLineOpts      ( dopt, DynFlag(Opt_D_dump_inlinings),
  12                           SimplifierSwitch(..)
  13                         )
  14 import SimplMonad
  15 import SimplUtils       ( mkCase, mkLam, newId, prepareAlts,
  16                           simplBinder, simplBinders, simplLamBndrs, simplRecBndrs, simplLetBndr,
  17                           SimplCont(..), DupFlag(..), LetRhsFlag(..),
  18                           mkRhsStop, mkBoringStop,  pushContArgs,
  19                           contResultType, countArgs, contIsDupable, contIsRhsOrArg,
  20                           getContArgs, interestingCallContext, interestingArg, isStrictType
  21                         )
  22 import Id               ( Id, idType, idInfo, idArity, isDataConWorkId,
  23                           setIdUnfolding, isDeadBinder,
  24                           idNewDemandInfo, setIdInfo,
  25                           setIdOccInfo, zapLamIdInfo, setOneShotLambda,
  26                         )
  27 import MkId             ( eRROR_ID )
  28 import Literal          ( mkStringLit )
  29 import OccName          ( encodeFS )
  30 import IdInfo           ( OccInfo(..), isLoopBreaker,
  31                           setArityInfo, zapDemandInfo,
  32                           setUnfoldingInfo,
  33                           occInfo
  34                         )
  35 import NewDemand        ( isStrictDmd )
  36 import Unify            ( coreRefineTys )
  37 import DataCon          ( dataConTyCon, dataConRepStrictness, isVanillaDataCon )
  38 import TyCon            ( tyConArity )
  39 import CoreSyn
  40 import PprCore          ( pprParendExpr, pprCoreExpr )
  41 import CoreUnfold       ( mkOtherCon, mkUnfolding, callSiteInline )
  42 import CoreUtils        ( exprIsDupable, exprIsTrivial, needsCaseBinding,
  43                           exprIsConApp_maybe, mkPiTypes, findAlt,
  44                           exprType, exprIsValue,
  45                           exprOkForSpeculation, exprArity,
  46                           mkCoerce, mkCoerce2, mkSCC, mkInlineMe, applyTypeToArg
  47                         )
  48 import Rules            ( lookupRule )
  49 import BasicTypes       ( isMarkedStrict )
  50 import CostCentre       ( currentCCS )
  51 import Type             ( isUnLiftedType, seqType, tyConAppArgs, funArgTy,
  52                           splitFunTy_maybe, splitFunTy, eqType, substTy
  53                         )
  54 import Subst            ( SubstResult(..), emptySubst, substExpr,
  55                           substId, simplIdInfo )
  56 import TysPrim          ( realWorldStatePrimTy )
  57 import PrelInfo         ( realWorldPrimId )
  58 import BasicTypes       ( TopLevelFlag(..), isTopLevel,
  59                           RecFlag(..), isNonRec
  60                         )
  61 import OrdList
  62 import Maybe            ( Maybe )
  63 import Maybes           ( orElse )
  64 import Outputable
  65 import Util             ( notNull )
  66 \end{code}
  67
  68
  69 The guts of the simplifier is in this module, but the driver loop for
  70 the simplifier is in SimplCore.lhs.
  71
  72
  73 -----------------------------------------
  74         *** IMPORTANT NOTE ***
  75 -----------------------------------------
  76 The simplifier used to guarantee that the output had no shadowing, but
  77 it does not do so any more.   (Actually, it never did!)  The reason is
  78 documented with simplifyArgs.
  79
  80
  81 -----------------------------------------
  82         *** IMPORTANT NOTE ***
  83 -----------------------------------------
  84 Many parts of the simplifier return a bunch of "floats" as well as an
  85 expression. This is wrapped as a datatype SimplUtils.FloatsWith.
  86
  87 All "floats" are let-binds, not case-binds, but some non-rec lets may
  88 be unlifted (with RHS ok-for-speculation).
  89
  90
  91
  92 -----------------------------------------
  93         ORGANISATION OF FUNCTIONS
  94 -----------------------------------------
  95 simplTopBinds
  96   - simplify all top-level binders
  97   - for NonRec, call simplRecOrTopPair
  98   - for Rec,    call simplRecBind
  99
 100
 101         ------------------------------
 102 simplExpr (applied lambda)      ==> simplNonRecBind
 103 simplExpr (Let (NonRec ...) ..) ==> simplNonRecBind
 104 simplExpr (Let (Rec ...)    ..) ==> simplify binders; simplRecBind
 105
 106         ------------------------------
 107 simplRecBind    [binders already simplfied]
 108   - use simplRecOrTopPair on each pair in turn
 109
 110 simplRecOrTopPair [binder already simplified]
 111   Used for: recursive bindings (top level and nested)
 112             top-level non-recursive bindings
 113   Returns:
 114   - check for PreInlineUnconditionally
 115   - simplLazyBind
 116
 117 simplNonRecBind
 118   Used for: non-top-level non-recursive bindings
 119             beta reductions (which amount to the same thing)
 120   Because it can deal with strict arts, it takes a
 121         "thing-inside" and returns an expression
 122
 123   - check for PreInlineUnconditionally
 124   - simplify binder, including its IdInfo
 125   - if strict binding
 126         simplStrictArg
 127         mkAtomicArgs
 128         completeNonRecX
 129     else
 130         simplLazyBind
 131         addFloats
 132
 133 simplNonRecX:   [given a *simplified* RHS, but an *unsimplified* binder]
 134   Used for: binding case-binder and constr args in a known-constructor case
 135   - check for PreInLineUnconditionally
 136   - simplify binder
 137   - completeNonRecX
 138
 139         ------------------------------
 140 simplLazyBind:  [binder already simplified, RHS not]
 141   Used for: recursive bindings (top level and nested)
 142             top-level non-recursive bindings
 143             non-top-level, but *lazy* non-recursive bindings
 144         [must not be strict or unboxed]
 145   Returns floats + an augmented environment, not an expression
 146   - substituteIdInfo and add result to in-scope
 147         [so that rules are available in rec rhs]
 148   - simplify rhs
 149   - mkAtomicArgs
 150   - float if exposes constructor or PAP
 151   - completeLazyBind
 152
 153
 154 completeNonRecX:        [binder and rhs both simplified]
 155   - if the the thing needs case binding (unlifted and not ok-for-spec)
 156         build a Case
 157    else
 158         completeLazyBind
 159         addFloats
 160
 161 completeLazyBind:       [given a simplified RHS]
 162         [used for both rec and non-rec bindings, top level and not]
 163   - try PostInlineUnconditionally
 164   - add unfolding [this is the only place we add an unfolding]
 165   - add arity
 166
 167
 168
 169 Right hand sides and arguments
 170 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 171 In many ways we want to treat
 172         (a) the right hand side of a let(rec), and
 173         (b) a function argument
 174 in the same way.  But not always!  In particular, we would
 175 like to leave these arguments exactly as they are, so they
 176 will match a RULE more easily.
 177
 178         f (g x, h x)
 179         g (+ x)
 180
 181 It's harder to make the rule match if we ANF-ise the constructor,
 182 or eta-expand the PAP:
 183
 184         f (let { a = g x; b = h x } in (a,b))
 185         g (\y. + x y)
 186
 187 On the other hand if we see the let-defns
 188
 189         p = (g x, h x)
 190         q = + x
 191
 192 then we *do* want to ANF-ise and eta-expand, so that p and q
 193 can be safely inlined.
 194
 195 Even floating lets out is a bit dubious.  For let RHS's we float lets
 196 out if that exposes a value, so that the value can be inlined more vigorously.
 197 For example
 198
 199         r = let x = e in (x,x)
 200
 201 Here, if we float the let out we'll expose a nice constructor. We did experiments
 202 that showed this to be a generally good thing.  But it was a bad thing to float
 203 lets out unconditionally, because that meant they got allocated more often.
 204
 205 For function arguments, there's less reason to expose a constructor (it won't
 206 get inlined).  Just possibly it might make a rule match, but I'm pretty skeptical.
 207 So for the moment we don't float lets out of function arguments either.
 208
 209
 210 Eta expansion
 211 ~~~~~~~~~~~~~~
 212 For eta expansion, we want to catch things like
 213
 214         case e of (a,b) -> \x -> case a of (p,q) -> \y -> r
 215
 216 If the \x was on the RHS of a let, we'd eta expand to bring the two
 217 lambdas together.  And in general that's a good thing to do.  Perhaps
 218 we should eta expand wherever we find a (value) lambda?  Then the eta
 219 expansion at a let RHS can concentrate solely on the PAP case.
 220
 221
 222 %************************************************************************
 223 %*                                                                      *
 224 \subsection{Bindings}
 225 %*                                                                      *
 226 %************************************************************************
 227
 228 \begin{code}
 229 simplTopBinds :: SimplEnv -> [InBind] -> SimplM [OutBind]
 230
 231 simplTopBinds env binds
 232   =     -- Put all the top-level binders into scope at the start
 233         -- so that if a transformation rule has unexpectedly brought
 234         -- anything into scope, then we don't get a complaint about that.
 235         -- It's rather as if the top-level binders were imported.
 236     simplRecBndrs env (bindersOfBinds binds)    `thenSmpl` \ (env, bndrs') ->
 237     simpl_binds env binds bndrs'                `thenSmpl` \ (floats, _) ->
 238     freeTick SimplifierDone                     `thenSmpl_`
 239     returnSmpl (floatBinds floats)
 240   where
 241         -- We need to track the zapped top-level binders, because
 242         -- they should have their fragile IdInfo zapped (notably occurrence info)
 243         -- That's why we run down binds and bndrs' simultaneously.
 244     simpl_binds :: SimplEnv -> [InBind] -> [OutId] -> SimplM (FloatsWith ())
 245     simpl_binds env []           bs = ASSERT( null bs ) returnSmpl (emptyFloats env, ())
 246     simpl_binds env (bind:binds) bs = simpl_bind env bind bs            `thenSmpl` \ (floats,env) ->
 247                                       addFloats env floats              $ \env ->
 248                                       simpl_binds env binds (drop_bs bind bs)
 249
 250     drop_bs (NonRec _ _) (_ : bs) = bs
 251     drop_bs (Rec prs)    bs       = drop (length prs) bs
 252
 253     simpl_bind env bind bs
 254       = getDOptsSmpl                            `thenSmpl` \ dflags ->
 255         if dopt Opt_D_dump_inlinings dflags then
 256            pprTrace "SimplBind" (ppr (bindersOf bind)) $ simpl_bind1 env bind bs
 257         else
 258            simpl_bind1 env bind bs
 259
 260     simpl_bind1 env (NonRec b r) (b':_) = simplRecOrTopPair env TopLevel b b' r
 261     simpl_bind1 env (Rec pairs)  bs'    = simplRecBind      env TopLevel pairs bs'
 262 \end{code}
 263
 264
 265 %************************************************************************
 266 %*                                                                      *
 267 \subsection{simplNonRec}
 268 %*                                                                      *
 269 %************************************************************************
 270
 271 simplNonRecBind is used for
 272   * non-top-level non-recursive lets in expressions
 273   * beta reduction
 274
 275 It takes
 276   * An unsimplified (binder, rhs) pair
 277   * The env for the RHS.  It may not be the same as the
 278         current env because the bind might occur via (\x.E) arg
 279
 280 It uses the CPS form because the binding might be strict, in which
 281 case we might discard the continuation:
 282         let x* = error "foo" in (...x...)
 283
 284 It needs to turn unlifted bindings into a @case@.  They can arise
 285 from, say:      (\x -> e) (4# + 3#)
 286
 287 \begin{code}
 288 simplNonRecBind :: SimplEnv
 289                 -> InId                                 -- Binder
 290                 -> InExpr -> SimplEnv                   -- Arg, with its subst-env
 291                 -> OutType                              -- Type of thing computed by the context
 292                 -> (SimplEnv -> SimplM FloatsWithExpr)  -- The body
 293                 -> SimplM FloatsWithExpr
 294 #ifdef DEBUG
 295 simplNonRecBind env bndr rhs rhs_se cont_ty thing_inside
 296   | isTyVar bndr
 297   = pprPanic "simplNonRecBind" (ppr bndr <+> ppr rhs)
 298 #endif
 299
 300 simplNonRecBind env bndr rhs rhs_se cont_ty thing_inside
 301   | preInlineUnconditionally env NotTopLevel bndr
 302   = tick (PreInlineUnconditionally bndr)                `thenSmpl_`
 303     thing_inside (extendIdSubst env bndr (ContEx (getSubst rhs_se) rhs))
 304
 305
 306   | isStrictDmd (idNewDemandInfo bndr) || isStrictType (idType bndr)    -- A strict let
 307   =     -- Don't use simplBinder because that doesn't keep
 308         -- fragile occurrence info in the substitution
 309     simplLetBndr env bndr                                       `thenSmpl` \ (env, bndr1) ->
 310     simplStrictArg AnRhs env rhs rhs_se (idType bndr1) cont_ty  $ \ env1 rhs1 ->
 311
 312         -- Now complete the binding and simplify the body
 313     let
 314         -- simplLetBndr doesn't deal with the IdInfo, so we must
 315         -- do so here (c.f. simplLazyBind)
 316         bndr2  = bndr1 `setIdInfo` simplIdInfo (getSubst env) (idInfo bndr)
 317         env2   = modifyInScope env1 bndr2 bndr2
 318     in
 319     completeNonRecX env2 True {- strict -} bndr bndr2 rhs1 thing_inside
 320
 321   | otherwise                                                   -- Normal, lazy case
 322   =     -- Don't use simplBinder because that doesn't keep
 323         -- fragile occurrence info in the substitution
 324     simplLetBndr env bndr                               `thenSmpl` \ (env, bndr') ->
 325     simplLazyBind env NotTopLevel NonRecursive
 326                   bndr bndr' rhs rhs_se                 `thenSmpl` \ (floats, env) ->
 327     addFloats env floats thing_inside
 328 \end{code}
 329
 330 A specialised variant of simplNonRec used when the RHS is already simplified, notably
 331 in knownCon.  It uses case-binding where necessary.
 332
 333 \begin{code}
 334 simplNonRecX :: SimplEnv
 335              -> InId            -- Old binder
 336              -> OutExpr         -- Simplified RHS
 337              -> (SimplEnv -> SimplM FloatsWithExpr)
 338              -> SimplM FloatsWithExpr
 339
 340 simplNonRecX env bndr new_rhs thing_inside
 341   | needsCaseBinding (idType bndr) new_rhs
 342         -- Make this test *before* the preInlineUnconditionally
 343         -- Consider     case I# (quotInt# x y) of
 344         --                I# v -> let w = J# v in ...
 345         -- If we gaily inline (quotInt# x y) for v, we end up building an
 346         -- extra thunk:
 347         --                let w = J# (quotInt# x y) in ...
 348         -- because quotInt# can fail.
 349   = simplBinder env bndr        `thenSmpl` \ (env, bndr') ->
 350     thing_inside env            `thenSmpl` \ (floats, body) ->
 351 -- gaw 2004
 352     let body' = wrapFloats floats body in
 353     returnSmpl (emptyFloats env, Case new_rhs bndr' (exprType body') [(DEFAULT, [], body')])
 354
 355   | preInlineUnconditionally env NotTopLevel  bndr
 356         -- This happens; for example, the case_bndr during case of
 357         -- known constructor:  case (a,b) of x { (p,q) -> ... }
 358         -- Here x isn't mentioned in the RHS, so we don't want to
 359         -- create the (dead) let-binding  let x = (a,b) in ...
 360         --
 361         -- Similarly, single occurrences can be inlined vigourously
 362         -- e.g.  case (f x, g y) of (a,b) -> ....
 363         -- If a,b occur once we can avoid constructing the let binding for them.
 364   = thing_inside (extendIdSubst env bndr (ContEx emptySubst new_rhs))
 365
 366   | otherwise
 367   = simplBinder env bndr        `thenSmpl` \ (env, bndr') ->
 368     completeNonRecX env False {- Non-strict; pessimistic -}
 369                     bndr bndr' new_rhs thing_inside
 370
 371 completeNonRecX env is_strict old_bndr new_bndr new_rhs thing_inside
 372   = mkAtomicArgs is_strict
 373                  True {- OK to float unlifted -}
 374                  new_rhs                        `thenSmpl` \ (aux_binds, rhs2) ->
 375
 376         -- Make the arguments atomic if necessary,
 377         -- adding suitable bindings
 378     addAtomicBindsE env (fromOL aux_binds)      $ \ env ->
 379     completeLazyBind env NotTopLevel
 380                      old_bndr new_bndr rhs2     `thenSmpl` \ (floats, env) ->
 381     addFloats env floats thing_inside
 382 \end{code}
 383
 384
 385 %************************************************************************
 386 %*                                                                      *
 387 \subsection{Lazy bindings}
 388 %*                                                                      *
 389 %************************************************************************
 390
 391 simplRecBind is used for
 392         * recursive bindings only
 393
 394 \begin{code}
 395 simplRecBind :: SimplEnv -> TopLevelFlag
 396              -> [(InId, InExpr)] -> [OutId]
 397              -> SimplM (FloatsWith SimplEnv)
 398 simplRecBind env top_lvl pairs bndrs'
 399   = go env pairs bndrs'         `thenSmpl` \ (floats, env) ->
 400     returnSmpl (flattenFloats floats, env)
 401   where
 402     go env [] _ = returnSmpl (emptyFloats env, env)
 403
 404     go env ((bndr, rhs) : pairs) (bndr' : bndrs')
 405         = simplRecOrTopPair env top_lvl bndr bndr' rhs  `thenSmpl` \ (floats, env) ->
 406           addFloats env floats (\env -> go env pairs bndrs')
 407 \end{code}
 408
 409
 410 simplRecOrTopPair is used for
 411         * recursive bindings (whether top level or not)
 412         * top-level non-recursive bindings
 413
 414 It assumes the binder has already been simplified, but not its IdInfo.
 415
 416 \begin{code}
 417 simplRecOrTopPair :: SimplEnv
 418                   -> TopLevelFlag
 419                   -> InId -> OutId              -- Binder, both pre-and post simpl
 420                   -> InExpr                     -- The RHS and its environment
 421                   -> SimplM (FloatsWith SimplEnv)
 422
 423 simplRecOrTopPair env top_lvl bndr bndr' rhs
 424   | preInlineUnconditionally env top_lvl bndr   -- Check for unconditional inline
 425   = tick (PreInlineUnconditionally bndr)        `thenSmpl_`
 426     returnSmpl (emptyFloats env, extendIdSubst env bndr (ContEx (getSubst env) rhs))
 427
 428   | otherwise
 429   = simplLazyBind env top_lvl Recursive bndr bndr' rhs env
 430         -- May not actually be recursive, but it doesn't matter
 431 \end{code}
 432
 433
 434 simplLazyBind is used for
 435         * recursive bindings (whether top level or not)
 436         * top-level non-recursive bindings
 437         * non-top-level *lazy* non-recursive bindings
 438
 439 [Thus it deals with the lazy cases from simplNonRecBind, and all cases
 440 from SimplRecOrTopBind]
 441
 442 Nota bene:
 443     1. It assumes that the binder is *already* simplified,
 444        and is in scope, but not its IdInfo
 445
 446     2. It assumes that the binder type is lifted.
 447
 448     3. It does not check for pre-inline-unconditionallly;
 449        that should have been done already.
 450
 451 \begin{code}
 452 simplLazyBind :: SimplEnv
 453               -> TopLevelFlag -> RecFlag
 454               -> InId -> OutId          -- Binder, both pre-and post simpl
 455               -> InExpr -> SimplEnv     -- The RHS and its environment
 456               -> SimplM (FloatsWith SimplEnv)
 457
 458 simplLazyBind env top_lvl is_rec bndr bndr1 rhs rhs_se
 459   = let -- Transfer the IdInfo of the original binder to the new binder
 460         -- This is crucial: we must preserve
 461         --      strictness
 462         --      rules
 463         --      worker info
 464         -- etc.  To do this we must apply the current substitution,
 465         -- which incorporates earlier substitutions in this very letrec group.
 466         --
 467         -- NB 1.  We do this *before* processing the RHS of the binder, so that
 468         -- its substituted rules are visible in its own RHS.
 469         -- This is important.  Manuel found cases where he really, really
 470         -- wanted a RULE for a recursive function to apply in that function's
 471         -- own right-hand side.
 472         --
 473         -- NB 2: We do not transfer the arity (see Subst.substIdInfo)
 474         -- The arity of an Id should not be visible
 475         -- in its own RHS, else we eta-reduce
 476         --      f = \x -> f x
 477         -- to
 478         --      f = f
 479         -- which isn't sound.  And it makes the arity in f's IdInfo greater than
 480         -- the manifest arity, which isn't good.
 481         -- The arity will get added later.
 482         --
 483         -- NB 3: It's important that we *do* transer the loop-breaker OccInfo,
 484         -- because that's what stops the Id getting inlined infinitely, in the body
 485         -- of the letrec.
 486
 487         -- NB 4: does no harm for non-recursive bindings
 488
 489         bndr2             = bndr1 `setIdInfo` simplIdInfo (getSubst env) (idInfo bndr)
 490         env1              = modifyInScope env bndr2 bndr2
 491         rhs_env           = setInScope rhs_se env1
 492         is_top_level      = isTopLevel top_lvl
 493         ok_float_unlifted = not is_top_level && isNonRec is_rec
 494         rhs_cont          = mkRhsStop (idType bndr1)
 495     in
 496         -- Simplify the RHS; note the mkRhsStop, which tells
 497         -- the simplifier that this is the RHS of a let.
 498     simplExprF rhs_env rhs rhs_cont             `thenSmpl` \ (floats, rhs1) ->
 499
 500         -- If any of the floats can't be floated, give up now
 501         -- (The allLifted predicate says True for empty floats.)
 502     if (not ok_float_unlifted && not (allLifted floats)) then
 503         completeLazyBind env1 top_lvl bndr bndr2
 504                          (wrapFloats floats rhs1)
 505     else
 506
 507         -- ANF-ise a constructor or PAP rhs
 508     mkAtomicArgs False {- Not strict -}
 509                  ok_float_unlifted rhs1                 `thenSmpl` \ (aux_binds, rhs2) ->
 510
 511         -- If the result is a PAP, float the floats out, else wrap them
 512         -- By this time it's already been ANF-ised (if necessary)
 513     if isEmptyFloats floats && isNilOL aux_binds then   -- Shortcut a common case
 514         completeLazyBind env1 top_lvl bndr bndr2 rhs2
 515
 516     else if is_top_level || exprIsTrivial rhs2 || exprIsValue rhs2 then
 517         --      WARNING: long dodgy argument coming up
 518         --      WANTED: a better way to do this
 519         --
 520         -- We can't use "exprIsCheap" instead of exprIsValue,
 521         -- because that causes a strictness bug.
 522         --         x = let y* = E in case (scc y) of { T -> F; F -> T}
 523         -- The case expression is 'cheap', but it's wrong to transform to
 524         --         y* = E; x = case (scc y) of {...}
 525         -- Either we must be careful not to float demanded non-values, or
 526         -- we must use exprIsValue for the test, which ensures that the
 527         -- thing is non-strict.  So exprIsValue => bindings are non-strict
 528         -- I think.  The WARN below tests for this.
 529         --
 530         -- We use exprIsTrivial here because we want to reveal lone variables.
 531         -- E.g.  let { x = letrec { y = E } in y } in ...
 532         -- Here we definitely want to float the y=E defn.
 533         -- exprIsValue definitely isn't right for that.
 534         --
 535         -- Again, the floated binding can't be strict; if it's recursive it'll
 536         -- be non-strict; if it's non-recursive it'd be inlined.
 537         --
 538         -- Note [SCC-and-exprIsTrivial]
 539         -- If we have
 540         --      y = let { x* = E } in scc "foo" x
 541         -- then we do *not* want to float out the x binding, because
 542         -- it's strict!  Fortunately, exprIsTrivial replies False to
 543         -- (scc "foo" x).
 544
 545                 -- There's a subtlety here.  There may be a binding (x* = e) in the
 546                 -- floats, where the '*' means 'will be demanded'.  So is it safe
 547                 -- to float it out?  Answer no, but it won't matter because
 548                 -- we only float if (a) arg' is a WHNF, or (b) it's going to top level
 549                 -- and so there can't be any 'will be demanded' bindings in the floats.
 550                 -- Hence the warning
 551         ASSERT2( is_top_level || not (any demanded_float (floatBinds floats)),
 552                  ppr (filter demanded_float (floatBinds floats)) )
 553
 554         tick LetFloatFromLet                    `thenSmpl_` (
 555         addFloats env1 floats                   $ \ env2 ->
 556         addAtomicBinds env2 (fromOL aux_binds)  $ \ env3 ->
 557         completeLazyBind env3 top_lvl bndr bndr2 rhs2)
 558
 559     else
 560         completeLazyBind env1 top_lvl bndr bndr2 (wrapFloats floats rhs1)
 561
 562 #ifdef DEBUG
 563 demanded_float (NonRec b r) = isStrictDmd (idNewDemandInfo b) && not (isUnLiftedType (idType b))
 564                 -- Unlifted-type (cheap-eagerness) lets may well have a demanded flag on them
 565 demanded_float (Rec _)      = False
 566 #endif
 567 \end{code}
 568
 569
 570 %************************************************************************
 571 %*                                                                      *
 572 \subsection{Completing a lazy binding}
 573 %*                                                                      *
 574 %************************************************************************
 575
 576 completeLazyBind
 577         * deals only with Ids, not TyVars
 578         * takes an already-simplified binder and RHS
 579         * is used for both recursive and non-recursive bindings
 580         * is used for both top-level and non-top-level bindings
 581
 582 It does the following:
 583   - tries discarding a dead binding
 584   - tries PostInlineUnconditionally
 585   - add unfolding [this is the only place we add an unfolding]
 586   - add arity
 587
 588 It does *not* attempt to do let-to-case.  Why?  Because it is used for
 589         - top-level bindings (when let-to-case is impossible)
 590         - many situations where the "rhs" is known to be a WHNF
 591                 (so let-to-case is inappropriate).
 592
 593 \begin{code}
 594 completeLazyBind :: SimplEnv
 595                  -> TopLevelFlag        -- Flag stuck into unfolding
 596                  -> InId                -- Old binder
 597                  -> OutId               -- New binder
 598                  -> OutExpr             -- Simplified RHS
 599                  -> SimplM (FloatsWith SimplEnv)
 600 -- We return a new SimplEnv, because completeLazyBind may choose to do its work
 601 -- by extending the substitution (e.g. let x = y in ...)
 602 -- The new binding (if any) is returned as part of the floats.
 603 -- NB: the returned SimplEnv has the right SubstEnv, but you should
 604 --     (as usual) use the in-scope-env from the floats
 605
 606 completeLazyBind env top_lvl old_bndr new_bndr new_rhs
 607   | postInlineUnconditionally env new_bndr occ_info new_rhs
 608   =             -- Drop the binding
 609     tick (PostInlineUnconditionally old_bndr)   `thenSmpl_`
 610     returnSmpl (emptyFloats env, extendIdSubst env old_bndr (DoneEx new_rhs))
 611                 -- Use the substitution to make quite, quite sure that the substitution
 612                 -- will happen, since we are going to discard the binding
 613
 614   |  otherwise
 615   = let
 616                 -- Add arity info
 617         new_bndr_info = idInfo new_bndr `setArityInfo` exprArity new_rhs
 618
 619         -- Add the unfolding *only* for non-loop-breakers
 620         -- Making loop breakers not have an unfolding at all
 621         -- means that we can avoid tests in exprIsConApp, for example.
 622         -- This is important: if exprIsConApp says 'yes' for a recursive
 623         -- thing, then we can get into an infinite loop
 624
 625         -- If the unfolding is a value, the demand info may
 626         -- go pear-shaped, so we nuke it.  Example:
 627         --      let x = (a,b) in
 628         --      case x of (p,q) -> h p q x
 629         -- Here x is certainly demanded. But after we've nuked
 630         -- the case, we'll get just
 631         --      let x = (a,b) in h a b x
 632         -- and now x is not demanded (I'm assuming h is lazy)
 633         -- This really happens.  Similarly
 634         --      let f = \x -> e in ...f..f...
 635         -- After inling f at some of its call sites the original binding may
 636         -- (for example) be no longer strictly demanded.
 637         -- The solution here is a bit ad hoc...
 638         unfolding  = mkUnfolding (isTopLevel top_lvl) new_rhs
 639         info_w_unf = new_bndr_info `setUnfoldingInfo` unfolding
 640         final_info | loop_breaker               = new_bndr_info
 641                    | isEvaldUnfolding unfolding = zapDemandInfo info_w_unf `orElse` info_w_unf
 642                    | otherwise                  = info_w_unf
 643
 644         final_id = new_bndr `setIdInfo` final_info
 645     in
 646                 -- These seqs forces the Id, and hence its IdInfo,
 647                 -- and hence any inner substitutions
 648     final_id                                    `seq`
 649     returnSmpl (unitFloat env final_id new_rhs, env)
 650
 651   where
 652     loop_breaker = isLoopBreaker occ_info
 653     old_info     = idInfo old_bndr
 654     occ_info     = occInfo old_info
 655 \end{code}
 656
 657
 658
 659 %************************************************************************
 660 %*                                                                      *
 661 \subsection[Simplify-simplExpr]{The main function: simplExpr}
 662 %*                                                                      *
 663 %************************************************************************
 664
 665 The reason for this OutExprStuff stuff is that we want to float *after*
 666 simplifying a RHS, not before.  If we do so naively we get quadratic
 667 behaviour as things float out.
 668
 669 To see why it's important to do it after, consider this (real) example:
 670
 671         let t = f x
 672         in fst t
 673 ==>
 674         let t = let a = e1
 675                     b = e2
 676                 in (a,b)
 677         in fst t
 678 ==>
 679         let a = e1
 680             b = e2
 681             t = (a,b)
 682         in
 683         a       -- Can't inline a this round, cos it appears twice
 684 ==>
 685         e1
 686
 687 Each of the ==> steps is a round of simplification.  We'd save a
 688 whole round if we float first.  This can cascade.  Consider
 689
 690         let f = g d
 691         in \x -> ...f...
 692 ==>
 693         let f = let d1 = ..d.. in \y -> e
 694         in \x -> ...f...
 695 ==>
 696         let d1 = ..d..
 697         in \x -> ...(\y ->e)...
 698
 699 Only in this second round can the \y be applied, and it
 700 might do the same again.
 701
 702
 703 \begin{code}
 704 simplExpr :: SimplEnv -> CoreExpr -> SimplM CoreExpr
 705 simplExpr env expr = simplExprC env expr (mkBoringStop expr_ty')
 706                    where
 707                      expr_ty' = substTy (getTvSubst env) (exprType expr)
 708         -- The type in the Stop continuation, expr_ty', is usually not used
 709         -- It's only needed when discarding continuations after finding
 710         -- a function that returns bottom.
 711         -- Hence the lazy substitution
 712
 713
 714 simplExprC :: SimplEnv -> CoreExpr -> SimplCont -> SimplM CoreExpr
 715         -- Simplify an expression, given a continuation
 716 simplExprC env expr cont
 717   = simplExprF env expr cont    `thenSmpl` \ (floats, expr) ->
 718     returnSmpl (wrapFloats floats expr)
 719
 720 simplExprF :: SimplEnv -> InExpr -> SimplCont -> SimplM FloatsWithExpr
 721         -- Simplify an expression, returning floated binds
 722
 723 simplExprF env (Var v)          cont = simplVar env v cont
 724 simplExprF env (Lit lit)        cont = rebuild env (Lit lit) cont
 725 simplExprF env expr@(Lam _ _)   cont = simplLam env expr cont
 726 simplExprF env (Note note expr) cont = simplNote env note expr cont
 727 simplExprF env (App fun arg)    cont = simplExprF env fun (ApplyTo NoDup arg env cont)
 728
 729 simplExprF env (Type ty) cont
 730   = ASSERT( contIsRhsOrArg cont )
 731     simplType env ty                    `thenSmpl` \ ty' ->
 732     rebuild env (Type ty') cont
 733
 734 -- gaw 2004
 735 simplExprF env (Case scrut bndr case_ty alts) cont
 736   | not (switchIsOn (getSwitchChecker env) NoCaseOfCase)
 737   =     -- Simplify the scrutinee with a Select continuation
 738     simplExprF env scrut (Select NoDup bndr alts env cont)
 739
 740   | otherwise
 741   =     -- If case-of-case is off, simply simplify the case expression
 742         -- in a vanilla Stop context, and rebuild the result around it
 743     simplExprC env scrut case_cont      `thenSmpl` \ case_expr' ->
 744     rebuild env case_expr' cont
 745   where
 746     case_cont = Select NoDup bndr alts env (mkBoringStop case_ty')
 747     case_ty'  = substTy (getTvSubst env) case_ty        -- c.f. defn of simplExpr
 748
 749 simplExprF env (Let (Rec pairs) body) cont
 750   = simplRecBndrs env (map fst pairs)           `thenSmpl` \ (env, bndrs') ->
 751         -- NB: bndrs' don't have unfoldings or rules
 752         -- We add them as we go down
 753
 754     simplRecBind env NotTopLevel pairs bndrs'   `thenSmpl` \ (floats, env) ->
 755     addFloats env floats                        $ \ env ->
 756     simplExprF env body cont
 757
 758 -- A non-recursive let is dealt with by simplNonRecBind
 759 simplExprF env (Let (NonRec bndr rhs) body) cont
 760   = simplNonRecBind env bndr rhs env (contResultType cont)      $ \ env ->
 761     simplExprF env body cont
 762
 763
 764 ---------------------------------
 765 simplType :: SimplEnv -> InType -> SimplM OutType
 766         -- Kept monadic just so we can do the seqType
 767 simplType env ty
 768   = seqType new_ty   `seq`   returnSmpl new_ty
 769   where
 770     new_ty = substTy (getTvSubst env) ty
 771 \end{code}
 772
 773
 774 %************************************************************************
 775 %*                                                                      *
 776 \subsection{Lambdas}
 777 %*                                                                      *
 778 %************************************************************************
 779
 780 \begin{code}
 781 simplLam env fun cont
 782   = go env fun cont
 783   where
 784     zap_it  = mkLamBndrZapper fun (countArgs cont)
 785     cont_ty = contResultType cont
 786
 787         -- Type-beta reduction
 788     go env (Lam bndr body) (ApplyTo _ (Type ty_arg) arg_se body_cont)
 789       = ASSERT( isTyVar bndr )
 790         tick (BetaReduction bndr)                       `thenSmpl_`
 791         simplType (setInScope arg_se env) ty_arg        `thenSmpl` \ ty_arg' ->
 792         go (extendTvSubst env bndr ty_arg') body body_cont
 793
 794         -- Ordinary beta reduction
 795     go env (Lam bndr body) cont@(ApplyTo _ arg arg_se body_cont)
 796       = tick (BetaReduction bndr)                               `thenSmpl_`
 797         simplNonRecBind env (zap_it bndr) arg arg_se cont_ty    $ \ env ->
 798         go env body body_cont
 799
 800         -- Not enough args, so there are real lambdas left to put in the result
 801     go env lam@(Lam _ _) cont
 802       = simplLamBndrs env bndrs         `thenSmpl` \ (env, bndrs') ->
 803         simplExpr env body              `thenSmpl` \ body' ->
 804         mkLam env bndrs' body' cont     `thenSmpl` \ (floats, new_lam) ->
 805         addFloats env floats            $ \ env ->
 806         rebuild env new_lam cont
 807       where
 808         (bndrs,body) = collectBinders lam
 809
 810         -- Exactly enough args
 811     go env expr cont = simplExprF env expr cont
 812
 813 mkLamBndrZapper :: CoreExpr     -- Function
 814                 -> Int          -- Number of args supplied, *including* type args
 815                 -> Id -> Id     -- Use this to zap the binders
 816 mkLamBndrZapper fun n_args
 817   | n_args >= n_params fun = \b -> b            -- Enough args
 818   | otherwise              = \b -> zapLamIdInfo b
 819   where
 820         -- NB: we count all the args incl type args
 821         -- so we must count all the binders (incl type lambdas)
 822     n_params (Note _ e) = n_params e
 823     n_params (Lam b e)  = 1 + n_params e
 824     n_params other      = 0::Int
 825 \end{code}
 826
 827
 828 %************************************************************************
 829 %*                                                                      *
 830 \subsection{Notes}
 831 %*                                                                      *
 832 %************************************************************************
 833
 834 \begin{code}
 835 simplNote env (Coerce to from) body cont
 836   = let
 837         addCoerce s1 k1 (CoerceIt t1 cont)
 838                 --      coerce T1 S1 (coerce S1 K1 e)
 839                 -- ==>
 840                 --      e,                      if T1=K1
 841                 --      coerce T1 K1 e,         otherwise
 842                 --
 843                 -- For example, in the initial form of a worker
 844                 -- we may find  (coerce T (coerce S (\x.e))) y
 845                 -- and we'd like it to simplify to e[y/x] in one round
 846                 -- of simplification
 847           | t1 `eqType` k1  = cont              -- The coerces cancel out
 848           | otherwise       = CoerceIt t1 cont  -- They don't cancel, but
 849                                                 -- the inner one is redundant
 850
 851         addCoerce t1t2 s1s2 (ApplyTo dup arg arg_se cont)
 852           | not (isTypeArg arg),        -- This whole case only works for value args
 853                                         -- Could upgrade to have equiv thing for type apps too
 854             Just (s1, s2) <- splitFunTy_maybe s1s2
 855                 --      (coerce (T1->T2) (S1->S2) F) E
 856                 -- ===>
 857                 --      coerce T2 S2 (F (coerce S1 T1 E))
 858                 --
 859                 -- t1t2 must be a function type, T1->T2, because it's applied to something
 860                 -- but s1s2 might conceivably not be
 861                 --
 862                 -- When we build the ApplyTo we can't mix the out-types
 863                 -- with the InExpr in the argument, so we simply substitute
 864                 -- to make it all consistent.  It's a bit messy.
 865                 -- But it isn't a common case.
 866           = let
 867                 (t1,t2) = splitFunTy t1t2
 868                 new_arg = mkCoerce2 s1 t1 (substExpr subst arg)
 869                 subst   = getSubst (setInScope arg_se env)
 870             in
 871             ApplyTo dup new_arg (zapSubstEnv env) (addCoerce t2 s2 cont)
 872
 873         addCoerce to' _ cont = CoerceIt to' cont
 874     in
 875     simplType env to            `thenSmpl` \ to' ->
 876     simplType env from          `thenSmpl` \ from' ->
 877     simplExprF env body (addCoerce to' from' cont)
 878
 879
 880 -- Hack: we only distinguish subsumed cost centre stacks for the purposes of
 881 -- inlining.  All other CCCSs are mapped to currentCCS.
 882 simplNote env (SCC cc) e cont
 883   = simplExpr (setEnclosingCC env currentCCS) e         `thenSmpl` \ e' ->
 884     rebuild env (mkSCC cc e') cont
 885
 886 simplNote env InlineCall e cont
 887   = simplExprF env e (InlinePlease cont)
 888
 889 -- See notes with SimplMonad.inlineMode
 890 simplNote env InlineMe e cont
 891   | contIsRhsOrArg cont         -- Totally boring continuation; see notes above
 892   =                             -- Don't inline inside an INLINE expression
 893     simplExpr (setMode inlineMode env )  e      `thenSmpl` \ e' ->
 894     rebuild env (mkInlineMe e') cont
 895
 896   | otherwise   -- Dissolve the InlineMe note if there's
 897                 -- an interesting context of any kind to combine with
 898                 -- (even a type application -- anything except Stop)
 899   = simplExprF env e cont
 900
 901 simplNote env (CoreNote s) e cont
 902   = simplExpr env e    `thenSmpl` \ e' ->
 903     rebuild env (Note (CoreNote s) e') cont
 904 \end{code}
 905
 906
 907 %************************************************************************
 908 %*                                                                      *
 909 \subsection{Dealing with calls}
 910 %*                                                                      *
 911 %************************************************************************
 912
 913 \begin{code}
 914 simplVar env var cont
 915   = case substId (getSubst env) var of
 916         DoneEx e        -> simplExprF (zapSubstEnv env) e cont
 917         ContEx se e     -> simplExprF (setSubstEnv env se) e cont
 918         DoneId var1 occ -> completeCall (zapSubstEnv env) var1 occ cont
 919                 -- Note [zapSubstEnv]
 920                 -- The template is already simplified, so don't re-substitute.
 921                 -- This is VITAL.  Consider
 922                 --      let x = e in
 923                 --      let y = \z -> ...x... in
 924                 --      \ x -> ...y...
 925                 -- We'll clone the inner \x, adding x->x' in the id_subst
 926                 -- Then when we inline y, we must *not* replace x by x' in
 927                 -- the inlined copy!!
 928
 929 ---------------------------------------------------------
 930 --      Dealing with a call site
 931
 932 completeCall env var occ_info cont
 933   =     -- Simplify the arguments
 934     getDOptsSmpl                                        `thenSmpl` \ dflags ->
 935     let
 936         chkr                           = getSwitchChecker env
 937         (args, call_cont, inline_call) = getContArgs chkr var cont
 938         fn_ty                          = idType var
 939     in
 940     simplifyArgs env fn_ty args (contResultType call_cont)      $ \ env args ->
 941
 942         -- Next, look for rules or specialisations that match
 943         --
 944         -- It's important to simplify the args first, because the rule-matcher
 945         -- doesn't do substitution as it goes.  We don't want to use subst_args
 946         -- (defined in the 'where') because that throws away useful occurrence info,
 947         -- and perhaps-very-important specialisations.
 948         --
 949         -- Some functions have specialisations *and* are strict; in this case,
 950         -- we don't want to inline the wrapper of the non-specialised thing; better
 951         -- to call the specialised thing instead.
 952         -- We used to use the black-listing mechanism to ensure that inlining of
 953         -- the wrapper didn't occur for things that have specialisations till a
 954         -- later phase, so but now we just try RULES first
 955         --
 956         -- You might think that we shouldn't apply rules for a loop breaker:
 957         -- doing so might give rise to an infinite loop, because a RULE is
 958         -- rather like an extra equation for the function:
 959         --      RULE:           f (g x) y = x+y
 960         --      Eqn:            f a     y = a-y
 961         --
 962         -- But it's too drastic to disable rules for loop breakers.
 963         -- Even the foldr/build rule would be disabled, because foldr
 964         -- is recursive, and hence a loop breaker:
 965         --      foldr k z (build g) = g k z
 966         -- So it's up to the programmer: rules can cause divergence
 967
 968     let
 969         in_scope   = getInScope env
 970         maybe_rule = case activeRule env of
 971                         Nothing     -> Nothing  -- No rules apply
 972                         Just act_fn -> lookupRule act_fn in_scope var args
 973     in
 974     case maybe_rule of {
 975         Just (rule_name, rule_rhs) ->
 976                 tick (RuleFired rule_name)                      `thenSmpl_`
 977                 (if dopt Opt_D_dump_inlinings dflags then
 978                    pprTrace "Rule fired" (vcat [
 979                         text "Rule:" <+> ftext rule_name,
 980                         text "Before:" <+> ppr var <+> sep (map pprParendExpr args),
 981                         text "After: " <+> pprCoreExpr rule_rhs,
 982                         text "Cont:  " <+> ppr call_cont])
 983                  else
 984                         id)             $
 985                 simplExprF env rule_rhs call_cont ;
 986
 987         Nothing ->              -- No rules
 988
 989         -- Next, look for an inlining
 990     let
 991         arg_infos = [ interestingArg arg | arg <- args, isValArg arg]
 992
 993         interesting_cont = interestingCallContext (notNull args)
 994                                                   (notNull arg_infos)
 995                                                   call_cont
 996
 997         active_inline = activeInline env var occ_info
 998         maybe_inline  = callSiteInline dflags active_inline inline_call occ_info
 999                                        var arg_infos interesting_cont
1000     in
1001     case maybe_inline of {
1002         Just unfolding          -- There is an inlining!
1003           ->  tick (UnfoldingDone var)          `thenSmpl_`
1004               makeThatCall env var unfolding args call_cont
1005
1006         ;
1007         Nothing ->              -- No inlining!
1008
1009         -- Done
1010     rebuild env (mkApps (Var var) args) call_cont
1011     }}
1012
1013 makeThatCall :: SimplEnv
1014              -> Id
1015              -> InExpr          -- Inlined function rhs
1016              -> [OutExpr]       -- Arguments, already simplified
1017              -> SimplCont       -- After the call
1018              -> SimplM FloatsWithExpr
1019 -- Similar to simplLam, but this time
1020 -- the arguments are already simplified
1021 makeThatCall orig_env var fun@(Lam _ _) args cont
1022   = go orig_env fun args
1023   where
1024     zap_it = mkLamBndrZapper fun (length args)
1025
1026         -- Type-beta reduction
1027     go env (Lam bndr body) (Type ty_arg : args)
1028       = ASSERT( isTyVar bndr )
1029         tick (BetaReduction bndr)                       `thenSmpl_`
1030         go (extendTvSubst env bndr ty_arg) body args
1031
1032         -- Ordinary beta reduction
1033     go env (Lam bndr body) (arg : args)
1034       = tick (BetaReduction bndr)                       `thenSmpl_`
1035         simplNonRecX env (zap_it bndr) arg              $ \ env ->
1036         go env body args
1037
1038         -- Not enough args, so there are real lambdas left to put in the result
1039     go env fun args
1040       = simplExprF env fun (pushContArgs orig_env args cont)
1041         -- NB: orig_env; the correct environment to capture with
1042         -- the arguments.... env has been augmented with substitutions
1043         -- from the beta reductions.
1044
1045 makeThatCall env var fun args cont
1046   = simplExprF env fun (pushContArgs env args cont)
1047 \end{code}
1048
1049
1050 %************************************************************************
1051 %*                                                                      *
1052 \subsection{Arguments}
1053 %*                                                                      *
1054 %************************************************************************
1055
1056 \begin{code}
1057 ---------------------------------------------------------
1058 --      Simplifying the arguments of a call
1059
1060 simplifyArgs :: SimplEnv
1061              -> OutType                         -- Type of the function
1062              -> [(InExpr, SimplEnv, Bool)]      -- Details of the arguments
1063              -> OutType                         -- Type of the continuation
1064              -> (SimplEnv -> [OutExpr] -> SimplM FloatsWithExpr)
1065              -> SimplM FloatsWithExpr
1066
1067 -- [CPS-like because of strict arguments]
1068
1069 -- Simplify the arguments to a call.
1070 -- This part of the simplifier may break the no-shadowing invariant
1071 -- Consider
1072 --      f (...(\a -> e)...) (case y of (a,b) -> e')
1073 -- where f is strict in its second arg
1074 -- If we simplify the innermost one first we get (...(\a -> e)...)
1075 -- Simplifying the second arg makes us float the case out, so we end up with
1076 --      case y of (a,b) -> f (...(\a -> e)...) e'
1077 -- So the output does not have the no-shadowing invariant.  However, there is
1078 -- no danger of getting name-capture, because when the first arg was simplified
1079 -- we used an in-scope set that at least mentioned all the variables free in its
1080 -- static environment, and that is enough.
1081 --
1082 -- We can't just do innermost first, or we'd end up with a dual problem:
1083 --      case x of (a,b) -> f e (...(\a -> e')...)
1084 --
1085 -- I spent hours trying to recover the no-shadowing invariant, but I just could
1086 -- not think of an elegant way to do it.  The simplifier is already knee-deep in
1087 -- continuations.  We have to keep the right in-scope set around; AND we have
1088 -- to get the effect that finding (error "foo") in a strict arg position will
1089 -- discard the entire application and replace it with (error "foo").  Getting
1090 -- all this at once is TOO HARD!
1091
1092 simplifyArgs env fn_ty args cont_ty thing_inside
1093   = go env fn_ty args thing_inside
1094   where
1095     go env fn_ty []         thing_inside = thing_inside env []
1096     go env fn_ty (arg:args) thing_inside = simplifyArg env fn_ty arg cont_ty            $ \ env arg' ->
1097                                            go env (applyTypeToArg fn_ty arg') args      $ \ env args' ->
1098                                            thing_inside env (arg':args')
1099
1100 simplifyArg env fn_ty (Type ty_arg, se, _) cont_ty thing_inside
1101   = simplType (setInScope se env) ty_arg        `thenSmpl` \ new_ty_arg ->
1102     thing_inside env (Type new_ty_arg)
1103
1104 simplifyArg env fn_ty (val_arg, arg_se, is_strict) cont_ty thing_inside
1105   | is_strict
1106   = simplStrictArg AnArg env val_arg arg_se arg_ty cont_ty thing_inside
1107
1108   | otherwise   -- Lazy argument
1109                 -- DO NOT float anything outside, hence simplExprC
1110                 -- There is no benefit (unlike in a let-binding), and we'd
1111                 -- have to be very careful about bogus strictness through
1112                 -- floating a demanded let.
1113   = simplExprC (setInScope arg_se env) val_arg
1114                (mkBoringStop arg_ty)            `thenSmpl` \ arg1 ->
1115    thing_inside env arg1
1116   where
1117     arg_ty = funArgTy fn_ty
1118
1119
1120 simplStrictArg ::  LetRhsFlag
1121                 -> SimplEnv             -- The env of the call
1122                 -> InExpr -> SimplEnv   -- The arg plus its env
1123                 -> OutType              -- arg_ty: type of the argument
1124                 -> OutType              -- cont_ty: Type of thing computed by the context
1125                 -> (SimplEnv -> OutExpr -> SimplM FloatsWithExpr)
1126                                         -- Takes an expression of type rhs_ty,
1127                                         -- returns an expression of type cont_ty
1128                                         -- The env passed to this continuation is the
1129                                         -- env of the call, plus any new in-scope variables
1130                 -> SimplM FloatsWithExpr        -- An expression of type cont_ty
1131
1132 simplStrictArg is_rhs call_env arg arg_env arg_ty cont_ty thing_inside
1133   = simplExprF (setInScope arg_env call_env) arg
1134                (ArgOf is_rhs arg_ty cont_ty (\ new_env -> thing_inside (setInScope call_env new_env)))
1135   -- Notice the way we use arg_env (augmented with in-scope vars from call_env)
1136   --    to simplify the argument
1137   -- and call-env (augmented with in-scope vars from the arg) to pass to the continuation
1138 \end{code}
1139
1140
1141 %************************************************************************
1142 %*                                                                      *
1143 \subsection{mkAtomicArgs}
1144 %*                                                                      *
1145 %************************************************************************
1146
1147 mkAtomicArgs takes a putative RHS, checks whether it's a PAP or
1148 constructor application and, if so, converts it to ANF, so that the
1149 resulting thing can be inlined more easily.  Thus
1150         x = (f a, g b)
1151 becomes
1152         t1 = f a
1153         t2 = g b
1154         x = (t1,t2)
1155
1156 There are three sorts of binding context, specified by the two
1157 boolean arguments
1158
1159 Strict
1160    OK-unlifted
1161
1162 N  N    Top-level or recursive                  Only bind args of lifted type
1163
1164 N  Y    Non-top-level and non-recursive,        Bind args of lifted type, or
1165                 but lazy                        unlifted-and-ok-for-speculation
1166
1167 Y  Y    Non-top-level, non-recursive,           Bind all args
1168                  and strict (demanded)
1169
1170
1171 For example, given
1172
1173         x = MkC (y div# z)
1174
1175 there is no point in transforming to
1176
1177         x = case (y div# z) of r -> MkC r
1178
1179 because the (y div# z) can't float out of the let. But if it was
1180 a *strict* let, then it would be a good thing to do.  Hence the
1181 context information.
1182
1183 \begin{code}
1184 mkAtomicArgs :: Bool    -- A strict binding
1185              -> Bool    -- OK to float unlifted args
1186              -> OutExpr
1187              -> SimplM (OrdList (OutId,OutExpr),  -- The floats (unusually) may include
1188                         OutExpr)                  -- things that need case-binding,
1189                                                   -- if the strict-binding flag is on
1190
1191 mkAtomicArgs is_strict ok_float_unlifted rhs
1192   | (Var fun, args) <- collectArgs rhs,                         -- It's an application
1193     isDataConWorkId fun || valArgCount args < idArity fun       -- And it's a constructor or PAP
1194   = go fun nilOL [] args        -- Have a go
1195
1196   | otherwise = bale_out        -- Give up
1197
1198   where
1199     bale_out = returnSmpl (nilOL, rhs)
1200
1201     go fun binds rev_args []
1202         = returnSmpl (binds, mkApps (Var fun) (reverse rev_args))
1203
1204     go fun binds rev_args (arg : args)
1205         | exprIsTrivial arg     -- Easy case
1206         = go fun binds (arg:rev_args) args
1207
1208         | not can_float_arg     -- Can't make this arg atomic
1209         = bale_out              -- ... so give up
1210
1211         | otherwise     -- Don't forget to do it recursively
1212                         -- E.g.  x = a:b:c:[]
1213         =  mkAtomicArgs is_strict ok_float_unlifted arg `thenSmpl` \ (arg_binds, arg') ->
1214            newId FSLIT("a") arg_ty                      `thenSmpl` \ arg_id ->
1215            go fun ((arg_binds `snocOL` (arg_id,arg')) `appOL` binds)
1216               (Var arg_id : rev_args) args
1217         where
1218           arg_ty        = exprType arg
1219           can_float_arg =  is_strict
1220                         || not (isUnLiftedType arg_ty)
1221                         || (ok_float_unlifted && exprOkForSpeculation arg)
1222
1223
1224 addAtomicBinds :: SimplEnv -> [(OutId,OutExpr)]
1225                -> (SimplEnv -> SimplM (FloatsWith a))
1226                -> SimplM (FloatsWith a)
1227 addAtomicBinds env []         thing_inside = thing_inside env
1228 addAtomicBinds env ((v,r):bs) thing_inside = addAuxiliaryBind env (NonRec v r) $ \ env ->
1229                                              addAtomicBinds env bs thing_inside
1230
1231 addAtomicBindsE :: SimplEnv -> [(OutId,OutExpr)]
1232                 -> (SimplEnv -> SimplM FloatsWithExpr)
1233                 -> SimplM FloatsWithExpr
1234 -- Same again, but this time we're in an expression context,
1235 -- and may need to do some case bindings
1236
1237 addAtomicBindsE env [] thing_inside
1238   = thing_inside env
1239 addAtomicBindsE env ((v,r):bs) thing_inside
1240   | needsCaseBinding (idType v) r
1241   = addAtomicBindsE (addNewInScopeIds env [v]) bs thing_inside  `thenSmpl` \ (floats, expr) ->
1242     WARN( exprIsTrivial expr, ppr v <+> pprCoreExpr expr )
1243     (let body = wrapFloats floats expr in
1244      returnSmpl (emptyFloats env, Case r v (exprType body) [(DEFAULT,[],body)]))
1245
1246   | otherwise
1247   = addAuxiliaryBind env (NonRec v r)   $ \ env ->
1248     addAtomicBindsE env bs thing_inside
1249 \end{code}
1250
1251
1252 %************************************************************************
1253 %*                                                                      *
1254 \subsection{The main rebuilder}
1255 %*                                                                      *
1256 %************************************************************************
1257
1258 \begin{code}
1259 rebuild :: SimplEnv -> OutExpr -> SimplCont -> SimplM FloatsWithExpr
1260
1261 rebuild env expr (Stop _ _ _)                 = rebuildDone env expr
1262 rebuild env expr (ArgOf _ _ _ cont_fn)        = cont_fn env expr
1263 rebuild env expr (CoerceIt to_ty cont)        = rebuild env (mkCoerce to_ty expr) cont
1264 rebuild env expr (InlinePlease cont)          = rebuild env (Note InlineCall expr) cont
1265 rebuild env expr (Select _ bndr alts se cont) = rebuildCase (setInScope se env) expr bndr alts cont
1266 rebuild env expr (ApplyTo _ arg se cont)      = rebuildApp  (setInScope se env) expr arg cont
1267
1268 rebuildApp env fun arg cont
1269   = simplExpr env arg   `thenSmpl` \ arg' ->
1270     rebuild env (App fun arg') cont
1271
1272 rebuildDone env expr = returnSmpl (emptyFloats env, expr)
1273 \end{code}
1274
1275
1276 %************************************************************************
1277 %*                                                                      *
1278 \subsection{Functions dealing with a case}
1279 %*                                                                      *
1280 %************************************************************************
1281
1282 Blob of helper functions for the "case-of-something-else" situation.
1283
1284 \begin{code}
1285 ---------------------------------------------------------
1286 --      Eliminate the case if possible
1287
1288 rebuildCase :: SimplEnv
1289             -> OutExpr          -- Scrutinee
1290             -> InId             -- Case binder
1291             -> [InAlt]          -- Alternatives
1292             -> SimplCont
1293             -> SimplM FloatsWithExpr
1294
1295 rebuildCase env scrut case_bndr alts cont
1296   | Just (con,args) <- exprIsConApp_maybe scrut
1297         -- Works when the scrutinee is a variable with a known unfolding
1298         -- as well as when it's an explicit constructor application
1299   = knownCon env (DataAlt con) args case_bndr alts cont
1300
1301   | Lit lit <- scrut    -- No need for same treatment as constructors
1302                         -- because literals are inlined more vigorously
1303   = knownCon env (LitAlt lit) [] case_bndr alts cont
1304
1305   | otherwise
1306   = prepareAlts scrut case_bndr alts            `thenSmpl` \ (better_alts, handled_cons) ->
1307
1308         -- Deal with the case binder, and prepare the continuation;
1309         -- The new subst_env is in place
1310     prepareCaseCont env better_alts cont        `thenSmpl` \ (floats, (dup_cont, nondup_cont)) ->
1311     addFloats env floats                        $ \ env ->
1312
1313     let
1314         -- The case expression is annotated with the result type of the continuation
1315         -- This may differ from the type originally on the case.  For example
1316         --      case(T) (case(Int#) a of { True -> 1#; False -> 0# }) of
1317         --         a# -> <blob>
1318         -- ===>
1319         --      let j a# = <blob>
1320         --      in case(T) a of { True -> j 1#; False -> j 0# }
1321         -- Note that the case that scrutinises a now returns a T not an Int#
1322         res_ty' = contResultType dup_cont
1323     in
1324
1325         -- Deal with variable scrutinee
1326     simplCaseBinder env scrut case_bndr         `thenSmpl` \ (alt_env, case_bndr', zap_occ_info) ->
1327
1328         -- Deal with the case alternatives
1329     simplAlts alt_env zap_occ_info handled_cons
1330               case_bndr' better_alts dup_cont res_ty'   `thenSmpl` \ alts' ->
1331
1332         -- Put the case back together
1333     mkCase scrut case_bndr' res_ty' alts'       `thenSmpl` \ case_expr ->
1334
1335         -- Notice that rebuildDone returns the in-scope set from env, not alt_env
1336         -- The case binder *not* scope over the whole returned case-expression
1337     rebuild env case_expr nondup_cont
1338 \end{code}
1339
1340 simplCaseBinder checks whether the scrutinee is a variable, v.  If so,
1341 try to eliminate uses of v in the RHSs in favour of case_bndr; that
1342 way, there's a chance that v will now only be used once, and hence
1343 inlined.
1344
1345 Note 1
1346 ~~~~~~
1347 There is a time we *don't* want to do that, namely when
1348 -fno-case-of-case is on.  This happens in the first simplifier pass,
1349 and enhances full laziness.  Here's the bad case:
1350         f = \ y -> ...(case x of I# v -> ...(case x of ...) ... )
1351 If we eliminate the inner case, we trap it inside the I# v -> arm,
1352 which might prevent some full laziness happening.  I've seen this
1353 in action in spectral/cichelli/Prog.hs:
1354          [(m,n) | m <- [1..max], n <- [1..max]]
1355 Hence the check for NoCaseOfCase.
1356
1357 Note 2
1358 ~~~~~~
1359 There is another situation when we don't want to do it.  If we have
1360
1361     case x of w1 { DEFAULT -> case x of w2 { A -> e1; B -> e2 }
1362                    ...other cases .... }
1363
1364 We'll perform the binder-swap for the outer case, giving
1365
1366     case x of w1 { DEFAULT -> case w1 of w2 { A -> e1; B -> e2 }
1367                    ...other cases .... }
1368
1369 But there is no point in doing it for the inner case, because w1 can't
1370 be inlined anyway.  Furthermore, doing the case-swapping involves
1371 zapping w2's occurrence info (see paragraphs that follow), and that
1372 forces us to bind w2 when doing case merging.  So we get
1373
1374     case x of w1 { A -> let w2 = w1 in e1
1375                    B -> let w2 = w1 in e2
1376                    ...other cases .... }
1377
1378 This is plain silly in the common case where w2 is dead.
1379
1380 Even so, I can't see a good way to implement this idea.  I tried
1381 not doing the binder-swap if the scrutinee was already evaluated
1382 but that failed big-time:
1383
1384         data T = MkT !Int
1385
1386         case v of w  { MkT x ->
1387         case x of x1 { I# y1 ->
1388         case x of x2 { I# y2 -> ...
1389
1390 Notice that because MkT is strict, x is marked "evaluated".  But to
1391 eliminate the last case, we must either make sure that x (as well as
1392 x1) has unfolding MkT y1.  THe straightforward thing to do is to do
1393 the binder-swap.  So this whole note is a no-op.
1394
1395 Note 3
1396 ~~~~~~
1397 If we replace the scrutinee, v, by tbe case binder, then we have to nuke
1398 any occurrence info (eg IAmDead) in the case binder, because the
1399 case-binder now effectively occurs whenever v does.  AND we have to do
1400 the same for the pattern-bound variables!  Example:
1401
1402         (case x of { (a,b) -> a }) (case x of { (p,q) -> q })
1403
1404 Here, b and p are dead.  But when we move the argment inside the first
1405 case RHS, and eliminate the second case, we get
1406
1407         case x or { (a,b) -> a b }
1408
1409 Urk! b is alive!  Reason: the scrutinee was a variable, and case elimination
1410 happened.  Hence the zap_occ_info function returned by simplCaseBinder
1411
1412 \begin{code}
1413 simplCaseBinder env (Var v) case_bndr
1414   | not (switchIsOn (getSwitchChecker env) NoCaseOfCase)
1415
1416 -- Failed try [see Note 2 above]
1417 --     not (isEvaldUnfolding (idUnfolding v))
1418
1419   = simplBinder env (zap case_bndr)             `thenSmpl` \ (env, case_bndr') ->
1420     returnSmpl (modifyInScope env v case_bndr', case_bndr', zap)
1421         -- We could extend the substitution instead, but it would be
1422         -- a hack because then the substitution wouldn't be idempotent
1423         -- any more (v is an OutId).  And this just just as well.
1424   where
1425     zap b = b `setIdOccInfo` NoOccInfo
1426
1427 simplCaseBinder env other_scrut case_bndr
1428   = simplBinder env case_bndr           `thenSmpl` \ (env, case_bndr') ->
1429     returnSmpl (env, case_bndr', \ bndr -> bndr)        -- NoOp on bndr
1430 \end{code}
1431
1432
1433
1434 \begin{code}
1435 simplAlts :: SimplEnv
1436           -> (InId -> InId)             -- Occ-info zapper
1437           -> [AltCon]                   -- Alternatives the scrutinee can't be
1438                                         -- in the default case
1439           -> OutId                      -- Case binder
1440           -> [InAlt] -> SimplCont
1441           -> OutType                    -- Result type
1442           -> SimplM [OutAlt]            -- Includes the continuation
1443
1444 simplAlts env zap_occ_info handled_cons case_bndr' alts cont' res_ty'
1445   = mapSmpl simpl_alt alts
1446   where
1447     mk_rhs_env env case_bndr_unf
1448         = modifyInScope env case_bndr' (case_bndr' `setIdUnfolding` case_bndr_unf)
1449
1450     simpl_alt (DEFAULT, _, rhs)
1451         = let unf = mkOtherCon handled_cons in
1452                 -- Record the constructors that the case-binder *can't* be.
1453           simplExprC (mk_rhs_env env unf) rhs cont'     `thenSmpl` \ rhs' ->
1454           returnSmpl (DEFAULT, [], rhs')
1455
1456     simpl_alt (LitAlt lit, _, rhs)
1457         = let unf = mkUnfolding False (Lit lit) in
1458           simplExprC (mk_rhs_env env unf) rhs cont'     `thenSmpl` \ rhs' ->
1459           returnSmpl (LitAlt lit, [], rhs')
1460
1461     simpl_alt (DataAlt con, vs, rhs)
1462         | isVanillaDataCon con
1463         =       -- Deal with the pattern-bound variables
1464                 -- Mark the ones that are in ! positions in the data constructor
1465                 -- as certainly-evaluated.
1466                 -- NB: it happens that simplBinders does *not* erase the OtherCon
1467                 --     form of unfolding, so it's ok to add this info before
1468                 --     doing simplBinders
1469           simplBinders env (add_evals con vs)           `thenSmpl` \ (env, vs') ->
1470
1471                 -- Bind the case-binder to (con args)
1472           let unf = mkUnfolding False (mkConApp con con_args)
1473               inst_tys' = tyConAppArgs (idType case_bndr')
1474               con_args  = map Type inst_tys' ++ map varToCoreExpr vs'
1475           in
1476           simplExprC (mk_rhs_env env unf) rhs cont'     `thenSmpl` \ rhs' ->
1477           returnSmpl (DataAlt con, vs', rhs')
1478
1479
1480         | otherwise     -- GADT case
1481         = simplBinders env (add_evals con vs)           `thenSmpl` \ (env, vs') ->
1482           let unf         = mkUnfolding False con_app
1483               con_app    = mkConApp con con_args
1484               con_args   = map varToCoreExpr vs'        -- NB: no inst_tys'
1485               pat_res_ty = exprType con_app
1486               env_w_unf  = mk_rhs_env env unf
1487               tv_subst   = getTvSubst env
1488           in
1489           case coreRefineTys vs' tv_subst pat_res_ty (idType case_bndr') of
1490              Just tv_subst_env ->
1491                 simplExprC (setTvSubstEnv env_w_unf tv_subst_env) rhs cont'     `thenSmpl` \ rhs' ->
1492                 returnSmpl (DataAlt con, vs', rhs')
1493              Nothing ->         -- Dead code; for now, I'm just going to put in an
1494                                 -- error case so I can see them
1495                 let rhs' = mkApps (Var eRROR_ID)
1496                                 [Type (substTy tv_subst (exprType rhs)),
1497                                  Lit (mkStringLit "Impossible alternative (GADT)")]
1498                 in
1499                 returnSmpl (DataAlt con, vs', rhs')
1500
1501         -- add_evals records the evaluated-ness of the bound variables of
1502         -- a case pattern.  This is *important*.  Consider
1503         --      data T = T !Int !Int
1504         --
1505         --      case x of { T a b -> T (a+1) b }
1506         --
1507         -- We really must record that b is already evaluated so that we don't
1508         -- go and re-evaluate it when constructing the result.
1509
1510     add_evals dc vs = cat_evals dc vs (dataConRepStrictness dc)
1511
1512     cat_evals dc vs strs
1513         = go vs strs
1514         where
1515           go [] [] = []
1516           go (v:vs) strs | isTyVar v = v : go vs strs
1517           go (v:vs) (str:strs)
1518             | isMarkedStrict str = evald_v  : go vs strs
1519             | otherwise          = zapped_v : go vs strs
1520             where
1521               zapped_v = zap_occ_info v
1522               evald_v  = zapped_v `setIdUnfolding` mkOtherCon []
1523           go _ _ = pprPanic "cat_evals" (ppr dc $$ ppr vs $$ ppr strs)
1524 \end{code}
1525
1526
1527 %************************************************************************
1528 %*                                                                      *
1529 \subsection{Known constructor}
1530 %*                                                                      *
1531 %************************************************************************
1532
1533 We are a bit careful with occurrence info.  Here's an example
1534
1535         (\x* -> case x of (a*, b) -> f a) (h v, e)
1536
1537 where the * means "occurs once".  This effectively becomes
1538         case (h v, e) of (a*, b) -> f a)
1539 and then
1540         let a* = h v; b = e in f a
1541 and then
1542         f (h v)
1543
1544 All this should happen in one sweep.
1545
1546 \begin{code}
1547 knownCon :: SimplEnv -> AltCon -> [OutExpr]
1548          -> InId -> [InAlt] -> SimplCont
1549          -> SimplM FloatsWithExpr
1550
1551 knownCon env con args bndr alts cont
1552   = tick (KnownBranch bndr)     `thenSmpl_`
1553     case findAlt con alts of
1554         (DEFAULT, bs, rhs)     -> ASSERT( null bs )
1555                                   simplNonRecX env bndr scrut   $ \ env ->
1556                                         -- This might give rise to a binding with non-atomic args
1557                                         -- like x = Node (f x) (g x)
1558                                         -- but no harm will be done
1559                                   simplExprF env rhs cont
1560                                 where
1561                                   scrut = case con of
1562                                             LitAlt lit -> Lit lit
1563                                             DataAlt dc -> mkConApp dc args
1564
1565         (LitAlt lit, bs, rhs) ->  ASSERT( null bs )
1566                                   simplNonRecX env bndr (Lit lit)       $ \ env ->
1567                                   simplExprF env rhs cont
1568
1569         (DataAlt dc, bs, rhs)
1570                 -> ASSERT( n_drop_tys + length bs == length args )
1571                    bind_args env bs (drop n_drop_tys args)      $ \ env ->
1572                    let
1573                         con_app  = mkConApp dc (take n_drop_tys args ++ con_args)
1574                         con_args = [substExpr (getSubst env) (varToCoreExpr b) | b <- bs]
1575                                         -- args are aready OutExprs, but bs are InIds
1576                    in
1577                    simplNonRecX env bndr con_app                $ \ env ->
1578                    simplExprF env rhs cont
1579                 where
1580                    n_drop_tys | isVanillaDataCon dc = tyConArity (dataConTyCon dc)
1581                               | otherwise           = 0
1582                         -- Vanilla data constructors lack type arguments in the pattern
1583
1584 -- Ugh!
1585 bind_args env [] _ thing_inside = thing_inside env
1586
1587 bind_args env (b:bs) (Type ty : args) thing_inside
1588   = ASSERT( isTyVar b )
1589     bind_args (extendTvSubst env b ty) bs args thing_inside
1590
1591 bind_args env (b:bs) (arg : args) thing_inside
1592   = ASSERT( isId b )
1593     simplNonRecX env b arg      $ \ env ->
1594     bind_args env bs args thing_inside
1595 \end{code}
1596
1597
1598 %************************************************************************
1599 %*                                                                      *
1600 \subsection{Duplicating continuations}
1601 %*                                                                      *
1602 %************************************************************************
1603
1604 \begin{code}
1605 prepareCaseCont :: SimplEnv
1606                 -> [InAlt] -> SimplCont
1607                 -> SimplM (FloatsWith (SimplCont,SimplCont))
1608                         -- Return a duplicatable continuation, a non-duplicable part
1609                         -- plus some extra bindings
1610
1611         -- No need to make it duplicatable if there's only one alternative
1612 prepareCaseCont env [alt] cont = returnSmpl (emptyFloats env, (cont, mkBoringStop (contResultType cont)))
1613 prepareCaseCont env alts  cont = mkDupableCont env cont
1614 \end{code}
1615
1616 \begin{code}
1617 mkDupableCont :: SimplEnv -> SimplCont
1618               -> SimplM (FloatsWith (SimplCont, SimplCont))
1619
1620 mkDupableCont env cont
1621   | contIsDupable cont
1622   = returnSmpl (emptyFloats env, (cont, mkBoringStop (contResultType cont)))
1623
1624 mkDupableCont env (CoerceIt ty cont)
1625   = mkDupableCont env cont              `thenSmpl` \ (floats, (dup_cont, nondup_cont)) ->
1626     returnSmpl (floats, (CoerceIt ty dup_cont, nondup_cont))
1627
1628 mkDupableCont env (InlinePlease cont)
1629   = mkDupableCont env cont              `thenSmpl` \ (floats, (dup_cont, nondup_cont)) ->
1630     returnSmpl (floats, (InlinePlease dup_cont, nondup_cont))
1631
1632 mkDupableCont env cont@(ArgOf _ arg_ty _ _)
1633   =  returnSmpl (emptyFloats env, (mkBoringStop arg_ty, cont))
1634         -- Do *not* duplicate an ArgOf continuation
1635         -- Because ArgOf continuations are opaque, we gain nothing by
1636         -- propagating them into the expressions, and we do lose a lot.
1637         -- Here's an example:
1638         --      && (case x of { T -> F; F -> T }) E
1639         -- Now, && is strict so we end up simplifying the case with
1640         -- an ArgOf continuation.  If we let-bind it, we get
1641         --
1642         --      let $j = \v -> && v E
1643         --      in simplExpr (case x of { T -> F; F -> T })
1644         --                   (ArgOf (\r -> $j r)
1645         -- And after simplifying more we get
1646         --
1647         --      let $j = \v -> && v E
1648         --      in case of { T -> $j F; F -> $j T }
1649         -- Which is a Very Bad Thing
1650         --
1651         -- The desire not to duplicate is the entire reason that
1652         -- mkDupableCont returns a pair of continuations.
1653         --
1654         -- The original plan had:
1655         -- e.g.         (...strict-fn...) [...hole...]
1656         --      ==>
1657         --              let $j = \a -> ...strict-fn...
1658         --              in $j [...hole...]
1659
1660 mkDupableCont env (ApplyTo _ arg se cont)
1661   =     -- e.g.         [...hole...] (...arg...)
1662         --      ==>
1663         --              let a = ...arg...
1664         --              in [...hole...] a
1665     simplExpr (setInScope se env) arg                   `thenSmpl` \ arg' ->
1666
1667     mkDupableCont env cont                              `thenSmpl` \ (floats, (dup_cont, nondup_cont)) ->
1668     addFloats env floats                                $ \ env ->
1669
1670     if exprIsDupable arg' then
1671         returnSmpl (emptyFloats env, (ApplyTo OkToDup arg' (zapSubstEnv se) dup_cont, nondup_cont))
1672     else
1673     newId FSLIT("a") (exprType arg')                    `thenSmpl` \ arg_id ->
1674
1675     tick (CaseOfCase arg_id)                            `thenSmpl_`
1676         -- Want to tick here so that we go round again,
1677         -- and maybe copy or inline the code.
1678         -- Not strictly CaseOfCase, but never mind
1679
1680     returnSmpl (unitFloat env arg_id arg',
1681                 (ApplyTo OkToDup (Var arg_id) (zapSubstEnv se) dup_cont,
1682                  nondup_cont))
1683         -- But what if the arg should be case-bound?
1684         -- This has been this way for a long time, so I'll leave it,
1685         -- but I can't convince myself that it's right.
1686
1687 -- gaw 2004
1688 mkDupableCont env (Select _ case_bndr alts se cont)
1689   =     -- e.g.         (case [...hole...] of { pi -> ei })
1690         --      ===>
1691         --              let ji = \xij -> ei
1692         --              in case [...hole...] of { pi -> ji xij }
1693     tick (CaseOfCase case_bndr)                                 `thenSmpl_`
1694     let
1695         alt_env = setInScope se env
1696     in
1697     prepareCaseCont alt_env alts cont                           `thenSmpl` \ (floats1, (dup_cont, nondup_cont)) ->
1698     addFloats alt_env floats1                                   $ \ alt_env ->
1699
1700     simplBinder alt_env case_bndr                               `thenSmpl` \ (alt_env, case_bndr') ->
1701         -- NB: simplBinder does not zap deadness occ-info, so
1702         -- a dead case_bndr' will still advertise its deadness
1703         -- This is really important because in
1704         --      case e of b { (# a,b #) -> ... }
1705         -- b is always dead, and indeed we are not allowed to bind b to (# a,b #),
1706         -- which might happen if e was an explicit unboxed pair and b wasn't marked dead.
1707         -- In the new alts we build, we have the new case binder, so it must retain
1708         -- its deadness.
1709
1710     mkDupableAlts alt_env case_bndr' alts dup_cont      `thenSmpl` \ (floats2, alts') ->
1711     addFloats alt_env floats2                           $ \ alt_env ->
1712     returnSmpl (emptyFloats alt_env,
1713                 (Select OkToDup case_bndr' alts' (zapSubstEnv se)
1714                         (mkBoringStop (contResultType dup_cont)),
1715                  nondup_cont))
1716
1717 mkDupableAlts :: SimplEnv -> OutId -> [InAlt] -> SimplCont
1718               -> SimplM (FloatsWith [InAlt])
1719 -- Absorbs the continuation into the new alternatives
1720
1721 mkDupableAlts env case_bndr' alts dupable_cont
1722   = go env alts
1723   where
1724     go env [] = returnSmpl (emptyFloats env, [])
1725     go env (alt:alts)
1726         = mkDupableAlt env case_bndr' dupable_cont alt  `thenSmpl` \ (floats1, alt') ->
1727           addFloats env floats1                         $ \ env ->
1728           go env alts                                   `thenSmpl` \ (floats2, alts') ->
1729           returnSmpl (floats2, alt' : alts')
1730
1731 mkDupableAlt env case_bndr' cont alt@(con, bndrs, rhs)
1732   = simplBinders env bndrs                              `thenSmpl` \ (env, bndrs') ->
1733     simplExprC env rhs cont                             `thenSmpl` \ rhs' ->
1734
1735     if exprIsDupable rhs' then
1736         returnSmpl (emptyFloats env, (con, bndrs', rhs'))
1737         -- It is worth checking for a small RHS because otherwise we
1738         -- get extra let bindings that may cause an extra iteration of the simplifier to
1739         -- inline back in place.  Quite often the rhs is just a variable or constructor.
1740         -- The Ord instance of Maybe in PrelMaybe.lhs, for example, took several extra
1741         -- iterations because the version with the let bindings looked big, and so wasn't
1742         -- inlined, but after the join points had been inlined it looked smaller, and so
1743         -- was inlined.
1744         --
1745         -- NB: we have to check the size of rhs', not rhs.
1746         -- Duplicating a small InAlt might invalidate occurrence information
1747         -- However, if it *is* dupable, we return the *un* simplified alternative,
1748         -- because otherwise we'd need to pair it up with an empty subst-env....
1749         -- but we only have one env shared between all the alts.
1750         -- (Remember we must zap the subst-env before re-simplifying something).
1751         -- Rather than do this we simply agree to re-simplify the original (small) thing later.
1752
1753     else
1754     let
1755         rhs_ty'     = exprType rhs'
1756         used_bndrs' = filter (not . isDeadBinder) (case_bndr' : bndrs')
1757                 -- The deadness info on the new binders is unscathed
1758     in
1759         -- If we try to lift a primitive-typed something out
1760         -- for let-binding-purposes, we will *caseify* it (!),
1761         -- with potentially-disastrous strictness results.  So
1762         -- instead we turn it into a function: \v -> e
1763         -- where v::State# RealWorld#.  The value passed to this function
1764         -- is realworld#, which generates (almost) no code.
1765
1766         -- There's a slight infelicity here: we pass the overall
1767         -- case_bndr to all the join points if it's used in *any* RHS,
1768         -- because we don't know its usage in each RHS separately
1769
1770         -- We used to say "&& isUnLiftedType rhs_ty'" here, but now
1771         -- we make the join point into a function whenever used_bndrs'
1772         -- is empty.  This makes the join-point more CPR friendly.
1773         -- Consider:    let j = if .. then I# 3 else I# 4
1774         --              in case .. of { A -> j; B -> j; C -> ... }
1775         --
1776         -- Now CPR doesn't w/w j because it's a thunk, so
1777         -- that means that the enclosing function can't w/w either,
1778         -- which is a lose.  Here's the example that happened in practice:
1779         --      kgmod :: Int -> Int -> Int
1780         --      kgmod x y = if x > 0 && y < 0 || x < 0 && y > 0
1781         --                  then 78
1782         --                  else 5
1783         --
1784         -- I have seen a case alternative like this:
1785         --      True -> \v -> ...
1786         -- It's a bit silly to add the realWorld dummy arg in this case, making
1787         --      $j = \s v -> ...
1788         --         True -> $j s
1789         -- (the \v alone is enough to make CPR happy) but I think it's rare
1790
1791     ( if null used_bndrs'
1792         then newId FSLIT("w") realWorldStatePrimTy      `thenSmpl` \ rw_id ->
1793              returnSmpl ([rw_id], [Var realWorldPrimId])
1794         else
1795              returnSmpl (used_bndrs', map varToCoreExpr used_bndrs')
1796     )                                                   `thenSmpl` \ (final_bndrs', final_args) ->
1797
1798         -- See comment about "$j" name above
1799     newId (encodeFS FSLIT("$j")) (mkPiTypes final_bndrs' rhs_ty')       `thenSmpl` \ join_bndr ->
1800         -- Notice the funky mkPiTypes.  If the contructor has existentials
1801         -- it's possible that the join point will be abstracted over
1802         -- type varaibles as well as term variables.
1803         --  Example:  Suppose we have
1804         --      data T = forall t.  C [t]
1805         --  Then faced with
1806         --      case (case e of ...) of
1807         --          C t xs::[t] -> rhs
1808         --  We get the join point
1809         --      let j :: forall t. [t] -> ...
1810         --          j = /\t \xs::[t] -> rhs
1811         --      in
1812         --      case (case e of ...) of
1813         --          C t xs::[t] -> j t xs
1814     let
1815         -- We make the lambdas into one-shot-lambdas.  The
1816         -- join point is sure to be applied at most once, and doing so
1817         -- prevents the body of the join point being floated out by
1818         -- the full laziness pass
1819         really_final_bndrs     = map one_shot final_bndrs'
1820         one_shot v | isId v    = setOneShotLambda v
1821                    | otherwise = v
1822         join_rhs  = mkLams really_final_bndrs rhs'
1823         join_call = mkApps (Var join_bndr) final_args
1824     in
1825     returnSmpl (unitFloat env join_bndr join_rhs, (con, bndrs', join_call))
1826 \end{code}