ghc/compiler/typecheck/TcClassDcl.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcClassDcl]{Typechecking class declarations}
   5
   6 \begin{code}
   7 module TcClassDcl ( tcClassDecl1, tcClassDecls2,
   8                     tcMethodBind, mkMethodBind, badMethodErr
   9                   ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn            ( TyClDecl(..), Sig(..), MonoBinds(..),
  14                           HsExpr(..), HsLit(..), InPat(WildPatIn),
  15                           mkSimpleMatch, andMonoBinds, andMonoBindList,
  16                           isClassOpSig, isPragSig,
  17                           getClassDeclSysNames, placeHolderType
  18                         )
  19 import BasicTypes       ( RecFlag(..), StrictnessMark(..) )
  20 import RnHsSyn          ( RenamedTyClDecl,
  21                           RenamedClassOpSig, RenamedMonoBinds,
  22                           maybeGenericMatch
  23                         )
  24 import TcHsSyn          ( TcMonoBinds )
  25
  26 import Inst             ( Inst, InstOrigin(..), LIE, emptyLIE, plusLIE, plusLIEs,
  27                           instToId, newDicts, newMethod )
  28 import TcEnv            ( TyThingDetails(..),
  29                           tcLookupClass, tcExtendTyVarEnv2,
  30                           tcExtendTyVarEnv
  31                         )
  32 import TcBinds          ( tcMonoBinds )
  33 import TcMonoType       ( TcSigInfo(..), tcHsType, tcHsTheta, mkTcSig )
  34 import TcSimplify       ( tcSimplifyCheck )
  35 import TcUnify          ( checkSigTyVars, sigCtxt )
  36 import TcMType          ( tcInstTyVars )
  37 import TcType           ( Type, TyVarDetails(..), TcType, TcThetaType, TcTyVar,
  38                           mkTyVarTys, mkPredTys, mkClassPred, tcSplitSigmaTy, tcSplitFunTys,
  39                           tcIsTyVarTy, tcSplitTyConApp_maybe
  40                         )
  41 import TcMonad
  42 import Generics         ( mkGenericRhs )
  43 import PrelInfo         ( nO_METHOD_BINDING_ERROR_ID )
  44 import Class            ( classTyVars, classBigSig, classTyCon,
  45                           Class, ClassOpItem, DefMeth (..) )
  46 import TyCon            ( tyConGenInfo )
  47 import MkId             ( mkDictSelId, mkDataConId, mkDataConWrapId, mkDefaultMethodId )
  48 import DataCon          ( mkDataCon )
  49 import Id               ( Id, idType, idName, setIdLocalExported )
  50 import Module           ( Module )
  51 import Name             ( Name, NamedThing(..) )
  52 import NameEnv          ( NameEnv, lookupNameEnv, emptyNameEnv, unitNameEnv, plusNameEnv )
  53 import NameSet          ( emptyNameSet )
  54 import Outputable
  55 import Var              ( TyVar )
  56 import CmdLineOpts
  57 import UnicodeUtil      ( stringToUtf8 )
  58 import ErrUtils         ( dumpIfSet )
  59 import Util             ( count, lengthIs, equalLength )
  60 import Maybes           ( seqMaybe )
  61 import Maybe            ( isJust )
  62 import FastString
  63 \end{code}
  64
  65
  66
  67 Dictionary handling
  68 ~~~~~~~~~~~~~~~~~~~
  69 Every class implicitly declares a new data type, corresponding to dictionaries
  70 of that class. So, for example:
  71
  72         class (D a) => C a where
  73           op1 :: a -> a
  74           op2 :: forall b. Ord b => a -> b -> b
  75
  76 would implicitly declare
  77
  78         data CDict a = CDict (D a)
  79                              (a -> a)
  80                              (forall b. Ord b => a -> b -> b)
  81
  82 (We could use a record decl, but that means changing more of the existing apparatus.
  83 One step at at time!)
  84
  85 For classes with just one superclass+method, we use a newtype decl instead:
  86
  87         class C a where
  88           op :: forallb. a -> b -> b
  89
  90 generates
  91
  92         newtype CDict a = CDict (forall b. a -> b -> b)
  93
  94 Now DictTy in Type is just a form of type synomym:
  95         DictTy c t = TyConTy CDict `AppTy` t
  96
  97 Death to "ExpandingDicts".
  98
  99
 100 %************************************************************************
 101 %*                                                                      *
 102 \subsection{Type checking}
 103 %*                                                                      *
 104 %************************************************************************
 105
 106 \begin{code}
 107
 108 tcClassDecl1 :: RenamedTyClDecl -> TcM (Name, TyThingDetails)
 109 tcClassDecl1 (ClassDecl {tcdCtxt = context, tcdName = class_name,
 110                          tcdTyVars = tyvar_names, tcdFDs = fundeps,
 111                          tcdSigs = class_sigs, tcdMeths = def_methods,
 112                          tcdSysNames = sys_names, tcdLoc = src_loc})
 113   =     -- LOOK THINGS UP IN THE ENVIRONMENT
 114     tcLookupClass class_name                            `thenTc` \ clas ->
 115     let
 116         tyvars   = classTyVars clas
 117         op_sigs  = filter isClassOpSig class_sigs
 118         op_names = [n | ClassOpSig n _ _ _ <- op_sigs]
 119         (_, datacon_name, datacon_wkr_name, sc_sel_names) = getClassDeclSysNames sys_names
 120     in
 121     tcExtendTyVarEnv tyvars                             $
 122
 123     checkDefaultBinds clas op_names def_methods   `thenTc` \ mb_dm_env ->
 124
 125         -- CHECK THE CONTEXT
 126         -- The renamer has already checked that the context mentions
 127         -- only the type variable of the class decl.
 128         -- Context is already kind-checked
 129     ASSERT( equalLength context sc_sel_names )
 130     tcHsTheta context                                   `thenTc` \ sc_theta ->
 131
 132         -- CHECK THE CLASS SIGNATURES,
 133     mapTc (tcClassSig clas tyvars mb_dm_env) op_sigs    `thenTc` \ sig_stuff ->
 134
 135         -- MAKE THE CLASS DETAILS
 136     let
 137         (op_tys, op_items) = unzip sig_stuff
 138         sc_tys             = mkPredTys sc_theta
 139         dict_component_tys = sc_tys ++ op_tys
 140         sc_sel_ids         = [mkDictSelId sc_name clas | sc_name <- sc_sel_names]
 141
 142         dict_con = mkDataCon datacon_name
 143                              [NotMarkedStrict | _ <- dict_component_tys]
 144                              [{- No labelled fields -}]
 145                              tyvars
 146                              [{-No context-}]
 147                              [{-No existential tyvars-}] [{-Or context-}]
 148                              dict_component_tys
 149                              (classTyCon clas)
 150                              dict_con_id dict_wrap_id
 151
 152         dict_con_id  = mkDataConId datacon_wkr_name dict_con
 153         dict_wrap_id = mkDataConWrapId dict_con
 154     in
 155     returnTc (class_name, ClassDetails sc_theta sc_sel_ids op_items dict_con)
 156 \end{code}
 157
 158 \begin{code}
 159 checkDefaultBinds :: Class -> [Name] -> Maybe RenamedMonoBinds
 160                   -> TcM (Maybe (NameEnv Bool))
 161         -- The returned environment says
 162         --      x not in env => no default method
 163         --      x -> True    => generic default method
 164         --      x -> False   => polymorphic default method
 165
 166   -- Check default bindings
 167   --    a) must be for a class op for this class
 168   --    b) must be all generic or all non-generic
 169   -- and return a mapping from class-op to DefMeth info
 170
 171   -- But do all this only for source binds
 172
 173 checkDefaultBinds clas ops Nothing
 174   = returnTc Nothing
 175
 176 checkDefaultBinds clas ops (Just mbs)
 177   = go mbs      `thenTc` \ dm_env ->
 178     returnTc (Just dm_env)
 179   where
 180     go EmptyMonoBinds = returnTc emptyNameEnv
 181
 182     go (AndMonoBinds b1 b2)
 183       = go b1   `thenTc` \ dm_info1 ->
 184         go b2   `thenTc` \ dm_info2 ->
 185         returnTc (dm_info1 `plusNameEnv` dm_info2)
 186
 187     go (FunMonoBind op _ matches loc)
 188       = tcAddSrcLoc loc                                 $
 189
 190         -- Check that the op is from this class
 191         checkTc (op `elem` ops) (badMethodErr clas op)          `thenTc_`
 192
 193         -- Check that all the defns ar generic, or none are
 194         checkTc (all_generic || none_generic) (mixedGenericErr op)      `thenTc_`
 195
 196         returnTc (unitNameEnv op all_generic)
 197       where
 198         n_generic    = count (isJust . maybeGenericMatch) matches
 199         none_generic = n_generic == 0
 200         all_generic  = matches `lengthIs` n_generic
 201 \end{code}
 202
 203
 204 \begin{code}
 205 tcClassSig :: Class                     -- ...ditto...
 206            -> [TyVar]                   -- The class type variable, used for error check only
 207            -> Maybe (NameEnv Bool)      -- Info about default methods;
 208                                         --      Nothing => imported class defn with no method binds
 209            -> RenamedClassOpSig
 210            -> TcM (Type,                -- Type of the method
 211                      ClassOpItem)       -- Selector Id, default-method Id, True if explicit default binding
 212
 213 -- This warrants an explanation: we need to separate generic
 214 -- default methods and default methods later on in the compiler
 215 -- so we distinguish them in checkDefaultBinds, and pass this knowledge in the
 216 -- Class.DefMeth data structure.
 217
 218 tcClassSig clas clas_tyvars maybe_dm_env
 219            (ClassOpSig op_name sig_dm op_ty src_loc)
 220   = tcAddSrcLoc src_loc $
 221
 222         -- Check the type signature.  NB that the envt *already has*
 223         -- bindings for the type variables; see comments in TcTyAndClassDcls.
 224     tcHsType op_ty                      `thenTc` \ local_ty ->
 225
 226     let
 227         theta = [mkClassPred clas (mkTyVarTys clas_tyvars)]
 228
 229         -- Build the selector id and default method id
 230         sel_id = mkDictSelId op_name clas
 231         DefMeth dm_name = sig_dm
 232
 233         dm_info = case maybe_dm_env of
 234                     Nothing     -> sig_dm
 235                     Just dm_env -> mk_src_dm_info dm_env
 236
 237         mk_src_dm_info dm_env = case lookupNameEnv dm_env op_name of
 238                                    Nothing    -> NoDefMeth
 239                                    Just True  -> GenDefMeth
 240                                    Just False -> DefMeth dm_name
 241     in
 242     returnTc (local_ty, (sel_id, dm_info))
 243 \end{code}
 244
 245
 246 %************************************************************************
 247 %*                                                                      *
 248 \subsection[Default methods]{Default methods}
 249 %*                                                                      *
 250 %************************************************************************
 251
 252 The default methods for a class are each passed a dictionary for the
 253 class, so that they get access to the other methods at the same type.
 254 So, given the class decl
 255 \begin{verbatim}
 256 class Foo a where
 257         op1 :: a -> Bool
 258         op2 :: Ord b => a -> b -> b -> b
 259
 260         op1 x = True
 261         op2 x y z = if (op1 x) && (y < z) then y else z
 262 \end{verbatim}
 263 we get the default methods:
 264 \begin{verbatim}
 265 defm.Foo.op1 :: forall a. Foo a => a -> Bool
 266 defm.Foo.op1 = /\a -> \dfoo -> \x -> True
 267
 268 defm.Foo.op2 :: forall a. Foo a => forall b. Ord b => a -> b -> b -> b
 269 defm.Foo.op2 = /\ a -> \ dfoo -> /\ b -> \ dord -> \x y z ->
 270                   if (op1 a dfoo x) && (< b dord y z) then y else z
 271 \end{verbatim}
 272
 273 When we come across an instance decl, we may need to use the default
 274 methods:
 275 \begin{verbatim}
 276 instance Foo Int where {}
 277 \end{verbatim}
 278 gives
 279 \begin{verbatim}
 280 const.Foo.Int.op1 :: Int -> Bool
 281 const.Foo.Int.op1 = defm.Foo.op1 Int dfun.Foo.Int
 282
 283 const.Foo.Int.op2 :: forall b. Ord b => Int -> b -> b -> b
 284 const.Foo.Int.op2 = defm.Foo.op2 Int dfun.Foo.Int
 285
 286 dfun.Foo.Int :: Foo Int
 287 dfun.Foo.Int = (const.Foo.Int.op1, const.Foo.Int.op2)
 288 \end{verbatim}
 289 Notice that, as with method selectors above, we assume that dictionary
 290 application is curried, so there's no need to mention the Ord dictionary
 291 in const.Foo.Int.op2 (or the type variable).
 292
 293 \begin{verbatim}
 294 instance Foo a => Foo [a] where {}
 295
 296 dfun.Foo.List :: forall a. Foo a -> Foo [a]
 297 dfun.Foo.List
 298   = /\ a -> \ dfoo_a ->
 299     let rec
 300         op1 = defm.Foo.op1 [a] dfoo_list
 301         op2 = defm.Foo.op2 [a] dfoo_list
 302         dfoo_list = (op1, op2)
 303     in
 304         dfoo_list
 305 \end{verbatim}
 306
 307 The function @tcClassDecls2@ just arranges to apply @tcClassDecl2@ to
 308 each local class decl.
 309
 310 \begin{code}
 311 tcClassDecls2 :: Module -> [RenamedTyClDecl] -> NF_TcM (LIE, TcMonoBinds, [Id])
 312
 313 tcClassDecls2 this_mod decls
 314   = foldr combine
 315           (returnNF_Tc (emptyLIE, EmptyMonoBinds, []))
 316           [tcClassDecl2 cls_decl | cls_decl@(ClassDecl {tcdMeths = Just _}) <- decls]
 317                 -- The 'Just' picks out source ClassDecls
 318   where
 319     combine tc1 tc2 = tc1 `thenNF_Tc` \ (lie1, binds1, ids1) ->
 320                       tc2 `thenNF_Tc` \ (lie2, binds2, ids2) ->
 321                       returnNF_Tc (lie1 `plusLIE` lie2,
 322                                    binds1 `AndMonoBinds` binds2,
 323                                    ids1 ++ ids2)
 324 \end{code}
 325
 326 @tcClassDecl2@ generates bindings for polymorphic default methods
 327 (generic default methods have by now turned into instance declarations)
 328
 329 \begin{code}
 330 tcClassDecl2 :: RenamedTyClDecl         -- The class declaration
 331              -> NF_TcM (LIE, TcMonoBinds, [Id])
 332
 333 tcClassDecl2 (ClassDecl {tcdName = class_name, tcdSigs = sigs,
 334                          tcdMeths = Just default_binds, tcdLoc = src_loc})
 335   =     -- The 'Just' picks out source ClassDecls
 336     recoverNF_Tc (returnNF_Tc (emptyLIE, EmptyMonoBinds, [])) $
 337     tcAddSrcLoc src_loc                                   $
 338     tcLookupClass class_name                              `thenNF_Tc` \ clas ->
 339
 340         -- We make a separate binding for each default method.
 341         -- At one time I used a single AbsBinds for all of them, thus
 342         -- AbsBind [d] [dm1, dm2, dm3] { dm1 = ...; dm2 = ...; dm3 = ... }
 343         -- But that desugars into
 344         --      ds = \d -> (..., ..., ...)
 345         --      dm1 = \d -> case ds d of (a,b,c) -> a
 346         -- And since ds is big, it doesn't get inlined, so we don't get good
 347         -- default methods.  Better to make separate AbsBinds for each
 348     let
 349         (tyvars, _, _, op_items) = classBigSig clas
 350         prags                    = filter isPragSig sigs
 351         tc_dm                    = tcDefMeth clas tyvars default_binds prags
 352     in
 353     mapAndUnzip3Tc tc_dm op_items       `thenTc` \ (defm_binds, const_lies, dm_ids_s) ->
 354
 355     returnTc (plusLIEs const_lies, andMonoBindList defm_binds, concat dm_ids_s)
 356
 357
 358 tcDefMeth clas tyvars binds_in prags (_, NoDefMeth)  = returnTc (EmptyMonoBinds, emptyLIE, [])
 359 tcDefMeth clas tyvars binds_in prags (_, GenDefMeth) = returnTc (EmptyMonoBinds, emptyLIE, [])
 360         -- Generate code for polymorphic default methods only
 361         -- (Generic default methods have turned into instance decls by now.)
 362         -- This is incompatible with Hugs, which expects a polymorphic
 363         -- default method for every class op, regardless of whether or not
 364         -- the programmer supplied an explicit default decl for the class.
 365         -- (If necessary we can fix that, but we don't have a convenient Id to hand.)
 366
 367 tcDefMeth clas tyvars binds_in prags op_item@(sel_id, DefMeth dm_name)
 368   = tcInstTyVars ClsTv tyvars           `thenNF_Tc` \ (clas_tyvars, inst_tys, _) ->
 369     let
 370         dm_ty = idType sel_id   -- Same as dict selector!
 371           -- The default method's type should really come from the
 372           -- iface file, since it could be usage-generalised, but this
 373           -- requires altering the mess of knots in TcModule and I'm
 374           -- too scared to do that.  Instead, I have disabled generalisation
 375           -- of types of default methods (and dict funs) by annotating them
 376           -- TyGenNever (in MkId).  Ugh!  KSW 1999-09.
 377
 378         theta       = [mkClassPred clas inst_tys]
 379         dm_id       = mkDefaultMethodId dm_name dm_ty
 380         local_dm_id = setIdLocalExported dm_id
 381                 -- Reason for setIdLocalExported: see notes with MkId.mkDictFunId
 382         xtve = tyvars `zip` clas_tyvars
 383     in
 384     newDicts origin theta                               `thenNF_Tc` \ [this_dict] ->
 385
 386     mkMethodBind origin clas inst_tys binds_in op_item  `thenTc` \ (dm_inst, meth_info) ->
 387     tcMethodBind xtve clas_tyvars theta
 388                  [this_dict] meth_info                  `thenTc` \ (defm_bind, insts_needed) ->
 389
 390     tcAddErrCtxt (defltMethCtxt clas) $
 391
 392         -- Check the context
 393     tcSimplifyCheck
 394         (ptext SLIT("class") <+> ppr clas)
 395         clas_tyvars
 396         [this_dict]
 397         insts_needed                    `thenTc` \ (const_lie, dict_binds) ->
 398
 399         -- Simplification can do unification
 400     checkSigTyVars clas_tyvars          `thenTc` \ clas_tyvars' ->
 401
 402     let
 403         full_bind = AbsBinds
 404                     clas_tyvars'
 405                     [instToId this_dict]
 406                     [(clas_tyvars', local_dm_id, instToId dm_inst)]
 407                     emptyNameSet        -- No inlines (yet)
 408                     (dict_binds `andMonoBinds` defm_bind)
 409     in
 410     returnTc (full_bind, const_lie, [dm_id])
 411   where
 412     origin = ClassDeclOrigin
 413 \end{code}
 414
 415
 416
 417 %************************************************************************
 418 %*                                                                      *
 419 \subsection{Typechecking a method}
 420 %*                                                                      *
 421 %************************************************************************
 422
 423 @tcMethodBind@ is used to type-check both default-method and
 424 instance-decl method declarations.  We must type-check methods one at a
 425 time, because their signatures may have different contexts and
 426 tyvar sets.
 427
 428 \begin{code}
 429 tcMethodBind
 430         :: [(TyVar,TcTyVar)]    -- Bindings for type environment
 431         -> [TcTyVar]            -- Instantiated type variables for the
 432                                 --      enclosing class/instance decl.
 433                                 --      They'll be signature tyvars, and we
 434                                 --      want to check that they don't get bound
 435                                 -- Always equal the range of the type envt
 436         -> TcThetaType          -- Available theta; it's just used for the error message
 437         -> [Inst]               -- Available from context, used to simplify constraints
 438                                 --      from the method body
 439         -> (Id, TcSigInfo, RenamedMonoBinds)    -- Details of this method
 440         -> TcM (TcMonoBinds, LIE)
 441
 442 tcMethodBind xtve inst_tyvars inst_theta avail_insts
 443              (sel_id, meth_sig, meth_bind)
 444   =
 445         -- Check the bindings; first adding inst_tyvars to the envt
 446         -- so that we don't quantify over them in nested places
 447      tcExtendTyVarEnv2 xtve (
 448         tcAddErrCtxt (methodCtxt sel_id)                $
 449         tcMonoBinds meth_bind [meth_sig] NonRecursive
 450      )                                                  `thenTc` \ (meth_bind, meth_lie, _, _) ->
 451
 452         -- Now do context reduction.   We simplify wrt both the local tyvars
 453         -- and the ones of the class/instance decl, so that there is
 454         -- no problem with
 455         --      class C a where
 456         --        op :: Eq a => a -> b -> a
 457         --
 458         -- We do this for each method independently to localise error messages
 459
 460      let
 461         TySigInfo meth_id meth_tvs meth_theta _ local_meth_id _ _ = meth_sig
 462      in
 463      tcAddErrCtxtM (sigCtxt sel_id inst_tyvars inst_theta (idType meth_id))     $
 464      newDicts SignatureOrigin meth_theta                `thenNF_Tc` \ meth_dicts ->
 465      let
 466         all_tyvars = meth_tvs ++ inst_tyvars
 467         all_insts  = avail_insts ++ meth_dicts
 468      in
 469      tcSimplifyCheck
 470          (ptext SLIT("class or instance method") <+> quotes (ppr sel_id))
 471          all_tyvars all_insts meth_lie                  `thenTc` \ (lie, lie_binds) ->
 472
 473      checkSigTyVars all_tyvars                          `thenTc` \ all_tyvars' ->
 474
 475      let
 476         meth_tvs'      = take (length meth_tvs) all_tyvars'
 477         poly_meth_bind = AbsBinds meth_tvs'
 478                                   (map instToId meth_dicts)
 479                                   [(meth_tvs', meth_id, local_meth_id)]
 480                                   emptyNameSet  -- Inlines?
 481                                   (lie_binds `andMonoBinds` meth_bind)
 482      in
 483      returnTc (poly_meth_bind, lie)
 484
 485
 486 mkMethodBind :: InstOrigin
 487              -> Class -> [TcType]       -- Class and instance types
 488              -> RenamedMonoBinds        -- Method binding (pick the right one from in here)
 489              -> ClassOpItem
 490              -> TcM (Inst,              -- Method inst
 491                      (Id,                       -- Global selector Id
 492                       TcSigInfo,                -- Signature
 493                       RenamedMonoBinds))        -- Binding for the method
 494
 495 mkMethodBind origin clas inst_tys meth_binds (sel_id, dm_info)
 496   = tcGetSrcLoc                         `thenNF_Tc` \ loc ->
 497     newMethod origin sel_id inst_tys    `thenNF_Tc` \ meth_inst ->
 498     let
 499         meth_id    = instToId meth_inst
 500         meth_name  = idName meth_id
 501     in
 502         -- Figure out what method binding to use
 503         -- If the user suppplied one, use it, else construct a default one
 504     (case find_bind (idName sel_id) meth_name meth_binds of
 505         Just user_bind -> returnTc user_bind
 506         Nothing        -> mkDefMethRhs origin clas inst_tys sel_id loc dm_info  `thenTc` \ rhs ->
 507                           returnTc (FunMonoBind meth_name False -- Not infix decl
 508                                                 [mkSimpleMatch [] rhs placeHolderType loc] loc)
 509     )                                                           `thenTc` \ meth_bind ->
 510
 511     mkTcSig meth_id loc                 `thenNF_Tc` \ meth_sig ->
 512
 513     returnTc (meth_inst, (sel_id, meth_sig, meth_bind))
 514
 515
 516      -- The user didn't supply a method binding,
 517      -- so we have to make up a default binding
 518      -- The RHS of a default method depends on the default-method info
 519 mkDefMethRhs origin clas inst_tys sel_id loc (DefMeth dm_name)
 520   =  -- An polymorphic default method
 521     returnTc (HsVar dm_name)
 522
 523 mkDefMethRhs origin clas inst_tys sel_id loc NoDefMeth
 524   =     -- No default method
 525         -- Warn only if -fwarn-missing-methods
 526     doptsTc Opt_WarnMissingMethods              `thenNF_Tc` \ warn ->
 527     warnTc (isInstDecl origin && warn)
 528            (omittedMethodWarn sel_id)           `thenNF_Tc_`
 529     returnTc error_rhs
 530   where
 531     error_rhs  = HsLam (mkSimpleMatch wild_pats simple_rhs placeHolderType loc)
 532     simple_rhs = HsApp (HsVar (getName nO_METHOD_BINDING_ERROR_ID))
 533                        (HsLit (HsStringPrim (mkFastString (stringToUtf8 error_msg))))
 534     error_msg = showSDoc (hcat [ppr loc, text "|", ppr sel_id ])
 535
 536         -- When the type is of form t1 -> t2 -> t3
 537         -- make a default method like (\ _ _ -> noMethBind "blah")
 538         -- rather than simply        (noMethBind "blah")
 539         -- Reason: if t1 or t2 are higher-ranked types we get n
 540         --         silly ambiguity messages.
 541         -- Example:     f :: (forall a. Eq a => a -> a) -> Int
 542         --              f = error "urk"
 543         -- Here, tcSub tries to force (error "urk") to have the right type,
 544         -- thus:        f = \(x::forall a. Eq a => a->a) -> error "urk" (x t)
 545         -- where 't' is fresh ty var.  This leads directly to "ambiguous t".
 546         --
 547         -- NB: technically this changes the meaning of the default-default
 548         --     method slightly, because `seq` can see the lambdas.  Oh well.
 549     (_,_,tau1)    = tcSplitSigmaTy (idType sel_id)
 550     (_,_,tau2)    = tcSplitSigmaTy tau1
 551         -- Need two splits because the  selector can have a type like
 552         --      forall a. Foo a => forall b. Eq b => ...
 553     (arg_tys, _) = tcSplitFunTys tau2
 554     wild_pats    = [WildPatIn | ty <- arg_tys]
 555
 556 mkDefMethRhs origin clas inst_tys sel_id loc GenDefMeth
 557   =     -- A generic default method
 558         -- If the method is defined generically, we can only do the job if the
 559         -- instance declaration is for a single-parameter type class with
 560         -- a type constructor applied to type arguments in the instance decl
 561         --      (checkTc, so False provokes the error)
 562      ASSERT( isInstDecl origin )        -- We never get here from a class decl
 563
 564      checkTc (isJust maybe_tycon)
 565              (badGenericInstance sel_id (notSimple inst_tys))   `thenTc_`
 566      checkTc (isJust (tyConGenInfo tycon))
 567              (badGenericInstance sel_id (notGeneric tycon))                     `thenTc_`
 568
 569      ioToTc (dumpIfSet opt_PprStyle_Debug "Generic RHS" stuff)  `thenNF_Tc_`
 570      returnTc rhs
 571   where
 572     rhs = mkGenericRhs sel_id clas_tyvar tycon
 573
 574     stuff = vcat [ppr clas <+> ppr inst_tys,
 575                   nest 4 (ppr sel_id <+> equals <+> ppr rhs)]
 576
 577           -- The tycon is only used in the generic case, and in that
 578           -- case we require that the instance decl is for a single-parameter
 579           -- type class with type variable arguments:
 580           --    instance (...) => C (T a b)
 581     clas_tyvar    = head (classTyVars clas)
 582     Just tycon    = maybe_tycon
 583     maybe_tycon   = case inst_tys of
 584                         [ty] -> case tcSplitTyConApp_maybe ty of
 585                                   Just (tycon, arg_tys) | all tcIsTyVarTy arg_tys -> Just tycon
 586                                   other                                           -> Nothing
 587                         other -> Nothing
 588
 589 isInstDecl InstanceDeclOrigin = True
 590 isInstDecl ClassDeclOrigin    = False
 591 \end{code}
 592
 593
 594 \begin{code}
 595 -- The renamer just puts the selector ID as the binder in the method binding
 596 -- but we must use the method name; so we substitute it here.  Crude but simple.
 597 find_bind sel_name meth_name (FunMonoBind op_name fix matches loc)
 598     | op_name == sel_name = Just (FunMonoBind meth_name fix matches loc)
 599 find_bind sel_name meth_name (AndMonoBinds b1 b2)
 600     = find_bind sel_name meth_name b1 `seqMaybe` find_bind sel_name meth_name b2
 601 find_bind sel_name meth_name other  = Nothing   -- Default case
 602
 603  -- Find the prags for this method, and replace the
 604  -- selector name with the method name
 605 find_prags sel_name meth_name [] = []
 606 find_prags sel_name meth_name (SpecSig name ty loc : prags)
 607      | name == sel_name = SpecSig meth_name ty loc : find_prags sel_name meth_name prags
 608 find_prags sel_name meth_name (InlineSig sense name phase loc : prags)
 609    | name == sel_name = InlineSig sense meth_name phase loc : find_prags sel_name meth_name prags
 610 find_prags sel_name meth_name (prag:prags) = find_prags sel_name meth_name prags
 611 \end{code}
 612
 613
 614 Contexts and errors
 615 ~~~~~~~~~~~~~~~~~~~
 616 \begin{code}
 617 defltMethCtxt clas
 618   = ptext SLIT("When checking the default methods for class") <+> quotes (ppr clas)
 619
 620 methodCtxt sel_id
 621   = ptext SLIT("In the definition for method") <+> quotes (ppr sel_id)
 622
 623 badMethodErr clas op
 624   = hsep [ptext SLIT("Class"), quotes (ppr clas),
 625           ptext SLIT("does not have a method"), quotes (ppr op)]
 626
 627 omittedMethodWarn sel_id
 628   = ptext SLIT("No explicit method nor default method for") <+> quotes (ppr sel_id)
 629
 630 badGenericInstance sel_id because
 631   = sep [ptext SLIT("Can't derive generic code for") <+> quotes (ppr sel_id),
 632          because]
 633
 634 notSimple inst_tys
 635   = vcat [ptext SLIT("because the instance type(s)"),
 636           nest 2 (ppr inst_tys),
 637           ptext SLIT("is not a simple type of form (T a b c)")]
 638
 639 notGeneric tycon
 640   = vcat [ptext SLIT("because the instance type constructor") <+> quotes (ppr tycon) <+>
 641           ptext SLIT("was not compiled with -fgenerics")]
 642
 643 mixedGenericErr op
 644   = ptext SLIT("Can't mix generic and non-generic equations for class method") <+> quotes (ppr op)
 645 \end{code}