ghc/compiler/typecheck/TcClassDcl.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcClassDcl]{Typechecking class declarations}
   5
   6 \begin{code}
   7 module TcClassDcl ( tcClassDecl1, checkValidClass, tcClassDecls2,
   8                     tcMethodBind, badMethodErr
   9                   ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn            ( TyClDecl(..), Sig(..), MonoBinds(..),
  14                           HsExpr(..), HsLit(..),
  15                           mkSimpleMatch, andMonoBinds, andMonoBindList,
  16                           isClassOpSig, isPragSig,
  17                           getClassDeclSysNames, placeHolderType
  18                         )
  19 import BasicTypes       ( TopLevelFlag(..), RecFlag(..), StrictnessMark(..) )
  20 import RnHsSyn          ( RenamedTyClDecl,
  21                           RenamedClassOpSig, RenamedMonoBinds,
  22                           RenamedSig, maybeGenericMatch
  23                         )
  24 import TcHsSyn          ( TcMonoBinds )
  25
  26 import Inst             ( Inst, InstOrigin(..), LIE, emptyLIE, plusLIE, plusLIEs,
  27                           instToId, newDicts, newMethod )
  28 import TcEnv            ( RecTcEnv, TyThingDetails(..), tcAddImportedIdInfo,
  29                           tcLookupClass, tcExtendTyVarEnvForMeths, tcExtendGlobalTyVars,
  30                           tcExtendLocalValEnv, tcExtendTyVarEnv
  31                         )
  32 import TcBinds          ( tcBindWithSigs, tcSpecSigs )
  33 import TcMonoType       ( tcHsType, tcHsTheta, checkSigTyVars, sigCtxt, mkTcSig )
  34 import TcSimplify       ( tcSimplifyCheck, bindInstsOfLocalFuns )
  35 import TcMType          ( tcInstTyVars, checkValidTheta, checkValidType, SourceTyCtxt(..), UserTypeCtxt(..) )
  36 import TcType           ( Type, mkSigmaTy, mkTyVarTys, mkPredTys, mkClassPred,
  37                           tcIsTyVarTy, tcSplitTyConApp_maybe, tcSplitSigmaTy
  38                         )
  39 import TcMonad
  40 import Generics         ( mkGenericRhs, validGenericMethodType )
  41 import PrelInfo         ( nO_METHOD_BINDING_ERROR_ID )
  42 import Class            ( classTyVars, classBigSig, classTyCon, className,
  43                           Class, ClassOpItem, DefMeth (..) )
  44 import MkId             ( mkDictSelId, mkDataConId, mkDataConWrapId, mkDefaultMethodId )
  45 import DataCon          ( mkDataCon )
  46 import Id               ( idType, idName, setIdLocalExported )
  47 import Module           ( Module )
  48 import Name             ( Name, NamedThing(..) )
  49 import NameEnv          ( NameEnv, lookupNameEnv, emptyNameEnv, unitNameEnv, plusNameEnv )
  50 import NameSet          ( emptyNameSet )
  51 import Outputable
  52 import Var              ( TyVar )
  53 import VarSet           ( mkVarSet, emptyVarSet )
  54 import CmdLineOpts
  55 import ErrUtils         ( dumpIfSet )
  56 import Util             ( count, isSingleton, lengthIs, equalLength )
  57 import Maybes           ( seqMaybe, maybeToBool )
  58 \end{code}
  59
  60
  61
  62 Dictionary handling
  63 ~~~~~~~~~~~~~~~~~~~
  64 Every class implicitly declares a new data type, corresponding to dictionaries
  65 of that class. So, for example:
  66
  67         class (D a) => C a where
  68           op1 :: a -> a
  69           op2 :: forall b. Ord b => a -> b -> b
  70
  71 would implicitly declare
  72
  73         data CDict a = CDict (D a)
  74                              (a -> a)
  75                              (forall b. Ord b => a -> b -> b)
  76
  77 (We could use a record decl, but that means changing more of the existing apparatus.
  78 One step at at time!)
  79
  80 For classes with just one superclass+method, we use a newtype decl instead:
  81
  82         class C a where
  83           op :: forallb. a -> b -> b
  84
  85 generates
  86
  87         newtype CDict a = CDict (forall b. a -> b -> b)
  88
  89 Now DictTy in Type is just a form of type synomym:
  90         DictTy c t = TyConTy CDict `AppTy` t
  91
  92 Death to "ExpandingDicts".
  93
  94
  95 %************************************************************************
  96 %*                                                                      *
  97 \subsection{Type checking}
  98 %*                                                                      *
  99 %************************************************************************
 100
 101 \begin{code}
 102
 103 tcClassDecl1 :: RecTcEnv -> RenamedTyClDecl -> TcM (Name, TyThingDetails)
 104 tcClassDecl1 rec_env
 105              (ClassDecl {tcdCtxt = context, tcdName = class_name,
 106                          tcdTyVars = tyvar_names, tcdFDs = fundeps,
 107                          tcdSigs = class_sigs, tcdMeths = def_methods,
 108                          tcdSysNames = sys_names, tcdLoc = src_loc})
 109   =     -- LOOK THINGS UP IN THE ENVIRONMENT
 110     tcLookupClass class_name                            `thenTc` \ clas ->
 111     let
 112         tyvars   = classTyVars clas
 113         op_sigs  = filter isClassOpSig class_sigs
 114         op_names = [n | ClassOpSig n _ _ _ <- op_sigs]
 115         (_, datacon_name, datacon_wkr_name, sc_sel_names) = getClassDeclSysNames sys_names
 116     in
 117     tcExtendTyVarEnv tyvars                             $
 118
 119     checkDefaultBinds clas op_names def_methods   `thenTc` \ mb_dm_env ->
 120
 121         -- CHECK THE CONTEXT
 122         -- The renamer has already checked that the context mentions
 123         -- only the type variable of the class decl.
 124         -- Context is already kind-checked
 125     ASSERT( equalLength context sc_sel_names )
 126     tcHsTheta context                                           `thenTc` \ sc_theta ->
 127
 128         -- CHECK THE CLASS SIGNATURES,
 129     mapTc (tcClassSig rec_env clas tyvars mb_dm_env) op_sigs    `thenTc` \ sig_stuff ->
 130
 131         -- MAKE THE CLASS DETAILS
 132     let
 133         (op_tys, op_items) = unzip sig_stuff
 134         sc_tys             = mkPredTys sc_theta
 135         dict_component_tys = sc_tys ++ op_tys
 136         sc_sel_ids         = [mkDictSelId sc_name clas | sc_name <- sc_sel_names]
 137
 138         dict_con = mkDataCon datacon_name
 139                              [NotMarkedStrict | _ <- dict_component_tys]
 140                              [{- No labelled fields -}]
 141                              tyvars
 142                              [{-No context-}]
 143                              [{-No existential tyvars-}] [{-Or context-}]
 144                              dict_component_tys
 145                              (classTyCon clas)
 146                              dict_con_id dict_wrap_id
 147
 148         dict_con_id  = mkDataConId datacon_wkr_name dict_con
 149         dict_wrap_id = mkDataConWrapId dict_con
 150     in
 151     returnTc (class_name, ClassDetails sc_theta sc_sel_ids op_items dict_con)
 152 \end{code}
 153
 154 \begin{code}
 155 checkDefaultBinds :: Class -> [Name] -> Maybe RenamedMonoBinds
 156                   -> TcM (Maybe (NameEnv Bool))
 157         -- The returned environment says
 158         --      x not in env => no default method
 159         --      x -> True    => generic default method
 160         --      x -> False   => polymorphic default method
 161
 162   -- Check default bindings
 163   --    a) must be for a class op for this class
 164   --    b) must be all generic or all non-generic
 165   -- and return a mapping from class-op to DefMeth info
 166
 167   -- But do all this only for source binds
 168
 169 checkDefaultBinds clas ops Nothing
 170   = returnTc Nothing
 171
 172 checkDefaultBinds clas ops (Just mbs)
 173   = go mbs      `thenTc` \ dm_env ->
 174     returnTc (Just dm_env)
 175   where
 176     go EmptyMonoBinds = returnTc emptyNameEnv
 177
 178     go (AndMonoBinds b1 b2)
 179       = go b1   `thenTc` \ dm_info1 ->
 180         go b2   `thenTc` \ dm_info2 ->
 181         returnTc (dm_info1 `plusNameEnv` dm_info2)
 182
 183     go (FunMonoBind op _ matches loc)
 184       = tcAddSrcLoc loc                                 $
 185
 186         -- Check that the op is from this class
 187         checkTc (op `elem` ops) (badMethodErr clas op)          `thenTc_`
 188
 189         -- Check that all the defns ar generic, or none are
 190         checkTc (all_generic || none_generic) (mixedGenericErr op)      `thenTc_`
 191
 192         returnTc (unitNameEnv op all_generic)
 193       where
 194         n_generic    = count (maybeToBool . maybeGenericMatch) matches
 195         none_generic = n_generic == 0
 196         all_generic  = matches `lengthIs` n_generic
 197 \end{code}
 198
 199
 200 \begin{code}
 201 tcClassSig :: RecTcEnv                  -- Knot tying only!
 202            -> Class                     -- ...ditto...
 203            -> [TyVar]                   -- The class type variable, used for error check only
 204            -> Maybe (NameEnv Bool)      -- Info about default methods;
 205                                         --      Nothing => imported class defn with no method binds
 206            -> RenamedClassOpSig
 207            -> TcM (Type,                -- Type of the method
 208                      ClassOpItem)       -- Selector Id, default-method Id, True if explicit default binding
 209
 210 -- This warrants an explanation: we need to separate generic
 211 -- default methods and default methods later on in the compiler
 212 -- so we distinguish them in checkDefaultBinds, and pass this knowledge in the
 213 -- Class.DefMeth data structure.
 214
 215 tcClassSig unf_env clas clas_tyvars maybe_dm_env
 216            (ClassOpSig op_name sig_dm op_ty src_loc)
 217   = tcAddSrcLoc src_loc $
 218
 219         -- Check the type signature.  NB that the envt *already has*
 220         -- bindings for the type variables; see comments in TcTyAndClassDcls.
 221     tcHsType op_ty                      `thenTc` \ local_ty ->
 222
 223     let
 224         theta = [mkClassPred clas (mkTyVarTys clas_tyvars)]
 225         global_ty = mkSigmaTy clas_tyvars theta local_ty
 226           -- The default method's type should really come from the
 227           -- iface file, since it could be usage-generalised, but this
 228           -- requires altering the mess of knots in TcModule and I'm
 229           -- too scared to do that.  Instead, I have disabled generalisation
 230           -- of types of default methods (and dict funs) by annotating them
 231           -- TyGenNever (in MkId).  Ugh!  KSW 1999-09.
 232
 233         -- Build the selector id and default method id
 234         sel_id = mkDictSelId op_name clas
 235         dm_id  = mkDefaultMethodId dm_name global_ty
 236         DefMeth dm_name = sig_dm
 237
 238         dm_info = case maybe_dm_env of
 239                     Nothing     -> iface_dm_info
 240                     Just dm_env -> mk_src_dm_info dm_env
 241
 242         iface_dm_info = case sig_dm of
 243                           NoDefMeth       -> NoDefMeth
 244                           GenDefMeth      -> GenDefMeth
 245                           DefMeth dm_name -> DefMeth (tcAddImportedIdInfo unf_env dm_id)
 246
 247         mk_src_dm_info dm_env = case lookupNameEnv dm_env op_name of
 248                                    Nothing    -> NoDefMeth
 249                                    Just True  -> GenDefMeth
 250                                    Just False -> DefMeth dm_id
 251     in
 252     returnTc (local_ty, (sel_id, dm_info))
 253 \end{code}
 254
 255 checkValidClass is called once the mutually-recursive knot has been
 256 tied, so we can look at things freely.
 257
 258 \begin{code}
 259 checkValidClass :: Class -> TcM ()
 260 checkValidClass cls
 261   =     -- CHECK ARITY 1 FOR HASKELL 1.4
 262     doptsTc Opt_GlasgowExts                             `thenTc` \ gla_exts ->
 263
 264         -- Check that the class is unary, unless GlaExs
 265     checkTc (not (null tyvars))         (nullaryClassErr cls)   `thenTc_`
 266     checkTc (gla_exts || unary) (classArityErr cls)     `thenTc_`
 267
 268         -- Check the super-classes
 269     checkValidTheta (ClassSCCtxt (className cls)) theta `thenTc_`
 270
 271         -- Check the class operations
 272     mapTc_ check_op op_stuff            `thenTc_`
 273
 274         -- Check that if the class has generic methods, then the
 275         -- class has only one parameter.  We can't do generic
 276         -- multi-parameter type classes!
 277     checkTc (unary || no_generics) (genericMultiParamErr cls)
 278
 279   where
 280     (tyvars, theta, _, op_stuff) = classBigSig cls
 281     unary       = isSingleton tyvars
 282     no_generics = null [() | (_, GenDefMeth) <- op_stuff]
 283
 284     check_op (sel_id, dm)
 285         = checkValidTheta SigmaCtxt (tail theta)        `thenTc_`
 286                 -- The 'tail' removes the initial (C a) from the
 287                 -- class itself, leaving just the method type
 288
 289           checkValidType (FunSigCtxt op_name) tau       `thenTc_`
 290
 291                 -- Check that for a generic method, the type of
 292                 -- the method is sufficiently simple
 293           checkTc (dm /= GenDefMeth || validGenericMethodType op_ty)
 294                   (badGenericMethodType op_name op_ty)
 295         where
 296           op_name = idName sel_id
 297           op_ty   = idType sel_id
 298           (_,theta,tau) = tcSplitSigmaTy op_ty
 299 \end{code}
 300
 301
 302 %************************************************************************
 303 %*                                                                      *
 304 \subsection[Default methods]{Default methods}
 305 %*                                                                      *
 306 %************************************************************************
 307
 308 The default methods for a class are each passed a dictionary for the
 309 class, so that they get access to the other methods at the same type.
 310 So, given the class decl
 311 \begin{verbatim}
 312 class Foo a where
 313         op1 :: a -> Bool
 314         op2 :: Ord b => a -> b -> b -> b
 315
 316         op1 x = True
 317         op2 x y z = if (op1 x) && (y < z) then y else z
 318 \end{verbatim}
 319 we get the default methods:
 320 \begin{verbatim}
 321 defm.Foo.op1 :: forall a. Foo a => a -> Bool
 322 defm.Foo.op1 = /\a -> \dfoo -> \x -> True
 323
 324 defm.Foo.op2 :: forall a. Foo a => forall b. Ord b => a -> b -> b -> b
 325 defm.Foo.op2 = /\ a -> \ dfoo -> /\ b -> \ dord -> \x y z ->
 326                   if (op1 a dfoo x) && (< b dord y z) then y else z
 327 \end{verbatim}
 328
 329 When we come across an instance decl, we may need to use the default
 330 methods:
 331 \begin{verbatim}
 332 instance Foo Int where {}
 333 \end{verbatim}
 334 gives
 335 \begin{verbatim}
 336 const.Foo.Int.op1 :: Int -> Bool
 337 const.Foo.Int.op1 = defm.Foo.op1 Int dfun.Foo.Int
 338
 339 const.Foo.Int.op2 :: forall b. Ord b => Int -> b -> b -> b
 340 const.Foo.Int.op2 = defm.Foo.op2 Int dfun.Foo.Int
 341
 342 dfun.Foo.Int :: Foo Int
 343 dfun.Foo.Int = (const.Foo.Int.op1, const.Foo.Int.op2)
 344 \end{verbatim}
 345 Notice that, as with method selectors above, we assume that dictionary
 346 application is curried, so there's no need to mention the Ord dictionary
 347 in const.Foo.Int.op2 (or the type variable).
 348
 349 \begin{verbatim}
 350 instance Foo a => Foo [a] where {}
 351
 352 dfun.Foo.List :: forall a. Foo a -> Foo [a]
 353 dfun.Foo.List
 354   = /\ a -> \ dfoo_a ->
 355     let rec
 356         op1 = defm.Foo.op1 [a] dfoo_list
 357         op2 = defm.Foo.op2 [a] dfoo_list
 358         dfoo_list = (op1, op2)
 359     in
 360         dfoo_list
 361 \end{verbatim}
 362
 363 The function @tcClassDecls2@ just arranges to apply @tcClassDecl2@ to
 364 each local class decl.
 365
 366 \begin{code}
 367 tcClassDecls2 :: Module -> [RenamedTyClDecl] -> NF_TcM (LIE, TcMonoBinds)
 368
 369 tcClassDecls2 this_mod decls
 370   = foldr combine
 371           (returnNF_Tc (emptyLIE, EmptyMonoBinds))
 372           [tcClassDecl2 cls_decl | cls_decl@(ClassDecl {tcdMeths = Just _}) <- decls]
 373                 -- The 'Just' picks out source ClassDecls
 374   where
 375     combine tc1 tc2 = tc1 `thenNF_Tc` \ (lie1, binds1) ->
 376                       tc2 `thenNF_Tc` \ (lie2, binds2) ->
 377                       returnNF_Tc (lie1 `plusLIE` lie2,
 378                                    binds1 `AndMonoBinds` binds2)
 379 \end{code}
 380
 381 @tcClassDecl2@ generates bindings for polymorphic default methods
 382 (generic default methods have by now turned into instance declarations)
 383
 384 \begin{code}
 385 tcClassDecl2 :: RenamedTyClDecl         -- The class declaration
 386              -> NF_TcM (LIE, TcMonoBinds)
 387
 388 tcClassDecl2 (ClassDecl {tcdName = class_name, tcdSigs = sigs,
 389                          tcdMeths = Just default_binds, tcdLoc = src_loc})
 390   =     -- The 'Just' picks out source ClassDecls
 391     recoverNF_Tc (returnNF_Tc (emptyLIE, EmptyMonoBinds)) $
 392     tcAddSrcLoc src_loc                                   $
 393     tcLookupClass class_name                              `thenNF_Tc` \ clas ->
 394
 395         -- We make a separate binding for each default method.
 396         -- At one time I used a single AbsBinds for all of them, thus
 397         -- AbsBind [d] [dm1, dm2, dm3] { dm1 = ...; dm2 = ...; dm3 = ... }
 398         -- But that desugars into
 399         --      ds = \d -> (..., ..., ...)
 400         --      dm1 = \d -> case ds d of (a,b,c) -> a
 401         -- And since ds is big, it doesn't get inlined, so we don't get good
 402         -- default methods.  Better to make separate AbsBinds for each
 403     let
 404         (tyvars, _, _, op_items) = classBigSig clas
 405         prags                    = filter isPragSig sigs
 406         tc_dm                    = tcDefMeth clas tyvars default_binds prags
 407     in
 408     mapAndUnzipTc tc_dm op_items        `thenTc` \ (defm_binds, const_lies) ->
 409
 410     returnTc (plusLIEs const_lies, andMonoBindList defm_binds)
 411
 412
 413 tcDefMeth clas tyvars binds_in prags (_, NoDefMeth)  = returnTc (EmptyMonoBinds, emptyLIE)
 414 tcDefMeth clas tyvars binds_in prags (_, GenDefMeth) = returnTc (EmptyMonoBinds, emptyLIE)
 415         -- Generate code for polymorphic default methods only
 416         -- (Generic default methods have turned into instance decls by now.)
 417         -- This is incompatible with Hugs, which expects a polymorphic
 418         -- default method for every class op, regardless of whether or not
 419         -- the programmer supplied an explicit default decl for the class.
 420         -- (If necessary we can fix that, but we don't have a convenient Id to hand.)
 421
 422 tcDefMeth clas tyvars binds_in prags op_item@(_, DefMeth dm_id)
 423   = tcInstTyVars tyvars                 `thenNF_Tc` \ (clas_tyvars, inst_tys, _) ->
 424     let
 425         theta = [(mkClassPred clas inst_tys)]
 426         local_dm_id = setIdLocalExported dm_id
 427                 -- Reason for setIdLocalExported: see notes with MkId.mkDictFunId
 428     in
 429     newDicts origin theta               `thenNF_Tc` \ [this_dict] ->
 430
 431     tcExtendTyVarEnvForMeths tyvars clas_tyvars (
 432         tcMethodBind clas origin clas_tyvars inst_tys theta
 433                      binds_in prags False op_item
 434     )                                   `thenTc` \ (defm_bind, insts_needed, local_dm_inst) ->
 435
 436     tcAddErrCtxt (defltMethCtxt clas) $
 437
 438         -- Check the context
 439     tcSimplifyCheck
 440         (ptext SLIT("class") <+> ppr clas)
 441         clas_tyvars
 442         [this_dict]
 443         insts_needed                            `thenTc` \ (const_lie, dict_binds) ->
 444
 445         -- Simplification can do unification
 446     checkSigTyVars clas_tyvars emptyVarSet      `thenTc` \ clas_tyvars' ->
 447
 448     let
 449         full_bind = AbsBinds
 450                     clas_tyvars'
 451                     [instToId this_dict]
 452                     [(clas_tyvars', local_dm_id, instToId local_dm_inst)]
 453                     emptyNameSet        -- No inlines (yet)
 454                     (dict_binds `andMonoBinds` defm_bind)
 455     in
 456     returnTc (full_bind, const_lie)
 457   where
 458     origin = ClassDeclOrigin
 459 \end{code}
 460
 461
 462
 463 %************************************************************************
 464 %*                                                                      *
 465 \subsection{Typechecking a method}
 466 %*                                                                      *
 467 %************************************************************************
 468
 469 @tcMethodBind@ is used to type-check both default-method and
 470 instance-decl method declarations.  We must type-check methods one at a
 471 time, because their signatures may have different contexts and
 472 tyvar sets.
 473
 474 \begin{code}
 475 tcMethodBind
 476         :: Class
 477         -> InstOrigin
 478         -> [TcTyVar]            -- Instantiated type variables for the
 479                                 --  enclosing class/instance decl.
 480                                 --  They'll be signature tyvars, and we
 481                                 --  want to check that they don't get bound
 482         -> [TcType]             -- Instance types
 483         -> TcThetaType          -- Available theta; this could be used to check
 484                                 --  the method signature, but actually that's done by
 485                                 --  the caller;  here, it's just used for the error message
 486         -> RenamedMonoBinds     -- Method binding (pick the right one from in here)
 487         -> [RenamedSig]         -- Pramgas (just for this one)
 488         -> Bool                 -- True <=> This method is from an instance declaration
 489         -> ClassOpItem          -- The method selector and default-method Id
 490         -> TcM (TcMonoBinds, LIE, Inst)
 491
 492 tcMethodBind clas origin inst_tyvars inst_tys inst_theta
 493              meth_binds prags is_inst_decl (sel_id, dm_info)
 494   = tcGetSrcLoc                         `thenNF_Tc` \ loc ->
 495     newMethod origin sel_id inst_tys    `thenNF_Tc` \ meth ->
 496     let
 497         meth_id    = instToId meth
 498         meth_name  = idName meth_id
 499         sig_msg    = ptext SLIT("When checking the expected type for class method") <+> ppr sel_id
 500         meth_prags = find_prags (idName sel_id) meth_name prags
 501     in
 502     mkTcSig meth_id loc                 `thenNF_Tc` \ sig_info ->
 503
 504         -- Figure out what method binding to use
 505         -- If the user suppplied one, use it, else construct a default one
 506     (case find_bind (idName sel_id) meth_name meth_binds of
 507         Just user_bind -> returnTc user_bind
 508         Nothing        -> mkDefMethRhs is_inst_decl clas inst_tys sel_id loc dm_info    `thenTc` \ rhs ->
 509                           returnTc (FunMonoBind meth_name False -- Not infix decl
 510                                                 [mkSimpleMatch [] rhs placeHolderType loc] loc)
 511     )                                                           `thenTc` \ meth_bind ->
 512      -- Check the bindings; first add inst_tyvars to the envt
 513      -- so that we don't quantify over them in nested places
 514      -- The *caller* put the class/inst decl tyvars into the envt
 515      tcExtendGlobalTyVars (mkVarSet inst_tyvars)
 516                     (tcAddErrCtxt (methodCtxt sel_id)           $
 517                      tcBindWithSigs NotTopLevel meth_bind
 518                                     [sig_info] meth_prags NonRecursive
 519                     )                                           `thenTc` \ (binds, insts, _) ->
 520
 521      tcExtendLocalValEnv [(meth_name, meth_id)]
 522                          (tcSpecSigs meth_prags)                `thenTc` \ (prag_binds1, prag_lie) ->
 523
 524      -- The prag_lie for a SPECIALISE pragma will mention the function
 525      -- itself, so we have to simplify them away right now lest they float
 526      -- outwards!
 527      bindInstsOfLocalFuns prag_lie [meth_id]    `thenTc` \ (prag_lie', prag_binds2) ->
 528
 529      -- Now check that the instance type variables
 530      -- (or, in the case of a class decl, the class tyvars)
 531      -- have not been unified with anything in the environment
 532      --
 533      -- We do this for each method independently to localise error messages
 534      -- ...and this is why the call to tcExtendGlobalTyVars must be here
 535      --    rather than in the caller
 536      tcAddErrCtxtM (sigCtxt sig_msg inst_tyvars inst_theta (idType meth_id))    $
 537      checkSigTyVars inst_tyvars emptyVarSet                                     `thenTc_`
 538
 539      returnTc (binds `AndMonoBinds` prag_binds1 `AndMonoBinds` prag_binds2,
 540                insts `plusLIE` prag_lie',
 541                meth)
 542
 543      -- The user didn't supply a method binding,
 544      -- so we have to make up a default binding
 545      -- The RHS of a default method depends on the default-method info
 546 mkDefMethRhs is_inst_decl clas inst_tys sel_id loc (DefMeth dm_id)
 547   =  -- An polymorphic default method
 548     returnTc (HsVar (idName dm_id))
 549
 550 mkDefMethRhs is_inst_decl clas inst_tys sel_id loc NoDefMeth
 551   =     -- No default method
 552         -- Warn only if -fwarn-missing-methods
 553     doptsTc Opt_WarnMissingMethods              `thenNF_Tc` \ warn ->
 554     warnTc (is_inst_decl && warn)
 555            (omittedMethodWarn sel_id)           `thenNF_Tc_`
 556     returnTc error_rhs
 557   where
 558     error_rhs = HsApp (HsVar (getName nO_METHOD_BINDING_ERROR_ID))
 559                           (HsLit (HsString (_PK_ error_msg)))
 560     error_msg = showSDoc (hcat [ppr loc, text "|", ppr sel_id ])
 561
 562
 563 mkDefMethRhs is_inst_decl clas inst_tys sel_id loc GenDefMeth
 564   =     -- A generic default method
 565         -- If the method is defined generically, we can only do the job if the
 566         -- instance declaration is for a single-parameter type class with
 567         -- a type constructor applied to type arguments in the instance decl
 568         --      (checkTc, so False provokes the error)
 569      checkTc (not is_inst_decl || simple_inst)
 570              (badGenericInstance sel_id)                        `thenTc_`
 571
 572      ioToTc (dumpIfSet opt_PprStyle_Debug "Generic RHS" stuff)  `thenNF_Tc_`
 573      returnTc rhs
 574   where
 575     rhs = mkGenericRhs sel_id clas_tyvar tycon
 576
 577     stuff = vcat [ppr clas <+> ppr inst_tys,
 578                   nest 4 (ppr sel_id <+> equals <+> ppr rhs)]
 579
 580           -- The tycon is only used in the generic case, and in that
 581           -- case we require that the instance decl is for a single-parameter
 582           -- type class with type variable arguments:
 583           --    instance (...) => C (T a b)
 584     simple_inst   = maybeToBool maybe_tycon
 585     clas_tyvar    = head (classTyVars clas)
 586     Just tycon    = maybe_tycon
 587     maybe_tycon   = case inst_tys of
 588                         [ty] -> case tcSplitTyConApp_maybe ty of
 589                                   Just (tycon, arg_tys) | all tcIsTyVarTy arg_tys -> Just tycon
 590                                   other                                           -> Nothing
 591                         other -> Nothing
 592 \end{code}
 593
 594
 595 \begin{code}
 596 -- The renamer just puts the selector ID as the binder in the method binding
 597 -- but we must use the method name; so we substitute it here.  Crude but simple.
 598 find_bind sel_name meth_name (FunMonoBind op_name fix matches loc)
 599     | op_name == sel_name = Just (FunMonoBind meth_name fix matches loc)
 600 find_bind sel_name meth_name (AndMonoBinds b1 b2)
 601     = find_bind sel_name meth_name b1 `seqMaybe` find_bind sel_name meth_name b2
 602 find_bind sel_name meth_name other  = Nothing   -- Default case
 603
 604  -- Find the prags for this method, and replace the
 605  -- selector name with the method name
 606 find_prags sel_name meth_name [] = []
 607 find_prags sel_name meth_name (SpecSig name ty loc : prags)
 608      | name == sel_name = SpecSig meth_name ty loc : find_prags sel_name meth_name prags
 609 find_prags sel_name meth_name (InlineSig sense name phase loc : prags)
 610    | name == sel_name = InlineSig sense meth_name phase loc : find_prags sel_name meth_name prags
 611 find_prags sel_name meth_name (prag:prags) = find_prags sel_name meth_name prags
 612 \end{code}
 613
 614
 615 Contexts and errors
 616 ~~~~~~~~~~~~~~~~~~~
 617 \begin{code}
 618 nullaryClassErr cls
 619   = ptext SLIT("No parameters for class")  <+> quotes (ppr cls)
 620
 621 classArityErr cls
 622   = vcat [ptext SLIT("Too many parameters for class") <+> quotes (ppr cls),
 623           parens (ptext SLIT("Use -fglasgow-exts to allow multi-parameter classes"))]
 624
 625 defltMethCtxt clas
 626   = ptext SLIT("When checking the default methods for class") <+> quotes (ppr clas)
 627
 628 methodCtxt sel_id
 629   = ptext SLIT("In the definition for method") <+> quotes (ppr sel_id)
 630
 631 badMethodErr clas op
 632   = hsep [ptext SLIT("Class"), quotes (ppr clas),
 633           ptext SLIT("does not have a method"), quotes (ppr op)]
 634
 635 omittedMethodWarn sel_id
 636   = ptext SLIT("No explicit method nor default method for") <+> quotes (ppr sel_id)
 637
 638 badGenericMethodType op op_ty
 639   = hang (ptext SLIT("Generic method type is too complex"))
 640        4 (vcat [ppr op <+> dcolon <+> ppr op_ty,
 641                 ptext SLIT("You can only use type variables, arrows, and tuples")])
 642
 643 badGenericInstance sel_id
 644   = sep [ptext SLIT("Can't derive generic code for") <+> quotes (ppr sel_id),
 645          ptext SLIT("because the instance declaration is not for a simple type (T a b c)"),
 646          ptext SLIT("(where T is a derivable type constructor)")]
 647
 648 mixedGenericErr op
 649   = ptext SLIT("Can't mix generic and non-generic equations for class method") <+> quotes (ppr op)
 650
 651 genericMultiParamErr clas
 652   = ptext SLIT("The multi-parameter class") <+> quotes (ppr clas) <+>
 653     ptext SLIT("cannot have generic methods")
 654 \end{code}