ghc/compiler/typecheck/TcClassDcl.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcClassDcl]{Typechecking class declarations}
   5
   6 \begin{code}
   7 module TcClassDcl ( tcClassDecl1, tcClassDecls2,
   8                     tcMethodBind, badMethodErr
   9                   ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn            ( TyClDecl(..), Sig(..), MonoBinds(..),
  14                           HsExpr(..), HsLit(..), HsType(..), HsPred(..),
  15                           mkSimpleMatch, andMonoBinds, andMonoBindList,
  16                           isClassOpSig, isPragSig,
  17                           getClassDeclSysNames,
  18                         )
  19 import BasicTypes       ( TopLevelFlag(..), RecFlag(..) )
  20 import RnHsSyn          ( RenamedTyClDecl,
  21                           RenamedClassOpSig, RenamedMonoBinds,
  22                           RenamedContext, RenamedSig,
  23                           maybeGenericMatch
  24                         )
  25 import TcHsSyn          ( TcMonoBinds )
  26
  27 import Inst             ( Inst, InstOrigin(..), LIE, emptyLIE, plusLIE, plusLIEs,
  28                           instToId, newDicts, newMethod )
  29 import TcEnv            ( RecTcEnv, TyThingDetails(..), tcAddImportedIdInfo,
  30                           tcLookupClass, tcExtendTyVarEnvForMeths, tcExtendGlobalTyVars,
  31                           tcExtendLocalValEnv, tcExtendTyVarEnv
  32                         )
  33 import TcBinds          ( tcBindWithSigs, tcSpecSigs )
  34 import TcMonoType       ( tcHsRecType, tcRecClassContext, checkSigTyVars, checkAmbiguity, sigCtxt, mkTcSig )
  35 import TcSimplify       ( tcSimplifyCheck, bindInstsOfLocalFuns )
  36 import TcType           ( TcType, TcTyVar, tcInstTyVars )
  37 import TcMonad
  38 import Generics         ( mkGenericRhs, validGenericMethodType )
  39 import PrelInfo         ( nO_METHOD_BINDING_ERROR_ID )
  40 import Class            ( classTyVars, classBigSig, classTyCon,
  41                           Class, ClassOpItem, DefMeth (..) )
  42 import MkId             ( mkDictSelId, mkDataConId, mkDataConWrapId, mkDefaultMethodId )
  43 import DataCon          ( mkDataCon, notMarkedStrict )
  44 import Id               ( Id, idType, idName )
  45 import Module           ( Module )
  46 import Name             ( Name, NamedThing(..) )
  47 import NameEnv          ( NameEnv, lookupNameEnv, emptyNameEnv, unitNameEnv, plusNameEnv, nameEnvElts )
  48 import NameSet          ( emptyNameSet )
  49 import Outputable
  50 import Type             ( Type, ClassContext, mkTyVarTys, mkDictTys, mkClassPred,
  51                           splitTyConApp_maybe, isTyVarTy
  52                         )
  53 import Var              ( TyVar )
  54 import VarSet           ( mkVarSet, emptyVarSet )
  55 import CmdLineOpts
  56 import ErrUtils         ( dumpIfSet )
  57 import Util             ( count )
  58 import Maybes           ( seqMaybe, maybeToBool )
  59 \end{code}
  60
  61
  62
  63 Dictionary handling
  64 ~~~~~~~~~~~~~~~~~~~
  65 Every class implicitly declares a new data type, corresponding to dictionaries
  66 of that class. So, for example:
  67
  68         class (D a) => C a where
  69           op1 :: a -> a
  70           op2 :: forall b. Ord b => a -> b -> b
  71
  72 would implicitly declare
  73
  74         data CDict a = CDict (D a)
  75                              (a -> a)
  76                              (forall b. Ord b => a -> b -> b)
  77
  78 (We could use a record decl, but that means changing more of the existing apparatus.
  79 One step at at time!)
  80
  81 For classes with just one superclass+method, we use a newtype decl instead:
  82
  83         class C a where
  84           op :: forallb. a -> b -> b
  85
  86 generates
  87
  88         newtype CDict a = CDict (forall b. a -> b -> b)
  89
  90 Now DictTy in Type is just a form of type synomym:
  91         DictTy c t = TyConTy CDict `AppTy` t
  92
  93 Death to "ExpandingDicts".
  94
  95
  96 %************************************************************************
  97 %*                                                                      *
  98 \subsection{Type checking}
  99 %*                                                                      *
 100 %************************************************************************
 101
 102 \begin{code}
 103
 104 tcClassDecl1 :: RecFlag -> RecTcEnv -> RenamedTyClDecl -> TcM (Name, TyThingDetails)
 105 tcClassDecl1 is_rec rec_env
 106              (ClassDecl {tcdCtxt = context, tcdName = class_name,
 107                          tcdTyVars = tyvar_names, tcdFDs = fundeps,
 108                          tcdSigs = class_sigs, tcdMeths = def_methods,
 109                          tcdSysNames = sys_names, tcdLoc = src_loc})
 110   =     -- CHECK ARITY 1 FOR HASKELL 1.4
 111     doptsTc Opt_GlasgowExts                             `thenTc` \ gla_ext_opt ->
 112     let
 113         gla_exts = gla_ext_opt || not (maybeToBool def_methods)
 114                 -- Accept extensions if gla_exts is on,
 115                 -- or if we're looking at an interface file decl
 116     in          -- (in which case def_methods = Nothing
 117
 118         -- LOOK THINGS UP IN THE ENVIRONMENT
 119     tcLookupClass class_name                            `thenTc` \ clas ->
 120     let
 121         tyvars   = classTyVars clas
 122         op_sigs  = filter isClassOpSig class_sigs
 123         op_names = [n | ClassOpSig n _ _ _ <- op_sigs]
 124         (_, datacon_name, datacon_wkr_name, sc_sel_names) = getClassDeclSysNames sys_names
 125     in
 126     tcExtendTyVarEnv tyvars                             $
 127
 128         -- SOURCE-CODE CONSISTENCY CHECKS
 129     (case def_methods of
 130         Nothing  ->     -- Not source
 131                     returnTc Nothing
 132
 133         Just dms ->     -- Source so do error checks
 134                     checkTc (gla_exts || length tyvar_names == 1)
 135                             (classArityErr class_name)                  `thenTc_`
 136
 137                     checkDefaultBinds clas op_names dms   `thenTc` \ dm_env ->
 138                     checkGenericClassIsUnary clas dm_env  `thenTc_`
 139                     returnTc (Just dm_env)
 140     )                                                      `thenTc` \ mb_dm_env ->
 141
 142         -- CHECK THE CONTEXT
 143     tcSuperClasses is_rec gla_exts clas context sc_sel_names    `thenTc` \ (sc_theta, sc_sel_ids) ->
 144
 145         -- CHECK THE CLASS SIGNATURES,
 146     mapTc (tcClassSig is_rec rec_env clas tyvars mb_dm_env) op_sigs     `thenTc` \ sig_stuff ->
 147
 148         -- MAKE THE CLASS DETAILS
 149     let
 150         (op_tys, op_items) = unzip sig_stuff
 151         sc_tys             = mkDictTys sc_theta
 152         dict_component_tys = sc_tys ++ op_tys
 153
 154         dict_con = mkDataCon datacon_name
 155                              [notMarkedStrict | _ <- dict_component_tys]
 156                              [{- No labelled fields -}]
 157                              tyvars
 158                              [{-No context-}]
 159                              [{-No existential tyvars-}] [{-Or context-}]
 160                              dict_component_tys
 161                              (classTyCon clas)
 162                              dict_con_id dict_wrap_id
 163
 164         dict_con_id  = mkDataConId datacon_wkr_name dict_con
 165         dict_wrap_id = mkDataConWrapId dict_con
 166     in
 167     returnTc (class_name, ClassDetails sc_theta sc_sel_ids op_items dict_con)
 168 \end{code}
 169
 170 \begin{code}
 171 checkDefaultBinds :: Class -> [Name] -> RenamedMonoBinds
 172                   -> TcM (NameEnv Bool)
 173         -- The returned environment says
 174         --      x not in env => no default method
 175         --      x -> True    => generic default method
 176         --      x -> False   => polymorphic default method
 177
 178   -- Check default bindings
 179   --    a) must be for a class op for this class
 180   --    b) must be all generic or all non-generic
 181   -- and return a mapping from class-op to DefMeth info
 182
 183   -- But do all this only for source binds
 184
 185 checkDefaultBinds clas ops EmptyMonoBinds = returnTc emptyNameEnv
 186
 187 checkDefaultBinds clas ops (AndMonoBinds b1 b2)
 188   = checkDefaultBinds clas ops b1       `thenTc` \ dm_info1 ->
 189     checkDefaultBinds clas ops b2       `thenTc` \ dm_info2 ->
 190     returnTc (dm_info1 `plusNameEnv` dm_info2)
 191
 192 checkDefaultBinds clas ops (FunMonoBind op _ matches loc)
 193   = tcAddSrcLoc loc                                     $
 194
 195         -- Check that the op is from this class
 196     checkTc (op `elem` ops) (badMethodErr clas op)              `thenTc_`
 197
 198         -- Check that all the defns ar generic, or none are
 199     checkTc (all_generic || none_generic) (mixedGenericErr op)  `thenTc_`
 200
 201     returnTc (unitNameEnv op all_generic)
 202   where
 203     n_generic    = count (maybeToBool . maybeGenericMatch) matches
 204     none_generic = n_generic == 0
 205     all_generic  = n_generic == length matches
 206
 207 checkGenericClassIsUnary clas dm_env
 208   = -- Check that if the class has generic methods, then the
 209     -- class has only one parameter.  We can't do generic
 210     -- multi-parameter type classes!
 211     checkTc (unary || no_generics) (genericMultiParamErr clas)
 212   where
 213     unary       = length (classTyVars clas) == 1
 214     no_generics = not (or (nameEnvElts dm_env))
 215 \end{code}
 216
 217
 218 \begin{code}
 219 tcSuperClasses :: RecFlag -> Bool -> Class
 220                -> RenamedContext        -- class context
 221                -> [Name]                -- Names for superclass selectors
 222                -> TcM (ClassContext,    -- the superclass context
 223                          [Id])          -- superclass selector Ids
 224
 225 tcSuperClasses is_rec gla_exts clas context sc_sel_names
 226   =     -- Check the context.
 227         -- The renamer has already checked that the context mentions
 228         -- only the type variable of the class decl.
 229
 230         -- For std Haskell check that the context constrains only tyvars
 231     (if gla_exts then
 232         returnTc ()
 233      else
 234         mapTc_ check_constraint context
 235     )                                           `thenTc_`
 236
 237         -- Context is already kind-checked
 238     tcRecClassContext is_rec context            `thenTc` \ sc_theta ->
 239     let
 240        sc_sel_ids = [mkDictSelId sc_name clas | sc_name <- sc_sel_names]
 241     in
 242         -- Done
 243     returnTc (sc_theta, sc_sel_ids)
 244
 245   where
 246     check_constraint sc@(HsPClass c tys)
 247         = checkTc (all is_tyvar tys) (superClassErr clas sc)
 248
 249     is_tyvar (HsTyVar _) = True
 250     is_tyvar other       = False
 251
 252
 253 tcClassSig :: RecFlag -> RecTcEnv       -- Knot tying only!
 254            -> Class                     -- ...ditto...
 255            -> [TyVar]                   -- The class type variable, used for error check only
 256            -> Maybe (NameEnv Bool)      -- Info about default methods
 257            -> RenamedClassOpSig
 258            -> TcM (Type,                -- Type of the method
 259                      ClassOpItem)       -- Selector Id, default-method Id, True if explicit default binding
 260
 261 -- This warrants an explanation: we need to separate generic
 262 -- default methods and default methods later on in the compiler
 263 -- so we distinguish them in checkDefaultBinds, and pass this knowledge in the
 264 -- Class.DefMeth data structure.
 265
 266 tcClassSig is_rec unf_env clas clas_tyvars maybe_dm_env
 267            (ClassOpSig op_name sig_dm op_ty src_loc)
 268   = tcAddSrcLoc src_loc $
 269
 270         -- Check the type signature.  NB that the envt *already has*
 271         -- bindings for the type variables; see comments in TcTyAndClassDcls.
 272
 273     tcHsRecType is_rec op_ty                            `thenTc` \ local_ty ->
 274
 275         -- Check for ambiguous class op types
 276     let
 277         theta = [mkClassPred clas (mkTyVarTys clas_tyvars)]
 278     in
 279     checkAmbiguity is_rec True clas_tyvars theta local_ty        `thenTc` \ global_ty ->
 280           -- The default method's type should really come from the
 281           -- iface file, since it could be usage-generalised, but this
 282           -- requires altering the mess of knots in TcModule and I'm
 283           -- too scared to do that.  Instead, I have disabled generalisation
 284           -- of types of default methods (and dict funs) by annotating them
 285           -- TyGenNever (in MkId).  Ugh!  KSW 1999-09.
 286
 287     let
 288         -- Build the selector id and default method id
 289         sel_id = mkDictSelId op_name clas
 290         dm_id  = mkDefaultMethodId dm_name global_ty
 291         DefMeth dm_name = sig_dm
 292
 293         dm_info = case maybe_dm_env of
 294                     Nothing     -> iface_dm_info
 295                     Just dm_env -> mk_src_dm_info dm_env
 296
 297         iface_dm_info = case sig_dm of
 298                           NoDefMeth       -> NoDefMeth
 299                           GenDefMeth      -> GenDefMeth
 300                           DefMeth dm_name -> DefMeth (tcAddImportedIdInfo unf_env dm_id)
 301
 302         mk_src_dm_info dm_env = case lookupNameEnv dm_env op_name of
 303                                    Nothing    -> NoDefMeth
 304                                    Just True  -> GenDefMeth
 305                                    Just False -> DefMeth dm_id
 306     in
 307         -- Check that for a generic method, the type of
 308         -- the method is sufficiently simple
 309     checkTc (dm_info /= GenDefMeth || validGenericMethodType local_ty)
 310             (badGenericMethodType op_name op_ty)                `thenTc_`
 311
 312     returnTc (local_ty, (sel_id, dm_info))
 313 \end{code}
 314
 315
 316 %************************************************************************
 317 %*                                                                      *
 318 \subsection[Default methods]{Default methods}
 319 %*                                                                      *
 320 %************************************************************************
 321
 322 The default methods for a class are each passed a dictionary for the
 323 class, so that they get access to the other methods at the same type.
 324 So, given the class decl
 325 \begin{verbatim}
 326 class Foo a where
 327         op1 :: a -> Bool
 328         op2 :: Ord b => a -> b -> b -> b
 329
 330         op1 x = True
 331         op2 x y z = if (op1 x) && (y < z) then y else z
 332 \end{verbatim}
 333 we get the default methods:
 334 \begin{verbatim}
 335 defm.Foo.op1 :: forall a. Foo a => a -> Bool
 336 defm.Foo.op1 = /\a -> \dfoo -> \x -> True
 337
 338 defm.Foo.op2 :: forall a. Foo a => forall b. Ord b => a -> b -> b -> b
 339 defm.Foo.op2 = /\ a -> \ dfoo -> /\ b -> \ dord -> \x y z ->
 340                   if (op1 a dfoo x) && (< b dord y z) then y else z
 341 \end{verbatim}
 342
 343 When we come across an instance decl, we may need to use the default
 344 methods:
 345 \begin{verbatim}
 346 instance Foo Int where {}
 347 \end{verbatim}
 348 gives
 349 \begin{verbatim}
 350 const.Foo.Int.op1 :: Int -> Bool
 351 const.Foo.Int.op1 = defm.Foo.op1 Int dfun.Foo.Int
 352
 353 const.Foo.Int.op2 :: forall b. Ord b => Int -> b -> b -> b
 354 const.Foo.Int.op2 = defm.Foo.op2 Int dfun.Foo.Int
 355
 356 dfun.Foo.Int :: Foo Int
 357 dfun.Foo.Int = (const.Foo.Int.op1, const.Foo.Int.op2)
 358 \end{verbatim}
 359 Notice that, as with method selectors above, we assume that dictionary
 360 application is curried, so there's no need to mention the Ord dictionary
 361 in const.Foo.Int.op2 (or the type variable).
 362
 363 \begin{verbatim}
 364 instance Foo a => Foo [a] where {}
 365
 366 dfun.Foo.List :: forall a. Foo a -> Foo [a]
 367 dfun.Foo.List
 368   = /\ a -> \ dfoo_a ->
 369     let rec
 370         op1 = defm.Foo.op1 [a] dfoo_list
 371         op2 = defm.Foo.op2 [a] dfoo_list
 372         dfoo_list = (op1, op2)
 373     in
 374         dfoo_list
 375 \end{verbatim}
 376
 377 The function @tcClassDecls2@ just arranges to apply @tcClassDecl2@ to
 378 each local class decl.
 379
 380 \begin{code}
 381 tcClassDecls2 :: Module -> [RenamedTyClDecl] -> NF_TcM (LIE, TcMonoBinds)
 382
 383 tcClassDecls2 this_mod decls
 384   = foldr combine
 385           (returnNF_Tc (emptyLIE, EmptyMonoBinds))
 386           [tcClassDecl2 cls_decl | cls_decl@(ClassDecl {tcdMeths = Just _}) <- decls]
 387                 -- The 'Just' picks out source ClassDecls
 388   where
 389     combine tc1 tc2 = tc1 `thenNF_Tc` \ (lie1, binds1) ->
 390                       tc2 `thenNF_Tc` \ (lie2, binds2) ->
 391                       returnNF_Tc (lie1 `plusLIE` lie2,
 392                                    binds1 `AndMonoBinds` binds2)
 393 \end{code}
 394
 395 @tcClassDecl2@ generates bindings for polymorphic default methods
 396 (generic default methods have by now turned into instance declarations)
 397
 398 \begin{code}
 399 tcClassDecl2 :: RenamedTyClDecl         -- The class declaration
 400              -> NF_TcM (LIE, TcMonoBinds)
 401
 402 tcClassDecl2 (ClassDecl {tcdName = class_name, tcdSigs = sigs,
 403                          tcdMeths = Just default_binds, tcdLoc = src_loc})
 404   =     -- The 'Just' picks out source ClassDecls
 405     recoverNF_Tc (returnNF_Tc (emptyLIE, EmptyMonoBinds)) $
 406     tcAddSrcLoc src_loc                                   $
 407     tcLookupClass class_name                              `thenNF_Tc` \ clas ->
 408
 409         -- We make a separate binding for each default method.
 410         -- At one time I used a single AbsBinds for all of them, thus
 411         -- AbsBind [d] [dm1, dm2, dm3] { dm1 = ...; dm2 = ...; dm3 = ... }
 412         -- But that desugars into
 413         --      ds = \d -> (..., ..., ...)
 414         --      dm1 = \d -> case ds d of (a,b,c) -> a
 415         -- And since ds is big, it doesn't get inlined, so we don't get good
 416         -- default methods.  Better to make separate AbsBinds for each
 417     let
 418         (tyvars, _, _, op_items) = classBigSig clas
 419         prags                    = filter isPragSig sigs
 420         tc_dm                    = tcDefMeth clas tyvars default_binds prags
 421     in
 422     mapAndUnzipTc tc_dm op_items        `thenTc` \ (defm_binds, const_lies) ->
 423
 424     returnTc (plusLIEs const_lies, andMonoBindList defm_binds)
 425
 426
 427 tcDefMeth clas tyvars binds_in prags (_, NoDefMeth)  = returnTc (EmptyMonoBinds, emptyLIE)
 428 tcDefMeth clas tyvars binds_in prags (_, GenDefMeth) = returnTc (EmptyMonoBinds, emptyLIE)
 429         -- Generate code for polymorphic default methods only
 430         -- (Generic default methods have turned into instance decls by now.)
 431         -- This is incompatible with Hugs, which expects a polymorphic
 432         -- default method for every class op, regardless of whether or not
 433         -- the programmer supplied an explicit default decl for the class.
 434         -- (If necessary we can fix that, but we don't have a convenient Id to hand.)
 435
 436 tcDefMeth clas tyvars binds_in prags op_item@(_, DefMeth dm_id)
 437   = tcInstTyVars tyvars                 `thenNF_Tc` \ (clas_tyvars, inst_tys, _) ->
 438     let
 439         theta = [(mkClassPred clas inst_tys)]
 440     in
 441     newDicts origin theta               `thenNF_Tc` \ [this_dict] ->
 442
 443     tcExtendTyVarEnvForMeths tyvars clas_tyvars (
 444         tcMethodBind clas origin clas_tyvars inst_tys theta
 445                      binds_in prags False op_item
 446     )                                   `thenTc` \ (defm_bind, insts_needed, local_dm_inst) ->
 447
 448     tcAddErrCtxt (defltMethCtxt clas) $
 449
 450         -- Check the context
 451     tcSimplifyCheck
 452         (ptext SLIT("class") <+> ppr clas)
 453         clas_tyvars
 454         [this_dict]
 455         insts_needed                            `thenTc` \ (const_lie, dict_binds) ->
 456
 457         -- Simplification can do unification
 458     checkSigTyVars clas_tyvars emptyVarSet      `thenTc` \ clas_tyvars' ->
 459
 460     let
 461         full_bind = AbsBinds
 462                     clas_tyvars'
 463                     [instToId this_dict]
 464                     [(clas_tyvars', dm_id, instToId local_dm_inst)]
 465                     emptyNameSet        -- No inlines (yet)
 466                     (dict_binds `andMonoBinds` defm_bind)
 467     in
 468     returnTc (full_bind, const_lie)
 469   where
 470     origin = ClassDeclOrigin
 471 \end{code}
 472
 473
 474
 475 %************************************************************************
 476 %*                                                                      *
 477 \subsection{Typechecking a method}
 478 %*                                                                      *
 479 %************************************************************************
 480
 481 @tcMethodBind@ is used to type-check both default-method and
 482 instance-decl method declarations.  We must type-check methods one at a
 483 time, because their signatures may have different contexts and
 484 tyvar sets.
 485
 486 \begin{code}
 487 tcMethodBind
 488         :: Class
 489         -> InstOrigin
 490         -> [TcTyVar]            -- Instantiated type variables for the
 491                                 --  enclosing class/instance decl.
 492                                 --  They'll be signature tyvars, and we
 493                                 --  want to check that they don't get bound
 494         -> [TcType]             -- Instance types
 495         -> TcThetaType          -- Available theta; this could be used to check
 496                                 --  the method signature, but actually that's done by
 497                                 --  the caller;  here, it's just used for the error message
 498         -> RenamedMonoBinds     -- Method binding (pick the right one from in here)
 499         -> [RenamedSig]         -- Pramgas (just for this one)
 500         -> Bool                 -- True <=> This method is from an instance declaration
 501         -> ClassOpItem          -- The method selector and default-method Id
 502         -> TcM (TcMonoBinds, LIE, Inst)
 503
 504 tcMethodBind clas origin inst_tyvars inst_tys inst_theta
 505              meth_binds prags is_inst_decl (sel_id, dm_info)
 506   = tcGetSrcLoc                         `thenNF_Tc` \ loc ->
 507     newMethod origin sel_id inst_tys    `thenNF_Tc` \ meth ->
 508     let
 509         meth_id    = instToId meth
 510         meth_name  = idName meth_id
 511         sig_msg    = ptext SLIT("When checking the expected type for class method") <+> ppr sel_id
 512         meth_prags = find_prags (idName sel_id) meth_name prags
 513     in
 514     mkTcSig meth_id loc                 `thenNF_Tc` \ sig_info ->
 515
 516         -- Figure out what method binding to use
 517         -- If the user suppplied one, use it, else construct a default one
 518     (case find_bind (idName sel_id) meth_name meth_binds of
 519         Just user_bind -> returnTc user_bind
 520         Nothing        -> mkDefMethRhs is_inst_decl clas inst_tys sel_id loc dm_info    `thenTc` \ rhs ->
 521                           returnTc (FunMonoBind meth_name False -- Not infix decl
 522                                                 [mkSimpleMatch [] rhs Nothing loc] loc)
 523     )                                                           `thenTc` \ meth_bind ->
 524      -- Check the bindings; first add inst_tyvars to the envt
 525      -- so that we don't quantify over them in nested places
 526      -- The *caller* put the class/inst decl tyvars into the envt
 527      tcExtendGlobalTyVars (mkVarSet inst_tyvars)
 528                     (tcAddErrCtxt (methodCtxt sel_id)           $
 529                      tcBindWithSigs NotTopLevel meth_bind
 530                      [sig_info] meth_prags NonRecursive
 531                     )                                           `thenTc` \ (binds, insts, _) ->
 532
 533      tcExtendLocalValEnv [(meth_name, meth_id)]
 534                          (tcSpecSigs meth_prags)                `thenTc` \ (prag_binds1, prag_lie) ->
 535
 536      -- The prag_lie for a SPECIALISE pragma will mention the function
 537      -- itself, so we have to simplify them away right now lest they float
 538      -- outwards!
 539      bindInstsOfLocalFuns prag_lie [meth_id]    `thenTc` \ (prag_lie', prag_binds2) ->
 540
 541      -- Now check that the instance type variables
 542      -- (or, in the case of a class decl, the class tyvars)
 543      -- have not been unified with anything in the environment
 544      --
 545      -- We do this for each method independently to localise error messages
 546      -- ...and this is why the call to tcExtendGlobalTyVars must be here
 547      --    rather than in the caller
 548      tcAddErrCtxtM (sigCtxt sig_msg inst_tyvars inst_theta (idType meth_id))    $
 549      checkSigTyVars inst_tyvars emptyVarSet                                     `thenTc_`
 550
 551      returnTc (binds `AndMonoBinds` prag_binds1 `AndMonoBinds` prag_binds2,
 552                insts `plusLIE` prag_lie',
 553                meth)
 554
 555      -- The user didn't supply a method binding,
 556      -- so we have to make up a default binding
 557      -- The RHS of a default method depends on the default-method info
 558 mkDefMethRhs is_inst_decl clas inst_tys sel_id loc (DefMeth dm_id)
 559   =  -- An polymorphic default method
 560     returnTc (HsVar (idName dm_id))
 561
 562 mkDefMethRhs is_inst_decl clas inst_tys sel_id loc NoDefMeth
 563   =     -- No default method
 564         -- Warn only if -fwarn-missing-methods
 565     doptsTc Opt_WarnMissingMethods  `thenNF_Tc` \ warn ->
 566     warnTc (is_inst_decl && warn)
 567            (omittedMethodWarn sel_id clas)              `thenNF_Tc_`
 568     returnTc error_rhs
 569   where
 570     error_rhs = HsApp (HsVar (getName nO_METHOD_BINDING_ERROR_ID))
 571                           (HsLit (HsString (_PK_ error_msg)))
 572     error_msg = showSDoc (hcat [ppr loc, text "|", ppr sel_id ])
 573
 574
 575 mkDefMethRhs is_inst_decl clas inst_tys sel_id loc GenDefMeth
 576   =     -- A generic default method
 577         -- If the method is defined generically, we can only do the job if the
 578         -- instance declaration is for a single-parameter type class with
 579         -- a type constructor applied to type arguments in the instance decl
 580         --      (checkTc, so False provokes the error)
 581      checkTc (not is_inst_decl || simple_inst)
 582              (badGenericInstance sel_id clas)                   `thenTc_`
 583
 584      ioToTc (dumpIfSet opt_PprStyle_Debug "Generic RHS" stuff)  `thenNF_Tc_`
 585      returnTc rhs
 586   where
 587     rhs = mkGenericRhs sel_id clas_tyvar tycon
 588
 589     stuff = vcat [ppr clas <+> ppr inst_tys,
 590                   nest 4 (ppr sel_id <+> equals <+> ppr rhs)]
 591
 592           -- The tycon is only used in the generic case, and in that
 593           -- case we require that the instance decl is for a single-parameter
 594           -- type class with type variable arguments:
 595           --    instance (...) => C (T a b)
 596     simple_inst   = maybeToBool maybe_tycon
 597     clas_tyvar    = head (classTyVars clas)
 598     Just tycon    = maybe_tycon
 599     maybe_tycon   = case inst_tys of
 600                         [ty] -> case splitTyConApp_maybe ty of
 601                                   Just (tycon, arg_tys) | all isTyVarTy arg_tys -> Just tycon
 602                                   other                                         -> Nothing
 603                         other -> Nothing
 604 \end{code}
 605
 606
 607 \begin{code}
 608 -- The renamer just puts the selector ID as the binder in the method binding
 609 -- but we must use the method name; so we substitute it here.  Crude but simple.
 610 find_bind sel_name meth_name (FunMonoBind op_name fix matches loc)
 611     | op_name == sel_name = Just (FunMonoBind meth_name fix matches loc)
 612 find_bind sel_name meth_name (AndMonoBinds b1 b2)
 613     = find_bind sel_name meth_name b1 `seqMaybe` find_bind sel_name meth_name b2
 614 find_bind sel_name meth_name other  = Nothing   -- Default case
 615
 616  -- Find the prags for this method, and replace the
 617  -- selector name with the method name
 618 find_prags sel_name meth_name [] = []
 619 find_prags sel_name meth_name (SpecSig name ty loc : prags)
 620      | name == sel_name = SpecSig meth_name ty loc : find_prags sel_name meth_name prags
 621 find_prags sel_name meth_name (InlineSig name phase loc : prags)
 622    | name == sel_name = InlineSig meth_name phase loc : find_prags sel_name meth_name prags
 623 find_prags sel_name meth_name (NoInlineSig name phase loc : prags)
 624    | name == sel_name = NoInlineSig meth_name phase loc : find_prags sel_name meth_name prags
 625 find_prags sel_name meth_name (prag:prags) = find_prags sel_name meth_name prags
 626 \end{code}
 627
 628
 629 Contexts and errors
 630 ~~~~~~~~~~~~~~~~~~~
 631 \begin{code}
 632 classArityErr class_name
 633   = ptext SLIT("Too many parameters for class") <+> quotes (ppr class_name)
 634
 635 superClassErr clas sc
 636   = ptext SLIT("Illegal superclass constraint") <+> quotes (ppr sc)
 637     <+> ptext SLIT("in declaration for class") <+> quotes (ppr clas)
 638
 639 defltMethCtxt clas
 640   = ptext SLIT("When checking the default methods for class") <+> quotes (ppr clas)
 641
 642 methodCtxt sel_id
 643   = ptext SLIT("In the definition for method") <+> quotes (ppr sel_id)
 644
 645 badMethodErr clas op
 646   = hsep [ptext SLIT("Class"), quotes (ppr clas),
 647           ptext SLIT("does not have a method"), quotes (ppr op)]
 648
 649 omittedMethodWarn sel_id clas
 650   = sep [ptext SLIT("No explicit method nor default method for") <+> quotes (ppr sel_id),
 651          ptext SLIT("in an instance declaration for") <+> quotes (ppr clas)]
 652
 653 badGenericMethodType op op_ty
 654   = hang (ptext SLIT("Generic method type is too complex"))
 655        4 (vcat [ppr op <+> dcolon <+> ppr op_ty,
 656                 ptext SLIT("You can only use type variables, arrows, and tuples")])
 657
 658 badGenericInstance sel_id clas
 659   = sep [ptext SLIT("Can't derive generic code for") <+> quotes (ppr sel_id),
 660          ptext SLIT("because the instance declaration is not for a simple type (T a b c)"),
 661          ptext SLIT("(where T is a derivable type constructor)"),
 662          ptext SLIT("in an instance declaration for") <+> quotes (ppr clas)]
 663
 664 mixedGenericErr op
 665   = ptext SLIT("Can't mix generic and non-generic equations for class method") <+> quotes (ppr op)
 666
 667 genericMultiParamErr clas
 668   = ptext SLIT("The multi-parameter class") <+> quotes (ppr clas) <+>
 669     ptext SLIT("cannot have generic methods")
 670 \end{code}