ghc/compiler/stranal/DmdAnal.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4
   5                         -----------------
   6                         A demand analysis
   7                         -----------------
   8
   9 \begin{code}
  10 module DmdAnal ( dmdAnalPgm, dmdAnalTopRhs,
  11                  both {- needed by WwLib -}
  12    ) where
  13
  14 #include "HsVersions.h"
  15
  16 import CmdLineOpts      ( DynFlags, DynFlag(..), opt_MaxWorkerArgs )
  17 import NewDemand        -- All of it
  18 import CoreSyn
  19 import PprCore
  20 import CoreUtils        ( exprIsValue, exprArity )
  21 import DataCon          ( dataConTyCon )
  22 import TyCon            ( isProductTyCon, isRecursiveTyCon )
  23 import Id               ( Id, idType, idInlinePragma,
  24                           isDataConId, isGlobalId, idArity,
  25 #ifdef OLD_STRICTNESS
  26                           idDemandInfo,  idStrictness, idCprInfo,
  27 #endif
  28                           idNewStrictness, idNewStrictness_maybe,
  29                           setIdNewStrictness, idNewDemandInfo,
  30                           idNewDemandInfo_maybe,
  31                           setIdNewDemandInfo, idName
  32                         )
  33 #ifdef OLD_STRICTNESS
  34 import IdInfo           ( newStrictnessFromOld, newDemand )
  35 #endif
  36 import Var              ( Var )
  37 import VarEnv
  38 import UniqFM           ( plusUFM_C, addToUFM_Directly, lookupUFM_Directly,
  39                           keysUFM, minusUFM, ufmToList, filterUFM )
  40 import Type             ( isUnLiftedType )
  41 import CoreLint         ( showPass, endPass )
  42 import Util             ( mapAndUnzip, mapAccumL, mapAccumR, lengthIs )
  43 import BasicTypes       ( Arity, TopLevelFlag(..), isTopLevel, isNeverActive )
  44 import Maybes           ( orElse, expectJust )
  45 import Outputable
  46 \end{code}
  47
  48 To think about
  49
  50 * set a noinline pragma on bottoming Ids
  51
  52 * Consider f x = x+1 `fatbar` error (show x)
  53   We'd like to unbox x, even if that means reboxing it in the error case.
  54
  55 \begin{code}
  56 instance Outputable TopLevelFlag where
  57   ppr flag = empty
  58 \end{code}
  59
  60 %************************************************************************
  61 %*                                                                      *
  62 \subsection{Top level stuff}
  63 %*                                                                      *
  64 %************************************************************************
  65
  66 \begin{code}
  67 dmdAnalPgm :: DynFlags -> [CoreBind] -> IO [CoreBind]
  68 dmdAnalPgm dflags binds
  69   = do {
  70         showPass dflags "Demand analysis" ;
  71         let { binds_plus_dmds = do_prog binds } ;
  72
  73         endPass dflags "Demand analysis"
  74                 Opt_D_dump_stranal binds_plus_dmds ;
  75 #ifdef OLD_STRICTNESS
  76         -- Only if OLD_STRICTNESS is on, because only then is the old
  77         -- strictness analyser run
  78         let { dmd_changes = get_changes binds_plus_dmds } ;
  79         printDump (text "Changes in demands" $$ dmd_changes) ;
  80 #endif
  81         return binds_plus_dmds
  82     }
  83   where
  84     do_prog :: [CoreBind] -> [CoreBind]
  85     do_prog binds = snd $ mapAccumL dmdAnalTopBind emptySigEnv binds
  86
  87 dmdAnalTopBind :: SigEnv
  88                -> CoreBind
  89                -> (SigEnv, CoreBind)
  90 dmdAnalTopBind sigs (NonRec id rhs)
  91   = let
  92         (    _, _, (_,   rhs1)) = dmdAnalRhs TopLevel sigs (id, rhs)
  93         (sigs2, _, (id2, rhs2)) = dmdAnalRhs TopLevel sigs (id, rhs1)
  94                 -- Do two passes to improve CPR information
  95                 -- See comments with ignore_cpr_info in mk_sig_ty
  96                 -- and with extendSigsWithLam
  97     in
  98     (sigs2, NonRec id2 rhs2)
  99
 100 dmdAnalTopBind sigs (Rec pairs)
 101   = let
 102         (sigs', _, pairs')  = dmdFix TopLevel sigs pairs
 103                 -- We get two iterations automatically
 104                 -- c.f. the NonRec case above
 105     in
 106     (sigs', Rec pairs')
 107 \end{code}
 108
 109 \begin{code}
 110 dmdAnalTopRhs :: CoreExpr -> (StrictSig, CoreExpr)
 111 -- Analyse the RHS and return
 112 --      a) appropriate strictness info
 113 --      b) the unfolding (decorated with stricntess info)
 114 dmdAnalTopRhs rhs
 115   = (sig, rhs')
 116   where
 117     arity          = exprArity rhs
 118     (rhs_ty, rhs') = dmdAnal emptySigEnv (vanillaCall arity) rhs
 119     sig            = mkTopSigTy rhs rhs_ty
 120 \end{code}
 121
 122 %************************************************************************
 123 %*                                                                      *
 124 \subsection{The analyser itself}
 125 %*                                                                      *
 126 %************************************************************************
 127
 128 \begin{code}
 129 dmdAnal :: SigEnv -> Demand -> CoreExpr -> (DmdType, CoreExpr)
 130
 131 dmdAnal sigs Abs  e = (topDmdType, e)
 132
 133 dmdAnal sigs dmd e
 134   | not (isStrictDmd dmd)
 135   = let
 136         (res_ty, e') = dmdAnal sigs evalDmd e
 137     in
 138     (deferType res_ty, e')
 139         -- It's important not to analyse e with a lazy demand because
 140         -- a) When we encounter   case s of (a,b) ->
 141         --      we demand s with U(d1d2)... but if the overall demand is lazy
 142         --      that is wrong, and we'd need to reduce the demand on s,
 143         --      which is inconvenient
 144         -- b) More important, consider
 145         --      f (let x = R in x+x), where f is lazy
 146         --    We still want to mark x as demanded, because it will be when we
 147         --    enter the let.  If we analyse f's arg with a Lazy demand, we'll
 148         --    just mark x as Lazy
 149         -- c) The application rule wouldn't be right either
 150         --    Evaluating (f x) in a L demand does *not* cause
 151         --    evaluation of f in a C(L) demand!
 152
 153
 154 dmdAnal sigs dmd (Lit lit)
 155   = (topDmdType, Lit lit)
 156
 157 dmdAnal sigs dmd (Var var)
 158   = (dmdTransform sigs var dmd, Var var)
 159
 160 dmdAnal sigs dmd (Note n e)
 161   = (dmd_ty, Note n e')
 162   where
 163     (dmd_ty, e') = dmdAnal sigs dmd' e
 164     dmd' = case n of
 165              Coerce _ _ -> evalDmd  -- This coerce usually arises from a recursive
 166              other      -> dmd      -- newtype, and we don't want to look inside them
 167                                     -- for exactly the same reason that we don't look
 168                                     -- inside recursive products -- we might not reach
 169                                     -- a fixpoint.  So revert to a vanilla Eval demand
 170
 171 dmdAnal sigs dmd (App fun (Type ty))
 172   = (fun_ty, App fun' (Type ty))
 173   where
 174     (fun_ty, fun') = dmdAnal sigs dmd fun
 175
 176 -- Lots of the other code is there to make this
 177 -- beautiful, compositional, application rule :-)
 178 dmdAnal sigs dmd e@(App fun arg)        -- Non-type arguments
 179   = let                         -- [Type arg handled above]
 180         (fun_ty, fun')    = dmdAnal sigs (Call dmd) fun
 181         (arg_ty, arg')    = dmdAnal sigs arg_dmd arg
 182         (arg_dmd, res_ty) = splitDmdTy fun_ty
 183     in
 184     (res_ty `bothType` arg_ty, App fun' arg')
 185
 186 dmdAnal sigs dmd (Lam var body)
 187   | isTyVar var
 188   = let
 189         (body_ty, body') = dmdAnal sigs dmd body
 190     in
 191     (body_ty, Lam var body')
 192
 193   | Call body_dmd <- dmd        -- A call demand: good!
 194   = let
 195         sigs'            = extendSigsWithLam sigs var
 196         (body_ty, body') = dmdAnal sigs' body_dmd body
 197         (lam_ty, var')   = annotateLamIdBndr body_ty var
 198     in
 199     (lam_ty, Lam var' body')
 200
 201   | otherwise   -- Not enough demand on the lambda; but do the body
 202   = let         -- anyway to annotate it and gather free var info
 203         (body_ty, body') = dmdAnal sigs evalDmd body
 204         (lam_ty, var')   = annotateLamIdBndr body_ty var
 205     in
 206     (deferType lam_ty, Lam var' body')
 207
 208 dmdAnal sigs dmd (Case scrut case_bndr [alt@(DataAlt dc,bndrs,rhs)])
 209   | let tycon = dataConTyCon dc,
 210     isProductTyCon tycon,
 211     not (isRecursiveTyCon tycon)
 212   = let
 213         sigs_alt              = extendSigEnv NotTopLevel sigs case_bndr case_bndr_sig
 214         (alt_ty, alt')        = dmdAnalAlt sigs_alt dmd alt
 215         (alt_ty1, case_bndr') = annotateBndr alt_ty case_bndr
 216         (_, bndrs', _)        = alt'
 217         case_bndr_sig         = cprSig
 218                 -- Inside the alternative, the case binder has the CPR property.
 219                 -- Meaning that a case on it will successfully cancel.
 220                 -- Example:
 221                 --      f True  x = case x of y { I# x' -> if x' ==# 3 then y else I# 8 }
 222                 --      f False x = I# 3
 223                 --
 224                 -- We want f to have the CPR property:
 225                 --      f b x = case fw b x of { r -> I# r }
 226                 --      fw True  x = case x of y { I# x' -> if x' ==# 3 then x' else 8 }
 227                 --      fw False x = 3
 228
 229         -- Figure out whether the demand on the case binder is used, and use
 230         -- that to set the scrut_dmd.  This is utterly essential.
 231         -- Consider     f x = case x of y { (a,b) -> k y a }
 232         -- If we just take scrut_demand = U(L,A), then we won't pass x to the
 233         -- worker, so the worker will rebuild
 234         --      x = (a, absent-error)
 235         -- and that'll crash.
 236         -- So at one stage I had:
 237         --      dead_case_bndr           = isAbsentDmd (idNewDemandInfo case_bndr')
 238         --      keepity | dead_case_bndr = Drop
 239         --              | otherwise      = Keep
 240         --
 241         -- But then consider
 242         --      case x of y { (a,b) -> h y + a }
 243         -- where h : U(LL) -> T
 244         -- The above code would compute a Keep for x, since y is not Abs, which is silly
 245         -- The insight is, of course, that a demand on y is a demand on the
 246         -- scrutinee, so we need to `both` it with the scrut demand
 247
 248         scrut_dmd          = Eval (Prod [idNewDemandInfo b | b <- bndrs', isId b])
 249                                    `both`
 250                              idNewDemandInfo case_bndr'
 251
 252         (scrut_ty, scrut') = dmdAnal sigs scrut_dmd scrut
 253     in
 254     (alt_ty1 `bothType` scrut_ty, Case scrut' case_bndr' [alt'])
 255
 256 dmdAnal sigs dmd (Case scrut case_bndr alts)
 257   = let
 258         (alt_tys, alts')        = mapAndUnzip (dmdAnalAlt sigs dmd) alts
 259         (scrut_ty, scrut')      = dmdAnal sigs evalDmd scrut
 260         (alt_ty, case_bndr')    = annotateBndr (foldr1 lubType alt_tys) case_bndr
 261     in
 262 --    pprTrace "dmdAnal:Case" (ppr alts $$ ppr alt_tys)
 263     (alt_ty `bothType` scrut_ty, Case scrut' case_bndr' alts')
 264
 265 dmdAnal sigs dmd (Let (NonRec id rhs) body)
 266   = let
 267         (sigs', lazy_fv, (id1, rhs')) = dmdAnalRhs NotTopLevel sigs (id, rhs)
 268         (body_ty, body')              = dmdAnal sigs' dmd body
 269         (body_ty1, id2)               = annotateBndr body_ty id1
 270         body_ty2                      = addLazyFVs body_ty1 lazy_fv
 271     in
 272 #ifdef DEBUG
 273         -- If the actual demand is better than the vanilla
 274         -- demand, we might do better to re-analyse with the
 275         -- stronger demand.
 276     (let vanilla_dmd = vanillaCall (idArity id)
 277          actual_dmd  = idNewDemandInfo id2
 278      in
 279      if actual_dmd `betterDemand` vanilla_dmd && actual_dmd /= vanilla_dmd then
 280         pprTrace "dmdLet: better demand" (ppr id <+> vcat [text "vanilla" <+> ppr vanilla_dmd,
 281                                                            text "actual" <+> ppr actual_dmd])
 282      else \x -> x)
 283 #endif
 284     (body_ty2, Let (NonRec id2 rhs') body')
 285
 286 dmdAnal sigs dmd (Let (Rec pairs) body)
 287   = let
 288         bndrs                    = map fst pairs
 289         (sigs', lazy_fv, pairs') = dmdFix NotTopLevel sigs pairs
 290         (body_ty, body')         = dmdAnal sigs' dmd body
 291         body_ty1                 = addLazyFVs body_ty lazy_fv
 292     in
 293     sigs' `seq` body_ty `seq`
 294     let
 295         (body_ty2, _) = annotateBndrs body_ty1 bndrs
 296                 -- Don't bother to add demand info to recursive
 297                 -- binders as annotateBndr does;
 298                 -- being recursive, we can't treat them strictly.
 299                 -- But we do need to remove the binders from the result demand env
 300     in
 301     (body_ty2,  Let (Rec pairs') body')
 302
 303
 304 dmdAnalAlt sigs dmd (con,bndrs,rhs)
 305   = let
 306         (rhs_ty, rhs')   = dmdAnal sigs dmd rhs
 307         (alt_ty, bndrs') = annotateBndrs rhs_ty bndrs
 308     in
 309     (alt_ty, (con, bndrs', rhs'))
 310 \end{code}
 311
 312 %************************************************************************
 313 %*                                                                      *
 314 \subsection{Bindings}
 315 %*                                                                      *
 316 %************************************************************************
 317
 318 \begin{code}
 319 dmdFix :: TopLevelFlag
 320        -> SigEnv                -- Does not include bindings for this binding
 321        -> [(Id,CoreExpr)]
 322        -> (SigEnv, DmdEnv,
 323            [(Id,CoreExpr)])     -- Binders annotated with stricness info
 324
 325 dmdFix top_lvl sigs orig_pairs
 326   = loop 1 initial_sigs orig_pairs
 327   where
 328     bndrs        = map fst orig_pairs
 329     initial_sigs = extendSigEnvList sigs [(id, (initialSig id, top_lvl)) | id <- bndrs]
 330
 331     loop :: Int
 332          -> SigEnv                      -- Already contains the current sigs
 333          -> [(Id,CoreExpr)]
 334          -> (SigEnv, DmdEnv, [(Id,CoreExpr)])
 335     loop n sigs pairs
 336       | all (same_sig sigs sigs') bndrs
 337       = (sigs', lazy_fv, pairs')
 338                 -- Note: use pairs', not pairs.   pairs' is the result of
 339                 -- processing the RHSs with sigs (= sigs'), whereas pairs
 340                 -- is the result of processing the RHSs with the *previous*
 341                 -- iteration of sigs.
 342       | n >= 10       = pprTrace "dmdFix loop" (ppr n <+> (vcat
 343                                 [ text "Sigs:" <+> ppr [(id,lookup sigs id, lookup sigs' id) | (id,_) <- pairs],
 344                                   text "env:" <+> ppr (ufmToList sigs),
 345                                   text "binds:" <+> pprCoreBinding (Rec pairs)]))
 346                               (emptySigEnv, emptyDmdEnv, orig_pairs)    -- Safe output
 347       | otherwise    = loop (n+1) sigs' pairs'
 348       where
 349                 -- Use the new signature to do the next pair
 350                 -- The occurrence analyser has arranged them in a good order
 351                 -- so this can significantly reduce the number of iterations needed
 352         ((sigs',lazy_fv), pairs') = mapAccumL (my_downRhs top_lvl) (sigs, emptyDmdEnv) pairs
 353
 354     my_downRhs top_lvl (sigs,lazy_fv) (id,rhs)
 355         = -- pprTrace "downRhs {" (ppr id <+> (ppr old_sig))
 356           -- (new_sig `seq`
 357           --    pprTrace "downRhsEnd" (ppr id <+> ppr new_sig <+> char '}' )
 358           ((sigs', lazy_fv'), pair')
 359           --     )
 360         where
 361           (sigs', lazy_fv1, pair') = dmdAnalRhs top_lvl sigs (id,rhs)
 362           lazy_fv'                 = plusUFM_C both lazy_fv lazy_fv1
 363           -- old_sig               = lookup sigs id
 364           -- new_sig               = lookup sigs' id
 365
 366     same_sig sigs sigs' var = lookup sigs var == lookup sigs' var
 367     lookup sigs var = case lookupVarEnv sigs var of
 368                         Just (sig,_) -> sig
 369
 370         -- Get an initial strictness signature from the Id
 371         -- itself.  That way we make use of earlier iterations
 372         -- of the fixpoint algorithm.  (Cunning plan.)
 373         -- Note that the cunning plan extends to the DmdEnv too,
 374         -- since it is part of the strictness signature
 375 initialSig id = idNewStrictness_maybe id `orElse` botSig
 376
 377 dmdAnalRhs :: TopLevelFlag
 378         -> SigEnv -> (Id, CoreExpr)
 379         -> (SigEnv,  DmdEnv, (Id, CoreExpr))
 380 -- Process the RHS of the binding, add the strictness signature
 381 -- to the Id, and augment the environment with the signature as well.
 382
 383 dmdAnalRhs top_lvl sigs (id, rhs)
 384  = (sigs', lazy_fv, (id', rhs'))
 385  where
 386   arity              = idArity id   -- The idArity should be up to date
 387                                     -- The simplifier was run just beforehand
 388   (rhs_dmd_ty, rhs') = dmdAnal sigs (vanillaCall arity) rhs
 389   (lazy_fv, sig_ty)  = WARN( arity /= dmdTypeDepth rhs_dmd_ty, ppr id )
 390                        mkSigTy top_lvl id rhs rhs_dmd_ty
 391   id'                = id `setIdNewStrictness` sig_ty
 392   sigs'              = extendSigEnv top_lvl sigs id sig_ty
 393 \end{code}
 394
 395 %************************************************************************
 396 %*                                                                      *
 397 \subsection{Strictness signatures and types}
 398 %*                                                                      *
 399 %************************************************************************
 400
 401 \begin{code}
 402 mkTopSigTy :: CoreExpr -> DmdType -> StrictSig
 403         -- Take a DmdType and turn it into a StrictSig
 404         -- NB: not used for never-inline things; hence False
 405 mkTopSigTy rhs dmd_ty = snd (mk_sig_ty False False rhs dmd_ty)
 406
 407 mkSigTy :: TopLevelFlag -> Id -> CoreExpr -> DmdType -> (DmdEnv, StrictSig)
 408 mkSigTy top_lvl id rhs dmd_ty
 409   = mk_sig_ty never_inline thunk_cpr_ok rhs dmd_ty
 410   where
 411     never_inline = isNeverActive (idInlinePragma id)
 412     maybe_id_dmd = idNewDemandInfo_maybe id
 413         -- Is Nothing the first time round
 414
 415     thunk_cpr_ok
 416         | isTopLevel top_lvl       = False      -- Top level things don't get
 417                                                 -- their demandInfo set at all
 418         | Just dmd <- maybe_id_dmd = isStrictDmd dmd
 419         | otherwise                = True       -- Optimistic, first time round
 420                                                 -- See notes below
 421 \end{code}
 422
 423 The thunk_cpr_ok stuff [CPR-AND-STRICTNESS]
 424 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 425 If the rhs is a thunk, we usually forget the CPR info, because
 426 it is presumably shared (else it would have been inlined, and
 427 so we'd lose sharing if w/w'd it into a function.
 428
 429 However, if the strictness analyser has figured out (in a previous
 430 iteration) that it's strict, then we DON'T need to forget the CPR info.
 431 Instead we can retain the CPR info and do the thunk-splitting transform
 432 (see WorkWrap.splitThunk).
 433
 434 This made a big difference to PrelBase.modInt, which had something like
 435         modInt = \ x -> let r = ... -> I# v in
 436                         ...body strict in r...
 437 r's RHS isn't a value yet; but modInt returns r in various branches, so
 438 if r doesn't have the CPR property then neither does modInt
 439 Another case I found in practice (in Complex.magnitude), looks like this:
 440                 let k = if ... then I# a else I# b
 441                 in ... body strict in k ....
 442 (For this example, it doesn't matter whether k is returned as part of
 443 the overall result; but it does matter that k's RHS has the CPR property.)
 444 Left to itself, the simplifier will make a join point thus:
 445                 let $j k = ...body strict in k...
 446                 if ... then $j (I# a) else $j (I# b)
 447 With thunk-splitting, we get instead
 448                 let $j x = let k = I#x in ...body strict in k...
 449                 in if ... then $j a else $j b
 450 This is much better; there's a good chance the I# won't get allocated.
 451
 452 The difficulty with this is that we need the strictness type to
 453 look at the body... but we now need the body to calculate the demand
 454 on the variable, so we can decide whether its strictness type should
 455 have a CPR in it or not.  Simple solution:
 456         a) use strictness info from the previous iteration
 457         b) make sure we do at least 2 iterations, by doing a second
 458            round for top-level non-recs.  Top level recs will get at
 459            least 2 iterations except for totally-bottom functions
 460            which aren't very interesting anyway.
 461
 462 NB: strictly_demanded is never true of a top-level Id, or of a recursive Id.
 463
 464 The Nothing case in thunk_cpr_ok [CPR-AND-STRICTNESS]
 465 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 466 Demand info now has a 'Nothing' state, just like strictness info.
 467 The analysis works from 'dangerous' towards a 'safe' state; so we
 468 start with botSig for 'Nothing' strictness infos, and we start with
 469 "yes, it's demanded" for 'Nothing' in the demand info.  The
 470 fixpoint iteration will sort it all out.
 471
 472 We can't start with 'not-demanded' because then consider
 473         f x = let
 474                   t = ... I# x
 475               in
 476               if ... then t else I# y else f x'
 477
 478 In the first iteration we'd have no demand info for x, so assume
 479 not-demanded; then we'd get TopRes for f's CPR info.  Next iteration
 480 we'd see that t was demanded, and so give it the CPR property, but
 481 by now f has TopRes, so it will stay TopRes.
 482 ever_in
 483 Instead, with the Nothing setting the first time round, we say
 484 'yes t is demanded' the first time.
 485
 486 However, this does mean that for non-recursive bindings we must
 487 iterate twice to be sure of not getting over-optimistic CPR info,
 488 in the case where t turns out to be not-demanded.  This is handled
 489 by dmdAnalTopBind.
 490
 491
 492 \begin{code}
 493 mk_sig_ty never_inline thunk_cpr_ok rhs (DmdType fv dmds res)
 494   | never_inline && not (isBotRes res)
 495         --                      HACK ALERT
 496         -- Don't strictness-analyse NOINLINE things.  Why not?  Because
 497         -- the NOINLINE says "don't expose any of the inner workings at the call
 498         -- site" and the strictness is certainly an inner working.
 499         --
 500         -- More concretely, the demand analyser discovers the following strictness
 501         -- for unsafePerformIO:  C(U(AV))
 502         -- But then consider
 503         --      unsafePerformIO (\s -> let r = f x in
 504         --                             case writeIORef v r s of (# s1, _ #) ->
 505         --                             (# s1, r #)
 506         -- The strictness analyser will find that the binding for r is strict,
 507         -- (becuase of uPIO's strictness sig), and so it'll evaluate it before
 508         -- doing the writeIORef.  This actually makes tests/lib/should_run/memo002
 509         -- get a deadlock!
 510         --
 511         -- Solution: don't expose the strictness of unsafePerformIO.
 512         --
 513         -- But we do want to expose the strictness of error functions,
 514         -- which are also often marked NOINLINE
 515         --      {-# NOINLINE foo #-}
 516         --      foo x = error ("wubble buggle" ++ x)
 517         -- So (hack, hack) we only drop the strictness for non-bottom things
 518         -- This is all very unsatisfactory.
 519   = (deferEnv fv, topSig)
 520
 521   | otherwise
 522   = (lazy_fv, mkStrictSig dmd_ty)
 523   where
 524     dmd_ty = DmdType strict_fv final_dmds res'
 525
 526     lazy_fv   = filterUFM (not . isStrictDmd) fv
 527     strict_fv = filterUFM isStrictDmd         fv
 528         -- We put the strict FVs in the DmdType of the Id, so
 529         -- that at its call sites we unleash demands on its strict fvs.
 530         -- An example is 'roll' in imaginary/wheel-sieve2
 531         -- Something like this:
 532         --      roll x = letrec
 533         --                   go y = if ... then roll (x-1) else x+1
 534         --               in
 535         --               go ms
 536         -- We want to see that roll is strict in x, which is because
 537         -- go is called.   So we put the DmdEnv for x in go's DmdType.
 538         --
 539         -- Another example:
 540         --      f :: Int -> Int -> Int
 541         --      f x y = let t = x+1
 542         --          h z = if z==0 then t else
 543         --                if z==1 then x+1 else
 544         --                x + h (z-1)
 545         --      in
 546         --      h y
 547         -- Calling h does indeed evaluate x, but we can only see
 548         -- that if we unleash a demand on x at the call site for t.
 549         --
 550         -- Incidentally, here's a place where lambda-lifting h would
 551         -- lose the cigar --- we couldn't see the joint strictness in t/x
 552         --
 553         --      ON THE OTHER HAND
 554         -- We don't want to put *all* the fv's from the RHS into the
 555         -- DmdType, because that makes fixpointing very slow --- the
 556         -- DmdType gets full of lazy demands that are slow to converge.
 557
 558     final_dmds = setUnpackStrategy dmds
 559         -- Set the unpacking strategy
 560
 561     res' = case res of
 562                 RetCPR | ignore_cpr_info -> TopRes
 563                 other                    -> res
 564     ignore_cpr_info = not (exprIsValue rhs || thunk_cpr_ok)
 565 \end{code}
 566
 567 The unpack strategy determines whether we'll *really* unpack the argument,
 568 or whether we'll just remember its strictness.  If unpacking would give
 569 rise to a *lot* of worker args, we may decide not to unpack after all.
 570
 571 \begin{code}
 572 setUnpackStrategy :: [Demand] -> [Demand]
 573 setUnpackStrategy ds
 574   = snd (go (opt_MaxWorkerArgs - nonAbsentArgs ds) ds)
 575   where
 576     go :: Int                   -- Max number of args available for sub-components of [Demand]
 577        -> [Demand]
 578        -> (Int, [Demand])       -- Args remaining after subcomponents of [Demand] are unpacked
 579
 580     go n (Eval (Prod cs) : ds)
 581         | n' >= 0   = Eval (Prod cs') `cons` go n'' ds
 582         | otherwise = Box (Eval (Prod cs)) `cons` go n ds
 583         where
 584           (n'',cs') = go n' cs
 585           n' = n + 1 - non_abs_args
 586                 -- Add one to the budget 'cos we drop the top-level arg
 587           non_abs_args = nonAbsentArgs cs
 588                 -- Delete # of non-absent args to which we'll now be committed
 589
 590     go n (d:ds) = d `cons` go n ds
 591     go n []     = (n,[])
 592
 593     cons d (n,ds) = (n, d:ds)
 594
 595 nonAbsentArgs :: [Demand] -> Int
 596 nonAbsentArgs []         = 0
 597 nonAbsentArgs (Abs : ds) = nonAbsentArgs ds
 598 nonAbsentArgs (d   : ds) = 1 + nonAbsentArgs ds
 599 \end{code}
 600
 601
 602 %************************************************************************
 603 %*                                                                      *
 604 \subsection{Strictness signatures and types}
 605 %*                                                                      *
 606 %************************************************************************
 607
 608 \begin{code}
 609 splitDmdTy :: DmdType -> (Demand, DmdType)
 610 -- Split off one function argument
 611 -- We already have a suitable demand on all
 612 -- free vars, so no need to add more!
 613 splitDmdTy (DmdType fv (dmd:dmds) res_ty) = (dmd, DmdType fv dmds res_ty)
 614 splitDmdTy ty@(DmdType fv [] res_ty)      = (resTypeArgDmd res_ty, ty)
 615 \end{code}
 616
 617 \begin{code}
 618 unitVarDmd var dmd = DmdType (unitVarEnv var dmd) [] TopRes
 619
 620 addVarDmd top_lvl dmd_ty@(DmdType fv ds res) var dmd
 621   | isTopLevel top_lvl = dmd_ty         -- Don't record top level things
 622   | otherwise          = DmdType (extendVarEnv fv var dmd) ds res
 623
 624 addLazyFVs (DmdType fv ds res) lazy_fvs
 625   = DmdType both_fv1 ds res
 626   where
 627     both_fv = (plusUFM_C both fv lazy_fvs)
 628     both_fv1 = modifyEnv (isBotRes res) (`both` Bot) lazy_fvs fv both_fv
 629         -- This modifyEnv is vital.  Consider
 630         --      let f = \x -> (x,y)
 631         --      in  error (f 3)
 632         -- Here, y is treated as a lazy-fv of f, but we must `both` that L
 633         -- demand with the bottom coming up from 'error'
 634         --
 635         -- I got a loop in the fixpointer without this, due to an interaction
 636         -- with the lazy_fv filtering in mkSigTy.  Roughly, it was
 637         --      letrec f n x
 638         --          = letrec g y = x `fatbar`
 639         --                         letrec h z = z + ...g...
 640         --                         in h (f (n-1) x)
 641         --      in ...
 642         -- In the initial iteration for f, f=Bot
 643         -- Suppose h is found to be strict in z, but the occurrence of g in its RHS
 644         -- is lazy.  Now consider the fixpoint iteration for g, esp the demands it
 645         -- places on its free variables.  Suppose it places none.  Then the
 646         --      x `fatbar` ...call to h...
 647         -- will give a x->V demand for x.  That turns into a L demand for x,
 648         -- which floats out of the defn for h.  Without the modifyEnv, that
 649         -- L demand doesn't get both'd with the Bot coming up from the inner
 650         -- call to f.  So we just get an L demand for x for g.
 651         --
 652         -- A better way to say this is that the lazy-fv filtering should give the
 653         -- same answer as putting the lazy fv demands in the function's type.
 654
 655 annotateBndr :: DmdType -> Var -> (DmdType, Var)
 656 -- The returned env has the var deleted
 657 -- The returned var is annotated with demand info
 658 -- No effect on the argument demands
 659 annotateBndr dmd_ty@(DmdType fv ds res) var
 660   | isTyVar var = (dmd_ty, var)
 661   | otherwise   = (DmdType fv' ds res, setIdNewDemandInfo var dmd)
 662   where
 663     (fv', dmd) = removeFV fv var res
 664
 665 annotateBndrs = mapAccumR annotateBndr
 666
 667 annotateLamIdBndr dmd_ty@(DmdType fv ds res) id
 668 -- For lambdas we add the demand to the argument demands
 669 -- Only called for Ids
 670   = ASSERT( isId id )
 671     (DmdType fv' (hacked_dmd:ds) res, setIdNewDemandInfo id hacked_dmd)
 672   where
 673     (fv', dmd) = removeFV fv id res
 674     hacked_dmd = argDemand dmd
 675         -- This call to argDemand is vital, because otherwise we label
 676         -- a lambda binder with demand 'B'.  But in terms of calling
 677         -- conventions that's Abs, because we don't pass it.  But
 678         -- when we do a w/w split we get
 679         --      fw x = (\x y:B -> ...) x (error "oops")
 680         -- And then the simplifier things the 'B' is a strict demand
 681         -- and evaluates the (error "oops").  Sigh
 682
 683 removeFV fv id res = (fv', zapUnlifted id dmd)
 684                 where
 685                   fv' = fv `delVarEnv` id
 686                   dmd = lookupVarEnv fv id `orElse` deflt
 687                   deflt | isBotRes res = Bot
 688                         | otherwise    = Abs
 689
 690 -- For unlifted-type variables, we are only
 691 -- interested in Bot/Abs/Box Abs
 692 zapUnlifted is Bot = Bot
 693 zapUnlifted id Abs = Abs
 694 zapUnlifted id dmd | isUnLiftedType (idType id) = lazyDmd
 695                    | otherwise                  = dmd
 696 \end{code}
 697
 698 %************************************************************************
 699 %*                                                                      *
 700 \subsection{Strictness signatures}
 701 %*                                                                      *
 702 %************************************************************************
 703
 704 \begin{code}
 705 type SigEnv  = VarEnv (StrictSig, TopLevelFlag)
 706         -- We use the SigEnv to tell us whether to
 707         -- record info about a variable in the DmdEnv
 708         -- We do so if it's a LocalId, but not top-level
 709         --
 710         -- The DmdEnv gives the demand on the free vars of the function
 711         -- when it is given enough args to satisfy the strictness signature
 712
 713 emptySigEnv  = emptyVarEnv
 714
 715 extendSigEnv :: TopLevelFlag -> SigEnv -> Id -> StrictSig -> SigEnv
 716 extendSigEnv top_lvl env var sig = extendVarEnv env var (sig, top_lvl)
 717
 718 extendSigEnvList = extendVarEnvList
 719
 720 extendSigsWithLam :: SigEnv -> Id -> SigEnv
 721 -- Extend the SigEnv when we meet a lambda binder
 722 --  If the binder is marked demanded with a product demand, then give it a CPR
 723 -- signature, because in the likely event that this is a lambda on a fn defn
 724 -- [we only use this when the lambda is being consumed with a call demand],
 725 -- it'll be w/w'd and so it will be CPR-ish.
 726 --
 727 --      NOTE: see notes [CPR-AND-STRICTNESS]
 728 --
 729 -- Also note that we only want to do this for something that
 730 -- definitely has product type, else we may get over-optimistic
 731 -- CPR results (e.g. from \x -> x!).
 732
 733 extendSigsWithLam sigs id
 734   = case idNewDemandInfo_maybe id of
 735         Nothing               -> extendVarEnv sigs id (cprSig, NotTopLevel)
 736         Just (Eval (Prod ds)) -> extendVarEnv sigs id (cprSig, NotTopLevel)
 737         other                 -> sigs
 738
 739 cprSig :: StrictSig
 740 cprSig = StrictSig (mkDmdType emptyVarEnv [] RetCPR)
 741
 742
 743 dmdTransform :: SigEnv          -- The strictness environment
 744              -> Id              -- The function
 745              -> Demand          -- The demand on the function
 746              -> DmdType         -- The demand type of the function in this context
 747         -- Returned DmdEnv includes the demand on
 748         -- this function plus demand on its free variables
 749
 750 dmdTransform sigs var dmd
 751
 752 ------  DATA CONSTRUCTOR
 753   | isDataConId var             -- Data constructor
 754   = let
 755         StrictSig dmd_ty    = idNewStrictness var       -- It must have a strictness sig
 756         DmdType _ _ con_res = dmd_ty
 757         arity               = idArity var
 758     in
 759     if arity == call_depth then         -- Saturated, so unleash the demand
 760         let
 761                 -- Important!  If we Keep the constructor application, then
 762                 -- we need the demands the constructor places (always lazy)
 763                 -- If not, we don't need to.  For example:
 764                 --      f p@(x,y) = (p,y)       -- S(AL)
 765                 --      g a b     = f (a,b)
 766                 -- It's vital that we don't calculate Absent for a!
 767            dmd_ds = case res_dmd of
 768                         Box (Eval ds) -> mapDmds box ds
 769                         Eval ds       -> ds
 770                         other         -> Poly Top
 771
 772                 -- ds can be empty, when we are just seq'ing the thing
 773                 -- If so we must make up a suitable bunch of demands
 774            arg_ds = case dmd_ds of
 775                       Poly d  -> replicate arity d
 776                       Prod ds -> ASSERT( ds `lengthIs` arity ) ds
 777
 778         in
 779         mkDmdType emptyDmdEnv arg_ds con_res
 780                 -- Must remember whether it's a product, hence con_res, not TopRes
 781     else
 782         topDmdType
 783
 784 ------  IMPORTED FUNCTION
 785   | isGlobalId var,             -- Imported function
 786     let StrictSig dmd_ty = idNewStrictness var
 787   = if dmdTypeDepth dmd_ty <= call_depth then   -- Saturated, so unleash the demand
 788         dmd_ty
 789     else
 790         topDmdType
 791
 792 ------  LOCAL LET/REC BOUND THING
 793   | Just (StrictSig dmd_ty, top_lvl) <- lookupVarEnv sigs var
 794   = let
 795         fn_ty | dmdTypeDepth dmd_ty <= call_depth = dmd_ty
 796               | otherwise                         = deferType dmd_ty
 797         -- NB: it's important to use deferType, and not just return topDmdType
 798         -- Consider     let { f x y = p + x } in f 1
 799         -- The application isn't saturated, but we must nevertheless propagate
 800         --      a lazy demand for p!
 801     in
 802     addVarDmd top_lvl fn_ty var dmd
 803
 804 ------  LOCAL NON-LET/REC BOUND THING
 805   | otherwise                   -- Default case
 806   = unitVarDmd var dmd
 807
 808   where
 809     (call_depth, res_dmd) = splitCallDmd dmd
 810 \end{code}
 811
 812
 813 %************************************************************************
 814 %*                                                                      *
 815 \subsection{Demands}
 816 %*                                                                      *
 817 %************************************************************************
 818
 819 \begin{code}
 820 splitCallDmd :: Demand -> (Int, Demand)
 821 splitCallDmd (Call d) = case splitCallDmd d of
 822                           (n, r) -> (n+1, r)
 823 splitCallDmd d        = (0, d)
 824
 825 vanillaCall :: Arity -> Demand
 826 vanillaCall 0 = evalDmd
 827 vanillaCall n = Call (vanillaCall (n-1))
 828
 829 deferType :: DmdType -> DmdType
 830 deferType (DmdType fv _ _) = DmdType (deferEnv fv) [] TopRes
 831         -- Notice that we throw away info about both arguments and results
 832         -- For example,   f = let ... in \x -> x
 833         -- We don't want to get a stricness type V->T for f.
 834         -- Peter??
 835
 836 deferEnv :: DmdEnv -> DmdEnv
 837 deferEnv fv = mapVarEnv defer fv
 838
 839
 840 ----------------
 841 argDemand :: Demand -> Demand
 842 -- The 'Defer' demands are just Lazy at function boundaries
 843 -- Ugly!  Ask John how to improve it.
 844 argDemand Top       = lazyDmd
 845 argDemand (Defer d) = lazyDmd
 846 argDemand (Eval ds) = Eval (mapDmds argDemand ds)
 847 argDemand (Box Bot) = evalDmd
 848 argDemand (Box d)   = box (argDemand d)
 849 argDemand Bot       = Abs       -- Don't pass args that are consumed by bottom/err
 850 argDemand d         = d
 851 \end{code}
 852
 853 \begin{code}
 854 betterStrictness :: StrictSig -> StrictSig -> Bool
 855 betterStrictness (StrictSig t1) (StrictSig t2) = betterDmdType t1 t2
 856
 857 betterDmdType t1 t2 = (t1 `lubType` t2) == t2
 858
 859 betterDemand :: Demand -> Demand -> Bool
 860 -- If d1 `better` d2, and d2 `better` d2, then d1==d2
 861 betterDemand d1 d2 = (d1 `lub` d2) == d2
 862 \end{code}
 863
 864 \begin{code}
 865 -------------------------
 866 -- Consider (if x then y else []) with demand V
 867 -- Then the first branch gives {y->V} and the second
 868 -- *implicitly* has {y->A}.  So we must put {y->(V `lub` A)}
 869 -- in the result env.
 870 lubType (DmdType fv1 ds1 r1) (DmdType fv2 ds2 r2)
 871   = DmdType lub_fv2 (lub_ds ds1 ds2) (r1 `lubRes` r2)
 872   where
 873     lub_fv  = plusUFM_C lub fv1 fv2
 874     lub_fv1 = modifyEnv (not (isBotRes r1)) absLub fv2 fv1 lub_fv
 875     lub_fv2 = modifyEnv (not (isBotRes r2)) absLub fv1 fv2 lub_fv1
 876         -- lub is the identity for Bot
 877
 878         -- Extend the shorter argument list to match the longer
 879     lub_ds (d1:ds1) (d2:ds2) = lub d1 d2 : lub_ds ds1 ds2
 880     lub_ds []       []       = []
 881     lub_ds ds1      []       = map (`lub` resTypeArgDmd r2) ds1
 882     lub_ds []       ds2      = map (resTypeArgDmd r1 `lub`) ds2
 883
 884 -----------------------------------
 885 -- (t1 `bothType` t2) takes the argument/result info from t1,
 886 -- using t2 just for its free-var info
 887 -- NB: Don't forget about r2!  It might be BotRes, which is
 888 --     a bottom demand on all the in-scope variables.
 889 -- Peter: can this be done more neatly?
 890 bothType (DmdType fv1 ds1 r1) (DmdType fv2 ds2 r2)
 891   = DmdType both_fv2 ds1 (r1 `bothRes` r2)
 892   where
 893     both_fv  = plusUFM_C both fv1 fv2
 894     both_fv1 = modifyEnv (isBotRes r1) (`both` Bot) fv2 fv1 both_fv
 895     both_fv2 = modifyEnv (isBotRes r2) (`both` Bot) fv1 fv2 both_fv1
 896         -- both is the identity for Abs
 897 \end{code}
 898
 899
 900 \begin{code}
 901 lubRes BotRes r      = r
 902 lubRes r      BotRes = r
 903 lubRes RetCPR RetCPR = RetCPR
 904 lubRes r1     r2     = TopRes
 905
 906 -- If either diverges, the whole thing does
 907 -- Otherwise take CPR info from the first
 908 bothRes r1 BotRes = BotRes
 909 bothRes r1 r2     = r1
 910 \end{code}
 911
 912 \begin{code}
 913 modifyEnv :: Bool                       -- No-op if False
 914           -> (Demand -> Demand)         -- The zapper
 915           -> DmdEnv -> DmdEnv           -- Env1 and Env2
 916           -> DmdEnv -> DmdEnv           -- Transform this env
 917         -- Zap anything in Env1 but not in Env2
 918         -- Assume: dom(env) includes dom(Env1) and dom(Env2)
 919
 920 modifyEnv need_to_modify zapper env1 env2 env
 921   | need_to_modify = foldr zap env (keysUFM (env1 `minusUFM` env2))
 922   | otherwise      = env
 923   where
 924     zap uniq env = addToUFM_Directly env uniq (zapper current_val)
 925                  where
 926                    current_val = expectJust "modifyEnv" (lookupUFM_Directly env uniq)
 927 \end{code}
 928
 929
 930 %************************************************************************
 931 %*                                                                      *
 932 \subsection{LUB and BOTH}
 933 %*                                                                      *
 934 %************************************************************************
 935
 936 \begin{code}
 937 lub :: Demand -> Demand -> Demand
 938
 939 lub Bot         d2 = d2
 940 lub Abs         d2 = absLub d2
 941 lub Top         d2 = Top
 942 lub (Defer ds1) d2 = defer (Eval ds1 `lub` d2)
 943
 944 lub (Call d1)   (Call d2)    = Call (d1 `lub` d2)
 945 lub d1@(Call _) (Box d2)     = d1 `lub` d2      -- Just strip the box
 946 lub d1@(Call _) d2@(Eval _)  = d2               -- Presumably seq or vanilla eval
 947 lub d1@(Call _) d2           = d2 `lub` d1      -- Bot, Abs, Top
 948
 949 -- For the Eval case, we use these approximation rules
 950 -- Box Bot       <= Eval (Box Bot ...)
 951 -- Box Top       <= Defer (Box Bot ...)
 952 -- Box (Eval ds) <= Eval (map Box ds)
 953 lub (Eval ds1)  (Eval ds2)        = Eval (ds1 `lubs` ds2)
 954 lub (Eval ds1)  (Box Bot)         = Eval (mapDmds (`lub` Box Bot) ds1)
 955 lub (Eval ds1)  (Box (Eval ds2)) = Eval (ds1 `lubs` mapDmds box ds2)
 956 lub (Eval ds1)  (Box Abs)        = deferEval (mapDmds (`lub` Box Bot) ds1)
 957 lub d1@(Eval _) d2                = d2 `lub` d1 -- Bot,Abs,Top,Call,Defer
 958
 959 lub (Box d1)   (Box d2) = box (d1 `lub` d2)
 960 lub d1@(Box _)  d2      = d2 `lub` d1
 961
 962 lubs = zipWithDmds lub
 963
 964 ---------------------
 965 -- box is the smart constructor for Box
 966 -- It computes <B,bot> & d
 967 -- INVARIANT: (Box d) => d = Bot, Abs, Eval
 968 -- Seems to be no point in allowing (Box (Call d))
 969 box (Call d)  = Call d  -- The odd man out.  Why?
 970 box (Box d)   = Box d
 971 box (Defer _) = lazyDmd
 972 box Top       = lazyDmd -- Box Abs and Box Top
 973 box Abs       = lazyDmd -- are the same <B,L>
 974 box d         = Box d   -- Bot, Eval
 975
 976 ---------------
 977 defer :: Demand -> Demand
 978
 979 -- defer is the smart constructor for Defer
 980 -- The idea is that (Defer ds) = <U(ds), L>
 981 --
 982 -- It specifies what happens at a lazy function argument
 983 -- or a lambda; the L* operator
 984 -- Set the strictness part to L, but leave
 985 -- the boxity side unaffected
 986 -- It also ensures that Defer (Eval [LLLL]) = L
 987
 988 defer Bot        = Abs
 989 defer Abs        = Abs
 990 defer Top        = Top
 991 defer (Call _)   = lazyDmd      -- Approximation here?
 992 defer (Box _)    = lazyDmd
 993 defer (Defer ds) = Defer ds
 994 defer (Eval ds)  = deferEval ds
 995
 996 -- deferEval ds = defer (Eval ds)
 997 deferEval ds | allTop ds = Top
 998              | otherwise  = Defer ds
 999
1000 ---------------------
1001 absLub :: Demand -> Demand
1002 -- Computes (Abs `lub` d)
1003 -- For the Bot case consider
1004 --      f x y = if ... then x else error x
1005 --   Then for y we get Abs `lub` Bot, and we really
1006 --   want Abs overall
1007 absLub Bot        = Abs
1008 absLub Abs        = Abs
1009 absLub Top        = Top
1010 absLub (Call _)   = Top
1011 absLub (Box _)    = Top
1012 absLub (Eval ds)  = Defer (absLubs ds)  -- Or (Defer ds)?
1013 absLub (Defer ds) = Defer (absLubs ds)  -- Or (Defer ds)?
1014
1015 absLubs = mapDmds absLub
1016
1017 ---------------
1018 both :: Demand -> Demand -> Demand
1019
1020 both Abs d2 = d2
1021
1022 both Bot Bot       = Bot
1023 both Bot Abs       = Bot
1024 both Bot (Eval ds) = Eval (mapDmds (`both` Bot) ds)
1025         -- Consider
1026         --      f x = error x
1027         -- From 'error' itself we get demand Bot on x
1028         -- From the arg demand on x we get
1029         --      x :-> evalDmd = Box (Eval (Poly Abs))
1030         -- So we get  Bot `both` Box (Eval (Poly Abs))
1031         --          = Seq Keep (Poly Bot)
1032         --
1033         -- Consider also
1034         --      f x = if ... then error (fst x) else fst x
1035         -- Then we get (Eval (Box Bot, Bot) `lub` Eval (SA))
1036         --      = Eval (SA)
1037         -- which is what we want.
1038 both Bot d = errDmd
1039
1040 both Top Bot         = errDmd
1041 both Top Abs         = Top
1042 both Top Top         = Top
1043 both Top (Box d)    = Box d
1044 both Top (Call d)   = Call d
1045 both Top (Eval ds)  = Eval (mapDmds (`both` Top) ds)
1046 both Top (Defer ds)     -- = defer (Top `both` Eval ds)
1047                         -- = defer (Eval (mapDmds (`both` Top) ds))
1048                      = deferEval (mapDmds (`both` Top) ds)
1049
1050
1051 both (Box d1)   (Box d2)    = box (d1 `both` d2)
1052 both (Box d1)   d2@(Call _) = box (d1 `both` d2)
1053 both (Box d1)   d2@(Eval _) = box (d1 `both` d2)
1054 both (Box d1)   (Defer d2)  = Box d1
1055 both d1@(Box _) d2          = d2 `both` d1
1056
1057 both (Call d1)   (Call d2)   = Call (d1 `both` d2)
1058 both (Call d1)   (Eval ds2)  = Call d1  -- Could do better for (Poly Bot)?
1059 both (Call d1)   (Defer ds2) = Call d1  -- Ditto
1060 both d1@(Call _) d2          = d1 `both` d1
1061
1062 both (Eval ds1)    (Eval  ds2) = Eval (ds1 `boths` ds2)
1063 both (Eval ds1)    (Defer ds2) = Eval (ds1 `boths` mapDmds defer ds2)
1064 both d1@(Eval ds1) d2          = d2 `both` d1
1065
1066 both (Defer ds1) (Defer ds2) = deferEval (ds1 `boths` ds2)
1067 both d1@(Defer ds1) d2       = d2 `both` d1
1068
1069 boths = zipWithDmds both
1070 \end{code}
1071
1072
1073
1074 %************************************************************************
1075 %*                                                                      *
1076 \subsection{Miscellaneous
1077 %*                                                                      *
1078 %************************************************************************
1079
1080
1081 \begin{code}
1082 #ifdef OLD_STRICTNESS
1083 get_changes binds = vcat (map get_changes_bind binds)
1084
1085 get_changes_bind (Rec pairs) = vcat (map get_changes_pr pairs)
1086 get_changes_bind (NonRec id rhs) = get_changes_pr (id,rhs)
1087
1088 get_changes_pr (id,rhs)
1089   = get_changes_var id $$ get_changes_expr rhs
1090
1091 get_changes_var var
1092   | isId var  = get_changes_str var $$ get_changes_dmd var
1093   | otherwise = empty
1094
1095 get_changes_expr (Type t)     = empty
1096 get_changes_expr (Var v)      = empty
1097 get_changes_expr (Lit l)      = empty
1098 get_changes_expr (Note n e)   = get_changes_expr e
1099 get_changes_expr (App e1 e2)  = get_changes_expr e1 $$ get_changes_expr e2
1100 get_changes_expr (Lam b e)    = {- get_changes_var b $$ -} get_changes_expr e
1101 get_changes_expr (Let b e)    = get_changes_bind b $$ get_changes_expr e
1102 get_changes_expr (Case e b a) = get_changes_expr e $$ {- get_changes_var b $$ -} vcat (map get_changes_alt a)
1103
1104 get_changes_alt (con,bs,rhs) = {- vcat (map get_changes_var bs) $$ -} get_changes_expr rhs
1105
1106 get_changes_str id
1107   | new_better && old_better = empty
1108   | new_better               = message "BETTER"
1109   | old_better               = message "WORSE"
1110   | otherwise                = message "INCOMPARABLE"
1111   where
1112     message word = text word <+> text "strictness for" <+> ppr id <+> info
1113     info = (text "Old" <+> ppr old) $$ (text "New" <+> ppr new)
1114     new = squashSig (idNewStrictness id)        -- Don't report spurious diffs that the old
1115                                                 -- strictness analyser can't track
1116     old = newStrictnessFromOld (idName id) (idArity id) (idStrictness id) (idCprInfo id)
1117     old_better = old `betterStrictness` new
1118     new_better = new `betterStrictness` old
1119
1120 get_changes_dmd id
1121   | isUnLiftedType (idType id) = empty  -- Not useful
1122   | new_better && old_better = empty
1123   | new_better               = message "BETTER"
1124   | old_better               = message "WORSE"
1125   | otherwise                = message "INCOMPARABLE"
1126   where
1127     message word = text word <+> text "demand for" <+> ppr id <+> info
1128     info = (text "Old" <+> ppr old) $$ (text "New" <+> ppr new)
1129     new = squashDmd (argDemand (idNewDemandInfo id))    -- To avoid spurious improvements
1130                                                         -- A bit of a hack
1131     old = newDemand (idDemandInfo id)
1132     new_better = new `betterDemand` old
1133     old_better = old `betterDemand` new
1134 #endif
1135
1136 squashSig (StrictSig (DmdType fv ds res))
1137   = StrictSig (DmdType emptyDmdEnv (map squashDmd ds) res)
1138   where
1139         -- squash just gets rid of call demands
1140         -- which the old analyser doesn't track
1141 squashDmd (Call d)   = evalDmd
1142 squashDmd (Box d)    = Box (squashDmd d)
1143 squashDmd (Eval ds)  = Eval (mapDmds squashDmd ds)
1144 squashDmd (Defer ds) = Defer (mapDmds squashDmd ds)
1145 squashDmd d          = d
1146 \end{code}