ghc/compiler/stranal/SaAbsInt.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[SaAbsInt]{Abstract interpreter for strictness analysis}
   5
   6 \begin{code}
   7 #ifndef DEBUG
   8 -- If DEBUG is off, omit all exports
   9 module SaAbsInt () where
  10
  11 #else
  12 module SaAbsInt (
  13         findStrictness,
  14         findDemand, findDemandAlts,
  15         absEval,
  16         widen,
  17         fixpoint,
  18         isBot
  19     ) where
  20 #endif /* DEBUG */
  21 #include "HsVersions.h"
  22
  23 import CmdLineOpts      ( opt_AllStrict, opt_NumbersStrict )
  24 import CoreSyn
  25 import CoreUnfold       ( maybeUnfoldingTemplate )
  26 import Id               ( Id, idType, idStrictness, idUnfolding, isDataConId_maybe )
  27 import DataCon          ( dataConTyCon, splitProductType_maybe, dataConRepArgTys )
  28 import IdInfo           ( StrictnessInfo(..) )
  29 import Demand           ( Demand(..), wwPrim, wwStrict, wwUnpack, wwLazy,
  30                           mkStrictnessInfo, isLazy
  31                         )
  32 import SaLib
  33 import TyCon            ( isProductTyCon, isRecursiveTyCon )
  34 import Type             ( splitTyConApp_maybe,
  35                           isUnLiftedType, Type )
  36 import TyCon            ( tyConUnique )
  37 import PrelInfo         ( numericTyKeys )
  38 import Util             ( isIn, nOfThem, zipWithEqual )
  39 import Outputable
  40 \end{code}
  41
  42 %************************************************************************
  43 %*                                                                      *
  44 \subsection[AbsVal-ops]{Operations on @AbsVals@}
  45 %*                                                                      *
  46 %************************************************************************
  47
  48 Least upper bound, greatest lower bound.
  49
  50 \begin{code}
  51 lub, glb :: AbsVal -> AbsVal -> AbsVal
  52
  53 lub AbsBot val2   = val2
  54 lub val1   AbsBot = val1
  55
  56 lub (AbsProd xs) (AbsProd ys) = AbsProd (zipWithEqual "lub" lub xs ys)
  57
  58 lub _             _           = AbsTop  -- Crude, but conservative
  59                                         -- The crudity only shows up if there
  60                                         -- are functions involved
  61
  62 -- Slightly funny glb; for absence analysis only;
  63 -- AbsBot is the safe answer.
  64 --
  65 -- Using anyBot rather than just testing for AbsBot is important.
  66 -- Consider:
  67 --
  68 --   f = \a b -> ...
  69 --
  70 --   g = \x y z -> case x of
  71 --                   []     -> f x
  72 --                   (p:ps) -> f p
  73 --
  74 -- Now, the abstract value of the branches of the case will be an
  75 -- AbsFun, but when testing for z's absence we want to spot that it's
  76 -- an AbsFun which can't possibly return AbsBot.  So when glb'ing we
  77 -- mustn't be too keen to bale out and return AbsBot; the anyBot test
  78 -- spots that (f x) can't possibly return AbsBot.
  79
  80 -- We have also tripped over the following interesting case:
  81 --      case x of
  82 --        []     -> \y -> 1
  83 --        (p:ps) -> f
  84 --
  85 -- Now, suppose f is bound to AbsTop.  Does this expression mention z?
  86 -- Obviously not.  But the case will take the glb of AbsTop (for f) and
  87 -- an AbsFun (for \y->1). We should not bale out and give AbsBot, because
  88 -- that would say that it *does* mention z (or anything else for that matter).
  89 -- Nor can we always return AbsTop, because the AbsFun might be something
  90 -- like (\y->z), which obviously does mention z. The point is that we're
  91 -- glbing two functions, and AbsTop is not actually the top of the function
  92 -- lattice.  It is more like (\xyz -> x|y|z); that is, AbsTop returns
  93 -- poison iff any of its arguments do.
  94
  95 -- Deal with functions specially, because AbsTop isn't the
  96 -- top of their domain.
  97
  98 glb v1 v2
  99   | is_fun v1 || is_fun v2
 100   = if not (anyBot v1) && not (anyBot v2)
 101     then
 102         AbsTop
 103     else
 104         AbsBot
 105   where
 106     is_fun (AbsFun _ _)       = True
 107     is_fun (AbsApproxFun _ _) = True    -- Not used, but the glb works ok
 108     is_fun other              = False
 109
 110 -- The non-functional cases are quite straightforward
 111
 112 glb (AbsProd xs) (AbsProd ys) = AbsProd (zipWithEqual "glb" glb xs ys)
 113
 114 glb AbsTop       v2           = v2
 115 glb v1           AbsTop       = v1
 116
 117 glb _            _            = AbsBot          -- Be pessimistic
 118 \end{code}
 119
 120 @isBot@ returns True if its argument is (a representation of) bottom.  The
 121 ``representation'' part is because we need to detect the bottom {\em function}
 122 too.  To detect the bottom function, bind its args to top, and see if it
 123 returns bottom.
 124
 125 Used only in strictness analysis:
 126 \begin{code}
 127 isBot :: AbsVal -> Bool
 128
 129 isBot AbsBot = True
 130 isBot other  = False    -- Functions aren't bottom any more
 131 \end{code}
 132
 133 Used only in absence analysis:
 134
 135 \begin{code}
 136 anyBot :: AbsVal -> Bool
 137
 138 anyBot AbsBot                  = True   -- poisoned!
 139 anyBot AbsTop                  = False
 140 anyBot (AbsProd vals)          = any anyBot vals
 141 anyBot (AbsFun bndr_ty abs_fn) = anyBot (abs_fn AbsTop)
 142 anyBot (AbsApproxFun _ val)    = anyBot val
 143 \end{code}
 144
 145 @widen@ takes an @AbsVal@, $val$, and returns and @AbsVal@ which is
 146 approximated by $val$.  Furthermore, the result has no @AbsFun@s in
 147 it, so it can be compared for equality by @sameVal@.
 148
 149 \begin{code}
 150 widen :: AnalysisKind -> AbsVal -> AbsVal
 151
 152 -- Widening is complicated by the fact that funtions are lifted
 153 widen StrAnal the_fn@(AbsFun bndr_ty _)
 154   = case widened_body of
 155         AbsApproxFun ds val -> AbsApproxFun (d : ds) val
 156                             where
 157                                d = findRecDemand str_fn abs_fn bndr_ty
 158                                str_fn val = isBot (foldl (absApply StrAnal) the_fn
 159                                                          (val : [AbsTop | d <- ds]))
 160
 161         other               -> AbsApproxFun [d] widened_body
 162                             where
 163                                d = findRecDemand str_fn abs_fn bndr_ty
 164                                str_fn val = isBot (absApply StrAnal the_fn val)
 165   where
 166     widened_body = widen StrAnal (absApply StrAnal the_fn AbsTop)
 167     abs_fn val   = False        -- Always says poison; so it looks as if
 168                                 -- nothing is absent; safe
 169
 170 {-      OLD comment...
 171         This stuff is now instead handled neatly by the fact that AbsApproxFun
 172         contains an AbsVal inside it.   SLPJ Jan 97
 173
 174   | isBot abs_body = AbsBot
 175     -- It's worth checking for a function which is unconditionally
 176     -- bottom.  Consider
 177     --
 178     --  f x y = let g y = case x of ...
 179     --          in (g ..) + (g ..)
 180     --
 181     -- Here, when we are considering strictness of f in x, we'll
 182     -- evaluate the body of f with x bound to bottom.  The current
 183     -- strategy is to bind g to its *widened* value; without the isBot
 184     -- (...) test above, we'd bind g to an AbsApproxFun, and deliver
 185     -- Top, not Bot as the value of f's rhs.  The test spots the
 186     -- unconditional bottom-ness of g when x is bottom.  (Another
 187     -- alternative here would be to bind g to its exact abstract
 188     -- value, but that entails lots of potential re-computation, at
 189     -- every application of g.)
 190 -}
 191
 192 widen StrAnal (AbsProd vals) = AbsProd (map (widen StrAnal) vals)
 193 widen StrAnal other_val      = other_val
 194
 195
 196 widen AbsAnal the_fn@(AbsFun bndr_ty _)
 197   | anyBot widened_body = AbsBot
 198         -- In the absence-analysis case it's *essential* to check
 199         -- that the function has no poison in its body.  If it does,
 200         -- anywhere, then the whole function is poisonous.
 201
 202   | otherwise
 203   = case widened_body of
 204         AbsApproxFun ds val -> AbsApproxFun (d : ds) val
 205                             where
 206                                d = findRecDemand str_fn abs_fn bndr_ty
 207                                abs_fn val = not (anyBot (foldl (absApply AbsAnal) the_fn
 208                                                                 (val : [AbsTop | d <- ds])))
 209
 210         other               -> AbsApproxFun [d] widened_body
 211                             where
 212                                d = findRecDemand str_fn abs_fn bndr_ty
 213                                abs_fn val = not (anyBot (absApply AbsAnal the_fn val))
 214   where
 215     widened_body = widen AbsAnal (absApply AbsAnal the_fn AbsTop)
 216     str_fn val   = True         -- Always says non-termination;
 217                                 -- that'll make findRecDemand peer into the
 218                                 -- structure of the value.
 219
 220 widen AbsAnal (AbsProd vals) = AbsProd (map (widen AbsAnal) vals)
 221
 222         -- It's desirable to do a good job of widening for product
 223         -- values.  Consider
 224         --
 225         --      let p = (x,y)
 226         --      in ...(case p of (x,y) -> x)...
 227         --
 228         -- Now, is y absent in this expression?  Currently the
 229         -- analyser widens p before looking at p's scope, to avoid
 230         -- lots of recomputation in the case where p is a function.
 231         -- So if widening doesn't have a case for products, we'll
 232         -- widen p to AbsBot (since when searching for absence in y we
 233         -- bind y to poison ie AbsBot), and now we are lost.
 234
 235 widen AbsAnal other_val = other_val
 236
 237 -- WAS:   if anyBot val then AbsBot else AbsTop
 238 -- Nowadays widen is doing a better job on functions for absence analysis.
 239 \end{code}
 240
 241 @crudeAbsWiden@ is used just for absence analysis, and always
 242 returns AbsTop or AbsBot, so it widens to a two-point domain
 243
 244 \begin{code}
 245 crudeAbsWiden :: AbsVal -> AbsVal
 246 crudeAbsWiden val = if anyBot val then AbsBot else AbsTop
 247 \end{code}
 248
 249 @sameVal@ compares two abstract values for equality.  It can't deal with
 250 @AbsFun@, but that should have been removed earlier in the day by @widen@.
 251
 252 \begin{code}
 253 sameVal :: AbsVal -> AbsVal -> Bool     -- Can't handle AbsFun!
 254
 255 #ifdef DEBUG
 256 sameVal (AbsFun _ _) _ = panic "sameVal: AbsFun: arg1"
 257 sameVal _ (AbsFun _ _) = panic "sameVal: AbsFun: arg2"
 258 #endif
 259
 260 sameVal AbsBot AbsBot = True
 261 sameVal AbsBot other  = False   -- widen has reduced AbsFun bots to AbsBot
 262
 263 sameVal AbsTop AbsTop = True
 264 sameVal AbsTop other  = False           -- Right?
 265
 266 sameVal (AbsProd vals1) (AbsProd vals2) = and (zipWithEqual "sameVal" sameVal vals1 vals2)
 267 sameVal (AbsProd _)     AbsTop          = False
 268 sameVal (AbsProd _)     AbsBot          = False
 269
 270 sameVal (AbsApproxFun str1 v1) (AbsApproxFun str2 v2) = str1 == str2 && sameVal v1 v2
 271 sameVal (AbsApproxFun _ _)     AbsTop                 = False
 272 sameVal (AbsApproxFun _ _)     AbsBot                 = False
 273
 274 sameVal val1 val2 = panic "sameVal: type mismatch or AbsFun encountered"
 275 \end{code}
 276
 277
 278 @evalStrictness@ compares a @Demand@ with an abstract value, returning
 279 @True@ iff the abstract value is {\em less defined} than the demand.
 280 (@True@ is the exciting answer; @False@ is always safe.)
 281
 282 \begin{code}
 283 evalStrictness :: Demand
 284                -> AbsVal
 285                -> Bool          -- True iff the value is sure
 286                                 -- to be less defined than the Demand
 287
 288 evalStrictness (WwLazy _) _   = False
 289 evalStrictness WwStrict   val = isBot val
 290 evalStrictness WwEnum     val = isBot val
 291
 292 evalStrictness (WwUnpack _ demand_info) val
 293   = case val of
 294       AbsTop       -> False
 295       AbsBot       -> True
 296       AbsProd vals -> or (zipWithEqual "evalStrictness" evalStrictness demand_info vals)
 297       _            -> pprTrace "evalStrictness?" empty False
 298
 299 evalStrictness WwPrim val
 300   = case val of
 301       AbsTop -> False
 302       AbsBot -> True    -- Can happen: consider f (g x), where g is a
 303                         -- recursive function returning an Int# that diverges
 304
 305       other  -> pprPanic "evalStrictness: WwPrim:" (ppr other)
 306 \end{code}
 307
 308 For absence analysis, we're interested in whether "poison" in the
 309 argument (ie a bottom therein) can propagate to the result of the
 310 function call; that is, whether the specified demand can {\em
 311 possibly} hit poison.
 312
 313 \begin{code}
 314 evalAbsence (WwLazy True) _ = False     -- Can't possibly hit poison
 315                                         -- with Absent demand
 316
 317 evalAbsence (WwUnpack _ demand_info) val
 318   = case val of
 319         AbsTop       -> False           -- No poison in here
 320         AbsBot       -> True            -- Pure poison
 321         AbsProd vals -> or (zipWithEqual "evalAbsence" evalAbsence demand_info vals)
 322         _            -> panic "evalAbsence: other"
 323
 324 evalAbsence other val = anyBot val
 325   -- The demand is conservative; even "Lazy" *might* evaluate the
 326   -- argument arbitrarily so we have to look everywhere for poison
 327 \end{code}
 328
 329 %************************************************************************
 330 %*                                                                      *
 331 \subsection[absEval]{Evaluate an expression in the abstract domain}
 332 %*                                                                      *
 333 %************************************************************************
 334
 335 \begin{code}
 336 -- The isBottomingId stuf is now dealt with via the Id's strictness info
 337 -- absId anal var env | isBottomingId var
 338 --   = case anal of
 339 --      StrAnal -> AbsBot       -- See discussion below
 340 --      AbsAnal -> AbsTop       -- Just want to see if there's any poison in
 341                                 -- error's arg
 342
 343 absId anal var env
 344   = case (lookupAbsValEnv env var,
 345           isDataConId_maybe var,
 346           idStrictness var,
 347           maybeUnfoldingTemplate (idUnfolding var)) of
 348
 349         (Just abs_val, _, _, _) ->
 350                         abs_val -- Bound in the environment
 351
 352         (_, Just data_con, _, _) | isProductTyCon tycon &&
 353                                    not (isRecursiveTyCon tycon)
 354                 ->      -- A product.  We get infinite loops if we don't
 355                         -- check for recursive products!
 356                         -- The strictness info on the constructor
 357                         -- isn't expressive enough to contain its abstract value
 358                    productAbsVal (dataConRepArgTys data_con) []
 359                 where
 360                    tycon = dataConTyCon data_con
 361
 362         (_, _, NoStrictnessInfo, Just unfolding) ->
 363                         -- We have an unfolding for the expr
 364                         -- Assume the unfolding has no free variables since it
 365                         -- came from inside the Id
 366                         absEval anal unfolding env
 367                 -- Notice here that we only look in the unfolding if we don't
 368                 -- have strictness info (an unusual situation).
 369                 -- We could have chosen to look in the unfolding if it exists,
 370                 -- and only try the strictness info if it doesn't, and that would
 371                 -- give more accurate results, at the cost of re-abstract-interpreting
 372                 -- the unfolding every time.
 373                 -- We found only one place where the look-at-unfolding-first
 374                 -- method gave better results, which is in the definition of
 375                 -- showInt in the Prelude.  In its defintion, fromIntegral is
 376                 -- not inlined (it's big) but ab-interp-ing its unfolding gave
 377                 -- a better result than looking at its strictness only.
 378                 --  showInt :: Integral a => a -> [Char] -> [Char]
 379                 -- !       {-# GHC_PRAGMA _A_ 1 _U_ 122 _S_
 380                 --         "U(U(U(U(SA)AAAAAAAAL)AA)AAAAASAAASA)" {...} _N_ _N_ #-}
 381                 -- --- 42,44 ----
 382                 --   showInt :: Integral a => a -> [Char] -> [Char]
 383                 -- !       {-# GHC_PRAGMA _A_ 1 _U_ 122 _S_
 384                 --        "U(U(U(U(SL)LLLLLLLLL)LL)LLLLLSLLLLL)" _N_ _N_ #-}
 385
 386
 387         (_, _, strictness_info, _) ->
 388                         -- Includes NoUnfolding
 389                         -- Try the strictness info
 390                         absValFromStrictness anal strictness_info
 391
 392 productAbsVal []                 rev_abs_args = AbsProd (reverse rev_abs_args)
 393 productAbsVal (arg_ty : arg_tys) rev_abs_args = AbsFun arg_ty (\ abs_arg -> productAbsVal arg_tys (abs_arg : rev_abs_args))
 394 \end{code}
 395
 396 \begin{code}
 397 absEval :: AnalysisKind -> CoreExpr -> AbsValEnv -> AbsVal
 398
 399 absEval anal (Type ty) env = AbsTop
 400 absEval anal (Var var) env = absId anal var env
 401 \end{code}
 402
 403 Discussion about error (following/quoting Lennart): Any expression
 404 'error e' is regarded as bottom (with HBC, with the -ffail-strict
 405 flag, on with -O).
 406
 407 Regarding it as bottom gives much better strictness properties for
 408 some functions.  E.g.
 409
 410         f [x] y = x+y
 411         f (x:xs) y = f xs (x+y)
 412 i.e.
 413         f [] _ = error "no match"
 414         f [x] y = x+y
 415         f (x:xs) y = f xs (x+y)
 416
 417 is strict in y, which you really want.  But, it may lead to
 418 transformations that turn a call to \tr{error} into non-termination.
 419 (The odds of this happening aren't good.)
 420
 421 Things are a little different for absence analysis, because we want
 422 to make sure that any poison (?????)
 423
 424 \begin{code}
 425 absEval anal (Lit _) env = AbsTop
 426         -- Literals terminate (strictness) and are not poison (absence)
 427 \end{code}
 428
 429 \begin{code}
 430 absEval anal (Lam bndr body) env
 431   | isTyVar bndr = absEval anal body env        -- Type lambda
 432   | otherwise    = AbsFun (idType bndr) abs_fn  -- Value lambda
 433   where
 434     abs_fn arg = absEval anal body (addOneToAbsValEnv env bndr arg)
 435
 436 absEval anal (App expr (Type ty)) env
 437   = absEval anal expr env                       -- Type appplication
 438 absEval anal (App f val_arg) env
 439   = absApply anal (absEval anal f env)          -- Value applicationn
 440                   (absEval anal val_arg env)
 441 \end{code}
 442
 443 \begin{code}
 444 absEval anal expr@(Case scrut case_bndr alts) env
 445   = let
 446         scrut_val  = absEval anal scrut env
 447         alts_env   = addOneToAbsValEnv env case_bndr scrut_val
 448     in
 449     case (scrut_val, alts) of
 450         (AbsBot, _) -> AbsBot
 451
 452         (AbsProd arg_vals, [(con, bndrs, rhs)])
 453                 | con /= DEFAULT ->
 454                 -- The scrutinee is a product value, so it must be of a single-constr
 455                 -- type; so the constructor in this alternative must be the right one
 456                 -- so we can go ahead and bind the constructor args to the components
 457                 -- of the product value.
 458             ASSERT(length arg_vals == length val_bndrs)
 459             absEval anal rhs rhs_env
 460           where
 461             val_bndrs = filter isId bndrs
 462             rhs_env   = growAbsValEnvList alts_env (val_bndrs `zip` arg_vals)
 463
 464         other -> absEvalAlts anal alts alts_env
 465 \end{code}
 466
 467 For @Lets@ we widen the value we get.  This is nothing to
 468 do with fixpointing.  The reason is so that we don't get an explosion
 469 in the amount of computation.  For example, consider:
 470 \begin{verbatim}
 471       let
 472         g a = case a of
 473                 q1 -> ...
 474                 q2 -> ...
 475         f x = case x of
 476                 p1 -> ...g r...
 477                 p2 -> ...g s...
 478       in
 479         f e
 480 \end{verbatim}
 481 If we bind @f@ and @g@ to their exact abstract value, then we'll
 482 ``execute'' one call to @f@ and {\em two} calls to @g@.  This can blow
 483 up exponentially.  Widening cuts it off by making a fixed
 484 approximation to @f@ and @g@, so that the bodies of @f@ and @g@ are
 485 not evaluated again at all when they are called.
 486
 487 Of course, this can lose useful joint strictness, which is sad.  An
 488 alternative approach would be to try with a certain amount of ``fuel''
 489 and be prepared to bale out.
 490
 491 \begin{code}
 492 absEval anal (Let (NonRec binder e1) e2) env
 493   = let
 494         new_env = addOneToAbsValEnv env binder (widen anal (absEval anal e1 env))
 495     in
 496         -- The binder of a NonRec should *not* be of unboxed type,
 497         -- hence no need to strictly evaluate the Rhs.
 498     absEval anal e2 new_env
 499
 500 absEval anal (Let (Rec pairs) body) env
 501   = let
 502         (binders,rhss) = unzip pairs
 503         rhs_vals = cheapFixpoint anal binders rhss env  -- Returns widened values
 504         new_env  = growAbsValEnvList env (binders `zip` rhs_vals)
 505     in
 506     absEval anal body new_env
 507
 508 absEval anal (Note note expr) env = absEval anal expr env
 509 \end{code}
 510
 511 \begin{code}
 512 absEvalAlts :: AnalysisKind -> [CoreAlt] -> AbsValEnv -> AbsVal
 513 absEvalAlts anal alts env
 514   = combine anal (map go alts)
 515   where
 516     combine StrAnal = foldr1 lub        -- Diverge only if all diverge
 517     combine AbsAnal = foldr1 glb        -- Find any poison
 518
 519     go (con, bndrs, rhs)
 520       = absEval anal rhs rhs_env
 521       where
 522         rhs_env = growAbsValEnvList env (filter isId bndrs `zip` repeat AbsTop)
 523 \end{code}
 524
 525 %************************************************************************
 526 %*                                                                      *
 527 \subsection[absApply]{Apply an abstract function to an abstract argument}
 528 %*                                                                      *
 529 %************************************************************************
 530
 531 Easy ones first:
 532
 533 \begin{code}
 534 absApply :: AnalysisKind -> AbsVal -> AbsVal -> AbsVal
 535
 536 absApply anal AbsBot arg = AbsBot
 537   -- AbsBot represents the abstract bottom *function* too
 538
 539 absApply StrAnal AbsTop arg = AbsTop
 540 absApply AbsAnal AbsTop arg = if anyBot arg
 541                               then AbsBot
 542                               else AbsTop
 543         -- To be conservative, we have to assume that a function about
 544         -- which we know nothing (AbsTop) might look at some part of
 545         -- its argument
 546 \end{code}
 547
 548 An @AbsFun@ with only one more argument needed---bind it and eval the
 549 result.  A @Lam@ with two or more args: return another @AbsFun@ with
 550 an augmented environment.
 551
 552 \begin{code}
 553 absApply anal (AbsFun bndr_ty abs_fn) arg = abs_fn arg
 554 \end{code}
 555
 556 \begin{code}
 557 absApply StrAnal (AbsApproxFun (d:ds) val) arg
 558   = case ds of
 559         []    -> val'
 560         other -> AbsApproxFun ds val'   -- Result is non-bot if there are still args
 561   where
 562     val' | evalStrictness d arg = AbsBot
 563          | otherwise            = val
 564
 565 absApply AbsAnal (AbsApproxFun (d:ds) val) arg
 566   = if evalAbsence d arg
 567     then AbsBot         -- Poison in arg means poison in the application
 568     else case ds of
 569                 []    -> val
 570                 other -> AbsApproxFun ds val
 571
 572 #ifdef DEBUG
 573 absApply anal f@(AbsProd _) arg
 574   = pprPanic ("absApply: Duff function: AbsProd." ++ show anal) ((ppr f) <+> (ppr arg))
 575 #endif
 576 \end{code}
 577
 578
 579
 580
 581 %************************************************************************
 582 %*                                                                      *
 583 \subsection[findStrictness]{Determine some binders' strictness}
 584 %*                                                                      *
 585 %************************************************************************
 586
 587 \begin{code}
 588 findStrictness :: Id
 589                -> AbsVal                -- Abstract strictness value of function
 590                -> AbsVal                -- Abstract absence value of function
 591                -> StrictnessInfo        -- Resulting strictness annotation
 592
 593 findStrictness id (AbsApproxFun str_ds str_res) (AbsApproxFun abs_ds _)
 594         -- You might think there's really no point in describing detailed
 595         -- strictness for a divergent function;
 596         -- If it's fully applied we get bottom regardless of the
 597         -- argument.  If it's not fully applied we don't get bottom.
 598         -- Finally, we don't want to regard the args of a divergent function
 599         -- as 'interesting' for inlining purposes (see Simplify.prepareArgs)
 600         --
 601         -- HOWEVER, if we make diverging functions appear lazy, they
 602         -- don't get wrappers, and then we get dreadful reboxing.
 603         -- See notes with WwLib.worthSplitting
 604   = find_strictness id str_ds str_res abs_ds
 605
 606 findStrictness id str_val abs_val
 607   | isBot str_val = mkStrictnessInfo ([], True)
 608   | otherwise     = NoStrictnessInfo
 609
 610 -- The list of absence demands passed to combineDemands
 611 -- can be shorter than the list of absence demands
 612 --
 613 --      lookup = \ dEq -> letrec {
 614 --                           lookup = \ key ds -> ...lookup...
 615 --                        }
 616 --                        in lookup
 617 -- Here the strictness value takes three args, but the absence value
 618 -- takes only one, for reasons I don't quite understand (see cheapFixpoint)
 619
 620 find_strictness id orig_str_ds orig_str_res orig_abs_ds
 621   = mkStrictnessInfo (go orig_str_ds orig_abs_ds, res_bot)
 622   where
 623     res_bot = isBot orig_str_res
 624
 625     go str_ds abs_ds = zipWith mk_dmd str_ds (abs_ds ++ repeat wwLazy)
 626
 627     mk_dmd str_dmd (WwLazy True)
 628          = WARN( not (res_bot || isLazy str_dmd),
 629                  ppr id <+> ppr orig_str_ds <+> ppr orig_abs_ds )
 630                 -- If the arg isn't used we jolly well don't expect the function
 631                 -- to be strict in it.  Unless the function diverges.
 632            WwLazy True  -- Best of all
 633
 634     mk_dmd (WwUnpack u str_ds)
 635            (WwUnpack _ abs_ds) = WwUnpack u (go str_ds abs_ds)
 636
 637     mk_dmd str_dmd abs_dmd = str_dmd
 638 \end{code}
 639
 640
 641 \begin{code}
 642 findDemand dmd str_env abs_env expr binder
 643   = findRecDemand str_fn abs_fn (idType binder)
 644   where
 645     str_fn val = evalStrictness   dmd (absEval StrAnal expr (addOneToAbsValEnv str_env binder val))
 646     abs_fn val = not (evalAbsence dmd (absEval AbsAnal expr (addOneToAbsValEnv abs_env binder val)))
 647
 648 findDemandAlts dmd str_env abs_env alts binder
 649   = findRecDemand str_fn abs_fn (idType binder)
 650   where
 651     str_fn val = evalStrictness   dmd (absEvalAlts StrAnal alts (addOneToAbsValEnv str_env binder val))
 652     abs_fn val = not (evalAbsence dmd (absEvalAlts AbsAnal alts (addOneToAbsValEnv abs_env binder val)))
 653 \end{code}
 654
 655 @findRecDemand@ is where we finally convert strictness/absence info
 656 into ``Demands'' which we can pin on Ids (etc.).
 657
 658 NOTE: What do we do if something is {\em both} strict and absent?
 659 Should \tr{f x y z = error "foo"} says that \tr{f}'s arguments are all
 660 strict (because of bottoming effect of \tr{error}) or all absent
 661 (because they're not used)?
 662
 663 Well, for practical reasons, we prefer absence over strictness.  In
 664 particular, it makes the ``default defaults'' for class methods (the
 665 ones that say \tr{defm.foo dict = error "I don't exist"}) come out
 666 nicely [saying ``the dict isn't used''], rather than saying it is
 667 strict in every component of the dictionary [massive gratuitious
 668 casing to take the dict apart].
 669
 670 But you could have examples where going for strictness would be better
 671 than absence.  Consider:
 672 \begin{verbatim}
 673         let x = something big
 674         in
 675         f x y z + g x
 676 \end{verbatim}
 677
 678 If \tr{x} is marked absent in \tr{f}, but not strict, and \tr{g} is
 679 lazy, then the thunk for \tr{x} will be built.  If \tr{f} was strict,
 680 then we'd let-to-case it:
 681 \begin{verbatim}
 682         case something big of
 683           x -> f x y z + g x
 684 \end{verbatim}
 685 Ho hum.
 686
 687 \begin{code}
 688 findRecDemand :: (AbsVal -> Bool)       -- True => function applied to this value yields Bot
 689               -> (AbsVal -> Bool)       -- True => function applied to this value yields no poison
 690               -> Type       -- The type of the argument
 691               -> Demand
 692
 693 findRecDemand str_fn abs_fn ty
 694   = if isUnLiftedType ty then -- It's a primitive type!
 695        wwPrim
 696
 697     else if abs_fn AbsBot then -- It's absent
 698        -- We prefer absence over strictness: see NOTE above.
 699        WwLazy True
 700
 701     else if not (opt_AllStrict ||
 702                  (opt_NumbersStrict && is_numeric_type ty) ||
 703                  str_fn AbsBot) then
 704         WwLazy False -- It's not strict and we're not pretending
 705
 706     else -- It's strict (or we're pretending it is)!
 707
 708        case splitProductType_maybe ty of
 709
 710          Nothing -> wwStrict    -- Could have a test for wwEnum, but
 711                                 -- we don't exploit it yet, so don't bother
 712
 713          Just (tycon,_,data_con,cmpnt_tys)      -- Single constructor case
 714            | isRecursiveTyCon tycon             -- Recursive data type; don't unpack
 715            ->   wwStrict                        --      (this applies to newtypes too:
 716                                                 --      e.g.  data Void = MkVoid Void)
 717
 718            |  null compt_strict_infos           -- A nullary data type
 719            ->   wwStrict
 720
 721            | otherwise                          -- Some other data type
 722            ->   wwUnpack compt_strict_infos
 723
 724            where
 725               prod_len = length cmpnt_tys
 726               compt_strict_infos
 727                 = [ findRecDemand
 728                          (\ cmpnt_val ->
 729                                str_fn (mkMainlyTopProd prod_len i cmpnt_val)
 730                          )
 731                          (\ cmpnt_val ->
 732                                abs_fn (mkMainlyTopProd prod_len i cmpnt_val)
 733                          )
 734                      cmpnt_ty
 735                   | (cmpnt_ty, i) <- cmpnt_tys `zip` [1..] ]
 736
 737   where
 738     is_numeric_type ty
 739       = case (splitTyConApp_maybe ty) of -- NB: duplicates stuff done above
 740           Nothing         -> False
 741           Just (tycon, _) -> tyConUnique tycon `is_elem` numericTyKeys
 742       where
 743         is_elem = isIn "is_numeric_type"
 744
 745     -- mkMainlyTopProd: make an AbsProd that is all AbsTops ("n"-1 of
 746     -- them) except for a given value in the "i"th position.
 747
 748     mkMainlyTopProd :: Int -> Int -> AbsVal -> AbsVal
 749
 750     mkMainlyTopProd n i val
 751       = let
 752             befores = nOfThem (i-1) AbsTop
 753             afters  = nOfThem (n-i) AbsTop
 754         in
 755         AbsProd (befores ++ (val : afters))
 756 \end{code}
 757
 758 %************************************************************************
 759 %*                                                                      *
 760 \subsection[fixpoint]{Fixpointer for the strictness analyser}
 761 %*                                                                      *
 762 %************************************************************************
 763
 764 The @fixpoint@ functions take a list of \tr{(binder, expr)} pairs, an
 765 environment, and returns the abstract value of each binder.
 766
 767 The @cheapFixpoint@ function makes a conservative approximation,
 768 by binding each of the variables to Top in their own right hand sides.
 769 That allows us to make rapid progress, at the cost of a less-than-wonderful
 770 approximation.
 771
 772 \begin{code}
 773 cheapFixpoint :: AnalysisKind -> [Id] -> [CoreExpr] -> AbsValEnv -> [AbsVal]
 774
 775 cheapFixpoint AbsAnal [id] [rhs] env
 776   = [crudeAbsWiden (absEval AbsAnal rhs new_env)]
 777   where
 778     new_env = addOneToAbsValEnv env id AbsTop   -- Unsafe starting point!
 779                     -- In the just-one-binding case, we guarantee to
 780                     -- find a fixed point in just one iteration,
 781                     -- because we are using only a two-point domain.
 782                     -- This improves matters in cases like:
 783                     --
 784                     --  f x y = letrec g = ...g...
 785                     --          in g x
 786                     --
 787                     -- Here, y isn't used at all, but if g is bound to
 788                     -- AbsBot we simply get AbsBot as the next
 789                     -- iteration too.
 790
 791 cheapFixpoint anal ids rhss env
 792   = [widen anal (absEval anal rhs new_env) | rhs <- rhss]
 793                 -- We do just one iteration, starting from a safe
 794                 -- approximation.  This won't do a good job in situations
 795                 -- like:
 796                 --      \x -> letrec f = ...g...
 797                 --                   g = ...f...x...
 798                 --            in
 799                 --            ...f...
 800                 -- Here, f will end up bound to Top after one iteration,
 801                 -- and hence we won't spot the strictness in x.
 802                 -- (A second iteration would solve this.  ToDo: try the effect of
 803                 --  really searching for a fixed point.)
 804   where
 805     new_env = growAbsValEnvList env [(id,safe_val) | id <- ids]
 806
 807     safe_val
 808       = case anal of    -- The safe starting point
 809           StrAnal -> AbsTop
 810           AbsAnal -> AbsBot
 811 \end{code}
 812
 813 \begin{code}
 814 fixpoint :: AnalysisKind -> [Id] -> [CoreExpr] -> AbsValEnv -> [AbsVal]
 815
 816 fixpoint anal [] _ env = []
 817
 818 fixpoint anal ids rhss env
 819   = fix_loop initial_vals
 820   where
 821     initial_val id
 822       = case anal of    -- The (unsafe) starting point
 823           AbsAnal -> AbsTop
 824           StrAnal -> AbsBot
 825                 -- At one stage for StrAnal we said:
 826                 --   if (returnsRealWorld (idType id))
 827                 --   then AbsTop -- this is a massively horrible hack (SLPJ 95/05)
 828                 -- but no one has the foggiest idea what this hack did,
 829                 -- and returnsRealWorld was a stub that always returned False
 830                 -- So this comment is all that is left of the hack!
 831
 832     initial_vals = [ initial_val id | id <- ids ]
 833
 834     fix_loop :: [AbsVal] -> [AbsVal]
 835
 836     fix_loop current_widened_vals
 837       = let
 838             new_env  = growAbsValEnvList env (ids `zip` current_widened_vals)
 839             new_vals = [ absEval anal rhs new_env | rhs <- rhss ]
 840             new_widened_vals = map (widen anal) new_vals
 841         in
 842         if (and (zipWith sameVal current_widened_vals new_widened_vals)) then
 843             current_widened_vals
 844
 845             -- NB: I was too chicken to make that a zipWithEqual,
 846             -- lest I jump into a black hole.  WDP 96/02
 847
 848             -- Return the widened values.  We might get a slightly
 849             -- better value by returning new_vals (which we used to
 850             -- do, see below), but alas that means that whenever the
 851             -- function is called we have to re-execute it, which is
 852             -- expensive.
 853
 854             -- OLD VERSION
 855             -- new_vals
 856             -- Return the un-widened values which may be a bit better
 857             -- than the widened ones, and are guaranteed safe, since
 858             -- they are one iteration beyond current_widened_vals,
 859             -- which itself is a fixed point.
 860         else
 861             fix_loop new_widened_vals
 862 \end{code}
 863
 864 For absence analysis, we make do with a very very simple approach:
 865 look for convergence in a two-point domain.
 866
 867 We used to use just one iteration, starting with the variables bound
 868 to @AbsBot@, which is safe.
 869
 870 Prior to that, we used one iteration starting from @AbsTop@ (which
 871 isn't safe).  Why isn't @AbsTop@ safe?  Consider:
 872 \begin{verbatim}
 873         letrec
 874           x = ...p..d...
 875           d = (x,y)
 876         in
 877         ...
 878 \end{verbatim}
 879 Here, if p is @AbsBot@, then we'd better {\em not} end up with a ``fixed
 880 point'' of @d@ being @(AbsTop, AbsTop)@!  An @AbsBot@ initial value is
 881 safe because it gives poison more often than really necessary, and
 882 thus may miss some absence, but will never claim absence when it ain't
 883 so.
 884
 885 Anyway, one iteration starting with everything bound to @AbsBot@ give
 886 bad results for
 887
 888         f = \ x -> ...f...
 889
 890 Here, f would always end up bound to @AbsBot@, which ain't very
 891 clever, because then it would introduce poison whenever it was
 892 applied.  Much better to start with f bound to @AbsTop@, and widen it
 893 to @AbsBot@ if any poison shows up. In effect we look for convergence
 894 in the two-point @AbsTop@/@AbsBot@ domain.
 895
 896 What we miss (compared with the cleverer strictness analysis) is
 897 spotting that in this case
 898
 899         f = \ x y -> ...y...(f x y')...
 900
 901 \tr{x} is actually absent, since it is only passed round the loop, never
 902 used.  But who cares about missing that?
 903
 904 NB: despite only having a two-point domain, we may still have many
 905 iterations, because there are several variables involved at once.