ghc/compiler/stranal/DmdAnal.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4
   5                         -----------------
   6                         A demand analysis
   7                         -----------------
   8
   9 \begin{code}
  10 module DmdAnal ( dmdAnalPgm, dmdAnalTopRhs,
  11                  both {- needed by WwLib -}
  12    ) where
  13
  14 #include "HsVersions.h"
  15
  16 import CmdLineOpts      ( DynFlags, DynFlag(..), opt_MaxWorkerArgs )
  17 import NewDemand        -- All of it
  18 import CoreSyn
  19 import PprCore
  20 import CoreUtils        ( exprIsValue, exprArity )
  21 import DataCon          ( dataConTyCon )
  22 import TyCon            ( isProductTyCon, isRecursiveTyCon )
  23 import Id               ( Id, idType, idInlinePragma,
  24                           isDataConWorkId, isGlobalId, idArity,
  25 #ifdef OLD_STRICTNESS
  26                           idDemandInfo,  idStrictness, idCprInfo, idName,
  27 #endif
  28                           idNewStrictness, idNewStrictness_maybe,
  29                           setIdNewStrictness, idNewDemandInfo,
  30                           idNewDemandInfo_maybe,
  31                           setIdNewDemandInfo
  32                         )
  33 #ifdef OLD_STRICTNESS
  34 import IdInfo           ( newStrictnessFromOld, newDemand )
  35 #endif
  36 import Var              ( Var )
  37 import VarEnv
  38 import TysWiredIn       ( unboxedPairDataCon )
  39 import TysPrim          ( realWorldStatePrimTy )
  40 import UniqFM           ( plusUFM_C, addToUFM_Directly, lookupUFM_Directly,
  41                           keysUFM, minusUFM, ufmToList, filterUFM )
  42 import Type             ( isUnLiftedType, eqType )
  43 import CoreLint         ( showPass, endPass )
  44 import Util             ( mapAndUnzip, mapAccumL, mapAccumR, lengthIs )
  45 import BasicTypes       ( Arity, TopLevelFlag(..), isTopLevel, isNeverActive,
  46                           RecFlag(..), isRec )
  47 import Maybes           ( orElse, expectJust )
  48 import Outputable
  49 \end{code}
  50
  51 To think about
  52
  53 * set a noinline pragma on bottoming Ids
  54
  55 * Consider f x = x+1 `fatbar` error (show x)
  56   We'd like to unbox x, even if that means reboxing it in the error case.
  57
  58
  59 %************************************************************************
  60 %*                                                                      *
  61 \subsection{Top level stuff}
  62 %*                                                                      *
  63 %************************************************************************
  64
  65 \begin{code}
  66 dmdAnalPgm :: DynFlags -> [CoreBind] -> IO [CoreBind]
  67 dmdAnalPgm dflags binds
  68   = do {
  69         showPass dflags "Demand analysis" ;
  70         let { binds_plus_dmds = do_prog binds } ;
  71
  72         endPass dflags "Demand analysis"
  73                 Opt_D_dump_stranal binds_plus_dmds ;
  74 #ifdef OLD_STRICTNESS
  75         -- Only if OLD_STRICTNESS is on, because only then is the old
  76         -- strictness analyser run
  77         let { dmd_changes = get_changes binds_plus_dmds } ;
  78         printDump (text "Changes in demands" $$ dmd_changes) ;
  79 #endif
  80         return binds_plus_dmds
  81     }
  82   where
  83     do_prog :: [CoreBind] -> [CoreBind]
  84     do_prog binds = snd $ mapAccumL dmdAnalTopBind emptySigEnv binds
  85
  86 dmdAnalTopBind :: SigEnv
  87                -> CoreBind
  88                -> (SigEnv, CoreBind)
  89 dmdAnalTopBind sigs (NonRec id rhs)
  90   = let
  91         (    _, _, (_,   rhs1)) = dmdAnalRhs TopLevel NonRecursive sigs (id, rhs)
  92         (sigs2, _, (id2, rhs2)) = dmdAnalRhs TopLevel NonRecursive sigs (id, rhs1)
  93                 -- Do two passes to improve CPR information
  94                 -- See comments with ignore_cpr_info in mk_sig_ty
  95                 -- and with extendSigsWithLam
  96     in
  97     (sigs2, NonRec id2 rhs2)
  98
  99 dmdAnalTopBind sigs (Rec pairs)
 100   = let
 101         (sigs', _, pairs')  = dmdFix TopLevel sigs pairs
 102                 -- We get two iterations automatically
 103                 -- c.f. the NonRec case above
 104     in
 105     (sigs', Rec pairs')
 106 \end{code}
 107
 108 \begin{code}
 109 dmdAnalTopRhs :: CoreExpr -> (StrictSig, CoreExpr)
 110 -- Analyse the RHS and return
 111 --      a) appropriate strictness info
 112 --      b) the unfolding (decorated with stricntess info)
 113 dmdAnalTopRhs rhs
 114   = (sig, rhs')
 115   where
 116     arity          = exprArity rhs
 117     (rhs_ty, rhs') = dmdAnal emptySigEnv (vanillaCall arity) rhs
 118     sig            = mkTopSigTy rhs rhs_ty
 119 \end{code}
 120
 121 %************************************************************************
 122 %*                                                                      *
 123 \subsection{The analyser itself}
 124 %*                                                                      *
 125 %************************************************************************
 126
 127 \begin{code}
 128 dmdAnal :: SigEnv -> Demand -> CoreExpr -> (DmdType, CoreExpr)
 129
 130 dmdAnal sigs Abs  e = (topDmdType, e)
 131
 132 dmdAnal sigs dmd e
 133   | not (isStrictDmd dmd)
 134   = let
 135         (res_ty, e') = dmdAnal sigs evalDmd e
 136     in
 137     (deferType res_ty, e')
 138         -- It's important not to analyse e with a lazy demand because
 139         -- a) When we encounter   case s of (a,b) ->
 140         --      we demand s with U(d1d2)... but if the overall demand is lazy
 141         --      that is wrong, and we'd need to reduce the demand on s,
 142         --      which is inconvenient
 143         -- b) More important, consider
 144         --      f (let x = R in x+x), where f is lazy
 145         --    We still want to mark x as demanded, because it will be when we
 146         --    enter the let.  If we analyse f's arg with a Lazy demand, we'll
 147         --    just mark x as Lazy
 148         -- c) The application rule wouldn't be right either
 149         --    Evaluating (f x) in a L demand does *not* cause
 150         --    evaluation of f in a C(L) demand!
 151
 152
 153 dmdAnal sigs dmd (Lit lit)
 154   = (topDmdType, Lit lit)
 155
 156 dmdAnal sigs dmd (Var var)
 157   = (dmdTransform sigs var dmd, Var var)
 158
 159 dmdAnal sigs dmd (Note n e)
 160   = (dmd_ty, Note n e')
 161   where
 162     (dmd_ty, e') = dmdAnal sigs dmd' e
 163     dmd' = case n of
 164              Coerce _ _ -> evalDmd  -- This coerce usually arises from a recursive
 165              other      -> dmd      -- newtype, and we don't want to look inside them
 166                                     -- for exactly the same reason that we don't look
 167                                     -- inside recursive products -- we might not reach
 168                                     -- a fixpoint.  So revert to a vanilla Eval demand
 169
 170 dmdAnal sigs dmd (App fun (Type ty))
 171   = (fun_ty, App fun' (Type ty))
 172   where
 173     (fun_ty, fun') = dmdAnal sigs dmd fun
 174
 175 -- Lots of the other code is there to make this
 176 -- beautiful, compositional, application rule :-)
 177 dmdAnal sigs dmd e@(App fun arg)        -- Non-type arguments
 178   = let                         -- [Type arg handled above]
 179         (fun_ty, fun')    = dmdAnal sigs (Call dmd) fun
 180         (arg_ty, arg')    = dmdAnal sigs arg_dmd arg
 181         (arg_dmd, res_ty) = splitDmdTy fun_ty
 182     in
 183     (res_ty `bothType` arg_ty, App fun' arg')
 184
 185 dmdAnal sigs dmd (Lam var body)
 186   | isTyVar var
 187   = let
 188         (body_ty, body') = dmdAnal sigs dmd body
 189     in
 190     (body_ty, Lam var body')
 191
 192   | Call body_dmd <- dmd        -- A call demand: good!
 193   = let
 194         sigs'            = extendSigsWithLam sigs var
 195         (body_ty, body') = dmdAnal sigs' body_dmd body
 196         (lam_ty, var')   = annotateLamIdBndr body_ty var
 197     in
 198     (lam_ty, Lam var' body')
 199
 200   | otherwise   -- Not enough demand on the lambda; but do the body
 201   = let         -- anyway to annotate it and gather free var info
 202         (body_ty, body') = dmdAnal sigs evalDmd body
 203         (lam_ty, var')   = annotateLamIdBndr body_ty var
 204     in
 205     (deferType lam_ty, Lam var' body')
 206
 207 dmdAnal sigs dmd (Case scrut case_bndr [alt@(DataAlt dc,bndrs,rhs)])
 208   | let tycon = dataConTyCon dc,
 209     isProductTyCon tycon,
 210     not (isRecursiveTyCon tycon)
 211   = let
 212         sigs_alt              = extendSigEnv NotTopLevel sigs case_bndr case_bndr_sig
 213         (alt_ty, alt')        = dmdAnalAlt sigs_alt dmd alt
 214         (alt_ty1, case_bndr') = annotateBndr alt_ty case_bndr
 215         (_, bndrs', _)        = alt'
 216         case_bndr_sig         = cprSig
 217                 -- Inside the alternative, the case binder has the CPR property.
 218                 -- Meaning that a case on it will successfully cancel.
 219                 -- Example:
 220                 --      f True  x = case x of y { I# x' -> if x' ==# 3 then y else I# 8 }
 221                 --      f False x = I# 3
 222                 --
 223                 -- We want f to have the CPR property:
 224                 --      f b x = case fw b x of { r -> I# r }
 225                 --      fw True  x = case x of y { I# x' -> if x' ==# 3 then x' else 8 }
 226                 --      fw False x = 3
 227
 228         -- Figure out whether the demand on the case binder is used, and use
 229         -- that to set the scrut_dmd.  This is utterly essential.
 230         -- Consider     f x = case x of y { (a,b) -> k y a }
 231         -- If we just take scrut_demand = U(L,A), then we won't pass x to the
 232         -- worker, so the worker will rebuild
 233         --      x = (a, absent-error)
 234         -- and that'll crash.
 235         -- So at one stage I had:
 236         --      dead_case_bndr           = isAbsentDmd (idNewDemandInfo case_bndr')
 237         --      keepity | dead_case_bndr = Drop
 238         --              | otherwise      = Keep
 239         --
 240         -- But then consider
 241         --      case x of y { (a,b) -> h y + a }
 242         -- where h : U(LL) -> T
 243         -- The above code would compute a Keep for x, since y is not Abs, which is silly
 244         -- The insight is, of course, that a demand on y is a demand on the
 245         -- scrutinee, so we need to `both` it with the scrut demand
 246
 247         scrut_dmd          = Eval (Prod [idNewDemandInfo b | b <- bndrs', isId b])
 248                                    `both`
 249                              idNewDemandInfo case_bndr'
 250
 251         (scrut_ty, scrut') = dmdAnal sigs scrut_dmd scrut
 252     in
 253     (alt_ty1 `bothType` scrut_ty, Case scrut' case_bndr' [alt'])
 254
 255 dmdAnal sigs dmd (Case scrut case_bndr alts)
 256   = let
 257         (alt_tys, alts')        = mapAndUnzip (dmdAnalAlt sigs dmd) alts
 258         (scrut_ty, scrut')      = dmdAnal sigs evalDmd scrut
 259         (alt_ty, case_bndr')    = annotateBndr (foldr1 lubType alt_tys) case_bndr
 260     in
 261 --    pprTrace "dmdAnal:Case" (ppr alts $$ ppr alt_tys)
 262     (alt_ty `bothType` scrut_ty, Case scrut' case_bndr' alts')
 263
 264 dmdAnal sigs dmd (Let (NonRec id rhs) body)
 265   = let
 266         (sigs', lazy_fv, (id1, rhs')) = dmdAnalRhs NotTopLevel NonRecursive sigs (id, rhs)
 267         (body_ty, body')              = dmdAnal sigs' dmd body
 268         (body_ty1, id2)               = annotateBndr body_ty id1
 269         body_ty2                      = addLazyFVs body_ty1 lazy_fv
 270     in
 271         -- If the actual demand is better than the vanilla call
 272         -- demand, you might think that we might do better to re-analyse
 273         -- the RHS with the stronger demand.
 274         -- But (a) That seldom happens, because it means that *every* path in
 275         --         the body of the let has to use that stronger demand
 276         -- (b) It often happens temporarily in when fixpointing, because
 277         --     the recursive function at first seems to place a massive demand.
 278         --     But we don't want to go to extra work when the function will
 279         --     probably iterate to something less demanding.
 280         -- In practice, all the times the actual demand on id2 is more than
 281         -- the vanilla call demand seem to be due to (b).  So we don't
 282         -- bother to re-analyse the RHS.
 283     (body_ty2, Let (NonRec id2 rhs') body')
 284
 285 dmdAnal sigs dmd (Let (Rec pairs) body)
 286   = let
 287         bndrs                    = map fst pairs
 288         (sigs', lazy_fv, pairs') = dmdFix NotTopLevel sigs pairs
 289         (body_ty, body')         = dmdAnal sigs' dmd body
 290         body_ty1                 = addLazyFVs body_ty lazy_fv
 291     in
 292     sigs' `seq` body_ty `seq`
 293     let
 294         (body_ty2, _) = annotateBndrs body_ty1 bndrs
 295                 -- Don't bother to add demand info to recursive
 296                 -- binders as annotateBndr does;
 297                 -- being recursive, we can't treat them strictly.
 298                 -- But we do need to remove the binders from the result demand env
 299     in
 300     (body_ty2,  Let (Rec pairs') body')
 301
 302
 303 dmdAnalAlt sigs dmd (con,bndrs,rhs)
 304   = let
 305         (rhs_ty, rhs')   = dmdAnal sigs dmd rhs
 306         (alt_ty, bndrs') = annotateBndrs rhs_ty bndrs
 307         final_alt_ty | io_hack_reqd = alt_ty `lubType` topDmdType
 308                      | otherwise    = alt_ty
 309
 310         -- There's a hack here for I/O operations.  Consider
 311         --      case foo x s of { (# s, r #) -> y }
 312         -- Is this strict in 'y'.  Normally yes, but what if 'foo' is an I/O
 313         -- operation that simply terminates the program (not in an erroneous way)?
 314         -- In that case we should not evaluate y before the call to 'foo'.
 315         -- Hackish solution: spot the IO-like situation and add a virtual branch,
 316         -- as if we had
 317         --      case foo x s of
 318         --         (# s, r #) -> y
 319         --         other      -> return ()
 320         -- So the 'y' isn't necessarily going to be evaluated
 321         --
 322         -- A more complete example where this shows up is:
 323         --      do { let len = <expensive> ;
 324         --         ; when (...) (exitWith ExitSuccess)
 325         --         ; print len }
 326
 327         io_hack_reqd = con == DataAlt unboxedPairDataCon &&
 328                        idType (head bndrs) `eqType` realWorldStatePrimTy
 329     in
 330     (final_alt_ty, (con, bndrs', rhs'))
 331 \end{code}
 332
 333 %************************************************************************
 334 %*                                                                      *
 335 \subsection{Bindings}
 336 %*                                                                      *
 337 %************************************************************************
 338
 339 \begin{code}
 340 dmdFix :: TopLevelFlag
 341        -> SigEnv                -- Does not include bindings for this binding
 342        -> [(Id,CoreExpr)]
 343        -> (SigEnv, DmdEnv,
 344            [(Id,CoreExpr)])     -- Binders annotated with stricness info
 345
 346 dmdFix top_lvl sigs orig_pairs
 347   = loop 1 initial_sigs orig_pairs
 348   where
 349     bndrs        = map fst orig_pairs
 350     initial_sigs = extendSigEnvList sigs [(id, (initialSig id, top_lvl)) | id <- bndrs]
 351
 352     loop :: Int
 353          -> SigEnv                      -- Already contains the current sigs
 354          -> [(Id,CoreExpr)]
 355          -> (SigEnv, DmdEnv, [(Id,CoreExpr)])
 356     loop n sigs pairs
 357       | found_fixpoint
 358       = (sigs', lazy_fv, pairs')
 359                 -- Note: use pairs', not pairs.   pairs' is the result of
 360                 -- processing the RHSs with sigs (= sigs'), whereas pairs
 361                 -- is the result of processing the RHSs with the *previous*
 362                 -- iteration of sigs.
 363
 364       | n >= 10  = pprTrace "dmdFix loop" (ppr n <+> (vcat
 365                                 [ text "Sigs:" <+> ppr [(id,lookup sigs id, lookup sigs' id) | (id,_) <- pairs],
 366                                   text "env:" <+> ppr (ufmToList sigs),
 367                                   text "binds:" <+> pprCoreBinding (Rec pairs)]))
 368                               (emptySigEnv, lazy_fv, orig_pairs)        -- Safe output
 369                         -- The lazy_fv part is really important!  orig_pairs has no strictness
 370                         -- info, including nothing about free vars.  But if we have
 371                         --      letrec f = ....y..... in ...f...
 372                         -- where 'y' is free in f, we must record that y is mentioned,
 373                         -- otherwise y will get recorded as absent altogether
 374
 375       | otherwise    = loop (n+1) sigs' pairs'
 376       where
 377         found_fixpoint = all (same_sig sigs sigs') bndrs
 378                 -- Use the new signature to do the next pair
 379                 -- The occurrence analyser has arranged them in a good order
 380                 -- so this can significantly reduce the number of iterations needed
 381         ((sigs',lazy_fv), pairs') = mapAccumL (my_downRhs top_lvl) (sigs, emptyDmdEnv) pairs
 382
 383     my_downRhs top_lvl (sigs,lazy_fv) (id,rhs)
 384         = -- pprTrace "downRhs {" (ppr id <+> (ppr old_sig))
 385           -- (new_sig `seq`
 386           --    pprTrace "downRhsEnd" (ppr id <+> ppr new_sig <+> char '}' )
 387           ((sigs', lazy_fv'), pair')
 388           --     )
 389         where
 390           (sigs', lazy_fv1, pair') = dmdAnalRhs top_lvl Recursive sigs (id,rhs)
 391           lazy_fv'                 = plusUFM_C both lazy_fv lazy_fv1
 392           -- old_sig               = lookup sigs id
 393           -- new_sig               = lookup sigs' id
 394
 395     same_sig sigs sigs' var = lookup sigs var == lookup sigs' var
 396     lookup sigs var = case lookupVarEnv sigs var of
 397                         Just (sig,_) -> sig
 398
 399         -- Get an initial strictness signature from the Id
 400         -- itself.  That way we make use of earlier iterations
 401         -- of the fixpoint algorithm.  (Cunning plan.)
 402         -- Note that the cunning plan extends to the DmdEnv too,
 403         -- since it is part of the strictness signature
 404 initialSig id = idNewStrictness_maybe id `orElse` botSig
 405
 406 dmdAnalRhs :: TopLevelFlag -> RecFlag
 407         -> SigEnv -> (Id, CoreExpr)
 408         -> (SigEnv,  DmdEnv, (Id, CoreExpr))
 409 -- Process the RHS of the binding, add the strictness signature
 410 -- to the Id, and augment the environment with the signature as well.
 411
 412 dmdAnalRhs top_lvl rec_flag sigs (id, rhs)
 413  = (sigs', lazy_fv, (id', rhs'))
 414  where
 415   arity              = idArity id   -- The idArity should be up to date
 416                                     -- The simplifier was run just beforehand
 417   (rhs_dmd_ty, rhs') = dmdAnal sigs (vanillaCall arity) rhs
 418   (lazy_fv, sig_ty)  = WARN( arity /= dmdTypeDepth rhs_dmd_ty, ppr id )
 419                        mkSigTy top_lvl rec_flag id rhs rhs_dmd_ty
 420   id'                = id `setIdNewStrictness` sig_ty
 421   sigs'              = extendSigEnv top_lvl sigs id sig_ty
 422 \end{code}
 423
 424 %************************************************************************
 425 %*                                                                      *
 426 \subsection{Strictness signatures and types}
 427 %*                                                                      *
 428 %************************************************************************
 429
 430 \begin{code}
 431 mkTopSigTy :: CoreExpr -> DmdType -> StrictSig
 432         -- Take a DmdType and turn it into a StrictSig
 433         -- NB: not used for never-inline things; hence False
 434 mkTopSigTy rhs dmd_ty = snd (mk_sig_ty False False rhs dmd_ty)
 435
 436 mkSigTy :: TopLevelFlag -> RecFlag -> Id -> CoreExpr -> DmdType -> (DmdEnv, StrictSig)
 437 mkSigTy top_lvl rec_flag id rhs dmd_ty
 438   = mk_sig_ty never_inline thunk_cpr_ok rhs dmd_ty
 439   where
 440     never_inline = isNeverActive (idInlinePragma id)
 441     maybe_id_dmd = idNewDemandInfo_maybe id
 442         -- Is Nothing the first time round
 443
 444     thunk_cpr_ok
 445         | isTopLevel top_lvl       = False      -- Top level things don't get
 446                                                 -- their demandInfo set at all
 447         | isRec rec_flag           = False      -- Ditto recursive things
 448         | Just dmd <- maybe_id_dmd = isStrictDmd dmd
 449         | otherwise                = True       -- Optimistic, first time round
 450                                                 -- See notes below
 451 \end{code}
 452
 453 The thunk_cpr_ok stuff [CPR-AND-STRICTNESS]
 454 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 455 If the rhs is a thunk, we usually forget the CPR info, because
 456 it is presumably shared (else it would have been inlined, and
 457 so we'd lose sharing if w/w'd it into a function.
 458
 459 However, if the strictness analyser has figured out (in a previous
 460 iteration) that it's strict, then we DON'T need to forget the CPR info.
 461 Instead we can retain the CPR info and do the thunk-splitting transform
 462 (see WorkWrap.splitThunk).
 463
 464 This made a big difference to PrelBase.modInt, which had something like
 465         modInt = \ x -> let r = ... -> I# v in
 466                         ...body strict in r...
 467 r's RHS isn't a value yet; but modInt returns r in various branches, so
 468 if r doesn't have the CPR property then neither does modInt
 469 Another case I found in practice (in Complex.magnitude), looks like this:
 470                 let k = if ... then I# a else I# b
 471                 in ... body strict in k ....
 472 (For this example, it doesn't matter whether k is returned as part of
 473 the overall result; but it does matter that k's RHS has the CPR property.)
 474 Left to itself, the simplifier will make a join point thus:
 475                 let $j k = ...body strict in k...
 476                 if ... then $j (I# a) else $j (I# b)
 477 With thunk-splitting, we get instead
 478                 let $j x = let k = I#x in ...body strict in k...
 479                 in if ... then $j a else $j b
 480 This is much better; there's a good chance the I# won't get allocated.
 481
 482 The difficulty with this is that we need the strictness type to
 483 look at the body... but we now need the body to calculate the demand
 484 on the variable, so we can decide whether its strictness type should
 485 have a CPR in it or not.  Simple solution:
 486         a) use strictness info from the previous iteration
 487         b) make sure we do at least 2 iterations, by doing a second
 488            round for top-level non-recs.  Top level recs will get at
 489            least 2 iterations except for totally-bottom functions
 490            which aren't very interesting anyway.
 491
 492 NB: strictly_demanded is never true of a top-level Id, or of a recursive Id.
 493
 494 The Nothing case in thunk_cpr_ok [CPR-AND-STRICTNESS]
 495 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 496 Demand info now has a 'Nothing' state, just like strictness info.
 497 The analysis works from 'dangerous' towards a 'safe' state; so we
 498 start with botSig for 'Nothing' strictness infos, and we start with
 499 "yes, it's demanded" for 'Nothing' in the demand info.  The
 500 fixpoint iteration will sort it all out.
 501
 502 We can't start with 'not-demanded' because then consider
 503         f x = let
 504                   t = ... I# x
 505               in
 506               if ... then t else I# y else f x'
 507
 508 In the first iteration we'd have no demand info for x, so assume
 509 not-demanded; then we'd get TopRes for f's CPR info.  Next iteration
 510 we'd see that t was demanded, and so give it the CPR property, but by
 511 now f has TopRes, so it will stay TopRes.  Instead, with the Nothing
 512 setting the first time round, we say 'yes t is demanded' the first
 513 time.
 514
 515 However, this does mean that for non-recursive bindings we must
 516 iterate twice to be sure of not getting over-optimistic CPR info,
 517 in the case where t turns out to be not-demanded.  This is handled
 518 by dmdAnalTopBind.
 519
 520
 521 \begin{code}
 522 mk_sig_ty never_inline thunk_cpr_ok rhs (DmdType fv dmds res)
 523   | never_inline && not (isBotRes res)
 524         --                      HACK ALERT
 525         -- Don't strictness-analyse NOINLINE things.  Why not?  Because
 526         -- the NOINLINE says "don't expose any of the inner workings at the call
 527         -- site" and the strictness is certainly an inner working.
 528         --
 529         -- More concretely, the demand analyser discovers the following strictness
 530         -- for unsafePerformIO:  C(U(AV))
 531         -- But then consider
 532         --      unsafePerformIO (\s -> let r = f x in
 533         --                             case writeIORef v r s of (# s1, _ #) ->
 534         --                             (# s1, r #)
 535         -- The strictness analyser will find that the binding for r is strict,
 536         -- (becuase of uPIO's strictness sig), and so it'll evaluate it before
 537         -- doing the writeIORef.  This actually makes tests/lib/should_run/memo002
 538         -- get a deadlock!
 539         --
 540         -- Solution: don't expose the strictness of unsafePerformIO.
 541         --
 542         -- But we do want to expose the strictness of error functions,
 543         -- which are also often marked NOINLINE
 544         --      {-# NOINLINE foo #-}
 545         --      foo x = error ("wubble buggle" ++ x)
 546         -- So (hack, hack) we only drop the strictness for non-bottom things
 547         -- This is all very unsatisfactory.
 548   = (deferEnv fv, topSig)
 549
 550   | otherwise
 551   = (lazy_fv, mkStrictSig dmd_ty)
 552   where
 553     dmd_ty = DmdType strict_fv final_dmds res'
 554
 555     lazy_fv   = filterUFM (not . isStrictDmd) fv
 556     strict_fv = filterUFM isStrictDmd         fv
 557         -- We put the strict FVs in the DmdType of the Id, so
 558         -- that at its call sites we unleash demands on its strict fvs.
 559         -- An example is 'roll' in imaginary/wheel-sieve2
 560         -- Something like this:
 561         --      roll x = letrec
 562         --                   go y = if ... then roll (x-1) else x+1
 563         --               in
 564         --               go ms
 565         -- We want to see that roll is strict in x, which is because
 566         -- go is called.   So we put the DmdEnv for x in go's DmdType.
 567         --
 568         -- Another example:
 569         --      f :: Int -> Int -> Int
 570         --      f x y = let t = x+1
 571         --          h z = if z==0 then t else
 572         --                if z==1 then x+1 else
 573         --                x + h (z-1)
 574         --      in
 575         --      h y
 576         -- Calling h does indeed evaluate x, but we can only see
 577         -- that if we unleash a demand on x at the call site for t.
 578         --
 579         -- Incidentally, here's a place where lambda-lifting h would
 580         -- lose the cigar --- we couldn't see the joint strictness in t/x
 581         --
 582         --      ON THE OTHER HAND
 583         -- We don't want to put *all* the fv's from the RHS into the
 584         -- DmdType, because that makes fixpointing very slow --- the
 585         -- DmdType gets full of lazy demands that are slow to converge.
 586
 587     final_dmds = setUnpackStrategy dmds
 588         -- Set the unpacking strategy
 589
 590     res' = case res of
 591                 RetCPR | ignore_cpr_info -> TopRes
 592                 other                    -> res
 593     ignore_cpr_info = not (exprIsValue rhs || thunk_cpr_ok)
 594 \end{code}
 595
 596 The unpack strategy determines whether we'll *really* unpack the argument,
 597 or whether we'll just remember its strictness.  If unpacking would give
 598 rise to a *lot* of worker args, we may decide not to unpack after all.
 599
 600 \begin{code}
 601 setUnpackStrategy :: [Demand] -> [Demand]
 602 setUnpackStrategy ds
 603   = snd (go (opt_MaxWorkerArgs - nonAbsentArgs ds) ds)
 604   where
 605     go :: Int                   -- Max number of args available for sub-components of [Demand]
 606        -> [Demand]
 607        -> (Int, [Demand])       -- Args remaining after subcomponents of [Demand] are unpacked
 608
 609     go n (Eval (Prod cs) : ds)
 610         | n' >= 0   = Eval (Prod cs') `cons` go n'' ds
 611         | otherwise = Box (Eval (Prod cs)) `cons` go n ds
 612         where
 613           (n'',cs') = go n' cs
 614           n' = n + 1 - non_abs_args
 615                 -- Add one to the budget 'cos we drop the top-level arg
 616           non_abs_args = nonAbsentArgs cs
 617                 -- Delete # of non-absent args to which we'll now be committed
 618
 619     go n (d:ds) = d `cons` go n ds
 620     go n []     = (n,[])
 621
 622     cons d (n,ds) = (n, d:ds)
 623
 624 nonAbsentArgs :: [Demand] -> Int
 625 nonAbsentArgs []         = 0
 626 nonAbsentArgs (Abs : ds) = nonAbsentArgs ds
 627 nonAbsentArgs (d   : ds) = 1 + nonAbsentArgs ds
 628 \end{code}
 629
 630
 631 %************************************************************************
 632 %*                                                                      *
 633 \subsection{Strictness signatures and types}
 634 %*                                                                      *
 635 %************************************************************************
 636
 637 \begin{code}
 638 splitDmdTy :: DmdType -> (Demand, DmdType)
 639 -- Split off one function argument
 640 -- We already have a suitable demand on all
 641 -- free vars, so no need to add more!
 642 splitDmdTy (DmdType fv (dmd:dmds) res_ty) = (dmd, DmdType fv dmds res_ty)
 643 splitDmdTy ty@(DmdType fv [] res_ty)      = (resTypeArgDmd res_ty, ty)
 644 \end{code}
 645
 646 \begin{code}
 647 unitVarDmd var dmd = DmdType (unitVarEnv var dmd) [] TopRes
 648
 649 addVarDmd top_lvl dmd_ty@(DmdType fv ds res) var dmd
 650   | isTopLevel top_lvl = dmd_ty         -- Don't record top level things
 651   | otherwise          = DmdType (extendVarEnv fv var dmd) ds res
 652
 653 addLazyFVs (DmdType fv ds res) lazy_fvs
 654   = DmdType both_fv1 ds res
 655   where
 656     both_fv = (plusUFM_C both fv lazy_fvs)
 657     both_fv1 = modifyEnv (isBotRes res) (`both` Bot) lazy_fvs fv both_fv
 658         -- This modifyEnv is vital.  Consider
 659         --      let f = \x -> (x,y)
 660         --      in  error (f 3)
 661         -- Here, y is treated as a lazy-fv of f, but we must `both` that L
 662         -- demand with the bottom coming up from 'error'
 663         --
 664         -- I got a loop in the fixpointer without this, due to an interaction
 665         -- with the lazy_fv filtering in mkSigTy.  Roughly, it was
 666         --      letrec f n x
 667         --          = letrec g y = x `fatbar`
 668         --                         letrec h z = z + ...g...
 669         --                         in h (f (n-1) x)
 670         --      in ...
 671         -- In the initial iteration for f, f=Bot
 672         -- Suppose h is found to be strict in z, but the occurrence of g in its RHS
 673         -- is lazy.  Now consider the fixpoint iteration for g, esp the demands it
 674         -- places on its free variables.  Suppose it places none.  Then the
 675         --      x `fatbar` ...call to h...
 676         -- will give a x->V demand for x.  That turns into a L demand for x,
 677         -- which floats out of the defn for h.  Without the modifyEnv, that
 678         -- L demand doesn't get both'd with the Bot coming up from the inner
 679         -- call to f.  So we just get an L demand for x for g.
 680         --
 681         -- A better way to say this is that the lazy-fv filtering should give the
 682         -- same answer as putting the lazy fv demands in the function's type.
 683
 684 annotateBndr :: DmdType -> Var -> (DmdType, Var)
 685 -- The returned env has the var deleted
 686 -- The returned var is annotated with demand info
 687 -- No effect on the argument demands
 688 annotateBndr dmd_ty@(DmdType fv ds res) var
 689   | isTyVar var = (dmd_ty, var)
 690   | otherwise   = (DmdType fv' ds res, setIdNewDemandInfo var dmd)
 691   where
 692     (fv', dmd) = removeFV fv var res
 693
 694 annotateBndrs = mapAccumR annotateBndr
 695
 696 annotateLamIdBndr dmd_ty@(DmdType fv ds res) id
 697 -- For lambdas we add the demand to the argument demands
 698 -- Only called for Ids
 699   = ASSERT( isId id )
 700     (DmdType fv' (hacked_dmd:ds) res, setIdNewDemandInfo id hacked_dmd)
 701   where
 702     (fv', dmd) = removeFV fv id res
 703     hacked_dmd = argDemand dmd
 704         -- This call to argDemand is vital, because otherwise we label
 705         -- a lambda binder with demand 'B'.  But in terms of calling
 706         -- conventions that's Abs, because we don't pass it.  But
 707         -- when we do a w/w split we get
 708         --      fw x = (\x y:B -> ...) x (error "oops")
 709         -- And then the simplifier things the 'B' is a strict demand
 710         -- and evaluates the (error "oops").  Sigh
 711
 712 removeFV fv id res = (fv', zapUnlifted id dmd)
 713                 where
 714                   fv' = fv `delVarEnv` id
 715                   dmd = lookupVarEnv fv id `orElse` deflt
 716                   deflt | isBotRes res = Bot
 717                         | otherwise    = Abs
 718
 719 -- For unlifted-type variables, we are only
 720 -- interested in Bot/Abs/Box Abs
 721 zapUnlifted is Bot = Bot
 722 zapUnlifted id Abs = Abs
 723 zapUnlifted id dmd | isUnLiftedType (idType id) = lazyDmd
 724                    | otherwise                  = dmd
 725 \end{code}
 726
 727 %************************************************************************
 728 %*                                                                      *
 729 \subsection{Strictness signatures}
 730 %*                                                                      *
 731 %************************************************************************
 732
 733 \begin{code}
 734 type SigEnv  = VarEnv (StrictSig, TopLevelFlag)
 735         -- We use the SigEnv to tell us whether to
 736         -- record info about a variable in the DmdEnv
 737         -- We do so if it's a LocalId, but not top-level
 738         --
 739         -- The DmdEnv gives the demand on the free vars of the function
 740         -- when it is given enough args to satisfy the strictness signature
 741
 742 emptySigEnv  = emptyVarEnv
 743
 744 extendSigEnv :: TopLevelFlag -> SigEnv -> Id -> StrictSig -> SigEnv
 745 extendSigEnv top_lvl env var sig = extendVarEnv env var (sig, top_lvl)
 746
 747 extendSigEnvList = extendVarEnvList
 748
 749 extendSigsWithLam :: SigEnv -> Id -> SigEnv
 750 -- Extend the SigEnv when we meet a lambda binder
 751 -- If the binder is marked demanded with a product demand, then give it a CPR
 752 -- signature, because in the likely event that this is a lambda on a fn defn
 753 -- [we only use this when the lambda is being consumed with a call demand],
 754 -- it'll be w/w'd and so it will be CPR-ish.  E.g.
 755 --      f = \x::(Int,Int).  if ...strict in x... then
 756 --                              x
 757 --                          else
 758 --                              (a,b)
 759 -- We want f to have the CPR property because x does, by the time f has been w/w'd
 760 --
 761 --      NOTE: see notes [CPR-AND-STRICTNESS]
 762 --
 763 -- Also note that we only want to do this for something that
 764 -- definitely has product type, else we may get over-optimistic
 765 -- CPR results (e.g. from \x -> x!).
 766
 767 extendSigsWithLam sigs id
 768   = case idNewDemandInfo_maybe id of
 769         Nothing               -> extendVarEnv sigs id (cprSig, NotTopLevel)
 770         Just (Eval (Prod ds)) -> extendVarEnv sigs id (cprSig, NotTopLevel)
 771         other                 -> sigs
 772
 773
 774 dmdTransform :: SigEnv          -- The strictness environment
 775              -> Id              -- The function
 776              -> Demand          -- The demand on the function
 777              -> DmdType         -- The demand type of the function in this context
 778         -- Returned DmdEnv includes the demand on
 779         -- this function plus demand on its free variables
 780
 781 dmdTransform sigs var dmd
 782
 783 ------  DATA CONSTRUCTOR
 784   | isDataConWorkId var         -- Data constructor
 785   = let
 786         StrictSig dmd_ty    = idNewStrictness var       -- It must have a strictness sig
 787         DmdType _ _ con_res = dmd_ty
 788         arity               = idArity var
 789     in
 790     if arity == call_depth then         -- Saturated, so unleash the demand
 791         let
 792                 -- Important!  If we Keep the constructor application, then
 793                 -- we need the demands the constructor places (always lazy)
 794                 -- If not, we don't need to.  For example:
 795                 --      f p@(x,y) = (p,y)       -- S(AL)
 796                 --      g a b     = f (a,b)
 797                 -- It's vital that we don't calculate Absent for a!
 798            dmd_ds = case res_dmd of
 799                         Box (Eval ds) -> mapDmds box ds
 800                         Eval ds       -> ds
 801                         other         -> Poly Top
 802
 803                 -- ds can be empty, when we are just seq'ing the thing
 804                 -- If so we must make up a suitable bunch of demands
 805            arg_ds = case dmd_ds of
 806                       Poly d  -> replicate arity d
 807                       Prod ds -> ASSERT( ds `lengthIs` arity ) ds
 808
 809         in
 810         mkDmdType emptyDmdEnv arg_ds con_res
 811                 -- Must remember whether it's a product, hence con_res, not TopRes
 812     else
 813         topDmdType
 814
 815 ------  IMPORTED FUNCTION
 816   | isGlobalId var,             -- Imported function
 817     let StrictSig dmd_ty = idNewStrictness var
 818   = if dmdTypeDepth dmd_ty <= call_depth then   -- Saturated, so unleash the demand
 819         dmd_ty
 820     else
 821         topDmdType
 822
 823 ------  LOCAL LET/REC BOUND THING
 824   | Just (StrictSig dmd_ty, top_lvl) <- lookupVarEnv sigs var
 825   = let
 826         fn_ty | dmdTypeDepth dmd_ty <= call_depth = dmd_ty
 827               | otherwise                         = deferType dmd_ty
 828         -- NB: it's important to use deferType, and not just return topDmdType
 829         -- Consider     let { f x y = p + x } in f 1
 830         -- The application isn't saturated, but we must nevertheless propagate
 831         --      a lazy demand for p!
 832     in
 833     addVarDmd top_lvl fn_ty var dmd
 834
 835 ------  LOCAL NON-LET/REC BOUND THING
 836   | otherwise                   -- Default case
 837   = unitVarDmd var dmd
 838
 839   where
 840     (call_depth, res_dmd) = splitCallDmd dmd
 841 \end{code}
 842
 843
 844 %************************************************************************
 845 %*                                                                      *
 846 \subsection{Demands}
 847 %*                                                                      *
 848 %************************************************************************
 849
 850 \begin{code}
 851 splitCallDmd :: Demand -> (Int, Demand)
 852 splitCallDmd (Call d) = case splitCallDmd d of
 853                           (n, r) -> (n+1, r)
 854 splitCallDmd d        = (0, d)
 855
 856 vanillaCall :: Arity -> Demand
 857 vanillaCall 0 = evalDmd
 858 vanillaCall n = Call (vanillaCall (n-1))
 859
 860 deferType :: DmdType -> DmdType
 861 deferType (DmdType fv _ _) = DmdType (deferEnv fv) [] TopRes
 862         -- Notice that we throw away info about both arguments and results
 863         -- For example,   f = let ... in \x -> x
 864         -- We don't want to get a stricness type V->T for f.
 865         -- Peter??
 866
 867 deferEnv :: DmdEnv -> DmdEnv
 868 deferEnv fv = mapVarEnv defer fv
 869
 870
 871 ----------------
 872 argDemand :: Demand -> Demand
 873 -- The 'Defer' demands are just Lazy at function boundaries
 874 -- Ugly!  Ask John how to improve it.
 875 argDemand Top       = lazyDmd
 876 argDemand (Defer d) = lazyDmd
 877 argDemand (Eval ds) = Eval (mapDmds argDemand ds)
 878 argDemand (Box Bot) = evalDmd
 879 argDemand (Box d)   = box (argDemand d)
 880 argDemand Bot       = Abs       -- Don't pass args that are consumed (only) by bottom
 881 argDemand d         = d
 882 \end{code}
 883
 884 \begin{code}
 885 -------------------------
 886 -- Consider (if x then y else []) with demand V
 887 -- Then the first branch gives {y->V} and the second
 888 -- *implicitly* has {y->A}.  So we must put {y->(V `lub` A)}
 889 -- in the result env.
 890 lubType (DmdType fv1 ds1 r1) (DmdType fv2 ds2 r2)
 891   = DmdType lub_fv2 (lub_ds ds1 ds2) (r1 `lubRes` r2)
 892   where
 893     lub_fv  = plusUFM_C lub fv1 fv2
 894     lub_fv1 = modifyEnv (not (isBotRes r1)) absLub fv2 fv1 lub_fv
 895     lub_fv2 = modifyEnv (not (isBotRes r2)) absLub fv1 fv2 lub_fv1
 896         -- lub is the identity for Bot
 897
 898         -- Extend the shorter argument list to match the longer
 899     lub_ds (d1:ds1) (d2:ds2) = lub d1 d2 : lub_ds ds1 ds2
 900     lub_ds []       []       = []
 901     lub_ds ds1      []       = map (`lub` resTypeArgDmd r2) ds1
 902     lub_ds []       ds2      = map (resTypeArgDmd r1 `lub`) ds2
 903
 904 -----------------------------------
 905 -- (t1 `bothType` t2) takes the argument/result info from t1,
 906 -- using t2 just for its free-var info
 907 -- NB: Don't forget about r2!  It might be BotRes, which is
 908 --     a bottom demand on all the in-scope variables.
 909 -- Peter: can this be done more neatly?
 910 bothType (DmdType fv1 ds1 r1) (DmdType fv2 ds2 r2)
 911   = DmdType both_fv2 ds1 (r1 `bothRes` r2)
 912   where
 913     both_fv  = plusUFM_C both fv1 fv2
 914     both_fv1 = modifyEnv (isBotRes r1) (`both` Bot) fv2 fv1 both_fv
 915     both_fv2 = modifyEnv (isBotRes r2) (`both` Bot) fv1 fv2 both_fv1
 916         -- both is the identity for Abs
 917 \end{code}
 918
 919
 920 \begin{code}
 921 lubRes BotRes r      = r
 922 lubRes r      BotRes = r
 923 lubRes RetCPR RetCPR = RetCPR
 924 lubRes r1     r2     = TopRes
 925
 926 -- If either diverges, the whole thing does
 927 -- Otherwise take CPR info from the first
 928 bothRes r1 BotRes = BotRes
 929 bothRes r1 r2     = r1
 930 \end{code}
 931
 932 \begin{code}
 933 modifyEnv :: Bool                       -- No-op if False
 934           -> (Demand -> Demand)         -- The zapper
 935           -> DmdEnv -> DmdEnv           -- Env1 and Env2
 936           -> DmdEnv -> DmdEnv           -- Transform this env
 937         -- Zap anything in Env1 but not in Env2
 938         -- Assume: dom(env) includes dom(Env1) and dom(Env2)
 939
 940 modifyEnv need_to_modify zapper env1 env2 env
 941   | need_to_modify = foldr zap env (keysUFM (env1 `minusUFM` env2))
 942   | otherwise      = env
 943   where
 944     zap uniq env = addToUFM_Directly env uniq (zapper current_val)
 945                  where
 946                    current_val = expectJust "modifyEnv" (lookupUFM_Directly env uniq)
 947 \end{code}
 948
 949
 950 %************************************************************************
 951 %*                                                                      *
 952 \subsection{LUB and BOTH}
 953 %*                                                                      *
 954 %************************************************************************
 955
 956 \begin{code}
 957 lub :: Demand -> Demand -> Demand
 958
 959 lub Bot         d2 = d2
 960 lub Abs         d2 = absLub d2
 961 lub Top         d2 = Top
 962 lub (Defer ds1) d2 = defer (Eval ds1 `lub` d2)
 963
 964 lub (Call d1)   (Call d2)    = Call (d1 `lub` d2)
 965 lub d1@(Call _) (Box d2)     = d1 `lub` d2      -- Just strip the box
 966 lub d1@(Call _) d2@(Eval _)  = d2               -- Presumably seq or vanilla eval
 967 lub d1@(Call _) d2           = d2 `lub` d1      -- Bot, Abs, Top
 968
 969 -- For the Eval case, we use these approximation rules
 970 -- Box Bot       <= Eval (Box Bot ...)
 971 -- Box Top       <= Defer (Box Bot ...)
 972 -- Box (Eval ds) <= Eval (map Box ds)
 973 lub (Eval ds1)  (Eval ds2)        = Eval (ds1 `lubs` ds2)
 974 lub (Eval ds1)  (Box Bot)         = Eval (mapDmds (`lub` Box Bot) ds1)
 975 lub (Eval ds1)  (Box (Eval ds2)) = Eval (ds1 `lubs` mapDmds box ds2)
 976 lub (Eval ds1)  (Box Abs)        = deferEval (mapDmds (`lub` Box Bot) ds1)
 977 lub d1@(Eval _) d2                = d2 `lub` d1 -- Bot,Abs,Top,Call,Defer
 978
 979 lub (Box d1)   (Box d2) = box (d1 `lub` d2)
 980 lub d1@(Box _)  d2      = d2 `lub` d1
 981
 982 lubs = zipWithDmds lub
 983
 984 ---------------------
 985 -- box is the smart constructor for Box
 986 -- It computes <B,bot> & d
 987 -- INVARIANT: (Box d) => d = Bot, Abs, Eval
 988 -- Seems to be no point in allowing (Box (Call d))
 989 box (Call d)  = Call d  -- The odd man out.  Why?
 990 box (Box d)   = Box d
 991 box (Defer _) = lazyDmd
 992 box Top       = lazyDmd -- Box Abs and Box Top
 993 box Abs       = lazyDmd -- are the same <B,L>
 994 box d         = Box d   -- Bot, Eval
 995
 996 ---------------
 997 defer :: Demand -> Demand
 998
 999 -- defer is the smart constructor for Defer
1000 -- The idea is that (Defer ds) = <U(ds), L>
1001 --
1002 -- It specifies what happens at a lazy function argument
1003 -- or a lambda; the L* operator
1004 -- Set the strictness part to L, but leave
1005 -- the boxity side unaffected
1006 -- It also ensures that Defer (Eval [LLLL]) = L
1007
1008 defer Bot        = Abs
1009 defer Abs        = Abs
1010 defer Top        = Top
1011 defer (Call _)   = lazyDmd      -- Approximation here?
1012 defer (Box _)    = lazyDmd
1013 defer (Defer ds) = Defer ds
1014 defer (Eval ds)  = deferEval ds
1015
1016 -- deferEval ds = defer (Eval ds)
1017 deferEval ds | allTop ds = Top
1018              | otherwise  = Defer ds
1019
1020 ---------------------
1021 absLub :: Demand -> Demand
1022 -- Computes (Abs `lub` d)
1023 -- For the Bot case consider
1024 --      f x y = if ... then x else error x
1025 --   Then for y we get Abs `lub` Bot, and we really
1026 --   want Abs overall
1027 absLub Bot        = Abs
1028 absLub Abs        = Abs
1029 absLub Top        = Top
1030 absLub (Call _)   = Top
1031 absLub (Box _)    = Top
1032 absLub (Eval ds)  = Defer (absLubs ds)  -- Or (Defer ds)?
1033 absLub (Defer ds) = Defer (absLubs ds)  -- Or (Defer ds)?
1034
1035 absLubs = mapDmds absLub
1036
1037 ---------------
1038 both :: Demand -> Demand -> Demand
1039
1040 both Abs d2 = d2
1041
1042 both Bot Bot       = Bot
1043 both Bot Abs       = Bot
1044 both Bot (Eval ds) = Eval (mapDmds (`both` Bot) ds)
1045         -- Consider
1046         --      f x = error x
1047         -- From 'error' itself we get demand Bot on x
1048         -- From the arg demand on x we get
1049         --      x :-> evalDmd = Box (Eval (Poly Abs))
1050         -- So we get  Bot `both` Box (Eval (Poly Abs))
1051         --          = Seq Keep (Poly Bot)
1052         --
1053         -- Consider also
1054         --      f x = if ... then error (fst x) else fst x
1055         -- Then we get (Eval (Box Bot, Bot) `lub` Eval (SA))
1056         --      = Eval (SA)
1057         -- which is what we want.
1058 both Bot d = errDmd
1059
1060 both Top Bot         = errDmd
1061 both Top Abs         = Top
1062 both Top Top         = Top
1063 both Top (Box d)    = Box d
1064 both Top (Call d)   = Call d
1065 both Top (Eval ds)  = Eval (mapDmds (`both` Top) ds)
1066 both Top (Defer ds)     -- = defer (Top `both` Eval ds)
1067                         -- = defer (Eval (mapDmds (`both` Top) ds))
1068                      = deferEval (mapDmds (`both` Top) ds)
1069
1070
1071 both (Box d1)   (Box d2)    = box (d1 `both` d2)
1072 both (Box d1)   d2@(Call _) = box (d1 `both` d2)
1073 both (Box d1)   d2@(Eval _) = box (d1 `both` d2)
1074 both (Box d1)   (Defer d2)  = Box d1
1075 both d1@(Box _) d2          = d2 `both` d1
1076
1077 both (Call d1)   (Call d2)   = Call (d1 `both` d2)
1078 both (Call d1)   (Eval ds2)  = Call d1  -- Could do better for (Poly Bot)?
1079 both (Call d1)   (Defer ds2) = Call d1  -- Ditto
1080 both d1@(Call _) d2          = d1 `both` d1
1081
1082 both (Eval ds1)    (Eval  ds2) = Eval (ds1 `boths` ds2)
1083 both (Eval ds1)    (Defer ds2) = Eval (ds1 `boths` mapDmds defer ds2)
1084 both d1@(Eval ds1) d2          = d2 `both` d1
1085
1086 both (Defer ds1) (Defer ds2) = deferEval (ds1 `boths` ds2)
1087 both d1@(Defer ds1) d2       = d2 `both` d1
1088
1089 boths = zipWithDmds both
1090 \end{code}
1091
1092
1093
1094 %************************************************************************
1095 %*                                                                      *
1096 \subsection{Miscellaneous
1097 %*                                                                      *
1098 %************************************************************************
1099
1100
1101 \begin{code}
1102 #ifdef OLD_STRICTNESS
1103 get_changes binds = vcat (map get_changes_bind binds)
1104
1105 get_changes_bind (Rec pairs) = vcat (map get_changes_pr pairs)
1106 get_changes_bind (NonRec id rhs) = get_changes_pr (id,rhs)
1107
1108 get_changes_pr (id,rhs)
1109   = get_changes_var id $$ get_changes_expr rhs
1110
1111 get_changes_var var
1112   | isId var  = get_changes_str var $$ get_changes_dmd var
1113   | otherwise = empty
1114
1115 get_changes_expr (Type t)     = empty
1116 get_changes_expr (Var v)      = empty
1117 get_changes_expr (Lit l)      = empty
1118 get_changes_expr (Note n e)   = get_changes_expr e
1119 get_changes_expr (App e1 e2)  = get_changes_expr e1 $$ get_changes_expr e2
1120 get_changes_expr (Lam b e)    = {- get_changes_var b $$ -} get_changes_expr e
1121 get_changes_expr (Let b e)    = get_changes_bind b $$ get_changes_expr e
1122 get_changes_expr (Case e b a) = get_changes_expr e $$ {- get_changes_var b $$ -} vcat (map get_changes_alt a)
1123
1124 get_changes_alt (con,bs,rhs) = {- vcat (map get_changes_var bs) $$ -} get_changes_expr rhs
1125
1126 get_changes_str id
1127   | new_better && old_better = empty
1128   | new_better               = message "BETTER"
1129   | old_better               = message "WORSE"
1130   | otherwise                = message "INCOMPARABLE"
1131   where
1132     message word = text word <+> text "strictness for" <+> ppr id <+> info
1133     info = (text "Old" <+> ppr old) $$ (text "New" <+> ppr new)
1134     new = squashSig (idNewStrictness id)        -- Don't report spurious diffs that the old
1135                                                 -- strictness analyser can't track
1136     old = newStrictnessFromOld (idName id) (idArity id) (idStrictness id) (idCprInfo id)
1137     old_better = old `betterStrictness` new
1138     new_better = new `betterStrictness` old
1139
1140 get_changes_dmd id
1141   | isUnLiftedType (idType id) = empty  -- Not useful
1142   | new_better && old_better = empty
1143   | new_better               = message "BETTER"
1144   | old_better               = message "WORSE"
1145   | otherwise                = message "INCOMPARABLE"
1146   where
1147     message word = text word <+> text "demand for" <+> ppr id <+> info
1148     info = (text "Old" <+> ppr old) $$ (text "New" <+> ppr new)
1149     new = squashDmd (argDemand (idNewDemandInfo id))    -- To avoid spurious improvements
1150                                                         -- A bit of a hack
1151     old = newDemand (idDemandInfo id)
1152     new_better = new `betterDemand` old
1153     old_better = old `betterDemand` new
1154
1155 betterStrictness :: StrictSig -> StrictSig -> Bool
1156 betterStrictness (StrictSig t1) (StrictSig t2) = betterDmdType t1 t2
1157
1158 betterDmdType t1 t2 = (t1 `lubType` t2) == t2
1159
1160 betterDemand :: Demand -> Demand -> Bool
1161 -- If d1 `better` d2, and d2 `better` d2, then d1==d2
1162 betterDemand d1 d2 = (d1 `lub` d2) == d2
1163
1164 squashSig (StrictSig (DmdType fv ds res))
1165   = StrictSig (DmdType emptyDmdEnv (map squashDmd ds) res)
1166   where
1167         -- squash just gets rid of call demands
1168         -- which the old analyser doesn't track
1169 squashDmd (Call d)   = evalDmd
1170 squashDmd (Box d)    = Box (squashDmd d)
1171 squashDmd (Eval ds)  = Eval (mapDmds squashDmd ds)
1172 squashDmd (Defer ds) = Defer (mapDmds squashDmd ds)
1173 squashDmd d          = d
1174 #endif
1175 \end{code}