ghc/compiler/typecheck/TcClassDcl.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcClassDcl]{Typechecking class declarations}
   5
   6 \begin{code}
   7 module TcClassDcl ( tcClassDecl1, tcClassDecls2,
   8                     tcMethodBind, mkMethodBind, badMethodErr
   9                   ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn            ( TyClDecl(..), Sig(..), MonoBinds(..),
  14                           HsExpr(..), HsLit(..),
  15                           mkSimpleMatch, andMonoBinds, andMonoBindList,
  16                           isClassOpSig, isPragSig,
  17                           getClassDeclSysNames, placeHolderType
  18                         )
  19 import BasicTypes       ( RecFlag(..), StrictnessMark(..) )
  20 import RnHsSyn          ( RenamedTyClDecl,
  21                           RenamedClassOpSig, RenamedMonoBinds,
  22                           maybeGenericMatch
  23                         )
  24 import TcHsSyn          ( TcMonoBinds )
  25
  26 import Inst             ( Inst, InstOrigin(..), LIE, emptyLIE, plusLIE, plusLIEs,
  27                           instToId, newDicts, newMethod )
  28 import TcEnv            ( TyThingDetails(..),
  29                           tcLookupClass, tcExtendTyVarEnv2,
  30                           tcExtendTyVarEnv
  31                         )
  32 import TcBinds          ( tcMonoBinds )
  33 import TcMonoType       ( TcSigInfo(..), tcHsType, tcHsTheta, mkTcSig )
  34 import TcSimplify       ( tcSimplifyCheck )
  35 import TcUnify          ( checkSigTyVars, sigCtxt )
  36 import TcMType          ( tcInstTyVars )
  37 import TcType           ( Type, TyVarDetails(..), TcType, TcThetaType, TcTyVar,
  38                           mkTyVarTys, mkPredTys, mkClassPred,
  39                           tcIsTyVarTy, tcSplitTyConApp_maybe
  40                         )
  41 import TcMonad
  42 import Generics         ( mkGenericRhs )
  43 import PrelInfo         ( nO_METHOD_BINDING_ERROR_ID )
  44 import Class            ( classTyVars, classBigSig, classTyCon,
  45                           Class, ClassOpItem, DefMeth (..) )
  46 import TyCon            ( tyConGenInfo )
  47 import MkId             ( mkDictSelId, mkDataConId, mkDataConWrapId, mkDefaultMethodId )
  48 import DataCon          ( mkDataCon )
  49 import Id               ( Id, idType, idName, setIdLocalExported )
  50 import Module           ( Module )
  51 import Name             ( Name, NamedThing(..) )
  52 import NameEnv          ( NameEnv, lookupNameEnv, emptyNameEnv, unitNameEnv, plusNameEnv )
  53 import NameSet          ( emptyNameSet )
  54 import Outputable
  55 import Var              ( TyVar )
  56 import CmdLineOpts
  57 import ErrUtils         ( dumpIfSet )
  58 import Util             ( count, lengthIs, equalLength )
  59 import Maybes           ( seqMaybe )
  60 import Maybe            ( isJust )
  61 \end{code}
  62
  63
  64
  65 Dictionary handling
  66 ~~~~~~~~~~~~~~~~~~~
  67 Every class implicitly declares a new data type, corresponding to dictionaries
  68 of that class. So, for example:
  69
  70         class (D a) => C a where
  71           op1 :: a -> a
  72           op2 :: forall b. Ord b => a -> b -> b
  73
  74 would implicitly declare
  75
  76         data CDict a = CDict (D a)
  77                              (a -> a)
  78                              (forall b. Ord b => a -> b -> b)
  79
  80 (We could use a record decl, but that means changing more of the existing apparatus.
  81 One step at at time!)
  82
  83 For classes with just one superclass+method, we use a newtype decl instead:
  84
  85         class C a where
  86           op :: forallb. a -> b -> b
  87
  88 generates
  89
  90         newtype CDict a = CDict (forall b. a -> b -> b)
  91
  92 Now DictTy in Type is just a form of type synomym:
  93         DictTy c t = TyConTy CDict `AppTy` t
  94
  95 Death to "ExpandingDicts".
  96
  97
  98 %************************************************************************
  99 %*                                                                      *
 100 \subsection{Type checking}
 101 %*                                                                      *
 102 %************************************************************************
 103
 104 \begin{code}
 105
 106 tcClassDecl1 :: RenamedTyClDecl -> TcM (Name, TyThingDetails)
 107 tcClassDecl1 (ClassDecl {tcdCtxt = context, tcdName = class_name,
 108                          tcdTyVars = tyvar_names, tcdFDs = fundeps,
 109                          tcdSigs = class_sigs, tcdMeths = def_methods,
 110                          tcdSysNames = sys_names, tcdLoc = src_loc})
 111   =     -- LOOK THINGS UP IN THE ENVIRONMENT
 112     tcLookupClass class_name                            `thenTc` \ clas ->
 113     let
 114         tyvars   = classTyVars clas
 115         op_sigs  = filter isClassOpSig class_sigs
 116         op_names = [n | ClassOpSig n _ _ _ <- op_sigs]
 117         (_, datacon_name, datacon_wkr_name, sc_sel_names) = getClassDeclSysNames sys_names
 118     in
 119     tcExtendTyVarEnv tyvars                             $
 120
 121     checkDefaultBinds clas op_names def_methods   `thenTc` \ mb_dm_env ->
 122
 123         -- CHECK THE CONTEXT
 124         -- The renamer has already checked that the context mentions
 125         -- only the type variable of the class decl.
 126         -- Context is already kind-checked
 127     ASSERT( equalLength context sc_sel_names )
 128     tcHsTheta context                                   `thenTc` \ sc_theta ->
 129
 130         -- CHECK THE CLASS SIGNATURES,
 131     mapTc (tcClassSig clas tyvars mb_dm_env) op_sigs    `thenTc` \ sig_stuff ->
 132
 133         -- MAKE THE CLASS DETAILS
 134     let
 135         (op_tys, op_items) = unzip sig_stuff
 136         sc_tys             = mkPredTys sc_theta
 137         dict_component_tys = sc_tys ++ op_tys
 138         sc_sel_ids         = [mkDictSelId sc_name clas | sc_name <- sc_sel_names]
 139
 140         dict_con = mkDataCon datacon_name
 141                              [NotMarkedStrict | _ <- dict_component_tys]
 142                              [{- No labelled fields -}]
 143                              tyvars
 144                              [{-No context-}]
 145                              [{-No existential tyvars-}] [{-Or context-}]
 146                              dict_component_tys
 147                              (classTyCon clas)
 148                              dict_con_id dict_wrap_id
 149
 150         dict_con_id  = mkDataConId datacon_wkr_name dict_con
 151         dict_wrap_id = mkDataConWrapId dict_con
 152     in
 153     returnTc (class_name, ClassDetails sc_theta sc_sel_ids op_items dict_con)
 154 \end{code}
 155
 156 \begin{code}
 157 checkDefaultBinds :: Class -> [Name] -> Maybe RenamedMonoBinds
 158                   -> TcM (Maybe (NameEnv Bool))
 159         -- The returned environment says
 160         --      x not in env => no default method
 161         --      x -> True    => generic default method
 162         --      x -> False   => polymorphic default method
 163
 164   -- Check default bindings
 165   --    a) must be for a class op for this class
 166   --    b) must be all generic or all non-generic
 167   -- and return a mapping from class-op to DefMeth info
 168
 169   -- But do all this only for source binds
 170
 171 checkDefaultBinds clas ops Nothing
 172   = returnTc Nothing
 173
 174 checkDefaultBinds clas ops (Just mbs)
 175   = go mbs      `thenTc` \ dm_env ->
 176     returnTc (Just dm_env)
 177   where
 178     go EmptyMonoBinds = returnTc emptyNameEnv
 179
 180     go (AndMonoBinds b1 b2)
 181       = go b1   `thenTc` \ dm_info1 ->
 182         go b2   `thenTc` \ dm_info2 ->
 183         returnTc (dm_info1 `plusNameEnv` dm_info2)
 184
 185     go (FunMonoBind op _ matches loc)
 186       = tcAddSrcLoc loc                                 $
 187
 188         -- Check that the op is from this class
 189         checkTc (op `elem` ops) (badMethodErr clas op)          `thenTc_`
 190
 191         -- Check that all the defns ar generic, or none are
 192         checkTc (all_generic || none_generic) (mixedGenericErr op)      `thenTc_`
 193
 194         returnTc (unitNameEnv op all_generic)
 195       where
 196         n_generic    = count (isJust . maybeGenericMatch) matches
 197         none_generic = n_generic == 0
 198         all_generic  = matches `lengthIs` n_generic
 199 \end{code}
 200
 201
 202 \begin{code}
 203 tcClassSig :: Class                     -- ...ditto...
 204            -> [TyVar]                   -- The class type variable, used for error check only
 205            -> Maybe (NameEnv Bool)      -- Info about default methods;
 206                                         --      Nothing => imported class defn with no method binds
 207            -> RenamedClassOpSig
 208            -> TcM (Type,                -- Type of the method
 209                      ClassOpItem)       -- Selector Id, default-method Id, True if explicit default binding
 210
 211 -- This warrants an explanation: we need to separate generic
 212 -- default methods and default methods later on in the compiler
 213 -- so we distinguish them in checkDefaultBinds, and pass this knowledge in the
 214 -- Class.DefMeth data structure.
 215
 216 tcClassSig clas clas_tyvars maybe_dm_env
 217            (ClassOpSig op_name sig_dm op_ty src_loc)
 218   = tcAddSrcLoc src_loc $
 219
 220         -- Check the type signature.  NB that the envt *already has*
 221         -- bindings for the type variables; see comments in TcTyAndClassDcls.
 222     tcHsType op_ty                      `thenTc` \ local_ty ->
 223
 224     let
 225         theta = [mkClassPred clas (mkTyVarTys clas_tyvars)]
 226
 227         -- Build the selector id and default method id
 228         sel_id = mkDictSelId op_name clas
 229         DefMeth dm_name = sig_dm
 230
 231         dm_info = case maybe_dm_env of
 232                     Nothing     -> sig_dm
 233                     Just dm_env -> mk_src_dm_info dm_env
 234
 235         mk_src_dm_info dm_env = case lookupNameEnv dm_env op_name of
 236                                    Nothing    -> NoDefMeth
 237                                    Just True  -> GenDefMeth
 238                                    Just False -> DefMeth dm_name
 239     in
 240     returnTc (local_ty, (sel_id, dm_info))
 241 \end{code}
 242
 243
 244 %************************************************************************
 245 %*                                                                      *
 246 \subsection[Default methods]{Default methods}
 247 %*                                                                      *
 248 %************************************************************************
 249
 250 The default methods for a class are each passed a dictionary for the
 251 class, so that they get access to the other methods at the same type.
 252 So, given the class decl
 253 \begin{verbatim}
 254 class Foo a where
 255         op1 :: a -> Bool
 256         op2 :: Ord b => a -> b -> b -> b
 257
 258         op1 x = True
 259         op2 x y z = if (op1 x) && (y < z) then y else z
 260 \end{verbatim}
 261 we get the default methods:
 262 \begin{verbatim}
 263 defm.Foo.op1 :: forall a. Foo a => a -> Bool
 264 defm.Foo.op1 = /\a -> \dfoo -> \x -> True
 265
 266 defm.Foo.op2 :: forall a. Foo a => forall b. Ord b => a -> b -> b -> b
 267 defm.Foo.op2 = /\ a -> \ dfoo -> /\ b -> \ dord -> \x y z ->
 268                   if (op1 a dfoo x) && (< b dord y z) then y else z
 269 \end{verbatim}
 270
 271 When we come across an instance decl, we may need to use the default
 272 methods:
 273 \begin{verbatim}
 274 instance Foo Int where {}
 275 \end{verbatim}
 276 gives
 277 \begin{verbatim}
 278 const.Foo.Int.op1 :: Int -> Bool
 279 const.Foo.Int.op1 = defm.Foo.op1 Int dfun.Foo.Int
 280
 281 const.Foo.Int.op2 :: forall b. Ord b => Int -> b -> b -> b
 282 const.Foo.Int.op2 = defm.Foo.op2 Int dfun.Foo.Int
 283
 284 dfun.Foo.Int :: Foo Int
 285 dfun.Foo.Int = (const.Foo.Int.op1, const.Foo.Int.op2)
 286 \end{verbatim}
 287 Notice that, as with method selectors above, we assume that dictionary
 288 application is curried, so there's no need to mention the Ord dictionary
 289 in const.Foo.Int.op2 (or the type variable).
 290
 291 \begin{verbatim}
 292 instance Foo a => Foo [a] where {}
 293
 294 dfun.Foo.List :: forall a. Foo a -> Foo [a]
 295 dfun.Foo.List
 296   = /\ a -> \ dfoo_a ->
 297     let rec
 298         op1 = defm.Foo.op1 [a] dfoo_list
 299         op2 = defm.Foo.op2 [a] dfoo_list
 300         dfoo_list = (op1, op2)
 301     in
 302         dfoo_list
 303 \end{verbatim}
 304
 305 The function @tcClassDecls2@ just arranges to apply @tcClassDecl2@ to
 306 each local class decl.
 307
 308 \begin{code}
 309 tcClassDecls2 :: Module -> [RenamedTyClDecl] -> NF_TcM (LIE, TcMonoBinds, [Id])
 310
 311 tcClassDecls2 this_mod decls
 312   = foldr combine
 313           (returnNF_Tc (emptyLIE, EmptyMonoBinds, []))
 314           [tcClassDecl2 cls_decl | cls_decl@(ClassDecl {tcdMeths = Just _}) <- decls]
 315                 -- The 'Just' picks out source ClassDecls
 316   where
 317     combine tc1 tc2 = tc1 `thenNF_Tc` \ (lie1, binds1, ids1) ->
 318                       tc2 `thenNF_Tc` \ (lie2, binds2, ids2) ->
 319                       returnNF_Tc (lie1 `plusLIE` lie2,
 320                                    binds1 `AndMonoBinds` binds2,
 321                                    ids1 ++ ids2)
 322 \end{code}
 323
 324 @tcClassDecl2@ generates bindings for polymorphic default methods
 325 (generic default methods have by now turned into instance declarations)
 326
 327 \begin{code}
 328 tcClassDecl2 :: RenamedTyClDecl         -- The class declaration
 329              -> NF_TcM (LIE, TcMonoBinds, [Id])
 330
 331 tcClassDecl2 (ClassDecl {tcdName = class_name, tcdSigs = sigs,
 332                          tcdMeths = Just default_binds, tcdLoc = src_loc})
 333   =     -- The 'Just' picks out source ClassDecls
 334     recoverNF_Tc (returnNF_Tc (emptyLIE, EmptyMonoBinds, [])) $
 335     tcAddSrcLoc src_loc                                   $
 336     tcLookupClass class_name                              `thenNF_Tc` \ clas ->
 337
 338         -- We make a separate binding for each default method.
 339         -- At one time I used a single AbsBinds for all of them, thus
 340         -- AbsBind [d] [dm1, dm2, dm3] { dm1 = ...; dm2 = ...; dm3 = ... }
 341         -- But that desugars into
 342         --      ds = \d -> (..., ..., ...)
 343         --      dm1 = \d -> case ds d of (a,b,c) -> a
 344         -- And since ds is big, it doesn't get inlined, so we don't get good
 345         -- default methods.  Better to make separate AbsBinds for each
 346     let
 347         (tyvars, _, _, op_items) = classBigSig clas
 348         prags                    = filter isPragSig sigs
 349         tc_dm                    = tcDefMeth clas tyvars default_binds prags
 350     in
 351     mapAndUnzip3Tc tc_dm op_items       `thenTc` \ (defm_binds, const_lies, dm_ids_s) ->
 352
 353     returnTc (plusLIEs const_lies, andMonoBindList defm_binds, concat dm_ids_s)
 354
 355
 356 tcDefMeth clas tyvars binds_in prags (_, NoDefMeth)  = returnTc (EmptyMonoBinds, emptyLIE, [])
 357 tcDefMeth clas tyvars binds_in prags (_, GenDefMeth) = returnTc (EmptyMonoBinds, emptyLIE, [])
 358         -- Generate code for polymorphic default methods only
 359         -- (Generic default methods have turned into instance decls by now.)
 360         -- This is incompatible with Hugs, which expects a polymorphic
 361         -- default method for every class op, regardless of whether or not
 362         -- the programmer supplied an explicit default decl for the class.
 363         -- (If necessary we can fix that, but we don't have a convenient Id to hand.)
 364
 365 tcDefMeth clas tyvars binds_in prags op_item@(sel_id, DefMeth dm_name)
 366   = tcInstTyVars ClsTv tyvars           `thenNF_Tc` \ (clas_tyvars, inst_tys, _) ->
 367     let
 368         dm_ty = idType sel_id   -- Same as dict selector!
 369           -- The default method's type should really come from the
 370           -- iface file, since it could be usage-generalised, but this
 371           -- requires altering the mess of knots in TcModule and I'm
 372           -- too scared to do that.  Instead, I have disabled generalisation
 373           -- of types of default methods (and dict funs) by annotating them
 374           -- TyGenNever (in MkId).  Ugh!  KSW 1999-09.
 375
 376         theta       = [mkClassPred clas inst_tys]
 377         dm_id       = mkDefaultMethodId dm_name dm_ty
 378         local_dm_id = setIdLocalExported dm_id
 379                 -- Reason for setIdLocalExported: see notes with MkId.mkDictFunId
 380         xtve = tyvars `zip` clas_tyvars
 381     in
 382     newDicts origin theta                               `thenNF_Tc` \ [this_dict] ->
 383
 384     mkMethodBind origin clas inst_tys binds_in op_item  `thenTc` \ (dm_inst, meth_info) ->
 385     tcMethodBind xtve clas_tyvars theta
 386                  [this_dict] meth_info                  `thenTc` \ (defm_bind, insts_needed) ->
 387
 388     tcAddErrCtxt (defltMethCtxt clas) $
 389
 390         -- Check the context
 391     tcSimplifyCheck
 392         (ptext SLIT("class") <+> ppr clas)
 393         clas_tyvars
 394         [this_dict]
 395         insts_needed                    `thenTc` \ (const_lie, dict_binds) ->
 396
 397         -- Simplification can do unification
 398     checkSigTyVars clas_tyvars          `thenTc` \ clas_tyvars' ->
 399
 400     let
 401         full_bind = AbsBinds
 402                     clas_tyvars'
 403                     [instToId this_dict]
 404                     [(clas_tyvars', local_dm_id, instToId dm_inst)]
 405                     emptyNameSet        -- No inlines (yet)
 406                     (dict_binds `andMonoBinds` defm_bind)
 407     in
 408     returnTc (full_bind, const_lie, [dm_id])
 409   where
 410     origin = ClassDeclOrigin
 411 \end{code}
 412
 413
 414
 415 %************************************************************************
 416 %*                                                                      *
 417 \subsection{Typechecking a method}
 418 %*                                                                      *
 419 %************************************************************************
 420
 421 @tcMethodBind@ is used to type-check both default-method and
 422 instance-decl method declarations.  We must type-check methods one at a
 423 time, because their signatures may have different contexts and
 424 tyvar sets.
 425
 426 \begin{code}
 427 tcMethodBind
 428         :: [(TyVar,TcTyVar)]    -- Bindings for type environment
 429         -> [TcTyVar]            -- Instantiated type variables for the
 430                                 --      enclosing class/instance decl.
 431                                 --      They'll be signature tyvars, and we
 432                                 --      want to check that they don't get bound
 433                                 -- Always equal the range of the type envt
 434         -> TcThetaType          -- Available theta; it's just used for the error message
 435         -> [Inst]               -- Available from context, used to simplify constraints
 436                                 --      from the method body
 437         -> (Id, TcSigInfo, RenamedMonoBinds)    -- Details of this method
 438         -> TcM (TcMonoBinds, LIE)
 439
 440 tcMethodBind xtve inst_tyvars inst_theta avail_insts
 441              (sel_id, meth_sig, meth_bind)
 442   =
 443         -- Check the bindings; first adding inst_tyvars to the envt
 444         -- so that we don't quantify over them in nested places
 445      tcExtendTyVarEnv2 xtve (
 446         tcAddErrCtxt (methodCtxt sel_id)                $
 447         tcMonoBinds meth_bind [meth_sig] NonRecursive
 448      )                                                  `thenTc` \ (meth_bind, meth_lie, _, _) ->
 449
 450         -- Now do context reduction.   We simplify wrt both the local tyvars
 451         -- and the ones of the class/instance decl, so that there is
 452         -- no problem with
 453         --      class C a where
 454         --        op :: Eq a => a -> b -> a
 455         --
 456         -- We do this for each method independently to localise error messages
 457
 458      let
 459         TySigInfo meth_id meth_tvs meth_theta _ local_meth_id _ _ = meth_sig
 460      in
 461      tcAddErrCtxtM (sigCtxt sel_id inst_tyvars inst_theta (idType meth_id))     $
 462      newDicts SignatureOrigin meth_theta                `thenNF_Tc` \ meth_dicts ->
 463      let
 464         all_tyvars = meth_tvs ++ inst_tyvars
 465         all_insts  = avail_insts ++ meth_dicts
 466      in
 467      tcSimplifyCheck
 468          (ptext SLIT("class or instance method") <+> quotes (ppr sel_id))
 469          all_tyvars all_insts meth_lie                  `thenTc` \ (lie, lie_binds) ->
 470
 471      checkSigTyVars all_tyvars                          `thenTc` \ all_tyvars' ->
 472
 473      let
 474         meth_tvs'      = take (length meth_tvs) all_tyvars'
 475         poly_meth_bind = AbsBinds meth_tvs'
 476                                   (map instToId meth_dicts)
 477                                   [(meth_tvs', meth_id, local_meth_id)]
 478                                   emptyNameSet  -- Inlines?
 479                                   (lie_binds `andMonoBinds` meth_bind)
 480      in
 481      returnTc (poly_meth_bind, lie)
 482
 483
 484 mkMethodBind :: InstOrigin
 485              -> Class -> [TcType]       -- Class and instance types
 486              -> RenamedMonoBinds        -- Method binding (pick the right one from in here)
 487              -> ClassOpItem
 488              -> TcM (Inst,              -- Method inst
 489                      (Id,                       -- Global selector Id
 490                       TcSigInfo,                -- Signature
 491                       RenamedMonoBinds))        -- Binding for the method
 492
 493 mkMethodBind origin clas inst_tys meth_binds (sel_id, dm_info)
 494   = tcGetSrcLoc                         `thenNF_Tc` \ loc ->
 495     newMethod origin sel_id inst_tys    `thenNF_Tc` \ meth_inst ->
 496     let
 497         meth_id    = instToId meth_inst
 498         meth_name  = idName meth_id
 499     in
 500         -- Figure out what method binding to use
 501         -- If the user suppplied one, use it, else construct a default one
 502     (case find_bind (idName sel_id) meth_name meth_binds of
 503         Just user_bind -> returnTc user_bind
 504         Nothing        -> mkDefMethRhs origin clas inst_tys sel_id loc dm_info  `thenTc` \ rhs ->
 505                           returnTc (FunMonoBind meth_name False -- Not infix decl
 506                                                 [mkSimpleMatch [] rhs placeHolderType loc] loc)
 507     )                                                           `thenTc` \ meth_bind ->
 508
 509     mkTcSig meth_id loc                 `thenNF_Tc` \ meth_sig ->
 510
 511     returnTc (meth_inst, (sel_id, meth_sig, meth_bind))
 512
 513
 514      -- The user didn't supply a method binding,
 515      -- so we have to make up a default binding
 516      -- The RHS of a default method depends on the default-method info
 517 mkDefMethRhs origin clas inst_tys sel_id loc (DefMeth dm_name)
 518   =  -- An polymorphic default method
 519     returnTc (HsVar dm_name)
 520
 521 mkDefMethRhs origin clas inst_tys sel_id loc NoDefMeth
 522   =     -- No default method
 523         -- Warn only if -fwarn-missing-methods
 524     doptsTc Opt_WarnMissingMethods              `thenNF_Tc` \ warn ->
 525     warnTc (isInstDecl origin && warn)
 526            (omittedMethodWarn sel_id)           `thenNF_Tc_`
 527     returnTc error_rhs
 528   where
 529     error_rhs = HsApp (HsVar (getName nO_METHOD_BINDING_ERROR_ID))
 530                           (HsLit (HsString (_PK_ error_msg)))
 531     error_msg = showSDoc (hcat [ppr loc, text "|", ppr sel_id ])
 532
 533
 534 mkDefMethRhs origin clas inst_tys sel_id loc GenDefMeth
 535   =     -- A generic default method
 536         -- If the method is defined generically, we can only do the job if the
 537         -- instance declaration is for a single-parameter type class with
 538         -- a type constructor applied to type arguments in the instance decl
 539         --      (checkTc, so False provokes the error)
 540      ASSERT( isInstDecl origin )        -- We never get here from a class decl
 541
 542      checkTc (isJust maybe_tycon)
 543              (badGenericInstance sel_id (notSimple inst_tys))   `thenTc_`
 544      checkTc (isJust (tyConGenInfo tycon))
 545              (badGenericInstance sel_id (notGeneric tycon))                     `thenTc_`
 546
 547      ioToTc (dumpIfSet opt_PprStyle_Debug "Generic RHS" stuff)  `thenNF_Tc_`
 548      returnTc rhs
 549   where
 550     rhs = mkGenericRhs sel_id clas_tyvar tycon
 551
 552     stuff = vcat [ppr clas <+> ppr inst_tys,
 553                   nest 4 (ppr sel_id <+> equals <+> ppr rhs)]
 554
 555           -- The tycon is only used in the generic case, and in that
 556           -- case we require that the instance decl is for a single-parameter
 557           -- type class with type variable arguments:
 558           --    instance (...) => C (T a b)
 559     clas_tyvar    = head (classTyVars clas)
 560     Just tycon    = maybe_tycon
 561     maybe_tycon   = case inst_tys of
 562                         [ty] -> case tcSplitTyConApp_maybe ty of
 563                                   Just (tycon, arg_tys) | all tcIsTyVarTy arg_tys -> Just tycon
 564                                   other                                           -> Nothing
 565                         other -> Nothing
 566
 567 isInstDecl InstanceDeclOrigin = True
 568 isInstDecl ClassDeclOrigin    = False
 569 \end{code}
 570
 571
 572 \begin{code}
 573 -- The renamer just puts the selector ID as the binder in the method binding
 574 -- but we must use the method name; so we substitute it here.  Crude but simple.
 575 find_bind sel_name meth_name (FunMonoBind op_name fix matches loc)
 576     | op_name == sel_name = Just (FunMonoBind meth_name fix matches loc)
 577 find_bind sel_name meth_name (AndMonoBinds b1 b2)
 578     = find_bind sel_name meth_name b1 `seqMaybe` find_bind sel_name meth_name b2
 579 find_bind sel_name meth_name other  = Nothing   -- Default case
 580
 581  -- Find the prags for this method, and replace the
 582  -- selector name with the method name
 583 find_prags sel_name meth_name [] = []
 584 find_prags sel_name meth_name (SpecSig name ty loc : prags)
 585      | name == sel_name = SpecSig meth_name ty loc : find_prags sel_name meth_name prags
 586 find_prags sel_name meth_name (InlineSig sense name phase loc : prags)
 587    | name == sel_name = InlineSig sense meth_name phase loc : find_prags sel_name meth_name prags
 588 find_prags sel_name meth_name (prag:prags) = find_prags sel_name meth_name prags
 589 \end{code}
 590
 591
 592 Contexts and errors
 593 ~~~~~~~~~~~~~~~~~~~
 594 \begin{code}
 595 defltMethCtxt clas
 596   = ptext SLIT("When checking the default methods for class") <+> quotes (ppr clas)
 597
 598 methodCtxt sel_id
 599   = ptext SLIT("In the definition for method") <+> quotes (ppr sel_id)
 600
 601 badMethodErr clas op
 602   = hsep [ptext SLIT("Class"), quotes (ppr clas),
 603           ptext SLIT("does not have a method"), quotes (ppr op)]
 604
 605 omittedMethodWarn sel_id
 606   = ptext SLIT("No explicit method nor default method for") <+> quotes (ppr sel_id)
 607
 608 badGenericInstance sel_id because
 609   = sep [ptext SLIT("Can't derive generic code for") <+> quotes (ppr sel_id),
 610          because]
 611
 612 notSimple inst_tys
 613   = vcat [ptext SLIT("because the instance type(s)"),
 614           nest 2 (ppr inst_tys),
 615           ptext SLIT("is not a simple type of form (T a b c)")]
 616
 617 notGeneric tycon
 618   = vcat [ptext SLIT("because the instance type constructor") <+> quotes (ppr tycon) <+>
 619           ptext SLIT("was not compiled with -fgenerics")]
 620
 621 mixedGenericErr op
 622   = ptext SLIT("Can't mix generic and non-generic equations for class method") <+> quotes (ppr op)
 623 \end{code}