ghc/compiler/typecheck/TcClassDcl.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcClassDcl]{Typechecking class declarations}
   5
   6 \begin{code}
   7 module TcClassDcl ( tcClassDecl1, checkValidClass, tcClassDecls2,
   8                     tcMethodBind, badMethodErr
   9                   ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn            ( TyClDecl(..), Sig(..), MonoBinds(..),
  14                           HsExpr(..), HsLit(..),
  15                           mkSimpleMatch, andMonoBinds, andMonoBindList,
  16                           isClassOpSig, isPragSig,
  17                           getClassDeclSysNames, placeHolderType
  18                         )
  19 import BasicTypes       ( TopLevelFlag(..), RecFlag(..), StrictnessMark(..) )
  20 import RnHsSyn          ( RenamedTyClDecl,
  21                           RenamedClassOpSig, RenamedMonoBinds,
  22                           RenamedSig, maybeGenericMatch
  23                         )
  24 import TcHsSyn          ( TcMonoBinds )
  25
  26 import Inst             ( Inst, InstOrigin(..), LIE, emptyLIE, plusLIE, plusLIEs,
  27                           instToId, newDicts, newMethod )
  28 import TcEnv            ( RecTcEnv, TyThingDetails(..),
  29                           tcLookupClass, tcExtendTyVarEnvForMeths, tcExtendGlobalTyVars,
  30                           tcExtendLocalValEnv, tcExtendTyVarEnv
  31                         )
  32 import TcBinds          ( tcBindWithSigs, tcSpecSigs )
  33 import TcMonoType       ( tcHsType, tcHsTheta, mkTcSig )
  34 import TcSimplify       ( tcSimplifyCheck, bindInstsOfLocalFuns )
  35 import TcUnify          ( checkSigTyVars, sigCtxt )
  36 import TcMType          ( tcInstSigTyVars, checkValidTheta, checkValidType, SourceTyCtxt(..), UserTypeCtxt(..) )
  37 import TcType           ( Type, TyVarDetails(..), TcType, TcThetaType, TcTyVar,
  38                           mkTyVarTys, mkPredTys, mkClassPred,
  39                           tcIsTyVarTy, tcSplitTyConApp_maybe, tcSplitSigmaTy
  40                         )
  41 import TcMonad
  42 import Generics         ( mkGenericRhs, validGenericMethodType )
  43 import PrelInfo         ( nO_METHOD_BINDING_ERROR_ID )
  44 import Class            ( classTyVars, classBigSig, classTyCon, className,
  45                           Class, ClassOpItem, DefMeth (..) )
  46 import MkId             ( mkDictSelId, mkDataConId, mkDataConWrapId, mkDefaultMethodId )
  47 import DataCon          ( mkDataCon )
  48 import Id               ( Id, idType, idName, setIdLocalExported )
  49 import Module           ( Module )
  50 import Name             ( Name, NamedThing(..) )
  51 import NameEnv          ( NameEnv, lookupNameEnv, emptyNameEnv, unitNameEnv, plusNameEnv )
  52 import NameSet          ( emptyNameSet )
  53 import Outputable
  54 import Var              ( TyVar )
  55 import VarSet           ( mkVarSet, emptyVarSet )
  56 import CmdLineOpts
  57 import ErrUtils         ( dumpIfSet )
  58 import Util             ( count, isSingleton, lengthIs, equalLength )
  59 import Maybes           ( seqMaybe, maybeToBool )
  60 \end{code}
  61
  62
  63
  64 Dictionary handling
  65 ~~~~~~~~~~~~~~~~~~~
  66 Every class implicitly declares a new data type, corresponding to dictionaries
  67 of that class. So, for example:
  68
  69         class (D a) => C a where
  70           op1 :: a -> a
  71           op2 :: forall b. Ord b => a -> b -> b
  72
  73 would implicitly declare
  74
  75         data CDict a = CDict (D a)
  76                              (a -> a)
  77                              (forall b. Ord b => a -> b -> b)
  78
  79 (We could use a record decl, but that means changing more of the existing apparatus.
  80 One step at at time!)
  81
  82 For classes with just one superclass+method, we use a newtype decl instead:
  83
  84         class C a where
  85           op :: forallb. a -> b -> b
  86
  87 generates
  88
  89         newtype CDict a = CDict (forall b. a -> b -> b)
  90
  91 Now DictTy in Type is just a form of type synomym:
  92         DictTy c t = TyConTy CDict `AppTy` t
  93
  94 Death to "ExpandingDicts".
  95
  96
  97 %************************************************************************
  98 %*                                                                      *
  99 \subsection{Type checking}
 100 %*                                                                      *
 101 %************************************************************************
 102
 103 \begin{code}
 104
 105 tcClassDecl1 :: RecTcEnv -> RenamedTyClDecl -> TcM (Name, TyThingDetails)
 106 tcClassDecl1 rec_env
 107              (ClassDecl {tcdCtxt = context, tcdName = class_name,
 108                          tcdTyVars = tyvar_names, tcdFDs = fundeps,
 109                          tcdSigs = class_sigs, tcdMeths = def_methods,
 110                          tcdSysNames = sys_names, tcdLoc = src_loc})
 111   =     -- LOOK THINGS UP IN THE ENVIRONMENT
 112     tcLookupClass class_name                            `thenTc` \ clas ->
 113     let
 114         tyvars   = classTyVars clas
 115         op_sigs  = filter isClassOpSig class_sigs
 116         op_names = [n | ClassOpSig n _ _ _ <- op_sigs]
 117         (_, datacon_name, datacon_wkr_name, sc_sel_names) = getClassDeclSysNames sys_names
 118     in
 119     tcExtendTyVarEnv tyvars                             $
 120
 121     checkDefaultBinds clas op_names def_methods   `thenTc` \ mb_dm_env ->
 122
 123         -- CHECK THE CONTEXT
 124         -- The renamer has already checked that the context mentions
 125         -- only the type variable of the class decl.
 126         -- Context is already kind-checked
 127     ASSERT( equalLength context sc_sel_names )
 128     tcHsTheta context                                           `thenTc` \ sc_theta ->
 129
 130         -- CHECK THE CLASS SIGNATURES,
 131     mapTc (tcClassSig rec_env clas tyvars mb_dm_env) op_sigs    `thenTc` \ sig_stuff ->
 132
 133         -- MAKE THE CLASS DETAILS
 134     let
 135         (op_tys, op_items) = unzip sig_stuff
 136         sc_tys             = mkPredTys sc_theta
 137         dict_component_tys = sc_tys ++ op_tys
 138         sc_sel_ids         = [mkDictSelId sc_name clas | sc_name <- sc_sel_names]
 139
 140         dict_con = mkDataCon datacon_name
 141                              [NotMarkedStrict | _ <- dict_component_tys]
 142                              [{- No labelled fields -}]
 143                              tyvars
 144                              [{-No context-}]
 145                              [{-No existential tyvars-}] [{-Or context-}]
 146                              dict_component_tys
 147                              (classTyCon clas)
 148                              dict_con_id dict_wrap_id
 149
 150         dict_con_id  = mkDataConId datacon_wkr_name dict_con
 151         dict_wrap_id = mkDataConWrapId dict_con
 152     in
 153     returnTc (class_name, ClassDetails sc_theta sc_sel_ids op_items dict_con)
 154 \end{code}
 155
 156 \begin{code}
 157 checkDefaultBinds :: Class -> [Name] -> Maybe RenamedMonoBinds
 158                   -> TcM (Maybe (NameEnv Bool))
 159         -- The returned environment says
 160         --      x not in env => no default method
 161         --      x -> True    => generic default method
 162         --      x -> False   => polymorphic default method
 163
 164   -- Check default bindings
 165   --    a) must be for a class op for this class
 166   --    b) must be all generic or all non-generic
 167   -- and return a mapping from class-op to DefMeth info
 168
 169   -- But do all this only for source binds
 170
 171 checkDefaultBinds clas ops Nothing
 172   = returnTc Nothing
 173
 174 checkDefaultBinds clas ops (Just mbs)
 175   = go mbs      `thenTc` \ dm_env ->
 176     returnTc (Just dm_env)
 177   where
 178     go EmptyMonoBinds = returnTc emptyNameEnv
 179
 180     go (AndMonoBinds b1 b2)
 181       = go b1   `thenTc` \ dm_info1 ->
 182         go b2   `thenTc` \ dm_info2 ->
 183         returnTc (dm_info1 `plusNameEnv` dm_info2)
 184
 185     go (FunMonoBind op _ matches loc)
 186       = tcAddSrcLoc loc                                 $
 187
 188         -- Check that the op is from this class
 189         checkTc (op `elem` ops) (badMethodErr clas op)          `thenTc_`
 190
 191         -- Check that all the defns ar generic, or none are
 192         checkTc (all_generic || none_generic) (mixedGenericErr op)      `thenTc_`
 193
 194         returnTc (unitNameEnv op all_generic)
 195       where
 196         n_generic    = count (maybeToBool . maybeGenericMatch) matches
 197         none_generic = n_generic == 0
 198         all_generic  = matches `lengthIs` n_generic
 199 \end{code}
 200
 201
 202 \begin{code}
 203 tcClassSig :: RecTcEnv                  -- Knot tying only!
 204            -> Class                     -- ...ditto...
 205            -> [TyVar]                   -- The class type variable, used for error check only
 206            -> Maybe (NameEnv Bool)      -- Info about default methods;
 207                                         --      Nothing => imported class defn with no method binds
 208            -> RenamedClassOpSig
 209            -> TcM (Type,                -- Type of the method
 210                      ClassOpItem)       -- Selector Id, default-method Id, True if explicit default binding
 211
 212 -- This warrants an explanation: we need to separate generic
 213 -- default methods and default methods later on in the compiler
 214 -- so we distinguish them in checkDefaultBinds, and pass this knowledge in the
 215 -- Class.DefMeth data structure.
 216
 217 tcClassSig unf_env clas clas_tyvars maybe_dm_env
 218            (ClassOpSig op_name sig_dm op_ty src_loc)
 219   = tcAddSrcLoc src_loc $
 220
 221         -- Check the type signature.  NB that the envt *already has*
 222         -- bindings for the type variables; see comments in TcTyAndClassDcls.
 223     tcHsType op_ty                      `thenTc` \ local_ty ->
 224
 225     let
 226         theta = [mkClassPred clas (mkTyVarTys clas_tyvars)]
 227
 228         -- Build the selector id and default method id
 229         sel_id = mkDictSelId op_name clas
 230         DefMeth dm_name = sig_dm
 231
 232         dm_info = case maybe_dm_env of
 233                     Nothing     -> sig_dm
 234                     Just dm_env -> mk_src_dm_info dm_env
 235
 236         mk_src_dm_info dm_env = case lookupNameEnv dm_env op_name of
 237                                    Nothing    -> NoDefMeth
 238                                    Just True  -> GenDefMeth
 239                                    Just False -> DefMeth dm_name
 240     in
 241     returnTc (local_ty, (sel_id, dm_info))
 242 \end{code}
 243
 244 checkValidClass is called once the mutually-recursive knot has been
 245 tied, so we can look at things freely.
 246
 247 \begin{code}
 248 checkValidClass :: Class -> TcM ()
 249 checkValidClass cls
 250   =     -- CHECK ARITY 1 FOR HASKELL 1.4
 251     doptsTc Opt_GlasgowExts                             `thenTc` \ gla_exts ->
 252
 253         -- Check that the class is unary, unless GlaExs
 254     checkTc (not (null tyvars))         (nullaryClassErr cls)   `thenTc_`
 255     checkTc (gla_exts || unary) (classArityErr cls)     `thenTc_`
 256
 257         -- Check the super-classes
 258     checkValidTheta (ClassSCCtxt (className cls)) theta `thenTc_`
 259
 260         -- Check the class operations
 261     mapTc_ check_op op_stuff            `thenTc_`
 262
 263         -- Check that if the class has generic methods, then the
 264         -- class has only one parameter.  We can't do generic
 265         -- multi-parameter type classes!
 266     checkTc (unary || no_generics) (genericMultiParamErr cls)
 267
 268   where
 269     (tyvars, theta, _, op_stuff) = classBigSig cls
 270     unary       = isSingleton tyvars
 271     no_generics = null [() | (_, GenDefMeth) <- op_stuff]
 272
 273     check_op (sel_id, dm)
 274         = checkValidTheta SigmaCtxt (tail theta)        `thenTc_`
 275                 -- The 'tail' removes the initial (C a) from the
 276                 -- class itself, leaving just the method type
 277
 278           checkValidType (FunSigCtxt op_name) tau       `thenTc_`
 279
 280                 -- Check that for a generic method, the type of
 281                 -- the method is sufficiently simple
 282           checkTc (dm /= GenDefMeth || validGenericMethodType op_ty)
 283                   (badGenericMethodType op_name op_ty)
 284         where
 285           op_name = idName sel_id
 286           op_ty   = idType sel_id
 287           (_,theta,tau) = tcSplitSigmaTy op_ty
 288 \end{code}
 289
 290
 291 %************************************************************************
 292 %*                                                                      *
 293 \subsection[Default methods]{Default methods}
 294 %*                                                                      *
 295 %************************************************************************
 296
 297 The default methods for a class are each passed a dictionary for the
 298 class, so that they get access to the other methods at the same type.
 299 So, given the class decl
 300 \begin{verbatim}
 301 class Foo a where
 302         op1 :: a -> Bool
 303         op2 :: Ord b => a -> b -> b -> b
 304
 305         op1 x = True
 306         op2 x y z = if (op1 x) && (y < z) then y else z
 307 \end{verbatim}
 308 we get the default methods:
 309 \begin{verbatim}
 310 defm.Foo.op1 :: forall a. Foo a => a -> Bool
 311 defm.Foo.op1 = /\a -> \dfoo -> \x -> True
 312
 313 defm.Foo.op2 :: forall a. Foo a => forall b. Ord b => a -> b -> b -> b
 314 defm.Foo.op2 = /\ a -> \ dfoo -> /\ b -> \ dord -> \x y z ->
 315                   if (op1 a dfoo x) && (< b dord y z) then y else z
 316 \end{verbatim}
 317
 318 When we come across an instance decl, we may need to use the default
 319 methods:
 320 \begin{verbatim}
 321 instance Foo Int where {}
 322 \end{verbatim}
 323 gives
 324 \begin{verbatim}
 325 const.Foo.Int.op1 :: Int -> Bool
 326 const.Foo.Int.op1 = defm.Foo.op1 Int dfun.Foo.Int
 327
 328 const.Foo.Int.op2 :: forall b. Ord b => Int -> b -> b -> b
 329 const.Foo.Int.op2 = defm.Foo.op2 Int dfun.Foo.Int
 330
 331 dfun.Foo.Int :: Foo Int
 332 dfun.Foo.Int = (const.Foo.Int.op1, const.Foo.Int.op2)
 333 \end{verbatim}
 334 Notice that, as with method selectors above, we assume that dictionary
 335 application is curried, so there's no need to mention the Ord dictionary
 336 in const.Foo.Int.op2 (or the type variable).
 337
 338 \begin{verbatim}
 339 instance Foo a => Foo [a] where {}
 340
 341 dfun.Foo.List :: forall a. Foo a -> Foo [a]
 342 dfun.Foo.List
 343   = /\ a -> \ dfoo_a ->
 344     let rec
 345         op1 = defm.Foo.op1 [a] dfoo_list
 346         op2 = defm.Foo.op2 [a] dfoo_list
 347         dfoo_list = (op1, op2)
 348     in
 349         dfoo_list
 350 \end{verbatim}
 351
 352 The function @tcClassDecls2@ just arranges to apply @tcClassDecl2@ to
 353 each local class decl.
 354
 355 \begin{code}
 356 tcClassDecls2 :: Module -> [RenamedTyClDecl] -> NF_TcM (LIE, TcMonoBinds, [Id])
 357
 358 tcClassDecls2 this_mod decls
 359   = foldr combine
 360           (returnNF_Tc (emptyLIE, EmptyMonoBinds, []))
 361           [tcClassDecl2 cls_decl | cls_decl@(ClassDecl {tcdMeths = Just _}) <- decls]
 362                 -- The 'Just' picks out source ClassDecls
 363   where
 364     combine tc1 tc2 = tc1 `thenNF_Tc` \ (lie1, binds1, ids1) ->
 365                       tc2 `thenNF_Tc` \ (lie2, binds2, ids2) ->
 366                       returnNF_Tc (lie1 `plusLIE` lie2,
 367                                    binds1 `AndMonoBinds` binds2,
 368                                    ids1 ++ ids2)
 369 \end{code}
 370
 371 @tcClassDecl2@ generates bindings for polymorphic default methods
 372 (generic default methods have by now turned into instance declarations)
 373
 374 \begin{code}
 375 tcClassDecl2 :: RenamedTyClDecl         -- The class declaration
 376              -> NF_TcM (LIE, TcMonoBinds, [Id])
 377
 378 tcClassDecl2 (ClassDecl {tcdName = class_name, tcdSigs = sigs,
 379                          tcdMeths = Just default_binds, tcdLoc = src_loc})
 380   =     -- The 'Just' picks out source ClassDecls
 381     recoverNF_Tc (returnNF_Tc (emptyLIE, EmptyMonoBinds, [])) $
 382     tcAddSrcLoc src_loc                                   $
 383     tcLookupClass class_name                              `thenNF_Tc` \ clas ->
 384
 385         -- We make a separate binding for each default method.
 386         -- At one time I used a single AbsBinds for all of them, thus
 387         -- AbsBind [d] [dm1, dm2, dm3] { dm1 = ...; dm2 = ...; dm3 = ... }
 388         -- But that desugars into
 389         --      ds = \d -> (..., ..., ...)
 390         --      dm1 = \d -> case ds d of (a,b,c) -> a
 391         -- And since ds is big, it doesn't get inlined, so we don't get good
 392         -- default methods.  Better to make separate AbsBinds for each
 393     let
 394         (tyvars, _, _, op_items) = classBigSig clas
 395         prags                    = filter isPragSig sigs
 396         tc_dm                    = tcDefMeth clas tyvars default_binds prags
 397     in
 398     mapAndUnzip3Tc tc_dm op_items       `thenTc` \ (defm_binds, const_lies, dm_ids_s) ->
 399
 400     returnTc (plusLIEs const_lies, andMonoBindList defm_binds, concat dm_ids_s)
 401
 402
 403 tcDefMeth clas tyvars binds_in prags (_, NoDefMeth)  = returnTc (EmptyMonoBinds, emptyLIE, [])
 404 tcDefMeth clas tyvars binds_in prags (_, GenDefMeth) = returnTc (EmptyMonoBinds, emptyLIE, [])
 405         -- Generate code for polymorphic default methods only
 406         -- (Generic default methods have turned into instance decls by now.)
 407         -- This is incompatible with Hugs, which expects a polymorphic
 408         -- default method for every class op, regardless of whether or not
 409         -- the programmer supplied an explicit default decl for the class.
 410         -- (If necessary we can fix that, but we don't have a convenient Id to hand.)
 411
 412 tcDefMeth clas tyvars binds_in prags op_item@(sel_id, DefMeth dm_name)
 413   = tcInstSigTyVars ClsTv tyvars                        `thenNF_Tc` \ clas_tyvars ->
 414     let
 415         dm_ty = idType sel_id   -- Same as dict selector!
 416           -- The default method's type should really come from the
 417           -- iface file, since it could be usage-generalised, but this
 418           -- requires altering the mess of knots in TcModule and I'm
 419           -- too scared to do that.  Instead, I have disabled generalisation
 420           -- of types of default methods (and dict funs) by annotating them
 421           -- TyGenNever (in MkId).  Ugh!  KSW 1999-09.
 422
 423         inst_tys    = mkTyVarTys clas_tyvars
 424         theta       = [mkClassPred clas inst_tys]
 425         dm_id       = mkDefaultMethodId dm_name dm_ty
 426         local_dm_id = setIdLocalExported dm_id
 427                 -- Reason for setIdLocalExported: see notes with MkId.mkDictFunId
 428     in
 429     newDicts origin theta               `thenNF_Tc` \ [this_dict] ->
 430
 431     tcExtendTyVarEnvForMeths tyvars clas_tyvars (
 432         tcMethodBind clas origin clas_tyvars inst_tys theta
 433                      binds_in prags False op_item
 434     )                                   `thenTc` \ (defm_bind, insts_needed, local_dm_inst) ->
 435
 436     tcAddErrCtxt (defltMethCtxt clas) $
 437
 438         -- Check the context
 439     tcSimplifyCheck
 440         (ptext SLIT("class") <+> ppr clas)
 441         clas_tyvars
 442         [this_dict]
 443         insts_needed                            `thenTc` \ (const_lie, dict_binds) ->
 444
 445         -- Simplification can do unification
 446     checkSigTyVars clas_tyvars emptyVarSet      `thenTc` \ clas_tyvars' ->
 447
 448     let
 449         full_bind = AbsBinds
 450                     clas_tyvars'
 451                     [instToId this_dict]
 452                     [(clas_tyvars', local_dm_id, instToId local_dm_inst)]
 453                     emptyNameSet        -- No inlines (yet)
 454                     (dict_binds `andMonoBinds` defm_bind)
 455     in
 456     returnTc (full_bind, const_lie, [dm_id])
 457   where
 458     origin = ClassDeclOrigin
 459 \end{code}
 460
 461
 462
 463 %************************************************************************
 464 %*                                                                      *
 465 \subsection{Typechecking a method}
 466 %*                                                                      *
 467 %************************************************************************
 468
 469 @tcMethodBind@ is used to type-check both default-method and
 470 instance-decl method declarations.  We must type-check methods one at a
 471 time, because their signatures may have different contexts and
 472 tyvar sets.
 473
 474 \begin{code}
 475 tcMethodBind
 476         :: Class
 477         -> InstOrigin
 478         -> [TcTyVar]            -- Instantiated type variables for the
 479                                 --  enclosing class/instance decl.
 480                                 --  They'll be signature tyvars, and we
 481                                 --  want to check that they don't get bound
 482         -> [TcType]             -- Instance types
 483         -> TcThetaType          -- Available theta; this could be used to check
 484                                 --  the method signature, but actually that's done by
 485                                 --  the caller;  here, it's just used for the error message
 486         -> RenamedMonoBinds     -- Method binding (pick the right one from in here)
 487         -> [RenamedSig]         -- Pramgas (just for this one)
 488         -> Bool                 -- True <=> This method is from an instance declaration
 489         -> ClassOpItem          -- The method selector and default-method Id
 490         -> TcM (TcMonoBinds, LIE, Inst)
 491
 492 tcMethodBind clas origin inst_tyvars inst_tys inst_theta
 493              meth_binds prags is_inst_decl (sel_id, dm_info)
 494   = tcGetSrcLoc                         `thenNF_Tc` \ loc ->
 495     newMethod origin sel_id inst_tys    `thenNF_Tc` \ meth ->
 496     let
 497         meth_id    = instToId meth
 498         meth_name  = idName meth_id
 499         meth_prags = find_prags (idName sel_id) meth_name prags
 500     in
 501     mkTcSig meth_id loc                 `thenNF_Tc` \ sig_info ->
 502
 503         -- Figure out what method binding to use
 504         -- If the user suppplied one, use it, else construct a default one
 505     (case find_bind (idName sel_id) meth_name meth_binds of
 506         Just user_bind -> returnTc user_bind
 507         Nothing        -> mkDefMethRhs is_inst_decl clas inst_tys sel_id loc dm_info    `thenTc` \ rhs ->
 508                           returnTc (FunMonoBind meth_name False -- Not infix decl
 509                                                 [mkSimpleMatch [] rhs placeHolderType loc] loc)
 510     )                                                           `thenTc` \ meth_bind ->
 511      -- Check the bindings; first add inst_tyvars to the envt
 512      -- so that we don't quantify over them in nested places
 513      -- The *caller* put the class/inst decl tyvars into the envt
 514      tcExtendGlobalTyVars (mkVarSet inst_tyvars)
 515                     (tcAddErrCtxt (methodCtxt sel_id)           $
 516                      tcBindWithSigs NotTopLevel meth_bind
 517                                     [sig_info] meth_prags NonRecursive
 518                     )                                           `thenTc` \ (binds, insts, _) ->
 519
 520      tcExtendLocalValEnv [(meth_name, meth_id)]
 521                          (tcSpecSigs meth_prags)                `thenTc` \ (prag_binds1, prag_lie) ->
 522
 523      -- The prag_lie for a SPECIALISE pragma will mention the function
 524      -- itself, so we have to simplify them away right now lest they float
 525      -- outwards!
 526      bindInstsOfLocalFuns prag_lie [meth_id]    `thenTc` \ (prag_lie', prag_binds2) ->
 527
 528      -- Now check that the instance type variables
 529      -- (or, in the case of a class decl, the class tyvars)
 530      -- have not been unified with anything in the environment
 531      --
 532      -- We do this for each method independently to localise error messages
 533      -- ...and this is why the call to tcExtendGlobalTyVars must be here
 534      --    rather than in the caller
 535      tcAddErrCtxt (ptext SLIT("When checking the type of class method")
 536                    <+> quotes (ppr sel_id))                                     $
 537      tcAddErrCtxtM (sigCtxt inst_tyvars inst_theta (idType meth_id))    $
 538      checkSigTyVars inst_tyvars emptyVarSet                                     `thenTc_`
 539
 540      returnTc (binds `AndMonoBinds` prag_binds1 `AndMonoBinds` prag_binds2,
 541                insts `plusLIE` prag_lie',
 542                meth)
 543
 544      -- The user didn't supply a method binding,
 545      -- so we have to make up a default binding
 546      -- The RHS of a default method depends on the default-method info
 547 mkDefMethRhs is_inst_decl clas inst_tys sel_id loc (DefMeth dm_name)
 548   =  -- An polymorphic default method
 549     returnTc (HsVar dm_name)
 550
 551 mkDefMethRhs is_inst_decl clas inst_tys sel_id loc NoDefMeth
 552   =     -- No default method
 553         -- Warn only if -fwarn-missing-methods
 554     doptsTc Opt_WarnMissingMethods              `thenNF_Tc` \ warn ->
 555     warnTc (is_inst_decl && warn)
 556            (omittedMethodWarn sel_id)           `thenNF_Tc_`
 557     returnTc error_rhs
 558   where
 559     error_rhs = HsApp (HsVar (getName nO_METHOD_BINDING_ERROR_ID))
 560                           (HsLit (HsString (_PK_ error_msg)))
 561     error_msg = showSDoc (hcat [ppr loc, text "|", ppr sel_id ])
 562
 563
 564 mkDefMethRhs is_inst_decl clas inst_tys sel_id loc GenDefMeth
 565   =     -- A generic default method
 566         -- If the method is defined generically, we can only do the job if the
 567         -- instance declaration is for a single-parameter type class with
 568         -- a type constructor applied to type arguments in the instance decl
 569         --      (checkTc, so False provokes the error)
 570      checkTc (not is_inst_decl || simple_inst)
 571              (badGenericInstance sel_id)                        `thenTc_`
 572
 573      ioToTc (dumpIfSet opt_PprStyle_Debug "Generic RHS" stuff)  `thenNF_Tc_`
 574      returnTc rhs
 575   where
 576     rhs = mkGenericRhs sel_id clas_tyvar tycon
 577
 578     stuff = vcat [ppr clas <+> ppr inst_tys,
 579                   nest 4 (ppr sel_id <+> equals <+> ppr rhs)]
 580
 581           -- The tycon is only used in the generic case, and in that
 582           -- case we require that the instance decl is for a single-parameter
 583           -- type class with type variable arguments:
 584           --    instance (...) => C (T a b)
 585     simple_inst   = maybeToBool maybe_tycon
 586     clas_tyvar    = head (classTyVars clas)
 587     Just tycon    = maybe_tycon
 588     maybe_tycon   = case inst_tys of
 589                         [ty] -> case tcSplitTyConApp_maybe ty of
 590                                   Just (tycon, arg_tys) | all tcIsTyVarTy arg_tys -> Just tycon
 591                                   other                                           -> Nothing
 592                         other -> Nothing
 593 \end{code}
 594
 595
 596 \begin{code}
 597 -- The renamer just puts the selector ID as the binder in the method binding
 598 -- but we must use the method name; so we substitute it here.  Crude but simple.
 599 find_bind sel_name meth_name (FunMonoBind op_name fix matches loc)
 600     | op_name == sel_name = Just (FunMonoBind meth_name fix matches loc)
 601 find_bind sel_name meth_name (AndMonoBinds b1 b2)
 602     = find_bind sel_name meth_name b1 `seqMaybe` find_bind sel_name meth_name b2
 603 find_bind sel_name meth_name other  = Nothing   -- Default case
 604
 605  -- Find the prags for this method, and replace the
 606  -- selector name with the method name
 607 find_prags sel_name meth_name [] = []
 608 find_prags sel_name meth_name (SpecSig name ty loc : prags)
 609      | name == sel_name = SpecSig meth_name ty loc : find_prags sel_name meth_name prags
 610 find_prags sel_name meth_name (InlineSig sense name phase loc : prags)
 611    | name == sel_name = InlineSig sense meth_name phase loc : find_prags sel_name meth_name prags
 612 find_prags sel_name meth_name (prag:prags) = find_prags sel_name meth_name prags
 613 \end{code}
 614
 615
 616 Contexts and errors
 617 ~~~~~~~~~~~~~~~~~~~
 618 \begin{code}
 619 nullaryClassErr cls
 620   = ptext SLIT("No parameters for class")  <+> quotes (ppr cls)
 621
 622 classArityErr cls
 623   = vcat [ptext SLIT("Too many parameters for class") <+> quotes (ppr cls),
 624           parens (ptext SLIT("Use -fglasgow-exts to allow multi-parameter classes"))]
 625
 626 defltMethCtxt clas
 627   = ptext SLIT("When checking the default methods for class") <+> quotes (ppr clas)
 628
 629 methodCtxt sel_id
 630   = ptext SLIT("In the definition for method") <+> quotes (ppr sel_id)
 631
 632 badMethodErr clas op
 633   = hsep [ptext SLIT("Class"), quotes (ppr clas),
 634           ptext SLIT("does not have a method"), quotes (ppr op)]
 635
 636 omittedMethodWarn sel_id
 637   = ptext SLIT("No explicit method nor default method for") <+> quotes (ppr sel_id)
 638
 639 badGenericMethodType op op_ty
 640   = hang (ptext SLIT("Generic method type is too complex"))
 641        4 (vcat [ppr op <+> dcolon <+> ppr op_ty,
 642                 ptext SLIT("You can only use type variables, arrows, and tuples")])
 643
 644 badGenericInstance sel_id
 645   = sep [ptext SLIT("Can't derive generic code for") <+> quotes (ppr sel_id),
 646          ptext SLIT("because the instance declaration is not for a simple type (T a b c)"),
 647          ptext SLIT("(where T is a derivable type constructor)")]
 648
 649 mixedGenericErr op
 650   = ptext SLIT("Can't mix generic and non-generic equations for class method") <+> quotes (ppr op)
 651
 652 genericMultiParamErr clas
 653   = ptext SLIT("The multi-parameter class") <+> quotes (ppr clas) <+>
 654     ptext SLIT("cannot have generic methods")
 655 \end{code}