ghc/compiler/stranal/DmdAnal.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4
   5                         -----------------
   6                         A demand analysis
   7                         -----------------
   8
   9 \begin{code}
  10 module DmdAnal ( dmdAnalPgm ) where
  11
  12 #include "HsVersions.h"
  13
  14 import CmdLineOpts      ( DynFlags, DynFlag(..), opt_MaxWorkerArgs )
  15 import NewDemand        -- All of it
  16 import CoreSyn
  17 import CoreUtils        ( exprIsValue, exprArity )
  18 import DataCon          ( dataConTyCon )
  19 import TyCon            ( isProductTyCon, isRecursiveTyCon )
  20 import Id               ( Id, idType, idInfo, idArity, idCprInfo, idDemandInfo,
  21                           modifyIdInfo, isDataConId, isImplicitId, isGlobalId,
  22                           idNewStrictness, idNewStrictness_maybe, getNewStrictness, setIdNewStrictness,
  23                           idNewDemandInfo, setIdNewDemandInfo, newStrictnessFromOld )
  24 import IdInfo           ( newDemand )
  25 import Var              ( Var )
  26 import VarEnv
  27 import UniqFM           ( plusUFM_C, addToUFM_Directly, lookupUFM_Directly,
  28                           keysUFM, minusUFM, ufmToList, filterUFM )
  29 import Type             ( isUnLiftedType )
  30 import CoreLint         ( showPass, endPass )
  31 import ErrUtils         ( dumpIfSet_dyn )
  32 import Util             ( mapAndUnzip, mapAccumL, mapAccumR, zipWithEqual )
  33 import BasicTypes       ( Arity, TopLevelFlag(..), isTopLevel )
  34 import Maybes           ( orElse, expectJust )
  35 import Outputable
  36 import FastTypes
  37 \end{code}
  38
  39 To think about
  40
  41 * set a noinline pragma on bottoming Ids
  42
  43 * Consider f x = x+1 `fatbar` error (show x)
  44   We'd like to unbox x, even if that means reboxing it in the error case.
  45
  46 \begin{code}
  47 instance Outputable TopLevelFlag where
  48   ppr flag = empty
  49 \end{code}
  50
  51 %************************************************************************
  52 %*                                                                      *
  53 \subsection{Top level stuff}
  54 %*                                                                      *
  55 %************************************************************************
  56
  57 \begin{code}
  58 dmdAnalPgm :: DynFlags -> [CoreBind] -> IO [CoreBind]
  59 dmdAnalPgm dflags binds
  60   = do {
  61         showPass dflags "Demand analysis" ;
  62         let { binds_plus_dmds = do_prog binds ;
  63               dmd_changes = get_changes binds_plus_dmds } ;
  64         endPass dflags "Demand analysis"
  65                 Opt_D_dump_stranal binds_plus_dmds ;
  66         printDump (text "Changes in demands" $$ dmd_changes) ;
  67         return binds_plus_dmds
  68     }
  69   where
  70     do_prog :: [CoreBind] -> [CoreBind]
  71     do_prog binds = snd $ mapAccumL dmdAnalTopBind emptySigEnv binds
  72
  73 dmdAnalTopBind :: SigEnv
  74                -> CoreBind
  75                -> (SigEnv, CoreBind)
  76 dmdAnalTopBind sigs (NonRec id rhs)
  77   | isImplicitId id             -- Don't touch the info on constructors, selectors etc
  78   = (sigs, NonRec id rhs)       -- It's pre-computed in MkId.lhs
  79   | otherwise
  80   = let
  81         (sigs', _, (id', rhs')) = downRhs TopLevel sigs (id, rhs)
  82     in
  83     (sigs', NonRec id' rhs')
  84
  85 dmdAnalTopBind sigs (Rec pairs)
  86   = let
  87         (sigs', _, pairs')  = dmdFix TopLevel sigs pairs
  88     in
  89     (sigs', Rec pairs')
  90 \end{code}
  91
  92
  93 %************************************************************************
  94 %*                                                                      *
  95 \subsection{The analyser itself}
  96 %*                                                                      *
  97 %************************************************************************
  98
  99 \begin{code}
 100 dmdAnal :: SigEnv -> Demand -> CoreExpr -> (DmdType, CoreExpr)
 101
 102 dmdAnal sigs Abs  e = (topDmdType, e)
 103
 104 dmdAnal sigs Lazy e = let
 105                         (res_ty, e') = dmdAnal sigs Eval e
 106                       in
 107                       (deferType res_ty, e')
 108         -- It's important not to analyse e with a lazy demand because
 109         -- a) When we encounter   case s of (a,b) ->
 110         --      we demand s with U(d1d2)... but if the overall demand is lazy
 111         --      that is wrong, and we'd need to reduce the demand on s,
 112         --      which is inconvenient
 113         -- b) More important, consider
 114         --      f (let x = R in x+x), where f is lazy
 115         --    We still want to mark x as demanded, because it will be when we
 116         --    enter the let.  If we analyse f's arg with a Lazy demand, we'll
 117         --    just mark x as Lazy
 118
 119
 120 dmdAnal sigs dmd (Lit lit)
 121   = (topDmdType, Lit lit)
 122
 123 dmdAnal sigs dmd (Var var)
 124   = (dmdTransform sigs var dmd, Var var)
 125
 126 dmdAnal sigs dmd (Note n e)
 127   = (dmd_ty, Note n e')
 128   where
 129     (dmd_ty, e') = dmdAnal sigs dmd e
 130
 131 dmdAnal sigs dmd (App fun (Type ty))
 132   = (fun_ty, App fun' (Type ty))
 133   where
 134     (fun_ty, fun') = dmdAnal sigs dmd fun
 135
 136 dmdAnal sigs dmd (App fun arg)  -- Non-type arguments
 137   = let                         -- [Type arg handled above]
 138         (fun_ty, fun')    = dmdAnal sigs (Call dmd) fun
 139         (arg_ty, arg')    = dmdAnal sigs arg_dmd arg
 140         (arg_dmd, res_ty) = splitDmdTy fun_ty
 141     in
 142     (res_ty `bothType` arg_ty, App fun' arg')
 143
 144 dmdAnal sigs dmd (Lam var body)
 145   | isTyVar var
 146   = let
 147         (body_ty, body') = dmdAnal sigs dmd body
 148     in
 149     (body_ty, Lam var body')
 150
 151   | Call body_dmd <- dmd        -- A call demand: good!
 152   = let
 153         (body_ty, body') = dmdAnal sigs body_dmd body
 154         (lam_ty, var')   = annotateLamIdBndr body_ty var
 155     in
 156     (lam_ty, Lam var' body')
 157
 158   | otherwise   -- Not enough demand on the lambda; but do the body
 159   = let         -- anyway to annotate it and gather free var info
 160         (body_ty, body') = dmdAnal sigs Eval body
 161         (lam_ty, var')   = annotateLamIdBndr body_ty var
 162     in
 163     (deferType lam_ty, Lam var' body')
 164
 165 dmdAnal sigs dmd (Case scrut case_bndr [alt@(DataAlt dc,bndrs,rhs)])
 166   | let tycon = dataConTyCon dc,
 167     isProductTyCon tycon,
 168     not (isRecursiveTyCon tycon)
 169   = let
 170         bndr_ids                = filter isId bndrs
 171         (alt_ty, alt')          = dmdAnalAlt sigs dmd alt
 172         (alt_ty1, case_bndr')   = annotateBndr alt_ty case_bndr
 173         (_, bndrs', _)          = alt'
 174         scrut_dmd               = Seq Drop Now [idNewDemandInfo b | b <- bndrs', isId b]
 175         (scrut_ty, scrut')      = dmdAnal sigs scrut_dmd scrut
 176     in
 177     (alt_ty1 `bothType` scrut_ty, Case scrut' case_bndr' [alt'])
 178
 179 dmdAnal sigs dmd (Case scrut case_bndr alts)
 180   = let
 181         (alt_tys, alts')        = mapAndUnzip (dmdAnalAlt sigs dmd) alts
 182         (scrut_ty, scrut')      = dmdAnal sigs Eval scrut
 183         (alt_ty, case_bndr')    = annotateBndr (foldr1 lubType alt_tys) case_bndr
 184     in
 185 --    pprTrace "dmdAnal:Case" (ppr alts $$ ppr alt_tys)
 186     (alt_ty `bothType` scrut_ty, Case scrut' case_bndr' alts')
 187
 188 dmdAnal sigs dmd (Let (NonRec id rhs) body)
 189   = let
 190         (sigs', lazy_fv, (id1, rhs')) = downRhs NotTopLevel sigs (id, rhs)
 191         (body_ty, body')              = dmdAnal sigs' dmd body
 192         (body_ty1, id2)               = annotateBndr body_ty id1
 193         body_ty2                      = addLazyFVs body_ty1 lazy_fv
 194     in
 195 --    pprTrace "dmdLet" (ppr id <+> ppr (sig,rhs_env))
 196     (body_ty2, Let (NonRec id2 rhs') body')
 197
 198 dmdAnal sigs dmd (Let (Rec pairs) body)
 199   = let
 200         bndrs                    = map fst pairs
 201         (sigs', lazy_fv, pairs') = dmdFix NotTopLevel sigs pairs
 202         (body_ty, body')         = dmdAnal sigs' dmd body
 203         body_ty1                 = addLazyFVs body_ty lazy_fv
 204     in
 205     sigs' `seq` body_ty `seq`
 206     let
 207         (body_ty2, _) = annotateBndrs body_ty1 bndrs
 208                 -- Don't bother to add demand info to recursive
 209                 -- binders as annotateBndr does;
 210                 -- being recursive, we can't treat them strictly.
 211                 -- But we do need to remove the binders from the result demand env
 212     in
 213     (body_ty2,  Let (Rec pairs') body')
 214
 215
 216 dmdAnalAlt sigs dmd (con,bndrs,rhs)
 217   = let
 218         (rhs_ty, rhs')   = dmdAnal sigs dmd rhs
 219         (alt_ty, bndrs') = annotateBndrs rhs_ty bndrs
 220     in
 221     (alt_ty, (con, bndrs', rhs'))
 222 \end{code}
 223
 224 %************************************************************************
 225 %*                                                                      *
 226 \subsection{Bindings}
 227 %*                                                                      *
 228 %************************************************************************
 229
 230 \begin{code}
 231 dmdFix :: TopLevelFlag
 232        -> SigEnv                -- Does not include bindings for this binding
 233        -> [(Id,CoreExpr)]
 234        -> (SigEnv, DmdEnv,
 235            [(Id,CoreExpr)])     -- Binders annotated with stricness info
 236
 237 dmdFix top_lvl sigs pairs
 238   = loop 1 initial_sigs pairs
 239   where
 240     bndrs        = map fst pairs
 241     initial_sigs = extendSigEnvList sigs [(id, (initial_sig id, top_lvl)) | id <- bndrs]
 242
 243     loop :: Int
 244          -> SigEnv                      -- Already contains the current sigs
 245          -> [(Id,CoreExpr)]
 246          -> (SigEnv, DmdEnv, [(Id,CoreExpr)])
 247     loop n sigs pairs
 248       | all (same_sig sigs sigs') bndrs = (sigs', lazy_fv, pairs')
 249                 -- Note: use pairs', not pairs.   pairs' is the result of
 250                 -- processing the RHSs with sigs (= sigs'), whereas pairs
 251                 -- is the result of processing the RHSs with the *previous*
 252                 -- iteration of sigs.
 253       | n >= 5              = pprTrace "dmdFix" (ppr n <+> ppr pairs)   (loop (n+1) sigs' pairs')
 254       | otherwise           = {- pprTrace "dmdFixLoop" (ppr id_sigs) -} (loop (n+1) sigs' pairs')
 255       where
 256                 -- Use the new signature to do the next pair
 257                 -- The occurrence analyser has arranged them in a good order
 258                 -- so this can significantly reduce the number of iterations needed
 259         ((sigs',lazy_fv), pairs') = mapAccumL (my_downRhs top_lvl) (sigs, emptyDmdEnv) pairs
 260
 261     my_downRhs top_lvl (sigs,lazy_fv) (id,rhs)
 262         = -- pprTrace "downRhs {" (ppr id <+> (ppr old_sig))
 263           -- (new_sig `seq`
 264           --    pprTrace "downRhsEnd" (ppr id <+> ppr new_sig <+> char '}' )
 265           ((sigs', lazy_fv'), pair')
 266           --     )
 267         where
 268           (sigs', lazy_fv1, pair') = downRhs top_lvl sigs (id,rhs)
 269           lazy_fv'                 = plusUFM_C both lazy_fv lazy_fv1
 270           old_sig                  = lookup sigs id
 271           new_sig                  = lookup sigs' id
 272
 273         -- Get an initial strictness signature from the Id
 274         -- itself.  That way we make use of earlier iterations
 275         -- of the fixpoint algorithm.  (Cunning plan.)
 276         -- Note that the cunning plan extends to the DmdEnv too,
 277         -- since it is part of the strictness signature
 278     initial_sig id = idNewStrictness_maybe id `orElse` botSig
 279
 280     same_sig sigs sigs' var = lookup sigs var == lookup sigs' var
 281     lookup sigs var = case lookupVarEnv sigs var of
 282                         Just (sig,_) -> sig
 283
 284 downRhs :: TopLevelFlag
 285         -> SigEnv -> (Id, CoreExpr)
 286         -> (SigEnv,  DmdEnv, (Id, CoreExpr))
 287 -- Process the RHS of the binding, add the strictness signature
 288 -- to the Id, and augment the environment with the signature as well.
 289
 290 downRhs top_lvl sigs (id, rhs)
 291  = (sigs', lazy_fv, (id', rhs'))
 292  where
 293   arity             = exprArity rhs   -- The idArity may not be up to date
 294   (rhs_ty, rhs')    = dmdAnal sigs (vanillaCall arity) rhs
 295   (lazy_fv, sig_ty) = mkSigTy id arity rhs rhs_ty
 296   id'               = id `setIdNewStrictness` sig_ty
 297   sigs'             = extendSigEnv top_lvl sigs id sig_ty
 298 \end{code}
 299
 300 %************************************************************************
 301 %*                                                                      *
 302 \subsection{Strictness signatures and types}
 303 %*                                                                      *
 304 %************************************************************************
 305
 306 \begin{code}
 307 mkSigTy :: Id -> Arity -> CoreExpr -> DmdType -> (DmdEnv, StrictSig)
 308 -- Take a DmdType and turn it into a StrictSig
 309 mkSigTy id arity rhs (DmdType fv dmds res)
 310   = (lazy_fv, mkStrictSig id arity dmd_ty)
 311   where
 312     dmd_ty = DmdType strict_fv lazified_dmds res'
 313
 314     lazy_fv   = filterUFM (not . isStrictDmd) fv
 315     strict_fv = filterUFM isStrictDmd         fv
 316         -- We put the strict FVs in the DmdType of the Id, so
 317         -- that at its call sites we unleash demands on its strict fvs.
 318         -- An example is 'roll' in imaginary/wheel-sieve2
 319         -- Something like this:
 320         --      roll x = letrec
 321         --                   go y = if ... then roll (x-1) else x+1
 322         --               in
 323         --               go ms
 324         -- We want to see that roll is strict in x, which is because
 325         -- go is called.   So we put the DmdEnv for x in go's DmdType.
 326         --
 327         -- Another example:
 328         --      f :: Int -> Int -> Int
 329         --      f x y = let t = x+1
 330         --          h z = if z==0 then t else
 331         --                if z==1 then x+1 else
 332         --                x + h (z-1)
 333         --      in
 334         --      h y
 335         -- Calling h does indeed evaluate x, but we can only see
 336         -- that if we unleash a demand on x at the call site for t.
 337         --
 338         -- Incidentally, here's a place where lambda-lifting h would
 339         -- lose the cigar --- we couldn't see the joint strictness in t/x
 340         --
 341         --      ON THE OTHER HAND
 342         -- We don't want to put *all* the fv's from the RHS into the
 343         -- DmdType, because that makes fixpointing very slow --- the
 344         -- DmdType gets full of lazy demands that are slow to converge.
 345
 346     lazified_dmds = map lazify dmds
 347         -- Get rid of defers in the arguments
 348     final_dmds = setUnpackStrategy lazified_dmds
 349         -- Set the unpacking strategy
 350
 351     res' = case (dmds, res) of
 352                 ([], RetCPR) | not (exprIsValue rhs) -> TopRes
 353                 other                                -> res
 354         -- If the rhs is a thunk, we forget the CPR info, because
 355         -- it is presumably shared (else it would have been inlined, and
 356         -- so we'd lose sharing if w/w'd it into a function.
 357         --
 358         --      DONE IN OLD CPR ANALYSER, BUT NOT YET HERE
 359         -- Also, if the strictness analyser has figured out that it's strict,
 360         -- the let-to-case transformation will happen, so again it's good.
 361         -- (CPR analysis runs before the simplifier has had a chance to do
 362         --  the let-to-case transform.)
 363         -- This made a big difference to PrelBase.modInt, which had something like
 364         --      modInt = \ x -> let r = ... -> I# v in
 365         --                      ...body strict in r...
 366         -- r's RHS isn't a value yet; but modInt returns r in various branches, so
 367         -- if r doesn't have the CPR property then neither does modInt
 368 \end{code}
 369
 370 The unpack strategy determines whether we'll *really* unpack the argument,
 371 or whether we'll just remember its strictness.  If unpacking would give
 372 rise to a *lot* of worker args, we may decide not to unpack after all.
 373
 374 \begin{code}
 375 setUnpackStrategy :: [Demand] -> [Demand]
 376 setUnpackStrategy ds
 377   = snd (go (opt_MaxWorkerArgs - nonAbsentArgs ds) ds)
 378   where
 379     go :: Int                   -- Max number of args available for sub-components of [Demand]
 380        -> [Demand]
 381        -> (Int, [Demand])       -- Args remaining after subcomponents of [Demand] are unpacked
 382
 383     go n (Seq keep _ cs : ds)
 384         | n' >= 0    = Seq keep Now cs' `cons` go n'' ds
 385         | otherwise  = Eval `cons` go n ds
 386         where
 387           (n'',cs') = go n' cs
 388           n' = n + box - non_abs_args
 389           box = case keep of
 390                    Keep -> 0
 391                    Drop -> 1    -- Add one to the budget if we drop the top-level arg
 392           non_abs_args = nonAbsentArgs cs
 393                 -- Delete # of non-absent args to which we'll now be committed
 394
 395     go n (d:ds) = d `cons` go n ds
 396     go n []     = (n,[])
 397
 398     cons d (n,ds) = (n, d:ds)
 399
 400 nonAbsentArgs :: [Demand] -> Int
 401 nonAbsentArgs []         = 0
 402 nonAbsentArgs (Abs : ds) = nonAbsentArgs ds
 403 nonAbsentArgs (d   : ds) = 1 + nonAbsentArgs ds
 404 \end{code}
 405
 406
 407 %************************************************************************
 408 %*                                                                      *
 409 \subsection{Strictness signatures and types}
 410 %*                                                                      *
 411 %************************************************************************
 412
 413 \begin{code}
 414 splitDmdTy :: DmdType -> (Demand, DmdType)
 415 -- Split off one function argument
 416 splitDmdTy (DmdType fv (dmd:dmds) res_ty) = (dmd, DmdType fv dmds res_ty)
 417 splitDmdTy ty@(DmdType fv [] TopRes)         = (topDmd, ty)
 418 splitDmdTy ty@(DmdType fv [] BotRes)         = (Abs,    ty)
 419         -- We already have a suitable demand on all
 420         -- free vars, so no need to add more!
 421 splitDmdTy (DmdType fv [] RetCPR)         = panic "splitDmdTy"
 422 \end{code}
 423
 424 \begin{code}
 425 unitVarDmd var dmd = DmdType (unitVarEnv var dmd) [] TopRes
 426
 427 addVarDmd top_lvl dmd_ty@(DmdType fv ds res) var dmd
 428   | isTopLevel top_lvl = dmd_ty         -- Don't record top level things
 429   | otherwise          = DmdType (extendVarEnv fv var dmd) ds res
 430
 431 addLazyFVs (DmdType fv ds res) lazy_fvs
 432   = DmdType (plusUFM_C both fv lazy_fvs) ds res
 433
 434 annotateBndr :: DmdType -> Var -> (DmdType, Var)
 435 -- The returned env has the var deleted
 436 -- The returned var is annotated with demand info
 437 -- No effect on the argument demands
 438 annotateBndr dmd_ty@(DmdType fv ds res) var
 439   | isTyVar var = (dmd_ty, var)
 440   | otherwise   = (DmdType fv' ds res, setIdNewDemandInfo var dmd)
 441   where
 442     (fv', dmd) = removeFV fv var res
 443
 444 annotateBndrs = mapAccumR annotateBndr
 445
 446 annotateLamIdBndr dmd_ty@(DmdType fv ds res) id
 447 -- For lambdas we add the demand to the argument demands
 448 -- Only called for Ids
 449   = ASSERT( isId id )
 450     (DmdType fv' (dmd:ds) res, setIdNewDemandInfo id dmd)
 451   where
 452     (fv', dmd) = removeFV fv id res
 453
 454 removeFV fv var res = (fv', dmd)
 455                 where
 456                   fv' = fv `delVarEnv` var
 457                   dmd = lookupVarEnv fv var `orElse` deflt
 458                   deflt | isBotRes res = Bot
 459                         | otherwise    = Abs
 460 \end{code}
 461
 462 %************************************************************************
 463 %*                                                                      *
 464 \subsection{Strictness signatures}
 465 %*                                                                      *
 466 %************************************************************************
 467
 468 \begin{code}
 469 type SigEnv  = VarEnv (StrictSig, TopLevelFlag)
 470         -- We use the SigEnv to tell us whether to
 471         -- record info about a variable in the DmdEnv
 472         -- We do so if it's a LocalId, but not top-level
 473         --
 474         -- The DmdEnv gives the demand on the free vars of the function
 475         -- when it is given enough args to satisfy the strictness signature
 476
 477 emptySigEnv  = emptyVarEnv
 478
 479 extendSigEnv :: TopLevelFlag -> SigEnv -> Id -> StrictSig -> SigEnv
 480 extendSigEnv top_lvl env var sig = extendVarEnv env var (sig, top_lvl)
 481
 482 extendSigEnvList = extendVarEnvList
 483
 484 dmdTransform :: SigEnv          -- The strictness environment
 485              -> Id              -- The function
 486              -> Demand          -- The demand on the function
 487              -> DmdType         -- The demand type of the function in this context
 488         -- Returned DmdEnv includes the demand on
 489         -- this function plus demand on its free variables
 490
 491 dmdTransform sigs var dmd
 492
 493 ------  DATA CONSTRUCTOR
 494   | isDataConId var,            -- Data constructor
 495     Seq k Now ds <- res_dmd,    -- and the demand looks inside its fields
 496     let StrictSig dmd_ty = idNewStrictness var  -- It must have a strictness sig
 497   = if dmdTypeDepth dmd_ty == length ds then    -- Saturated, so unleash the demand
 498         -- ds can be empty, when we are just seq'ing the thing
 499         mkDmdType emptyDmdEnv ds (dmdTypeRes dmd_ty)
 500                 -- Need to extract whether it's a product, hence dmdTypeRes
 501     else
 502         topDmdType
 503
 504 ------  IMPORTED FUNCTION
 505   | isGlobalId var,             -- Imported function
 506     let StrictSig dmd_ty = getNewStrictness var
 507   = if dmdTypeDepth dmd_ty <= call_depth then   -- Saturated, so unleash the demand
 508         dmd_ty
 509     else
 510         topDmdType
 511
 512 ------  LOCAL LET/REC BOUND THING
 513   | Just (StrictSig dmd_ty, top_lvl) <- lookupVarEnv sigs var
 514   = let
 515         fn_ty | dmdTypeDepth dmd_ty <= call_depth = dmd_ty
 516               | otherwise                         = deferType dmd_ty
 517         -- NB: it's important to use deferType, and not just return topDmdType
 518         -- Consider     let { f x y = p + x } in f 1
 519         -- The application isn't saturated, but we must nevertheless propagate
 520         --      a lazy demand for p!
 521     in
 522     addVarDmd top_lvl fn_ty var dmd
 523
 524 ------  LOCAL NON-LET/REC BOUND THING
 525   | otherwise                   -- Default case
 526   = unitVarDmd var dmd
 527
 528   where
 529     (call_depth, res_dmd) = splitCallDmd dmd
 530 \end{code}
 531
 532
 533 %************************************************************************
 534 %*                                                                      *
 535 \subsection{Demands}
 536 %*                                                                      *
 537 %************************************************************************
 538
 539 \begin{code}
 540 splitCallDmd :: Demand -> (Int, Demand)
 541 splitCallDmd (Call d) = case splitCallDmd d of
 542                           (n, r) -> (n+1, r)
 543 splitCallDmd d        = (0, d)
 544
 545 vanillaCall :: Arity -> Demand
 546 vanillaCall 0 = Eval
 547 vanillaCall n = Call (vanillaCall (n-1))
 548
 549 deferType :: DmdType -> DmdType
 550 deferType (DmdType fv _ _) = DmdType (mapVarEnv defer fv) [] TopRes
 551         -- Notice that we throw away info about both arguments and results
 552         -- For example,   f = let ... in \x -> x
 553         -- We don't want to get a stricness type V->T for f.
 554
 555 defer :: Demand -> Demand
 556 -- c.f. `lub` Abs
 557 defer Abs          = Abs
 558 defer (Seq k _ ds) = Seq k Defer ds
 559 defer other        = Lazy
 560
 561 lazify :: Demand -> Demand
 562 -- The 'Defer' demands are just Lazy at function boundaries
 563 lazify (Seq k Defer ds) = Lazy
 564 lazify (Seq k Now   ds) = Seq k Now (map lazify ds)
 565 lazify Bot              = Abs   -- Don't pass args that are consumed by bottom
 566 lazify d                = d
 567 \end{code}
 568
 569 \begin{code}
 570 betterStrictness :: StrictSig -> StrictSig -> Bool
 571 betterStrictness (StrictSig t1) (StrictSig t2) = betterDmdType t1 t2
 572
 573 betterDmdType t1 t2 = (t1 `lubType` t2) == t2
 574
 575 betterDemand :: Demand -> Demand -> Bool
 576 -- If d1 `better` d2, and d2 `better` d2, then d1==d2
 577 betterDemand d1 d2 = (d1 `lub` d2) == d2
 578
 579 squashDmdEnv (StrictSig (DmdType fv ds res)) = StrictSig (DmdType emptyDmdEnv ds res)
 580 \end{code}
 581
 582
 583 %************************************************************************
 584 %*                                                                      *
 585 \subsection{LUB and BOTH}
 586 %*                                                                      *
 587 %************************************************************************
 588
 589 \begin{code}
 590 lub :: Demand -> Demand -> Demand
 591
 592 lub Bot  d = d
 593
 594 lub Lazy d = Lazy
 595
 596 lub Err Bot = Err
 597 lub Err d   = d
 598
 599 lub Abs Bot          = Abs
 600 lub Abs Err          = Abs
 601 lub Abs Abs          = Abs
 602 lub Abs (Seq k _ ds) = Seq k Defer ds   -- Very important ('radicals' example)
 603 lub Abs d            = Lazy
 604
 605 lub Eval Abs            = Lazy
 606 lub Eval Lazy           = Lazy
 607 lub Eval (Seq k Now ds) = Seq Keep Now ds
 608 lub Eval d              = Eval
 609
 610 lub (Call d1) (Call d2) = Call (lub d1 d2)
 611
 612 lub (Seq k1 l1 ds1) (Seq k2 l2 ds2) = Seq (k1 `vee` k2) (l1 `or_defer` l2)
 613                                           (zipWithEqual "lub" lub ds1 ds2)
 614
 615 -- The last clauses deal with the remaining cases for Call and Seq
 616 lub d1@(Call _) d2@(Seq _ _ _) = pprPanic "lub" (ppr d1 $$ ppr d2)
 617 lub d1 d2                      = lub d2 d1
 618
 619 or_defer Now Now = Now
 620 or_defer _   _   = Defer
 621
 622 -------------------------
 623 -- Consider (if x then y else []) with demand V
 624 -- Then the first branch gives {y->V} and the second
 625 -- *implicitly* has {y->A}.  So we must put {y->(V `lub` A)}
 626 -- in the result env.
 627 lubType (DmdType fv1 ds1 r1) (DmdType fv2 ds2 r2)
 628   = DmdType lub_fv2 (zipWith lub ds1 ds2) (r1 `lubRes` r2)
 629   where
 630     lub_fv  = plusUFM_C lub fv1 fv2
 631     lub_fv1 = modifyEnv (not (isBotRes r1)) (Abs `lub`) fv2 fv1 lub_fv
 632     lub_fv2 = modifyEnv (not (isBotRes r2)) (Abs `lub`) fv1 fv2 lub_fv1
 633         -- lub is the identity for Bot
 634
 635 -------------------------
 636 lubRes BotRes r      = r
 637 lubRes r      BotRes = r
 638 lubRes RetCPR RetCPR = RetCPR
 639 lubRes r1     r2     = TopRes
 640
 641 -----------------------------------
 642 vee :: Keepity -> Keepity -> Keepity
 643 vee Drop Drop = Drop
 644 vee k1   k2   = Keep
 645
 646 -----------------------------------
 647 both :: Demand -> Demand -> Demand
 648
 649 -- The normal one
 650 -- both Bot d = Bot
 651
 652 -- The experimental one
 653 both Bot Bot = Bot
 654 both Bot Abs = Bot
 655 both Bot d   = d
 656
 657
 658 both Abs Bot = Bot
 659 both Abs d   = d
 660
 661 both Err Bot = Bot
 662 both Err Abs = Err
 663 both Err d   = d
 664
 665 both Lazy Bot            = Bot
 666 both Lazy Abs            = Lazy
 667 both Lazy Err            = Lazy
 668 both Lazy (Seq k Now ds) = Seq Keep Now ds
 669 both Lazy d              = d
 670
 671 -- Part of the Bot like Err experiment
 672 -- both Eval Bot               = Bot
 673 both Eval (Seq k l ds) = Seq Keep Now ds
 674 both Eval (Call d)     = Call d
 675 both Eval d            = Eval
 676
 677 both (Seq k1 Defer ds1) (Seq k2 Defer ds2) = Seq (k1 `vee` k2) Defer
 678                                                  (zipWithEqual "both" both ds1 ds2)
 679 both (Seq k1 l1 ds1) (Seq k2 l2 ds2) = Seq (k1 `vee` k2) Now
 680                                            (zipWithEqual "both" both ds1' ds2')
 681                                      where
 682                                         ds1' = case l1 of { Now -> ds1; Defer -> map defer ds1 }
 683                                         ds2' = case l2 of { Now -> ds2; Defer -> map defer ds2 }
 684
 685 both (Call d1) (Call d2) = Call (d1 `both` d2)
 686
 687 -- The last clauses deal with the remaining cases for Call and Seq
 688 both d1@(Call _) d2@(Seq _ _ _) = pprPanic "both" (ppr d1 $$ ppr d2)
 689 both d1 d2                      = both d2 d1
 690
 691 -----------------------------------
 692 bothRes :: DmdResult -> DmdResult -> DmdResult
 693 -- Left-biased for CPR info
 694 bothRes BotRes _ = BotRes
 695 bothRes _ BotRes = BotRes
 696 bothRes r1 _     = r1
 697
 698 -----------------------------------
 699 -- (t1 `bothType` t2) takes the argument/result info from t1,
 700 -- using t2 just for its free-var info
 701 bothType (DmdType fv1 ds1 r1) (DmdType fv2 ds2 r2)
 702   = DmdType both_fv2 ds1 r1
 703   where
 704     both_fv  = plusUFM_C both fv1 fv2
 705     both_fv1 = modifyEnv (isBotRes r1) (`both` Bot) fv2 fv1 both_fv
 706     both_fv2 = modifyEnv (isBotRes r2) (`both` Bot) fv1 fv2 both_fv1
 707         -- both is the identity for Abs
 708 \end{code}
 709
 710 \begin{code}
 711 modifyEnv :: Bool                       -- No-op if False
 712           -> (Demand -> Demand)         -- The zapper
 713           -> DmdEnv -> DmdEnv           -- Env1 and Env2
 714           -> DmdEnv -> DmdEnv           -- Transform this env
 715         -- Zap anything in Env1 but not in Env2
 716         -- Assume: dom(env) includes dom(Env1) and dom(Env2)
 717
 718 modifyEnv need_to_modify zapper env1 env2 env
 719   | need_to_modify = foldr zap env (keysUFM (env1 `minusUFM` env2))
 720   | otherwise      = env
 721   where
 722     zap uniq env = addToUFM_Directly env uniq (zapper current_val)
 723                  where
 724                    current_val = expectJust "modifyEnv" (lookupUFM_Directly env uniq)
 725 \end{code}
 726
 727
 728 %************************************************************************
 729 %*                                                                      *
 730 \subsection{Miscellaneous
 731 %*                                                                      *
 732 %************************************************************************
 733
 734
 735 \begin{code}
 736 get_changes binds = vcat (map get_changes_bind binds)
 737
 738 get_changes_bind (Rec pairs) = vcat (map get_changes_pr pairs)
 739 get_changes_bind (NonRec id rhs) = get_changes_pr (id,rhs)
 740
 741 get_changes_pr (id,rhs)
 742   | isImplicitId id = empty  -- We don't look inside these
 743   | otherwise       = get_changes_var id $$ get_changes_expr rhs
 744
 745 get_changes_var var
 746   | isId var  = get_changes_str var $$ get_changes_dmd var
 747   | otherwise = empty
 748
 749 get_changes_expr (Type t)     = empty
 750 get_changes_expr (Var v)      = empty
 751 get_changes_expr (Lit l)      = empty
 752 get_changes_expr (Note n e)   = get_changes_expr e
 753 get_changes_expr (App e1 e2)  = get_changes_expr e1 $$ get_changes_expr e2
 754 get_changes_expr (Lam b e)    = {- get_changes_var b $$ -} get_changes_expr e
 755 get_changes_expr (Let b e)    = get_changes_bind b $$ get_changes_expr e
 756 get_changes_expr (Case e b a) = get_changes_expr e $$ get_changes_var b $$ vcat (map get_changes_alt a)
 757
 758 get_changes_alt (con,bs,rhs) = {- vcat (map get_changes_var bs) $$ -} get_changes_expr rhs
 759
 760 get_changes_str id
 761   | new_better && old_better = empty
 762   | new_better               = message "BETTER"
 763   | old_better               = message "WORSE"
 764   | otherwise                = message "INCOMPARABLE"
 765   where
 766     message word = text word <+> text "strictness for" <+> ppr id <+> info
 767     info = (text "Old" <+> ppr old) $$ (text "New" <+> ppr new)
 768     new = squashDmdEnv (idNewStrictness id)     -- Don't report diffs in the env
 769     old = newStrictnessFromOld id
 770     old_better = old `betterStrictness` new
 771     new_better = new `betterStrictness` old
 772
 773 get_changes_dmd id
 774   | isUnLiftedType (idType id) = empty  -- Not useful
 775   | new_better && old_better = empty
 776   | new_better               = message "BETTER"
 777   | old_better               = message "WORSE"
 778   | otherwise                = message "INCOMPARABLE"
 779   where
 780     message word = text word <+> text "demand for" <+> ppr id <+> info
 781     info = (text "Old" <+> ppr old) $$ (text "New" <+> ppr new)
 782     new = lazify (idNewDemandInfo id)   -- Lazify to avoid spurious improvements
 783     old = newDemand (idDemandInfo id)
 784     new_better = new `betterDemand` old
 785     old_better = old `betterDemand` new
 786 \end{code}