ghc/compiler/stranal/WwLib.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1996
   3 %
   4 \section[WwLib]{A library for the ``worker/wrapper'' back-end to the strictness analyser}
   5
   6 \begin{code}
   7 #include "HsVersions.h"
   8
   9 module WwLib (
  10         WwBinding(..),
  11
  12         worthSplitting, setUnpackStrategy,
  13         mkWwBodies, mkWrapper
  14     ) where
  15
  16 IMP_Ubiq(){-uitous-}
  17
  18 import CoreSyn
  19 import Id               ( idType, mkSysLocal, dataConArgTys, SYN_IE(Id) )
  20 import IdInfo           ( mkStrictnessInfo, {-??nonAbsentArgs,-} Demand(..) )
  21 import PrelVals         ( aBSENT_ERROR_ID, voidId )
  22 import TysPrim          ( voidTy )
  23 import SrcLoc           ( noSrcLoc )
  24 import Type             ( isPrimType, mkTyVarTys, mkForAllTys, mkFunTys,
  25                           splitForAllTy, splitFunTyExpandingDicts,
  26                           maybeAppDataTyConExpandingDicts,
  27                           SYN_IE(Type)
  28                         )
  29 import TyVar            ( SYN_IE(TyVar) )
  30 import UniqSupply       ( returnUs, thenUs, thenMaybeUs,
  31                           getUniques, getUnique, SYN_IE(UniqSM)
  32                         )
  33 import Util             ( zipWithEqual, zipEqual, assertPanic, panic, pprPanic )
  34 import PprStyle
  35 import Pretty
  36 import Outputable
  37 \end{code}
  38
  39 %************************************************************************
  40 %*                                                                      *
  41 \subsection[datatype-WwLib]{@WwBinding@: a datatype for worker/wrapper-ing}
  42 %*                                                                      *
  43 %************************************************************************
  44
  45 In the worker/wrapper stuff, we want to carry around @CoreBindings@ in
  46 an ``intermediate form'' that can later be turned into a \tr{let} or
  47 \tr{case} (depending on strictness info).
  48
  49 \begin{code}
  50 data WwBinding
  51   = WwLet  [CoreBinding]
  52   | WwCase (CoreExpr -> CoreExpr)
  53                 -- the "case" will be a "strict let" of the form:
  54                 --
  55                 --  case rhs of
  56                 --    <blah> -> body
  57                 --
  58                 -- (instead of "let <blah> = rhs in body")
  59                 --
  60                 -- The expr you pass to the function is "body" (the
  61                 -- expression that goes "in the corner").
  62 \end{code}
  63
  64 %************************************************************************
  65 %*                                                                      *
  66 \subsection[mkWrapperAndWorker]{@mkWrapperAndWorker@}
  67 %*                                                                      *
  68 %************************************************************************
  69
  70         ************   WARNING  ******************
  71         these comments are rather out of date
  72         *****************************************
  73
  74 @mkWrapperAndWorker@ is given:
  75 \begin{enumerate}
  76 \item
  77 The {\em original function} \tr{f}, of the form:
  78 \begin{verbatim}
  79 f = /\ tyvars -> \ args -> body
  80 \end{verbatim}
  81 The original-binder \tr{f}, the \tr{tyvars}, \tr{args}, and \tr{body}
  82 are given separately.
  83
  84 We use the Id \tr{f} mostly to get its type.
  85
  86 \item
  87 Strictness information about \tr{f}, in the form of a list of
  88 @Demands@.
  89
  90 \item
  91 A @UniqueSupply@.
  92 \end{enumerate}
  93
  94 @mkWrapperAndWorker@ produces (A BIT OUT-OF-DATE...):
  95 \begin{enumerate}
  96 \item
  97 Maybe @Nothing@: no worker/wrappering going on in this case. This can
  98 happen (a)~if the strictness info says that there is nothing
  99 interesting to do or (b)~if *any* of the argument types corresponding
 100 to ``active'' arg postitions is abstract or will be to the outside
 101 world (i.e., {\em this} module can see the constructors, but nobody
 102 else will be able to).  An ``active'' arg position is one which the
 103 wrapper has to unpack.  An importing module can't do this unpacking,
 104 so it simply has to give up and call the wrapper only.
 105
 106 \item
 107 Maybe \tr{Just (wrapper_Id, wrapper_body, worker_Id, worker_body)}.
 108
 109 The @wrapper_Id@ is just the one that was passed in, with its
 110 strictness IdInfo updated.
 111 \end{enumerate}
 112
 113 The \tr{body} of the original function may not be given (i.e., it's
 114 BOTTOM), in which case you'd jolly well better not tug on the
 115 worker-body output!
 116
 117 Here's an example.  The original function is:
 118 \begin{verbatim}
 119 g :: forall a . Int -> [a] -> a
 120
 121 g = /\ a -> \ x ys ->
 122         case x of
 123           0 -> head ys
 124           _ -> head (tail ys)
 125 \end{verbatim}
 126
 127 From this, we want to produce:
 128 \begin{verbatim}
 129 -- wrapper (an unfolding)
 130 g :: forall a . Int -> [a] -> a
 131
 132 g = /\ a -> \ x ys ->
 133         case x of
 134           I# x# -> g.wrk a x# ys
 135             -- call the worker; don't forget the type args!
 136
 137 -- worker
 138 g.wrk :: forall a . Int# -> [a] -> a
 139
 140 g.wrk = /\ a -> \ x# ys ->
 141         let
 142             x = I# x#
 143         in
 144             case x of               -- note: body of g moved intact
 145               0 -> head ys
 146               _ -> head (tail ys)
 147 \end{verbatim}
 148
 149 Something we have to be careful about:  Here's an example:
 150 \begin{verbatim}
 151 -- "f" strictness: U(P)U(P)
 152 f (I# a) (I# b) = a +# b
 153
 154 g = f   -- "g" strictness same as "f"
 155 \end{verbatim}
 156 \tr{f} will get a worker all nice and friendly-like; that's good.
 157 {\em But we don't want a worker for \tr{g}}, even though it has the
 158 same strictness as \tr{f}.  Doing so could break laziness, at best.
 159
 160 Consequently, we insist that the number of strictness-info items is
 161 exactly the same as the number of lambda-bound arguments.  (This is
 162 probably slightly paranoid, but OK in practice.)  If it isn't the
 163 same, we ``revise'' the strictness info, so that we won't propagate
 164 the unusable strictness-info into the interfaces.
 165
 166
 167 %************************************************************************
 168 %*                                                                      *
 169 \subsection{Functions over Demands}
 170 %*                                                                      *
 171 %************************************************************************
 172
 173 \begin{code}
 174 mAX_WORKER_ARGS :: Int          -- ToDo: set via flag
 175 mAX_WORKER_ARGS = 6
 176
 177 setUnpackStrategy :: [Demand] -> [Demand]
 178 setUnpackStrategy ds
 179   = snd (go (mAX_WORKER_ARGS - nonAbsentArgs ds) ds)
 180   where
 181     go :: Int                   -- Max number of args available for sub-components of [Demand]
 182        -> [Demand]
 183        -> (Int, [Demand])       -- Args remaining after subcomponents of [Demand] are unpacked
 184
 185     go n (WwUnpack _ cs : ds) | n' >= 0
 186                               = WwUnpack True cs' `cons` go n'' ds
 187                               | otherwise
 188                               = WwUnpack False cs `cons` go n ds
 189                               where
 190                                 n' = n + 1 - nonAbsentArgs cs
 191                                         -- Add one because we don't pass the top-level arg any more
 192                                         -- Delete # of non-absent args to which we'll now be committed
 193                                 (n'',cs') = go n' cs
 194
 195     go n (d:ds) = d `cons` go n ds
 196     go n []     = (n,[])
 197
 198     cons d (n,ds) = (n, d:ds)
 199
 200 nonAbsentArgs :: [Demand] -> Int
 201 nonAbsentArgs []                 = 0
 202 nonAbsentArgs (WwLazy True : ds) = nonAbsentArgs ds
 203 nonAbsentArgs (d           : ds) = 1 + nonAbsentArgs ds
 204
 205 worthSplitting :: [Demand] -> Bool      -- True <=> the wrapper would not be an identity function
 206 worthSplitting []                       = False
 207 worthSplitting (WwLazy True : ds)       = True          -- Absent arg
 208 worthSplitting (WwUnpack True _ : ds)   = True          -- Arg to unpack
 209 worthSplitting (d : ds)                 = worthSplitting ds
 210
 211 allAbsent :: [Demand] -> Bool
 212 allAbsent (WwLazy True      : ds) = allAbsent ds
 213 allAbsent (WwUnpack True cs : ds) = allAbsent cs && allAbsent ds
 214 allAbsent (d                : ds) = False
 215 allAbsent []                      = True
 216 \end{code}
 217
 218
 219 %************************************************************************
 220 %*                                                                      *
 221 \subsection{The worker wrapper core}
 222 %*                                                                      *
 223 %************************************************************************
 224
 225 @mkWrapper@ is called when importing a function.  We have the type of
 226 the function and the name of its worker, and we want to make its body (the wrapper).
 227
 228 \begin{code}
 229 mkWrapper :: Type               -- Wrapper type
 230           -> [Demand]           -- Wrapper strictness info
 231           -> UniqSM (Id -> CoreExpr)    -- Wrapper body, missing worker Id
 232
 233 mkWrapper fun_ty demands
 234   = let
 235         n_wrap_args = length demands
 236     in
 237     getUniques n_wrap_args      `thenUs` \ wrap_uniqs ->
 238     let
 239         (tyvars, tau_ty)   = splitForAllTy fun_ty
 240         (arg_tys, body_ty) = splitFunTyExpandingDicts tau_ty
 241         wrap_args          = zipWith mk_ww_local wrap_uniqs arg_tys
 242         leftover_arg_tys   = drop n_wrap_args arg_tys
 243         final_body_ty      = mkFunTys leftover_arg_tys body_ty
 244     in
 245     mkWwBodies tyvars wrap_args final_body_ty demands   `thenUs` \ (wrap_fn, _, _) ->
 246     returnUs wrap_fn
 247 \end{code}
 248
 249 @mkWwBodies@ is called when doing the worker/wrapper split inside a module.
 250
 251 \begin{code}
 252 mkWwBodies :: [TyVar] -> [Id] -> Type           -- Original fn args and body type
 253            -> [Demand]                          -- Strictness info for original fn; corresp 1-1 with args
 254            -> UniqSM (Id -> CoreExpr,           -- Wrapper body, lacking only the worker Id
 255                       CoreExpr -> CoreExpr,     -- Worker body, lacking the original function body
 256                       [Demand])                 -- Strictness info for worker
 257
 258 mkWwBodies tyvars args body_ty demands
 259   | allAbsent demands &&
 260     isPrimType body_ty
 261   =     -- Horrid special case.  If the worker would have no arguments, and the
 262         -- function returns a primitive type value, that would make the worker into
 263         -- an unboxed value.  We box it by passing a dummy void argument, thus:
 264         --
 265         --      f = /\abc. \xyz. fw abc void
 266         --      fw = /\abc. \v. body
 267         --
 268     getUnique           `thenUs` \ void_arg_uniq ->
 269     let
 270         void_arg = mk_ww_local void_arg_uniq voidTy
 271     in
 272     returnUs (\ work_id -> mkLam tyvars args (App (mkTyApp (Var work_id) (mkTyVarTys tyvars)) (VarArg voidId)),
 273               \ body    -> mkLam tyvars [void_arg] body,
 274               [WwLazy True])
 275
 276 mkWwBodies tyvars args body_ty demands
 277   | otherwise
 278   = let
 279         args_w_demands = zipEqual "mkWwBodies" args demands
 280     in
 281     mkWW args_w_demands         `thenUs` \ (wrap_fn, work_args_w_demands, work_fn) ->
 282     let
 283         (work_args, work_demands) = unzip work_args_w_demands
 284     in
 285     returnUs (\ work_id -> mkLam tyvars args (wrap_fn (mkTyApp (Var work_id) (mkTyVarTys tyvars))),
 286               \ body    -> mkLam tyvars work_args (work_fn body),
 287               work_demands)
 288 \end{code}
 289
 290
 291 \begin{code}
 292 mkWW :: [(Id,Demand)]
 293      -> UniqSM (CoreExpr -> CoreExpr,   -- Wrapper body, lacking the inner call to the worker
 294                                         -- and without its lambdas
 295                 [(Id,Demand)],          -- Worker args and their demand infos
 296                 CoreExpr -> CoreExpr)   -- Worker body, lacking the original body of the function
 297
 298
 299         -- Empty case
 300 mkWW []
 301   = returnUs (\ wrapper_body -> wrapper_body,
 302               [],
 303               \ worker_body  -> worker_body)
 304
 305
 306         -- Absent case
 307 mkWW ((arg,WwLazy True) : ds)
 308   = mkWW ds             `thenUs` \ (wrap_fn, worker_args, work_fn) ->
 309     returnUs (\ wrapper_body -> wrap_fn wrapper_body,
 310               worker_args,
 311               \ worker_body  -> mk_absent_let arg (work_fn worker_body))
 312
 313
 314         -- Unpack case
 315 mkWW ((arg,WwUnpack True cs) : ds)
 316   = getUniques (length inst_con_arg_tys)                `thenUs` \ uniqs ->
 317     let
 318         unpk_args        = zipWith mk_ww_local uniqs inst_con_arg_tys
 319         unpk_args_w_ds   = zipEqual "mkWW" unpk_args cs
 320     in
 321     mkWW (unpk_args_w_ds ++ ds)         `thenUs` \ (wrap_fn, worker_args, work_fn) ->
 322     returnUs (\ wrapper_body -> mk_unpk_case arg unpk_args data_con arg_tycon (wrap_fn wrapper_body),
 323               worker_args,
 324               \ worker_body  -> work_fn (mk_pk_let arg data_con tycon_arg_tys unpk_args worker_body))
 325   where
 326     inst_con_arg_tys = dataConArgTys data_con tycon_arg_tys
 327     (arg_tycon, tycon_arg_tys, data_con)
 328         = case (maybeAppDataTyConExpandingDicts (idType arg)) of
 329
 330               Just (arg_tycon, tycon_arg_tys, [data_con]) ->
 331                                      -- The main event: a single-constructor data type
 332                                      (arg_tycon, tycon_arg_tys, data_con)
 333
 334               Just (_, _, data_cons) ->  pprPanic "mk_ww_arg_processing: not one constr (interface files not consistent/up to date ?)" ((ppr PprDebug arg) <+> (ppr PprDebug (idType arg)))
 335               Nothing                ->  panic "mk_ww_arg_processing: not datatype"
 336
 337
 338         -- Other cases
 339 mkWW ((arg,other_demand) : ds)
 340   = mkWW ds             `thenUs` \ (wrap_fn, worker_args, work_fn) ->
 341     returnUs (\ wrapper_body -> wrap_fn (App wrapper_body (VarArg arg)),
 342               (arg,other_demand) : worker_args,
 343               work_fn)
 344 \end{code}
 345
 346
 347 %************************************************************************
 348 %*                                                                      *
 349 \subsection{Utilities}
 350 %*                                                                      *
 351 %************************************************************************
 352
 353
 354 \begin{code}
 355 mk_absent_let arg body
 356   | not (isPrimType arg_ty)
 357   = Let (NonRec arg (mkTyApp (Var aBSENT_ERROR_ID) [arg_ty])) body
 358   | otherwise
 359   = panic "WwLib: haven't done mk_absent_let for primitives yet"
 360   where
 361     arg_ty = idType arg
 362
 363 mk_unpk_case arg unpk_args boxing_con boxing_tycon body
 364   = Case (Var arg)
 365          (AlgAlts [(boxing_con, unpk_args, body)]
 366                   NoDefault
 367          )
 368
 369 mk_pk_let arg boxing_con con_tys unpk_args body
 370   = Let (NonRec arg (Con boxing_con con_args)) body
 371   where
 372     con_args = map TyArg con_tys ++ map VarArg unpk_args
 373
 374 mk_ww_local uniq ty
 375   = mkSysLocal SLIT("ww") uniq ty noSrcLoc
 376 \end{code}