ghc/compiler/stgSyn/StgSyn.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[StgSyn]{Shared term graph (STG) syntax for spineless-tagless code generation}
   5
   6 This data type represents programs just before code generation
   7 (conversion to @AbstractC@): basically, what we have is a stylised
   8 form of @CoreSyntax@, the style being one that happens to be ideally
   9 suited to spineless tagless code generation.
  10
  11 \begin{code}
  12 module StgSyn (
  13         GenStgArg(..),
  14         GenStgLiveVars,
  15
  16         GenStgBinding(..), GenStgExpr(..), GenStgRhs(..),
  17         GenStgAlt, AltType(..),
  18
  19         UpdateFlag(..), isUpdatable,
  20
  21         StgBinderInfo,
  22         noBinderInfo, stgSatOcc, stgUnsatOcc, satCallsOnly,
  23         combineStgBinderInfo,
  24
  25         -- a set of synonyms for the most common (only :-) parameterisation
  26         StgArg, StgLiveVars,
  27         StgBinding, StgExpr, StgRhs, StgAlt,
  28
  29         -- StgOp
  30         StgOp(..),
  31
  32         -- SRTs
  33         SRT(..), noSRT, nonEmptySRT,
  34
  35         -- utils
  36         stgBindHasCafRefs,  stgArgHasCafRefs, stgRhsArity, getArgPrimRep,
  37         isDllConApp, isStgTypeArg,
  38         stgArgType, stgBinders,
  39
  40         pprStgBinding, pprStgBindings, pprStgBindingsWithSRTs
  41
  42 #ifdef DEBUG
  43         , pprStgLVs
  44 #endif
  45     ) where
  46
  47 #include "HsVersions.h"
  48
  49 import CostCentre       ( CostCentreStack, CostCentre )
  50 import VarSet           ( IdSet, isEmptyVarSet )
  51 import Var              ( isId )
  52 import Id               ( Id, idName, idPrimRep, idType, idCafInfo )
  53 import IdInfo           ( mayHaveCafRefs )
  54 import Name             ( isDllName )
  55 import Literal          ( Literal, literalType, literalPrimRep )
  56 import ForeignCall      ( ForeignCall )
  57 import DataCon          ( DataCon, dataConName )
  58 import CoreSyn          ( AltCon )
  59 import PrimOp           ( PrimOp )
  60 import Outputable
  61 import Util             ( count )
  62 import Type             ( Type )
  63 import TyCon            ( TyCon )
  64 import UniqSet          ( isEmptyUniqSet, uniqSetToList, UniqSet )
  65 import Unique           ( Unique )
  66 import Bitmap
  67 import CmdLineOpts      ( opt_SccProfilingOn )
  68 \end{code}
  69
  70 %************************************************************************
  71 %*                                                                      *
  72 \subsection{@GenStgBinding@}
  73 %*                                                                      *
  74 %************************************************************************
  75
  76 As usual, expressions are interesting; other things are boring.  Here
  77 are the boring things [except note the @GenStgRhs@], parameterised
  78 with respect to binder and occurrence information (just as in
  79 @CoreSyn@):
  80
  81 There is one SRT for each group of bindings.
  82
  83 \begin{code}
  84 data GenStgBinding bndr occ
  85   = StgNonRec   bndr (GenStgRhs bndr occ)
  86   | StgRec      [(bndr, GenStgRhs bndr occ)]
  87
  88 stgBinders :: GenStgBinding bndr occ -> [bndr]
  89 stgBinders (StgNonRec b _) = [b]
  90 stgBinders (StgRec bs)     = map fst bs
  91 \end{code}
  92
  93 %************************************************************************
  94 %*                                                                      *
  95 \subsection{@GenStgArg@}
  96 %*                                                                      *
  97 %************************************************************************
  98
  99 \begin{code}
 100 data GenStgArg occ
 101   = StgVarArg   occ
 102   | StgLitArg   Literal
 103   | StgTypeArg  Type            -- For when we want to preserve all type info
 104 \end{code}
 105
 106 \begin{code}
 107 getArgPrimRep (StgVarArg local) = idPrimRep local
 108 getArgPrimRep (StgLitArg lit)   = literalPrimRep lit
 109
 110 isStgTypeArg (StgTypeArg _) = True
 111 isStgTypeArg other          = False
 112
 113 isDllArg :: StgArg -> Bool
 114         -- Does this argument refer to something in a different DLL?
 115 isDllArg (StgTypeArg v)  = False
 116 isDllArg (StgVarArg v)   = isDllName (idName v)
 117 isDllArg (StgLitArg lit) = False
 118
 119 isDllConApp :: DataCon -> [StgArg] -> Bool
 120         -- Does this constructor application refer to
 121         -- anything in a different DLL?
 122         -- If so, we can't allocate it statically
 123 isDllConApp con args = isDllName (dataConName con) || any isDllArg args
 124
 125 stgArgType :: StgArg -> Type
 126         -- Very half baked becase we have lost the type arguments
 127 stgArgType (StgVarArg v)   = idType v
 128 stgArgType (StgLitArg lit) = literalType lit
 129 stgArgType (StgTypeArg lit) = panic "stgArgType called on stgTypeArg"
 130 \end{code}
 131
 132 %************************************************************************
 133 %*                                                                      *
 134 \subsection{STG expressions}
 135 %*                                                                      *
 136 %************************************************************************
 137
 138 The @GenStgExpr@ data type is parameterised on binder and occurrence
 139 info, as before.
 140
 141 %************************************************************************
 142 %*                                                                      *
 143 \subsubsection{@GenStgExpr@ application}
 144 %*                                                                      *
 145 %************************************************************************
 146
 147 An application is of a function to a list of atoms [not expressions].
 148 Operationally, we want to push the arguments on the stack and call the
 149 function.  (If the arguments were expressions, we would have to build
 150 their closures first.)
 151
 152 There is no constructor for a lone variable; it would appear as
 153 @StgApp var [] _@.
 154 \begin{code}
 155 type GenStgLiveVars occ = UniqSet occ
 156
 157 data GenStgExpr bndr occ
 158   = StgApp
 159         occ             -- function
 160         [GenStgArg occ] -- arguments; may be empty
 161 \end{code}
 162
 163 %************************************************************************
 164 %*                                                                      *
 165 \subsubsection{@StgConApp@ and @StgPrimApp@---saturated applications}
 166 %*                                                                      *
 167 %************************************************************************
 168
 169 There are a specialised forms of application, for
 170 constructors, primitives, and literals.
 171 \begin{code}
 172   | StgLit      Literal
 173
 174   | StgConApp   DataCon
 175                 [GenStgArg occ] -- Saturated
 176
 177   | StgOpApp    StgOp           -- Primitive op or foreign call
 178                 [GenStgArg occ] -- Saturated
 179                 Type            -- Result type; we need to know the result type
 180                                 -- so that we can assign result registers.
 181 \end{code}
 182
 183 %************************************************************************
 184 %*                                                                      *
 185 \subsubsection{@StgLam@}
 186 %*                                                                      *
 187 %************************************************************************
 188
 189 StgLam is used *only* during CoreToStg's work.  Before CoreToStg has finished
 190 it encodes (\x -> e) as (let f = \x -> e in f)
 191
 192 \begin{code}
 193   | StgLam
 194         Type            -- Type of whole lambda (useful when making a binder for it)
 195         [bndr]
 196         StgExpr         -- Body of lambda
 197 \end{code}
 198
 199
 200 %************************************************************************
 201 %*                                                                      *
 202 \subsubsection{@GenStgExpr@: case-expressions}
 203 %*                                                                      *
 204 %************************************************************************
 205
 206 This has the same boxed/unboxed business as Core case expressions.
 207 \begin{code}
 208   | StgCase
 209         (GenStgExpr bndr occ)
 210                         -- the thing to examine
 211
 212         (GenStgLiveVars occ) -- Live vars of whole case expression,
 213                         -- plus everything that happens after the case
 214                         -- i.e., those which mustn't be overwritten
 215
 216         (GenStgLiveVars occ) -- Live vars of RHSs (plus what happens afterwards)
 217                         -- i.e., those which must be saved before eval.
 218                         --
 219                         -- note that an alt's constructor's
 220                         -- binder-variables are NOT counted in the
 221                         -- free vars for the alt's RHS
 222
 223         bndr            -- binds the result of evaluating the scrutinee
 224
 225         SRT             -- The SRT for the continuation
 226
 227         AltType
 228
 229         [GenStgAlt bndr occ]    -- The DEFAULT case is always *first*
 230                                 -- if it is there at all
 231 \end{code}
 232
 233 %************************************************************************
 234 %*                                                                      *
 235 \subsubsection{@GenStgExpr@:  @let(rec)@-expressions}
 236 %*                                                                      *
 237 %************************************************************************
 238
 239 The various forms of let(rec)-expression encode most of the
 240 interesting things we want to do.
 241 \begin{enumerate}
 242 \item
 243 \begin{verbatim}
 244 let-closure x = [free-vars] expr [args]
 245 in e
 246 \end{verbatim}
 247 is equivalent to
 248 \begin{verbatim}
 249 let x = (\free-vars -> \args -> expr) free-vars
 250 \end{verbatim}
 251 \tr{args} may be empty (and is for most closures).  It isn't under
 252 circumstances like this:
 253 \begin{verbatim}
 254 let x = (\y -> y+z)
 255 \end{verbatim}
 256 This gets mangled to
 257 \begin{verbatim}
 258 let-closure x = [z] [y] (y+z)
 259 \end{verbatim}
 260 The idea is that we compile code for @(y+z)@ in an environment in which
 261 @z@ is bound to an offset from \tr{Node}, and @y@ is bound to an
 262 offset from the stack pointer.
 263
 264 (A let-closure is an @StgLet@ with a @StgRhsClosure@ RHS.)
 265
 266 \item
 267 \begin{verbatim}
 268 let-constructor x = Constructor [args]
 269 in e
 270 \end{verbatim}
 271
 272 (A let-constructor is an @StgLet@ with a @StgRhsCon@ RHS.)
 273
 274 \item
 275 Letrec-expressions are essentially the same deal as
 276 let-closure/let-constructor, so we use a common structure and
 277 distinguish between them with an @is_recursive@ boolean flag.
 278
 279 \item
 280 \begin{verbatim}
 281 let-unboxed u = an arbitrary arithmetic expression in unboxed values
 282 in e
 283 \end{verbatim}
 284 All the stuff on the RHS must be fully evaluated.  No function calls either!
 285
 286 (We've backed away from this toward case-expressions with
 287 suitably-magical alts ...)
 288
 289 \item
 290 ~[Advanced stuff here!  Not to start with, but makes pattern matching
 291 generate more efficient code.]
 292
 293 \begin{verbatim}
 294 let-escapes-not fail = expr
 295 in e'
 296 \end{verbatim}
 297 Here the idea is that @e'@ guarantees not to put @fail@ in a data structure,
 298 or pass it to another function.  All @e'@ will ever do is tail-call @fail@.
 299 Rather than build a closure for @fail@, all we need do is to record the stack
 300 level at the moment of the @let-escapes-not@; then entering @fail@ is just
 301 a matter of adjusting the stack pointer back down to that point and entering
 302 the code for it.
 303
 304 Another example:
 305 \begin{verbatim}
 306 f x y = let z = huge-expression in
 307         if y==1 then z else
 308         if y==2 then z else
 309         1
 310 \end{verbatim}
 311
 312 (A let-escapes-not is an @StgLetNoEscape@.)
 313
 314 \item
 315 We may eventually want:
 316 \begin{verbatim}
 317 let-literal x = Literal
 318 in e
 319 \end{verbatim}
 320
 321 (ToDo: is this obsolete?)
 322 \end{enumerate}
 323
 324 And so the code for let(rec)-things:
 325 \begin{code}
 326   | StgLet
 327         (GenStgBinding bndr occ)        -- right hand sides (see below)
 328         (GenStgExpr bndr occ)           -- body
 329
 330   | StgLetNoEscape                      -- remember: ``advanced stuff''
 331         (GenStgLiveVars occ)            -- Live in the whole let-expression
 332                                         -- Mustn't overwrite these stack slots
 333                                         -- *Doesn't* include binders of the let(rec).
 334
 335         (GenStgLiveVars occ)            -- Live in the right hand sides (only)
 336                                         -- These are the ones which must be saved on
 337                                         -- the stack if they aren't there already
 338                                         -- *Does* include binders of the let(rec) if recursive.
 339
 340         (GenStgBinding bndr occ)        -- right hand sides (see below)
 341         (GenStgExpr bndr occ)           -- body
 342 \end{code}
 343
 344 %************************************************************************
 345 %*                                                                      *
 346 \subsubsection{@GenStgExpr@: @scc@ expressions}
 347 %*                                                                      *
 348 %************************************************************************
 349
 350 Finally for @scc@ expressions we introduce a new STG construct.
 351
 352 \begin{code}
 353   | StgSCC
 354         CostCentre              -- label of SCC expression
 355         (GenStgExpr bndr occ)   -- scc expression
 356   -- end of GenStgExpr
 357 \end{code}
 358
 359 %************************************************************************
 360 %*                                                                      *
 361 \subsection{STG right-hand sides}
 362 %*                                                                      *
 363 %************************************************************************
 364
 365 Here's the rest of the interesting stuff for @StgLet@s; the first
 366 flavour is for closures:
 367 \begin{code}
 368 data GenStgRhs bndr occ
 369   = StgRhsClosure
 370         CostCentreStack         -- CCS to be attached (default is CurrentCCS)
 371         StgBinderInfo           -- Info about how this binder is used (see below)
 372         [occ]                   -- non-global free vars; a list, rather than
 373                                 -- a set, because order is important
 374         !UpdateFlag             -- ReEntrant | Updatable | SingleEntry
 375         SRT                     -- The SRT reference
 376         [bndr]                  -- arguments; if empty, then not a function;
 377                                 -- as above, order is important.
 378         (GenStgExpr bndr occ)   -- body
 379 \end{code}
 380 An example may be in order.  Consider:
 381 \begin{verbatim}
 382 let t = \x -> \y -> ... x ... y ... p ... q in e
 383 \end{verbatim}
 384 Pulling out the free vars and stylising somewhat, we get the equivalent:
 385 \begin{verbatim}
 386 let t = (\[p,q] -> \[x,y] -> ... x ... y ... p ...q) p q
 387 \end{verbatim}
 388 Stg-operationally, the @[x,y]@ are on the stack, the @[p,q]@ are
 389 offsets from @Node@ into the closure, and the code ptr for the closure
 390 will be exactly that in parentheses above.
 391
 392 The second flavour of right-hand-side is for constructors (simple but important):
 393 \begin{code}
 394   | StgRhsCon
 395         CostCentreStack         -- CCS to be attached (default is CurrentCCS).
 396                                 -- Top-level (static) ones will end up with
 397                                 -- DontCareCCS, because we don't count static
 398                                 -- data in heap profiles, and we don't set CCCS
 399                                 -- from static closure.
 400         DataCon                 -- constructor
 401         [GenStgArg occ] -- args
 402 \end{code}
 403
 404 \begin{code}
 405 stgRhsArity :: StgRhs -> Int
 406 stgRhsArity (StgRhsClosure _ _ _ _ _ bndrs _) = count isId bndrs
 407   -- The arity never includes type parameters, so
 408   -- when keeping type arguments and binders in the Stg syntax
 409   -- (opt_RuntimeTypes) we have to fliter out the type binders.
 410 stgRhsArity (StgRhsCon _ _ _) = 0
 411 \end{code}
 412
 413 \begin{code}
 414 stgBindHasCafRefs :: GenStgBinding bndr Id -> Bool
 415 stgBindHasCafRefs (StgNonRec _ rhs) = rhsHasCafRefs rhs
 416 stgBindHasCafRefs (StgRec binds)    = any rhsHasCafRefs (map snd binds)
 417
 418 rhsHasCafRefs (StgRhsClosure _ _ _ upd srt _ _)
 419   = isUpdatable upd || nonEmptySRT srt
 420 rhsHasCafRefs (StgRhsCon _ _ args)
 421   = any stgArgHasCafRefs args
 422
 423 stgArgHasCafRefs (StgVarArg id) = mayHaveCafRefs (idCafInfo id)
 424 stgArgHasCafRefs _ = False
 425 \end{code}
 426
 427 Here's the @StgBinderInfo@ type, and its combining op:
 428 \begin{code}
 429 data StgBinderInfo
 430   = NoStgBinderInfo
 431   | SatCallsOnly        -- All occurrences are *saturated* *function* calls
 432                         -- This means we don't need to build an info table and
 433                         -- slow entry code for the thing
 434                         -- Thunks never get this value
 435
 436 noBinderInfo = NoStgBinderInfo
 437 stgUnsatOcc  = NoStgBinderInfo
 438 stgSatOcc    = SatCallsOnly
 439
 440 satCallsOnly :: StgBinderInfo -> Bool
 441 satCallsOnly SatCallsOnly    = True
 442 satCallsOnly NoStgBinderInfo = False
 443
 444 combineStgBinderInfo :: StgBinderInfo -> StgBinderInfo -> StgBinderInfo
 445 combineStgBinderInfo SatCallsOnly SatCallsOnly = SatCallsOnly
 446 combineStgBinderInfo info1 info2               = NoStgBinderInfo
 447
 448 --------------
 449 pp_binder_info NoStgBinderInfo = empty
 450 pp_binder_info SatCallsOnly    = ptext SLIT("sat-only")
 451 \end{code}
 452
 453 %************************************************************************
 454 %*                                                                      *
 455 \subsection[Stg-case-alternatives]{STG case alternatives}
 456 %*                                                                      *
 457 %************************************************************************
 458
 459 Very like in @CoreSyntax@ (except no type-world stuff).
 460
 461 The type constructor is guaranteed not to be abstract; that is, we can
 462 see its representation.  This is important because the code generator
 463 uses it to determine return conventions etc.  But it's not trivial
 464 where there's a moduule loop involved, because some versions of a type
 465 constructor might not have all the constructors visible.  So
 466 mkStgAlgAlts (in CoreToStg) ensures that it gets the TyCon from the
 467 constructors or literals (which are guaranteed to have the Real McCoy)
 468 rather than from the scrutinee type.
 469
 470 \begin{code}
 471 type GenStgAlt bndr occ
 472   = (AltCon,            -- alts: data constructor,
 473      [bndr],            -- constructor's parameters,
 474      [Bool],            -- "use mask", same length as
 475                         -- parameters; a True in a
 476                         -- param's position if it is
 477                         -- used in the ...
 478      GenStgExpr bndr occ)       -- ...right-hand side.
 479
 480 data AltType
 481   = PolyAlt             -- Polymorphic (a type variable)
 482   | UbxTupAlt TyCon     -- Unboxed tuple
 483   | AlgAlt    TyCon     -- Algebraic data type; the AltCons will be DataAlts
 484   | PrimAlt   TyCon     -- Primitive data type; the AltCons will be LitAlts
 485 \end{code}
 486
 487 %************************************************************************
 488 %*                                                                      *
 489 \subsection[Stg]{The Plain STG parameterisation}
 490 %*                                                                      *
 491 %************************************************************************
 492
 493 This happens to be the only one we use at the moment.
 494
 495 \begin{code}
 496 type StgBinding     = GenStgBinding     Id Id
 497 type StgArg         = GenStgArg         Id
 498 type StgLiveVars    = GenStgLiveVars    Id
 499 type StgExpr        = GenStgExpr        Id Id
 500 type StgRhs         = GenStgRhs         Id Id
 501 type StgAlt         = GenStgAlt         Id Id
 502 \end{code}
 503
 504 %************************************************************************
 505 %*                                                                      *
 506 \subsubsection[UpdateFlag-datatype]{@UpdateFlag@}
 507 %*                                                                      *
 508 %************************************************************************
 509
 510 This is also used in @LambdaFormInfo@ in the @ClosureInfo@ module.
 511
 512 A @ReEntrant@ closure may be entered multiple times, but should not be
 513 updated or blackholed.  An @Updatable@ closure should be updated after
 514 evaluation (and may be blackholed during evaluation).  A @SingleEntry@
 515 closure will only be entered once, and so need not be updated but may
 516 safely be blackholed.
 517
 518 \begin{code}
 519 data UpdateFlag = ReEntrant | Updatable | SingleEntry
 520
 521 instance Outputable UpdateFlag where
 522     ppr u
 523       = char (case u of { ReEntrant -> 'r';  Updatable -> 'u';  SingleEntry -> 's' })
 524
 525 isUpdatable ReEntrant   = False
 526 isUpdatable SingleEntry = False
 527 isUpdatable Updatable   = True
 528 \end{code}
 529
 530 %************************************************************************
 531 %*                                                                      *
 532 \subsubsection{StgOp}
 533 %*                                                                      *
 534 %************************************************************************
 535
 536 An StgOp allows us to group together PrimOps and ForeignCalls.
 537 It's quite useful to move these around together, notably
 538 in StgOpApp and COpStmt.
 539
 540 \begin{code}
 541 data StgOp = StgPrimOp  PrimOp
 542
 543            | StgFCallOp ForeignCall Unique
 544                 -- The Unique is occasionally needed by the C pretty-printer
 545                 -- (which lacks a unique supply), notably when generating a
 546                 -- typedef for foreign-export-dynamic
 547 \end{code}
 548
 549
 550 %************************************************************************
 551 %*                                                                      *
 552 \subsubsection[Static Reference Tables]{@SRT@}
 553 %*                                                                      *
 554 %************************************************************************
 555
 556 There is one SRT per top-level function group.  Each local binding and
 557 case expression within this binding group has a subrange of the whole
 558 SRT, expressed as an offset and length.
 559
 560 In CoreToStg we collect the list of CafRefs at each SRT site, which is later
 561 converted into the length and offset form by the SRT pass.
 562
 563 \begin{code}
 564 data SRT = NoSRT
 565          | SRTEntries IdSet
 566                 -- generated by CoreToStg
 567          | SRT !Int{-offset-} !Int{-length-} !Bitmap{-bitmap-}
 568                 -- generated by computeSRTs
 569
 570 noSRT :: SRT
 571 noSRT = NoSRT
 572
 573 nonEmptySRT NoSRT           = False
 574 nonEmptySRT (SRTEntries vs) = not (isEmptyVarSet vs)
 575 nonEmptySRT _               = True
 576
 577 pprSRT (NoSRT) = ptext SLIT("_no_srt_")
 578 pprSRT (SRTEntries ids) = text "SRT:" <> ppr ids
 579 pprSRT (SRT off length bitmap) = parens (ppr off <> comma <> text "*bitmap*")
 580 \end{code}
 581
 582 %************************************************************************
 583 %*                                                                      *
 584 \subsection[Stg-pretty-printing]{Pretty-printing}
 585 %*                                                                      *
 586 %************************************************************************
 587
 588 Robin Popplestone asked for semi-colon separators on STG binds; here's
 589 hoping he likes terminators instead...  Ditto for case alternatives.
 590
 591 \begin{code}
 592 pprGenStgBinding :: (Outputable bndr, Outputable bdee, Ord bdee)
 593                  => GenStgBinding bndr bdee -> SDoc
 594
 595 pprGenStgBinding (StgNonRec bndr rhs)
 596   = hang (hsep [ppr bndr, equals])
 597         4 ((<>) (ppr rhs) semi)
 598
 599 pprGenStgBinding (StgRec pairs)
 600   = vcat ((ifPprDebug (ptext SLIT("{- StgRec (begin) -}"))) :
 601            (map (ppr_bind) pairs) ++ [(ifPprDebug (ptext SLIT("{- StgRec (end) -}")))])
 602   where
 603     ppr_bind (bndr, expr)
 604       = hang (hsep [ppr bndr, equals])
 605              4 ((<>) (ppr expr) semi)
 606
 607 pprStgBinding  :: StgBinding -> SDoc
 608 pprStgBinding  bind  = pprGenStgBinding bind
 609
 610 pprStgBindings :: [StgBinding] -> SDoc
 611 pprStgBindings binds = vcat (map pprGenStgBinding binds)
 612
 613 pprGenStgBindingWithSRT
 614         :: (Outputable bndr, Outputable bdee, Ord bdee)
 615         => (GenStgBinding bndr bdee,[(Id,[Id])]) -> SDoc
 616
 617 pprGenStgBindingWithSRT (bind,srts)
 618   = vcat (pprGenStgBinding bind : map pprSRT srts)
 619   where pprSRT (id,srt) =
 620            ptext SLIT("SRT") <> parens (ppr id) <> ptext SLIT(": ") <> ppr srt
 621
 622 pprStgBindingsWithSRTs :: [(StgBinding,[(Id,[Id])])] -> SDoc
 623 pprStgBindingsWithSRTs binds = vcat (map pprGenStgBindingWithSRT binds)
 624 \end{code}
 625
 626 \begin{code}
 627 instance (Outputable bdee) => Outputable (GenStgArg bdee) where
 628     ppr = pprStgArg
 629
 630 instance (Outputable bndr, Outputable bdee, Ord bdee)
 631                 => Outputable (GenStgBinding bndr bdee) where
 632     ppr = pprGenStgBinding
 633
 634 instance (Outputable bndr, Outputable bdee, Ord bdee)
 635                 => Outputable (GenStgExpr bndr bdee) where
 636     ppr = pprStgExpr
 637
 638 instance (Outputable bndr, Outputable bdee, Ord bdee)
 639                 => Outputable (GenStgRhs bndr bdee) where
 640     ppr rhs = pprStgRhs rhs
 641 \end{code}
 642
 643 \begin{code}
 644 pprStgArg :: (Outputable bdee) => GenStgArg bdee -> SDoc
 645
 646 pprStgArg (StgVarArg var) = ppr var
 647 pprStgArg (StgLitArg con) = ppr con
 648 pprStgArg (StgTypeArg ty) = char '@' <+> ppr ty
 649 \end{code}
 650
 651 \begin{code}
 652 pprStgExpr :: (Outputable bndr, Outputable bdee, Ord bdee)
 653            => GenStgExpr bndr bdee -> SDoc
 654 -- special case
 655 pprStgExpr (StgLit lit)     = ppr lit
 656
 657 -- general case
 658 pprStgExpr (StgApp func args)
 659   = hang (ppr func)
 660          4 (sep (map (ppr) args))
 661 \end{code}
 662
 663 \begin{code}
 664 pprStgExpr (StgConApp con args)
 665   = hsep [ ppr con, brackets (interppSP args)]
 666
 667 pprStgExpr (StgOpApp op args _)
 668   = hsep [ pprStgOp op, brackets (interppSP args)]
 669
 670 pprStgExpr (StgLam _ bndrs body)
 671   =sep [ char '\\' <+> ppr bndrs <+> ptext SLIT("->"),
 672          pprStgExpr body ]
 673 \end{code}
 674
 675 \begin{code}
 676 -- special case: let v = <very specific thing>
 677 --               in
 678 --               let ...
 679 --               in
 680 --               ...
 681 --
 682 -- Very special!  Suspicious! (SLPJ)
 683
 684 {-
 685 pprStgExpr (StgLet srt (StgNonRec bndr (StgRhsClosure cc bi free_vars upd_flag args rhs))
 686                         expr@(StgLet _ _))
 687   = ($$)
 688       (hang (hcat [ptext SLIT("let { "), ppr bndr, ptext SLIT(" = "),
 689                           ppr cc,
 690                           pp_binder_info bi,
 691                           ptext SLIT(" ["), ifPprDebug (interppSP free_vars), ptext SLIT("] \\"),
 692                           ppr upd_flag, ptext SLIT(" ["),
 693                           interppSP args, char ']'])
 694             8 (sep [hsep [ppr rhs, ptext SLIT("} in")]]))
 695       (ppr expr)
 696 -}
 697
 698 -- special case: let ... in let ...
 699
 700 pprStgExpr (StgLet bind expr@(StgLet _ _))
 701   = ($$)
 702       (sep [hang (ptext SLIT("let {"))
 703                 2 (hsep [pprGenStgBinding bind, ptext SLIT("} in")])])
 704       (ppr expr)
 705
 706 -- general case
 707 pprStgExpr (StgLet bind expr)
 708   = sep [hang (ptext SLIT("let {")) 2 (pprGenStgBinding bind),
 709            hang (ptext SLIT("} in ")) 2 (ppr expr)]
 710
 711 pprStgExpr (StgLetNoEscape lvs_whole lvs_rhss bind expr)
 712   = sep [hang (ptext SLIT("let-no-escape {"))
 713                 2 (pprGenStgBinding bind),
 714            hang ((<>) (ptext SLIT("} in "))
 715                    (ifPprDebug (
 716                     nest 4 (
 717                       hcat [ptext  SLIT("-- lvs: ["), interppSP (uniqSetToList lvs_whole),
 718                              ptext SLIT("]; rhs lvs: ["), interppSP (uniqSetToList lvs_rhss),
 719                              char ']']))))
 720                 2 (ppr expr)]
 721
 722 pprStgExpr (StgSCC cc expr)
 723   = sep [ hsep [ptext SLIT("_scc_"), ppr cc],
 724           pprStgExpr expr ]
 725
 726 pprStgExpr (StgCase expr lvs_whole lvs_rhss bndr srt alt_type alts)
 727   = sep [sep [ptext SLIT("case"),
 728            nest 4 (hsep [pprStgExpr expr,
 729              ifPprDebug (dcolon <+> ppr alt_type)]),
 730            ptext SLIT("of"), ppr bndr, char '{'],
 731            ifPprDebug (
 732            nest 4 (
 733              hcat [ptext  SLIT("-- lvs: ["), interppSP (uniqSetToList lvs_whole),
 734                     ptext SLIT("]; rhs lvs: ["), interppSP (uniqSetToList lvs_rhss),
 735                     ptext SLIT("]; "),
 736                     pprMaybeSRT srt])),
 737            nest 2 (vcat (map pprStgAlt alts)),
 738            char '}']
 739
 740 pprStgAlt (con, params, use_mask, expr)
 741   = hang (hsep [ppr con, interppSP params, ptext SLIT("->")])
 742          4 (ppr expr <> semi)
 743
 744 pprStgOp (StgPrimOp  op)   = ppr op
 745 pprStgOp (StgFCallOp op _) = ppr op
 746
 747 instance Outputable AltType where
 748   ppr PolyAlt        = ptext SLIT("Polymorphic")
 749   ppr (UbxTupAlt tc) = ptext SLIT("UbxTup") <+> ppr tc
 750   ppr (AlgAlt tc)    = ptext SLIT("Alg")    <+> ppr tc
 751   ppr (PrimAlt tc)   = ptext SLIT("Prim")   <+> ppr tc
 752 \end{code}
 753
 754 \begin{code}
 755 pprStgLVs :: Outputable occ => GenStgLiveVars occ -> SDoc
 756 pprStgLVs lvs
 757   = getPprStyle $ \ sty ->
 758     if userStyle sty || isEmptyUniqSet lvs then
 759         empty
 760     else
 761         hcat [text "{-lvs:", interpp'SP (uniqSetToList lvs), text "-}"]
 762 \end{code}
 763
 764 \begin{code}
 765 pprStgRhs :: (Outputable bndr, Outputable bdee, Ord bdee)
 766           => GenStgRhs bndr bdee -> SDoc
 767
 768 -- special case
 769 pprStgRhs (StgRhsClosure cc bi [free_var] upd_flag srt [{-no args-}] (StgApp func []))
 770   = hcat [ ppr cc,
 771            pp_binder_info bi,
 772            brackets (ifPprDebug (ppr free_var)),
 773            ptext SLIT(" \\"), ppr upd_flag, pprMaybeSRT srt, ptext SLIT(" [] "), ppr func ]
 774
 775 -- general case
 776 pprStgRhs (StgRhsClosure cc bi free_vars upd_flag srt args body)
 777   = hang (hsep [if opt_SccProfilingOn then ppr cc else empty,
 778                 pp_binder_info bi,
 779                 ifPprDebug (brackets (interppSP free_vars)),
 780                 char '\\' <> ppr upd_flag, pprMaybeSRT srt, brackets (interppSP args)])
 781          4 (ppr body)
 782
 783 pprStgRhs (StgRhsCon cc con args)
 784   = hcat [ ppr cc,
 785            space, ppr con, ptext SLIT("! "), brackets (interppSP args)]
 786
 787 pprMaybeSRT (NoSRT) = empty
 788 pprMaybeSRT srt     = ptext SLIT("srt:") <> pprSRT srt
 789 \end{code}