ghc/compiler/stranal/WorkWrap.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[WorkWrap]{Worker/wrapper-generating back-end of strictness analyser}
   5
   6 \begin{code}
   7 module WorkWrap ( wwTopBinds, mkWrapper ) where
   8
   9 #include "HsVersions.h"
  10
  11 import CoreSyn
  12 import CoreUnfold       ( certainlyWillInline )
  13 import CoreLint         ( showPass, endPass )
  14 import CoreUtils        ( exprType, exprIsValue )
  15 import Id               ( Id, idType, isOneShotLambda,
  16                           setIdNewStrictness, mkWorkerId,
  17                           setIdWorkerInfo, setInlinePragma,
  18                           idInfo )
  19 import Type             ( Type )
  20 import IdInfo           ( WorkerInfo(..), arityInfo,
  21                           newDemandInfo, newStrictnessInfo, unfoldingInfo, inlinePragInfo
  22                         )
  23 import NewDemand        ( Demand(..), StrictSig(..), DmdType(..), DmdResult(..),
  24                           Demands(..), mkTopDmdType, isBotRes, returnsCPR, topSig, isAbsent
  25                         )
  26 import UniqSupply       ( UniqSupply, initUs_, returnUs, thenUs, mapUs, getUniqueUs, UniqSM )
  27 import BasicTypes       ( RecFlag(..), isNonRec, Activation(..) )
  28 import VarEnv           ( isEmptyVarEnv )
  29 import Maybes           ( orElse )
  30 import CmdLineOpts
  31 import WwLib
  32 import Util             ( lengthIs )
  33 import Outputable
  34 \end{code}
  35
  36 We take Core bindings whose binders have:
  37
  38 \begin{enumerate}
  39
  40 \item Strictness attached (by the front-end of the strictness
  41 analyser), and / or
  42
  43 \item Constructed Product Result information attached by the CPR
  44 analysis pass.
  45
  46 \end{enumerate}
  47
  48 and we return some ``plain'' bindings which have been
  49 worker/wrapper-ified, meaning:
  50
  51 \begin{enumerate}
  52
  53 \item Functions have been split into workers and wrappers where
  54 appropriate.  If a function has both strictness and CPR properties
  55 then only one worker/wrapper doing both transformations is produced;
  56
  57 \item Binders' @IdInfos@ have been updated to reflect the existence of
  58 these workers/wrappers (this is where we get STRICTNESS and CPR pragma
  59 info for exported values).
  60 \end{enumerate}
  61
  62 \begin{code}
  63
  64 wwTopBinds :: DynFlags
  65            -> UniqSupply
  66            -> [CoreBind]
  67            -> IO [CoreBind]
  68
  69 wwTopBinds dflags us binds
  70   = do {
  71         showPass dflags "Worker Wrapper binds";
  72
  73         -- Create worker/wrappers, and mark binders with their
  74         -- "strictness info" [which encodes their worker/wrapper-ness]
  75         let { binds' = workersAndWrappers us binds };
  76
  77         endPass dflags "Worker Wrapper binds"
  78                 Opt_D_dump_worker_wrapper binds'
  79     }
  80 \end{code}
  81
  82
  83 \begin{code}
  84 workersAndWrappers :: UniqSupply -> [CoreBind] -> [CoreBind]
  85
  86 workersAndWrappers us top_binds
  87   = initUs_ us $
  88     mapUs wwBind top_binds `thenUs` \ top_binds' ->
  89     returnUs (concat top_binds')
  90 \end{code}
  91
  92 %************************************************************************
  93 %*                                                                      *
  94 \subsection[wwBind-wwExpr]{@wwBind@ and @wwExpr@}
  95 %*                                                                      *
  96 %************************************************************************
  97
  98 @wwBind@ works on a binding, trying each \tr{(binder, expr)} pair in
  99 turn.  Non-recursive case first, then recursive...
 100
 101 \begin{code}
 102 wwBind  :: CoreBind
 103         -> UniqSM [CoreBind]    -- returns a WwBinding intermediate form;
 104                                 -- the caller will convert to Expr/Binding,
 105                                 -- as appropriate.
 106
 107 wwBind (NonRec binder rhs)
 108   = wwExpr rhs                          `thenUs` \ new_rhs ->
 109     tryWW NonRecursive binder new_rhs   `thenUs` \ new_pairs ->
 110     returnUs [NonRec b e | (b,e) <- new_pairs]
 111       -- Generated bindings must be non-recursive
 112       -- because the original binding was.
 113
 114 wwBind (Rec pairs)
 115   = mapUs do_one pairs          `thenUs` \ new_pairs ->
 116     returnUs [Rec (concat new_pairs)]
 117   where
 118     do_one (binder, rhs) = wwExpr rhs   `thenUs` \ new_rhs ->
 119                            tryWW Recursive binder new_rhs
 120 \end{code}
 121
 122 @wwExpr@ basically just walks the tree, looking for appropriate
 123 annotations that can be used. Remember it is @wwBind@ that does the
 124 matching by looking for strict arguments of the correct type.
 125 @wwExpr@ is a version that just returns the ``Plain'' Tree.
 126
 127 \begin{code}
 128 wwExpr :: CoreExpr -> UniqSM CoreExpr
 129
 130 wwExpr e@(Type _)   = returnUs e
 131 wwExpr e@(Var _)    = returnUs e
 132 wwExpr e@(Lit _)    = returnUs e
 133
 134 wwExpr (Lam binder expr)
 135   = wwExpr expr                 `thenUs` \ new_expr ->
 136     returnUs (Lam binder new_expr)
 137
 138 wwExpr (App f a)
 139   = wwExpr f                    `thenUs` \ new_f ->
 140     wwExpr a                    `thenUs` \ new_a ->
 141     returnUs (App new_f new_a)
 142
 143 wwExpr (Note note expr)
 144   = wwExpr expr                 `thenUs` \ new_expr ->
 145     returnUs (Note note new_expr)
 146
 147 wwExpr (Let bind expr)
 148   = wwBind bind                 `thenUs` \ intermediate_bind ->
 149     wwExpr expr                 `thenUs` \ new_expr ->
 150     returnUs (mkLets intermediate_bind new_expr)
 151
 152 wwExpr (Case expr binder alts)
 153   = wwExpr expr                         `thenUs` \ new_expr ->
 154     mapUs ww_alt alts                   `thenUs` \ new_alts ->
 155     returnUs (Case new_expr binder new_alts)
 156   where
 157     ww_alt (con, binders, rhs)
 158       = wwExpr rhs                      `thenUs` \ new_rhs ->
 159         returnUs (con, binders, new_rhs)
 160 \end{code}
 161
 162 %************************************************************************
 163 %*                                                                      *
 164 \subsection[tryWW]{@tryWW@: attempt a worker/wrapper pair}
 165 %*                                                                      *
 166 %************************************************************************
 167
 168 @tryWW@ just accumulates arguments, converts strictness info from the
 169 front-end into the proper form, then calls @mkWwBodies@ to do
 170 the business.
 171
 172 We have to BE CAREFUL that we don't worker-wrapperize an Id that has
 173 already been w-w'd!  (You can end up with several liked-named Ids
 174 bouncing around at the same time---absolute mischief.)  So the
 175 criterion we use is: if an Id already has an unfolding (for whatever
 176 reason), then we don't w-w it.
 177
 178 The only reason this is monadised is for the unique supply.
 179
 180 \begin{code}
 181 tryWW   :: RecFlag
 182         -> Id                           -- The fn binder
 183         -> CoreExpr                     -- The bound rhs; its innards
 184                                         --   are already ww'd
 185         -> UniqSM [(Id, CoreExpr)]      -- either *one* or *two* pairs;
 186                                         -- if one, then no worker (only
 187                                         -- the orig "wrapper" lives on);
 188                                         -- if two, then a worker and a
 189                                         -- wrapper.
 190 tryWW is_rec fn_id rhs
 191   |  isNonRec is_rec && certainlyWillInline unfolding
 192         -- No point in worker/wrappering a function that is going to be
 193         -- INLINEd wholesale anyway.  If the strictness analyser is run
 194         -- twice, this test also prevents wrappers (which are INLINEd)
 195         -- from being re-done.
 196         --
 197         -- It's very important to refrain from w/w-ing an INLINE function
 198         -- If we do so by mistake we transform
 199         --      f = __inline (\x -> E)
 200         -- into
 201         --      f = __inline (\x -> case x of (a,b) -> fw E)
 202         --      fw = \ab -> (__inline (\x -> E)) (a,b)
 203         -- and the original __inline now vanishes, so E is no longer
 204         -- inside its __inline wrapper.  Death!  Disaster!
 205   = returnUs [ (fn_id', rhs) ]
 206
 207   | is_thunk && worthSplittingThunk fn_dmd res_info
 208   = ASSERT( isNonRec is_rec )   -- The thunk must be non-recursive
 209     splitThunk fn_id' rhs
 210
 211   | is_fun && worthSplittingFun wrap_dmds res_info
 212   = splitFun fn_id' fn_info wrap_dmds res_info inline_prag rhs
 213
 214   | otherwise
 215   = returnUs [ (fn_id', rhs) ]
 216
 217   where
 218     fn_info     = idInfo fn_id
 219     fn_dmd      = newDemandInfo fn_info
 220     unfolding   = unfoldingInfo fn_info
 221     inline_prag = inlinePragInfo fn_info
 222     maybe_sig   = newStrictnessInfo fn_info
 223
 224         -- In practice it always will have a strictness
 225         -- signature, even if it's a uninformative one
 226     strict_sig  = newStrictnessInfo fn_info `orElse` topSig
 227     StrictSig (DmdType env wrap_dmds res_info) = strict_sig
 228
 229         -- fn_id' has the DmdEnv zapped.
 230         --      (a) it is never used again
 231         --      (b) it wastes space
 232         --      (c) it becomes incorrect as things are cloned, because
 233         --          we don't push the substitution into it
 234     fn_id' | isEmptyVarEnv env = fn_id
 235            | otherwise         = fn_id `setIdNewStrictness`
 236                                    StrictSig (mkTopDmdType wrap_dmds res_info)
 237
 238     is_fun    = not (null wrap_dmds)
 239     is_thunk  = not is_fun && not (exprIsValue rhs)
 240
 241 ---------------------
 242 splitFun fn_id fn_info wrap_dmds res_info inline_prag rhs
 243   = WARN( not (wrap_dmds `lengthIs` arity), ppr fn_id <+> (ppr arity $$ ppr wrap_dmds $$ ppr res_info) )
 244         -- The arity should match the signature
 245     mkWwBodies fun_ty wrap_dmds res_info one_shots      `thenUs` \ (work_demands, wrap_fn, work_fn) ->
 246     getUniqueUs                                         `thenUs` \ work_uniq ->
 247     let
 248         work_rhs = work_fn rhs
 249         work_id  = mkWorkerId work_uniq fn_id (exprType work_rhs)
 250                         `setInlinePragma` inline_prag
 251                         `setIdNewStrictness` StrictSig (mkTopDmdType work_demands work_res_info)
 252                                 -- Even though we may not be at top level,
 253                                 -- it's ok to give it an empty DmdEnv
 254
 255         wrap_rhs = wrap_fn work_id
 256         wrap_id  = fn_id `setIdWorkerInfo` HasWorker work_id arity
 257                          `setInlinePragma` AlwaysActive -- Zap any inline pragma;
 258                                                         -- Put it on the worker instead
 259     in
 260     returnUs ([(work_id, work_rhs), (wrap_id, wrap_rhs)])
 261         -- Worker first, because wrapper mentions it
 262         -- mkWwBodies has already built a wrap_rhs with an INLINE pragma wrapped around it
 263   where
 264     fun_ty = idType fn_id
 265
 266     arity  = arityInfo fn_info  -- The arity is set by the simplifier using exprEtaExpandArity
 267                                 -- So it may be more than the number of top-level-visible lambdas
 268
 269     work_res_info | isBotRes res_info = BotRes  -- Cpr stuff done by wrapper
 270                   | otherwise         = TopRes
 271
 272     one_shots = get_one_shots rhs
 273
 274 -- If the original function has one-shot arguments, it is important to
 275 -- make the wrapper and worker have corresponding one-shot arguments too.
 276 -- Otherwise we spuriously float stuff out of case-expression join points,
 277 -- which is very annoying.
 278 get_one_shots (Lam b e)
 279   | isId b    = isOneShotLambda b : get_one_shots e
 280   | otherwise = get_one_shots e
 281 get_one_shots (Note _ e) = get_one_shots e
 282 get_one_shots other      = noOneShotInfo
 283 \end{code}
 284
 285 Thunk splitting
 286 ~~~~~~~~~~~~~~~
 287 Suppose x is used strictly (never mind whether it has the CPR
 288 property).
 289
 290       let
 291         x* = x-rhs
 292       in body
 293
 294 splitThunk transforms like this:
 295
 296       let
 297         x* = case x-rhs of { I# a -> I# a }
 298       in body
 299
 300 Now simplifier will transform to
 301
 302       case x-rhs of
 303         I# a -> let x* = I# b
 304                 in body
 305
 306 which is what we want. Now suppose x-rhs is itself a case:
 307
 308         x-rhs = case e of { T -> I# a; F -> I# b }
 309
 310 The join point will abstract over a, rather than over (which is
 311 what would have happened before) which is fine.
 312
 313 Notice that x certainly has the CPR property now!
 314
 315 In fact, splitThunk uses the function argument w/w splitting
 316 function, so that if x's demand is deeper (say U(U(L,L),L))
 317 then the splitting will go deeper too.
 318
 319 \begin{code}
 320 -- splitThunk converts the *non-recursive* binding
 321 --      x = e
 322 -- into
 323 --      x = let x = e
 324 --          in case x of
 325 --               I# y -> let x = I# y in x }
 326 -- See comments above. Is it not beautifully short?
 327
 328 splitThunk fn_id rhs
 329   = mkWWstr [fn_id]             `thenUs` \ (_, wrap_fn, work_fn) ->
 330     returnUs [ (fn_id, Let (NonRec fn_id rhs) (wrap_fn (work_fn (Var fn_id)))) ]
 331 \end{code}
 332
 333
 334 %************************************************************************
 335 %*                                                                      *
 336 \subsection{Functions over Demands}
 337 %*                                                                      *
 338 %************************************************************************
 339
 340 \begin{code}
 341 worthSplittingFun :: [Demand] -> DmdResult -> Bool
 342                 -- True <=> the wrapper would not be an identity function
 343 worthSplittingFun ds res
 344   = any worth_it ds || returnsCPR res
 345         -- worthSplitting returns False for an empty list of demands,
 346         -- and hence do_strict_ww is False if arity is zero and there is no CPR
 347
 348         -- We used not to split if the result is bottom.
 349         -- [Justification:  there's no efficiency to be gained.]
 350         -- But it's sometimes bad not to make a wrapper.  Consider
 351         --      fw = \x# -> let x = I# x# in case e of
 352         --                                      p1 -> error_fn x
 353         --                                      p2 -> error_fn x
 354         --                                      p3 -> the real stuff
 355         -- The re-boxing code won't go away unless error_fn gets a wrapper too.
 356         -- [We don't do reboxing now, but in general it's better to pass
 357         --  an unboxed thing to f, and have it reboxed in the error cases....]
 358   where
 359     worth_it Abs              = True    -- Absent arg
 360     worth_it (Eval (Prod ds)) = True    -- Product arg to evaluate
 361     worth_it other            = False
 362
 363 worthSplittingThunk :: Demand           -- Demand on the thunk
 364                     -> DmdResult        -- CPR info for the thunk
 365                     -> Bool
 366 worthSplittingThunk dmd res
 367   = worth_it dmd || returnsCPR res
 368   where
 369         -- Split if the thing is unpacked
 370     worth_it (Eval (Prod ds)) = not (all isAbsent ds)
 371     worth_it other            = False
 372 \end{code}
 373
 374
 375
 376 %************************************************************************
 377 %*                                                                      *
 378 \subsection{The worker wrapper core}
 379 %*                                                                      *
 380 %************************************************************************
 381
 382 @mkWrapper@ is called when importing a function.  We have the type of
 383 the function and the name of its worker, and we want to make its body (the wrapper).
 384
 385 \begin{code}
 386 mkWrapper :: Type               -- Wrapper type
 387           -> StrictSig          -- Wrapper strictness info
 388           -> UniqSM (Id -> CoreExpr)    -- Wrapper body, missing worker Id
 389
 390 mkWrapper fun_ty (StrictSig (DmdType _ demands res_info))
 391   = mkWwBodies fun_ty demands res_info noOneShotInfo    `thenUs` \ (_, wrap_fn, _) ->
 392     returnUs wrap_fn
 393
 394 noOneShotInfo = repeat False
 395 \end{code}