ghc/compiler/specialise/Rules.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[CoreRules]{Transformation rules}
   5
   6 \begin{code}
   7 module Rules (
   8         RuleBase, emptyRuleBase, mkRuleBase, extendRuleBaseList,
   9         unionRuleBase, pprRuleBase, ruleCheckProgram,
  10
  11         mkSpecInfo, extendSpecInfo, addSpecInfo,
  12         rulesOfBinds, addIdSpecialisations,
  13
  14         lookupRule, mkLocalRule, roughTopNames
  15     ) where
  16
  17 #include "HsVersions.h"
  18
  19 import CoreSyn          -- All of it
  20 import OccurAnal        ( occurAnalyseGlobalExpr )
  21 import CoreFVs          ( exprFreeVars, exprsFreeVars, rulesRhsFreeVars )
  22 import CoreUnfold       ( isCheapUnfolding, unfoldingTemplate )
  23 import CoreUtils        ( tcEqExprX )
  24 import PprCore          ( pprRules )
  25 import Type             ( Type )
  26 import TcType           ( tcSplitTyConApp_maybe )
  27 import CoreTidy         ( tidyRules )
  28 import Id               ( Id, idUnfolding, isLocalId, isGlobalId, idName,
  29                           idSpecialisation, idCoreRules, setIdSpecialisation )
  30 import IdInfo           ( SpecInfo( SpecInfo ) )
  31 import Var              ( Var )
  32 import VarEnv           ( IdEnv, TyVarEnv, InScopeSet, emptyTidyEnv,
  33                           emptyInScopeSet, mkInScopeSet, extendInScopeSetList,
  34                           emptyVarEnv, lookupVarEnv, extendVarEnv,
  35                           nukeRnEnvL, mkRnEnv2, rnOccR, rnOccL, inRnEnvR,
  36                           rnBndrR, rnBndr2, rnBndrL, rnBndrs2 )
  37 import VarSet
  38 import Name             ( Name, NamedThing(..), nameOccName )
  39 import NameEnv
  40 import Unify            ( tcMatchTyX, MatchEnv(..) )
  41 import BasicTypes       ( Activation, CompilerPhase, isActive )
  42
  43 import Outputable
  44 import FastString
  45 import Maybe            ( isJust )
  46 import Bag
  47 import List             ( isPrefixOf )
  48 \end{code}
  49
  50
  51 %************************************************************************
  52 %*                                                                      *
  53 \subsection[specialisation-IdInfo]{Specialisation info about an @Id@}
  54 %*                                                                      *
  55 %************************************************************************
  56
  57 A @CoreRule@ holds details of one rule for an @Id@, which
  58 includes its specialisations.
  59
  60 For example, if a rule for @f@ contains the mapping:
  61 \begin{verbatim}
  62         forall a b d. [Type (List a), Type b, Var d]  ===>  f' a b
  63 \end{verbatim}
  64 then when we find an application of f to matching types, we simply replace
  65 it by the matching RHS:
  66 \begin{verbatim}
  67         f (List Int) Bool dict ===>  f' Int Bool
  68 \end{verbatim}
  69 All the stuff about how many dictionaries to discard, and what types
  70 to apply the specialised function to, are handled by the fact that the
  71 Rule contains a template for the result of the specialisation.
  72
  73 There is one more exciting case, which is dealt with in exactly the same
  74 way.  If the specialised value is unboxed then it is lifted at its
  75 definition site and unlifted at its uses.  For example:
  76
  77         pi :: forall a. Num a => a
  78
  79 might have a specialisation
  80
  81         [Int#] ===>  (case pi' of Lift pi# -> pi#)
  82
  83 where pi' :: Lift Int# is the specialised version of pi.
  84
  85 \begin{code}
  86 mkLocalRule :: RuleName -> Activation
  87             -> Name -> [CoreBndr] -> [CoreExpr] -> CoreExpr -> CoreRule
  88 -- Used to make CoreRule for an Id defined in this module
  89 mkLocalRule name act fn bndrs args rhs
  90   = Rule { ru_name = name, ru_fn = fn, ru_act = act,
  91            ru_bndrs = bndrs, ru_args = args,
  92            ru_rhs = rhs, ru_rough = roughTopNames args,
  93            ru_orph = Just (nameOccName fn), ru_local = True }
  94
  95 --------------
  96 roughTopNames :: [CoreExpr] -> [Maybe Name]
  97 roughTopNames args = map roughTopName args
  98
  99 roughTopName :: CoreExpr -> Maybe Name
 100 -- Find the "top" free name of an expression
 101 -- a) the function in an App chain (if a GlobalId)
 102 -- b) the TyCon in a type
 103 -- This is used for the fast-match-check for rules;
 104 --      if the top names don't match, the rest can't
 105 roughTopName (Type ty) = case tcSplitTyConApp_maybe ty of
 106                           Just (tc,_) -> Just (getName tc)
 107                           Nothing     -> Nothing
 108 roughTopName (App f a) = roughTopName f
 109 roughTopName (Var f) | isGlobalId f = Just (idName f)
 110                      | otherwise    = Nothing
 111 roughTopName other = Nothing
 112
 113 ruleCantMatch :: [Maybe Name] -> [Maybe Name] -> Bool
 114 -- (ruleCantMatch tpl actual) returns True only if 'actual'
 115 -- definitely can't match 'tpl' by instantiating 'tpl'.
 116 -- It's only a one-way match; unlike instance matching we
 117 -- don't consider unification
 118 ruleCantMatch (Just n1 : ts) (Just n2 : as) = n1 /= n2 || ruleCantMatch ts as
 119 ruleCantMatch (Just n1 : ts) (Nothing : as) = True
 120 ruleCantMatch (t       : ts) (a       : as) = ruleCantMatch ts as
 121 ruleCantMatch ts             as             = False
 122 \end{code}
 123
 124
 125 %************************************************************************
 126 %*                                                                      *
 127                 SpecInfo: the rules in an IdInfo
 128 %*                                                                      *
 129 %************************************************************************
 130
 131 \begin{code}
 132 mkSpecInfo :: [CoreRule] -> SpecInfo
 133 mkSpecInfo rules = SpecInfo rules (rulesRhsFreeVars rules)
 134
 135 extendSpecInfo :: SpecInfo -> [CoreRule] -> SpecInfo
 136 extendSpecInfo (SpecInfo rs1 fvs1) rs2
 137   = SpecInfo (rs2 ++ rs1) (rulesRhsFreeVars rs2 `unionVarSet` fvs1)
 138
 139 addSpecInfo :: SpecInfo -> SpecInfo -> SpecInfo
 140 addSpecInfo (SpecInfo rs1 fvs1) (SpecInfo rs2 fvs2)
 141   = SpecInfo (rs1 ++ rs2) (fvs1 `unionVarSet` fvs2)
 142
 143 addIdSpecialisations :: Id -> [CoreRule] -> Id
 144 addIdSpecialisations id rules
 145   = setIdSpecialisation id $
 146     extendSpecInfo (idSpecialisation id) rules
 147
 148 rulesOfBinds :: [CoreBind] -> [CoreRule]
 149 rulesOfBinds binds = concatMap (concatMap idCoreRules . bindersOf) binds
 150 \end{code}
 151
 152
 153 %************************************************************************
 154 %*                                                                      *
 155                 RuleBase
 156 %*                                                                      *
 157 %************************************************************************
 158
 159 \begin{code}
 160 type RuleBase = NameEnv [CoreRule]
 161         -- Maps (the name of) an Id to its rules
 162         -- The rules are are unordered;
 163         -- we sort out any overlaps on lookup
 164
 165 emptyRuleBase = emptyNameEnv
 166
 167 mkRuleBase :: [CoreRule] -> RuleBase
 168 mkRuleBase rules = extendRuleBaseList emptyRuleBase rules
 169
 170 extendRuleBaseList :: RuleBase -> [CoreRule] -> RuleBase
 171 extendRuleBaseList rule_base new_guys
 172   = foldl extendRuleBase rule_base new_guys
 173
 174 unionRuleBase :: RuleBase -> RuleBase -> RuleBase
 175 unionRuleBase rb1 rb2 = plusNameEnv_C (++) rb1 rb2
 176
 177 extendRuleBase :: RuleBase -> CoreRule -> RuleBase
 178 extendRuleBase rule_base rule
 179   = extendNameEnv_C add rule_base (ruleIdName rule) [rule]
 180   where
 181     add rules _ = rule : rules
 182
 183 pprRuleBase :: RuleBase -> SDoc
 184 pprRuleBase rules = vcat [ pprRules (tidyRules emptyTidyEnv rs)
 185                          | rs <- nameEnvElts rules ]
 186 \end{code}
 187
 188
 189 %************************************************************************
 190 %*                                                                      *
 191 \subsection{Matching}
 192 %*                                                                      *
 193 %************************************************************************
 194
 195 \begin{code}
 196 lookupRule :: (Activation -> Bool) -> InScopeSet
 197            -> RuleBase  -- Imported rules
 198            -> Id -> [CoreExpr] -> Maybe (RuleName, CoreExpr)
 199 lookupRule is_active in_scope rule_base fn args
 200   = matchRules is_active in_scope fn args rules
 201   where
 202     rules | isLocalId fn = idCoreRules fn
 203           | otherwise    = case lookupNameEnv rule_base (idName fn) of
 204                                 Just rules -> rules
 205                                 Nothing    -> []
 206
 207 matchRules :: (Activation -> Bool) -> InScopeSet
 208            -> Id -> [CoreExpr]
 209            -> [CoreRule] -> Maybe (RuleName, CoreExpr)
 210 -- See comments on matchRule
 211 matchRules is_active in_scope fn args rules
 212   = case go [] rules of
 213         []     -> Nothing
 214         (m:ms) -> Just (case findBest (fn,args) m ms of
 215                           (rule, ans) -> (ru_name rule, ans))
 216   where
 217     rough_args = map roughTopName args
 218
 219     go :: [(CoreRule,CoreExpr)] -> [CoreRule] -> [(CoreRule,CoreExpr)]
 220     go ms []           = ms
 221     go ms (r:rs) = case (matchRule is_active in_scope args rough_args r) of
 222                         Just e  -> go ((r,e):ms) rs
 223                         Nothing -> go ms         rs
 224
 225 findBest :: (Id, [CoreExpr])
 226          -> (CoreRule,CoreExpr) -> [(CoreRule,CoreExpr)] -> (CoreRule,CoreExpr)
 227 -- All these pairs matched the expression
 228 -- Return the pair the the most specific rule
 229 -- The (fn,args) is just for overlap reporting
 230
 231 findBest target (rule,ans)   [] = (rule,ans)
 232 findBest target (rule1,ans1) ((rule2,ans2):prs)
 233   | rule1 `isMoreSpecific` rule2 = findBest target (rule1,ans1) prs
 234   | rule2 `isMoreSpecific` rule1 = findBest target (rule1,ans1) prs
 235 #ifdef DEBUG
 236   | otherwise = pprTrace "Rules.findBest: rule overlap (Rule 1 wins)"
 237                          (vcat [ptext SLIT("Expression to match:") <+> ppr fn <+> sep (map ppr args),
 238                                 ptext SLIT("Rule 1:") <+> ppr rule1,
 239                                 ptext SLIT("Rule 2:") <+> ppr rule2]) $
 240                 findBest target (rule1,ans1) prs
 241 #else
 242   | otherwise = findBest target (rule1,ans1) prs
 243 #endif
 244   where
 245     (fn,args) = target
 246
 247 isMoreSpecific :: CoreRule -> CoreRule -> Bool
 248 isMoreSpecific (BuiltinRule {}) r2 = True
 249 isMoreSpecific r1 (BuiltinRule {}) = False
 250 isMoreSpecific (Rule { ru_bndrs = bndrs1, ru_args = args1 })
 251                (Rule { ru_bndrs = bndrs2, ru_args = args2 })
 252   = isJust (matchN in_scope bndrs2 args2 args1)
 253   where
 254    in_scope = mkInScopeSet (mkVarSet bndrs1)
 255         -- Actually we should probably include the free vars
 256         -- of rule1's args, but I can't be bothered
 257
 258 noBlackList :: Activation -> Bool
 259 noBlackList act = False         -- Nothing is black listed
 260
 261 matchRule :: (Activation -> Bool) -> InScopeSet
 262           -> [CoreExpr] -> [Maybe Name]
 263           -> CoreRule -> Maybe CoreExpr
 264
 265 -- If (matchRule rule args) returns Just (name,rhs)
 266 -- then (f args) matches the rule, and the corresponding
 267 -- rewritten RHS is rhs
 268 --
 269 -- The bndrs and rhs is occurrence-analysed
 270 --
 271 --      Example
 272 --
 273 -- The rule
 274 --      forall f g x. map f (map g x) ==> map (f . g) x
 275 -- is stored
 276 --      CoreRule "map/map"
 277 --               [f,g,x]                -- tpl_vars
 278 --               [f,map g x]            -- tpl_args
 279 --               map (f.g) x)           -- rhs
 280 --
 281 -- Then the call: matchRule the_rule [e1,map e2 e3]
 282 --        = Just ("map/map", (\f,g,x -> rhs) e1 e2 e3)
 283 --
 284 -- Any 'surplus' arguments in the input are simply put on the end
 285 -- of the output.
 286
 287 matchRule is_active in_scope args rough_args
 288           (BuiltinRule { ru_name = name, ru_try = match_fn })
 289   = case match_fn args of
 290         Just expr -> Just expr
 291         Nothing   -> Nothing
 292
 293 matchRule is_active in_scope args rough_args
 294           (Rule { ru_name = rn, ru_act = act, ru_rough = tpl_tops,
 295                   ru_bndrs = tpl_vars, ru_args = tpl_args,
 296                   ru_rhs = rhs })
 297   | not (is_active act)               = Nothing
 298   | ruleCantMatch tpl_tops rough_args = Nothing
 299   | otherwise
 300   = case matchN in_scope tpl_vars tpl_args args of
 301         Nothing                    -> Nothing
 302         Just (tpl_vals, leftovers) -> Just (rule_fn
 303                                             `mkApps` tpl_vals
 304                                             `mkApps` leftovers)
 305   where
 306     rule_fn = occurAnalyseGlobalExpr (mkLams tpl_vars rhs)
 307         -- We could do this when putting things into the rulebase, I guess
 308 \end{code}
 309
 310 \begin{code}
 311 matchN  :: InScopeSet
 312         -> [Var]                -- Template tyvars
 313         -> [CoreExpr]           -- Template
 314         -> [CoreExpr]           -- Target; can have more elts than template
 315         -> Maybe ([CoreExpr],   -- What is substituted for each template var
 316                   [CoreExpr])   -- Leftover target exprs
 317
 318 matchN in_scope tmpl_vars tmpl_es target_es
 319   = do  { (subst, leftover_es) <- go init_menv emptySubstEnv tmpl_es target_es
 320         ; return (map (lookup_tmpl subst) tmpl_vars, leftover_es) }
 321   where
 322     init_menv = ME { me_tmpls = mkVarSet tmpl_vars, me_env = init_rn_env }
 323     init_rn_env = mkRnEnv2 (extendInScopeSetList in_scope tmpl_vars)
 324
 325     go menv subst []     es     = Just (subst, es)
 326     go menv subst ts     []     = Nothing       -- Fail if too few actual args
 327     go menv subst (t:ts) (e:es) = do { subst1 <- match menv subst t e
 328                                      ; go menv subst1 ts es }
 329
 330     lookup_tmpl :: (TvSubstEnv, IdSubstEnv) -> Var -> CoreExpr
 331     lookup_tmpl (tv_subst, id_subst) tmpl_var
 332         | isTyVar tmpl_var = case lookupVarEnv tv_subst tmpl_var of
 333                                 Just ty         -> Type ty
 334                                 Nothing         -> unbound tmpl_var
 335         | otherwise        = case lookupVarEnv id_subst tmpl_var of
 336                                 Just e -> e
 337                                 other  -> unbound tmpl_var
 338
 339     unbound var = pprPanic "Template variable unbound in rewrite rule" (ppr var)
 340 \end{code}
 341
 342
 343         ---------------------------------------------
 344                 The inner workings of matching
 345         ---------------------------------------------
 346
 347 \begin{code}
 348 -- These two definitions are not the same as in Subst,
 349 -- but they simple and direct, and purely local to this module
 350 -- The third, for TvSubstEnv, is the same as in VarEnv, but repeated here
 351 -- for uniformity with IdSubstEnv
 352 type SubstEnv   = (TvSubstEnv, IdSubstEnv)
 353 type IdSubstEnv = IdEnv    CoreExpr
 354 type TvSubstEnv = TyVarEnv Type
 355
 356 emptySubstEnv :: SubstEnv
 357 emptySubstEnv = (emptyVarEnv, emptyVarEnv)
 358
 359
 360 --      At one stage I tried to match even if there are more
 361 --      template args than real args.
 362
 363 --      I now think this is probably a bad idea.
 364 --      Should the template (map f xs) match (map g)?  I think not.
 365 --      For a start, in general eta expansion wastes work.
 366 --      SLPJ July 99
 367
 368
 369 match :: MatchEnv
 370       -> SubstEnv
 371       -> CoreExpr               -- Template
 372       -> CoreExpr               -- Target
 373       -> Maybe SubstEnv
 374
 375 -- See the notes with Unify.match, which matches types
 376 -- Everything is very similar for terms
 377
 378 -- Interesting examples:
 379 -- Consider matching
 380 --      \x->f      against    \f->f
 381 -- When we meet the lambdas we must remember to rename f to f' in the
 382 -- second expresion.  The RnEnv2 does that.
 383 --
 384 -- Consider matching
 385 --      forall a. \b->b    against   \a->3
 386 -- We must rename the \a.  Otherwise when we meet the lambdas we
 387 -- might substitute [a/b] in the template, and then erroneously
 388 -- succeed in matching what looks like the template variable 'a' against 3.
 389
 390 -- The Var case follows closely what happens in Unify.match
 391 match menv subst@(tv_subst, id_subst) (Var v1) e2
 392   | v1 `elemVarSet` me_tmpls menv
 393   = case lookupVarEnv id_subst v1' of
 394         Nothing | any (inRnEnvR rn_env) (varSetElems (exprFreeVars e2))
 395                 -> Nothing      -- Occurs check failure
 396                 -- e.g. match forall a. (\x-> a x) against (\y. y y)
 397
 398                 | otherwise
 399                 -> Just (tv_subst, extendVarEnv id_subst v1 e2)
 400
 401         Just e2' | tcEqExprX (nukeRnEnvL rn_env) e2' e2
 402                  -> Just subst
 403
 404         other -> Nothing
 405
 406   | otherwise   -- v1 is not a template variable
 407   = case e2 of
 408         Var v2 | v1' == rnOccR rn_env v2 -> Just subst
 409         other                            -> Nothing
 410   where
 411     rn_env = me_env menv
 412     v1'    = rnOccL rn_env v1
 413
 414 -- Here is another important rule: if the term being matched is a
 415 -- variable, we expand it so long as its unfolding is a WHNF
 416 -- (Its occurrence information is not necessarily up to date,
 417 --  so we don't use it.)
 418 match menv subst e1 (Var v2)
 419   | isCheapUnfolding unfolding
 420   = match menv subst e1 (unfoldingTemplate unfolding)
 421   where
 422     unfolding = idUnfolding v2
 423
 424 match menv subst (Lit lit1) (Lit lit2)
 425   | lit1 == lit2
 426   = Just subst
 427
 428 match menv subst (App f1 a1) (App f2 a2)
 429   = do  { subst' <- match menv subst f1 f2
 430         ; match menv subst' a1 a2 }
 431
 432 match menv subst (Lam x1 e1) (Lam x2 e2)
 433   = match menv' subst e1 e2
 434   where
 435     menv' = menv { me_env = rnBndr2 (me_env menv) x1 x2 }
 436
 437 -- This rule does eta expansion
 438 --              (\x.M)  ~  N    iff     M  ~  N x
 439 match menv subst (Lam x1 e1) e2
 440   = match menv' subst e1 (App e2 (varToCoreExpr new_x))
 441   where
 442     (rn_env', new_x) = rnBndrL (me_env menv) x1
 443     menv' = menv { me_env = rn_env' }
 444
 445 -- Eta expansion the other way
 446 --      M  ~  (\y.N)    iff   M y     ~  N
 447 match menv subst e1 (Lam x2 e2)
 448   = match menv' subst (App e1 (varToCoreExpr new_x)) e2
 449   where
 450     (rn_env', new_x) = rnBndrR (me_env menv) x2
 451     menv' = menv { me_env = rn_env' }
 452
 453 match menv subst (Case e1 x1 ty1 alts1) (Case e2 x2 ty2 alts2)
 454   = do  { subst1 <- match_ty menv subst ty1 ty2
 455         ; subst2 <- match menv subst1 e1 e2
 456         ; let menv' = menv { me_env = rnBndr2 (me_env menv) x2 x2 }
 457         ; match_alts menv' subst2 alts1 alts2   -- Alts are both sorted
 458         }
 459
 460 match menv subst (Type ty1) (Type ty2)
 461   = match_ty menv subst ty1 ty2
 462
 463 match menv subst (Note (Coerce to1 from1) e1) (Note (Coerce to2 from2) e2)
 464   = do  { subst1 <- match_ty menv subst  to1   to2
 465         ; subst2 <- match_ty menv subst1 from1 from2
 466         ; match menv subst2 e1 e2 }
 467
 468 -- This is an interesting rule: we simply ignore lets in the
 469 -- term being matched against!  The unfolding inside it is (by assumption)
 470 -- already inside any occurrences of the bound variables, so we'll expand
 471 -- them when we encounter them.
 472 match menv subst e1 (Let (NonRec x2 r2) e2)
 473   = match menv' subst e1 e2
 474   where
 475     menv' = menv { me_env = fst (rnBndrR (me_env menv) x2) }
 476         -- It's important to do this renaming. For example:
 477         -- Matching
 478         --      forall f,x,xs. f (x:xs)
 479         --   against
 480         --      f (let y = e in (y:[]))
 481         -- We must not get success with x->y!  Instead, we
 482         -- need an occurs check.
 483
 484 -- Everything else fails
 485 match menv subst e1 e2 = Nothing
 486
 487 ------------------------------------------
 488 match_alts :: MatchEnv
 489       -> SubstEnv
 490       -> [CoreAlt]              -- Template
 491       -> [CoreAlt]              -- Target
 492       -> Maybe SubstEnv
 493 match_alts menv subst [] []
 494   = return subst
 495 match_alts menv subst ((c1,vs1,r1):alts1) ((c2,vs2,r2):alts2)
 496   | c1 == c2
 497   = do  { subst1 <- match menv' subst r1 r2
 498         ; match_alts menv subst1 alts1 alts2 }
 499   where
 500     menv' :: MatchEnv
 501     menv' = menv { me_env = rnBndrs2 (me_env menv) vs1 vs2 }
 502
 503 match_alts menv subst alts1 alts2
 504   = Nothing
 505 \end{code}
 506
 507 Matching Core types: use the matcher in TcType.
 508 Notice that we treat newtypes as opaque.  For example, suppose
 509 we have a specialised version of a function at a newtype, say
 510         newtype T = MkT Int
 511 We only want to replace (f T) with f', not (f Int).
 512
 513 \begin{code}
 514 ------------------------------------------
 515 match_ty menv (tv_subst, id_subst) ty1 ty2
 516   = do  { tv_subst' <- Unify.tcMatchTyX menv tv_subst ty1 ty2
 517         ; return (tv_subst', id_subst) }
 518 \end{code}
 519
 520
 521 %************************************************************************
 522 %*                                                                      *
 523 \subsection{Checking a program for failing rule applications}
 524 %*                                                                      *
 525 %************************************************************************
 526
 527 -----------------------------------------------------
 528                         Game plan
 529 -----------------------------------------------------
 530
 531 We want to know what sites have rules that could have fired but didn't.
 532 This pass runs over the tree (without changing it) and reports such.
 533
 534 NB: we assume that this follows a run of the simplifier, so every Id
 535 occurrence (including occurrences of imported Ids) is decorated with
 536 all its (active) rules.  No need to construct a rule base or anything
 537 like that.
 538
 539 \begin{code}
 540 ruleCheckProgram :: CompilerPhase -> String -> [CoreBind] -> SDoc
 541 -- Report partial matches for rules beginning
 542 -- with the specified string
 543 ruleCheckProgram phase rule_pat binds
 544   | isEmptyBag results
 545   = text "Rule check results: no rule application sites"
 546   | otherwise
 547   = vcat [text "Rule check results:",
 548           line,
 549           vcat [ p $$ line | p <- bagToList results ]
 550          ]
 551   where
 552     results = unionManyBags (map (ruleCheckBind (phase, rule_pat)) binds)
 553     line = text (replicate 20 '-')
 554
 555 type RuleCheckEnv = (CompilerPhase, String)     -- Phase and Pattern
 556
 557 ruleCheckBind :: RuleCheckEnv -> CoreBind -> Bag SDoc
 558    -- The Bag returned has one SDoc for each call site found
 559 ruleCheckBind env (NonRec b r) = ruleCheck env r
 560 ruleCheckBind env (Rec prs)    = unionManyBags [ruleCheck env r | (b,r) <- prs]
 561
 562 ruleCheck :: RuleCheckEnv -> CoreExpr -> Bag SDoc
 563 ruleCheck env (Var v)       = emptyBag
 564 ruleCheck env (Lit l)       = emptyBag
 565 ruleCheck env (Type ty)     = emptyBag
 566 ruleCheck env (App f a)     = ruleCheckApp env (App f a) []
 567 ruleCheck env (Note n e)    = ruleCheck env e
 568 ruleCheck env (Let bd e)    = ruleCheckBind env bd `unionBags` ruleCheck env e
 569 ruleCheck env (Lam b e)     = ruleCheck env e
 570 ruleCheck env (Case e _ _ as) = ruleCheck env e `unionBags`
 571                                 unionManyBags [ruleCheck env r | (_,_,r) <- as]
 572
 573 ruleCheckApp env (App f a) as = ruleCheck env a `unionBags` ruleCheckApp env f (a:as)
 574 ruleCheckApp env (Var f) as   = ruleCheckFun env f as
 575 ruleCheckApp env other as     = ruleCheck env other
 576 \end{code}
 577
 578 \begin{code}
 579 ruleCheckFun :: RuleCheckEnv -> Id -> [CoreExpr] -> Bag SDoc
 580 -- Produce a report for all rules matching the predicate
 581 -- saying why it doesn't match the specified application
 582
 583 ruleCheckFun (phase, pat) fn args
 584   | null name_match_rules = emptyBag
 585   | otherwise             = unitBag (ruleAppCheck_help phase fn args name_match_rules)
 586   where
 587     name_match_rules = filter match (idCoreRules fn)
 588     match rule = pat `isPrefixOf` unpackFS (ruleName rule)
 589
 590 ruleAppCheck_help :: CompilerPhase -> Id -> [CoreExpr] -> [CoreRule] -> SDoc
 591 ruleAppCheck_help phase fn args rules
 592   =     -- The rules match the pattern, so we want to print something
 593     vcat [text "Expression:" <+> ppr (mkApps (Var fn) args),
 594           vcat (map check_rule rules)]
 595   where
 596     n_args = length args
 597     i_args = args `zip` [1::Int ..]
 598     rough_args = map roughTopName args
 599
 600     check_rule rule = rule_herald rule <> colon <+> rule_info rule
 601
 602     rule_herald (BuiltinRule { ru_name = name })
 603         = ptext SLIT("Builtin rule") <+> doubleQuotes (ftext name)
 604     rule_herald (Rule { ru_name = name })
 605         = ptext SLIT("Rule") <+> doubleQuotes (ftext name)
 606
 607     rule_info rule
 608         | Just _ <- matchRule noBlackList emptyInScopeSet args rough_args rule
 609         = text "matches (which is very peculiar!)"
 610
 611     rule_info (BuiltinRule {}) = text "does not match"
 612
 613     rule_info (Rule { ru_name = name, ru_act = act,
 614                       ru_bndrs = rule_bndrs, ru_args = rule_args})
 615         | not (isActive phase act)    = text "active only in later phase"
 616         | n_args < n_rule_args        = text "too few arguments"
 617         | n_mismatches == n_rule_args = text "no arguments match"
 618         | n_mismatches == 0           = text "all arguments match (considered individually), but rule as a whole does not"
 619         | otherwise                   = text "arguments" <+> ppr mismatches <+> text "do not match (1-indexing)"
 620         where
 621           n_rule_args  = length rule_args
 622           n_mismatches = length mismatches
 623           mismatches   = [i | (rule_arg, (arg,i)) <- rule_args `zip` i_args,
 624                               not (isJust (match_fn rule_arg arg))]
 625
 626           lhs_fvs = exprsFreeVars rule_args     -- Includes template tyvars
 627           match_fn rule_arg arg = match menv emptySubstEnv rule_arg arg
 628                 where
 629                   in_scope = lhs_fvs `unionVarSet` exprFreeVars arg
 630                   menv = ME { me_env   = mkRnEnv2 (mkInScopeSet in_scope)
 631                             , me_tmpls = mkVarSet rule_bndrs }
 632 \end{code}
 633