ghc/compiler/stgSyn/CoreToStg.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[CoreToStg]{Converts Core to STG Syntax}
   5
   6 And, as we have the info in hand, we may convert some lets to
   7 let-no-escapes.
   8
   9 \begin{code}
  10 module CoreToStg ( coreToStg, coreExprToStg ) where
  11
  12 #include "HsVersions.h"
  13
  14 import CoreSyn
  15 import CoreUtils        ( rhsIsStatic, manifestArity, exprType )
  16 import StgSyn
  17
  18 import Type
  19 import TyCon            ( isAlgTyCon )
  20 import Id
  21 import Var              ( Var, globalIdDetails, idType )
  22 import TyCon            ( isUnboxedTupleTyCon, isPrimTyCon, isFunTyCon, isHiBootTyCon )
  23 #ifdef ILX
  24 import MkId             ( unsafeCoerceId )
  25 #endif
  26 import IdInfo
  27 import DataCon
  28 import CostCentre       ( noCCS )
  29 import VarSet
  30 import VarEnv
  31 import Maybes           ( maybeToBool )
  32 import Name             ( getOccName, isExternalName, nameOccName )
  33 import OccName          ( occNameUserString, occNameFS )
  34 import BasicTypes       ( Arity )
  35 import DynFlags         ( DynFlags )
  36 import StaticFlags      ( opt_RuntimeTypes )
  37 import Outputable
  38
  39 infixr 9 `thenLne`
  40 \end{code}
  41
  42 %************************************************************************
  43 %*                                                                      *
  44 \subsection[live-vs-free-doc]{Documentation}
  45 %*                                                                      *
  46 %************************************************************************
  47
  48 (There is other relevant documentation in codeGen/CgLetNoEscape.)
  49
  50 The actual Stg datatype is decorated with {\em live variable}
  51 information, as well as {\em free variable} information.  The two are
  52 {\em not} the same.  Liveness is an operational property rather than a
  53 semantic one.  A variable is live at a particular execution point if
  54 it can be referred to {\em directly} again.  In particular, a dead
  55 variable's stack slot (if it has one):
  56 \begin{enumerate}
  57 \item
  58 should be stubbed to avoid space leaks, and
  59 \item
  60 may be reused for something else.
  61 \end{enumerate}
  62
  63 There ought to be a better way to say this.  Here are some examples:
  64 \begin{verbatim}
  65         let v = [q] \[x] -> e
  66         in
  67         ...v...  (but no q's)
  68 \end{verbatim}
  69
  70 Just after the `in', v is live, but q is dead.  If the whole of that
  71 let expression was enclosed in a case expression, thus:
  72 \begin{verbatim}
  73         case (let v = [q] \[x] -> e in ...v...) of
  74                 alts[...q...]
  75 \end{verbatim}
  76 (ie @alts@ mention @q@), then @q@ is live even after the `in'; because
  77 we'll return later to the @alts@ and need it.
  78
  79 Let-no-escapes make this a bit more interesting:
  80 \begin{verbatim}
  81         let-no-escape v = [q] \ [x] -> e
  82         in
  83         ...v...
  84 \end{verbatim}
  85 Here, @q@ is still live at the `in', because @v@ is represented not by
  86 a closure but by the current stack state.  In other words, if @v@ is
  87 live then so is @q@.  Furthermore, if @e@ mentions an enclosing
  88 let-no-escaped variable, then {\em its} free variables are also live
  89 if @v@ is.
  90
  91 %************************************************************************
  92 %*                                                                      *
  93 \subsection[caf-info]{Collecting live CAF info}
  94 %*                                                                      *
  95 %************************************************************************
  96
  97 In this pass we also collect information on which CAFs are live for
  98 constructing SRTs (see SRT.lhs).
  99
 100 A top-level Id has CafInfo, which is
 101
 102         - MayHaveCafRefs, if it may refer indirectly to
 103           one or more CAFs, or
 104         - NoCafRefs if it definitely doesn't
 105
 106 The CafInfo has already been calculated during the CoreTidy pass.
 107
 108 During CoreToStg, we then pin onto each binding and case expression, a
 109 list of Ids which represents the "live" CAFs at that point.  The meaning
 110 of "live" here is the same as for live variables, see above (which is
 111 why it's convenient to collect CAF information here rather than elsewhere).
 112
 113 The later SRT pass takes these lists of Ids and uses them to construct
 114 the actual nested SRTs, and replaces the lists of Ids with (offset,length)
 115 pairs.
 116
 117
 118 Interaction of let-no-escape with SRTs   [Sept 01]
 119 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 120 Consider
 121
 122         let-no-escape x = ...caf1...caf2...
 123         in
 124         ...x...x...x...
 125
 126 where caf1,caf2 are CAFs.  Since x doesn't have a closure, we
 127 build SRTs just as if x's defn was inlined at each call site, and
 128 that means that x's CAF refs get duplicated in the overall SRT.
 129
 130 This is unlike ordinary lets, in which the CAF refs are not duplicated.
 131
 132 We could fix this loss of (static) sharing by making a sort of pseudo-closure
 133 for x, solely to put in the SRTs lower down.
 134
 135
 136 %************************************************************************
 137 %*                                                                      *
 138 \subsection[binds-StgVarInfo]{Setting variable info: top-level, binds, RHSs}
 139 %*                                                                      *
 140 %************************************************************************
 141
 142 \begin{code}
 143 coreToStg :: DynFlags -> [CoreBind] -> IO [StgBinding]
 144 coreToStg dflags pgm
 145   = return pgm'
 146   where (_, _, pgm') = coreTopBindsToStg dflags emptyVarEnv pgm
 147
 148 coreExprToStg :: CoreExpr -> StgExpr
 149 coreExprToStg expr
 150   = new_expr where (new_expr,_,_) = initLne emptyVarEnv (coreToStgExpr expr)
 151
 152
 153 coreTopBindsToStg
 154     :: DynFlags
 155     -> IdEnv HowBound           -- environment for the bindings
 156     -> [CoreBind]
 157     -> (IdEnv HowBound, FreeVarsInfo, [StgBinding])
 158
 159 coreTopBindsToStg dflags env [] = (env, emptyFVInfo, [])
 160 coreTopBindsToStg dflags env (b:bs)
 161   = (env2, fvs2, b':bs')
 162   where
 163         -- env accumulates down the list of binds, fvs accumulates upwards
 164         (env1, fvs2, b' ) = coreTopBindToStg dflags env fvs1 b
 165         (env2, fvs1, bs') = coreTopBindsToStg dflags env1 bs
 166
 167
 168 coreTopBindToStg
 169         :: DynFlags
 170         -> IdEnv HowBound
 171         -> FreeVarsInfo         -- Info about the body
 172         -> CoreBind
 173         -> (IdEnv HowBound, FreeVarsInfo, StgBinding)
 174
 175 coreTopBindToStg dflags env body_fvs (NonRec id rhs)
 176   = let
 177         env'      = extendVarEnv env id how_bound
 178         how_bound = LetBound TopLet (manifestArity rhs)
 179
 180         (stg_rhs, fvs') =
 181             initLne env (
 182               coreToTopStgRhs dflags body_fvs (id,rhs)  `thenLne` \ (stg_rhs, fvs') ->
 183               returnLne (stg_rhs, fvs')
 184            )
 185
 186         bind = StgNonRec id stg_rhs
 187     in
 188     ASSERT2(manifestArity rhs == stgRhsArity stg_rhs, ppr id)
 189     ASSERT2(consistentCafInfo id bind, ppr id)
 190 --    WARN(not (consistent caf_info bind), ppr id <+> ppr cafs <+> ppCafInfo caf_info)
 191     (env', fvs' `unionFVInfo` body_fvs, bind)
 192
 193 coreTopBindToStg dflags env body_fvs (Rec pairs)
 194   = let
 195         (binders, rhss) = unzip pairs
 196
 197         extra_env' = [ (b, LetBound TopLet (manifestArity rhs))
 198                      | (b, rhs) <- pairs ]
 199         env' = extendVarEnvList env extra_env'
 200
 201         (stg_rhss, fvs')
 202           = initLne env' (
 203                mapAndUnzipLne (coreToTopStgRhs dflags body_fvs) pairs
 204                                                 `thenLne` \ (stg_rhss, fvss') ->
 205                let fvs' = unionFVInfos fvss' in
 206                returnLne (stg_rhss, fvs')
 207            )
 208
 209         bind = StgRec (zip binders stg_rhss)
 210     in
 211     ASSERT2(and [manifestArity rhs == stgRhsArity stg_rhs | (rhs,stg_rhs) <- rhss `zip` stg_rhss], ppr binders)
 212     ASSERT2(consistentCafInfo (head binders) bind, ppr binders)
 213     (env', fvs' `unionFVInfo` body_fvs, bind)
 214
 215 #ifdef DEBUG
 216 -- Assertion helper: this checks that the CafInfo on the Id matches
 217 -- what CoreToStg has figured out about the binding's SRT.  The
 218 -- CafInfo will be exact in all cases except when CorePrep has
 219 -- floated out a binding, in which case it will be approximate.
 220 consistentCafInfo id bind
 221   | occNameFS (nameOccName (idName id)) == FSLIT("sat")
 222   = safe
 223   | otherwise
 224   = WARN (not exact, ppr id) safe
 225   where
 226         safe  = id_marked_caffy || not binding_is_caffy
 227         exact = id_marked_caffy == binding_is_caffy
 228         id_marked_caffy  = mayHaveCafRefs (idCafInfo id)
 229         binding_is_caffy = stgBindHasCafRefs bind
 230 #endif
 231 \end{code}
 232
 233 \begin{code}
 234 coreToTopStgRhs
 235         :: DynFlags
 236         -> FreeVarsInfo         -- Free var info for the scope of the binding
 237         -> (Id,CoreExpr)
 238         -> LneM (StgRhs, FreeVarsInfo)
 239
 240 coreToTopStgRhs dflags scope_fv_info (bndr, rhs)
 241   = coreToStgExpr rhs           `thenLne` \ (new_rhs, rhs_fvs, _) ->
 242     freeVarsToLiveVars rhs_fvs  `thenLne` \ lv_info ->
 243     returnLne (mkTopStgRhs is_static rhs_fvs (mkSRT lv_info) bndr_info new_rhs, rhs_fvs)
 244   where
 245     bndr_info = lookupFVInfo scope_fv_info bndr
 246     is_static = rhsIsStatic dflags rhs
 247
 248 mkTopStgRhs :: Bool -> FreeVarsInfo -> SRT -> StgBinderInfo -> StgExpr
 249         -> StgRhs
 250
 251 mkTopStgRhs is_static rhs_fvs srt binder_info (StgLam _ bndrs body)
 252   = ASSERT( is_static )
 253     StgRhsClosure noCCS binder_info
 254                   (getFVs rhs_fvs)
 255                   ReEntrant
 256                   srt
 257                   bndrs body
 258
 259 mkTopStgRhs is_static rhs_fvs srt binder_info (StgConApp con args)
 260   | is_static    -- StgConApps can be updatable (see isCrossDllConApp)
 261   = StgRhsCon noCCS con args
 262
 263 mkTopStgRhs is_static rhs_fvs srt binder_info rhs
 264   = ASSERT2( not is_static, ppr rhs )
 265     StgRhsClosure noCCS binder_info
 266                   (getFVs rhs_fvs)
 267                   Updatable
 268                   srt
 269                   [] rhs
 270 \end{code}
 271
 272
 273 -- ---------------------------------------------------------------------------
 274 -- Expressions
 275 -- ---------------------------------------------------------------------------
 276
 277 \begin{code}
 278 coreToStgExpr
 279         :: CoreExpr
 280         -> LneM (StgExpr,       -- Decorated STG expr
 281                  FreeVarsInfo,  -- Its free vars (NB free, not live)
 282                  EscVarsSet)    -- Its escapees, a subset of its free vars;
 283                                 -- also a subset of the domain of the envt
 284                                 -- because we are only interested in the escapees
 285                                 -- for vars which might be turned into
 286                                 -- let-no-escaped ones.
 287 \end{code}
 288
 289 The second and third components can be derived in a simple bottom up pass, not
 290 dependent on any decisions about which variables will be let-no-escaped or
 291 not.  The first component, that is, the decorated expression, may then depend
 292 on these components, but it in turn is not scrutinised as the basis for any
 293 decisions.  Hence no black holes.
 294
 295 \begin{code}
 296 coreToStgExpr (Lit l) = returnLne (StgLit l, emptyFVInfo, emptyVarSet)
 297 coreToStgExpr (Var v) = coreToStgApp Nothing v []
 298
 299 coreToStgExpr expr@(App _ _)
 300   = coreToStgApp Nothing f args
 301   where
 302     (f, args) = myCollectArgs expr
 303
 304 coreToStgExpr expr@(Lam _ _)
 305   = let
 306         (args, body) = myCollectBinders expr
 307         args'        = filterStgBinders args
 308     in
 309     extendVarEnvLne [ (a, LambdaBound) | a <- args' ] $
 310     coreToStgExpr body  `thenLne` \ (body, body_fvs, body_escs) ->
 311     let
 312         fvs             = args' `minusFVBinders` body_fvs
 313         escs            = body_escs `delVarSetList` args'
 314         result_expr | null args' = body
 315                     | otherwise  = StgLam (exprType expr) args' body
 316     in
 317     returnLne (result_expr, fvs, escs)
 318
 319 coreToStgExpr (Note (SCC cc) expr)
 320   = coreToStgExpr expr          `thenLne` ( \ (expr2, fvs, escs) ->
 321     returnLne (StgSCC cc expr2, fvs, escs) )
 322
 323 #ifdef ILX
 324 -- For ILX, convert (__coerce__ to_ty from_ty e)
 325 --          into    (coerce to_ty from_ty e)
 326 -- where coerce is real function
 327 coreToStgExpr (Note (Coerce to_ty from_ty) expr)
 328   = coreToStgExpr (mkApps (Var unsafeCoerceId)
 329                           [Type from_ty, Type to_ty, expr])
 330 #endif
 331
 332 coreToStgExpr (Note other_note expr)
 333   = coreToStgExpr expr
 334
 335 -- Cases require a little more real work.
 336
 337 coreToStgExpr (Case scrut bndr _ alts)
 338   = extendVarEnvLne [(bndr, LambdaBound)]       (
 339          mapAndUnzip3Lne vars_alt alts  `thenLne` \ (alts2, fvs_s, escs_s) ->
 340          returnLne ( alts2,
 341                      unionFVInfos fvs_s,
 342                      unionVarSets escs_s )
 343     )                                   `thenLne` \ (alts2, alts_fvs, alts_escs) ->
 344     let
 345         -- Determine whether the default binder is dead or not
 346         -- This helps the code generator to avoid generating an assignment
 347         -- for the case binder (is extremely rare cases) ToDo: remove.
 348         bndr' | bndr `elementOfFVInfo` alts_fvs = bndr
 349               | otherwise                       = bndr `setIdOccInfo` IAmDead
 350
 351         -- Don't consider the default binder as being 'live in alts',
 352         -- since this is from the point of view of the case expr, where
 353         -- the default binder is not free.
 354         alts_fvs_wo_bndr  = bndr `minusFVBinder` alts_fvs
 355         alts_escs_wo_bndr = alts_escs `delVarSet` bndr
 356     in
 357
 358     freeVarsToLiveVars alts_fvs_wo_bndr         `thenLne` \ alts_lv_info ->
 359
 360         -- We tell the scrutinee that everything
 361         -- live in the alts is live in it, too.
 362     setVarsLiveInCont alts_lv_info (
 363         coreToStgExpr scrut       `thenLne` \ (scrut2, scrut_fvs, scrut_escs) ->
 364         freeVarsToLiveVars scrut_fvs `thenLne` \ scrut_lv_info ->
 365         returnLne (scrut2, scrut_fvs, scrut_escs, scrut_lv_info)
 366       )
 367                 `thenLne` \ (scrut2, scrut_fvs, scrut_escs, scrut_lv_info) ->
 368
 369     returnLne (
 370       StgCase scrut2 (getLiveVars scrut_lv_info)
 371                      (getLiveVars alts_lv_info)
 372                      bndr'
 373                      (mkSRT alts_lv_info)
 374                      (mkStgAltType (idType bndr))
 375                      alts2,
 376       scrut_fvs `unionFVInfo` alts_fvs_wo_bndr,
 377       alts_escs_wo_bndr `unionVarSet` getFVSet scrut_fvs
 378                 -- You might think we should have scrut_escs, not
 379                 -- (getFVSet scrut_fvs), but actually we can't call, and
 380                 -- then return from, a let-no-escape thing.
 381       )
 382   where
 383     vars_alt (con, binders, rhs)
 384       = let     -- Remove type variables
 385             binders' = filterStgBinders binders
 386         in
 387         extendVarEnvLne [(b, LambdaBound) | b <- binders']      $
 388         coreToStgExpr rhs       `thenLne` \ (rhs2, rhs_fvs, rhs_escs) ->
 389         let
 390                 -- Records whether each param is used in the RHS
 391             good_use_mask = [ b `elementOfFVInfo` rhs_fvs | b <- binders' ]
 392         in
 393         returnLne ( (con, binders', good_use_mask, rhs2),
 394                     binders' `minusFVBinders` rhs_fvs,
 395                     rhs_escs `delVarSetList` binders' )
 396                 -- ToDo: remove the delVarSet;
 397                 -- since escs won't include any of these binders
 398 \end{code}
 399
 400 Lets not only take quite a bit of work, but this is where we convert
 401 then to let-no-escapes, if we wish.
 402
 403 (Meanwhile, we don't expect to see let-no-escapes...)
 404 \begin{code}
 405 coreToStgExpr (Let bind body)
 406   = fixLne (\ ~(_, _, _, no_binder_escapes) ->
 407         coreToStgLet no_binder_escapes bind body
 408     )                           `thenLne` \ (new_let, fvs, escs, _) ->
 409
 410     returnLne (new_let, fvs, escs)
 411 \end{code}
 412
 413 \begin{code}
 414 mkStgAltType scrut_ty
 415   = case splitTyConApp_maybe (repType scrut_ty) of
 416         Just (tc,_) | isUnboxedTupleTyCon tc -> UbxTupAlt tc
 417                     | isPrimTyCon tc         -> PrimAlt tc
 418                     | isHiBootTyCon tc       -> PolyAlt -- Algebraic, but no constructors visible
 419                     | isAlgTyCon tc          -> AlgAlt tc
 420                     | isFunTyCon tc          -> PolyAlt
 421                     | otherwise              -> pprPanic "mkStgAlts" (ppr tc)
 422         Nothing                              -> PolyAlt
 423 \end{code}
 424
 425
 426 -- ---------------------------------------------------------------------------
 427 -- Applications
 428 -- ---------------------------------------------------------------------------
 429
 430 \begin{code}
 431 coreToStgApp
 432          :: Maybe UpdateFlag            -- Just upd <=> this application is
 433                                         -- the rhs of a thunk binding
 434                                         --      x = [...] \upd [] -> the_app
 435                                         -- with specified update flag
 436         -> Id                           -- Function
 437         -> [CoreArg]                    -- Arguments
 438         -> LneM (StgExpr, FreeVarsInfo, EscVarsSet)
 439
 440 coreToStgApp maybe_thunk_body f args
 441   = coreToStgArgs args          `thenLne` \ (args', args_fvs) ->
 442     lookupVarLne f              `thenLne` \ how_bound ->
 443
 444     let
 445         n_val_args       = valArgCount args
 446         not_letrec_bound = not (isLetBound how_bound)
 447         fun_fvs
 448           = let fvs = singletonFVInfo f how_bound fun_occ in
 449             -- e.g. (f :: a -> int) (x :: a)
 450             -- Here the free variables are "f", "x" AND the type variable "a"
 451             -- coreToStgArgs will deal with the arguments recursively
 452             if opt_RuntimeTypes then
 453               fvs `unionFVInfo` tyvarFVInfo (tyVarsOfType (idType f))
 454             else fvs
 455
 456         -- Mostly, the arity info of a function is in the fn's IdInfo
 457         -- But new bindings introduced by CoreSat may not have no
 458         -- arity info; it would do us no good anyway.  For example:
 459         --      let f = \ab -> e in f
 460         -- No point in having correct arity info for f!
 461         -- Hence the hasArity stuff below.
 462         -- NB: f_arity is only consulted for LetBound things
 463         f_arity   = stgArity f how_bound
 464         saturated = f_arity <= n_val_args
 465
 466         fun_occ
 467          | not_letrec_bound         = noBinderInfo      -- Uninteresting variable
 468          | f_arity > 0 && saturated = stgSatOcc -- Saturated or over-saturated function call
 469          | otherwise                = stgUnsatOcc       -- Unsaturated function or thunk
 470
 471         fun_escs
 472          | not_letrec_bound      = emptyVarSet  -- Only letrec-bound escapees are interesting
 473          | f_arity == n_val_args = emptyVarSet  -- A function *or thunk* with an exactly
 474                                                 -- saturated call doesn't escape
 475                                                 -- (let-no-escape applies to 'thunks' too)
 476
 477          | otherwise         = unitVarSet f     -- Inexact application; it does escape
 478
 479         -- At the moment of the call:
 480
 481         --  either the function is *not* let-no-escaped, in which case
 482         --         nothing is live except live_in_cont
 483         --      or the function *is* let-no-escaped in which case the
 484         --         variables it uses are live, but still the function
 485         --         itself is not.  PS.  In this case, the function's
 486         --         live vars should already include those of the
 487         --         continuation, but it does no harm to just union the
 488         --         two regardless.
 489
 490         res_ty = exprType (mkApps (Var f) args)
 491         app = case globalIdDetails f of
 492                 DataConWorkId dc | saturated -> StgConApp dc args'
 493                 PrimOpId op                  -> ASSERT( saturated )
 494                                                 StgOpApp (StgPrimOp op) args' res_ty
 495                 FCallId call     -> ASSERT( saturated )
 496                                     StgOpApp (StgFCallOp call (idUnique f)) args' res_ty
 497                 _other           -> StgApp f args'
 498
 499     in
 500     returnLne (
 501         app,
 502         fun_fvs  `unionFVInfo` args_fvs,
 503         fun_escs `unionVarSet` (getFVSet args_fvs)
 504                                 -- All the free vars of the args are disqualified
 505                                 -- from being let-no-escaped.
 506     )
 507
 508
 509
 510 -- ---------------------------------------------------------------------------
 511 -- Argument lists
 512 -- This is the guy that turns applications into A-normal form
 513 -- ---------------------------------------------------------------------------
 514
 515 coreToStgArgs :: [CoreArg] -> LneM ([StgArg], FreeVarsInfo)
 516 coreToStgArgs []
 517   = returnLne ([], emptyFVInfo)
 518
 519 coreToStgArgs (Type ty : args)  -- Type argument
 520   = coreToStgArgs args  `thenLne` \ (args', fvs) ->
 521     if opt_RuntimeTypes then
 522         returnLne (StgTypeArg ty : args', fvs `unionFVInfo` tyvarFVInfo (tyVarsOfType ty))
 523     else
 524     returnLne (args', fvs)
 525
 526 coreToStgArgs (arg : args)      -- Non-type argument
 527   = coreToStgArgs args  `thenLne` \ (stg_args, args_fvs) ->
 528     coreToStgExpr arg   `thenLne` \ (arg', arg_fvs, escs) ->
 529     let
 530         fvs = args_fvs `unionFVInfo` arg_fvs
 531         stg_arg = case arg' of
 532                        StgApp v []      -> StgVarArg v
 533                        StgConApp con [] -> StgVarArg (dataConWorkId con)
 534                        StgLit lit       -> StgLitArg lit
 535                        _                -> pprPanic "coreToStgArgs" (ppr arg)
 536     in
 537     returnLne (stg_arg : stg_args, fvs)
 538
 539
 540 -- ---------------------------------------------------------------------------
 541 -- The magic for lets:
 542 -- ---------------------------------------------------------------------------
 543
 544 coreToStgLet
 545          :: Bool        -- True <=> yes, we are let-no-escaping this let
 546          -> CoreBind    -- bindings
 547          -> CoreExpr    -- body
 548          -> LneM (StgExpr,      -- new let
 549                   FreeVarsInfo, -- variables free in the whole let
 550                   EscVarsSet,   -- variables that escape from the whole let
 551                   Bool)         -- True <=> none of the binders in the bindings
 552                                 -- is among the escaping vars
 553
 554 coreToStgLet let_no_escape bind body
 555   = fixLne (\ ~(_, _, _, _, _, rec_body_fvs, _, _) ->
 556
 557         -- Do the bindings, setting live_in_cont to empty if
 558         -- we ain't in a let-no-escape world
 559         getVarsLiveInCont               `thenLne` \ live_in_cont ->
 560         setVarsLiveInCont (if let_no_escape
 561                                 then live_in_cont
 562                                 else emptyLiveInfo)
 563                           (vars_bind rec_body_fvs bind)
 564             `thenLne` \ ( bind2, bind_fvs, bind_escs, bind_lv_info, env_ext) ->
 565
 566         -- Do the body
 567         extendVarEnvLne env_ext (
 568           coreToStgExpr body          `thenLne` \(body2, body_fvs, body_escs) ->
 569           freeVarsToLiveVars body_fvs `thenLne` \ body_lv_info ->
 570
 571           returnLne (bind2, bind_fvs, bind_escs, getLiveVars bind_lv_info,
 572                      body2, body_fvs, body_escs, getLiveVars body_lv_info)
 573         )
 574
 575     ) `thenLne` (\ (bind2, bind_fvs, bind_escs, bind_lvs,
 576                     body2, body_fvs, body_escs, body_lvs) ->
 577
 578
 579         -- Compute the new let-expression
 580     let
 581         new_let | let_no_escape = StgLetNoEscape live_in_whole_let bind_lvs bind2 body2
 582                 | otherwise     = StgLet bind2 body2
 583
 584         free_in_whole_let
 585           = binders `minusFVBinders` (bind_fvs `unionFVInfo` body_fvs)
 586
 587         live_in_whole_let
 588           = bind_lvs `unionVarSet` (body_lvs `delVarSetList` binders)
 589
 590         real_bind_escs = if let_no_escape then
 591                             bind_escs
 592                          else
 593                             getFVSet bind_fvs
 594                             -- Everything escapes which is free in the bindings
 595
 596         let_escs = (real_bind_escs `unionVarSet` body_escs) `delVarSetList` binders
 597
 598         all_escs = bind_escs `unionVarSet` body_escs    -- Still includes binders of
 599                                                         -- this let(rec)
 600
 601         no_binder_escapes = isEmptyVarSet (set_of_binders `intersectVarSet` all_escs)
 602
 603 #ifdef DEBUG
 604         -- Debugging code as requested by Andrew Kennedy
 605         checked_no_binder_escapes
 606                 | not no_binder_escapes && any is_join_var binders
 607                 = pprTrace "Interesting!  A join var that isn't let-no-escaped" (ppr binders)
 608                   False
 609                 | otherwise = no_binder_escapes
 610 #else
 611         checked_no_binder_escapes = no_binder_escapes
 612 #endif
 613
 614                 -- Mustn't depend on the passed-in let_no_escape flag, since
 615                 -- no_binder_escapes is used by the caller to derive the flag!
 616     in
 617     returnLne (
 618         new_let,
 619         free_in_whole_let,
 620         let_escs,
 621         checked_no_binder_escapes
 622     ))
 623   where
 624     set_of_binders = mkVarSet binders
 625     binders        = bindersOf bind
 626
 627     mk_binding bind_lv_info binder rhs
 628         = (binder, LetBound (NestedLet live_vars) (manifestArity rhs))
 629         where
 630            live_vars | let_no_escape = addLiveVar bind_lv_info binder
 631                      | otherwise     = unitLiveVar binder
 632                 -- c.f. the invariant on NestedLet
 633
 634     vars_bind :: FreeVarsInfo           -- Free var info for body of binding
 635               -> CoreBind
 636               -> LneM (StgBinding,
 637                        FreeVarsInfo,
 638                        EscVarsSet,        -- free vars; escapee vars
 639                        LiveInfo,          -- Vars and CAFs live in binding
 640                        [(Id, HowBound)])  -- extension to environment
 641
 642
 643     vars_bind body_fvs (NonRec binder rhs)
 644       = coreToStgRhs body_fvs [] (binder,rhs)
 645                                 `thenLne` \ (rhs2, bind_fvs, bind_lv_info, escs) ->
 646         let
 647             env_ext_item = mk_binding bind_lv_info binder rhs
 648         in
 649         returnLne (StgNonRec binder rhs2,
 650                    bind_fvs, escs, bind_lv_info, [env_ext_item])
 651
 652
 653     vars_bind body_fvs (Rec pairs)
 654       = fixLne (\ ~(_, rec_rhs_fvs, _, bind_lv_info, _) ->
 655            let
 656                 rec_scope_fvs = unionFVInfo body_fvs rec_rhs_fvs
 657                 binders = map fst pairs
 658                 env_ext = [ mk_binding bind_lv_info b rhs
 659                           | (b,rhs) <- pairs ]
 660            in
 661            extendVarEnvLne env_ext (
 662               mapAndUnzip4Lne (coreToStgRhs rec_scope_fvs binders) pairs
 663                                         `thenLne` \ (rhss2, fvss, lv_infos, escss) ->
 664               let
 665                         bind_fvs = unionFVInfos fvss
 666                         bind_lv_info = foldr unionLiveInfo emptyLiveInfo lv_infos
 667                         escs     = unionVarSets escss
 668               in
 669               returnLne (StgRec (binders `zip` rhss2),
 670                          bind_fvs, escs, bind_lv_info, env_ext)
 671            )
 672         )
 673
 674 is_join_var :: Id -> Bool
 675 -- A hack (used only for compiler debuggging) to tell if
 676 -- a variable started life as a join point ($j)
 677 is_join_var j = occNameUserString (getOccName j) == "$j"
 678 \end{code}
 679
 680 \begin{code}
 681 coreToStgRhs :: FreeVarsInfo            -- Free var info for the scope of the binding
 682              -> [Id]
 683              -> (Id,CoreExpr)
 684              -> LneM (StgRhs, FreeVarsInfo, LiveInfo, EscVarsSet)
 685
 686 coreToStgRhs scope_fv_info binders (bndr, rhs)
 687   = coreToStgExpr rhs           `thenLne` \ (new_rhs, rhs_fvs, rhs_escs) ->
 688     getEnvLne                   `thenLne` \ env ->
 689     freeVarsToLiveVars (binders `minusFVBinders` rhs_fvs) `thenLne` \ lv_info ->
 690     returnLne (mkStgRhs rhs_fvs (mkSRT lv_info) bndr_info new_rhs,
 691                rhs_fvs, lv_info, rhs_escs)
 692   where
 693     bndr_info = lookupFVInfo scope_fv_info bndr
 694
 695 mkStgRhs :: FreeVarsInfo -> SRT -> StgBinderInfo -> StgExpr -> StgRhs
 696
 697 mkStgRhs rhs_fvs srt binder_info (StgConApp con args)
 698   = StgRhsCon noCCS con args
 699
 700 mkStgRhs rhs_fvs srt binder_info (StgLam _ bndrs body)
 701   = StgRhsClosure noCCS binder_info
 702                   (getFVs rhs_fvs)
 703                   ReEntrant
 704                   srt bndrs body
 705
 706 mkStgRhs rhs_fvs srt binder_info rhs
 707   = StgRhsClosure noCCS binder_info
 708                   (getFVs rhs_fvs)
 709                   upd_flag srt [] rhs
 710   where
 711    upd_flag = Updatable
 712   {-
 713     SDM: disabled.  Eval/Apply can't handle functions with arity zero very
 714     well; and making these into simple non-updatable thunks breaks other
 715     assumptions (namely that they will be entered only once).
 716
 717     upd_flag | isPAP env rhs  = ReEntrant
 718              | otherwise      = Updatable
 719   -}
 720
 721 {- ToDo:
 722           upd = if isOnceDem dem
 723                     then (if isNotTop toplev
 724                             then SingleEntry    -- HA!  Paydirt for "dem"
 725                             else
 726 #ifdef DEBUG
 727                      trace "WARNING: SE CAFs unsupported, forcing UPD instead" $
 728 #endif
 729                      Updatable)
 730                 else Updatable
 731         -- For now we forbid SingleEntry CAFs; they tickle the
 732         -- ASSERT in rts/Storage.c line 215 at newCAF() re mut_link,
 733         -- and I don't understand why.  There's only one SE_CAF (well,
 734         -- only one that tickled a great gaping bug in an earlier attempt
 735         -- at ClosureInfo.getEntryConvention) in the whole of nofib,
 736         -- specifically Main.lvl6 in spectral/cryptarithm2.
 737         -- So no great loss.  KSW 2000-07.
 738 -}
 739 \end{code}
 740
 741 Detect thunks which will reduce immediately to PAPs, and make them
 742 non-updatable.  This has several advantages:
 743
 744         - the non-updatable thunk behaves exactly like the PAP,
 745
 746         - the thunk is more efficient to enter, because it is
 747           specialised to the task.
 748
 749         - we save one update frame, one stg_update_PAP, one update
 750           and lots of PAP_enters.
 751
 752         - in the case where the thunk is top-level, we save building
 753           a black hole and futhermore the thunk isn't considered to
 754           be a CAF any more, so it doesn't appear in any SRTs.
 755
 756 We do it here, because the arity information is accurate, and we need
 757 to do it before the SRT pass to save the SRT entries associated with
 758 any top-level PAPs.
 759
 760 isPAP env (StgApp f args) = listLengthCmp args arity == LT -- idArity f > length args
 761                           where
 762                             arity = stgArity f (lookupBinding env f)
 763 isPAP env _               = False
 764
 765
 766 %************************************************************************
 767 %*                                                                      *
 768 \subsection[LNE-monad]{A little monad for this let-no-escaping pass}
 769 %*                                                                      *
 770 %************************************************************************
 771
 772 There's a lot of stuff to pass around, so we use this @LneM@ monad to
 773 help.  All the stuff here is only passed *down*.
 774
 775 \begin{code}
 776 type LneM a =  IdEnv HowBound
 777             -> LiveInfo         -- Vars and CAFs live in continuation
 778             -> a
 779
 780 type LiveInfo = (StgLiveVars,   -- Dynamic live variables;
 781                                 -- i.e. ones with a nested (non-top-level) binding
 782                  CafSet)        -- Static live variables;
 783                                 -- i.e. top-level variables that are CAFs or refer to them
 784
 785 type EscVarsSet = IdSet
 786 type CafSet     = IdSet
 787
 788 data HowBound
 789   = ImportBound         -- Used only as a response to lookupBinding; never
 790                         -- exists in the range of the (IdEnv HowBound)
 791
 792   | LetBound            -- A let(rec) in this module
 793         LetInfo         -- Whether top level or nested
 794         Arity           -- Its arity (local Ids don't have arity info at this point)
 795
 796   | LambdaBound         -- Used for both lambda and case
 797
 798 data LetInfo
 799   = TopLet              -- top level things
 800   | NestedLet LiveInfo  -- For nested things, what is live if this
 801                         -- thing is live?  Invariant: the binder
 802                         -- itself is always a member of
 803                         -- the dynamic set of its own LiveInfo
 804
 805 isLetBound (LetBound _ _) = True
 806 isLetBound other          = False
 807
 808 topLevelBound ImportBound         = True
 809 topLevelBound (LetBound TopLet _) = True
 810 topLevelBound other               = False
 811 \end{code}
 812
 813 For a let(rec)-bound variable, x, we record LiveInfo, the set of
 814 variables that are live if x is live.  This LiveInfo comprises
 815         (a) dynamic live variables (ones with a non-top-level binding)
 816         (b) static live variabes (CAFs or things that refer to CAFs)
 817
 818 For "normal" variables (a) is just x alone.  If x is a let-no-escaped
 819 variable then x is represented by a code pointer and a stack pointer
 820 (well, one for each stack).  So all of the variables needed in the
 821 execution of x are live if x is, and are therefore recorded in the
 822 LetBound constructor; x itself *is* included.
 823
 824 The set of dynamic live variables is guaranteed ot have no further let-no-escaped
 825 variables in it.
 826
 827 \begin{code}
 828 emptyLiveInfo :: LiveInfo
 829 emptyLiveInfo = (emptyVarSet,emptyVarSet)
 830
 831 unitLiveVar :: Id -> LiveInfo
 832 unitLiveVar lv = (unitVarSet lv, emptyVarSet)
 833
 834 unitLiveCaf :: Id -> LiveInfo
 835 unitLiveCaf caf = (emptyVarSet, unitVarSet caf)
 836
 837 addLiveVar :: LiveInfo -> Id -> LiveInfo
 838 addLiveVar (lvs, cafs) id = (lvs `extendVarSet` id, cafs)
 839
 840 unionLiveInfo :: LiveInfo -> LiveInfo -> LiveInfo
 841 unionLiveInfo (lv1,caf1) (lv2,caf2) = (lv1 `unionVarSet` lv2, caf1 `unionVarSet` caf2)
 842
 843 mkSRT :: LiveInfo -> SRT
 844 mkSRT (_, cafs) = SRTEntries cafs
 845
 846 getLiveVars :: LiveInfo -> StgLiveVars
 847 getLiveVars (lvs, _) = lvs
 848 \end{code}
 849
 850
 851 The std monad functions:
 852 \begin{code}
 853 initLne :: IdEnv HowBound -> LneM a -> a
 854 initLne env m = m env emptyLiveInfo
 855
 856
 857
 858 {-# INLINE thenLne #-}
 859 {-# INLINE returnLne #-}
 860
 861 returnLne :: a -> LneM a
 862 returnLne e env lvs_cont = e
 863
 864 thenLne :: LneM a -> (a -> LneM b) -> LneM b
 865 thenLne m k env lvs_cont
 866   = k (m env lvs_cont) env lvs_cont
 867
 868 mapAndUnzipLne  :: (a -> LneM (b,c))   -> [a] -> LneM ([b],[c])
 869 mapAndUnzipLne f [] = returnLne ([],[])
 870 mapAndUnzipLne f (x:xs)
 871   = f x                 `thenLne` \ (r1,  r2)  ->
 872     mapAndUnzipLne f xs `thenLne` \ (rs1, rs2) ->
 873     returnLne (r1:rs1, r2:rs2)
 874
 875 mapAndUnzip3Lne :: (a -> LneM (b,c,d)) -> [a] -> LneM ([b],[c],[d])
 876 mapAndUnzip3Lne f []    = returnLne ([],[],[])
 877 mapAndUnzip3Lne f (x:xs)
 878   = f x                  `thenLne` \ (r1,  r2,  r3)  ->
 879     mapAndUnzip3Lne f xs `thenLne` \ (rs1, rs2, rs3) ->
 880     returnLne (r1:rs1, r2:rs2, r3:rs3)
 881
 882 mapAndUnzip4Lne :: (a -> LneM (b,c,d,e)) -> [a] -> LneM ([b],[c],[d],[e])
 883 mapAndUnzip4Lne f []    = returnLne ([],[],[],[])
 884 mapAndUnzip4Lne f (x:xs)
 885   = f x                  `thenLne` \ (r1,  r2,  r3, r4)  ->
 886     mapAndUnzip4Lne f xs `thenLne` \ (rs1, rs2, rs3, rs4) ->
 887     returnLne (r1:rs1, r2:rs2, r3:rs3, r4:rs4)
 888
 889 fixLne :: (a -> LneM a) -> LneM a
 890 fixLne expr env lvs_cont
 891   = result
 892   where
 893     result = expr result env lvs_cont
 894 \end{code}
 895
 896 Functions specific to this monad:
 897
 898 \begin{code}
 899 getVarsLiveInCont :: LneM LiveInfo
 900 getVarsLiveInCont env lvs_cont = lvs_cont
 901
 902 setVarsLiveInCont :: LiveInfo -> LneM a -> LneM a
 903 setVarsLiveInCont new_lvs_cont expr env lvs_cont
 904   = expr env new_lvs_cont
 905
 906 extendVarEnvLne :: [(Id, HowBound)] -> LneM a -> LneM a
 907 extendVarEnvLne ids_w_howbound expr env lvs_cont
 908   = expr (extendVarEnvList env ids_w_howbound) lvs_cont
 909
 910 lookupVarLne :: Id -> LneM HowBound
 911 lookupVarLne v env lvs_cont = returnLne (lookupBinding env v) env lvs_cont
 912
 913 getEnvLne :: LneM (IdEnv HowBound)
 914 getEnvLne env lvs_cont = returnLne env env lvs_cont
 915
 916 lookupBinding :: IdEnv HowBound -> Id -> HowBound
 917 lookupBinding env v = case lookupVarEnv env v of
 918                         Just xx -> xx
 919                         Nothing -> ASSERT2( isGlobalId v, ppr v ) ImportBound
 920
 921
 922 -- The result of lookupLiveVarsForSet, a set of live variables, is
 923 -- only ever tacked onto a decorated expression. It is never used as
 924 -- the basis of a control decision, which might give a black hole.
 925
 926 freeVarsToLiveVars :: FreeVarsInfo -> LneM LiveInfo
 927 freeVarsToLiveVars fvs env live_in_cont
 928   = returnLne live_info env live_in_cont
 929   where
 930     live_info    = foldr unionLiveInfo live_in_cont lvs_from_fvs
 931     lvs_from_fvs = map do_one (allFreeIds fvs)
 932
 933     do_one (v, how_bound)
 934       = case how_bound of
 935           ImportBound                     -> unitLiveCaf v      -- Only CAF imports are
 936                                                                 -- recorded in fvs
 937           LetBound TopLet _
 938                 | mayHaveCafRefs (idCafInfo v) -> unitLiveCaf v
 939                 | otherwise                    -> emptyLiveInfo
 940
 941           LetBound (NestedLet lvs) _      -> lvs        -- lvs already contains v
 942                                                         -- (see the invariant on NestedLet)
 943
 944           _lambda_or_case_binding         -> unitLiveVar v      -- Bound by lambda or case
 945 \end{code}
 946
 947 %************************************************************************
 948 %*                                                                      *
 949 \subsection[Free-var info]{Free variable information}
 950 %*                                                                      *
 951 %************************************************************************
 952
 953 \begin{code}
 954 type FreeVarsInfo = VarEnv (Var, HowBound, StgBinderInfo)
 955         -- The Var is so we can gather up the free variables
 956         -- as a set.
 957         --
 958         -- The HowBound info just saves repeated lookups;
 959         -- we look up just once when we encounter the occurrence.
 960         -- INVARIANT: Any ImportBound Ids are HaveCafRef Ids
 961         --            Imported Ids without CAF refs are simply
 962         --            not put in the FreeVarsInfo for an expression.
 963         --            See singletonFVInfo and freeVarsToLiveVars
 964         --
 965         -- StgBinderInfo records how it occurs; notably, we
 966         -- are interested in whether it only occurs in saturated
 967         -- applications, because then we don't need to build a
 968         -- curried version.
 969         -- If f is mapped to noBinderInfo, that means
 970         -- that f *is* mentioned (else it wouldn't be in the
 971         -- IdEnv at all), but perhaps in an unsaturated applications.
 972         --
 973         -- All case/lambda-bound things are also mapped to
 974         -- noBinderInfo, since we aren't interested in their
 975         -- occurence info.
 976         --
 977         -- For ILX we track free var info for type variables too;
 978         -- hence VarEnv not IdEnv
 979 \end{code}
 980
 981 \begin{code}
 982 emptyFVInfo :: FreeVarsInfo
 983 emptyFVInfo = emptyVarEnv
 984
 985 singletonFVInfo :: Id -> HowBound -> StgBinderInfo -> FreeVarsInfo
 986 -- Don't record non-CAF imports at all, to keep free-var sets small
 987 singletonFVInfo id ImportBound info
 988    | mayHaveCafRefs (idCafInfo id) = unitVarEnv id (id, ImportBound, info)
 989    | otherwise                     = emptyVarEnv
 990 singletonFVInfo id how_bound info  = unitVarEnv id (id, how_bound, info)
 991
 992 tyvarFVInfo :: TyVarSet -> FreeVarsInfo
 993 tyvarFVInfo tvs = foldVarSet add emptyFVInfo tvs
 994         where
 995           add tv fvs = extendVarEnv fvs tv (tv, LambdaBound, noBinderInfo)
 996                 -- Type variables must be lambda-bound
 997
 998 unionFVInfo :: FreeVarsInfo -> FreeVarsInfo -> FreeVarsInfo
 999 unionFVInfo fv1 fv2 = plusVarEnv_C plusFVInfo fv1 fv2
1000
1001 unionFVInfos :: [FreeVarsInfo] -> FreeVarsInfo
1002 unionFVInfos fvs = foldr unionFVInfo emptyFVInfo fvs
1003
1004 minusFVBinders :: [Id] -> FreeVarsInfo -> FreeVarsInfo
1005 minusFVBinders vs fv = foldr minusFVBinder fv vs
1006
1007 minusFVBinder :: Id -> FreeVarsInfo -> FreeVarsInfo
1008 minusFVBinder v fv | isId v && opt_RuntimeTypes
1009                    = (fv `delVarEnv` v) `unionFVInfo`
1010                      tyvarFVInfo (tyVarsOfType (idType v))
1011                    | otherwise = fv `delVarEnv` v
1012         -- When removing a binder, remember to add its type variables
1013         -- c.f. CoreFVs.delBinderFV
1014
1015 elementOfFVInfo :: Id -> FreeVarsInfo -> Bool
1016 elementOfFVInfo id fvs = maybeToBool (lookupVarEnv fvs id)
1017
1018 lookupFVInfo :: FreeVarsInfo -> Id -> StgBinderInfo
1019 -- Find how the given Id is used.
1020 -- Externally visible things may be used any old how
1021 lookupFVInfo fvs id
1022   | isExternalName (idName id) = noBinderInfo
1023   | otherwise = case lookupVarEnv fvs id of
1024                         Nothing         -> noBinderInfo
1025                         Just (_,_,info) -> info
1026
1027 allFreeIds :: FreeVarsInfo -> [(Id,HowBound)]   -- Both top level and non-top-level Ids
1028 allFreeIds fvs = [(id,how_bound) | (id,how_bound,_) <- varEnvElts fvs, isId id]
1029
1030 -- Non-top-level things only, both type variables and ids
1031 -- (type variables only if opt_RuntimeTypes)
1032 getFVs :: FreeVarsInfo -> [Var]
1033 getFVs fvs = [id | (id, how_bound, _) <- varEnvElts fvs,
1034                     not (topLevelBound how_bound) ]
1035
1036 getFVSet :: FreeVarsInfo -> VarSet
1037 getFVSet fvs = mkVarSet (getFVs fvs)
1038
1039 plusFVInfo (id1,hb1,info1) (id2,hb2,info2)
1040   = ASSERT (id1 == id2 && hb1 `check_eq_how_bound` hb2)
1041     (id1, hb1, combineStgBinderInfo info1 info2)
1042
1043 #ifdef DEBUG
1044 -- The HowBound info for a variable in the FVInfo should be consistent
1045 check_eq_how_bound ImportBound        ImportBound        = True
1046 check_eq_how_bound LambdaBound        LambdaBound        = True
1047 check_eq_how_bound (LetBound li1 ar1) (LetBound li2 ar2) = ar1 == ar2 && check_eq_li li1 li2
1048 check_eq_how_bound hb1                hb2                = False
1049
1050 check_eq_li (NestedLet _) (NestedLet _) = True
1051 check_eq_li TopLet        TopLet        = True
1052 check_eq_li li1           li2           = False
1053 #endif
1054 \end{code}
1055
1056 Misc.
1057 \begin{code}
1058 filterStgBinders :: [Var] -> [Var]
1059 filterStgBinders bndrs
1060   | opt_RuntimeTypes = bndrs
1061   | otherwise        = filter isId bndrs
1062 \end{code}
1063
1064
1065 \begin{code}
1066         -- Ignore all notes except SCC
1067 myCollectBinders expr
1068   = go [] expr
1069   where
1070     go bs (Lam b e)          = go (b:bs) e
1071     go bs e@(Note (SCC _) _) = (reverse bs, e)
1072     go bs (Note _ e)         = go bs e
1073     go bs e                  = (reverse bs, e)
1074
1075 myCollectArgs :: CoreExpr -> (Id, [CoreArg])
1076         -- We assume that we only have variables
1077         -- in the function position by now
1078 myCollectArgs expr
1079   = go expr []
1080   where
1081     go (Var v)          as = (v, as)
1082     go (App f a) as        = go f (a:as)
1083     go (Note (SCC _) e) as = pprPanic "CoreToStg.myCollectArgs" (ppr expr)
1084     go (Note n e)       as = go e as
1085     go _                as = pprPanic "CoreToStg.myCollectArgs" (ppr expr)
1086 \end{code}
1087
1088 \begin{code}
1089 stgArity :: Id -> HowBound -> Arity
1090 stgArity f (LetBound _ arity) = arity
1091 stgArity f ImportBound        = idArity f
1092 stgArity f LambdaBound        = 0
1093 \end{code}