ghc/compiler/simplCore/Simplify.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[Simplify]{The main module of the simplifier}
   5
   6 \begin{code}
   7 module Simplify ( simplTopBinds, simplExpr ) where
   8
   9 #include "HsVersions.h"
  10
  11 import CmdLineOpts      ( dopt, DynFlag(Opt_D_dump_inlinings),
  12                           SimplifierSwitch(..)
  13                         )
  14 import SimplMonad
  15 import SimplUtils       ( mkCase, mkLam, newId, prepareAlts,
  16                           simplBinder, simplBinders, simplLamBndrs, simplRecBndrs, simplLetBndr,
  17                           SimplCont(..), DupFlag(..), LetRhsFlag(..),
  18                           mkStop, mkBoringStop,  pushContArgs,
  19                           contResultType, countArgs, contIsDupable, contIsRhsOrArg,
  20                           getContArgs, interestingCallContext, interestingArg, isStrictType
  21                         )
  22 import Var              ( mustHaveLocalBinding )
  23 import VarEnv
  24 import Id               ( Id, idType, idInfo, idArity, isDataConWorkId,
  25                           setIdUnfolding, isDeadBinder,
  26                           idNewDemandInfo, setIdInfo,
  27                           setIdOccInfo, zapLamIdInfo, setOneShotLambda,
  28                         )
  29 import OccName          ( encodeFS )
  30 import IdInfo           ( OccInfo(..), isLoopBreaker,
  31                           setArityInfo,
  32                           setUnfoldingInfo,
  33                           occInfo
  34                         )
  35 import NewDemand        ( isStrictDmd )
  36 import DataCon          ( dataConNumInstArgs, dataConRepStrictness )
  37 import CoreSyn
  38 import PprCore          ( pprParendExpr, pprCoreExpr )
  39 import CoreUnfold       ( mkOtherCon, mkUnfolding, callSiteInline )
  40 import CoreUtils        ( exprIsDupable, exprIsTrivial, needsCaseBinding,
  41                           exprIsConApp_maybe, mkPiTypes, findAlt,
  42                           exprType, exprIsValue,
  43                           exprOkForSpeculation, exprArity,
  44                           mkCoerce, mkCoerce2, mkSCC, mkInlineMe, mkAltExpr, applyTypeToArg
  45                         )
  46 import Rules            ( lookupRule )
  47 import BasicTypes       ( isMarkedStrict )
  48 import CostCentre       ( currentCCS )
  49 import Type             ( isUnLiftedType, seqType, tyConAppArgs, funArgTy,
  50                           splitFunTy_maybe, splitFunTy, eqType
  51                         )
  52 import Subst            ( mkSubst, substTy, substExpr,
  53                           isInScope, lookupIdSubst, simplIdInfo
  54                         )
  55 import TysPrim          ( realWorldStatePrimTy )
  56 import PrelInfo         ( realWorldPrimId )
  57 import BasicTypes       ( TopLevelFlag(..), isTopLevel,
  58                           RecFlag(..), isNonRec
  59                         )
  60 import OrdList
  61 import Maybe            ( Maybe )
  62 import Outputable
  63 import Util             ( notNull )
  64 \end{code}
  65
  66
  67 The guts of the simplifier is in this module, but the driver loop for
  68 the simplifier is in SimplCore.lhs.
  69
  70
  71 -----------------------------------------
  72         *** IMPORTANT NOTE ***
  73 -----------------------------------------
  74 The simplifier used to guarantee that the output had no shadowing, but
  75 it does not do so any more.   (Actually, it never did!)  The reason is
  76 documented with simplifyArgs.
  77
  78
  79 -----------------------------------------
  80         *** IMPORTANT NOTE ***
  81 -----------------------------------------
  82 Many parts of the simplifier return a bunch of "floats" as well as an
  83 expression. This is wrapped as a datatype SimplUtils.FloatsWith.
  84
  85 All "floats" are let-binds, not case-binds, but some non-rec lets may
  86 be unlifted (with RHS ok-for-speculation).
  87
  88
  89
  90 -----------------------------------------
  91         ORGANISATION OF FUNCTIONS
  92 -----------------------------------------
  93 simplTopBinds
  94   - simplify all top-level binders
  95   - for NonRec, call simplRecOrTopPair
  96   - for Rec,    call simplRecBind
  97
  98
  99         ------------------------------
 100 simplExpr (applied lambda)      ==> simplNonRecBind
 101 simplExpr (Let (NonRec ...) ..) ==> simplNonRecBind
 102 simplExpr (Let (Rec ...)    ..) ==> simplify binders; simplRecBind
 103
 104         ------------------------------
 105 simplRecBind    [binders already simplfied]
 106   - use simplRecOrTopPair on each pair in turn
 107
 108 simplRecOrTopPair [binder already simplified]
 109   Used for: recursive bindings (top level and nested)
 110             top-level non-recursive bindings
 111   Returns:
 112   - check for PreInlineUnconditionally
 113   - simplLazyBind
 114
 115 simplNonRecBind
 116   Used for: non-top-level non-recursive bindings
 117             beta reductions (which amount to the same thing)
 118   Because it can deal with strict arts, it takes a
 119         "thing-inside" and returns an expression
 120
 121   - check for PreInlineUnconditionally
 122   - simplify binder, including its IdInfo
 123   - if strict binding
 124         simplStrictArg
 125         mkAtomicArgs
 126         completeNonRecX
 127     else
 128         simplLazyBind
 129         addFloats
 130
 131 simplNonRecX:   [given a *simplified* RHS, but an *unsimplified* binder]
 132   Used for: binding case-binder and constr args in a known-constructor case
 133   - check for PreInLineUnconditionally
 134   - simplify binder
 135   - completeNonRecX
 136
 137         ------------------------------
 138 simplLazyBind:  [binder already simplified, RHS not]
 139   Used for: recursive bindings (top level and nested)
 140             top-level non-recursive bindings
 141             non-top-level, but *lazy* non-recursive bindings
 142         [must not be strict or unboxed]
 143   Returns floats + an augmented environment, not an expression
 144   - substituteIdInfo and add result to in-scope
 145         [so that rules are available in rec rhs]
 146   - simplify rhs
 147   - mkAtomicArgs
 148   - float if exposes constructor or PAP
 149   - completeLazyBind
 150
 151
 152 completeNonRecX:        [binder and rhs both simplified]
 153   - if the the thing needs case binding (unlifted and not ok-for-spec)
 154         build a Case
 155    else
 156         completeLazyBind
 157         addFloats
 158
 159 completeLazyBind:       [given a simplified RHS]
 160         [used for both rec and non-rec bindings, top level and not]
 161   - try PostInlineUnconditionally
 162   - add unfolding [this is the only place we add an unfolding]
 163   - add arity
 164
 165
 166
 167 Right hand sides and arguments
 168 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 169 In many ways we want to treat
 170         (a) the right hand side of a let(rec), and
 171         (b) a function argument
 172 in the same way.  But not always!  In particular, we would
 173 like to leave these arguments exactly as they are, so they
 174 will match a RULE more easily.
 175
 176         f (g x, h x)
 177         g (+ x)
 178
 179 It's harder to make the rule match if we ANF-ise the constructor,
 180 or eta-expand the PAP:
 181
 182         f (let { a = g x; b = h x } in (a,b))
 183         g (\y. + x y)
 184
 185 On the other hand if we see the let-defns
 186
 187         p = (g x, h x)
 188         q = + x
 189
 190 then we *do* want to ANF-ise and eta-expand, so that p and q
 191 can be safely inlined.
 192
 193 Even floating lets out is a bit dubious.  For let RHS's we float lets
 194 out if that exposes a value, so that the value can be inlined more vigorously.
 195 For example
 196
 197         r = let x = e in (x,x)
 198
 199 Here, if we float the let out we'll expose a nice constructor. We did experiments
 200 that showed this to be a generally good thing.  But it was a bad thing to float
 201 lets out unconditionally, because that meant they got allocated more often.
 202
 203 For function arguments, there's less reason to expose a constructor (it won't
 204 get inlined).  Just possibly it might make a rule match, but I'm pretty skeptical.
 205 So for the moment we don't float lets out of function arguments either.
 206
 207
 208 Eta expansion
 209 ~~~~~~~~~~~~~~
 210 For eta expansion, we want to catch things like
 211
 212         case e of (a,b) -> \x -> case a of (p,q) -> \y -> r
 213
 214 If the \x was on the RHS of a let, we'd eta expand to bring the two
 215 lambdas together.  And in general that's a good thing to do.  Perhaps
 216 we should eta expand wherever we find a (value) lambda?  Then the eta
 217 expansion at a let RHS can concentrate solely on the PAP case.
 218
 219
 220 %************************************************************************
 221 %*                                                                      *
 222 \subsection{Bindings}
 223 %*                                                                      *
 224 %************************************************************************
 225
 226 \begin{code}
 227 simplTopBinds :: SimplEnv -> [InBind] -> SimplM [OutBind]
 228
 229 simplTopBinds env binds
 230   =     -- Put all the top-level binders into scope at the start
 231         -- so that if a transformation rule has unexpectedly brought
 232         -- anything into scope, then we don't get a complaint about that.
 233         -- It's rather as if the top-level binders were imported.
 234     simplRecBndrs env (bindersOfBinds binds)    `thenSmpl` \ (env, bndrs') ->
 235     simpl_binds env binds bndrs'                `thenSmpl` \ (floats, _) ->
 236     freeTick SimplifierDone                     `thenSmpl_`
 237     returnSmpl (floatBinds floats)
 238   where
 239         -- We need to track the zapped top-level binders, because
 240         -- they should have their fragile IdInfo zapped (notably occurrence info)
 241         -- That's why we run down binds and bndrs' simultaneously.
 242     simpl_binds :: SimplEnv -> [InBind] -> [OutId] -> SimplM (FloatsWith ())
 243     simpl_binds env []           bs = ASSERT( null bs ) returnSmpl (emptyFloats env, ())
 244     simpl_binds env (bind:binds) bs = simpl_bind env bind bs            `thenSmpl` \ (floats,env) ->
 245                                       addFloats env floats              $ \env ->
 246                                       simpl_binds env binds (drop_bs bind bs)
 247
 248     drop_bs (NonRec _ _) (_ : bs) = bs
 249     drop_bs (Rec prs)    bs       = drop (length prs) bs
 250
 251     simpl_bind env bind bs
 252       = getDOptsSmpl                            `thenSmpl` \ dflags ->
 253         if dopt Opt_D_dump_inlinings dflags then
 254            pprTrace "SimplBind" (ppr (bindersOf bind)) $ simpl_bind1 env bind bs
 255         else
 256            simpl_bind1 env bind bs
 257
 258     simpl_bind1 env (NonRec b r) (b':_) = simplRecOrTopPair env TopLevel b b' r
 259     simpl_bind1 env (Rec pairs)  bs'    = simplRecBind      env TopLevel pairs bs'
 260 \end{code}
 261
 262
 263 %************************************************************************
 264 %*                                                                      *
 265 \subsection{simplNonRec}
 266 %*                                                                      *
 267 %************************************************************************
 268
 269 simplNonRecBind is used for
 270   * non-top-level non-recursive lets in expressions
 271   * beta reduction
 272
 273 It takes
 274   * An unsimplified (binder, rhs) pair
 275   * The env for the RHS.  It may not be the same as the
 276         current env because the bind might occur via (\x.E) arg
 277
 278 It uses the CPS form because the binding might be strict, in which
 279 case we might discard the continuation:
 280         let x* = error "foo" in (...x...)
 281
 282 It needs to turn unlifted bindings into a @case@.  They can arise
 283 from, say:      (\x -> e) (4# + 3#)
 284
 285 \begin{code}
 286 simplNonRecBind :: SimplEnv
 287                 -> InId                                 -- Binder
 288                 -> InExpr -> SimplEnv                   -- Arg, with its subst-env
 289                 -> OutType                              -- Type of thing computed by the context
 290                 -> (SimplEnv -> SimplM FloatsWithExpr)  -- The body
 291                 -> SimplM FloatsWithExpr
 292 #ifdef DEBUG
 293 simplNonRecBind env bndr rhs rhs_se cont_ty thing_inside
 294   | isTyVar bndr
 295   = pprPanic "simplNonRecBind" (ppr bndr <+> ppr rhs)
 296 #endif
 297
 298 simplNonRecBind env bndr rhs rhs_se cont_ty thing_inside
 299   | preInlineUnconditionally env NotTopLevel bndr
 300   = tick (PreInlineUnconditionally bndr)                `thenSmpl_`
 301     thing_inside (extendSubst env bndr (ContEx (getSubstEnv rhs_se) rhs))
 302
 303
 304   | isStrictDmd (idNewDemandInfo bndr) || isStrictType (idType bndr)    -- A strict let
 305   =     -- Don't use simplBinder because that doesn't keep
 306         -- fragile occurrence info in the substitution
 307     simplLetBndr env bndr                                       `thenSmpl` \ (env, bndr1) ->
 308     simplStrictArg AnRhs env rhs rhs_se (idType bndr1) cont_ty  $ \ env1 rhs1 ->
 309
 310         -- Now complete the binding and simplify the body
 311     let
 312         -- simplLetBndr doesn't deal with the IdInfo, so we must
 313         -- do so here (c.f. simplLazyBind)
 314         bndr2  = bndr1 `setIdInfo` simplIdInfo (getSubst env) (idInfo bndr)
 315         env2   = modifyInScope env1 bndr2 bndr2
 316     in
 317     completeNonRecX env2 True {- strict -} bndr bndr2 rhs1 thing_inside
 318
 319   | otherwise                                                   -- Normal, lazy case
 320   =     -- Don't use simplBinder because that doesn't keep
 321         -- fragile occurrence info in the substitution
 322     simplLetBndr env bndr                               `thenSmpl` \ (env, bndr') ->
 323     simplLazyBind env NotTopLevel NonRecursive
 324                   bndr bndr' rhs rhs_se                 `thenSmpl` \ (floats, env) ->
 325     addFloats env floats thing_inside
 326 \end{code}
 327
 328 A specialised variant of simplNonRec used when the RHS is already simplified, notably
 329 in knownCon.  It uses case-binding where necessary.
 330
 331 \begin{code}
 332 simplNonRecX :: SimplEnv
 333              -> InId            -- Old binder
 334              -> OutExpr         -- Simplified RHS
 335              -> (SimplEnv -> SimplM FloatsWithExpr)
 336              -> SimplM FloatsWithExpr
 337
 338 simplNonRecX env bndr new_rhs thing_inside
 339   | needsCaseBinding (idType bndr) new_rhs
 340         -- Make this test *before* the preInlineUnconditionally
 341         -- Consider     case I# (quotInt# x y) of
 342         --                I# v -> let w = J# v in ...
 343         -- If we gaily inline (quotInt# x y) for v, we end up building an
 344         -- extra thunk:
 345         --                let w = J# (quotInt# x y) in ...
 346         -- because quotInt# can fail.
 347   = simplBinder env bndr        `thenSmpl` \ (env, bndr') ->
 348     thing_inside env            `thenSmpl` \ (floats, body) ->
 349     returnSmpl (emptyFloats env, Case new_rhs bndr' [(DEFAULT, [], wrapFloats floats body)])
 350
 351   | preInlineUnconditionally env NotTopLevel  bndr
 352         -- This happens; for example, the case_bndr during case of
 353         -- known constructor:  case (a,b) of x { (p,q) -> ... }
 354         -- Here x isn't mentioned in the RHS, so we don't want to
 355         -- create the (dead) let-binding  let x = (a,b) in ...
 356         --
 357         -- Similarly, single occurrences can be inlined vigourously
 358         -- e.g.  case (f x, g y) of (a,b) -> ....
 359         -- If a,b occur once we can avoid constructing the let binding for them.
 360   = thing_inside (extendSubst env bndr (ContEx emptySubstEnv new_rhs))
 361
 362   | otherwise
 363   = simplBinder env bndr        `thenSmpl` \ (env, bndr') ->
 364     completeNonRecX env False {- Non-strict; pessimistic -}
 365                     bndr bndr' new_rhs thing_inside
 366
 367 completeNonRecX env is_strict old_bndr new_bndr new_rhs thing_inside
 368   = mkAtomicArgs is_strict
 369                  True {- OK to float unlifted -}
 370                  new_rhs                        `thenSmpl` \ (aux_binds, rhs2) ->
 371
 372         -- Make the arguments atomic if necessary,
 373         -- adding suitable bindings
 374     addAtomicBindsE env (fromOL aux_binds)      $ \ env ->
 375     completeLazyBind env NotTopLevel
 376                      old_bndr new_bndr rhs2     `thenSmpl` \ (floats, env) ->
 377     addFloats env floats thing_inside
 378 \end{code}
 379
 380
 381 %************************************************************************
 382 %*                                                                      *
 383 \subsection{Lazy bindings}
 384 %*                                                                      *
 385 %************************************************************************
 386
 387 simplRecBind is used for
 388         * recursive bindings only
 389
 390 \begin{code}
 391 simplRecBind :: SimplEnv -> TopLevelFlag
 392              -> [(InId, InExpr)] -> [OutId]
 393              -> SimplM (FloatsWith SimplEnv)
 394 simplRecBind env top_lvl pairs bndrs'
 395   = go env pairs bndrs'         `thenSmpl` \ (floats, env) ->
 396     returnSmpl (flattenFloats floats, env)
 397   where
 398     go env [] _ = returnSmpl (emptyFloats env, env)
 399
 400     go env ((bndr, rhs) : pairs) (bndr' : bndrs')
 401         = simplRecOrTopPair env top_lvl bndr bndr' rhs  `thenSmpl` \ (floats, env) ->
 402           addFloats env floats (\env -> go env pairs bndrs')
 403 \end{code}
 404
 405
 406 simplRecOrTopPair is used for
 407         * recursive bindings (whether top level or not)
 408         * top-level non-recursive bindings
 409
 410 It assumes the binder has already been simplified, but not its IdInfo.
 411
 412 \begin{code}
 413 simplRecOrTopPair :: SimplEnv
 414                   -> TopLevelFlag
 415                   -> InId -> OutId              -- Binder, both pre-and post simpl
 416                   -> InExpr                     -- The RHS and its environment
 417                   -> SimplM (FloatsWith SimplEnv)
 418
 419 simplRecOrTopPair env top_lvl bndr bndr' rhs
 420   | preInlineUnconditionally env top_lvl bndr   -- Check for unconditional inline
 421   = tick (PreInlineUnconditionally bndr)        `thenSmpl_`
 422     returnSmpl (emptyFloats env, extendSubst env bndr (ContEx (getSubstEnv env) rhs))
 423
 424   | otherwise
 425   = simplLazyBind env top_lvl Recursive bndr bndr' rhs env
 426         -- May not actually be recursive, but it doesn't matter
 427 \end{code}
 428
 429
 430 simplLazyBind is used for
 431         * recursive bindings (whether top level or not)
 432         * top-level non-recursive bindings
 433         * non-top-level *lazy* non-recursive bindings
 434
 435 [Thus it deals with the lazy cases from simplNonRecBind, and all cases
 436 from SimplRecOrTopBind]
 437
 438 Nota bene:
 439     1. It assumes that the binder is *already* simplified,
 440        and is in scope, but not its IdInfo
 441
 442     2. It assumes that the binder type is lifted.
 443
 444     3. It does not check for pre-inline-unconditionallly;
 445        that should have been done already.
 446
 447 \begin{code}
 448 simplLazyBind :: SimplEnv
 449               -> TopLevelFlag -> RecFlag
 450               -> InId -> OutId          -- Binder, both pre-and post simpl
 451               -> InExpr -> SimplEnv     -- The RHS and its environment
 452               -> SimplM (FloatsWith SimplEnv)
 453
 454 simplLazyBind env top_lvl is_rec bndr bndr1 rhs rhs_se
 455   = let -- Transfer the IdInfo of the original binder to the new binder
 456         -- This is crucial: we must preserve
 457         --      strictness
 458         --      rules
 459         --      worker info
 460         -- etc.  To do this we must apply the current substitution,
 461         -- which incorporates earlier substitutions in this very letrec group.
 462         --
 463         -- NB 1.  We do this *before* processing the RHS of the binder, so that
 464         -- its substituted rules are visible in its own RHS.
 465         -- This is important.  Manuel found cases where he really, really
 466         -- wanted a RULE for a recursive function to apply in that function's
 467         -- own right-hand side.
 468         --
 469         -- NB 2: We do not transfer the arity (see Subst.substIdInfo)
 470         -- The arity of an Id should not be visible
 471         -- in its own RHS, else we eta-reduce
 472         --      f = \x -> f x
 473         -- to
 474         --      f = f
 475         -- which isn't sound.  And it makes the arity in f's IdInfo greater than
 476         -- the manifest arity, which isn't good.
 477         -- The arity will get added later.
 478         --
 479         -- NB 3: It's important that we *do* transer the loop-breaker OccInfo,
 480         -- because that's what stops the Id getting inlined infinitely, in the body
 481         -- of the letrec.
 482
 483         -- NB 4: does no harm for non-recursive bindings
 484
 485         bndr2             = bndr1 `setIdInfo` simplIdInfo (getSubst env) (idInfo bndr)
 486         env1              = modifyInScope env bndr2 bndr2
 487         rhs_env           = setInScope rhs_se env1
 488         is_top_level      = isTopLevel top_lvl
 489         ok_float_unlifted = not is_top_level && isNonRec is_rec
 490         rhs_cont          = mkStop (idType bndr1) AnRhs
 491     in
 492         -- Simplify the RHS; note the mkStop, which tells
 493         -- the simplifier that this is the RHS of a let.
 494     simplExprF rhs_env rhs rhs_cont             `thenSmpl` \ (floats, rhs1) ->
 495
 496         -- If any of the floats can't be floated, give up now
 497         -- (The allLifted predicate says True for empty floats.)
 498     if (not ok_float_unlifted && not (allLifted floats)) then
 499         completeLazyBind env1 top_lvl bndr bndr2
 500                          (wrapFloats floats rhs1)
 501     else
 502
 503         -- ANF-ise a constructor or PAP rhs
 504     mkAtomicArgs False {- Not strict -}
 505                  ok_float_unlifted rhs1                 `thenSmpl` \ (aux_binds, rhs2) ->
 506
 507         -- If the result is a PAP, float the floats out, else wrap them
 508         -- By this time it's already been ANF-ised (if necessary)
 509     if isEmptyFloats floats && isNilOL aux_binds then   -- Shortcut a common case
 510         completeLazyBind env1 top_lvl bndr bndr2 rhs2
 511
 512     else if is_top_level || exprIsTrivial rhs2 || exprIsValue rhs2 then
 513         --      WARNING: long dodgy argument coming up
 514         --      WANTED: a better way to do this
 515         --
 516         -- We can't use "exprIsCheap" instead of exprIsValue,
 517         -- because that causes a strictness bug.
 518         --         x = let y* = E in case (scc y) of { T -> F; F -> T}
 519         -- The case expression is 'cheap', but it's wrong to transform to
 520         --         y* = E; x = case (scc y) of {...}
 521         -- Either we must be careful not to float demanded non-values, or
 522         -- we must use exprIsValue for the test, which ensures that the
 523         -- thing is non-strict.  So exprIsValue => bindings are non-strict
 524         -- I think.  The WARN below tests for this.
 525         --
 526         -- We use exprIsTrivial here because we want to reveal lone variables.
 527         -- E.g.  let { x = letrec { y = E } in y } in ...
 528         -- Here we definitely want to float the y=E defn.
 529         -- exprIsValue definitely isn't right for that.
 530         --
 531         -- Again, the floated binding can't be strict; if it's recursive it'll
 532         -- be non-strict; if it's non-recursive it'd be inlined.
 533         --
 534         -- Note [SCC-and-exprIsTrivial]
 535         -- If we have
 536         --      y = let { x* = E } in scc "foo" x
 537         -- then we do *not* want to float out the x binding, because
 538         -- it's strict!  Fortunately, exprIsTrivial replies False to
 539         -- (scc "foo" x).
 540
 541                 -- There's a subtlety here.  There may be a binding (x* = e) in the
 542                 -- floats, where the '*' means 'will be demanded'.  So is it safe
 543                 -- to float it out?  Answer no, but it won't matter because
 544                 -- we only float if (a) arg' is a WHNF, or (b) it's going to top level
 545                 -- and so there can't be any 'will be demanded' bindings in the floats.
 546                 -- Hence the warning
 547         ASSERT2( is_top_level || not (any demanded_float (floatBinds floats)),
 548                  ppr (filter demanded_float (floatBinds floats)) )
 549
 550         tick LetFloatFromLet                    `thenSmpl_` (
 551         addFloats env1 floats                   $ \ env2 ->
 552         addAtomicBinds env2 (fromOL aux_binds)  $ \ env3 ->
 553         completeLazyBind env3 top_lvl bndr bndr2 rhs2)
 554
 555     else
 556         completeLazyBind env1 top_lvl bndr bndr2 (wrapFloats floats rhs1)
 557
 558 #ifdef DEBUG
 559 demanded_float (NonRec b r) = isStrictDmd (idNewDemandInfo b) && not (isUnLiftedType (idType b))
 560                 -- Unlifted-type (cheap-eagerness) lets may well have a demanded flag on them
 561 demanded_float (Rec _)      = False
 562 #endif
 563 \end{code}
 564
 565
 566 %************************************************************************
 567 %*                                                                      *
 568 \subsection{Completing a lazy binding}
 569 %*                                                                      *
 570 %************************************************************************
 571
 572 completeLazyBind
 573         * deals only with Ids, not TyVars
 574         * takes an already-simplified binder and RHS
 575         * is used for both recursive and non-recursive bindings
 576         * is used for both top-level and non-top-level bindings
 577
 578 It does the following:
 579   - tries discarding a dead binding
 580   - tries PostInlineUnconditionally
 581   - add unfolding [this is the only place we add an unfolding]
 582   - add arity
 583
 584 It does *not* attempt to do let-to-case.  Why?  Because it is used for
 585         - top-level bindings (when let-to-case is impossible)
 586         - many situations where the "rhs" is known to be a WHNF
 587                 (so let-to-case is inappropriate).
 588
 589 \begin{code}
 590 completeLazyBind :: SimplEnv
 591                  -> TopLevelFlag        -- Flag stuck into unfolding
 592                  -> InId                -- Old binder
 593                  -> OutId               -- New binder
 594                  -> OutExpr             -- Simplified RHS
 595                  -> SimplM (FloatsWith SimplEnv)
 596 -- We return a new SimplEnv, because completeLazyBind may choose to do its work
 597 -- by extending the substitution (e.g. let x = y in ...)
 598 -- The new binding (if any) is returned as part of the floats.
 599 -- NB: the returned SimplEnv has the right SubstEnv, but you should
 600 --     (as usual) use the in-scope-env from the floats
 601
 602 completeLazyBind env top_lvl old_bndr new_bndr new_rhs
 603   | postInlineUnconditionally env new_bndr occ_info new_rhs
 604   =             -- Drop the binding
 605     tick (PostInlineUnconditionally old_bndr)   `thenSmpl_`
 606     returnSmpl (emptyFloats env, extendSubst env old_bndr (DoneEx new_rhs))
 607                 -- Use the substitution to make quite, quite sure that the substitution
 608                 -- will happen, since we are going to discard the binding
 609
 610   |  otherwise
 611   = let
 612                 -- Add arity info
 613         new_bndr_info = idInfo new_bndr `setArityInfo` exprArity new_rhs
 614
 615                 -- Add the unfolding *only* for non-loop-breakers
 616                 -- Making loop breakers not have an unfolding at all
 617                 -- means that we can avoid tests in exprIsConApp, for example.
 618                 -- This is important: if exprIsConApp says 'yes' for a recursive
 619                 -- thing, then we can get into an infinite loop
 620         info_w_unf | loop_breaker = new_bndr_info
 621                    | otherwise    = new_bndr_info `setUnfoldingInfo` unfolding
 622         unfolding = mkUnfolding (isTopLevel top_lvl) new_rhs
 623
 624         final_id = new_bndr `setIdInfo` info_w_unf
 625     in
 626                 -- These seqs forces the Id, and hence its IdInfo,
 627                 -- and hence any inner substitutions
 628     final_id                                    `seq`
 629     returnSmpl (unitFloat env final_id new_rhs, env)
 630
 631   where
 632     loop_breaker = isLoopBreaker occ_info
 633     old_info     = idInfo old_bndr
 634     occ_info     = occInfo old_info
 635 \end{code}
 636
 637
 638
 639 %************************************************************************
 640 %*                                                                      *
 641 \subsection[Simplify-simplExpr]{The main function: simplExpr}
 642 %*                                                                      *
 643 %************************************************************************
 644
 645 The reason for this OutExprStuff stuff is that we want to float *after*
 646 simplifying a RHS, not before.  If we do so naively we get quadratic
 647 behaviour as things float out.
 648
 649 To see why it's important to do it after, consider this (real) example:
 650
 651         let t = f x
 652         in fst t
 653 ==>
 654         let t = let a = e1
 655                     b = e2
 656                 in (a,b)
 657         in fst t
 658 ==>
 659         let a = e1
 660             b = e2
 661             t = (a,b)
 662         in
 663         a       -- Can't inline a this round, cos it appears twice
 664 ==>
 665         e1
 666
 667 Each of the ==> steps is a round of simplification.  We'd save a
 668 whole round if we float first.  This can cascade.  Consider
 669
 670         let f = g d
 671         in \x -> ...f...
 672 ==>
 673         let f = let d1 = ..d.. in \y -> e
 674         in \x -> ...f...
 675 ==>
 676         let d1 = ..d..
 677         in \x -> ...(\y ->e)...
 678
 679 Only in this second round can the \y be applied, and it
 680 might do the same again.
 681
 682
 683 \begin{code}
 684 simplExpr :: SimplEnv -> CoreExpr -> SimplM CoreExpr
 685 simplExpr env expr = simplExprC env expr (mkStop expr_ty' AnArg)
 686                    where
 687                      expr_ty' = substTy (getSubst env) (exprType expr)
 688         -- The type in the Stop continuation, expr_ty', is usually not used
 689         -- It's only needed when discarding continuations after finding
 690         -- a function that returns bottom.
 691         -- Hence the lazy substitution
 692
 693
 694 simplExprC :: SimplEnv -> CoreExpr -> SimplCont -> SimplM CoreExpr
 695         -- Simplify an expression, given a continuation
 696 simplExprC env expr cont
 697   = simplExprF env expr cont    `thenSmpl` \ (floats, expr) ->
 698     returnSmpl (wrapFloats floats expr)
 699
 700 simplExprF :: SimplEnv -> InExpr -> SimplCont -> SimplM FloatsWithExpr
 701         -- Simplify an expression, returning floated binds
 702
 703 simplExprF env (Var v)          cont = simplVar env v cont
 704 simplExprF env (Lit lit)        cont = rebuild env (Lit lit) cont
 705 simplExprF env expr@(Lam _ _)   cont = simplLam env expr cont
 706 simplExprF env (Note note expr) cont = simplNote env note expr cont
 707 simplExprF env (App fun arg)    cont = simplExprF env fun (ApplyTo NoDup arg env cont)
 708
 709 simplExprF env (Type ty) cont
 710   = ASSERT( contIsRhsOrArg cont )
 711     simplType env ty                    `thenSmpl` \ ty' ->
 712     rebuild env (Type ty') cont
 713
 714 simplExprF env (Case scrut bndr alts) cont
 715   | not (switchIsOn (getSwitchChecker env) NoCaseOfCase)
 716   =     -- Simplify the scrutinee with a Select continuation
 717     simplExprF env scrut (Select NoDup bndr alts env cont)
 718
 719   | otherwise
 720   =     -- If case-of-case is off, simply simplify the case expression
 721         -- in a vanilla Stop context, and rebuild the result around it
 722     simplExprC env scrut case_cont      `thenSmpl` \ case_expr' ->
 723     rebuild env case_expr' cont
 724   where
 725     case_cont = Select NoDup bndr alts env (mkBoringStop (contResultType cont))
 726
 727 simplExprF env (Let (Rec pairs) body) cont
 728   = simplRecBndrs env (map fst pairs)           `thenSmpl` \ (env, bndrs') ->
 729         -- NB: bndrs' don't have unfoldings or rules
 730         -- We add them as we go down
 731
 732     simplRecBind env NotTopLevel pairs bndrs'   `thenSmpl` \ (floats, env) ->
 733     addFloats env floats                        $ \ env ->
 734     simplExprF env body cont
 735
 736 -- A non-recursive let is dealt with by simplNonRecBind
 737 simplExprF env (Let (NonRec bndr rhs) body) cont
 738   = simplNonRecBind env bndr rhs env (contResultType cont)      $ \ env ->
 739     simplExprF env body cont
 740
 741
 742 ---------------------------------
 743 simplType :: SimplEnv -> InType -> SimplM OutType
 744         -- Kept monadic just so we can do the seqType
 745 simplType env ty
 746   = seqType new_ty   `seq`   returnSmpl new_ty
 747   where
 748     new_ty = substTy (getSubst env) ty
 749 \end{code}
 750
 751
 752 %************************************************************************
 753 %*                                                                      *
 754 \subsection{Lambdas}
 755 %*                                                                      *
 756 %************************************************************************
 757
 758 \begin{code}
 759 simplLam env fun cont
 760   = go env fun cont
 761   where
 762     zap_it  = mkLamBndrZapper fun (countArgs cont)
 763     cont_ty = contResultType cont
 764
 765         -- Type-beta reduction
 766     go env (Lam bndr body) (ApplyTo _ (Type ty_arg) arg_se body_cont)
 767       = ASSERT( isTyVar bndr )
 768         tick (BetaReduction bndr)                       `thenSmpl_`
 769         simplType (setInScope arg_se env) ty_arg        `thenSmpl` \ ty_arg' ->
 770         go (extendSubst env bndr (DoneTy ty_arg')) body body_cont
 771
 772         -- Ordinary beta reduction
 773     go env (Lam bndr body) cont@(ApplyTo _ arg arg_se body_cont)
 774       = tick (BetaReduction bndr)                               `thenSmpl_`
 775         simplNonRecBind env (zap_it bndr) arg arg_se cont_ty    $ \ env ->
 776         go env body body_cont
 777
 778         -- Not enough args, so there are real lambdas left to put in the result
 779     go env lam@(Lam _ _) cont
 780       = simplLamBndrs env bndrs         `thenSmpl` \ (env, bndrs') ->
 781         simplExpr env body              `thenSmpl` \ body' ->
 782         mkLam env bndrs' body' cont     `thenSmpl` \ (floats, new_lam) ->
 783         addFloats env floats            $ \ env ->
 784         rebuild env new_lam cont
 785       where
 786         (bndrs,body) = collectBinders lam
 787
 788         -- Exactly enough args
 789     go env expr cont = simplExprF env expr cont
 790
 791 mkLamBndrZapper :: CoreExpr     -- Function
 792                 -> Int          -- Number of args supplied, *including* type args
 793                 -> Id -> Id     -- Use this to zap the binders
 794 mkLamBndrZapper fun n_args
 795   | n_args >= n_params fun = \b -> b            -- Enough args
 796   | otherwise              = \b -> zapLamIdInfo b
 797   where
 798         -- NB: we count all the args incl type args
 799         -- so we must count all the binders (incl type lambdas)
 800     n_params (Note _ e) = n_params e
 801     n_params (Lam b e)  = 1 + n_params e
 802     n_params other      = 0::Int
 803 \end{code}
 804
 805
 806 %************************************************************************
 807 %*                                                                      *
 808 \subsection{Notes}
 809 %*                                                                      *
 810 %************************************************************************
 811
 812 \begin{code}
 813 simplNote env (Coerce to from) body cont
 814   = let
 815         in_scope = getInScope env
 816
 817         addCoerce s1 k1 (CoerceIt t1 cont)
 818                 --      coerce T1 S1 (coerce S1 K1 e)
 819                 -- ==>
 820                 --      e,                      if T1=K1
 821                 --      coerce T1 K1 e,         otherwise
 822                 --
 823                 -- For example, in the initial form of a worker
 824                 -- we may find  (coerce T (coerce S (\x.e))) y
 825                 -- and we'd like it to simplify to e[y/x] in one round
 826                 -- of simplification
 827           | t1 `eqType` k1  = cont              -- The coerces cancel out
 828           | otherwise       = CoerceIt t1 cont  -- They don't cancel, but
 829                                                 -- the inner one is redundant
 830
 831         addCoerce t1t2 s1s2 (ApplyTo dup arg arg_se cont)
 832           | not (isTypeArg arg),        -- This whole case only works for value args
 833                                         -- Could upgrade to have equiv thing for type apps too
 834             Just (s1, s2) <- splitFunTy_maybe s1s2
 835                 --      (coerce (T1->T2) (S1->S2) F) E
 836                 -- ===>
 837                 --      coerce T2 S2 (F (coerce S1 T1 E))
 838                 --
 839                 -- t1t2 must be a function type, T1->T2, because it's applied to something
 840                 -- but s1s2 might conceivably not be
 841                 --
 842                 -- When we build the ApplyTo we can't mix the out-types
 843                 -- with the InExpr in the argument, so we simply substitute
 844                 -- to make it all consistent.  It's a bit messy.
 845                 -- But it isn't a common case.
 846           = let
 847                 (t1,t2) = splitFunTy t1t2
 848                 new_arg = mkCoerce2 s1 t1 (substExpr (mkSubst in_scope (getSubstEnv arg_se)) arg)
 849             in
 850             ApplyTo dup new_arg (zapSubstEnv env) (addCoerce t2 s2 cont)
 851
 852         addCoerce to' _ cont = CoerceIt to' cont
 853     in
 854     simplType env to            `thenSmpl` \ to' ->
 855     simplType env from          `thenSmpl` \ from' ->
 856     simplExprF env body (addCoerce to' from' cont)
 857
 858
 859 -- Hack: we only distinguish subsumed cost centre stacks for the purposes of
 860 -- inlining.  All other CCCSs are mapped to currentCCS.
 861 simplNote env (SCC cc) e cont
 862   = simplExpr (setEnclosingCC env currentCCS) e         `thenSmpl` \ e' ->
 863     rebuild env (mkSCC cc e') cont
 864
 865 simplNote env InlineCall e cont
 866   = simplExprF env e (InlinePlease cont)
 867
 868 -- See notes with SimplMonad.inlineMode
 869 simplNote env InlineMe e cont
 870   | contIsRhsOrArg cont         -- Totally boring continuation; see notes above
 871   =                             -- Don't inline inside an INLINE expression
 872     simplExpr (setMode inlineMode env )  e      `thenSmpl` \ e' ->
 873     rebuild env (mkInlineMe e') cont
 874
 875   | otherwise   -- Dissolve the InlineMe note if there's
 876                 -- an interesting context of any kind to combine with
 877                 -- (even a type application -- anything except Stop)
 878   = simplExprF env e cont
 879
 880 simplNote env (CoreNote s) e cont
 881   = simplExpr env e    `thenSmpl` \ e' ->
 882     rebuild env (Note (CoreNote s) e') cont
 883 \end{code}
 884
 885
 886 %************************************************************************
 887 %*                                                                      *
 888 \subsection{Dealing with calls}
 889 %*                                                                      *
 890 %************************************************************************
 891
 892 \begin{code}
 893 simplVar env var cont
 894   = case lookupIdSubst (getSubst env) var of
 895         DoneEx e        -> simplExprF (zapSubstEnv env) e cont
 896         ContEx se e     -> simplExprF (setSubstEnv env se) e cont
 897         DoneId var1 occ -> WARN( not (isInScope var1 (getSubst env)) && mustHaveLocalBinding var1,
 898                                  text "simplVar:" <+> ppr var )
 899                            completeCall (zapSubstEnv env) var1 occ cont
 900                 -- The template is already simplified, so don't re-substitute.
 901                 -- This is VITAL.  Consider
 902                 --      let x = e in
 903                 --      let y = \z -> ...x... in
 904                 --      \ x -> ...y...
 905                 -- We'll clone the inner \x, adding x->x' in the id_subst
 906                 -- Then when we inline y, we must *not* replace x by x' in
 907                 -- the inlined copy!!
 908
 909 ---------------------------------------------------------
 910 --      Dealing with a call site
 911
 912 completeCall env var occ_info cont
 913   =     -- Simplify the arguments
 914     getDOptsSmpl                                        `thenSmpl` \ dflags ->
 915     let
 916         chkr                           = getSwitchChecker env
 917         (args, call_cont, inline_call) = getContArgs chkr var cont
 918         fn_ty                          = idType var
 919     in
 920     simplifyArgs env fn_ty args (contResultType call_cont)      $ \ env args ->
 921
 922         -- Next, look for rules or specialisations that match
 923         --
 924         -- It's important to simplify the args first, because the rule-matcher
 925         -- doesn't do substitution as it goes.  We don't want to use subst_args
 926         -- (defined in the 'where') because that throws away useful occurrence info,
 927         -- and perhaps-very-important specialisations.
 928         --
 929         -- Some functions have specialisations *and* are strict; in this case,
 930         -- we don't want to inline the wrapper of the non-specialised thing; better
 931         -- to call the specialised thing instead.
 932         -- We used to use the black-listing mechanism to ensure that inlining of
 933         -- the wrapper didn't occur for things that have specialisations till a
 934         -- later phase, so but now we just try RULES first
 935         --
 936         -- You might think that we shouldn't apply rules for a loop breaker:
 937         -- doing so might give rise to an infinite loop, because a RULE is
 938         -- rather like an extra equation for the function:
 939         --      RULE:           f (g x) y = x+y
 940         --      Eqn:            f a     y = a-y
 941         --
 942         -- But it's too drastic to disable rules for loop breakers.
 943         -- Even the foldr/build rule would be disabled, because foldr
 944         -- is recursive, and hence a loop breaker:
 945         --      foldr k z (build g) = g k z
 946         -- So it's up to the programmer: rules can cause divergence
 947
 948     let
 949         in_scope   = getInScope env
 950         maybe_rule = case activeRule env of
 951                         Nothing     -> Nothing  -- No rules apply
 952                         Just act_fn -> lookupRule act_fn in_scope var args
 953     in
 954     case maybe_rule of {
 955         Just (rule_name, rule_rhs) ->
 956                 tick (RuleFired rule_name)                      `thenSmpl_`
 957                 (if dopt Opt_D_dump_inlinings dflags then
 958                    pprTrace "Rule fired" (vcat [
 959                         text "Rule:" <+> ftext rule_name,
 960                         text "Before:" <+> ppr var <+> sep (map pprParendExpr args),
 961                         text "After: " <+> pprCoreExpr rule_rhs,
 962                         text "Cont:  " <+> ppr call_cont])
 963                  else
 964                         id)             $
 965                 simplExprF env rule_rhs call_cont ;
 966
 967         Nothing ->              -- No rules
 968
 969         -- Next, look for an inlining
 970     let
 971         arg_infos = [ interestingArg arg | arg <- args, isValArg arg]
 972
 973         interesting_cont = interestingCallContext (notNull args)
 974                                                   (notNull arg_infos)
 975                                                   call_cont
 976
 977         active_inline = activeInline env var occ_info
 978         maybe_inline  = callSiteInline dflags active_inline inline_call occ_info
 979                                        var arg_infos interesting_cont
 980     in
 981     case maybe_inline of {
 982         Just unfolding          -- There is an inlining!
 983           ->  tick (UnfoldingDone var)          `thenSmpl_`
 984               makeThatCall env var unfolding args call_cont
 985
 986         ;
 987         Nothing ->              -- No inlining!
 988
 989         -- Done
 990     rebuild env (mkApps (Var var) args) call_cont
 991     }}
 992
 993 makeThatCall :: SimplEnv
 994              -> Id
 995              -> InExpr          -- Inlined function rhs
 996              -> [OutExpr]       -- Arguments, already simplified
 997              -> SimplCont       -- After the call
 998              -> SimplM FloatsWithExpr
 999 -- Similar to simplLam, but this time
1000 -- the arguments are already simplified
1001 makeThatCall orig_env var fun@(Lam _ _) args cont
1002   = go orig_env fun args
1003   where
1004     zap_it = mkLamBndrZapper fun (length args)
1005
1006         -- Type-beta reduction
1007     go env (Lam bndr body) (Type ty_arg : args)
1008       = ASSERT( isTyVar bndr )
1009         tick (BetaReduction bndr)                       `thenSmpl_`
1010         go (extendSubst env bndr (DoneTy ty_arg)) body args
1011
1012         -- Ordinary beta reduction
1013     go env (Lam bndr body) (arg : args)
1014       = tick (BetaReduction bndr)                       `thenSmpl_`
1015         simplNonRecX env (zap_it bndr) arg              $ \ env ->
1016         go env body args
1017
1018         -- Not enough args, so there are real lambdas left to put in the result
1019     go env fun args
1020       = simplExprF env fun (pushContArgs orig_env args cont)
1021         -- NB: orig_env; the correct environment to capture with
1022         -- the arguments.... env has been augmented with substitutions
1023         -- from the beta reductions.
1024
1025 makeThatCall env var fun args cont
1026   = simplExprF env fun (pushContArgs env args cont)
1027 \end{code}
1028
1029
1030 %************************************************************************
1031 %*                                                                      *
1032 \subsection{Arguments}
1033 %*                                                                      *
1034 %************************************************************************
1035
1036 \begin{code}
1037 ---------------------------------------------------------
1038 --      Simplifying the arguments of a call
1039
1040 simplifyArgs :: SimplEnv
1041              -> OutType                         -- Type of the function
1042              -> [(InExpr, SimplEnv, Bool)]      -- Details of the arguments
1043              -> OutType                         -- Type of the continuation
1044              -> (SimplEnv -> [OutExpr] -> SimplM FloatsWithExpr)
1045              -> SimplM FloatsWithExpr
1046
1047 -- [CPS-like because of strict arguments]
1048
1049 -- Simplify the arguments to a call.
1050 -- This part of the simplifier may break the no-shadowing invariant
1051 -- Consider
1052 --      f (...(\a -> e)...) (case y of (a,b) -> e')
1053 -- where f is strict in its second arg
1054 -- If we simplify the innermost one first we get (...(\a -> e)...)
1055 -- Simplifying the second arg makes us float the case out, so we end up with
1056 --      case y of (a,b) -> f (...(\a -> e)...) e'
1057 -- So the output does not have the no-shadowing invariant.  However, there is
1058 -- no danger of getting name-capture, because when the first arg was simplified
1059 -- we used an in-scope set that at least mentioned all the variables free in its
1060 -- static environment, and that is enough.
1061 --
1062 -- We can't just do innermost first, or we'd end up with a dual problem:
1063 --      case x of (a,b) -> f e (...(\a -> e')...)
1064 --
1065 -- I spent hours trying to recover the no-shadowing invariant, but I just could
1066 -- not think of an elegant way to do it.  The simplifier is already knee-deep in
1067 -- continuations.  We have to keep the right in-scope set around; AND we have
1068 -- to get the effect that finding (error "foo") in a strict arg position will
1069 -- discard the entire application and replace it with (error "foo").  Getting
1070 -- all this at once is TOO HARD!
1071
1072 simplifyArgs env fn_ty args cont_ty thing_inside
1073   = go env fn_ty args thing_inside
1074   where
1075     go env fn_ty []         thing_inside = thing_inside env []
1076     go env fn_ty (arg:args) thing_inside = simplifyArg env fn_ty arg cont_ty            $ \ env arg' ->
1077                                            go env (applyTypeToArg fn_ty arg') args      $ \ env args' ->
1078                                            thing_inside env (arg':args')
1079
1080 simplifyArg env fn_ty (Type ty_arg, se, _) cont_ty thing_inside
1081   = simplType (setInScope se env) ty_arg        `thenSmpl` \ new_ty_arg ->
1082     thing_inside env (Type new_ty_arg)
1083
1084 simplifyArg env fn_ty (val_arg, arg_se, is_strict) cont_ty thing_inside
1085   | is_strict
1086   = simplStrictArg AnArg env val_arg arg_se arg_ty cont_ty thing_inside
1087
1088   | otherwise   -- Lazy argument
1089                 -- DO NOT float anything outside, hence simplExprC
1090                 -- There is no benefit (unlike in a let-binding), and we'd
1091                 -- have to be very careful about bogus strictness through
1092                 -- floating a demanded let.
1093   = simplExprC (setInScope arg_se env) val_arg
1094                (mkStop arg_ty AnArg)            `thenSmpl` \ arg1 ->
1095    thing_inside env arg1
1096   where
1097     arg_ty = funArgTy fn_ty
1098
1099
1100 simplStrictArg ::  LetRhsFlag
1101                 -> SimplEnv             -- The env of the call
1102                 -> InExpr -> SimplEnv   -- The arg plus its env
1103                 -> OutType              -- arg_ty: type of the argument
1104                 -> OutType              -- cont_ty: Type of thing computed by the context
1105                 -> (SimplEnv -> OutExpr -> SimplM FloatsWithExpr)
1106                                         -- Takes an expression of type rhs_ty,
1107                                         -- returns an expression of type cont_ty
1108                                         -- The env passed to this continuation is the
1109                                         -- env of the call, plus any new in-scope variables
1110                 -> SimplM FloatsWithExpr        -- An expression of type cont_ty
1111
1112 simplStrictArg is_rhs call_env arg arg_env arg_ty cont_ty thing_inside
1113   = simplExprF (setInScope arg_env call_env) arg
1114                (ArgOf is_rhs arg_ty cont_ty (\ new_env -> thing_inside (setInScope call_env new_env)))
1115   -- Notice the way we use arg_env (augmented with in-scope vars from call_env)
1116   --    to simplify the argument
1117   -- and call-env (augmented with in-scope vars from the arg) to pass to the continuation
1118 \end{code}
1119
1120
1121 %************************************************************************
1122 %*                                                                      *
1123 \subsection{mkAtomicArgs}
1124 %*                                                                      *
1125 %************************************************************************
1126
1127 mkAtomicArgs takes a putative RHS, checks whether it's a PAP or
1128 constructor application and, if so, converts it to ANF, so that the
1129 resulting thing can be inlined more easily.  Thus
1130         x = (f a, g b)
1131 becomes
1132         t1 = f a
1133         t2 = g b
1134         x = (t1,t2)
1135
1136 There are three sorts of binding context, specified by the two
1137 boolean arguments
1138
1139 Strict
1140    OK-unlifted
1141
1142 N  N    Top-level or recursive                  Only bind args of lifted type
1143
1144 N  Y    Non-top-level and non-recursive,        Bind args of lifted type, or
1145                 but lazy                        unlifted-and-ok-for-speculation
1146
1147 Y  Y    Non-top-level, non-recursive,           Bind all args
1148                  and strict (demanded)
1149
1150
1151 For example, given
1152
1153         x = MkC (y div# z)
1154
1155 there is no point in transforming to
1156
1157         x = case (y div# z) of r -> MkC r
1158
1159 because the (y div# z) can't float out of the let. But if it was
1160 a *strict* let, then it would be a good thing to do.  Hence the
1161 context information.
1162
1163 \begin{code}
1164 mkAtomicArgs :: Bool    -- A strict binding
1165              -> Bool    -- OK to float unlifted args
1166              -> OutExpr
1167              -> SimplM (OrdList (OutId,OutExpr),  -- The floats (unusually) may include
1168                         OutExpr)                  -- things that need case-binding,
1169                                                   -- if the strict-binding flag is on
1170
1171 mkAtomicArgs is_strict ok_float_unlifted rhs
1172   | (Var fun, args) <- collectArgs rhs,                         -- It's an application
1173     isDataConWorkId fun || valArgCount args < idArity fun       -- And it's a constructor or PAP
1174   = go fun nilOL [] args        -- Have a go
1175
1176   | otherwise = bale_out        -- Give up
1177
1178   where
1179     bale_out = returnSmpl (nilOL, rhs)
1180
1181     go fun binds rev_args []
1182         = returnSmpl (binds, mkApps (Var fun) (reverse rev_args))
1183
1184     go fun binds rev_args (arg : args)
1185         | exprIsTrivial arg     -- Easy case
1186         = go fun binds (arg:rev_args) args
1187
1188         | not can_float_arg     -- Can't make this arg atomic
1189         = bale_out              -- ... so give up
1190
1191         | otherwise     -- Don't forget to do it recursively
1192                         -- E.g.  x = a:b:c:[]
1193         =  mkAtomicArgs is_strict ok_float_unlifted arg `thenSmpl` \ (arg_binds, arg') ->
1194            newId FSLIT("a") arg_ty                      `thenSmpl` \ arg_id ->
1195            go fun ((arg_binds `snocOL` (arg_id,arg')) `appOL` binds)
1196               (Var arg_id : rev_args) args
1197         where
1198           arg_ty        = exprType arg
1199           can_float_arg =  is_strict
1200                         || not (isUnLiftedType arg_ty)
1201                         || (ok_float_unlifted && exprOkForSpeculation arg)
1202
1203
1204 addAtomicBinds :: SimplEnv -> [(OutId,OutExpr)]
1205                -> (SimplEnv -> SimplM (FloatsWith a))
1206                -> SimplM (FloatsWith a)
1207 addAtomicBinds env []         thing_inside = thing_inside env
1208 addAtomicBinds env ((v,r):bs) thing_inside = addAuxiliaryBind env (NonRec v r) $ \ env ->
1209                                              addAtomicBinds env bs thing_inside
1210
1211 addAtomicBindsE :: SimplEnv -> [(OutId,OutExpr)]
1212                 -> (SimplEnv -> SimplM FloatsWithExpr)
1213                 -> SimplM FloatsWithExpr
1214 -- Same again, but this time we're in an expression context,
1215 -- and may need to do some case bindings
1216
1217 addAtomicBindsE env [] thing_inside
1218   = thing_inside env
1219 addAtomicBindsE env ((v,r):bs) thing_inside
1220   | needsCaseBinding (idType v) r
1221   = addAtomicBindsE (addNewInScopeIds env [v]) bs thing_inside  `thenSmpl` \ (floats, expr) ->
1222     WARN( exprIsTrivial expr, ppr v <+> pprCoreExpr expr )
1223     returnSmpl (emptyFloats env, Case r v [(DEFAULT,[], wrapFloats floats expr)])
1224
1225   | otherwise
1226   = addAuxiliaryBind env (NonRec v r)   $ \ env ->
1227     addAtomicBindsE env bs thing_inside
1228 \end{code}
1229
1230
1231 %************************************************************************
1232 %*                                                                      *
1233 \subsection{The main rebuilder}
1234 %*                                                                      *
1235 %************************************************************************
1236
1237 \begin{code}
1238 rebuild :: SimplEnv -> OutExpr -> SimplCont -> SimplM FloatsWithExpr
1239
1240 rebuild env expr (Stop _ _ _)                 = rebuildDone env expr
1241 rebuild env expr (ArgOf _ _ _ cont_fn)        = cont_fn env expr
1242 rebuild env expr (CoerceIt to_ty cont)        = rebuild env (mkCoerce to_ty expr) cont
1243 rebuild env expr (InlinePlease cont)          = rebuild env (Note InlineCall expr) cont
1244 rebuild env expr (Select _ bndr alts se cont) = rebuildCase (setInScope se env) expr bndr alts cont
1245 rebuild env expr (ApplyTo _ arg se cont)      = rebuildApp  (setInScope se env) expr arg cont
1246
1247 rebuildApp env fun arg cont
1248   = simplExpr env arg   `thenSmpl` \ arg' ->
1249     rebuild env (App fun arg') cont
1250
1251 rebuildDone env expr = returnSmpl (emptyFloats env, expr)
1252 \end{code}
1253
1254
1255 %************************************************************************
1256 %*                                                                      *
1257 \subsection{Functions dealing with a case}
1258 %*                                                                      *
1259 %************************************************************************
1260
1261 Blob of helper functions for the "case-of-something-else" situation.
1262
1263 \begin{code}
1264 ---------------------------------------------------------
1265 --      Eliminate the case if possible
1266
1267 rebuildCase :: SimplEnv
1268             -> OutExpr          -- Scrutinee
1269             -> InId             -- Case binder
1270             -> [InAlt]          -- Alternatives
1271             -> SimplCont
1272             -> SimplM FloatsWithExpr
1273
1274 rebuildCase env scrut case_bndr alts cont
1275   | Just (con,args) <- exprIsConApp_maybe scrut
1276         -- Works when the scrutinee is a variable with a known unfolding
1277         -- as well as when it's an explicit constructor application
1278   = knownCon env (DataAlt con) args case_bndr alts cont
1279
1280   | Lit lit <- scrut    -- No need for same treatment as constructors
1281                         -- because literals are inlined more vigorously
1282   = knownCon env (LitAlt lit) [] case_bndr alts cont
1283
1284   | otherwise
1285   = prepareAlts scrut case_bndr alts            `thenSmpl` \ (better_alts, handled_cons) ->
1286
1287         -- Deal with the case binder, and prepare the continuation;
1288         -- The new subst_env is in place
1289     prepareCaseCont env better_alts cont        `thenSmpl` \ (floats, (dup_cont, nondup_cont)) ->
1290     addFloats env floats                        $ \ env ->
1291
1292         -- Deal with variable scrutinee
1293     simplCaseBinder env scrut case_bndr         `thenSmpl` \ (alt_env, case_bndr', zap_occ_info) ->
1294
1295         -- Deal with the case alternatives
1296     simplAlts alt_env zap_occ_info handled_cons
1297               case_bndr' better_alts dup_cont   `thenSmpl` \ alts' ->
1298
1299         -- Put the case back together
1300     mkCase scrut case_bndr' alts'               `thenSmpl` \ case_expr ->
1301
1302         -- Notice that rebuildDone returns the in-scope set from env, not alt_env
1303         -- The case binder *not* scope over the whole returned case-expression
1304     rebuild env case_expr nondup_cont
1305 \end{code}
1306
1307 simplCaseBinder checks whether the scrutinee is a variable, v.  If so,
1308 try to eliminate uses of v in the RHSs in favour of case_bndr; that
1309 way, there's a chance that v will now only be used once, and hence
1310 inlined.
1311
1312 Note 1
1313 ~~~~~~
1314 There is a time we *don't* want to do that, namely when
1315 -fno-case-of-case is on.  This happens in the first simplifier pass,
1316 and enhances full laziness.  Here's the bad case:
1317         f = \ y -> ...(case x of I# v -> ...(case x of ...) ... )
1318 If we eliminate the inner case, we trap it inside the I# v -> arm,
1319 which might prevent some full laziness happening.  I've seen this
1320 in action in spectral/cichelli/Prog.hs:
1321          [(m,n) | m <- [1..max], n <- [1..max]]
1322 Hence the check for NoCaseOfCase.
1323
1324 Note 2
1325 ~~~~~~
1326 There is another situation when we don't want to do it.  If we have
1327
1328     case x of w1 { DEFAULT -> case x of w2 { A -> e1; B -> e2 }
1329                    ...other cases .... }
1330
1331 We'll perform the binder-swap for the outer case, giving
1332
1333     case x of w1 { DEFAULT -> case w1 of w2 { A -> e1; B -> e2 }
1334                    ...other cases .... }
1335
1336 But there is no point in doing it for the inner case, because w1 can't
1337 be inlined anyway.  Furthermore, doing the case-swapping involves
1338 zapping w2's occurrence info (see paragraphs that follow), and that
1339 forces us to bind w2 when doing case merging.  So we get
1340
1341     case x of w1 { A -> let w2 = w1 in e1
1342                    B -> let w2 = w1 in e2
1343                    ...other cases .... }
1344
1345 This is plain silly in the common case where w2 is dead.
1346
1347 Even so, I can't see a good way to implement this idea.  I tried
1348 not doing the binder-swap if the scrutinee was already evaluated
1349 but that failed big-time:
1350
1351         data T = MkT !Int
1352
1353         case v of w  { MkT x ->
1354         case x of x1 { I# y1 ->
1355         case x of x2 { I# y2 -> ...
1356
1357 Notice that because MkT is strict, x is marked "evaluated".  But to
1358 eliminate the last case, we must either make sure that x (as well as
1359 x1) has unfolding MkT y1.  THe straightforward thing to do is to do
1360 the binder-swap.  So this whole note is a no-op.
1361
1362 Note 3
1363 ~~~~~~
1364 If we replace the scrutinee, v, by tbe case binder, then we have to nuke
1365 any occurrence info (eg IAmDead) in the case binder, because the
1366 case-binder now effectively occurs whenever v does.  AND we have to do
1367 the same for the pattern-bound variables!  Example:
1368
1369         (case x of { (a,b) -> a }) (case x of { (p,q) -> q })
1370
1371 Here, b and p are dead.  But when we move the argment inside the first
1372 case RHS, and eliminate the second case, we get
1373
1374         case x or { (a,b) -> a b }
1375
1376 Urk! b is alive!  Reason: the scrutinee was a variable, and case elimination
1377 happened.  Hence the zap_occ_info function returned by simplCaseBinder
1378
1379 \begin{code}
1380 simplCaseBinder env (Var v) case_bndr
1381   | not (switchIsOn (getSwitchChecker env) NoCaseOfCase)
1382
1383 -- Failed try [see Note 2 above]
1384 --     not (isEvaldUnfolding (idUnfolding v))
1385
1386   = simplBinder env (zap case_bndr)             `thenSmpl` \ (env, case_bndr') ->
1387     returnSmpl (modifyInScope env v case_bndr', case_bndr', zap)
1388         -- We could extend the substitution instead, but it would be
1389         -- a hack because then the substitution wouldn't be idempotent
1390         -- any more (v is an OutId).  And this just just as well.
1391   where
1392     zap b = b `setIdOccInfo` NoOccInfo
1393
1394 simplCaseBinder env other_scrut case_bndr
1395   = simplBinder env case_bndr           `thenSmpl` \ (env, case_bndr') ->
1396     returnSmpl (env, case_bndr', \ bndr -> bndr)        -- NoOp on bndr
1397 \end{code}
1398
1399
1400
1401 \begin{code}
1402 simplAlts :: SimplEnv
1403           -> (InId -> InId)             -- Occ-info zapper
1404           -> [AltCon]                   -- Alternatives the scrutinee can't be
1405                                         -- in the default case
1406           -> OutId                      -- Case binder
1407           -> [InAlt] -> SimplCont
1408           -> SimplM [OutAlt]            -- Includes the continuation
1409
1410 simplAlts env zap_occ_info handled_cons case_bndr' alts cont'
1411   = mapSmpl simpl_alt alts
1412   where
1413     inst_tys' = tyConAppArgs (idType case_bndr')
1414
1415     simpl_alt (DEFAULT, _, rhs)
1416         = let
1417                 -- In the default case we record the constructors that the
1418                 -- case-binder *can't* be.
1419                 -- We take advantage of any OtherCon info in the case scrutinee
1420                 case_bndr_w_unf = case_bndr' `setIdUnfolding` mkOtherCon handled_cons
1421                 env_with_unf    = modifyInScope env case_bndr' case_bndr_w_unf
1422           in
1423           simplExprC env_with_unf rhs cont'     `thenSmpl` \ rhs' ->
1424           returnSmpl (DEFAULT, [], rhs')
1425
1426     simpl_alt (con, vs, rhs)
1427         =       -- Deal with the pattern-bound variables
1428                 -- Mark the ones that are in ! positions in the data constructor
1429                 -- as certainly-evaluated.
1430                 -- NB: it happens that simplBinders does *not* erase the OtherCon
1431                 --     form of unfolding, so it's ok to add this info before
1432                 --     doing simplBinders
1433           simplBinders env (add_evals con vs)           `thenSmpl` \ (env, vs') ->
1434
1435                 -- Bind the case-binder to (con args)
1436           let
1437                 unfolding    = mkUnfolding False (mkAltExpr con vs' inst_tys')
1438                 env_with_unf = modifyInScope env case_bndr' (case_bndr' `setIdUnfolding` unfolding)
1439           in
1440           simplExprC env_with_unf rhs cont'             `thenSmpl` \ rhs' ->
1441           returnSmpl (con, vs', rhs')
1442
1443
1444         -- add_evals records the evaluated-ness of the bound variables of
1445         -- a case pattern.  This is *important*.  Consider
1446         --      data T = T !Int !Int
1447         --
1448         --      case x of { T a b -> T (a+1) b }
1449         --
1450         -- We really must record that b is already evaluated so that we don't
1451         -- go and re-evaluate it when constructing the result.
1452
1453     add_evals (DataAlt dc) vs = cat_evals vs (dataConRepStrictness dc)
1454     add_evals other_con    vs = vs
1455
1456     cat_evals [] [] = []
1457     cat_evals (v:vs) (str:strs)
1458         | isTyVar v          = v        : cat_evals vs (str:strs)
1459         | isMarkedStrict str = evald_v  : cat_evals vs strs
1460         | otherwise          = zapped_v : cat_evals vs strs
1461         where
1462           zapped_v = zap_occ_info v
1463           evald_v  = zapped_v `setIdUnfolding` mkOtherCon []
1464 \end{code}
1465
1466
1467 %************************************************************************
1468 %*                                                                      *
1469 \subsection{Known constructor}
1470 %*                                                                      *
1471 %************************************************************************
1472
1473 We are a bit careful with occurrence info.  Here's an example
1474
1475         (\x* -> case x of (a*, b) -> f a) (h v, e)
1476
1477 where the * means "occurs once".  This effectively becomes
1478         case (h v, e) of (a*, b) -> f a)
1479 and then
1480         let a* = h v; b = e in f a
1481 and then
1482         f (h v)
1483
1484 All this should happen in one sweep.
1485
1486 \begin{code}
1487 knownCon :: SimplEnv -> AltCon -> [OutExpr]
1488          -> InId -> [InAlt] -> SimplCont
1489          -> SimplM FloatsWithExpr
1490
1491 knownCon env con args bndr alts cont
1492   = tick (KnownBranch bndr)     `thenSmpl_`
1493     case findAlt con alts of
1494         (DEFAULT, bs, rhs)     -> ASSERT( null bs )
1495                                   simplNonRecX env bndr scrut   $ \ env ->
1496                                         -- This might give rise to a binding with non-atomic args
1497                                         -- like x = Node (f x) (g x)
1498                                         -- but no harm will be done
1499                                   simplExprF env rhs cont
1500                                 where
1501                                   scrut = case con of
1502                                             LitAlt lit -> Lit lit
1503                                             DataAlt dc -> mkConApp dc args
1504
1505         (LitAlt lit, bs, rhs) ->  ASSERT( null bs )
1506                                   simplNonRecX env bndr (Lit lit)       $ \ env ->
1507                                   simplExprF env rhs cont
1508
1509         (DataAlt dc, bs, rhs)  -> ASSERT( length bs + n_tys == length args )
1510                                   bind_args env bs (drop n_tys args)    $ \ env ->
1511                                   let
1512                                     con_app  = mkConApp dc (take n_tys args ++ con_args)
1513                                     con_args = [substExpr (getSubst env) (varToCoreExpr b) | b <- bs]
1514                                         -- args are aready OutExprs, but bs are InIds
1515                                   in
1516                                   simplNonRecX env bndr con_app         $ \ env ->
1517                                   simplExprF env rhs cont
1518                                where
1519                                   n_tys = dataConNumInstArgs dc -- Non-existential type args
1520 -- Ugh!
1521 bind_args env [] _ thing_inside = thing_inside env
1522
1523 bind_args env (b:bs) (Type ty : args) thing_inside
1524   = bind_args (extendSubst env b (DoneTy ty)) bs args thing_inside
1525
1526 bind_args env (b:bs) (arg : args) thing_inside
1527   = simplNonRecX env b arg      $ \ env ->
1528     bind_args env bs args thing_inside
1529 \end{code}
1530
1531
1532 %************************************************************************
1533 %*                                                                      *
1534 \subsection{Duplicating continuations}
1535 %*                                                                      *
1536 %************************************************************************
1537
1538 \begin{code}
1539 prepareCaseCont :: SimplEnv
1540                 -> [InAlt] -> SimplCont
1541                 -> SimplM (FloatsWith (SimplCont,SimplCont))
1542                         -- Return a duplicatable continuation, a non-duplicable part
1543                         -- plus some extra bindings
1544
1545         -- No need to make it duplicatable if there's only one alternative
1546 prepareCaseCont env [alt] cont = returnSmpl (emptyFloats env, (cont, mkBoringStop (contResultType cont)))
1547 prepareCaseCont env alts  cont = mkDupableCont env cont
1548 \end{code}
1549
1550 \begin{code}
1551 mkDupableCont :: SimplEnv -> SimplCont
1552               -> SimplM (FloatsWith (SimplCont, SimplCont))
1553
1554 mkDupableCont env cont
1555   | contIsDupable cont
1556   = returnSmpl (emptyFloats env, (cont, mkBoringStop (contResultType cont)))
1557
1558 mkDupableCont env (CoerceIt ty cont)
1559   = mkDupableCont env cont              `thenSmpl` \ (floats, (dup_cont, nondup_cont)) ->
1560     returnSmpl (floats, (CoerceIt ty dup_cont, nondup_cont))
1561
1562 mkDupableCont env (InlinePlease cont)
1563   = mkDupableCont env cont              `thenSmpl` \ (floats, (dup_cont, nondup_cont)) ->
1564     returnSmpl (floats, (InlinePlease dup_cont, nondup_cont))
1565
1566 mkDupableCont env cont@(ArgOf _ arg_ty _ _)
1567   =  returnSmpl (emptyFloats env, (mkBoringStop arg_ty, cont))
1568         -- Do *not* duplicate an ArgOf continuation
1569         -- Because ArgOf continuations are opaque, we gain nothing by
1570         -- propagating them into the expressions, and we do lose a lot.
1571         -- Here's an example:
1572         --      && (case x of { T -> F; F -> T }) E
1573         -- Now, && is strict so we end up simplifying the case with
1574         -- an ArgOf continuation.  If we let-bind it, we get
1575         --
1576         --      let $j = \v -> && v E
1577         --      in simplExpr (case x of { T -> F; F -> T })
1578         --                   (ArgOf (\r -> $j r)
1579         -- And after simplifying more we get
1580         --
1581         --      let $j = \v -> && v E
1582         --      in case of { T -> $j F; F -> $j T }
1583         -- Which is a Very Bad Thing
1584         --
1585         -- The desire not to duplicate is the entire reason that
1586         -- mkDupableCont returns a pair of continuations.
1587         --
1588         -- The original plan had:
1589         -- e.g.         (...strict-fn...) [...hole...]
1590         --      ==>
1591         --              let $j = \a -> ...strict-fn...
1592         --              in $j [...hole...]
1593
1594 mkDupableCont env (ApplyTo _ arg se cont)
1595   =     -- e.g.         [...hole...] (...arg...)
1596         --      ==>
1597         --              let a = ...arg...
1598         --              in [...hole...] a
1599     simplExpr (setInScope se env) arg                   `thenSmpl` \ arg' ->
1600
1601     mkDupableCont env cont                              `thenSmpl` \ (floats, (dup_cont, nondup_cont)) ->
1602     addFloats env floats                                $ \ env ->
1603
1604     if exprIsDupable arg' then
1605         returnSmpl (emptyFloats env, (ApplyTo OkToDup arg' (zapSubstEnv se) dup_cont, nondup_cont))
1606     else
1607     newId FSLIT("a") (exprType arg')                    `thenSmpl` \ arg_id ->
1608
1609     tick (CaseOfCase arg_id)                            `thenSmpl_`
1610         -- Want to tick here so that we go round again,
1611         -- and maybe copy or inline the code.
1612         -- Not strictly CaseOfCase, but never mind
1613
1614     returnSmpl (unitFloat env arg_id arg',
1615                 (ApplyTo OkToDup (Var arg_id) (zapSubstEnv se) dup_cont,
1616                  nondup_cont))
1617         -- But what if the arg should be case-bound?
1618         -- This has been this way for a long time, so I'll leave it,
1619         -- but I can't convince myself that it's right.
1620
1621
1622 mkDupableCont env (Select _ case_bndr alts se cont)
1623   =     -- e.g.         (case [...hole...] of { pi -> ei })
1624         --      ===>
1625         --              let ji = \xij -> ei
1626         --              in case [...hole...] of { pi -> ji xij }
1627     tick (CaseOfCase case_bndr)                                 `thenSmpl_`
1628     let
1629         alt_env = setInScope se env
1630     in
1631     prepareCaseCont alt_env alts cont                           `thenSmpl` \ (floats1, (dup_cont, nondup_cont)) ->
1632     addFloats alt_env floats1                                   $ \ alt_env ->
1633
1634     simplBinder alt_env case_bndr                               `thenSmpl` \ (alt_env, case_bndr') ->
1635         -- NB: simplBinder does not zap deadness occ-info, so
1636         -- a dead case_bndr' will still advertise its deadness
1637         -- This is really important because in
1638         --      case e of b { (# a,b #) -> ... }
1639         -- b is always dead, and indeed we are not allowed to bind b to (# a,b #),
1640         -- which might happen if e was an explicit unboxed pair and b wasn't marked dead.
1641         -- In the new alts we build, we have the new case binder, so it must retain
1642         -- its deadness.
1643
1644     mkDupableAlts alt_env case_bndr' alts dup_cont      `thenSmpl` \ (floats2, alts') ->
1645     addFloats alt_env floats2                           $ \ alt_env ->
1646     returnSmpl (emptyFloats alt_env,
1647                 (Select OkToDup case_bndr' alts' (zapSubstEnv se)
1648                         (mkBoringStop (contResultType dup_cont)),
1649                  nondup_cont))
1650
1651 mkDupableAlts :: SimplEnv -> OutId -> [InAlt] -> SimplCont
1652               -> SimplM (FloatsWith [InAlt])
1653 -- Absorbs the continuation into the new alternatives
1654
1655 mkDupableAlts env case_bndr' alts dupable_cont
1656   = go env alts
1657   where
1658     go env [] = returnSmpl (emptyFloats env, [])
1659     go env (alt:alts)
1660         = mkDupableAlt env case_bndr' dupable_cont alt  `thenSmpl` \ (floats1, alt') ->
1661           addFloats env floats1                         $ \ env ->
1662           go env alts                                   `thenSmpl` \ (floats2, alts') ->
1663           returnSmpl (floats2, alt' : alts')
1664
1665 mkDupableAlt env case_bndr' cont alt@(con, bndrs, rhs)
1666   = simplBinders env bndrs                              `thenSmpl` \ (env, bndrs') ->
1667     simplExprC env rhs cont                             `thenSmpl` \ rhs' ->
1668
1669     if exprIsDupable rhs' then
1670         returnSmpl (emptyFloats env, (con, bndrs', rhs'))
1671         -- It is worth checking for a small RHS because otherwise we
1672         -- get extra let bindings that may cause an extra iteration of the simplifier to
1673         -- inline back in place.  Quite often the rhs is just a variable or constructor.
1674         -- The Ord instance of Maybe in PrelMaybe.lhs, for example, took several extra
1675         -- iterations because the version with the let bindings looked big, and so wasn't
1676         -- inlined, but after the join points had been inlined it looked smaller, and so
1677         -- was inlined.
1678         --
1679         -- NB: we have to check the size of rhs', not rhs.
1680         -- Duplicating a small InAlt might invalidate occurrence information
1681         -- However, if it *is* dupable, we return the *un* simplified alternative,
1682         -- because otherwise we'd need to pair it up with an empty subst-env....
1683         -- but we only have one env shared between all the alts.
1684         -- (Remember we must zap the subst-env before re-simplifying something).
1685         -- Rather than do this we simply agree to re-simplify the original (small) thing later.
1686
1687     else
1688     let
1689         rhs_ty'     = exprType rhs'
1690         used_bndrs' = filter (not . isDeadBinder) (case_bndr' : bndrs')
1691                 -- The deadness info on the new binders is unscathed
1692     in
1693         -- If we try to lift a primitive-typed something out
1694         -- for let-binding-purposes, we will *caseify* it (!),
1695         -- with potentially-disastrous strictness results.  So
1696         -- instead we turn it into a function: \v -> e
1697         -- where v::State# RealWorld#.  The value passed to this function
1698         -- is realworld#, which generates (almost) no code.
1699
1700         -- There's a slight infelicity here: we pass the overall
1701         -- case_bndr to all the join points if it's used in *any* RHS,
1702         -- because we don't know its usage in each RHS separately
1703
1704         -- We used to say "&& isUnLiftedType rhs_ty'" here, but now
1705         -- we make the join point into a function whenever used_bndrs'
1706         -- is empty.  This makes the join-point more CPR friendly.
1707         -- Consider:    let j = if .. then I# 3 else I# 4
1708         --              in case .. of { A -> j; B -> j; C -> ... }
1709         --
1710         -- Now CPR doesn't w/w j because it's a thunk, so
1711         -- that means that the enclosing function can't w/w either,
1712         -- which is a lose.  Here's the example that happened in practice:
1713         --      kgmod :: Int -> Int -> Int
1714         --      kgmod x y = if x > 0 && y < 0 || x < 0 && y > 0
1715         --                  then 78
1716         --                  else 5
1717         --
1718         -- I have seen a case alternative like this:
1719         --      True -> \v -> ...
1720         -- It's a bit silly to add the realWorld dummy arg in this case, making
1721         --      $j = \s v -> ...
1722         --         True -> $j s
1723         -- (the \v alone is enough to make CPR happy) but I think it's rare
1724
1725     ( if null used_bndrs'
1726         then newId FSLIT("w") realWorldStatePrimTy      `thenSmpl` \ rw_id ->
1727              returnSmpl ([rw_id], [Var realWorldPrimId])
1728         else
1729              returnSmpl (used_bndrs', map varToCoreExpr used_bndrs')
1730     )                                                   `thenSmpl` \ (final_bndrs', final_args) ->
1731
1732         -- See comment about "$j" name above
1733     newId (encodeFS FSLIT("$j")) (mkPiTypes final_bndrs' rhs_ty')       `thenSmpl` \ join_bndr ->
1734         -- Notice the funky mkPiTypes.  If the contructor has existentials
1735         -- it's possible that the join point will be abstracted over
1736         -- type varaibles as well as term variables.
1737         --  Example:  Suppose we have
1738         --      data T = forall t.  C [t]
1739         --  Then faced with
1740         --      case (case e of ...) of
1741         --          C t xs::[t] -> rhs
1742         --  We get the join point
1743         --      let j :: forall t. [t] -> ...
1744         --          j = /\t \xs::[t] -> rhs
1745         --      in
1746         --      case (case e of ...) of
1747         --          C t xs::[t] -> j t xs
1748     let
1749         -- We make the lambdas into one-shot-lambdas.  The
1750         -- join point is sure to be applied at most once, and doing so
1751         -- prevents the body of the join point being floated out by
1752         -- the full laziness pass
1753         really_final_bndrs     = map one_shot final_bndrs'
1754         one_shot v | isId v    = setOneShotLambda v
1755                    | otherwise = v
1756         join_rhs  = mkLams really_final_bndrs rhs'
1757         join_call = mkApps (Var join_bndr) final_args
1758     in
1759     returnSmpl (unitFloat env join_bndr join_rhs, (con, bndrs', join_call))
1760 \end{code}