ghc/compiler/typecheck/TcClassDcl.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcClassDcl]{Typechecking class declarations}
   5
   6 \begin{code}
   7 module TcClassDcl ( tcClassDecl1, checkValidClass, tcClassDecls2,
   8                     tcMethodBind, badMethodErr
   9                   ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn            ( TyClDecl(..), Sig(..), MonoBinds(..),
  14                           HsExpr(..), HsLit(..),
  15                           mkSimpleMatch, andMonoBinds, andMonoBindList,
  16                           isClassOpSig, isPragSig,
  17                           getClassDeclSysNames, placeHolderType
  18                         )
  19 import BasicTypes       ( TopLevelFlag(..), RecFlag(..), StrictnessMark(..) )
  20 import RnHsSyn          ( RenamedTyClDecl,
  21                           RenamedClassOpSig, RenamedMonoBinds,
  22                           RenamedSig, maybeGenericMatch
  23                         )
  24 import TcHsSyn          ( TcMonoBinds )
  25
  26 import Inst             ( Inst, InstOrigin(..), LIE, emptyLIE, plusLIE, plusLIEs,
  27                           instToId, newDicts, newMethod )
  28 import TcEnv            ( RecTcEnv, TyThingDetails(..), tcAddImportedIdInfo,
  29                           tcLookupClass, tcExtendTyVarEnvForMeths, tcExtendGlobalTyVars,
  30                           tcExtendLocalValEnv, tcExtendTyVarEnv
  31                         )
  32 import TcBinds          ( tcBindWithSigs, tcSpecSigs )
  33 import TcMonoType       ( tcHsType, tcHsTheta, checkSigTyVars, sigCtxt, mkTcSig )
  34 import TcSimplify       ( tcSimplifyCheck, bindInstsOfLocalFuns )
  35 import TcMType          ( tcInstTyVars, checkValidTheta, checkValidType, SourceTyCtxt(..), UserTypeCtxt(..) )
  36 import TcType           ( Type, mkSigmaTy, mkTyVarTys, mkPredTys, mkClassPred,
  37                           tcIsTyVarTy, tcSplitTyConApp_maybe, tcSplitSigmaTy
  38                         )
  39 import TcMonad
  40 import Generics         ( mkGenericRhs, validGenericMethodType )
  41 import PrelInfo         ( nO_METHOD_BINDING_ERROR_ID )
  42 import Class            ( classTyVars, classBigSig, classTyCon, className,
  43                           Class, ClassOpItem, DefMeth (..) )
  44 import MkId             ( mkDictSelId, mkDataConId, mkDataConWrapId, mkDefaultMethodId )
  45 import DataCon          ( mkDataCon )
  46 import Id               ( idType, idName )
  47 import Module           ( Module )
  48 import Name             ( Name, NamedThing(..) )
  49 import NameEnv          ( NameEnv, lookupNameEnv, emptyNameEnv, unitNameEnv, plusNameEnv )
  50 import NameSet          ( emptyNameSet )
  51 import Outputable
  52 import Var              ( TyVar )
  53 import VarSet           ( mkVarSet, emptyVarSet )
  54 import CmdLineOpts
  55 import ErrUtils         ( dumpIfSet )
  56 import Util             ( count )
  57 import Maybes           ( seqMaybe, maybeToBool )
  58 \end{code}
  59
  60
  61
  62 Dictionary handling
  63 ~~~~~~~~~~~~~~~~~~~
  64 Every class implicitly declares a new data type, corresponding to dictionaries
  65 of that class. So, for example:
  66
  67         class (D a) => C a where
  68           op1 :: a -> a
  69           op2 :: forall b. Ord b => a -> b -> b
  70
  71 would implicitly declare
  72
  73         data CDict a = CDict (D a)
  74                              (a -> a)
  75                              (forall b. Ord b => a -> b -> b)
  76
  77 (We could use a record decl, but that means changing more of the existing apparatus.
  78 One step at at time!)
  79
  80 For classes with just one superclass+method, we use a newtype decl instead:
  81
  82         class C a where
  83           op :: forallb. a -> b -> b
  84
  85 generates
  86
  87         newtype CDict a = CDict (forall b. a -> b -> b)
  88
  89 Now DictTy in Type is just a form of type synomym:
  90         DictTy c t = TyConTy CDict `AppTy` t
  91
  92 Death to "ExpandingDicts".
  93
  94
  95 %************************************************************************
  96 %*                                                                      *
  97 \subsection{Type checking}
  98 %*                                                                      *
  99 %************************************************************************
 100
 101 \begin{code}
 102
 103 tcClassDecl1 :: RecTcEnv -> RenamedTyClDecl -> TcM (Name, TyThingDetails)
 104 tcClassDecl1 rec_env
 105              (ClassDecl {tcdCtxt = context, tcdName = class_name,
 106                          tcdTyVars = tyvar_names, tcdFDs = fundeps,
 107                          tcdSigs = class_sigs, tcdMeths = def_methods,
 108                          tcdSysNames = sys_names, tcdLoc = src_loc})
 109   =     -- LOOK THINGS UP IN THE ENVIRONMENT
 110     tcLookupClass class_name                            `thenTc` \ clas ->
 111     let
 112         tyvars   = classTyVars clas
 113         op_sigs  = filter isClassOpSig class_sigs
 114         op_names = [n | ClassOpSig n _ _ _ <- op_sigs]
 115         (_, datacon_name, datacon_wkr_name, sc_sel_names) = getClassDeclSysNames sys_names
 116     in
 117     tcExtendTyVarEnv tyvars                             $
 118
 119     checkDefaultBinds clas op_names def_methods   `thenTc` \ mb_dm_env ->
 120
 121         -- CHECK THE CONTEXT
 122         -- The renamer has already checked that the context mentions
 123         -- only the type variable of the class decl.
 124         -- Context is already kind-checked
 125     ASSERT( length context == length sc_sel_names )
 126     tcHsTheta context                                           `thenTc` \ sc_theta ->
 127
 128         -- CHECK THE CLASS SIGNATURES,
 129     mapTc (tcClassSig rec_env clas tyvars mb_dm_env) op_sigs    `thenTc` \ sig_stuff ->
 130
 131         -- MAKE THE CLASS DETAILS
 132     let
 133         (op_tys, op_items) = unzip sig_stuff
 134         sc_tys             = mkPredTys sc_theta
 135         dict_component_tys = sc_tys ++ op_tys
 136         sc_sel_ids         = [mkDictSelId sc_name clas | sc_name <- sc_sel_names]
 137
 138         dict_con = mkDataCon datacon_name
 139                              [NotMarkedStrict | _ <- dict_component_tys]
 140                              [{- No labelled fields -}]
 141                              tyvars
 142                              [{-No context-}]
 143                              [{-No existential tyvars-}] [{-Or context-}]
 144                              dict_component_tys
 145                              (classTyCon clas)
 146                              dict_con_id dict_wrap_id
 147
 148         dict_con_id  = mkDataConId datacon_wkr_name dict_con
 149         dict_wrap_id = mkDataConWrapId dict_con
 150     in
 151     returnTc (class_name, ClassDetails sc_theta sc_sel_ids op_items dict_con)
 152 \end{code}
 153
 154 \begin{code}
 155 checkDefaultBinds :: Class -> [Name] -> Maybe RenamedMonoBinds
 156                   -> TcM (Maybe (NameEnv Bool))
 157         -- The returned environment says
 158         --      x not in env => no default method
 159         --      x -> True    => generic default method
 160         --      x -> False   => polymorphic default method
 161
 162   -- Check default bindings
 163   --    a) must be for a class op for this class
 164   --    b) must be all generic or all non-generic
 165   -- and return a mapping from class-op to DefMeth info
 166
 167   -- But do all this only for source binds
 168
 169 checkDefaultBinds clas ops Nothing
 170   = returnTc Nothing
 171
 172 checkDefaultBinds clas ops (Just mbs)
 173   = go mbs      `thenTc` \ dm_env ->
 174     returnTc (Just dm_env)
 175   where
 176     go EmptyMonoBinds = returnTc emptyNameEnv
 177
 178     go (AndMonoBinds b1 b2)
 179       = go b1   `thenTc` \ dm_info1 ->
 180         go b2   `thenTc` \ dm_info2 ->
 181         returnTc (dm_info1 `plusNameEnv` dm_info2)
 182
 183     go (FunMonoBind op _ matches loc)
 184       = tcAddSrcLoc loc                                 $
 185
 186         -- Check that the op is from this class
 187         checkTc (op `elem` ops) (badMethodErr clas op)          `thenTc_`
 188
 189         -- Check that all the defns ar generic, or none are
 190         checkTc (all_generic || none_generic) (mixedGenericErr op)      `thenTc_`
 191
 192         returnTc (unitNameEnv op all_generic)
 193       where
 194         n_generic    = count (maybeToBool . maybeGenericMatch) matches
 195         none_generic = n_generic == 0
 196         all_generic  = n_generic == length matches
 197 \end{code}
 198
 199
 200 \begin{code}
 201 tcClassSig :: RecTcEnv                  -- Knot tying only!
 202            -> Class                     -- ...ditto...
 203            -> [TyVar]                   -- The class type variable, used for error check only
 204            -> Maybe (NameEnv Bool)      -- Info about default methods
 205            -> RenamedClassOpSig
 206            -> TcM (Type,                -- Type of the method
 207                      ClassOpItem)       -- Selector Id, default-method Id, True if explicit default binding
 208
 209 -- This warrants an explanation: we need to separate generic
 210 -- default methods and default methods later on in the compiler
 211 -- so we distinguish them in checkDefaultBinds, and pass this knowledge in the
 212 -- Class.DefMeth data structure.
 213
 214 tcClassSig unf_env clas clas_tyvars maybe_dm_env
 215            (ClassOpSig op_name sig_dm op_ty src_loc)
 216   = tcAddSrcLoc src_loc $
 217
 218         -- Check the type signature.  NB that the envt *already has*
 219         -- bindings for the type variables; see comments in TcTyAndClassDcls.
 220     tcHsType op_ty                      `thenTc` \ local_ty ->
 221
 222     let
 223         theta = [mkClassPred clas (mkTyVarTys clas_tyvars)]
 224         global_ty = mkSigmaTy clas_tyvars theta local_ty
 225           -- The default method's type should really come from the
 226           -- iface file, since it could be usage-generalised, but this
 227           -- requires altering the mess of knots in TcModule and I'm
 228           -- too scared to do that.  Instead, I have disabled generalisation
 229           -- of types of default methods (and dict funs) by annotating them
 230           -- TyGenNever (in MkId).  Ugh!  KSW 1999-09.
 231
 232         -- Build the selector id and default method id
 233         sel_id = mkDictSelId op_name clas
 234         dm_id  = mkDefaultMethodId dm_name global_ty
 235         DefMeth dm_name = sig_dm
 236
 237         dm_info = case maybe_dm_env of
 238                     Nothing     -> iface_dm_info
 239                     Just dm_env -> mk_src_dm_info dm_env
 240
 241         iface_dm_info = case sig_dm of
 242                           NoDefMeth       -> NoDefMeth
 243                           GenDefMeth      -> GenDefMeth
 244                           DefMeth dm_name -> DefMeth (tcAddImportedIdInfo unf_env dm_id)
 245
 246         mk_src_dm_info dm_env = case lookupNameEnv dm_env op_name of
 247                                    Nothing    -> NoDefMeth
 248                                    Just True  -> GenDefMeth
 249                                    Just False -> DefMeth dm_id
 250     in
 251     returnTc (local_ty, (sel_id, dm_info))
 252 \end{code}
 253
 254 checkValidClass is called once the mutually-recursive knot has been
 255 tied, so we can look at things freely.
 256
 257 \begin{code}
 258 checkValidClass :: Class -> TcM ()
 259 checkValidClass cls
 260   =     -- CHECK ARITY 1 FOR HASKELL 1.4
 261     doptsTc Opt_GlasgowExts                             `thenTc` \ gla_exts ->
 262
 263         -- Check that the class is unary, unless GlaExs
 264     checkTc (gla_exts || unary)
 265             (classArityErr cls)                         `thenTc_`
 266
 267         -- Check the super-classes
 268     checkValidTheta (ClassSCCtxt (className cls)) theta `thenTc_`
 269
 270         -- Check the class operations
 271     mapTc_ check_op op_stuff            `thenTc_`
 272
 273         -- Check that if the class has generic methods, then the
 274         -- class has only one parameter.  We can't do generic
 275         -- multi-parameter type classes!
 276     checkTc (unary || no_generics) (genericMultiParamErr cls)
 277
 278   where
 279     (tyvars, theta, sel_ids, op_stuff) = classBigSig cls
 280     unary       = length tyvars == 1
 281     no_generics = null [() | (_, GenDefMeth) <- op_stuff]
 282
 283     check_op (sel_id, dm)
 284         = checkValidTheta SigmaCtxt (tail theta)        `thenTc_`
 285                 -- The 'tail' removes the initial (C a) from the
 286                 -- class itself, leaving just the method type
 287
 288           checkValidType (FunSigCtxt op_name) tau       `thenTc_`
 289
 290                 -- Check that for a generic method, the type of
 291                 -- the method is sufficiently simple
 292           checkTc (dm /= GenDefMeth || validGenericMethodType op_ty)
 293                   (badGenericMethodType op_name op_ty)
 294         where
 295           op_name = idName sel_id
 296           op_ty   = idType sel_id
 297           (_,theta,tau) = tcSplitSigmaTy op_ty
 298 \end{code}
 299
 300
 301 %************************************************************************
 302 %*                                                                      *
 303 \subsection[Default methods]{Default methods}
 304 %*                                                                      *
 305 %************************************************************************
 306
 307 The default methods for a class are each passed a dictionary for the
 308 class, so that they get access to the other methods at the same type.
 309 So, given the class decl
 310 \begin{verbatim}
 311 class Foo a where
 312         op1 :: a -> Bool
 313         op2 :: Ord b => a -> b -> b -> b
 314
 315         op1 x = True
 316         op2 x y z = if (op1 x) && (y < z) then y else z
 317 \end{verbatim}
 318 we get the default methods:
 319 \begin{verbatim}
 320 defm.Foo.op1 :: forall a. Foo a => a -> Bool
 321 defm.Foo.op1 = /\a -> \dfoo -> \x -> True
 322
 323 defm.Foo.op2 :: forall a. Foo a => forall b. Ord b => a -> b -> b -> b
 324 defm.Foo.op2 = /\ a -> \ dfoo -> /\ b -> \ dord -> \x y z ->
 325                   if (op1 a dfoo x) && (< b dord y z) then y else z
 326 \end{verbatim}
 327
 328 When we come across an instance decl, we may need to use the default
 329 methods:
 330 \begin{verbatim}
 331 instance Foo Int where {}
 332 \end{verbatim}
 333 gives
 334 \begin{verbatim}
 335 const.Foo.Int.op1 :: Int -> Bool
 336 const.Foo.Int.op1 = defm.Foo.op1 Int dfun.Foo.Int
 337
 338 const.Foo.Int.op2 :: forall b. Ord b => Int -> b -> b -> b
 339 const.Foo.Int.op2 = defm.Foo.op2 Int dfun.Foo.Int
 340
 341 dfun.Foo.Int :: Foo Int
 342 dfun.Foo.Int = (const.Foo.Int.op1, const.Foo.Int.op2)
 343 \end{verbatim}
 344 Notice that, as with method selectors above, we assume that dictionary
 345 application is curried, so there's no need to mention the Ord dictionary
 346 in const.Foo.Int.op2 (or the type variable).
 347
 348 \begin{verbatim}
 349 instance Foo a => Foo [a] where {}
 350
 351 dfun.Foo.List :: forall a. Foo a -> Foo [a]
 352 dfun.Foo.List
 353   = /\ a -> \ dfoo_a ->
 354     let rec
 355         op1 = defm.Foo.op1 [a] dfoo_list
 356         op2 = defm.Foo.op2 [a] dfoo_list
 357         dfoo_list = (op1, op2)
 358     in
 359         dfoo_list
 360 \end{verbatim}
 361
 362 The function @tcClassDecls2@ just arranges to apply @tcClassDecl2@ to
 363 each local class decl.
 364
 365 \begin{code}
 366 tcClassDecls2 :: Module -> [RenamedTyClDecl] -> NF_TcM (LIE, TcMonoBinds)
 367
 368 tcClassDecls2 this_mod decls
 369   = foldr combine
 370           (returnNF_Tc (emptyLIE, EmptyMonoBinds))
 371           [tcClassDecl2 cls_decl | cls_decl@(ClassDecl {tcdMeths = Just _}) <- decls]
 372                 -- The 'Just' picks out source ClassDecls
 373   where
 374     combine tc1 tc2 = tc1 `thenNF_Tc` \ (lie1, binds1) ->
 375                       tc2 `thenNF_Tc` \ (lie2, binds2) ->
 376                       returnNF_Tc (lie1 `plusLIE` lie2,
 377                                    binds1 `AndMonoBinds` binds2)
 378 \end{code}
 379
 380 @tcClassDecl2@ generates bindings for polymorphic default methods
 381 (generic default methods have by now turned into instance declarations)
 382
 383 \begin{code}
 384 tcClassDecl2 :: RenamedTyClDecl         -- The class declaration
 385              -> NF_TcM (LIE, TcMonoBinds)
 386
 387 tcClassDecl2 (ClassDecl {tcdName = class_name, tcdSigs = sigs,
 388                          tcdMeths = Just default_binds, tcdLoc = src_loc})
 389   =     -- The 'Just' picks out source ClassDecls
 390     recoverNF_Tc (returnNF_Tc (emptyLIE, EmptyMonoBinds)) $
 391     tcAddSrcLoc src_loc                                   $
 392     tcLookupClass class_name                              `thenNF_Tc` \ clas ->
 393
 394         -- We make a separate binding for each default method.
 395         -- At one time I used a single AbsBinds for all of them, thus
 396         -- AbsBind [d] [dm1, dm2, dm3] { dm1 = ...; dm2 = ...; dm3 = ... }
 397         -- But that desugars into
 398         --      ds = \d -> (..., ..., ...)
 399         --      dm1 = \d -> case ds d of (a,b,c) -> a
 400         -- And since ds is big, it doesn't get inlined, so we don't get good
 401         -- default methods.  Better to make separate AbsBinds for each
 402     let
 403         (tyvars, _, _, op_items) = classBigSig clas
 404         prags                    = filter isPragSig sigs
 405         tc_dm                    = tcDefMeth clas tyvars default_binds prags
 406     in
 407     mapAndUnzipTc tc_dm op_items        `thenTc` \ (defm_binds, const_lies) ->
 408
 409     returnTc (plusLIEs const_lies, andMonoBindList defm_binds)
 410
 411
 412 tcDefMeth clas tyvars binds_in prags (_, NoDefMeth)  = returnTc (EmptyMonoBinds, emptyLIE)
 413 tcDefMeth clas tyvars binds_in prags (_, GenDefMeth) = returnTc (EmptyMonoBinds, emptyLIE)
 414         -- Generate code for polymorphic default methods only
 415         -- (Generic default methods have turned into instance decls by now.)
 416         -- This is incompatible with Hugs, which expects a polymorphic
 417         -- default method for every class op, regardless of whether or not
 418         -- the programmer supplied an explicit default decl for the class.
 419         -- (If necessary we can fix that, but we don't have a convenient Id to hand.)
 420
 421 tcDefMeth clas tyvars binds_in prags op_item@(_, DefMeth dm_id)
 422   = tcInstTyVars tyvars                 `thenNF_Tc` \ (clas_tyvars, inst_tys, _) ->
 423     let
 424         theta = [(mkClassPred clas inst_tys)]
 425     in
 426     newDicts origin theta               `thenNF_Tc` \ [this_dict] ->
 427
 428     tcExtendTyVarEnvForMeths tyvars clas_tyvars (
 429         tcMethodBind clas origin clas_tyvars inst_tys theta
 430                      binds_in prags False op_item
 431     )                                   `thenTc` \ (defm_bind, insts_needed, local_dm_inst) ->
 432
 433     tcAddErrCtxt (defltMethCtxt clas) $
 434
 435         -- Check the context
 436     tcSimplifyCheck
 437         (ptext SLIT("class") <+> ppr clas)
 438         clas_tyvars
 439         [this_dict]
 440         insts_needed                            `thenTc` \ (const_lie, dict_binds) ->
 441
 442         -- Simplification can do unification
 443     checkSigTyVars clas_tyvars emptyVarSet      `thenTc` \ clas_tyvars' ->
 444
 445     let
 446         full_bind = AbsBinds
 447                     clas_tyvars'
 448                     [instToId this_dict]
 449                     [(clas_tyvars', dm_id, instToId local_dm_inst)]
 450                     emptyNameSet        -- No inlines (yet)
 451                     (dict_binds `andMonoBinds` defm_bind)
 452     in
 453     returnTc (full_bind, const_lie)
 454   where
 455     origin = ClassDeclOrigin
 456 \end{code}
 457
 458
 459
 460 %************************************************************************
 461 %*                                                                      *
 462 \subsection{Typechecking a method}
 463 %*                                                                      *
 464 %************************************************************************
 465
 466 @tcMethodBind@ is used to type-check both default-method and
 467 instance-decl method declarations.  We must type-check methods one at a
 468 time, because their signatures may have different contexts and
 469 tyvar sets.
 470
 471 \begin{code}
 472 tcMethodBind
 473         :: Class
 474         -> InstOrigin
 475         -> [TcTyVar]            -- Instantiated type variables for the
 476                                 --  enclosing class/instance decl.
 477                                 --  They'll be signature tyvars, and we
 478                                 --  want to check that they don't get bound
 479         -> [TcType]             -- Instance types
 480         -> TcThetaType          -- Available theta; this could be used to check
 481                                 --  the method signature, but actually that's done by
 482                                 --  the caller;  here, it's just used for the error message
 483         -> RenamedMonoBinds     -- Method binding (pick the right one from in here)
 484         -> [RenamedSig]         -- Pramgas (just for this one)
 485         -> Bool                 -- True <=> This method is from an instance declaration
 486         -> ClassOpItem          -- The method selector and default-method Id
 487         -> TcM (TcMonoBinds, LIE, Inst)
 488
 489 tcMethodBind clas origin inst_tyvars inst_tys inst_theta
 490              meth_binds prags is_inst_decl (sel_id, dm_info)
 491   = tcGetSrcLoc                         `thenNF_Tc` \ loc ->
 492     newMethod origin sel_id inst_tys    `thenNF_Tc` \ meth ->
 493     let
 494         meth_id    = instToId meth
 495         meth_name  = idName meth_id
 496         sig_msg    = ptext SLIT("When checking the expected type for class method") <+> ppr sel_id
 497         meth_prags = find_prags (idName sel_id) meth_name prags
 498     in
 499     mkTcSig meth_id loc                 `thenNF_Tc` \ sig_info ->
 500
 501         -- Figure out what method binding to use
 502         -- If the user suppplied one, use it, else construct a default one
 503     (case find_bind (idName sel_id) meth_name meth_binds of
 504         Just user_bind -> returnTc user_bind
 505         Nothing        -> mkDefMethRhs is_inst_decl clas inst_tys sel_id loc dm_info    `thenTc` \ rhs ->
 506                           returnTc (FunMonoBind meth_name False -- Not infix decl
 507                                                 [mkSimpleMatch [] rhs placeHolderType loc] loc)
 508     )                                                           `thenTc` \ meth_bind ->
 509      -- Check the bindings; first add inst_tyvars to the envt
 510      -- so that we don't quantify over them in nested places
 511      -- The *caller* put the class/inst decl tyvars into the envt
 512      tcExtendGlobalTyVars (mkVarSet inst_tyvars)
 513                     (tcAddErrCtxt (methodCtxt sel_id)           $
 514                      tcBindWithSigs NotTopLevel meth_bind
 515                                     [sig_info] meth_prags NonRecursive
 516                     )                                           `thenTc` \ (binds, insts, _) ->
 517
 518      tcExtendLocalValEnv [(meth_name, meth_id)]
 519                          (tcSpecSigs meth_prags)                `thenTc` \ (prag_binds1, prag_lie) ->
 520
 521      -- The prag_lie for a SPECIALISE pragma will mention the function
 522      -- itself, so we have to simplify them away right now lest they float
 523      -- outwards!
 524      bindInstsOfLocalFuns prag_lie [meth_id]    `thenTc` \ (prag_lie', prag_binds2) ->
 525
 526      -- Now check that the instance type variables
 527      -- (or, in the case of a class decl, the class tyvars)
 528      -- have not been unified with anything in the environment
 529      --
 530      -- We do this for each method independently to localise error messages
 531      -- ...and this is why the call to tcExtendGlobalTyVars must be here
 532      --    rather than in the caller
 533      tcAddErrCtxtM (sigCtxt sig_msg inst_tyvars inst_theta (idType meth_id))    $
 534      checkSigTyVars inst_tyvars emptyVarSet                                     `thenTc_`
 535
 536      returnTc (binds `AndMonoBinds` prag_binds1 `AndMonoBinds` prag_binds2,
 537                insts `plusLIE` prag_lie',
 538                meth)
 539
 540      -- The user didn't supply a method binding,
 541      -- so we have to make up a default binding
 542      -- The RHS of a default method depends on the default-method info
 543 mkDefMethRhs is_inst_decl clas inst_tys sel_id loc (DefMeth dm_id)
 544   =  -- An polymorphic default method
 545     returnTc (HsVar (idName dm_id))
 546
 547 mkDefMethRhs is_inst_decl clas inst_tys sel_id loc NoDefMeth
 548   =     -- No default method
 549         -- Warn only if -fwarn-missing-methods
 550     doptsTc Opt_WarnMissingMethods              `thenNF_Tc` \ warn ->
 551     warnTc (is_inst_decl && warn)
 552            (omittedMethodWarn sel_id)           `thenNF_Tc_`
 553     returnTc error_rhs
 554   where
 555     error_rhs = HsApp (HsVar (getName nO_METHOD_BINDING_ERROR_ID))
 556                           (HsLit (HsString (_PK_ error_msg)))
 557     error_msg = showSDoc (hcat [ppr loc, text "|", ppr sel_id ])
 558
 559
 560 mkDefMethRhs is_inst_decl clas inst_tys sel_id loc GenDefMeth
 561   =     -- A generic default method
 562         -- If the method is defined generically, we can only do the job if the
 563         -- instance declaration is for a single-parameter type class with
 564         -- a type constructor applied to type arguments in the instance decl
 565         --      (checkTc, so False provokes the error)
 566      checkTc (not is_inst_decl || simple_inst)
 567              (badGenericInstance sel_id)                        `thenTc_`
 568
 569      ioToTc (dumpIfSet opt_PprStyle_Debug "Generic RHS" stuff)  `thenNF_Tc_`
 570      returnTc rhs
 571   where
 572     rhs = mkGenericRhs sel_id clas_tyvar tycon
 573
 574     stuff = vcat [ppr clas <+> ppr inst_tys,
 575                   nest 4 (ppr sel_id <+> equals <+> ppr rhs)]
 576
 577           -- The tycon is only used in the generic case, and in that
 578           -- case we require that the instance decl is for a single-parameter
 579           -- type class with type variable arguments:
 580           --    instance (...) => C (T a b)
 581     simple_inst   = maybeToBool maybe_tycon
 582     clas_tyvar    = head (classTyVars clas)
 583     Just tycon    = maybe_tycon
 584     maybe_tycon   = case inst_tys of
 585                         [ty] -> case tcSplitTyConApp_maybe ty of
 586                                   Just (tycon, arg_tys) | all tcIsTyVarTy arg_tys -> Just tycon
 587                                   other                                           -> Nothing
 588                         other -> Nothing
 589 \end{code}
 590
 591
 592 \begin{code}
 593 -- The renamer just puts the selector ID as the binder in the method binding
 594 -- but we must use the method name; so we substitute it here.  Crude but simple.
 595 find_bind sel_name meth_name (FunMonoBind op_name fix matches loc)
 596     | op_name == sel_name = Just (FunMonoBind meth_name fix matches loc)
 597 find_bind sel_name meth_name (AndMonoBinds b1 b2)
 598     = find_bind sel_name meth_name b1 `seqMaybe` find_bind sel_name meth_name b2
 599 find_bind sel_name meth_name other  = Nothing   -- Default case
 600
 601  -- Find the prags for this method, and replace the
 602  -- selector name with the method name
 603 find_prags sel_name meth_name [] = []
 604 find_prags sel_name meth_name (SpecSig name ty loc : prags)
 605      | name == sel_name = SpecSig meth_name ty loc : find_prags sel_name meth_name prags
 606 find_prags sel_name meth_name (InlineSig name phase loc : prags)
 607    | name == sel_name = InlineSig meth_name phase loc : find_prags sel_name meth_name prags
 608 find_prags sel_name meth_name (NoInlineSig name phase loc : prags)
 609    | name == sel_name = NoInlineSig meth_name phase loc : find_prags sel_name meth_name prags
 610 find_prags sel_name meth_name (prag:prags) = find_prags sel_name meth_name prags
 611 \end{code}
 612
 613
 614 Contexts and errors
 615 ~~~~~~~~~~~~~~~~~~~
 616 \begin{code}
 617 classArityErr cls
 618   = ptext SLIT("Too many parameters for class") <+> quotes (ppr cls)
 619
 620 defltMethCtxt clas
 621   = ptext SLIT("When checking the default methods for class") <+> quotes (ppr clas)
 622
 623 methodCtxt sel_id
 624   = ptext SLIT("In the definition for method") <+> quotes (ppr sel_id)
 625
 626 badMethodErr clas op
 627   = hsep [ptext SLIT("Class"), quotes (ppr clas),
 628           ptext SLIT("does not have a method"), quotes (ppr op)]
 629
 630 omittedMethodWarn sel_id
 631   = ptext SLIT("No explicit method nor default method for") <+> quotes (ppr sel_id)
 632
 633 badGenericMethodType op op_ty
 634   = hang (ptext SLIT("Generic method type is too complex"))
 635        4 (vcat [ppr op <+> dcolon <+> ppr op_ty,
 636                 ptext SLIT("You can only use type variables, arrows, and tuples")])
 637
 638 badGenericInstance sel_id
 639   = sep [ptext SLIT("Can't derive generic code for") <+> quotes (ppr sel_id),
 640          ptext SLIT("because the instance declaration is not for a simple type (T a b c)"),
 641          ptext SLIT("(where T is a derivable type constructor)")]
 642
 643 mixedGenericErr op
 644   = ptext SLIT("Can't mix generic and non-generic equations for class method") <+> quotes (ppr op)
 645
 646 genericMultiParamErr clas
 647   = ptext SLIT("The multi-parameter class") <+> quotes (ppr clas) <+>
 648     ptext SLIT("cannot have generic methods")
 649 \end{code}