ghc/compiler/stranal/DmdAnal.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4
   5                         -----------------
   6                         A demand analysis
   7                         -----------------
   8
   9 \begin{code}
  10 module DmdAnal ( dmdAnalPgm, dmdAnalTopRhs,
  11                  both {- needed by WwLib -}
  12    ) where
  13
  14 #include "HsVersions.h"
  15
  16 import DynFlags         ( DynFlags, DynFlag(..) )
  17 import StaticFlags      ( opt_MaxWorkerArgs )
  18 import NewDemand        -- All of it
  19 import CoreSyn
  20 import PprCore
  21 import CoreUtils        ( exprIsHNF, exprIsTrivial, exprArity )
  22 import DataCon          ( dataConTyCon )
  23 import TyCon            ( isProductTyCon, isRecursiveTyCon )
  24 import Id               ( Id, idType, idInlinePragma,
  25                           isDataConWorkId, isGlobalId, idArity,
  26 #ifdef OLD_STRICTNESS
  27                           idDemandInfo,  idStrictness, idCprInfo, idName,
  28 #endif
  29                           idNewStrictness, idNewStrictness_maybe,
  30                           setIdNewStrictness, idNewDemandInfo,
  31                           idNewDemandInfo_maybe,
  32                           setIdNewDemandInfo
  33                         )
  34 #ifdef OLD_STRICTNESS
  35 import IdInfo           ( newStrictnessFromOld, newDemand )
  36 #endif
  37 import Var              ( Var )
  38 import VarEnv
  39 import TysWiredIn       ( unboxedPairDataCon )
  40 import TysPrim          ( realWorldStatePrimTy )
  41 import UniqFM           ( plusUFM_C, addToUFM_Directly, lookupUFM_Directly,
  42                           keysUFM, minusUFM, ufmToList, filterUFM )
  43 import Type             ( isUnLiftedType, coreEqType )
  44 import CoreLint         ( showPass, endPass )
  45 import Util             ( mapAndUnzip, mapAccumL, mapAccumR, lengthIs )
  46 import BasicTypes       ( Arity, TopLevelFlag(..), isTopLevel, isNeverActive,
  47                           RecFlag(..), isRec )
  48 import Maybes           ( orElse, expectJust )
  49 import Outputable
  50 \end{code}
  51
  52 To think about
  53
  54 * set a noinline pragma on bottoming Ids
  55
  56 * Consider f x = x+1 `fatbar` error (show x)
  57   We'd like to unbox x, even if that means reboxing it in the error case.
  58
  59
  60 %************************************************************************
  61 %*                                                                      *
  62 \subsection{Top level stuff}
  63 %*                                                                      *
  64 %************************************************************************
  65
  66 \begin{code}
  67 dmdAnalPgm :: DynFlags -> [CoreBind] -> IO [CoreBind]
  68 dmdAnalPgm dflags binds
  69   = do {
  70         showPass dflags "Demand analysis" ;
  71         let { binds_plus_dmds = do_prog binds } ;
  72
  73         endPass dflags "Demand analysis"
  74                 Opt_D_dump_stranal binds_plus_dmds ;
  75 #ifdef OLD_STRICTNESS
  76         -- Only if OLD_STRICTNESS is on, because only then is the old
  77         -- strictness analyser run
  78         let { dmd_changes = get_changes binds_plus_dmds } ;
  79         printDump (text "Changes in demands" $$ dmd_changes) ;
  80 #endif
  81         return binds_plus_dmds
  82     }
  83   where
  84     do_prog :: [CoreBind] -> [CoreBind]
  85     do_prog binds = snd $ mapAccumL dmdAnalTopBind emptySigEnv binds
  86
  87 dmdAnalTopBind :: SigEnv
  88                -> CoreBind
  89                -> (SigEnv, CoreBind)
  90 dmdAnalTopBind sigs (NonRec id rhs)
  91   = let
  92         (    _, _, (_,   rhs1)) = dmdAnalRhs TopLevel NonRecursive sigs (id, rhs)
  93         (sigs2, _, (id2, rhs2)) = dmdAnalRhs TopLevel NonRecursive sigs (id, rhs1)
  94                 -- Do two passes to improve CPR information
  95                 -- See comments with ignore_cpr_info in mk_sig_ty
  96                 -- and with extendSigsWithLam
  97     in
  98     (sigs2, NonRec id2 rhs2)
  99
 100 dmdAnalTopBind sigs (Rec pairs)
 101   = let
 102         (sigs', _, pairs')  = dmdFix TopLevel sigs pairs
 103                 -- We get two iterations automatically
 104                 -- c.f. the NonRec case above
 105     in
 106     (sigs', Rec pairs')
 107 \end{code}
 108
 109 \begin{code}
 110 dmdAnalTopRhs :: CoreExpr -> (StrictSig, CoreExpr)
 111 -- Analyse the RHS and return
 112 --      a) appropriate strictness info
 113 --      b) the unfolding (decorated with stricntess info)
 114 dmdAnalTopRhs rhs
 115   = (sig, rhs2)
 116   where
 117     call_dmd       = vanillaCall (exprArity rhs)
 118     (_,      rhs1) = dmdAnal emptySigEnv call_dmd rhs
 119     (rhs_ty, rhs2) = dmdAnal emptySigEnv call_dmd rhs1
 120     sig            = mkTopSigTy rhs rhs_ty
 121         -- Do two passes; see notes with extendSigsWithLam
 122         -- Otherwise we get bogus CPR info for constructors like
 123         --      newtype T a = MkT a
 124         -- The constructor looks like (\x::T a -> x), modulo the coerce
 125         -- extendSigsWithLam will optimistically give x a CPR tag the
 126         -- first time, which is wrong in the end.
 127 \end{code}
 128
 129 %************************************************************************
 130 %*                                                                      *
 131 \subsection{The analyser itself}
 132 %*                                                                      *
 133 %************************************************************************
 134
 135 \begin{code}
 136 dmdAnal :: SigEnv -> Demand -> CoreExpr -> (DmdType, CoreExpr)
 137
 138 dmdAnal sigs Abs  e = (topDmdType, e)
 139
 140 dmdAnal sigs dmd e
 141   | not (isStrictDmd dmd)
 142   = let
 143         (res_ty, e') = dmdAnal sigs evalDmd e
 144     in
 145     (deferType res_ty, e')
 146         -- It's important not to analyse e with a lazy demand because
 147         -- a) When we encounter   case s of (a,b) ->
 148         --      we demand s with U(d1d2)... but if the overall demand is lazy
 149         --      that is wrong, and we'd need to reduce the demand on s,
 150         --      which is inconvenient
 151         -- b) More important, consider
 152         --      f (let x = R in x+x), where f is lazy
 153         --    We still want to mark x as demanded, because it will be when we
 154         --    enter the let.  If we analyse f's arg with a Lazy demand, we'll
 155         --    just mark x as Lazy
 156         -- c) The application rule wouldn't be right either
 157         --    Evaluating (f x) in a L demand does *not* cause
 158         --    evaluation of f in a C(L) demand!
 159
 160
 161 dmdAnal sigs dmd (Lit lit)
 162   = (topDmdType, Lit lit)
 163
 164 dmdAnal sigs dmd (Var var)
 165   = (dmdTransform sigs var dmd, Var var)
 166
 167 dmdAnal sigs dmd (Note n e)
 168   = (dmd_ty, Note n e')
 169   where
 170     (dmd_ty, e') = dmdAnal sigs dmd' e
 171     dmd' = case n of
 172              Coerce _ _ -> evalDmd  -- This coerce usually arises from a recursive
 173              other      -> dmd      -- newtype, and we don't want to look inside them
 174                                     -- for exactly the same reason that we don't look
 175                                     -- inside recursive products -- we might not reach
 176                                     -- a fixpoint.  So revert to a vanilla Eval demand
 177
 178 dmdAnal sigs dmd (App fun (Type ty))
 179   = (fun_ty, App fun' (Type ty))
 180   where
 181     (fun_ty, fun') = dmdAnal sigs dmd fun
 182
 183 -- Lots of the other code is there to make this
 184 -- beautiful, compositional, application rule :-)
 185 dmdAnal sigs dmd e@(App fun arg)        -- Non-type arguments
 186   = let                         -- [Type arg handled above]
 187         (fun_ty, fun')    = dmdAnal sigs (Call dmd) fun
 188         (arg_ty, arg')    = dmdAnal sigs arg_dmd arg
 189         (arg_dmd, res_ty) = splitDmdTy fun_ty
 190     in
 191     (res_ty `bothType` arg_ty, App fun' arg')
 192
 193 dmdAnal sigs dmd (Lam var body)
 194   | isTyVar var
 195   = let
 196         (body_ty, body') = dmdAnal sigs dmd body
 197     in
 198     (body_ty, Lam var body')
 199
 200   | Call body_dmd <- dmd        -- A call demand: good!
 201   = let
 202         sigs'            = extendSigsWithLam sigs var
 203         (body_ty, body') = dmdAnal sigs' body_dmd body
 204         (lam_ty, var')   = annotateLamIdBndr body_ty var
 205     in
 206     (lam_ty, Lam var' body')
 207
 208   | otherwise   -- Not enough demand on the lambda; but do the body
 209   = let         -- anyway to annotate it and gather free var info
 210         (body_ty, body') = dmdAnal sigs evalDmd body
 211         (lam_ty, var')   = annotateLamIdBndr body_ty var
 212     in
 213     (deferType lam_ty, Lam var' body')
 214
 215 dmdAnal sigs dmd (Case scrut case_bndr ty [alt@(DataAlt dc,bndrs,rhs)])
 216   | let tycon = dataConTyCon dc,
 217     isProductTyCon tycon,
 218     not (isRecursiveTyCon tycon)
 219   = let
 220         sigs_alt              = extendSigEnv NotTopLevel sigs case_bndr case_bndr_sig
 221         (alt_ty, alt')        = dmdAnalAlt sigs_alt dmd alt
 222         (alt_ty1, case_bndr') = annotateBndr alt_ty case_bndr
 223         (_, bndrs', _)        = alt'
 224         case_bndr_sig         = cprSig
 225                 -- Inside the alternative, the case binder has the CPR property.
 226                 -- Meaning that a case on it will successfully cancel.
 227                 -- Example:
 228                 --      f True  x = case x of y { I# x' -> if x' ==# 3 then y else I# 8 }
 229                 --      f False x = I# 3
 230                 --
 231                 -- We want f to have the CPR property:
 232                 --      f b x = case fw b x of { r -> I# r }
 233                 --      fw True  x = case x of y { I# x' -> if x' ==# 3 then x' else 8 }
 234                 --      fw False x = 3
 235
 236         -- Figure out whether the demand on the case binder is used, and use
 237         -- that to set the scrut_dmd.  This is utterly essential.
 238         -- Consider     f x = case x of y { (a,b) -> k y a }
 239         -- If we just take scrut_demand = U(L,A), then we won't pass x to the
 240         -- worker, so the worker will rebuild
 241         --      x = (a, absent-error)
 242         -- and that'll crash.
 243         -- So at one stage I had:
 244         --      dead_case_bndr           = isAbsentDmd (idNewDemandInfo case_bndr')
 245         --      keepity | dead_case_bndr = Drop
 246         --              | otherwise      = Keep
 247         --
 248         -- But then consider
 249         --      case x of y { (a,b) -> h y + a }
 250         -- where h : U(LL) -> T
 251         -- The above code would compute a Keep for x, since y is not Abs, which is silly
 252         -- The insight is, of course, that a demand on y is a demand on the
 253         -- scrutinee, so we need to `both` it with the scrut demand
 254
 255         scrut_dmd          = Eval (Prod [idNewDemandInfo b | b <- bndrs', isId b])
 256                                    `both`
 257                              idNewDemandInfo case_bndr'
 258
 259         (scrut_ty, scrut') = dmdAnal sigs scrut_dmd scrut
 260     in
 261     (alt_ty1 `bothType` scrut_ty, Case scrut' case_bndr' ty [alt'])
 262
 263 dmdAnal sigs dmd (Case scrut case_bndr ty alts)
 264   = let
 265         (alt_tys, alts')        = mapAndUnzip (dmdAnalAlt sigs dmd) alts
 266         (scrut_ty, scrut')      = dmdAnal sigs evalDmd scrut
 267         (alt_ty, case_bndr')    = annotateBndr (foldr1 lubType alt_tys) case_bndr
 268     in
 269 --    pprTrace "dmdAnal:Case" (ppr alts $$ ppr alt_tys)
 270     (alt_ty `bothType` scrut_ty, Case scrut' case_bndr' ty alts')
 271
 272 dmdAnal sigs dmd (Let (NonRec id rhs) body)
 273   = let
 274         (sigs', lazy_fv, (id1, rhs')) = dmdAnalRhs NotTopLevel NonRecursive sigs (id, rhs)
 275         (body_ty, body')              = dmdAnal sigs' dmd body
 276         (body_ty1, id2)               = annotateBndr body_ty id1
 277         body_ty2                      = addLazyFVs body_ty1 lazy_fv
 278     in
 279         -- If the actual demand is better than the vanilla call
 280         -- demand, you might think that we might do better to re-analyse
 281         -- the RHS with the stronger demand.
 282         -- But (a) That seldom happens, because it means that *every* path in
 283         --         the body of the let has to use that stronger demand
 284         -- (b) It often happens temporarily in when fixpointing, because
 285         --     the recursive function at first seems to place a massive demand.
 286         --     But we don't want to go to extra work when the function will
 287         --     probably iterate to something less demanding.
 288         -- In practice, all the times the actual demand on id2 is more than
 289         -- the vanilla call demand seem to be due to (b).  So we don't
 290         -- bother to re-analyse the RHS.
 291     (body_ty2, Let (NonRec id2 rhs') body')
 292
 293 dmdAnal sigs dmd (Let (Rec pairs) body)
 294   = let
 295         bndrs                    = map fst pairs
 296         (sigs', lazy_fv, pairs') = dmdFix NotTopLevel sigs pairs
 297         (body_ty, body')         = dmdAnal sigs' dmd body
 298         body_ty1                 = addLazyFVs body_ty lazy_fv
 299     in
 300     sigs' `seq` body_ty `seq`
 301     let
 302         (body_ty2, _) = annotateBndrs body_ty1 bndrs
 303                 -- Don't bother to add demand info to recursive
 304                 -- binders as annotateBndr does;
 305                 -- being recursive, we can't treat them strictly.
 306                 -- But we do need to remove the binders from the result demand env
 307     in
 308     (body_ty2,  Let (Rec pairs') body')
 309
 310
 311 dmdAnalAlt sigs dmd (con,bndrs,rhs)
 312   = let
 313         (rhs_ty, rhs')   = dmdAnal sigs dmd rhs
 314         (alt_ty, bndrs') = annotateBndrs rhs_ty bndrs
 315         final_alt_ty | io_hack_reqd = alt_ty `lubType` topDmdType
 316                      | otherwise    = alt_ty
 317
 318         -- There's a hack here for I/O operations.  Consider
 319         --      case foo x s of { (# s, r #) -> y }
 320         -- Is this strict in 'y'.  Normally yes, but what if 'foo' is an I/O
 321         -- operation that simply terminates the program (not in an erroneous way)?
 322         -- In that case we should not evaluate y before the call to 'foo'.
 323         -- Hackish solution: spot the IO-like situation and add a virtual branch,
 324         -- as if we had
 325         --      case foo x s of
 326         --         (# s, r #) -> y
 327         --         other      -> return ()
 328         -- So the 'y' isn't necessarily going to be evaluated
 329         --
 330         -- A more complete example where this shows up is:
 331         --      do { let len = <expensive> ;
 332         --         ; when (...) (exitWith ExitSuccess)
 333         --         ; print len }
 334
 335         io_hack_reqd = con == DataAlt unboxedPairDataCon &&
 336                        idType (head bndrs) `coreEqType` realWorldStatePrimTy
 337     in
 338     (final_alt_ty, (con, bndrs', rhs'))
 339 \end{code}
 340
 341 %************************************************************************
 342 %*                                                                      *
 343 \subsection{Bindings}
 344 %*                                                                      *
 345 %************************************************************************
 346
 347 \begin{code}
 348 dmdFix :: TopLevelFlag
 349        -> SigEnv                -- Does not include bindings for this binding
 350        -> [(Id,CoreExpr)]
 351        -> (SigEnv, DmdEnv,
 352            [(Id,CoreExpr)])     -- Binders annotated with stricness info
 353
 354 dmdFix top_lvl sigs orig_pairs
 355   = loop 1 initial_sigs orig_pairs
 356   where
 357     bndrs        = map fst orig_pairs
 358     initial_sigs = extendSigEnvList sigs [(id, (initialSig id, top_lvl)) | id <- bndrs]
 359
 360     loop :: Int
 361          -> SigEnv                      -- Already contains the current sigs
 362          -> [(Id,CoreExpr)]
 363          -> (SigEnv, DmdEnv, [(Id,CoreExpr)])
 364     loop n sigs pairs
 365       | found_fixpoint
 366       = (sigs', lazy_fv, pairs')
 367                 -- Note: use pairs', not pairs.   pairs' is the result of
 368                 -- processing the RHSs with sigs (= sigs'), whereas pairs
 369                 -- is the result of processing the RHSs with the *previous*
 370                 -- iteration of sigs.
 371
 372       | n >= 10  = pprTrace "dmdFix loop" (ppr n <+> (vcat
 373                                 [ text "Sigs:" <+> ppr [(id,lookup sigs id, lookup sigs' id) | (id,_) <- pairs],
 374                                   text "env:" <+> ppr (ufmToList sigs),
 375                                   text "binds:" <+> pprCoreBinding (Rec pairs)]))
 376                               (emptySigEnv, lazy_fv, orig_pairs)        -- Safe output
 377                         -- The lazy_fv part is really important!  orig_pairs has no strictness
 378                         -- info, including nothing about free vars.  But if we have
 379                         --      letrec f = ....y..... in ...f...
 380                         -- where 'y' is free in f, we must record that y is mentioned,
 381                         -- otherwise y will get recorded as absent altogether
 382
 383       | otherwise    = loop (n+1) sigs' pairs'
 384       where
 385         found_fixpoint = all (same_sig sigs sigs') bndrs
 386                 -- Use the new signature to do the next pair
 387                 -- The occurrence analyser has arranged them in a good order
 388                 -- so this can significantly reduce the number of iterations needed
 389         ((sigs',lazy_fv), pairs') = mapAccumL (my_downRhs top_lvl) (sigs, emptyDmdEnv) pairs
 390
 391     my_downRhs top_lvl (sigs,lazy_fv) (id,rhs)
 392         = -- pprTrace "downRhs {" (ppr id <+> (ppr old_sig))
 393           -- (new_sig `seq`
 394           --    pprTrace "downRhsEnd" (ppr id <+> ppr new_sig <+> char '}' )
 395           ((sigs', lazy_fv'), pair')
 396           --     )
 397         where
 398           (sigs', lazy_fv1, pair') = dmdAnalRhs top_lvl Recursive sigs (id,rhs)
 399           lazy_fv'                 = plusUFM_C both lazy_fv lazy_fv1
 400           -- old_sig               = lookup sigs id
 401           -- new_sig               = lookup sigs' id
 402
 403     same_sig sigs sigs' var = lookup sigs var == lookup sigs' var
 404     lookup sigs var = case lookupVarEnv sigs var of
 405                         Just (sig,_) -> sig
 406
 407         -- Get an initial strictness signature from the Id
 408         -- itself.  That way we make use of earlier iterations
 409         -- of the fixpoint algorithm.  (Cunning plan.)
 410         -- Note that the cunning plan extends to the DmdEnv too,
 411         -- since it is part of the strictness signature
 412 initialSig id = idNewStrictness_maybe id `orElse` botSig
 413
 414 dmdAnalRhs :: TopLevelFlag -> RecFlag
 415         -> SigEnv -> (Id, CoreExpr)
 416         -> (SigEnv,  DmdEnv, (Id, CoreExpr))
 417 -- Process the RHS of the binding, add the strictness signature
 418 -- to the Id, and augment the environment with the signature as well.
 419
 420 dmdAnalRhs top_lvl rec_flag sigs (id, rhs)
 421  = (sigs', lazy_fv, (id', rhs'))
 422  where
 423   arity              = idArity id   -- The idArity should be up to date
 424                                     -- The simplifier was run just beforehand
 425   (rhs_dmd_ty, rhs') = dmdAnal sigs (vanillaCall arity) rhs
 426   (lazy_fv, sig_ty)  = WARN( arity /= dmdTypeDepth rhs_dmd_ty && not (exprIsTrivial rhs), ppr id )
 427                                 -- The RHS can be eta-reduced to just a variable,
 428                                 -- in which case we should not complain.
 429                        mkSigTy top_lvl rec_flag id rhs rhs_dmd_ty
 430   id'                = id `setIdNewStrictness` sig_ty
 431   sigs'              = extendSigEnv top_lvl sigs id sig_ty
 432 \end{code}
 433
 434 %************************************************************************
 435 %*                                                                      *
 436 \subsection{Strictness signatures and types}
 437 %*                                                                      *
 438 %************************************************************************
 439
 440 \begin{code}
 441 mkTopSigTy :: CoreExpr -> DmdType -> StrictSig
 442         -- Take a DmdType and turn it into a StrictSig
 443         -- NB: not used for never-inline things; hence False
 444 mkTopSigTy rhs dmd_ty = snd (mk_sig_ty False False rhs dmd_ty)
 445
 446 mkSigTy :: TopLevelFlag -> RecFlag -> Id -> CoreExpr -> DmdType -> (DmdEnv, StrictSig)
 447 mkSigTy top_lvl rec_flag id rhs dmd_ty
 448   = mk_sig_ty never_inline thunk_cpr_ok rhs dmd_ty
 449   where
 450     never_inline = isNeverActive (idInlinePragma id)
 451     maybe_id_dmd = idNewDemandInfo_maybe id
 452         -- Is Nothing the first time round
 453
 454     thunk_cpr_ok
 455         | isTopLevel top_lvl       = False      -- Top level things don't get
 456                                                 -- their demandInfo set at all
 457         | isRec rec_flag           = False      -- Ditto recursive things
 458         | Just dmd <- maybe_id_dmd = isStrictDmd dmd
 459         | otherwise                = True       -- Optimistic, first time round
 460                                                 -- See notes below
 461 \end{code}
 462
 463 The thunk_cpr_ok stuff [CPR-AND-STRICTNESS]
 464 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 465 If the rhs is a thunk, we usually forget the CPR info, because
 466 it is presumably shared (else it would have been inlined, and
 467 so we'd lose sharing if w/w'd it into a function.
 468
 469 However, if the strictness analyser has figured out (in a previous
 470 iteration) that it's strict, then we DON'T need to forget the CPR info.
 471 Instead we can retain the CPR info and do the thunk-splitting transform
 472 (see WorkWrap.splitThunk).
 473
 474 This made a big difference to PrelBase.modInt, which had something like
 475         modInt = \ x -> let r = ... -> I# v in
 476                         ...body strict in r...
 477 r's RHS isn't a value yet; but modInt returns r in various branches, so
 478 if r doesn't have the CPR property then neither does modInt
 479 Another case I found in practice (in Complex.magnitude), looks like this:
 480                 let k = if ... then I# a else I# b
 481                 in ... body strict in k ....
 482 (For this example, it doesn't matter whether k is returned as part of
 483 the overall result; but it does matter that k's RHS has the CPR property.)
 484 Left to itself, the simplifier will make a join point thus:
 485                 let $j k = ...body strict in k...
 486                 if ... then $j (I# a) else $j (I# b)
 487 With thunk-splitting, we get instead
 488                 let $j x = let k = I#x in ...body strict in k...
 489                 in if ... then $j a else $j b
 490 This is much better; there's a good chance the I# won't get allocated.
 491
 492 The difficulty with this is that we need the strictness type to
 493 look at the body... but we now need the body to calculate the demand
 494 on the variable, so we can decide whether its strictness type should
 495 have a CPR in it or not.  Simple solution:
 496         a) use strictness info from the previous iteration
 497         b) make sure we do at least 2 iterations, by doing a second
 498            round for top-level non-recs.  Top level recs will get at
 499            least 2 iterations except for totally-bottom functions
 500            which aren't very interesting anyway.
 501
 502 NB: strictly_demanded is never true of a top-level Id, or of a recursive Id.
 503
 504 The Nothing case in thunk_cpr_ok [CPR-AND-STRICTNESS]
 505 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 506 Demand info now has a 'Nothing' state, just like strictness info.
 507 The analysis works from 'dangerous' towards a 'safe' state; so we
 508 start with botSig for 'Nothing' strictness infos, and we start with
 509 "yes, it's demanded" for 'Nothing' in the demand info.  The
 510 fixpoint iteration will sort it all out.
 511
 512 We can't start with 'not-demanded' because then consider
 513         f x = let
 514                   t = ... I# x
 515               in
 516               if ... then t else I# y else f x'
 517
 518 In the first iteration we'd have no demand info for x, so assume
 519 not-demanded; then we'd get TopRes for f's CPR info.  Next iteration
 520 we'd see that t was demanded, and so give it the CPR property, but by
 521 now f has TopRes, so it will stay TopRes.  Instead, with the Nothing
 522 setting the first time round, we say 'yes t is demanded' the first
 523 time.
 524
 525 However, this does mean that for non-recursive bindings we must
 526 iterate twice to be sure of not getting over-optimistic CPR info,
 527 in the case where t turns out to be not-demanded.  This is handled
 528 by dmdAnalTopBind.
 529
 530
 531 \begin{code}
 532 mk_sig_ty never_inline thunk_cpr_ok rhs (DmdType fv dmds res)
 533   | never_inline && not (isBotRes res)
 534         --                      HACK ALERT
 535         -- Don't strictness-analyse NOINLINE things.  Why not?  Because
 536         -- the NOINLINE says "don't expose any of the inner workings at the call
 537         -- site" and the strictness is certainly an inner working.
 538         --
 539         -- More concretely, the demand analyser discovers the following strictness
 540         -- for unsafePerformIO:  C(U(AV))
 541         -- But then consider
 542         --      unsafePerformIO (\s -> let r = f x in
 543         --                             case writeIORef v r s of (# s1, _ #) ->
 544         --                             (# s1, r #)
 545         -- The strictness analyser will find that the binding for r is strict,
 546         -- (becuase of uPIO's strictness sig), and so it'll evaluate it before
 547         -- doing the writeIORef.  This actually makes tests/lib/should_run/memo002
 548         -- get a deadlock!
 549         --
 550         -- Solution: don't expose the strictness of unsafePerformIO.
 551         --
 552         -- But we do want to expose the strictness of error functions,
 553         -- which are also often marked NOINLINE
 554         --      {-# NOINLINE foo #-}
 555         --      foo x = error ("wubble buggle" ++ x)
 556         -- So (hack, hack) we only drop the strictness for non-bottom things
 557         -- This is all very unsatisfactory.
 558   = (deferEnv fv, topSig)
 559
 560   | otherwise
 561   = (lazy_fv, mkStrictSig dmd_ty)
 562   where
 563     dmd_ty = DmdType strict_fv final_dmds res'
 564
 565     lazy_fv   = filterUFM (not . isStrictDmd) fv
 566     strict_fv = filterUFM isStrictDmd         fv
 567         -- We put the strict FVs in the DmdType of the Id, so
 568         -- that at its call sites we unleash demands on its strict fvs.
 569         -- An example is 'roll' in imaginary/wheel-sieve2
 570         -- Something like this:
 571         --      roll x = letrec
 572         --                   go y = if ... then roll (x-1) else x+1
 573         --               in
 574         --               go ms
 575         -- We want to see that roll is strict in x, which is because
 576         -- go is called.   So we put the DmdEnv for x in go's DmdType.
 577         --
 578         -- Another example:
 579         --      f :: Int -> Int -> Int
 580         --      f x y = let t = x+1
 581         --          h z = if z==0 then t else
 582         --                if z==1 then x+1 else
 583         --                x + h (z-1)
 584         --      in
 585         --      h y
 586         -- Calling h does indeed evaluate x, but we can only see
 587         -- that if we unleash a demand on x at the call site for t.
 588         --
 589         -- Incidentally, here's a place where lambda-lifting h would
 590         -- lose the cigar --- we couldn't see the joint strictness in t/x
 591         --
 592         --      ON THE OTHER HAND
 593         -- We don't want to put *all* the fv's from the RHS into the
 594         -- DmdType, because that makes fixpointing very slow --- the
 595         -- DmdType gets full of lazy demands that are slow to converge.
 596
 597     final_dmds = setUnpackStrategy dmds
 598         -- Set the unpacking strategy
 599
 600     res' = case res of
 601                 RetCPR | ignore_cpr_info -> TopRes
 602                 other                    -> res
 603     ignore_cpr_info = not (exprIsHNF rhs || thunk_cpr_ok)
 604 \end{code}
 605
 606 The unpack strategy determines whether we'll *really* unpack the argument,
 607 or whether we'll just remember its strictness.  If unpacking would give
 608 rise to a *lot* of worker args, we may decide not to unpack after all.
 609
 610 \begin{code}
 611 setUnpackStrategy :: [Demand] -> [Demand]
 612 setUnpackStrategy ds
 613   = snd (go (opt_MaxWorkerArgs - nonAbsentArgs ds) ds)
 614   where
 615     go :: Int                   -- Max number of args available for sub-components of [Demand]
 616        -> [Demand]
 617        -> (Int, [Demand])       -- Args remaining after subcomponents of [Demand] are unpacked
 618
 619     go n (Eval (Prod cs) : ds)
 620         | n' >= 0   = Eval (Prod cs') `cons` go n'' ds
 621         | otherwise = Box (Eval (Prod cs)) `cons` go n ds
 622         where
 623           (n'',cs') = go n' cs
 624           n' = n + 1 - non_abs_args
 625                 -- Add one to the budget 'cos we drop the top-level arg
 626           non_abs_args = nonAbsentArgs cs
 627                 -- Delete # of non-absent args to which we'll now be committed
 628
 629     go n (d:ds) = d `cons` go n ds
 630     go n []     = (n,[])
 631
 632     cons d (n,ds) = (n, d:ds)
 633
 634 nonAbsentArgs :: [Demand] -> Int
 635 nonAbsentArgs []         = 0
 636 nonAbsentArgs (Abs : ds) = nonAbsentArgs ds
 637 nonAbsentArgs (d   : ds) = 1 + nonAbsentArgs ds
 638 \end{code}
 639
 640
 641 %************************************************************************
 642 %*                                                                      *
 643 \subsection{Strictness signatures and types}
 644 %*                                                                      *
 645 %************************************************************************
 646
 647 \begin{code}
 648 splitDmdTy :: DmdType -> (Demand, DmdType)
 649 -- Split off one function argument
 650 -- We already have a suitable demand on all
 651 -- free vars, so no need to add more!
 652 splitDmdTy (DmdType fv (dmd:dmds) res_ty) = (dmd, DmdType fv dmds res_ty)
 653 splitDmdTy ty@(DmdType fv [] res_ty)      = (resTypeArgDmd res_ty, ty)
 654 \end{code}
 655
 656 \begin{code}
 657 unitVarDmd var dmd = DmdType (unitVarEnv var dmd) [] TopRes
 658
 659 addVarDmd top_lvl dmd_ty@(DmdType fv ds res) var dmd
 660   | isTopLevel top_lvl = dmd_ty         -- Don't record top level things
 661   | otherwise          = DmdType (extendVarEnv fv var dmd) ds res
 662
 663 addLazyFVs (DmdType fv ds res) lazy_fvs
 664   = DmdType both_fv1 ds res
 665   where
 666     both_fv = (plusUFM_C both fv lazy_fvs)
 667     both_fv1 = modifyEnv (isBotRes res) (`both` Bot) lazy_fvs fv both_fv
 668         -- This modifyEnv is vital.  Consider
 669         --      let f = \x -> (x,y)
 670         --      in  error (f 3)
 671         -- Here, y is treated as a lazy-fv of f, but we must `both` that L
 672         -- demand with the bottom coming up from 'error'
 673         --
 674         -- I got a loop in the fixpointer without this, due to an interaction
 675         -- with the lazy_fv filtering in mkSigTy.  Roughly, it was
 676         --      letrec f n x
 677         --          = letrec g y = x `fatbar`
 678         --                         letrec h z = z + ...g...
 679         --                         in h (f (n-1) x)
 680         --      in ...
 681         -- In the initial iteration for f, f=Bot
 682         -- Suppose h is found to be strict in z, but the occurrence of g in its RHS
 683         -- is lazy.  Now consider the fixpoint iteration for g, esp the demands it
 684         -- places on its free variables.  Suppose it places none.  Then the
 685         --      x `fatbar` ...call to h...
 686         -- will give a x->V demand for x.  That turns into a L demand for x,
 687         -- which floats out of the defn for h.  Without the modifyEnv, that
 688         -- L demand doesn't get both'd with the Bot coming up from the inner
 689         -- call to f.  So we just get an L demand for x for g.
 690         --
 691         -- A better way to say this is that the lazy-fv filtering should give the
 692         -- same answer as putting the lazy fv demands in the function's type.
 693
 694 annotateBndr :: DmdType -> Var -> (DmdType, Var)
 695 -- The returned env has the var deleted
 696 -- The returned var is annotated with demand info
 697 -- No effect on the argument demands
 698 annotateBndr dmd_ty@(DmdType fv ds res) var
 699   | isTyVar var = (dmd_ty, var)
 700   | otherwise   = (DmdType fv' ds res, setIdNewDemandInfo var dmd)
 701   where
 702     (fv', dmd) = removeFV fv var res
 703
 704 annotateBndrs = mapAccumR annotateBndr
 705
 706 annotateLamIdBndr dmd_ty@(DmdType fv ds res) id
 707 -- For lambdas we add the demand to the argument demands
 708 -- Only called for Ids
 709   = ASSERT( isId id )
 710     (DmdType fv' (hacked_dmd:ds) res, setIdNewDemandInfo id hacked_dmd)
 711   where
 712     (fv', dmd) = removeFV fv id res
 713     hacked_dmd = argDemand dmd
 714         -- This call to argDemand is vital, because otherwise we label
 715         -- a lambda binder with demand 'B'.  But in terms of calling
 716         -- conventions that's Abs, because we don't pass it.  But
 717         -- when we do a w/w split we get
 718         --      fw x = (\x y:B -> ...) x (error "oops")
 719         -- And then the simplifier things the 'B' is a strict demand
 720         -- and evaluates the (error "oops").  Sigh
 721
 722 removeFV fv id res = (fv', zapUnlifted id dmd)
 723                 where
 724                   fv' = fv `delVarEnv` id
 725                   dmd = lookupVarEnv fv id `orElse` deflt
 726                   deflt | isBotRes res = Bot
 727                         | otherwise    = Abs
 728
 729 -- For unlifted-type variables, we are only
 730 -- interested in Bot/Abs/Box Abs
 731 zapUnlifted is Bot = Bot
 732 zapUnlifted id Abs = Abs
 733 zapUnlifted id dmd | isUnLiftedType (idType id) = lazyDmd
 734                    | otherwise                  = dmd
 735 \end{code}
 736
 737 %************************************************************************
 738 %*                                                                      *
 739 \subsection{Strictness signatures}
 740 %*                                                                      *
 741 %************************************************************************
 742
 743 \begin{code}
 744 type SigEnv  = VarEnv (StrictSig, TopLevelFlag)
 745         -- We use the SigEnv to tell us whether to
 746         -- record info about a variable in the DmdEnv
 747         -- We do so if it's a LocalId, but not top-level
 748         --
 749         -- The DmdEnv gives the demand on the free vars of the function
 750         -- when it is given enough args to satisfy the strictness signature
 751
 752 emptySigEnv  = emptyVarEnv
 753
 754 extendSigEnv :: TopLevelFlag -> SigEnv -> Id -> StrictSig -> SigEnv
 755 extendSigEnv top_lvl env var sig = extendVarEnv env var (sig, top_lvl)
 756
 757 extendSigEnvList = extendVarEnvList
 758
 759 extendSigsWithLam :: SigEnv -> Id -> SigEnv
 760 -- Extend the SigEnv when we meet a lambda binder
 761 -- If the binder is marked demanded with a product demand, then give it a CPR
 762 -- signature, because in the likely event that this is a lambda on a fn defn
 763 -- [we only use this when the lambda is being consumed with a call demand],
 764 -- it'll be w/w'd and so it will be CPR-ish.  E.g.
 765 --      f = \x::(Int,Int).  if ...strict in x... then
 766 --                              x
 767 --                          else
 768 --                              (a,b)
 769 -- We want f to have the CPR property because x does, by the time f has been w/w'd
 770 --
 771 -- Also note that we only want to do this for something that
 772 -- definitely has product type, else we may get over-optimistic
 773 -- CPR results (e.g. from \x -> x!).
 774
 775 extendSigsWithLam sigs id
 776   = case idNewDemandInfo_maybe id of
 777         Nothing               -> extendVarEnv sigs id (cprSig, NotTopLevel)
 778                 -- Optimistic in the Nothing case;
 779                 -- See notes [CPR-AND-STRICTNESS]
 780         Just (Eval (Prod ds)) -> extendVarEnv sigs id (cprSig, NotTopLevel)
 781         other                 -> sigs
 782
 783
 784 dmdTransform :: SigEnv          -- The strictness environment
 785              -> Id              -- The function
 786              -> Demand          -- The demand on the function
 787              -> DmdType         -- The demand type of the function in this context
 788         -- Returned DmdEnv includes the demand on
 789         -- this function plus demand on its free variables
 790
 791 dmdTransform sigs var dmd
 792
 793 ------  DATA CONSTRUCTOR
 794   | isDataConWorkId var         -- Data constructor
 795   = let
 796         StrictSig dmd_ty    = idNewStrictness var       -- It must have a strictness sig
 797         DmdType _ _ con_res = dmd_ty
 798         arity               = idArity var
 799     in
 800     if arity == call_depth then         -- Saturated, so unleash the demand
 801         let
 802                 -- Important!  If we Keep the constructor application, then
 803                 -- we need the demands the constructor places (always lazy)
 804                 -- If not, we don't need to.  For example:
 805                 --      f p@(x,y) = (p,y)       -- S(AL)
 806                 --      g a b     = f (a,b)
 807                 -- It's vital that we don't calculate Absent for a!
 808            dmd_ds = case res_dmd of
 809                         Box (Eval ds) -> mapDmds box ds
 810                         Eval ds       -> ds
 811                         other         -> Poly Top
 812
 813                 -- ds can be empty, when we are just seq'ing the thing
 814                 -- If so we must make up a suitable bunch of demands
 815            arg_ds = case dmd_ds of
 816                       Poly d  -> replicate arity d
 817                       Prod ds -> ASSERT( ds `lengthIs` arity ) ds
 818
 819         in
 820         mkDmdType emptyDmdEnv arg_ds con_res
 821                 -- Must remember whether it's a product, hence con_res, not TopRes
 822     else
 823         topDmdType
 824
 825 ------  IMPORTED FUNCTION
 826   | isGlobalId var,             -- Imported function
 827     let StrictSig dmd_ty = idNewStrictness var
 828   = if dmdTypeDepth dmd_ty <= call_depth then   -- Saturated, so unleash the demand
 829         dmd_ty
 830     else
 831         topDmdType
 832
 833 ------  LOCAL LET/REC BOUND THING
 834   | Just (StrictSig dmd_ty, top_lvl) <- lookupVarEnv sigs var
 835   = let
 836         fn_ty | dmdTypeDepth dmd_ty <= call_depth = dmd_ty
 837               | otherwise                         = deferType dmd_ty
 838         -- NB: it's important to use deferType, and not just return topDmdType
 839         -- Consider     let { f x y = p + x } in f 1
 840         -- The application isn't saturated, but we must nevertheless propagate
 841         --      a lazy demand for p!
 842     in
 843     addVarDmd top_lvl fn_ty var dmd
 844
 845 ------  LOCAL NON-LET/REC BOUND THING
 846   | otherwise                   -- Default case
 847   = unitVarDmd var dmd
 848
 849   where
 850     (call_depth, res_dmd) = splitCallDmd dmd
 851 \end{code}
 852
 853
 854 %************************************************************************
 855 %*                                                                      *
 856 \subsection{Demands}
 857 %*                                                                      *
 858 %************************************************************************
 859
 860 \begin{code}
 861 splitCallDmd :: Demand -> (Int, Demand)
 862 splitCallDmd (Call d) = case splitCallDmd d of
 863                           (n, r) -> (n+1, r)
 864 splitCallDmd d        = (0, d)
 865
 866 vanillaCall :: Arity -> Demand
 867 vanillaCall 0 = evalDmd
 868 vanillaCall n = Call (vanillaCall (n-1))
 869
 870 deferType :: DmdType -> DmdType
 871 deferType (DmdType fv _ _) = DmdType (deferEnv fv) [] TopRes
 872         -- Notice that we throw away info about both arguments and results
 873         -- For example,   f = let ... in \x -> x
 874         -- We don't want to get a stricness type V->T for f.
 875         -- Peter??
 876
 877 deferEnv :: DmdEnv -> DmdEnv
 878 deferEnv fv = mapVarEnv defer fv
 879
 880
 881 ----------------
 882 argDemand :: Demand -> Demand
 883 -- The 'Defer' demands are just Lazy at function boundaries
 884 -- Ugly!  Ask John how to improve it.
 885 argDemand Top       = lazyDmd
 886 argDemand (Defer d) = lazyDmd
 887 argDemand (Eval ds) = Eval (mapDmds argDemand ds)
 888 argDemand (Box Bot) = evalDmd
 889 argDemand (Box d)   = box (argDemand d)
 890 argDemand Bot       = Abs       -- Don't pass args that are consumed (only) by bottom
 891 argDemand d         = d
 892 \end{code}
 893
 894 \begin{code}
 895 -------------------------
 896 -- Consider (if x then y else []) with demand V
 897 -- Then the first branch gives {y->V} and the second
 898 --  *implicitly* has {y->A}.  So we must put {y->(V `lub` A)}
 899 -- in the result env.
 900 lubType (DmdType fv1 ds1 r1) (DmdType fv2 ds2 r2)
 901   = DmdType lub_fv2 (lub_ds ds1 ds2) (r1 `lubRes` r2)
 902   where
 903     lub_fv  = plusUFM_C lub fv1 fv2
 904     lub_fv1 = modifyEnv (not (isBotRes r1)) absLub fv2 fv1 lub_fv
 905     lub_fv2 = modifyEnv (not (isBotRes r2)) absLub fv1 fv2 lub_fv1
 906         -- lub is the identity for Bot
 907
 908         -- Extend the shorter argument list to match the longer
 909     lub_ds (d1:ds1) (d2:ds2) = lub d1 d2 : lub_ds ds1 ds2
 910     lub_ds []       []       = []
 911     lub_ds ds1      []       = map (`lub` resTypeArgDmd r2) ds1
 912     lub_ds []       ds2      = map (resTypeArgDmd r1 `lub`) ds2
 913
 914 -----------------------------------
 915 -- (t1 `bothType` t2) takes the argument/result info from t1,
 916 -- using t2 just for its free-var info
 917 -- NB: Don't forget about r2!  It might be BotRes, which is
 918 --     a bottom demand on all the in-scope variables.
 919 -- Peter: can this be done more neatly?
 920 bothType (DmdType fv1 ds1 r1) (DmdType fv2 ds2 r2)
 921   = DmdType both_fv2 ds1 (r1 `bothRes` r2)
 922   where
 923     both_fv  = plusUFM_C both fv1 fv2
 924     both_fv1 = modifyEnv (isBotRes r1) (`both` Bot) fv2 fv1 both_fv
 925     both_fv2 = modifyEnv (isBotRes r2) (`both` Bot) fv1 fv2 both_fv1
 926         -- both is the identity for Abs
 927 \end{code}
 928
 929
 930 \begin{code}
 931 lubRes BotRes r      = r
 932 lubRes r      BotRes = r
 933 lubRes RetCPR RetCPR = RetCPR
 934 lubRes r1     r2     = TopRes
 935
 936 -- If either diverges, the whole thing does
 937 -- Otherwise take CPR info from the first
 938 bothRes r1 BotRes = BotRes
 939 bothRes r1 r2     = r1
 940 \end{code}
 941
 942 \begin{code}
 943 modifyEnv :: Bool                       -- No-op if False
 944           -> (Demand -> Demand)         -- The zapper
 945           -> DmdEnv -> DmdEnv           -- Env1 and Env2
 946           -> DmdEnv -> DmdEnv           -- Transform this env
 947         -- Zap anything in Env1 but not in Env2
 948         -- Assume: dom(env) includes dom(Env1) and dom(Env2)
 949
 950 modifyEnv need_to_modify zapper env1 env2 env
 951   | need_to_modify = foldr zap env (keysUFM (env1 `minusUFM` env2))
 952   | otherwise      = env
 953   where
 954     zap uniq env = addToUFM_Directly env uniq (zapper current_val)
 955                  where
 956                    current_val = expectJust "modifyEnv" (lookupUFM_Directly env uniq)
 957 \end{code}
 958
 959
 960 %************************************************************************
 961 %*                                                                      *
 962 \subsection{LUB and BOTH}
 963 %*                                                                      *
 964 %************************************************************************
 965
 966 \begin{code}
 967 lub :: Demand -> Demand -> Demand
 968
 969 lub Bot         d2 = d2
 970 lub Abs         d2 = absLub d2
 971 lub Top         d2 = Top
 972 lub (Defer ds1) d2 = defer (Eval ds1 `lub` d2)
 973
 974 lub (Call d1)   (Call d2)    = Call (d1 `lub` d2)
 975 lub d1@(Call _) (Box d2)     = d1 `lub` d2      -- Just strip the box
 976 lub d1@(Call _) d2@(Eval _)  = d2               -- Presumably seq or vanilla eval
 977 lub d1@(Call _) d2           = d2 `lub` d1      -- Bot, Abs, Top
 978
 979 -- For the Eval case, we use these approximation rules
 980 -- Box Bot       <= Eval (Box Bot ...)
 981 -- Box Top       <= Defer (Box Bot ...)
 982 -- Box (Eval ds) <= Eval (map Box ds)
 983 lub (Eval ds1)  (Eval ds2)        = Eval (ds1 `lubs` ds2)
 984 lub (Eval ds1)  (Box Bot)         = Eval (mapDmds (`lub` Box Bot) ds1)
 985 lub (Eval ds1)  (Box (Eval ds2)) = Eval (ds1 `lubs` mapDmds box ds2)
 986 lub (Eval ds1)  (Box Abs)        = deferEval (mapDmds (`lub` Box Bot) ds1)
 987 lub d1@(Eval _) d2                = d2 `lub` d1 -- Bot,Abs,Top,Call,Defer
 988
 989 lub (Box d1)   (Box d2) = box (d1 `lub` d2)
 990 lub d1@(Box _)  d2      = d2 `lub` d1
 991
 992 lubs = zipWithDmds lub
 993
 994 ---------------------
 995 -- box is the smart constructor for Box
 996 -- It computes <B,bot> & d
 997 -- INVARIANT: (Box d) => d = Bot, Abs, Eval
 998 -- Seems to be no point in allowing (Box (Call d))
 999 box (Call d)  = Call d  -- The odd man out.  Why?
1000 box (Box d)   = Box d
1001 box (Defer _) = lazyDmd
1002 box Top       = lazyDmd -- Box Abs and Box Top
1003 box Abs       = lazyDmd -- are the same <B,L>
1004 box d         = Box d   -- Bot, Eval
1005
1006 ---------------
1007 defer :: Demand -> Demand
1008
1009 -- defer is the smart constructor for Defer
1010 -- The idea is that (Defer ds) = <U(ds), L>
1011 --
1012 -- It specifies what happens at a lazy function argument
1013 -- or a lambda; the L* operator
1014 -- Set the strictness part to L, but leave
1015 -- the boxity side unaffected
1016 -- It also ensures that Defer (Eval [LLLL]) = L
1017
1018 defer Bot        = Abs
1019 defer Abs        = Abs
1020 defer Top        = Top
1021 defer (Call _)   = lazyDmd      -- Approximation here?
1022 defer (Box _)    = lazyDmd
1023 defer (Defer ds) = Defer ds
1024 defer (Eval ds)  = deferEval ds
1025
1026 -- deferEval ds = defer (Eval ds)
1027 deferEval ds | allTop ds = Top
1028              | otherwise  = Defer ds
1029
1030 ---------------------
1031 absLub :: Demand -> Demand
1032 -- Computes (Abs `lub` d)
1033 -- For the Bot case consider
1034 --      f x y = if ... then x else error x
1035 --   Then for y we get Abs `lub` Bot, and we really
1036 --   want Abs overall
1037 absLub Bot        = Abs
1038 absLub Abs        = Abs
1039 absLub Top        = Top
1040 absLub (Call _)   = Top
1041 absLub (Box _)    = Top
1042 absLub (Eval ds)  = Defer (absLubs ds)  -- Or (Defer ds)?
1043 absLub (Defer ds) = Defer (absLubs ds)  -- Or (Defer ds)?
1044
1045 absLubs = mapDmds absLub
1046
1047 ---------------
1048 both :: Demand -> Demand -> Demand
1049
1050 both Abs d2 = d2
1051
1052 both Bot Bot       = Bot
1053 both Bot Abs       = Bot
1054 both Bot (Eval ds) = Eval (mapDmds (`both` Bot) ds)
1055         -- Consider
1056         --      f x = error x
1057         -- From 'error' itself we get demand Bot on x
1058         -- From the arg demand on x we get
1059         --      x :-> evalDmd = Box (Eval (Poly Abs))
1060         -- So we get  Bot `both` Box (Eval (Poly Abs))
1061         --          = Seq Keep (Poly Bot)
1062         --
1063         -- Consider also
1064         --      f x = if ... then error (fst x) else fst x
1065         -- Then we get (Eval (Box Bot, Bot) `lub` Eval (SA))
1066         --      = Eval (SA)
1067         -- which is what we want.
1068 both Bot d = errDmd
1069
1070 both Top Bot         = errDmd
1071 both Top Abs         = Top
1072 both Top Top         = Top
1073 both Top (Box d)    = Box d
1074 both Top (Call d)   = Call d
1075 both Top (Eval ds)  = Eval (mapDmds (`both` Top) ds)
1076 both Top (Defer ds)     -- = defer (Top `both` Eval ds)
1077                         -- = defer (Eval (mapDmds (`both` Top) ds))
1078                      = deferEval (mapDmds (`both` Top) ds)
1079
1080
1081 both (Box d1)   (Box d2)    = box (d1 `both` d2)
1082 both (Box d1)   d2@(Call _) = box (d1 `both` d2)
1083 both (Box d1)   d2@(Eval _) = box (d1 `both` d2)
1084 both (Box d1)   (Defer d2)  = Box d1
1085 both d1@(Box _) d2          = d2 `both` d1
1086
1087 both (Call d1)   (Call d2)   = Call (d1 `both` d2)
1088 both (Call d1)   (Eval ds2)  = Call d1  -- Could do better for (Poly Bot)?
1089 both (Call d1)   (Defer ds2) = Call d1  -- Ditto
1090 both d1@(Call _) d2          = d1 `both` d1
1091
1092 both (Eval ds1)    (Eval  ds2) = Eval (ds1 `boths` ds2)
1093 both (Eval ds1)    (Defer ds2) = Eval (ds1 `boths` mapDmds defer ds2)
1094 both d1@(Eval ds1) d2          = d2 `both` d1
1095
1096 both (Defer ds1) (Defer ds2) = deferEval (ds1 `boths` ds2)
1097 both d1@(Defer ds1) d2       = d2 `both` d1
1098
1099 boths = zipWithDmds both
1100 \end{code}
1101
1102
1103
1104 %************************************************************************
1105 %*                                                                      *
1106 \subsection{Miscellaneous
1107 %*                                                                      *
1108 %************************************************************************
1109
1110
1111 \begin{code}
1112 #ifdef OLD_STRICTNESS
1113 get_changes binds = vcat (map get_changes_bind binds)
1114
1115 get_changes_bind (Rec pairs) = vcat (map get_changes_pr pairs)
1116 get_changes_bind (NonRec id rhs) = get_changes_pr (id,rhs)
1117
1118 get_changes_pr (id,rhs)
1119   = get_changes_var id $$ get_changes_expr rhs
1120
1121 get_changes_var var
1122   | isId var  = get_changes_str var $$ get_changes_dmd var
1123   | otherwise = empty
1124
1125 get_changes_expr (Type t)     = empty
1126 get_changes_expr (Var v)      = empty
1127 get_changes_expr (Lit l)      = empty
1128 get_changes_expr (Note n e)   = get_changes_expr e
1129 get_changes_expr (App e1 e2)  = get_changes_expr e1 $$ get_changes_expr e2
1130 get_changes_expr (Lam b e)    = {- get_changes_var b $$ -} get_changes_expr e
1131 get_changes_expr (Let b e)    = get_changes_bind b $$ get_changes_expr e
1132 get_changes_expr (Case e b a) = get_changes_expr e $$ {- get_changes_var b $$ -} vcat (map get_changes_alt a)
1133
1134 get_changes_alt (con,bs,rhs) = {- vcat (map get_changes_var bs) $$ -} get_changes_expr rhs
1135
1136 get_changes_str id
1137   | new_better && old_better = empty
1138   | new_better               = message "BETTER"
1139   | old_better               = message "WORSE"
1140   | otherwise                = message "INCOMPARABLE"
1141   where
1142     message word = text word <+> text "strictness for" <+> ppr id <+> info
1143     info = (text "Old" <+> ppr old) $$ (text "New" <+> ppr new)
1144     new = squashSig (idNewStrictness id)        -- Don't report spurious diffs that the old
1145                                                 -- strictness analyser can't track
1146     old = newStrictnessFromOld (idName id) (idArity id) (idStrictness id) (idCprInfo id)
1147     old_better = old `betterStrictness` new
1148     new_better = new `betterStrictness` old
1149
1150 get_changes_dmd id
1151   | isUnLiftedType (idType id) = empty  -- Not useful
1152   | new_better && old_better = empty
1153   | new_better               = message "BETTER"
1154   | old_better               = message "WORSE"
1155   | otherwise                = message "INCOMPARABLE"
1156   where
1157     message word = text word <+> text "demand for" <+> ppr id <+> info
1158     info = (text "Old" <+> ppr old) $$ (text "New" <+> ppr new)
1159     new = squashDmd (argDemand (idNewDemandInfo id))    -- To avoid spurious improvements
1160                                                         -- A bit of a hack
1161     old = newDemand (idDemandInfo id)
1162     new_better = new `betterDemand` old
1163     old_better = old `betterDemand` new
1164
1165 betterStrictness :: StrictSig -> StrictSig -> Bool
1166 betterStrictness (StrictSig t1) (StrictSig t2) = betterDmdType t1 t2
1167
1168 betterDmdType t1 t2 = (t1 `lubType` t2) == t2
1169
1170 betterDemand :: Demand -> Demand -> Bool
1171 -- If d1 `better` d2, and d2 `better` d2, then d1==d2
1172 betterDemand d1 d2 = (d1 `lub` d2) == d2
1173
1174 squashSig (StrictSig (DmdType fv ds res))
1175   = StrictSig (DmdType emptyDmdEnv (map squashDmd ds) res)
1176   where
1177         -- squash just gets rid of call demands
1178         -- which the old analyser doesn't track
1179 squashDmd (Call d)   = evalDmd
1180 squashDmd (Box d)    = Box (squashDmd d)
1181 squashDmd (Eval ds)  = Eval (mapDmds squashDmd ds)
1182 squashDmd (Defer ds) = Defer (mapDmds squashDmd ds)
1183 squashDmd d          = d
1184 #endif
1185 \end{code}