ghc/compiler/typecheck/TcClassDcl.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcClassDcl]{Typechecking class declarations}
   5
   6 \begin{code}
   7 module TcClassDcl ( tcClassDecl1, tcClassDecls2,
   8                     tcMethodBind, badMethodErr
   9                   ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn            ( TyClDecl(..), Sig(..), MonoBinds(..),
  14                           HsExpr(..), HsLit(..), HsType(..), HsPred(..),
  15                           mkSimpleMatch, andMonoBinds, andMonoBindList,
  16                           isClassOpSig, isPragSig,
  17                           getClassDeclSysNames,
  18                         )
  19 import BasicTypes       ( TopLevelFlag(..), RecFlag(..) )
  20 import RnHsSyn          ( RenamedTyClDecl,
  21                           RenamedClassOpSig, RenamedMonoBinds,
  22                           RenamedContext, RenamedSig,
  23                           maybeGenericMatch
  24                         )
  25 import TcHsSyn          ( TcMonoBinds )
  26
  27 import Inst             ( Inst, InstOrigin(..), LIE, emptyLIE, plusLIE, plusLIEs,
  28                           instToId, newDicts, newMethod )
  29 import TcEnv            ( RecTcEnv, TyThingDetails(..), tcAddImportedIdInfo,
  30                           tcLookupClass, tcExtendTyVarEnvForMeths, tcExtendGlobalTyVars,
  31                           tcExtendLocalValEnv, tcExtendTyVarEnv
  32                         )
  33 import TcBinds          ( tcBindWithSigs, tcSpecSigs )
  34 import TcMonoType       ( tcHsRecType, tcRecTheta, checkSigTyVars, checkAmbiguity, sigCtxt, mkTcSig )
  35 import TcSimplify       ( tcSimplifyCheck, bindInstsOfLocalFuns )
  36 import TcType           ( TcType, TcTyVar, tcInstTyVars )
  37 import TcMonad
  38 import Generics         ( mkGenericRhs, validGenericMethodType )
  39 import PrelInfo         ( nO_METHOD_BINDING_ERROR_ID )
  40 import Class            ( classTyVars, classBigSig, classTyCon,
  41                           Class, ClassOpItem, DefMeth (..) )
  42 import MkId             ( mkDictSelId, mkDataConId, mkDataConWrapId, mkDefaultMethodId )
  43 import DataCon          ( mkDataCon, notMarkedStrict )
  44 import Id               ( Id, idType, idName )
  45 import Module           ( Module )
  46 import Name             ( Name, NamedThing(..) )
  47 import NameEnv          ( NameEnv, lookupNameEnv, emptyNameEnv, unitNameEnv, plusNameEnv, nameEnvElts )
  48 import NameSet          ( emptyNameSet )
  49 import Outputable
  50 import Type             ( Type, ThetaType, mkTyVarTys, mkPredTys, mkClassPred,
  51                           splitTyConApp_maybe, isTyVarTy
  52                         )
  53 import Var              ( TyVar )
  54 import VarSet           ( mkVarSet, emptyVarSet )
  55 import CmdLineOpts
  56 import ErrUtils         ( dumpIfSet )
  57 import Util             ( count )
  58 import Maybes           ( seqMaybe, maybeToBool )
  59 \end{code}
  60
  61
  62
  63 Dictionary handling
  64 ~~~~~~~~~~~~~~~~~~~
  65 Every class implicitly declares a new data type, corresponding to dictionaries
  66 of that class. So, for example:
  67
  68         class (D a) => C a where
  69           op1 :: a -> a
  70           op2 :: forall b. Ord b => a -> b -> b
  71
  72 would implicitly declare
  73
  74         data CDict a = CDict (D a)
  75                              (a -> a)
  76                              (forall b. Ord b => a -> b -> b)
  77
  78 (We could use a record decl, but that means changing more of the existing apparatus.
  79 One step at at time!)
  80
  81 For classes with just one superclass+method, we use a newtype decl instead:
  82
  83         class C a where
  84           op :: forallb. a -> b -> b
  85
  86 generates
  87
  88         newtype CDict a = CDict (forall b. a -> b -> b)
  89
  90 Now DictTy in Type is just a form of type synomym:
  91         DictTy c t = TyConTy CDict `AppTy` t
  92
  93 Death to "ExpandingDicts".
  94
  95
  96 %************************************************************************
  97 %*                                                                      *
  98 \subsection{Type checking}
  99 %*                                                                      *
 100 %************************************************************************
 101
 102 \begin{code}
 103
 104 tcClassDecl1 :: RecFlag -> RecTcEnv -> RenamedTyClDecl -> TcM (Name, TyThingDetails)
 105 tcClassDecl1 is_rec rec_env
 106              (ClassDecl {tcdCtxt = context, tcdName = class_name,
 107                          tcdTyVars = tyvar_names, tcdFDs = fundeps,
 108                          tcdSigs = class_sigs, tcdMeths = def_methods,
 109                          tcdSysNames = sys_names, tcdLoc = src_loc})
 110   =     -- CHECK ARITY 1 FOR HASKELL 1.4
 111     doptsTc Opt_GlasgowExts                             `thenTc` \ gla_ext_opt ->
 112     let
 113         gla_exts = gla_ext_opt || not (maybeToBool def_methods)
 114                 -- Accept extensions if gla_exts is on,
 115                 -- or if we're looking at an interface file decl
 116     in          -- (in which case def_methods = Nothing
 117
 118         -- LOOK THINGS UP IN THE ENVIRONMENT
 119     tcLookupClass class_name                            `thenTc` \ clas ->
 120     let
 121         tyvars   = classTyVars clas
 122         op_sigs  = filter isClassOpSig class_sigs
 123         op_names = [n | ClassOpSig n _ _ _ <- op_sigs]
 124         (_, datacon_name, datacon_wkr_name, sc_sel_names) = getClassDeclSysNames sys_names
 125     in
 126     tcExtendTyVarEnv tyvars                             $
 127
 128         -- SOURCE-CODE CONSISTENCY CHECKS
 129     (case def_methods of
 130         Nothing  ->     -- Not source
 131                     returnTc Nothing
 132
 133         Just dms ->     -- Source so do error checks
 134                     checkTc (gla_exts || length tyvar_names == 1)
 135                             (classArityErr class_name)                  `thenTc_`
 136
 137                     checkDefaultBinds clas op_names dms   `thenTc` \ dm_env ->
 138                     checkGenericClassIsUnary clas dm_env  `thenTc_`
 139                     returnTc (Just dm_env)
 140     )                                                      `thenTc` \ mb_dm_env ->
 141
 142         -- CHECK THE CONTEXT
 143     tcSuperClasses is_rec gla_exts clas context sc_sel_names    `thenTc` \ (sc_theta, sc_sel_ids) ->
 144
 145         -- CHECK THE CLASS SIGNATURES,
 146     mapTc (tcClassSig is_rec rec_env clas tyvars mb_dm_env) op_sigs     `thenTc` \ sig_stuff ->
 147
 148         -- MAKE THE CLASS DETAILS
 149     let
 150         (op_tys, op_items) = unzip sig_stuff
 151         sc_tys             = mkPredTys sc_theta
 152         dict_component_tys = sc_tys ++ op_tys
 153
 154         dict_con = mkDataCon datacon_name
 155                              [notMarkedStrict | _ <- dict_component_tys]
 156                              [{- No labelled fields -}]
 157                              tyvars
 158                              [{-No context-}]
 159                              [{-No existential tyvars-}] [{-Or context-}]
 160                              dict_component_tys
 161                              (classTyCon clas)
 162                              dict_con_id dict_wrap_id
 163
 164         dict_con_id  = mkDataConId datacon_wkr_name dict_con
 165         dict_wrap_id = mkDataConWrapId dict_con
 166     in
 167     returnTc (class_name, ClassDetails sc_theta sc_sel_ids op_items dict_con)
 168 \end{code}
 169
 170 \begin{code}
 171 checkDefaultBinds :: Class -> [Name] -> RenamedMonoBinds
 172                   -> TcM (NameEnv Bool)
 173         -- The returned environment says
 174         --      x not in env => no default method
 175         --      x -> True    => generic default method
 176         --      x -> False   => polymorphic default method
 177
 178   -- Check default bindings
 179   --    a) must be for a class op for this class
 180   --    b) must be all generic or all non-generic
 181   -- and return a mapping from class-op to DefMeth info
 182
 183   -- But do all this only for source binds
 184
 185 checkDefaultBinds clas ops EmptyMonoBinds = returnTc emptyNameEnv
 186
 187 checkDefaultBinds clas ops (AndMonoBinds b1 b2)
 188   = checkDefaultBinds clas ops b1       `thenTc` \ dm_info1 ->
 189     checkDefaultBinds clas ops b2       `thenTc` \ dm_info2 ->
 190     returnTc (dm_info1 `plusNameEnv` dm_info2)
 191
 192 checkDefaultBinds clas ops (FunMonoBind op _ matches loc)
 193   = tcAddSrcLoc loc                                     $
 194
 195         -- Check that the op is from this class
 196     checkTc (op `elem` ops) (badMethodErr clas op)              `thenTc_`
 197
 198         -- Check that all the defns ar generic, or none are
 199     checkTc (all_generic || none_generic) (mixedGenericErr op)  `thenTc_`
 200
 201     returnTc (unitNameEnv op all_generic)
 202   where
 203     n_generic    = count (maybeToBool . maybeGenericMatch) matches
 204     none_generic = n_generic == 0
 205     all_generic  = n_generic == length matches
 206
 207 checkGenericClassIsUnary clas dm_env
 208   = -- Check that if the class has generic methods, then the
 209     -- class has only one parameter.  We can't do generic
 210     -- multi-parameter type classes!
 211     checkTc (unary || no_generics) (genericMultiParamErr clas)
 212   where
 213     unary       = length (classTyVars clas) == 1
 214     no_generics = not (or (nameEnvElts dm_env))
 215 \end{code}
 216
 217
 218 \begin{code}
 219 tcSuperClasses :: RecFlag -> Bool -> Class
 220                -> RenamedContext        -- class context
 221                -> [Name]                -- Names for superclass selectors
 222                -> TcM (ThetaType,       -- the superclass context
 223                        [Id])            -- superclass selector Ids
 224
 225 tcSuperClasses is_rec gla_exts clas context sc_sel_names
 226   = ASSERT( length context == length sc_sel_names )
 227         -- Check the context.
 228         -- The renamer has already checked that the context mentions
 229         -- only the type variable of the class decl.
 230
 231         -- For std Haskell check that the context constrains only tyvars
 232     mapTc_ check_constraint context                     `thenTc_`
 233
 234         -- Context is already kind-checked
 235     tcRecTheta is_rec context           `thenTc` \ sc_theta ->
 236     let
 237        sc_sel_ids = [mkDictSelId sc_name clas | sc_name <- sc_sel_names]
 238     in
 239         -- Done
 240     returnTc (sc_theta, sc_sel_ids)
 241
 242   where
 243     check_constraint sc = checkTc (ok sc) (superClassErr clas sc)
 244     ok (HsClassP c tys) | gla_exts  = True
 245                         | otherwise = all is_tyvar tys
 246     ok (HsIParam _ _)  = False          -- Never legal
 247
 248     is_tyvar (HsTyVar _) = True
 249     is_tyvar other       = False
 250
 251
 252 tcClassSig :: RecFlag -> RecTcEnv       -- Knot tying only!
 253            -> Class                     -- ...ditto...
 254            -> [TyVar]                   -- The class type variable, used for error check only
 255            -> Maybe (NameEnv Bool)      -- Info about default methods
 256            -> RenamedClassOpSig
 257            -> TcM (Type,                -- Type of the method
 258                      ClassOpItem)       -- Selector Id, default-method Id, True if explicit default binding
 259
 260 -- This warrants an explanation: we need to separate generic
 261 -- default methods and default methods later on in the compiler
 262 -- so we distinguish them in checkDefaultBinds, and pass this knowledge in the
 263 -- Class.DefMeth data structure.
 264
 265 tcClassSig is_rec unf_env clas clas_tyvars maybe_dm_env
 266            (ClassOpSig op_name sig_dm op_ty src_loc)
 267   = tcAddSrcLoc src_loc $
 268
 269         -- Check the type signature.  NB that the envt *already has*
 270         -- bindings for the type variables; see comments in TcTyAndClassDcls.
 271
 272     tcHsRecType is_rec op_ty                            `thenTc` \ local_ty ->
 273
 274         -- Check for ambiguous class op types
 275     let
 276         theta = [mkClassPred clas (mkTyVarTys clas_tyvars)]
 277     in
 278     checkAmbiguity is_rec True clas_tyvars theta local_ty        `thenTc` \ global_ty ->
 279           -- The default method's type should really come from the
 280           -- iface file, since it could be usage-generalised, but this
 281           -- requires altering the mess of knots in TcModule and I'm
 282           -- too scared to do that.  Instead, I have disabled generalisation
 283           -- of types of default methods (and dict funs) by annotating them
 284           -- TyGenNever (in MkId).  Ugh!  KSW 1999-09.
 285
 286     let
 287         -- Build the selector id and default method id
 288         sel_id = mkDictSelId op_name clas
 289         dm_id  = mkDefaultMethodId dm_name global_ty
 290         DefMeth dm_name = sig_dm
 291
 292         dm_info = case maybe_dm_env of
 293                     Nothing     -> iface_dm_info
 294                     Just dm_env -> mk_src_dm_info dm_env
 295
 296         iface_dm_info = case sig_dm of
 297                           NoDefMeth       -> NoDefMeth
 298                           GenDefMeth      -> GenDefMeth
 299                           DefMeth dm_name -> DefMeth (tcAddImportedIdInfo unf_env dm_id)
 300
 301         mk_src_dm_info dm_env = case lookupNameEnv dm_env op_name of
 302                                    Nothing    -> NoDefMeth
 303                                    Just True  -> GenDefMeth
 304                                    Just False -> DefMeth dm_id
 305     in
 306         -- Check that for a generic method, the type of
 307         -- the method is sufficiently simple
 308     checkTc (dm_info /= GenDefMeth || validGenericMethodType local_ty)
 309             (badGenericMethodType op_name op_ty)                `thenTc_`
 310
 311     returnTc (local_ty, (sel_id, dm_info))
 312 \end{code}
 313
 314
 315 %************************************************************************
 316 %*                                                                      *
 317 \subsection[Default methods]{Default methods}
 318 %*                                                                      *
 319 %************************************************************************
 320
 321 The default methods for a class are each passed a dictionary for the
 322 class, so that they get access to the other methods at the same type.
 323 So, given the class decl
 324 \begin{verbatim}
 325 class Foo a where
 326         op1 :: a -> Bool
 327         op2 :: Ord b => a -> b -> b -> b
 328
 329         op1 x = True
 330         op2 x y z = if (op1 x) && (y < z) then y else z
 331 \end{verbatim}
 332 we get the default methods:
 333 \begin{verbatim}
 334 defm.Foo.op1 :: forall a. Foo a => a -> Bool
 335 defm.Foo.op1 = /\a -> \dfoo -> \x -> True
 336
 337 defm.Foo.op2 :: forall a. Foo a => forall b. Ord b => a -> b -> b -> b
 338 defm.Foo.op2 = /\ a -> \ dfoo -> /\ b -> \ dord -> \x y z ->
 339                   if (op1 a dfoo x) && (< b dord y z) then y else z
 340 \end{verbatim}
 341
 342 When we come across an instance decl, we may need to use the default
 343 methods:
 344 \begin{verbatim}
 345 instance Foo Int where {}
 346 \end{verbatim}
 347 gives
 348 \begin{verbatim}
 349 const.Foo.Int.op1 :: Int -> Bool
 350 const.Foo.Int.op1 = defm.Foo.op1 Int dfun.Foo.Int
 351
 352 const.Foo.Int.op2 :: forall b. Ord b => Int -> b -> b -> b
 353 const.Foo.Int.op2 = defm.Foo.op2 Int dfun.Foo.Int
 354
 355 dfun.Foo.Int :: Foo Int
 356 dfun.Foo.Int = (const.Foo.Int.op1, const.Foo.Int.op2)
 357 \end{verbatim}
 358 Notice that, as with method selectors above, we assume that dictionary
 359 application is curried, so there's no need to mention the Ord dictionary
 360 in const.Foo.Int.op2 (or the type variable).
 361
 362 \begin{verbatim}
 363 instance Foo a => Foo [a] where {}
 364
 365 dfun.Foo.List :: forall a. Foo a -> Foo [a]
 366 dfun.Foo.List
 367   = /\ a -> \ dfoo_a ->
 368     let rec
 369         op1 = defm.Foo.op1 [a] dfoo_list
 370         op2 = defm.Foo.op2 [a] dfoo_list
 371         dfoo_list = (op1, op2)
 372     in
 373         dfoo_list
 374 \end{verbatim}
 375
 376 The function @tcClassDecls2@ just arranges to apply @tcClassDecl2@ to
 377 each local class decl.
 378
 379 \begin{code}
 380 tcClassDecls2 :: Module -> [RenamedTyClDecl] -> NF_TcM (LIE, TcMonoBinds)
 381
 382 tcClassDecls2 this_mod decls
 383   = foldr combine
 384           (returnNF_Tc (emptyLIE, EmptyMonoBinds))
 385           [tcClassDecl2 cls_decl | cls_decl@(ClassDecl {tcdMeths = Just _}) <- decls]
 386                 -- The 'Just' picks out source ClassDecls
 387   where
 388     combine tc1 tc2 = tc1 `thenNF_Tc` \ (lie1, binds1) ->
 389                       tc2 `thenNF_Tc` \ (lie2, binds2) ->
 390                       returnNF_Tc (lie1 `plusLIE` lie2,
 391                                    binds1 `AndMonoBinds` binds2)
 392 \end{code}
 393
 394 @tcClassDecl2@ generates bindings for polymorphic default methods
 395 (generic default methods have by now turned into instance declarations)
 396
 397 \begin{code}
 398 tcClassDecl2 :: RenamedTyClDecl         -- The class declaration
 399              -> NF_TcM (LIE, TcMonoBinds)
 400
 401 tcClassDecl2 (ClassDecl {tcdName = class_name, tcdSigs = sigs,
 402                          tcdMeths = Just default_binds, tcdLoc = src_loc})
 403   =     -- The 'Just' picks out source ClassDecls
 404     recoverNF_Tc (returnNF_Tc (emptyLIE, EmptyMonoBinds)) $
 405     tcAddSrcLoc src_loc                                   $
 406     tcLookupClass class_name                              `thenNF_Tc` \ clas ->
 407
 408         -- We make a separate binding for each default method.
 409         -- At one time I used a single AbsBinds for all of them, thus
 410         -- AbsBind [d] [dm1, dm2, dm3] { dm1 = ...; dm2 = ...; dm3 = ... }
 411         -- But that desugars into
 412         --      ds = \d -> (..., ..., ...)
 413         --      dm1 = \d -> case ds d of (a,b,c) -> a
 414         -- And since ds is big, it doesn't get inlined, so we don't get good
 415         -- default methods.  Better to make separate AbsBinds for each
 416     let
 417         (tyvars, _, _, op_items) = classBigSig clas
 418         prags                    = filter isPragSig sigs
 419         tc_dm                    = tcDefMeth clas tyvars default_binds prags
 420     in
 421     mapAndUnzipTc tc_dm op_items        `thenTc` \ (defm_binds, const_lies) ->
 422
 423     returnTc (plusLIEs const_lies, andMonoBindList defm_binds)
 424
 425
 426 tcDefMeth clas tyvars binds_in prags (_, NoDefMeth)  = returnTc (EmptyMonoBinds, emptyLIE)
 427 tcDefMeth clas tyvars binds_in prags (_, GenDefMeth) = returnTc (EmptyMonoBinds, emptyLIE)
 428         -- Generate code for polymorphic default methods only
 429         -- (Generic default methods have turned into instance decls by now.)
 430         -- This is incompatible with Hugs, which expects a polymorphic
 431         -- default method for every class op, regardless of whether or not
 432         -- the programmer supplied an explicit default decl for the class.
 433         -- (If necessary we can fix that, but we don't have a convenient Id to hand.)
 434
 435 tcDefMeth clas tyvars binds_in prags op_item@(_, DefMeth dm_id)
 436   = tcInstTyVars tyvars                 `thenNF_Tc` \ (clas_tyvars, inst_tys, _) ->
 437     let
 438         theta = [(mkClassPred clas inst_tys)]
 439     in
 440     newDicts origin theta               `thenNF_Tc` \ [this_dict] ->
 441
 442     tcExtendTyVarEnvForMeths tyvars clas_tyvars (
 443         tcMethodBind clas origin clas_tyvars inst_tys theta
 444                      binds_in prags False op_item
 445     )                                   `thenTc` \ (defm_bind, insts_needed, local_dm_inst) ->
 446
 447     tcAddErrCtxt (defltMethCtxt clas) $
 448
 449         -- Check the context
 450     tcSimplifyCheck
 451         (ptext SLIT("class") <+> ppr clas)
 452         clas_tyvars
 453         [this_dict]
 454         insts_needed                            `thenTc` \ (const_lie, dict_binds) ->
 455
 456         -- Simplification can do unification
 457     checkSigTyVars clas_tyvars emptyVarSet      `thenTc` \ clas_tyvars' ->
 458
 459     let
 460         full_bind = AbsBinds
 461                     clas_tyvars'
 462                     [instToId this_dict]
 463                     [(clas_tyvars', dm_id, instToId local_dm_inst)]
 464                     emptyNameSet        -- No inlines (yet)
 465                     (dict_binds `andMonoBinds` defm_bind)
 466     in
 467     returnTc (full_bind, const_lie)
 468   where
 469     origin = ClassDeclOrigin
 470 \end{code}
 471
 472
 473
 474 %************************************************************************
 475 %*                                                                      *
 476 \subsection{Typechecking a method}
 477 %*                                                                      *
 478 %************************************************************************
 479
 480 @tcMethodBind@ is used to type-check both default-method and
 481 instance-decl method declarations.  We must type-check methods one at a
 482 time, because their signatures may have different contexts and
 483 tyvar sets.
 484
 485 \begin{code}
 486 tcMethodBind
 487         :: Class
 488         -> InstOrigin
 489         -> [TcTyVar]            -- Instantiated type variables for the
 490                                 --  enclosing class/instance decl.
 491                                 --  They'll be signature tyvars, and we
 492                                 --  want to check that they don't get bound
 493         -> [TcType]             -- Instance types
 494         -> TcThetaType          -- Available theta; this could be used to check
 495                                 --  the method signature, but actually that's done by
 496                                 --  the caller;  here, it's just used for the error message
 497         -> RenamedMonoBinds     -- Method binding (pick the right one from in here)
 498         -> [RenamedSig]         -- Pramgas (just for this one)
 499         -> Bool                 -- True <=> This method is from an instance declaration
 500         -> ClassOpItem          -- The method selector and default-method Id
 501         -> TcM (TcMonoBinds, LIE, Inst)
 502
 503 tcMethodBind clas origin inst_tyvars inst_tys inst_theta
 504              meth_binds prags is_inst_decl (sel_id, dm_info)
 505   = tcGetSrcLoc                         `thenNF_Tc` \ loc ->
 506     newMethod origin sel_id inst_tys    `thenNF_Tc` \ meth ->
 507     let
 508         meth_id    = instToId meth
 509         meth_name  = idName meth_id
 510         sig_msg    = ptext SLIT("When checking the expected type for class method") <+> ppr sel_id
 511         meth_prags = find_prags (idName sel_id) meth_name prags
 512     in
 513     mkTcSig meth_id loc                 `thenNF_Tc` \ sig_info ->
 514
 515         -- Figure out what method binding to use
 516         -- If the user suppplied one, use it, else construct a default one
 517     (case find_bind (idName sel_id) meth_name meth_binds of
 518         Just user_bind -> returnTc user_bind
 519         Nothing        -> mkDefMethRhs is_inst_decl clas inst_tys sel_id loc dm_info    `thenTc` \ rhs ->
 520                           returnTc (FunMonoBind meth_name False -- Not infix decl
 521                                                 [mkSimpleMatch [] rhs Nothing loc] loc)
 522     )                                                           `thenTc` \ meth_bind ->
 523      -- Check the bindings; first add inst_tyvars to the envt
 524      -- so that we don't quantify over them in nested places
 525      -- The *caller* put the class/inst decl tyvars into the envt
 526      tcExtendGlobalTyVars (mkVarSet inst_tyvars)
 527                     (tcAddErrCtxt (methodCtxt sel_id)           $
 528                      tcBindWithSigs NotTopLevel meth_bind
 529                      [sig_info] meth_prags NonRecursive
 530                     )                                           `thenTc` \ (binds, insts, _) ->
 531
 532      tcExtendLocalValEnv [(meth_name, meth_id)]
 533                          (tcSpecSigs meth_prags)                `thenTc` \ (prag_binds1, prag_lie) ->
 534
 535      -- The prag_lie for a SPECIALISE pragma will mention the function
 536      -- itself, so we have to simplify them away right now lest they float
 537      -- outwards!
 538      bindInstsOfLocalFuns prag_lie [meth_id]    `thenTc` \ (prag_lie', prag_binds2) ->
 539
 540      -- Now check that the instance type variables
 541      -- (or, in the case of a class decl, the class tyvars)
 542      -- have not been unified with anything in the environment
 543      --
 544      -- We do this for each method independently to localise error messages
 545      -- ...and this is why the call to tcExtendGlobalTyVars must be here
 546      --    rather than in the caller
 547      tcAddErrCtxtM (sigCtxt sig_msg inst_tyvars inst_theta (idType meth_id))    $
 548      checkSigTyVars inst_tyvars emptyVarSet                                     `thenTc_`
 549
 550      returnTc (binds `AndMonoBinds` prag_binds1 `AndMonoBinds` prag_binds2,
 551                insts `plusLIE` prag_lie',
 552                meth)
 553
 554      -- The user didn't supply a method binding,
 555      -- so we have to make up a default binding
 556      -- The RHS of a default method depends on the default-method info
 557 mkDefMethRhs is_inst_decl clas inst_tys sel_id loc (DefMeth dm_id)
 558   =  -- An polymorphic default method
 559     returnTc (HsVar (idName dm_id))
 560
 561 mkDefMethRhs is_inst_decl clas inst_tys sel_id loc NoDefMeth
 562   =     -- No default method
 563         -- Warn only if -fwarn-missing-methods
 564     doptsTc Opt_WarnMissingMethods  `thenNF_Tc` \ warn ->
 565     warnTc (is_inst_decl && warn)
 566            (omittedMethodWarn sel_id clas)              `thenNF_Tc_`
 567     returnTc error_rhs
 568   where
 569     error_rhs = HsApp (HsVar (getName nO_METHOD_BINDING_ERROR_ID))
 570                           (HsLit (HsString (_PK_ error_msg)))
 571     error_msg = showSDoc (hcat [ppr loc, text "|", ppr sel_id ])
 572
 573
 574 mkDefMethRhs is_inst_decl clas inst_tys sel_id loc GenDefMeth
 575   =     -- A generic default method
 576         -- If the method is defined generically, we can only do the job if the
 577         -- instance declaration is for a single-parameter type class with
 578         -- a type constructor applied to type arguments in the instance decl
 579         --      (checkTc, so False provokes the error)
 580      checkTc (not is_inst_decl || simple_inst)
 581              (badGenericInstance sel_id clas)                   `thenTc_`
 582
 583      ioToTc (dumpIfSet opt_PprStyle_Debug "Generic RHS" stuff)  `thenNF_Tc_`
 584      returnTc rhs
 585   where
 586     rhs = mkGenericRhs sel_id clas_tyvar tycon
 587
 588     stuff = vcat [ppr clas <+> ppr inst_tys,
 589                   nest 4 (ppr sel_id <+> equals <+> ppr rhs)]
 590
 591           -- The tycon is only used in the generic case, and in that
 592           -- case we require that the instance decl is for a single-parameter
 593           -- type class with type variable arguments:
 594           --    instance (...) => C (T a b)
 595     simple_inst   = maybeToBool maybe_tycon
 596     clas_tyvar    = head (classTyVars clas)
 597     Just tycon    = maybe_tycon
 598     maybe_tycon   = case inst_tys of
 599                         [ty] -> case splitTyConApp_maybe ty of
 600                                   Just (tycon, arg_tys) | all isTyVarTy arg_tys -> Just tycon
 601                                   other                                         -> Nothing
 602                         other -> Nothing
 603 \end{code}
 604
 605
 606 \begin{code}
 607 -- The renamer just puts the selector ID as the binder in the method binding
 608 -- but we must use the method name; so we substitute it here.  Crude but simple.
 609 find_bind sel_name meth_name (FunMonoBind op_name fix matches loc)
 610     | op_name == sel_name = Just (FunMonoBind meth_name fix matches loc)
 611 find_bind sel_name meth_name (AndMonoBinds b1 b2)
 612     = find_bind sel_name meth_name b1 `seqMaybe` find_bind sel_name meth_name b2
 613 find_bind sel_name meth_name other  = Nothing   -- Default case
 614
 615  -- Find the prags for this method, and replace the
 616  -- selector name with the method name
 617 find_prags sel_name meth_name [] = []
 618 find_prags sel_name meth_name (SpecSig name ty loc : prags)
 619      | name == sel_name = SpecSig meth_name ty loc : find_prags sel_name meth_name prags
 620 find_prags sel_name meth_name (InlineSig name phase loc : prags)
 621    | name == sel_name = InlineSig meth_name phase loc : find_prags sel_name meth_name prags
 622 find_prags sel_name meth_name (NoInlineSig name phase loc : prags)
 623    | name == sel_name = NoInlineSig meth_name phase loc : find_prags sel_name meth_name prags
 624 find_prags sel_name meth_name (prag:prags) = find_prags sel_name meth_name prags
 625 \end{code}
 626
 627
 628 Contexts and errors
 629 ~~~~~~~~~~~~~~~~~~~
 630 \begin{code}
 631 classArityErr class_name
 632   = ptext SLIT("Too many parameters for class") <+> quotes (ppr class_name)
 633
 634 superClassErr clas sc
 635   = ptext SLIT("Illegal superclass constraint") <+> quotes (ppr sc)
 636     <+> ptext SLIT("in declaration for class") <+> quotes (ppr clas)
 637
 638 defltMethCtxt clas
 639   = ptext SLIT("When checking the default methods for class") <+> quotes (ppr clas)
 640
 641 methodCtxt sel_id
 642   = ptext SLIT("In the definition for method") <+> quotes (ppr sel_id)
 643
 644 badMethodErr clas op
 645   = hsep [ptext SLIT("Class"), quotes (ppr clas),
 646           ptext SLIT("does not have a method"), quotes (ppr op)]
 647
 648 omittedMethodWarn sel_id clas
 649   = sep [ptext SLIT("No explicit method nor default method for") <+> quotes (ppr sel_id),
 650          ptext SLIT("in an instance declaration for") <+> quotes (ppr clas)]
 651
 652 badGenericMethodType op op_ty
 653   = hang (ptext SLIT("Generic method type is too complex"))
 654        4 (vcat [ppr op <+> dcolon <+> ppr op_ty,
 655                 ptext SLIT("You can only use type variables, arrows, and tuples")])
 656
 657 badGenericInstance sel_id clas
 658   = sep [ptext SLIT("Can't derive generic code for") <+> quotes (ppr sel_id),
 659          ptext SLIT("because the instance declaration is not for a simple type (T a b c)"),
 660          ptext SLIT("(where T is a derivable type constructor)"),
 661          ptext SLIT("in an instance declaration for") <+> quotes (ppr clas)]
 662
 663 mixedGenericErr op
 664   = ptext SLIT("Can't mix generic and non-generic equations for class method") <+> quotes (ppr op)
 665
 666 genericMultiParamErr clas
 667   = ptext SLIT("The multi-parameter class") <+> quotes (ppr clas) <+>
 668     ptext SLIT("cannot have generic methods")
 669 \end{code}