ghc/compiler/typecheck/TcClassDcl.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcClassDcl]{Typechecking class declarations}
   5
   6 \begin{code}
   7 module TcClassDcl ( kcClassDecl, tcClassDecl1, tcClassDecls2, mkImplicitClassBinds,
   8                     tcMethodBind, checkFromThisClass
   9                   ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn            ( HsDecl(..), TyClDecl(..), Sig(..), MonoBinds(..),
  14                           InPat(..), HsBinds(..), GRHSs(..),
  15                           HsExpr(..), HsLit(..), HsType(..), HsPred(..),
  16                           mkSimpleMatch,
  17                           andMonoBinds, andMonoBindList, getTyVarName,
  18                           isClassDecl, isClassOpSig, isPragSig, collectMonoBinders
  19                         )
  20 import HsPragmas        ( ClassPragmas(..) )
  21 import BasicTypes       ( NewOrData(..), TopLevelFlag(..), RecFlag(..) )
  22 import RnHsSyn          ( RenamedTyClDecl, RenamedClassPragmas,
  23                           RenamedClassOpSig, RenamedMonoBinds,
  24                           RenamedContext, RenamedHsDecl, RenamedSig
  25                         )
  26 import TcHsSyn          ( TcMonoBinds, idsToMonoBinds )
  27
  28 import Inst             ( Inst, InstOrigin(..), LIE, emptyLIE, plusLIE, plusLIEs, newDicts, newMethod )
  29 import TcEnv            ( TcId, ValueEnv, TcTyThing(..), tcAddImportedIdInfo,
  30                           tcLookupTy, tcExtendTyVarEnvForMeths, tcExtendGlobalTyVars,
  31                           tcExtendLocalValEnv
  32                         )
  33 import TcBinds          ( tcBindWithSigs, tcSpecSigs )
  34 import TcTyDecls        ( mkNewTyConRep )
  35 import TcUnify          ( unifyKinds )
  36 import TcMonad
  37 import TcMonoType       ( kcHsType, tcHsTopType, tcExtendTopTyVarScope,
  38                           tcContext, checkSigTyVars, sigCtxt, mkTcSig
  39                         )
  40 import TcSimplify       ( tcSimplifyAndCheck, bindInstsOfLocalFuns )
  41 import TcType           ( TcType, TcTyVar, tcInstTyVars, zonkTcTyVarBndr, tcGetTyVar )
  42 import TcInstUtil       ( classDataCon )
  43 import PrelInfo         ( nO_METHOD_BINDING_ERROR_ID )
  44 import FieldLabel       ( firstFieldLabelTag )
  45 import Bag              ( unionManyBags, bagToList )
  46 import Class            ( mkClass, classBigSig, classSelIds, Class, ClassOpItem )
  47 import CmdLineOpts      ( opt_GlasgowExts, opt_WarnMissingMethods )
  48 import MkId             ( mkDictSelId, mkDataConId, mkDataConWrapId, mkDefaultMethodId )
  49 import DataCon          ( mkDataCon, dataConId, dataConWrapId, notMarkedStrict )
  50 import Id               ( Id, setInlinePragma, idUnfolding, idType, idName )
  51 import CoreUnfold       ( unfoldingTemplate )
  52 import IdInfo
  53 import Name             ( Name, nameOccName, isLocallyDefined, NamedThing(..) )
  54 import NameSet          ( emptyNameSet )
  55 import Outputable
  56 import Type             ( Type, ThetaType, ClassContext,
  57                           mkFunTy, mkTyVarTy, mkTyVarTys, mkDictTy, mkDictTys,
  58                           mkSigmaTy, mkForAllTys, mkClassPred, classesOfPreds,
  59                           boxedTypeKind, mkArrowKind
  60                         )
  61 import Var              ( tyVarKind, TyVar )
  62 import VarSet           ( mkVarSet, emptyVarSet )
  63 import TyCon            ( AlgTyConFlavour(..), mkClassTyCon )
  64 import Unique           ( Unique, Uniquable(..) )
  65 import Util
  66 import Maybes           ( seqMaybe )
  67 import FiniteMap        ( lookupWithDefaultFM )
  68 \end{code}
  69
  70
  71
  72 Dictionary handling
  73 ~~~~~~~~~~~~~~~~~~~
  74 Every class implicitly declares a new data type, corresponding to dictionaries
  75 of that class. So, for example:
  76
  77         class (D a) => C a where
  78           op1 :: a -> a
  79           op2 :: forall b. Ord b => a -> b -> b
  80
  81 would implicitly declare
  82
  83         data CDict a = CDict (D a)
  84                              (a -> a)
  85                              (forall b. Ord b => a -> b -> b)
  86
  87 (We could use a record decl, but that means changing more of the existing apparatus.
  88 One step at at time!)
  89
  90 For classes with just one superclass+method, we use a newtype decl instead:
  91
  92         class C a where
  93           op :: forallb. a -> b -> b
  94
  95 generates
  96
  97         newtype CDict a = CDict (forall b. a -> b -> b)
  98
  99 Now DictTy in Type is just a form of type synomym:
 100         DictTy c t = TyConTy CDict `AppTy` t
 101
 102 Death to "ExpandingDicts".
 103
 104
 105 %************************************************************************
 106 %*                                                                      *
 107 \subsection{Kind checking}
 108 %*                                                                      *
 109 %************************************************************************
 110
 111 \begin{code}
 112 kcClassDecl (ClassDecl  context class_name
 113                         tyvar_names fundeps class_sigs def_methods pragmas
 114                         _ _ _ _ src_loc)
 115   =         -- CHECK ARITY 1 FOR HASKELL 1.4
 116     checkTc (opt_GlasgowExts || length tyvar_names == 1)
 117             (classArityErr class_name)          `thenTc_`
 118
 119         -- Get the (mutable) class kind
 120     tcLookupTy class_name                       `thenNF_Tc` \ (kind, _) ->
 121
 122         -- Make suitable tyvars and do kind checking
 123         -- The net effect is to mutate the class kind
 124     tcExtendTopTyVarScope kind tyvar_names      $ \ _ _ ->
 125     tcContext context                           `thenTc_`
 126     mapTc kc_sig the_class_sigs                 `thenTc_`
 127
 128     returnTc ()
 129   where
 130     the_class_sigs = filter isClassOpSig class_sigs
 131
 132     kc_sig (ClassOpSig _ _ _ op_ty loc) = tcAddSrcLoc loc (kcHsType op_ty)
 133 \end{code}
 134
 135
 136 %************************************************************************
 137 %*                                                                      *
 138 \subsection{Type checking}
 139 %*                                                                      *
 140 %************************************************************************
 141
 142 \begin{code}
 143 tcClassDecl1 rec_env rec_inst_mapper rec_vrcs
 144              (ClassDecl context class_name
 145                         tyvar_names fundeps class_sigs def_methods pragmas
 146                         tycon_name datacon_name datacon_wkr_name sc_sel_names src_loc)
 147   =     -- LOOK THINGS UP IN THE ENVIRONMENT
 148     tcLookupTy class_name                               `thenTc` \ (class_kind, AClass rec_class arity) ->
 149     tcExtendTopTyVarScope class_kind tyvar_names        $ \ tyvars _ ->
 150         -- The class kind is by now immutable
 151
 152         -- CHECK THE CONTEXT
 153 --  traceTc (text "tcClassCtxt" <+> ppr class_name)     `thenTc_`
 154     tcClassContext class_name rec_class tyvars context sc_sel_names
 155                                                 `thenTc` \ (sc_theta, sc_tys, sc_sel_ids) ->
 156 --  traceTc (text "tcClassCtxt done" <+> ppr class_name)        `thenTc_`
 157
 158         -- CHECK THE FUNCTIONAL DEPENDENCIES,
 159     tcFundeps fundeps                           `thenTc` \ fds ->
 160
 161         -- CHECK THE CLASS SIGNATURES,
 162     mapTc (tcClassSig rec_env rec_class tyvars)
 163           (filter isClassOpSig class_sigs)
 164                                                 `thenTc` \ sig_stuff ->
 165
 166         -- MAKE THE CLASS OBJECT ITSELF
 167     let
 168         (op_tys, op_items) = unzip sig_stuff
 169         rec_class_inst_env = rec_inst_mapper rec_class
 170         clas = mkClass class_name tyvars fds
 171                        sc_theta sc_sel_ids op_items
 172                        tycon
 173                        rec_class_inst_env
 174
 175         dict_component_tys = sc_tys ++ op_tys
 176         new_or_data = case dict_component_tys of
 177                         [_]   -> NewTyCon (mkNewTyConRep tycon)
 178                         other -> DataTyCon
 179
 180         dict_con = mkDataCon datacon_name
 181                            [notMarkedStrict | _ <- dict_component_tys]
 182                            [{- No labelled fields -}]
 183                            tyvars
 184                            [{-No context-}]
 185                            [{-No existential tyvars-}] [{-Or context-}]
 186                            dict_component_tys
 187                            tycon dict_con_id dict_wrap_id
 188
 189         dict_con_id  = mkDataConId datacon_wkr_name dict_con
 190         dict_wrap_id = mkDataConWrapId dict_con
 191
 192         argvrcs = lookupWithDefaultFM rec_vrcs (pprPanic "tcClassDecl1: argvrcs:" $
 193                                                          ppr tycon_name)
 194                                       tycon_name
 195
 196         tycon = mkClassTyCon tycon_name
 197                              class_kind
 198                              tyvars
 199                              argvrcs
 200                              dict_con           -- Constructors
 201                              clas               -- Yes!  It's a dictionary
 202                              new_or_data
 203     in
 204     returnTc (class_name, AClass clas arity)
 205 \end{code}
 206
 207 \begin{code}
 208 tcFundeps = mapTc tc_fundep
 209 tc_fundep (us, vs) =
 210     mapTc tc_fd_tyvar us        `thenTc` \ us' ->
 211     mapTc tc_fd_tyvar vs        `thenTc` \ vs' ->
 212     returnTc (us', vs')
 213 tc_fd_tyvar v =
 214     tcLookupTy v         `thenTc` \(_, ATyVar tv) ->
 215     returnTc tv
 216 \end{code}
 217
 218 \begin{code}
 219 tcClassContext :: Name -> Class -> [TyVar]
 220                -> RenamedContext        -- class context
 221                -> [Name]                -- Names for superclass selectors
 222                -> TcM s (ClassContext,  -- the superclass context
 223                          [Type],        -- types of the superclass dictionaries
 224                          [Id])          -- superclass selector Ids
 225
 226 tcClassContext class_name rec_class rec_tyvars context sc_sel_names
 227   =     -- Check the context.
 228         -- The renamer has already checked that the context mentions
 229         -- only the type variable of the class decl.
 230
 231         -- For std Haskell check that the context constrains only tyvars
 232     (if opt_GlasgowExts then
 233         returnTc []
 234      else
 235         mapTc check_constraint context
 236     )                                   `thenTc_`
 237
 238     tcContext context                   `thenTc` \ sc_theta ->
 239
 240     let
 241        sc_theta' = classesOfPreds sc_theta
 242        sc_tys = mkDictTys sc_theta'
 243        sc_sel_ids = [mkDictSelId sc_name rec_class | sc_name <- sc_sel_names]
 244     in
 245         -- Done
 246     returnTc (sc_theta', sc_tys, sc_sel_ids)
 247
 248   where
 249     check_constraint sc@(HsPClass c tys) = checkTc (all is_tyvar tys)
 250                                                    (superClassErr class_name sc)
 251
 252     is_tyvar (HsTyVar _) = True
 253     is_tyvar other       = False
 254
 255
 256 tcClassSig :: ValueEnv          -- Knot tying only!
 257            -> Class                     -- ...ditto...
 258            -> [TyVar]                   -- The class type variable, used for error check only
 259            -> RenamedClassOpSig
 260            -> TcM s (Type,              -- Type of the method
 261                      ClassOpItem)       -- Selector Id, default-method Id, True if explicit default binding
 262
 263
 264 tcClassSig rec_env rec_clas rec_clas_tyvars
 265            (ClassOpSig op_name dm_name explicit_dm
 266                        op_ty src_loc)
 267   = tcAddSrcLoc src_loc $
 268
 269         -- Check the type signature.  NB that the envt *already has*
 270         -- bindings for the type variables; see comments in TcTyAndClassDcls.
 271
 272     -- NB: Renamer checks that the class type variable is mentioned in local_ty,
 273     -- and that it is not constrained by theta
 274 --  traceTc (text "tcClassSig" <+> ppr op_name) `thenTc_`
 275     tcHsTopType op_ty                           `thenTc` \ local_ty ->
 276     let
 277         global_ty   = mkSigmaTy rec_clas_tyvars
 278                                 [mkClassPred rec_clas (mkTyVarTys rec_clas_tyvars)]
 279                                 local_ty
 280
 281         -- Build the selector id and default method id
 282         sel_id      = mkDictSelId op_name rec_clas
 283         dm_id       = mkDefaultMethodId dm_name rec_clas global_ty
 284         final_dm_id = tcAddImportedIdInfo rec_env dm_id
 285     in
 286 --  traceTc (text "tcClassSig done" <+> ppr op_name)    `thenTc_`
 287     returnTc (local_ty, (sel_id, final_dm_id, explicit_dm))
 288 \end{code}
 289
 290
 291 %************************************************************************
 292 %*                                                                      *
 293 \subsection[ClassDcl-pass2]{Class decls pass 2: default methods}
 294 %*                                                                      *
 295 %************************************************************************
 296
 297 The purpose of pass 2 is
 298 \begin{enumerate}
 299 \item
 300 to beat on the explicitly-provided default-method decls (if any),
 301 using them to produce a complete set of default-method decls.
 302 (Omitted ones elicit an error message.)
 303 \item
 304 to produce a definition for the selector function for each method
 305 and superclass dictionary.
 306 \end{enumerate}
 307
 308 Pass~2 only applies to locally-defined class declarations.
 309
 310 The function @tcClassDecls2@ just arranges to apply @tcClassDecl2@ to
 311 each local class decl.
 312
 313 \begin{code}
 314 tcClassDecls2 :: [RenamedHsDecl]
 315               -> NF_TcM s (LIE, TcMonoBinds)
 316
 317 tcClassDecls2 decls
 318   = foldr combine
 319           (returnNF_Tc (emptyLIE, EmptyMonoBinds))
 320           [tcClassDecl2 cls_decl | TyClD cls_decl <- decls, isClassDecl cls_decl]
 321   where
 322     combine tc1 tc2 = tc1 `thenNF_Tc` \ (lie1, binds1) ->
 323                       tc2 `thenNF_Tc` \ (lie2, binds2) ->
 324                       returnNF_Tc (lie1 `plusLIE` lie2,
 325                                    binds1 `AndMonoBinds` binds2)
 326 \end{code}
 327
 328 @tcClassDecl2@ is the business end of things.
 329
 330 \begin{code}
 331 tcClassDecl2 :: RenamedTyClDecl         -- The class declaration
 332              -> NF_TcM s (LIE, TcMonoBinds)
 333
 334 tcClassDecl2 (ClassDecl context class_name
 335                         tyvar_names _ class_sigs default_binds pragmas _ _ _ _ src_loc)
 336
 337   | not (isLocallyDefined class_name)
 338   = returnNF_Tc (emptyLIE, EmptyMonoBinds)
 339
 340   | otherwise   -- It is locally defined
 341   = recoverNF_Tc (returnNF_Tc (emptyLIE, EmptyMonoBinds)) $
 342     tcAddSrcLoc src_loc                                   $
 343     tcLookupTy class_name                               `thenNF_Tc` \ (_, AClass clas _) ->
 344     tcDefaultMethodBinds clas default_binds class_sigs
 345 \end{code}
 346
 347 \begin{code}
 348 mkImplicitClassBinds :: [Class] -> NF_TcM s ([Id], TcMonoBinds)
 349 mkImplicitClassBinds classes
 350   = returnNF_Tc (concat cls_ids_s, andMonoBindList binds_s)
 351         -- The selector binds are already in the selector Id's unfoldings
 352   where
 353     (cls_ids_s, binds_s) = unzip (map mk_implicit classes)
 354
 355     mk_implicit clas = (all_cls_ids, binds)
 356                      where
 357                         dict_con    = classDataCon clas
 358                         all_cls_ids = dataConId dict_con : cls_ids
 359                         cls_ids     = dataConWrapId dict_con : classSelIds clas
 360
 361                         -- The wrapper and selectors get bindings, the worker does not
 362                         binds | isLocallyDefined clas = idsToMonoBinds cls_ids
 363                               | otherwise             = EmptyMonoBinds
 364 \end{code}
 365
 366 %************************************************************************
 367 %*                                                                      *
 368 \subsection[Default methods]{Default methods}
 369 %*                                                                      *
 370 %************************************************************************
 371
 372 The default methods for a class are each passed a dictionary for the
 373 class, so that they get access to the other methods at the same type.
 374 So, given the class decl
 375 \begin{verbatim}
 376 class Foo a where
 377         op1 :: a -> Bool
 378         op2 :: Ord b => a -> b -> b -> b
 379
 380         op1 x = True
 381         op2 x y z = if (op1 x) && (y < z) then y else z
 382 \end{verbatim}
 383 we get the default methods:
 384 \begin{verbatim}
 385 defm.Foo.op1 :: forall a. Foo a => a -> Bool
 386 defm.Foo.op1 = /\a -> \dfoo -> \x -> True
 387
 388 defm.Foo.op2 :: forall a. Foo a => forall b. Ord b => a -> b -> b -> b
 389 defm.Foo.op2 = /\ a -> \ dfoo -> /\ b -> \ dord -> \x y z ->
 390                   if (op1 a dfoo x) && (< b dord y z) then y else z
 391 \end{verbatim}
 392
 393 When we come across an instance decl, we may need to use the default
 394 methods:
 395 \begin{verbatim}
 396 instance Foo Int where {}
 397 \end{verbatim}
 398 gives
 399 \begin{verbatim}
 400 const.Foo.Int.op1 :: Int -> Bool
 401 const.Foo.Int.op1 = defm.Foo.op1 Int dfun.Foo.Int
 402
 403 const.Foo.Int.op2 :: forall b. Ord b => Int -> b -> b -> b
 404 const.Foo.Int.op2 = defm.Foo.op2 Int dfun.Foo.Int
 405
 406 dfun.Foo.Int :: Foo Int
 407 dfun.Foo.Int = (const.Foo.Int.op1, const.Foo.Int.op2)
 408 \end{verbatim}
 409 Notice that, as with method selectors above, we assume that dictionary
 410 application is curried, so there's no need to mention the Ord dictionary
 411 in const.Foo.Int.op2 (or the type variable).
 412
 413 \begin{verbatim}
 414 instance Foo a => Foo [a] where {}
 415
 416 dfun.Foo.List :: forall a. Foo a -> Foo [a]
 417 dfun.Foo.List
 418   = /\ a -> \ dfoo_a ->
 419     let rec
 420         op1 = defm.Foo.op1 [a] dfoo_list
 421         op2 = defm.Foo.op2 [a] dfoo_list
 422         dfoo_list = (op1, op2)
 423     in
 424         dfoo_list
 425 \end{verbatim}
 426
 427 \begin{code}
 428 tcDefaultMethodBinds
 429         :: Class
 430         -> RenamedMonoBinds
 431         -> [RenamedSig]
 432         -> TcM s (LIE, TcMonoBinds)
 433
 434 tcDefaultMethodBinds clas default_binds sigs
 435   =     -- Check that the default bindings come from this class
 436     checkFromThisClass clas op_items default_binds      `thenNF_Tc_`
 437
 438         -- Do each default method separately
 439         -- For Hugs compatibility we make a default-method for every
 440         -- class op, regardless of whether or not the programmer supplied an
 441         -- explicit default decl for the class.  GHC will actually never
 442         -- call the default method for such operations, because it'll whip up
 443         -- a more-informative default method at each instance decl.
 444     mapAndUnzipTc tc_dm op_items                `thenTc` \ (defm_binds, const_lies) ->
 445
 446     returnTc (plusLIEs const_lies, andMonoBindList defm_binds)
 447   where
 448     prags = filter isPragSig sigs
 449
 450     (tyvars, _, _, op_items) = classBigSig clas
 451
 452     origin = ClassDeclOrigin
 453
 454     -- We make a separate binding for each default method.
 455     -- At one time I used a single AbsBinds for all of them, thus
 456     --  AbsBind [d] [dm1, dm2, dm3] { dm1 = ...; dm2 = ...; dm3 = ... }
 457     -- But that desugars into
 458     --  ds = \d -> (..., ..., ...)
 459     --  dm1 = \d -> case ds d of (a,b,c) -> a
 460     -- And since ds is big, it doesn't get inlined, so we don't get good
 461     -- default methods.  Better to make separate AbsBinds for each
 462
 463     tc_dm op_item@(_, dm_id, _)
 464       = tcInstTyVars tyvars             `thenNF_Tc` \ (clas_tyvars, inst_tys, _) ->
 465         let
 466             theta = [(mkClassPred clas inst_tys)]
 467         in
 468         newDicts origin theta                   `thenNF_Tc` \ (this_dict, [this_dict_id]) ->
 469         let
 470             avail_insts = this_dict
 471         in
 472         tcExtendTyVarEnvForMeths tyvars clas_tyvars (
 473             tcMethodBind clas origin clas_tyvars inst_tys theta
 474                          default_binds prags False
 475                          op_item
 476         )                                       `thenTc` \ (defm_bind, insts_needed, (_, local_dm_id)) ->
 477
 478         tcAddErrCtxt (defltMethCtxt clas) $
 479
 480             -- tcMethodBind has checked that the class_tyvars havn't
 481             -- been unified with each other or another type, but we must
 482             -- still zonk them before passing them to tcSimplifyAndCheck
 483         mapNF_Tc zonkTcTyVarBndr clas_tyvars    `thenNF_Tc` \ clas_tyvars' ->
 484
 485             -- Check the context
 486         tcSimplifyAndCheck
 487             (ptext SLIT("class") <+> ppr clas)
 488             (mkVarSet clas_tyvars')
 489             avail_insts
 490             insts_needed                        `thenTc` \ (const_lie, dict_binds) ->
 491
 492         let
 493             full_bind = AbsBinds
 494                             clas_tyvars'
 495                             [this_dict_id]
 496                             [(clas_tyvars', dm_id, local_dm_id)]
 497                             emptyNameSet        -- No inlines (yet)
 498                             (dict_binds `andMonoBinds` defm_bind)
 499         in
 500         returnTc (full_bind, const_lie)
 501 \end{code}
 502
 503 \begin{code}
 504 checkFromThisClass :: Class -> [ClassOpItem] -> RenamedMonoBinds -> NF_TcM s ()
 505 checkFromThisClass clas op_items mono_binds
 506   = mapNF_Tc check_from_this_class bndrs        `thenNF_Tc_`
 507     returnNF_Tc ()
 508   where
 509     check_from_this_class (bndr, loc)
 510           | nameOccName bndr `elem` sel_names = returnNF_Tc ()
 511           | otherwise                         = tcAddSrcLoc loc $
 512                                                 addErrTc (badMethodErr bndr clas)
 513     sel_names = [getOccName sel_id | (sel_id,_,_) <- op_items]
 514     bndrs = bagToList (collectMonoBinders mono_binds)
 515 \end{code}
 516
 517
 518 @tcMethodBind@ is used to type-check both default-method and
 519 instance-decl method declarations.  We must type-check methods one at a
 520 time, because their signatures may have different contexts and
 521 tyvar sets.
 522
 523 \begin{code}
 524 tcMethodBind
 525         :: Class
 526         -> InstOrigin
 527         -> [TcTyVar]            -- Instantiated type variables for the
 528                                 --  enclosing class/instance decl.
 529                                 --  They'll be signature tyvars, and we
 530                                 --  want to check that they don't get bound
 531         -> [TcType]             -- Instance types
 532         -> TcThetaType          -- Available theta; this could be used to check
 533                                 --  the method signature, but actually that's done by
 534                                 --  the caller;  here, it's just used for the error message
 535         -> RenamedMonoBinds     -- Method binding (pick the right one from in here)
 536         -> [RenamedSig]         -- Pramgas (just for this one)
 537         -> Bool                 -- True <=> This method is from an instance declaration
 538         -> ClassOpItem          -- The method selector and default-method Id
 539         -> TcM s (TcMonoBinds, LIE, (LIE, TcId))
 540
 541 tcMethodBind clas origin inst_tyvars inst_tys inst_theta
 542              meth_binds prags is_inst_decl
 543              (sel_id, dm_id, explicit_dm)
 544  = tcGetSrcLoc          `thenNF_Tc` \ loc ->
 545
 546    newMethod origin sel_id inst_tys     `thenNF_Tc` \ meth@(_, meth_id) ->
 547    mkTcSig meth_id loc                  `thenNF_Tc` \ sig_info ->
 548
 549    let
 550      meth_name       = idName meth_id
 551      maybe_user_bind = find_bind meth_name meth_binds
 552
 553      no_user_bind    = case maybe_user_bind of {Nothing -> True; other -> False}
 554
 555      meth_bind = case maybe_user_bind of
 556                         Just bind -> bind
 557                         Nothing   -> mk_default_bind meth_name loc
 558
 559      meth_prags = find_prags meth_name prags
 560    in
 561
 562         -- Warn if no method binding, only if -fwarn-missing-methods
 563    warnTc (is_inst_decl && opt_WarnMissingMethods && no_user_bind && not explicit_dm)
 564           (omittedMethodWarn sel_id clas)               `thenNF_Tc_`
 565
 566         -- Check the bindings; first add inst_tyvars to the envt
 567         -- so that we don't quantify over them in nested places
 568         -- The *caller* put the class/inst decl tyvars into the envt
 569    tcExtendGlobalTyVars (mkVarSet inst_tyvars) (
 570      tcAddErrCtxt (methodCtxt sel_id)           $
 571      tcBindWithSigs NotTopLevel meth_bind
 572                     [sig_info] meth_prags NonRecursive
 573    )                                            `thenTc` \ (binds, insts, _) ->
 574
 575
 576    tcExtendLocalValEnv [(meth_name, meth_id)] (
 577         tcSpecSigs meth_prags
 578    )                                            `thenTc` \ (prag_binds1, prag_lie) ->
 579
 580         -- The prag_lie for a SPECIALISE pragma will mention the function
 581         -- itself, so we have to simplify them away right now lest they float
 582         -- outwards!
 583    bindInstsOfLocalFuns prag_lie [meth_id]      `thenTc` \ (prag_lie', prag_binds2) ->
 584
 585
 586         -- Now check that the instance type variables
 587         -- (or, in the case of a class decl, the class tyvars)
 588         -- have not been unified with anything in the environment
 589    tcAddErrCtxtM (sigCtxt sig_msg inst_tyvars inst_theta (idType meth_id))      $
 590    checkSigTyVars inst_tyvars emptyVarSet                                       `thenTc_`
 591
 592    returnTc (binds `AndMonoBinds` prag_binds1 `AndMonoBinds` prag_binds2,
 593              insts `plusLIE` prag_lie',
 594              meth)
 595  where
 596    sig_msg = ptext SLIT("When checking the expected type for class method") <+> ppr sel_name
 597
 598    sel_name = idName sel_id
 599
 600         -- The renamer just puts the selector ID as the binder in the method binding
 601         -- but we must use the method name; so we substitute it here.  Crude but simple.
 602    find_bind meth_name (FunMonoBind op_name fix matches loc)
 603         | op_name == sel_name = Just (FunMonoBind meth_name fix matches loc)
 604    find_bind meth_name (AndMonoBinds b1 b2)
 605                               = find_bind meth_name b1 `seqMaybe` find_bind meth_name b2
 606    find_bind meth_name other  = Nothing -- Default case
 607
 608
 609         -- Find the prags for this method, and replace the
 610         -- selector name with the method name
 611    find_prags meth_name [] = []
 612    find_prags meth_name (SpecSig name ty loc : prags)
 613         | name == sel_name = SpecSig meth_name ty loc : find_prags meth_name prags
 614    find_prags meth_name (InlineSig name phase loc : prags)
 615         | name == sel_name = InlineSig meth_name phase loc : find_prags meth_name prags
 616    find_prags meth_name (NoInlineSig name phase loc : prags)
 617         | name == sel_name = NoInlineSig meth_name phase loc : find_prags meth_name prags
 618    find_prags meth_name (prag:prags) = find_prags meth_name prags
 619
 620    mk_default_bind local_meth_name loc
 621       = FunMonoBind local_meth_name
 622                     False       -- Not infix decl
 623                     [mkSimpleMatch [] (default_expr loc) Nothing loc]
 624                     loc
 625
 626    default_expr loc
 627         | explicit_dm = HsVar (getName dm_id)   -- There's a default method
 628         | otherwise   = error_expr loc          -- No default method
 629
 630    error_expr loc = HsApp (HsVar (getName nO_METHOD_BINDING_ERROR_ID))
 631                           (HsLit (HsString (_PK_ (error_msg loc))))
 632
 633    error_msg loc = showSDoc (hcat [ppr loc, text "|", ppr sel_id ])
 634 \end{code}
 635
 636 Contexts and errors
 637 ~~~~~~~~~~~~~~~~~~~
 638 \begin{code}
 639 classArityErr class_name
 640   = ptext SLIT("Too many parameters for class") <+> quotes (ppr class_name)
 641
 642 superClassErr class_name sc
 643   = ptext SLIT("Illegal superclass constraint") <+> quotes (ppr sc)
 644     <+> ptext SLIT("in declaration for class") <+> quotes (ppr class_name)
 645
 646 defltMethCtxt class_name
 647   = ptext SLIT("When checking the default methods for class") <+> quotes (ppr class_name)
 648
 649 methodCtxt sel_id
 650   = ptext SLIT("In the definition for method") <+> quotes (ppr sel_id)
 651
 652 badMethodErr bndr clas
 653   = hsep [ptext SLIT("Class"), quotes (ppr clas),
 654           ptext SLIT("does not have a method"), quotes (ppr bndr)]
 655
 656 omittedMethodWarn sel_id clas
 657   = sep [ptext SLIT("No explicit method nor default method for") <+> quotes (ppr sel_id),
 658          ptext SLIT("in an instance declaration for") <+> quotes (ppr clas)]
 659 \end{code}