ghc/compiler/stranal/DmdAnal.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4
   5                         -----------------
   6                         A demand analysis
   7                         -----------------
   8
   9 \begin{code}
  10 module DmdAnal ( dmdAnalPgm ) where
  11
  12 #include "HsVersions.h"
  13
  14 import CmdLineOpts      ( DynFlags, DynFlag(..), opt_MaxWorkerArgs )
  15 import NewDemand        -- All of it
  16 import CoreSyn
  17 import CoreUtils        ( exprIsValue, exprArity )
  18 import DataCon          ( dataConTyCon )
  19 import TyCon            ( isProductTyCon, isRecursiveTyCon )
  20 import Id               ( Id, idType, idInfo, idArity, idCprInfo, idDemandInfo,
  21                           modifyIdInfo, isDataConId, isImplicitId, isGlobalId,
  22                           idNewStrictness, idNewStrictness_maybe, getNewStrictness, setIdNewStrictness,
  23                           idNewDemandInfo, setIdNewDemandInfo, newStrictnessFromOld )
  24 import IdInfo           ( newDemand )
  25 import Var              ( Var )
  26 import VarEnv
  27 import UniqFM           ( plusUFM_C, addToUFM_Directly, lookupUFM_Directly,
  28                           keysUFM, minusUFM, ufmToList, filterUFM )
  29 import Type             ( isUnLiftedType )
  30 import CoreLint         ( showPass, endPass )
  31 import ErrUtils         ( dumpIfSet_dyn )
  32 import Util             ( mapAndUnzip, mapAccumL, mapAccumR, zipWithEqual )
  33 import BasicTypes       ( Arity, TopLevelFlag(..), isTopLevel )
  34 import Maybes           ( orElse, expectJust )
  35 import Outputable
  36 import FastTypes
  37 \end{code}
  38
  39 To think about
  40
  41 * set a noinline pragma on bottoming Ids
  42
  43 * Consider f x = x+1 `fatbar` error (show x)
  44   We'd like to unbox x, even if that means reboxing it in the error case.
  45
  46 \begin{code}
  47 instance Outputable TopLevelFlag where
  48   ppr flag = empty
  49 \end{code}
  50
  51 %************************************************************************
  52 %*                                                                      *
  53 \subsection{Top level stuff}
  54 %*                                                                      *
  55 %************************************************************************
  56
  57 \begin{code}
  58 dmdAnalPgm :: DynFlags -> [CoreBind] -> IO [CoreBind]
  59 dmdAnalPgm dflags binds
  60   = do {
  61         showPass dflags "Demand analysis" ;
  62         let { binds_plus_dmds = do_prog binds ;
  63               dmd_changes = get_changes binds_plus_dmds } ;
  64         endPass dflags "Demand analysis"
  65                 Opt_D_dump_stranal binds_plus_dmds ;
  66         printDump (text "Changes in demands" $$ dmd_changes) ;
  67         return binds_plus_dmds
  68     }
  69   where
  70     do_prog :: [CoreBind] -> [CoreBind]
  71     do_prog binds = snd $ mapAccumL dmdAnalTopBind emptySigEnv binds
  72
  73 dmdAnalTopBind :: SigEnv
  74                -> CoreBind
  75                -> (SigEnv, CoreBind)
  76 dmdAnalTopBind sigs (NonRec id rhs)
  77   | isImplicitId id             -- Don't touch the info on constructors, selectors etc
  78   = (sigs, NonRec id rhs)       -- It's pre-computed in MkId.lhs
  79   | otherwise
  80   = let
  81         (sigs', _, (id', rhs')) = downRhs TopLevel sigs (id, rhs)
  82     in
  83     (sigs', NonRec id' rhs')
  84
  85 dmdAnalTopBind sigs (Rec pairs)
  86   = let
  87         (sigs', _, pairs')  = dmdFix TopLevel sigs pairs
  88     in
  89     (sigs', Rec pairs')
  90 \end{code}
  91
  92
  93 %************************************************************************
  94 %*                                                                      *
  95 \subsection{The analyser itself}
  96 %*                                                                      *
  97 %************************************************************************
  98
  99 \begin{code}
 100 dmdAnal :: SigEnv -> Demand -> CoreExpr -> (DmdType, CoreExpr)
 101
 102 dmdAnal sigs Abs  e = (topDmdType, e)
 103
 104 dmdAnal sigs Lazy e = let
 105                         (res_ty, e') = dmdAnal sigs Eval e
 106                       in
 107                       (deferType res_ty, e')
 108         -- It's important not to analyse e with a lazy demand because
 109         -- a) When we encounter   case s of (a,b) ->
 110         --      we demand s with U(d1d2)... but if the overall demand is lazy
 111         --      that is wrong, and we'd need to reduce the demand on s,
 112         --      which is inconvenient
 113         -- b) More important, consider
 114         --      f (let x = R in x+x), where f is lazy
 115         --    We still want to mark x as demanded, because it will be when we
 116         --    enter the let.  If we analyse f's arg with a Lazy demand, we'll
 117         --    just mark x as Lazy
 118
 119
 120 dmdAnal sigs dmd (Lit lit)
 121   = (topDmdType, Lit lit)
 122
 123 dmdAnal sigs dmd (Var var)
 124   = (dmdTransform sigs var dmd, Var var)
 125
 126 dmdAnal sigs dmd (Note n e)
 127   = (dmd_ty, Note n e')
 128   where
 129     (dmd_ty, e') = dmdAnal sigs dmd' e
 130     dmd' = case n of
 131              Coerce _ _ -> Eval   -- This coerce usually arises from a recursive
 132              other      -> dmd    -- newtype, and we don't want to look inside them
 133                                   -- for exactly the same reason that we don't look
 134                                   -- inside recursive products -- we might not reach
 135                                   -- a fixpoint.  So revert to a vanilla Eval demand
 136
 137 dmdAnal sigs dmd (App fun (Type ty))
 138   = (fun_ty, App fun' (Type ty))
 139   where
 140     (fun_ty, fun') = dmdAnal sigs dmd fun
 141
 142 dmdAnal sigs dmd (App fun arg)  -- Non-type arguments
 143   = let                         -- [Type arg handled above]
 144         (fun_ty, fun')    = dmdAnal sigs (Call dmd) fun
 145         (arg_ty, arg')    = dmdAnal sigs arg_dmd arg
 146         (arg_dmd, res_ty) = splitDmdTy fun_ty
 147     in
 148     (res_ty `bothType` arg_ty, App fun' arg')
 149
 150 dmdAnal sigs dmd (Lam var body)
 151   | isTyVar var
 152   = let
 153         (body_ty, body') = dmdAnal sigs dmd body
 154     in
 155     (body_ty, Lam var body')
 156
 157   | Call body_dmd <- dmd        -- A call demand: good!
 158   = let
 159         (body_ty, body') = dmdAnal sigs body_dmd body
 160         (lam_ty, var')   = annotateLamIdBndr body_ty var
 161     in
 162     (lam_ty, Lam var' body')
 163
 164   | otherwise   -- Not enough demand on the lambda; but do the body
 165   = let         -- anyway to annotate it and gather free var info
 166         (body_ty, body') = dmdAnal sigs Eval body
 167         (lam_ty, var')   = annotateLamIdBndr body_ty var
 168     in
 169     (deferType lam_ty, Lam var' body')
 170
 171 dmdAnal sigs dmd (Case scrut case_bndr [alt@(DataAlt dc,bndrs,rhs)])
 172   | let tycon = dataConTyCon dc,
 173     isProductTyCon tycon,
 174     not (isRecursiveTyCon tycon)
 175   = let
 176         bndr_ids                 = filter isId bndrs
 177         (alt_ty, alt')           = dmdAnalAlt sigs dmd alt
 178         (alt_ty1, case_bndr')    = annotateBndr alt_ty case_bndr
 179         (_, bndrs', _)           = alt'
 180
 181         -- Figure out whether the case binder is used, and use
 182         -- that to set the keepity of the demand.  This is utterly essential.
 183         -- Consider     f x = case x of y { (a,b) -> k y a }
 184         -- If we just take scrut_demand = U(L,A), then we won't pass x to the
 185         -- worker, so the worker will rebuild
 186         --      x = (a, absent-error)
 187         -- and that'll crash.
 188         dead_case_bndr           = isAbsentDmd (idNewDemandInfo case_bndr')
 189         keepity | dead_case_bndr = Drop
 190                 | otherwise      = Keep
 191
 192         scrut_dmd                = Seq keepity Now [idNewDemandInfo b | b <- bndrs', isId b]
 193         (scrut_ty, scrut')       = dmdAnal sigs scrut_dmd scrut
 194     in
 195     (alt_ty1 `bothType` scrut_ty, Case scrut' case_bndr' [alt'])
 196
 197 dmdAnal sigs dmd (Case scrut case_bndr alts)
 198   = let
 199         (alt_tys, alts')        = mapAndUnzip (dmdAnalAlt sigs dmd) alts
 200         (scrut_ty, scrut')      = dmdAnal sigs Eval scrut
 201         (alt_ty, case_bndr')    = annotateBndr (foldr1 lubType alt_tys) case_bndr
 202     in
 203 --    pprTrace "dmdAnal:Case" (ppr alts $$ ppr alt_tys)
 204     (alt_ty `bothType` scrut_ty, Case scrut' case_bndr' alts')
 205
 206 dmdAnal sigs dmd (Let (NonRec id rhs) body)
 207   = let
 208         (sigs', lazy_fv, (id1, rhs')) = downRhs NotTopLevel sigs (id, rhs)
 209         (body_ty, body')              = dmdAnal sigs' dmd body
 210         (body_ty1, id2)               = annotateBndr body_ty id1
 211         body_ty2                      = addLazyFVs body_ty1 lazy_fv
 212     in
 213 --    pprTrace "dmdLet" (ppr id <+> ppr (sig,rhs_env))
 214     (body_ty2, Let (NonRec id2 rhs') body')
 215
 216 dmdAnal sigs dmd (Let (Rec pairs) body)
 217   = let
 218         bndrs                    = map fst pairs
 219         (sigs', lazy_fv, pairs') = dmdFix NotTopLevel sigs pairs
 220         (body_ty, body')         = dmdAnal sigs' dmd body
 221         body_ty1                 = addLazyFVs body_ty lazy_fv
 222     in
 223     sigs' `seq` body_ty `seq`
 224     let
 225         (body_ty2, _) = annotateBndrs body_ty1 bndrs
 226                 -- Don't bother to add demand info to recursive
 227                 -- binders as annotateBndr does;
 228                 -- being recursive, we can't treat them strictly.
 229                 -- But we do need to remove the binders from the result demand env
 230     in
 231     (body_ty2,  Let (Rec pairs') body')
 232
 233
 234 dmdAnalAlt sigs dmd (con,bndrs,rhs)
 235   = let
 236         (rhs_ty, rhs')   = dmdAnal sigs dmd rhs
 237         (alt_ty, bndrs') = annotateBndrs rhs_ty bndrs
 238     in
 239     (alt_ty, (con, bndrs', rhs'))
 240 \end{code}
 241
 242 %************************************************************************
 243 %*                                                                      *
 244 \subsection{Bindings}
 245 %*                                                                      *
 246 %************************************************************************
 247
 248 \begin{code}
 249 dmdFix :: TopLevelFlag
 250        -> SigEnv                -- Does not include bindings for this binding
 251        -> [(Id,CoreExpr)]
 252        -> (SigEnv, DmdEnv,
 253            [(Id,CoreExpr)])     -- Binders annotated with stricness info
 254
 255 dmdFix top_lvl sigs pairs
 256   = loop 1 initial_sigs pairs
 257   where
 258     bndrs        = map fst pairs
 259     initial_sigs = extendSigEnvList sigs [(id, (initial_sig id, top_lvl)) | id <- bndrs]
 260
 261     loop :: Int
 262          -> SigEnv                      -- Already contains the current sigs
 263          -> [(Id,CoreExpr)]
 264          -> (SigEnv, DmdEnv, [(Id,CoreExpr)])
 265     loop n sigs pairs
 266       | all (same_sig sigs sigs') bndrs = (sigs', lazy_fv, pairs')
 267                 -- Note: use pairs', not pairs.   pairs' is the result of
 268                 -- processing the RHSs with sigs (= sigs'), whereas pairs
 269                 -- is the result of processing the RHSs with the *previous*
 270                 -- iteration of sigs.
 271       | n >= 5              = pprTrace "dmdFix" (ppr n <+> ppr pairs)   (loop (n+1) sigs' pairs')
 272       | otherwise           = {- pprTrace "dmdFixLoop" (ppr id_sigs) -} (loop (n+1) sigs' pairs')
 273       where
 274                 -- Use the new signature to do the next pair
 275                 -- The occurrence analyser has arranged them in a good order
 276                 -- so this can significantly reduce the number of iterations needed
 277         ((sigs',lazy_fv), pairs') = mapAccumL (my_downRhs top_lvl) (sigs, emptyDmdEnv) pairs
 278
 279     my_downRhs top_lvl (sigs,lazy_fv) (id,rhs)
 280         = -- pprTrace "downRhs {" (ppr id <+> (ppr old_sig))
 281           -- (new_sig `seq`
 282           --    pprTrace "downRhsEnd" (ppr id <+> ppr new_sig <+> char '}' )
 283           ((sigs', lazy_fv'), pair')
 284           --     )
 285         where
 286           (sigs', lazy_fv1, pair') = downRhs top_lvl sigs (id,rhs)
 287           lazy_fv'                 = plusUFM_C both lazy_fv lazy_fv1
 288           old_sig                  = lookup sigs id
 289           new_sig                  = lookup sigs' id
 290
 291         -- Get an initial strictness signature from the Id
 292         -- itself.  That way we make use of earlier iterations
 293         -- of the fixpoint algorithm.  (Cunning plan.)
 294         -- Note that the cunning plan extends to the DmdEnv too,
 295         -- since it is part of the strictness signature
 296     initial_sig id = idNewStrictness_maybe id `orElse` botSig
 297
 298     same_sig sigs sigs' var = lookup sigs var == lookup sigs' var
 299     lookup sigs var = case lookupVarEnv sigs var of
 300                         Just (sig,_) -> sig
 301
 302 downRhs :: TopLevelFlag
 303         -> SigEnv -> (Id, CoreExpr)
 304         -> (SigEnv,  DmdEnv, (Id, CoreExpr))
 305 -- Process the RHS of the binding, add the strictness signature
 306 -- to the Id, and augment the environment with the signature as well.
 307
 308 downRhs top_lvl sigs (id, rhs)
 309  = (sigs', lazy_fv, (id', rhs'))
 310  where
 311   arity             = exprArity rhs   -- The idArity may not be up to date
 312   (rhs_ty, rhs')    = dmdAnal sigs (vanillaCall arity) rhs
 313   (lazy_fv, sig_ty) = mkSigTy id arity rhs rhs_ty
 314   id'               = id `setIdNewStrictness` sig_ty
 315   sigs'             = extendSigEnv top_lvl sigs id sig_ty
 316 \end{code}
 317
 318 %************************************************************************
 319 %*                                                                      *
 320 \subsection{Strictness signatures and types}
 321 %*                                                                      *
 322 %************************************************************************
 323
 324 \begin{code}
 325 mkSigTy :: Id -> Arity -> CoreExpr -> DmdType -> (DmdEnv, StrictSig)
 326 -- Take a DmdType and turn it into a StrictSig
 327 mkSigTy id arity rhs (DmdType fv dmds res)
 328   = (lazy_fv, mkStrictSig id arity dmd_ty)
 329   where
 330     dmd_ty = DmdType strict_fv lazified_dmds res'
 331
 332     lazy_fv   = filterUFM (not . isStrictDmd) fv
 333     strict_fv = filterUFM isStrictDmd         fv
 334         -- We put the strict FVs in the DmdType of the Id, so
 335         -- that at its call sites we unleash demands on its strict fvs.
 336         -- An example is 'roll' in imaginary/wheel-sieve2
 337         -- Something like this:
 338         --      roll x = letrec
 339         --                   go y = if ... then roll (x-1) else x+1
 340         --               in
 341         --               go ms
 342         -- We want to see that roll is strict in x, which is because
 343         -- go is called.   So we put the DmdEnv for x in go's DmdType.
 344         --
 345         -- Another example:
 346         --      f :: Int -> Int -> Int
 347         --      f x y = let t = x+1
 348         --          h z = if z==0 then t else
 349         --                if z==1 then x+1 else
 350         --                x + h (z-1)
 351         --      in
 352         --      h y
 353         -- Calling h does indeed evaluate x, but we can only see
 354         -- that if we unleash a demand on x at the call site for t.
 355         --
 356         -- Incidentally, here's a place where lambda-lifting h would
 357         -- lose the cigar --- we couldn't see the joint strictness in t/x
 358         --
 359         --      ON THE OTHER HAND
 360         -- We don't want to put *all* the fv's from the RHS into the
 361         -- DmdType, because that makes fixpointing very slow --- the
 362         -- DmdType gets full of lazy demands that are slow to converge.
 363
 364     lazified_dmds = map lazify dmds
 365         -- Get rid of defers in the arguments
 366     final_dmds = setUnpackStrategy lazified_dmds
 367         -- Set the unpacking strategy
 368
 369     res' = case (dmds, res) of
 370                 ([], RetCPR) | not (exprIsValue rhs) -> TopRes
 371                 other                                -> res
 372         -- If the rhs is a thunk, we forget the CPR info, because
 373         -- it is presumably shared (else it would have been inlined, and
 374         -- so we'd lose sharing if w/w'd it into a function.
 375         --
 376         --      DONE IN OLD CPR ANALYSER, BUT NOT YET HERE
 377         -- Also, if the strictness analyser has figured out that it's strict,
 378         -- the let-to-case transformation will happen, so again it's good.
 379         -- (CPR analysis runs before the simplifier has had a chance to do
 380         --  the let-to-case transform.)
 381         -- This made a big difference to PrelBase.modInt, which had something like
 382         --      modInt = \ x -> let r = ... -> I# v in
 383         --                      ...body strict in r...
 384         -- r's RHS isn't a value yet; but modInt returns r in various branches, so
 385         -- if r doesn't have the CPR property then neither does modInt
 386 \end{code}
 387
 388 The unpack strategy determines whether we'll *really* unpack the argument,
 389 or whether we'll just remember its strictness.  If unpacking would give
 390 rise to a *lot* of worker args, we may decide not to unpack after all.
 391
 392 \begin{code}
 393 setUnpackStrategy :: [Demand] -> [Demand]
 394 setUnpackStrategy ds
 395   = snd (go (opt_MaxWorkerArgs - nonAbsentArgs ds) ds)
 396   where
 397     go :: Int                   -- Max number of args available for sub-components of [Demand]
 398        -> [Demand]
 399        -> (Int, [Demand])       -- Args remaining after subcomponents of [Demand] are unpacked
 400
 401     go n (Seq keep _ cs : ds)
 402         | n' >= 0    = Seq keep Now cs' `cons` go n'' ds
 403         | otherwise  = Eval `cons` go n ds
 404         where
 405           (n'',cs') = go n' cs
 406           n' = n + box - non_abs_args
 407           box = case keep of
 408                    Keep -> 0
 409                    Drop -> 1    -- Add one to the budget if we drop the top-level arg
 410           non_abs_args = nonAbsentArgs cs
 411                 -- Delete # of non-absent args to which we'll now be committed
 412
 413     go n (d:ds) = d `cons` go n ds
 414     go n []     = (n,[])
 415
 416     cons d (n,ds) = (n, d:ds)
 417
 418 nonAbsentArgs :: [Demand] -> Int
 419 nonAbsentArgs []         = 0
 420 nonAbsentArgs (Abs : ds) = nonAbsentArgs ds
 421 nonAbsentArgs (d   : ds) = 1 + nonAbsentArgs ds
 422 \end{code}
 423
 424
 425 %************************************************************************
 426 %*                                                                      *
 427 \subsection{Strictness signatures and types}
 428 %*                                                                      *
 429 %************************************************************************
 430
 431 \begin{code}
 432 splitDmdTy :: DmdType -> (Demand, DmdType)
 433 -- Split off one function argument
 434 splitDmdTy (DmdType fv (dmd:dmds) res_ty) = (dmd, DmdType fv dmds res_ty)
 435 splitDmdTy ty@(DmdType fv [] TopRes)         = (topDmd, ty)
 436 splitDmdTy ty@(DmdType fv [] BotRes)         = (Abs,    ty)
 437         -- We already have a suitable demand on all
 438         -- free vars, so no need to add more!
 439 splitDmdTy (DmdType fv [] RetCPR)         = panic "splitDmdTy"
 440 \end{code}
 441
 442 \begin{code}
 443 unitVarDmd var dmd = DmdType (unitVarEnv var dmd) [] TopRes
 444
 445 addVarDmd top_lvl dmd_ty@(DmdType fv ds res) var dmd
 446   | isTopLevel top_lvl = dmd_ty         -- Don't record top level things
 447   | otherwise          = DmdType (extendVarEnv fv var dmd) ds res
 448
 449 addLazyFVs (DmdType fv ds res) lazy_fvs
 450   = DmdType (plusUFM_C both fv lazy_fvs) ds res
 451
 452 annotateBndr :: DmdType -> Var -> (DmdType, Var)
 453 -- The returned env has the var deleted
 454 -- The returned var is annotated with demand info
 455 -- No effect on the argument demands
 456 annotateBndr dmd_ty@(DmdType fv ds res) var
 457   | isTyVar var = (dmd_ty, var)
 458   | otherwise   = (DmdType fv' ds res, setIdNewDemandInfo var dmd)
 459   where
 460     (fv', dmd) = removeFV fv var res
 461
 462 annotateBndrs = mapAccumR annotateBndr
 463
 464 annotateLamIdBndr dmd_ty@(DmdType fv ds res) id
 465 -- For lambdas we add the demand to the argument demands
 466 -- Only called for Ids
 467   = ASSERT( isId id )
 468     (DmdType fv' (dmd:ds) res, setIdNewDemandInfo id dmd)
 469   where
 470     (fv', dmd) = removeFV fv id res
 471
 472 removeFV fv var res = (fv', dmd)
 473                 where
 474                   fv' = fv `delVarEnv` var
 475                   dmd = lookupVarEnv fv var `orElse` deflt
 476                   deflt | isBotRes res = Bot
 477                         | otherwise    = Abs
 478 \end{code}
 479
 480 %************************************************************************
 481 %*                                                                      *
 482 \subsection{Strictness signatures}
 483 %*                                                                      *
 484 %************************************************************************
 485
 486 \begin{code}
 487 type SigEnv  = VarEnv (StrictSig, TopLevelFlag)
 488         -- We use the SigEnv to tell us whether to
 489         -- record info about a variable in the DmdEnv
 490         -- We do so if it's a LocalId, but not top-level
 491         --
 492         -- The DmdEnv gives the demand on the free vars of the function
 493         -- when it is given enough args to satisfy the strictness signature
 494
 495 emptySigEnv  = emptyVarEnv
 496
 497 extendSigEnv :: TopLevelFlag -> SigEnv -> Id -> StrictSig -> SigEnv
 498 extendSigEnv top_lvl env var sig = extendVarEnv env var (sig, top_lvl)
 499
 500 extendSigEnvList = extendVarEnvList
 501
 502 dmdTransform :: SigEnv          -- The strictness environment
 503              -> Id              -- The function
 504              -> Demand          -- The demand on the function
 505              -> DmdType         -- The demand type of the function in this context
 506         -- Returned DmdEnv includes the demand on
 507         -- this function plus demand on its free variables
 508
 509 dmdTransform sigs var dmd
 510
 511 ------  DATA CONSTRUCTOR
 512   | isDataConId var,            -- Data constructor
 513     Seq k Now ds <- res_dmd,    -- and the demand looks inside its fields
 514     let StrictSig dmd_ty = idNewStrictness var  -- It must have a strictness sig
 515   = if dmdTypeDepth dmd_ty == length ds then    -- Saturated, so unleash the demand
 516         -- ds can be empty, when we are just seq'ing the thing
 517         mkDmdType emptyDmdEnv ds (dmdTypeRes dmd_ty)
 518                 -- Need to extract whether it's a product, hence dmdTypeRes
 519     else
 520         topDmdType
 521
 522 ------  IMPORTED FUNCTION
 523   | isGlobalId var,             -- Imported function
 524     let StrictSig dmd_ty = getNewStrictness var
 525   = if dmdTypeDepth dmd_ty <= call_depth then   -- Saturated, so unleash the demand
 526         dmd_ty
 527     else
 528         topDmdType
 529
 530 ------  LOCAL LET/REC BOUND THING
 531   | Just (StrictSig dmd_ty, top_lvl) <- lookupVarEnv sigs var
 532   = let
 533         fn_ty | dmdTypeDepth dmd_ty <= call_depth = dmd_ty
 534               | otherwise                         = deferType dmd_ty
 535         -- NB: it's important to use deferType, and not just return topDmdType
 536         -- Consider     let { f x y = p + x } in f 1
 537         -- The application isn't saturated, but we must nevertheless propagate
 538         --      a lazy demand for p!
 539     in
 540     addVarDmd top_lvl fn_ty var dmd
 541
 542 ------  LOCAL NON-LET/REC BOUND THING
 543   | otherwise                   -- Default case
 544   = unitVarDmd var dmd
 545
 546   where
 547     (call_depth, res_dmd) = splitCallDmd dmd
 548 \end{code}
 549
 550
 551 %************************************************************************
 552 %*                                                                      *
 553 \subsection{Demands}
 554 %*                                                                      *
 555 %************************************************************************
 556
 557 \begin{code}
 558 splitCallDmd :: Demand -> (Int, Demand)
 559 splitCallDmd (Call d) = case splitCallDmd d of
 560                           (n, r) -> (n+1, r)
 561 splitCallDmd d        = (0, d)
 562
 563 vanillaCall :: Arity -> Demand
 564 vanillaCall 0 = Eval
 565 vanillaCall n = Call (vanillaCall (n-1))
 566
 567 deferType :: DmdType -> DmdType
 568 deferType (DmdType fv _ _) = DmdType (mapVarEnv defer fv) [] TopRes
 569         -- Notice that we throw away info about both arguments and results
 570         -- For example,   f = let ... in \x -> x
 571         -- We don't want to get a stricness type V->T for f.
 572
 573 defer :: Demand -> Demand
 574 -- c.f. `lub` Abs
 575 defer Abs          = Abs
 576 defer (Seq k _ ds) = Seq k Defer ds
 577 defer other        = Lazy
 578
 579 lazify :: Demand -> Demand
 580 -- The 'Defer' demands are just Lazy at function boundaries
 581 lazify (Seq k Defer ds) = Lazy
 582 lazify (Seq k Now   ds) = Seq k Now (map lazify ds)
 583 lazify Bot              = Abs   -- Don't pass args that are consumed by bottom
 584 lazify d                = d
 585 \end{code}
 586
 587 \begin{code}
 588 betterStrictness :: StrictSig -> StrictSig -> Bool
 589 betterStrictness (StrictSig t1) (StrictSig t2) = betterDmdType t1 t2
 590
 591 betterDmdType t1 t2 = (t1 `lubType` t2) == t2
 592
 593 betterDemand :: Demand -> Demand -> Bool
 594 -- If d1 `better` d2, and d2 `better` d2, then d1==d2
 595 betterDemand d1 d2 = (d1 `lub` d2) == d2
 596
 597 squashDmdEnv (StrictSig (DmdType fv ds res)) = StrictSig (DmdType emptyDmdEnv ds res)
 598 \end{code}
 599
 600
 601 %************************************************************************
 602 %*                                                                      *
 603 \subsection{LUB and BOTH}
 604 %*                                                                      *
 605 %************************************************************************
 606
 607 \begin{code}
 608 lub :: Demand -> Demand -> Demand
 609
 610 lub Bot  d = d
 611
 612 lub Lazy d = Lazy
 613
 614 lub Err Bot = Err
 615 lub Err d   = d
 616
 617 lub Abs Bot          = Abs
 618 lub Abs Err          = Abs
 619 lub Abs Abs          = Abs
 620 lub Abs (Seq k _ ds) = Seq k Defer ds   -- Very important ('radicals' example)
 621 lub Abs d            = Lazy
 622
 623 lub Eval Abs            = Lazy
 624 lub Eval Lazy           = Lazy
 625 lub Eval (Seq k Now ds) = Seq Keep Now ds
 626 lub Eval d              = Eval
 627
 628 lub (Call d1) (Call d2) = Call (lub d1 d2)
 629
 630 lub (Seq k1 l1 ds1) (Seq k2 l2 ds2) = Seq (k1 `vee` k2) (l1 `or_defer` l2) (lubs ds1 ds2)
 631
 632 -- The last clauses deal with the remaining cases for Call and Seq
 633 lub d1@(Call _) d2@(Seq _ _ _) = pprPanic "lub" (ppr d1 $$ ppr d2)
 634 lub d1 d2                      = lub d2 d1
 635
 636 -- A Seq can have an empty list of demands, in the polymorphic case.
 637 lubs [] ds2 = ds2
 638 lubs ds1 [] = ds1
 639 lubs ds1 ds2 = ASSERT( length ds1 == length ds2 ) zipWith lub ds1 ds2
 640
 641 or_defer Now Now = Now
 642 or_defer _   _   = Defer
 643
 644 -------------------------
 645 -- Consider (if x then y else []) with demand V
 646 -- Then the first branch gives {y->V} and the second
 647 -- *implicitly* has {y->A}.  So we must put {y->(V `lub` A)}
 648 -- in the result env.
 649 lubType (DmdType fv1 ds1 r1) (DmdType fv2 ds2 r2)
 650   = DmdType lub_fv2 (zipWith lub ds1 ds2) (r1 `lubRes` r2)
 651   where
 652     lub_fv  = plusUFM_C lub fv1 fv2
 653     lub_fv1 = modifyEnv (not (isBotRes r1)) (Abs `lub`) fv2 fv1 lub_fv
 654     lub_fv2 = modifyEnv (not (isBotRes r2)) (Abs `lub`) fv1 fv2 lub_fv1
 655         -- lub is the identity for Bot
 656
 657 -------------------------
 658 lubRes BotRes r      = r
 659 lubRes r      BotRes = r
 660 lubRes RetCPR RetCPR = RetCPR
 661 lubRes r1     r2     = TopRes
 662
 663 -----------------------------------
 664 vee :: Keepity -> Keepity -> Keepity
 665 vee Drop Drop = Drop
 666 vee k1   k2   = Keep
 667
 668 -----------------------------------
 669 both :: Demand -> Demand -> Demand
 670
 671 -- The normal one
 672 -- both Bot d = Bot
 673
 674 -- The experimental one
 675 both Bot Bot = Bot
 676 both Bot Abs = Bot
 677 both Bot d   = d
 678
 679
 680 both Abs Bot = Bot
 681 both Abs d   = d
 682
 683 both Err Bot = Bot
 684 both Err Abs = Err
 685 both Err d   = d
 686
 687 both Lazy Bot            = Bot
 688 both Lazy Abs            = Lazy
 689 both Lazy Err            = Lazy
 690 both Lazy (Seq k Now ds) = Seq Keep Now ds
 691 both Lazy d              = d
 692
 693 -- Part of the Bot like Err experiment
 694 -- both Eval Bot               = Bot
 695 both Eval (Seq k l ds) = Seq Keep Now ds
 696 both Eval (Call d)     = Call d
 697 both Eval d            = Eval
 698
 699 both (Seq k1 Defer ds1) (Seq k2 Defer ds2) = Seq (k1 `vee` k2) Defer (boths ds1  ds2)
 700 both (Seq k1 l1 ds1)    (Seq k2 l2 ds2)    = Seq (k1 `vee` k2) Now   (boths ds1' ds2')
 701                                            where
 702                                              ds1' = case l1 of { Now -> ds1; Defer -> map defer ds1 }
 703                                              ds2' = case l2 of { Now -> ds2; Defer -> map defer ds2 }
 704
 705 both (Call d1) (Call d2) = Call (d1 `both` d2)
 706
 707 -- The last clauses deal with the remaining cases for Call and Seq
 708 both d1@(Call _) d2@(Seq _ _ _) = pprPanic "both" (ppr d1 $$ ppr d2)
 709 both d1 d2                      = both d2 d1
 710
 711 -----------------------------------
 712 -- A Seq can have an empty list of demands, in the polymorphic case.
 713 boths [] ds2  = ds2
 714 boths ds1 []  = ds1
 715 boths ds1 ds2 = ASSERT( length ds1 == length ds2 ) zipWith both ds1 ds2
 716
 717 -----------------------------------
 718 bothRes :: DmdResult -> DmdResult -> DmdResult
 719 -- Left-biased for CPR info
 720 bothRes BotRes _ = BotRes
 721 bothRes _ BotRes = BotRes
 722 bothRes r1 _     = r1
 723
 724 -----------------------------------
 725 -- (t1 `bothType` t2) takes the argument/result info from t1,
 726 -- using t2 just for its free-var info
 727 bothType (DmdType fv1 ds1 r1) (DmdType fv2 ds2 r2)
 728   = DmdType both_fv2 ds1 r1
 729   where
 730     both_fv  = plusUFM_C both fv1 fv2
 731     both_fv1 = modifyEnv (isBotRes r1) (`both` Bot) fv2 fv1 both_fv
 732     both_fv2 = modifyEnv (isBotRes r2) (`both` Bot) fv1 fv2 both_fv1
 733         -- both is the identity for Abs
 734 \end{code}
 735
 736 \begin{code}
 737 modifyEnv :: Bool                       -- No-op if False
 738           -> (Demand -> Demand)         -- The zapper
 739           -> DmdEnv -> DmdEnv           -- Env1 and Env2
 740           -> DmdEnv -> DmdEnv           -- Transform this env
 741         -- Zap anything in Env1 but not in Env2
 742         -- Assume: dom(env) includes dom(Env1) and dom(Env2)
 743
 744 modifyEnv need_to_modify zapper env1 env2 env
 745   | need_to_modify = foldr zap env (keysUFM (env1 `minusUFM` env2))
 746   | otherwise      = env
 747   where
 748     zap uniq env = addToUFM_Directly env uniq (zapper current_val)
 749                  where
 750                    current_val = expectJust "modifyEnv" (lookupUFM_Directly env uniq)
 751 \end{code}
 752
 753
 754 %************************************************************************
 755 %*                                                                      *
 756 \subsection{Miscellaneous
 757 %*                                                                      *
 758 %************************************************************************
 759
 760
 761 \begin{code}
 762 get_changes binds = vcat (map get_changes_bind binds)
 763
 764 get_changes_bind (Rec pairs) = vcat (map get_changes_pr pairs)
 765 get_changes_bind (NonRec id rhs) = get_changes_pr (id,rhs)
 766
 767 get_changes_pr (id,rhs)
 768   | isImplicitId id = empty  -- We don't look inside these
 769   | otherwise       = get_changes_var id $$ get_changes_expr rhs
 770
 771 get_changes_var var
 772   | isId var  = get_changes_str var $$ get_changes_dmd var
 773   | otherwise = empty
 774
 775 get_changes_expr (Type t)     = empty
 776 get_changes_expr (Var v)      = empty
 777 get_changes_expr (Lit l)      = empty
 778 get_changes_expr (Note n e)   = get_changes_expr e
 779 get_changes_expr (App e1 e2)  = get_changes_expr e1 $$ get_changes_expr e2
 780 get_changes_expr (Lam b e)    = {- get_changes_var b $$ -} get_changes_expr e
 781 get_changes_expr (Let b e)    = get_changes_bind b $$ get_changes_expr e
 782 get_changes_expr (Case e b a) = get_changes_expr e $$ get_changes_var b $$ vcat (map get_changes_alt a)
 783
 784 get_changes_alt (con,bs,rhs) = {- vcat (map get_changes_var bs) $$ -} get_changes_expr rhs
 785
 786 get_changes_str id
 787   | new_better && old_better = empty
 788   | new_better               = message "BETTER"
 789   | old_better               = message "WORSE"
 790   | otherwise                = message "INCOMPARABLE"
 791   where
 792     message word = text word <+> text "strictness for" <+> ppr id <+> info
 793     info = (text "Old" <+> ppr old) $$ (text "New" <+> ppr new)
 794     new = squashDmdEnv (idNewStrictness id)     -- Don't report diffs in the env
 795     old = newStrictnessFromOld id
 796     old_better = old `betterStrictness` new
 797     new_better = new `betterStrictness` old
 798
 799 get_changes_dmd id
 800   | isUnLiftedType (idType id) = empty  -- Not useful
 801   | new_better && old_better = empty
 802   | new_better               = message "BETTER"
 803   | old_better               = message "WORSE"
 804   | otherwise                = message "INCOMPARABLE"
 805   where
 806     message word = text word <+> text "demand for" <+> ppr id <+> info
 807     info = (text "Old" <+> ppr old) $$ (text "New" <+> ppr new)
 808     new = lazify (idNewDemandInfo id)   -- Lazify to avoid spurious improvements
 809     old = newDemand (idDemandInfo id)
 810     new_better = new `betterDemand` old
 811     old_better = old `betterDemand` new
 812 \end{code}