ghc/compiler/typecheck/TcClassDcl.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcClassDcl]{Typechecking class declarations}
   5
   6 \begin{code}
   7 module TcClassDcl ( tcClassDecl1, checkValidClass, tcClassDecls2,
   8                     tcMethodBind, mkMethodBind, badMethodErr
   9                   ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn            ( TyClDecl(..), Sig(..), MonoBinds(..),
  14                           HsExpr(..), HsLit(..),
  15                           mkSimpleMatch, andMonoBinds, andMonoBindList,
  16                           isClassOpSig, isPragSig,
  17                           getClassDeclSysNames, placeHolderType
  18                         )
  19 import BasicTypes       ( RecFlag(..), StrictnessMark(..) )
  20 import RnHsSyn          ( RenamedTyClDecl,
  21                           RenamedClassOpSig, RenamedMonoBinds,
  22                           maybeGenericMatch
  23                         )
  24 import TcHsSyn          ( TcMonoBinds )
  25
  26 import Inst             ( Inst, InstOrigin(..), LIE, emptyLIE, plusLIE, plusLIEs,
  27                           instToId, newDicts, newMethod )
  28 import TcEnv            ( TyThingDetails(..),
  29                           tcLookupClass, tcExtendTyVarEnv2,
  30                           tcExtendTyVarEnv
  31                         )
  32 import TcBinds          ( tcMonoBinds )
  33 import TcMonoType       ( TcSigInfo(..), tcHsType, tcHsTheta, mkTcSig )
  34 import TcSimplify       ( tcSimplifyCheck )
  35 import TcUnify          ( checkSigTyVars, sigCtxt )
  36 import TcMType          ( tcInstTyVars, checkValidTheta, checkValidType, SourceTyCtxt(..), UserTypeCtxt(..) )
  37 import TcType           ( Type, TyVarDetails(..), TcType, TcThetaType, TcTyVar,
  38                           mkTyVarTys, mkPredTys, mkClassPred,
  39                           tcIsTyVarTy, tcSplitTyConApp_maybe, tcSplitSigmaTy
  40                         )
  41 import TcMonad
  42 import Generics         ( mkGenericRhs, validGenericMethodType )
  43 import PrelInfo         ( nO_METHOD_BINDING_ERROR_ID )
  44 import Class            ( classTyVars, classBigSig, classTyCon, className,
  45                           Class, ClassOpItem, DefMeth (..) )
  46 import MkId             ( mkDictSelId, mkDataConId, mkDataConWrapId, mkDefaultMethodId )
  47 import DataCon          ( mkDataCon )
  48 import Id               ( Id, idType, idName, setIdLocalExported )
  49 import Module           ( Module )
  50 import Name             ( Name, NamedThing(..) )
  51 import NameEnv          ( NameEnv, lookupNameEnv, emptyNameEnv, unitNameEnv, plusNameEnv )
  52 import NameSet          ( emptyNameSet )
  53 import Outputable
  54 import Var              ( TyVar )
  55 import CmdLineOpts
  56 import ErrUtils         ( dumpIfSet )
  57 import Util             ( count, isSingleton, lengthIs, equalLength )
  58 import Maybes           ( seqMaybe, maybeToBool )
  59 \end{code}
  60
  61
  62
  63 Dictionary handling
  64 ~~~~~~~~~~~~~~~~~~~
  65 Every class implicitly declares a new data type, corresponding to dictionaries
  66 of that class. So, for example:
  67
  68         class (D a) => C a where
  69           op1 :: a -> a
  70           op2 :: forall b. Ord b => a -> b -> b
  71
  72 would implicitly declare
  73
  74         data CDict a = CDict (D a)
  75                              (a -> a)
  76                              (forall b. Ord b => a -> b -> b)
  77
  78 (We could use a record decl, but that means changing more of the existing apparatus.
  79 One step at at time!)
  80
  81 For classes with just one superclass+method, we use a newtype decl instead:
  82
  83         class C a where
  84           op :: forallb. a -> b -> b
  85
  86 generates
  87
  88         newtype CDict a = CDict (forall b. a -> b -> b)
  89
  90 Now DictTy in Type is just a form of type synomym:
  91         DictTy c t = TyConTy CDict `AppTy` t
  92
  93 Death to "ExpandingDicts".
  94
  95
  96 %************************************************************************
  97 %*                                                                      *
  98 \subsection{Type checking}
  99 %*                                                                      *
 100 %************************************************************************
 101
 102 \begin{code}
 103
 104 tcClassDecl1 :: RenamedTyClDecl -> TcM (Name, TyThingDetails)
 105 tcClassDecl1 (ClassDecl {tcdCtxt = context, tcdName = class_name,
 106                          tcdTyVars = tyvar_names, tcdFDs = fundeps,
 107                          tcdSigs = class_sigs, tcdMeths = def_methods,
 108                          tcdSysNames = sys_names, tcdLoc = src_loc})
 109   =     -- LOOK THINGS UP IN THE ENVIRONMENT
 110     tcLookupClass class_name                            `thenTc` \ clas ->
 111     let
 112         tyvars   = classTyVars clas
 113         op_sigs  = filter isClassOpSig class_sigs
 114         op_names = [n | ClassOpSig n _ _ _ <- op_sigs]
 115         (_, datacon_name, datacon_wkr_name, sc_sel_names) = getClassDeclSysNames sys_names
 116     in
 117     tcExtendTyVarEnv tyvars                             $
 118
 119     checkDefaultBinds clas op_names def_methods   `thenTc` \ mb_dm_env ->
 120
 121         -- CHECK THE CONTEXT
 122         -- The renamer has already checked that the context mentions
 123         -- only the type variable of the class decl.
 124         -- Context is already kind-checked
 125     ASSERT( equalLength context sc_sel_names )
 126     tcHsTheta context                                   `thenTc` \ sc_theta ->
 127
 128         -- CHECK THE CLASS SIGNATURES,
 129     mapTc (tcClassSig clas tyvars mb_dm_env) op_sigs    `thenTc` \ sig_stuff ->
 130
 131         -- MAKE THE CLASS DETAILS
 132     let
 133         (op_tys, op_items) = unzip sig_stuff
 134         sc_tys             = mkPredTys sc_theta
 135         dict_component_tys = sc_tys ++ op_tys
 136         sc_sel_ids         = [mkDictSelId sc_name clas | sc_name <- sc_sel_names]
 137
 138         dict_con = mkDataCon datacon_name
 139                              [NotMarkedStrict | _ <- dict_component_tys]
 140                              [{- No labelled fields -}]
 141                              tyvars
 142                              [{-No context-}]
 143                              [{-No existential tyvars-}] [{-Or context-}]
 144                              dict_component_tys
 145                              (classTyCon clas)
 146                              dict_con_id dict_wrap_id
 147
 148         dict_con_id  = mkDataConId datacon_wkr_name dict_con
 149         dict_wrap_id = mkDataConWrapId dict_con
 150     in
 151     returnTc (class_name, ClassDetails sc_theta sc_sel_ids op_items dict_con)
 152 \end{code}
 153
 154 \begin{code}
 155 checkDefaultBinds :: Class -> [Name] -> Maybe RenamedMonoBinds
 156                   -> TcM (Maybe (NameEnv Bool))
 157         -- The returned environment says
 158         --      x not in env => no default method
 159         --      x -> True    => generic default method
 160         --      x -> False   => polymorphic default method
 161
 162   -- Check default bindings
 163   --    a) must be for a class op for this class
 164   --    b) must be all generic or all non-generic
 165   -- and return a mapping from class-op to DefMeth info
 166
 167   -- But do all this only for source binds
 168
 169 checkDefaultBinds clas ops Nothing
 170   = returnTc Nothing
 171
 172 checkDefaultBinds clas ops (Just mbs)
 173   = go mbs      `thenTc` \ dm_env ->
 174     returnTc (Just dm_env)
 175   where
 176     go EmptyMonoBinds = returnTc emptyNameEnv
 177
 178     go (AndMonoBinds b1 b2)
 179       = go b1   `thenTc` \ dm_info1 ->
 180         go b2   `thenTc` \ dm_info2 ->
 181         returnTc (dm_info1 `plusNameEnv` dm_info2)
 182
 183     go (FunMonoBind op _ matches loc)
 184       = tcAddSrcLoc loc                                 $
 185
 186         -- Check that the op is from this class
 187         checkTc (op `elem` ops) (badMethodErr clas op)          `thenTc_`
 188
 189         -- Check that all the defns ar generic, or none are
 190         checkTc (all_generic || none_generic) (mixedGenericErr op)      `thenTc_`
 191
 192         returnTc (unitNameEnv op all_generic)
 193       where
 194         n_generic    = count (maybeToBool . maybeGenericMatch) matches
 195         none_generic = n_generic == 0
 196         all_generic  = matches `lengthIs` n_generic
 197 \end{code}
 198
 199
 200 \begin{code}
 201 tcClassSig :: Class                     -- ...ditto...
 202            -> [TyVar]                   -- The class type variable, used for error check only
 203            -> Maybe (NameEnv Bool)      -- Info about default methods;
 204                                         --      Nothing => imported class defn with no method binds
 205            -> RenamedClassOpSig
 206            -> TcM (Type,                -- Type of the method
 207                      ClassOpItem)       -- Selector Id, default-method Id, True if explicit default binding
 208
 209 -- This warrants an explanation: we need to separate generic
 210 -- default methods and default methods later on in the compiler
 211 -- so we distinguish them in checkDefaultBinds, and pass this knowledge in the
 212 -- Class.DefMeth data structure.
 213
 214 tcClassSig clas clas_tyvars maybe_dm_env
 215            (ClassOpSig op_name sig_dm op_ty src_loc)
 216   = tcAddSrcLoc src_loc $
 217
 218         -- Check the type signature.  NB that the envt *already has*
 219         -- bindings for the type variables; see comments in TcTyAndClassDcls.
 220     tcHsType op_ty                      `thenTc` \ local_ty ->
 221
 222     let
 223         theta = [mkClassPred clas (mkTyVarTys clas_tyvars)]
 224
 225         -- Build the selector id and default method id
 226         sel_id = mkDictSelId op_name clas
 227         DefMeth dm_name = sig_dm
 228
 229         dm_info = case maybe_dm_env of
 230                     Nothing     -> sig_dm
 231                     Just dm_env -> mk_src_dm_info dm_env
 232
 233         mk_src_dm_info dm_env = case lookupNameEnv dm_env op_name of
 234                                    Nothing    -> NoDefMeth
 235                                    Just True  -> GenDefMeth
 236                                    Just False -> DefMeth dm_name
 237     in
 238     returnTc (local_ty, (sel_id, dm_info))
 239 \end{code}
 240
 241 checkValidClass is called once the mutually-recursive knot has been
 242 tied, so we can look at things freely.
 243
 244 \begin{code}
 245 checkValidClass :: Class -> TcM ()
 246 checkValidClass cls
 247   =     -- CHECK ARITY 1 FOR HASKELL 1.4
 248     doptsTc Opt_GlasgowExts                             `thenTc` \ gla_exts ->
 249
 250         -- Check that the class is unary, unless GlaExs
 251     checkTc (not (null tyvars))         (nullaryClassErr cls)   `thenTc_`
 252     checkTc (gla_exts || unary) (classArityErr cls)     `thenTc_`
 253
 254         -- Check the super-classes
 255     checkValidTheta (ClassSCCtxt (className cls)) theta `thenTc_`
 256
 257         -- Check the class operations
 258     mapTc_ check_op op_stuff            `thenTc_`
 259
 260         -- Check that if the class has generic methods, then the
 261         -- class has only one parameter.  We can't do generic
 262         -- multi-parameter type classes!
 263     checkTc (unary || no_generics) (genericMultiParamErr cls)
 264
 265   where
 266     (tyvars, theta, _, op_stuff) = classBigSig cls
 267     unary       = isSingleton tyvars
 268     no_generics = null [() | (_, GenDefMeth) <- op_stuff]
 269
 270     check_op (sel_id, dm)
 271         = checkValidTheta SigmaCtxt (tail theta)        `thenTc_`
 272                 -- The 'tail' removes the initial (C a) from the
 273                 -- class itself, leaving just the method type
 274
 275           checkValidType (FunSigCtxt op_name) tau       `thenTc_`
 276
 277                 -- Check that for a generic method, the type of
 278                 -- the method is sufficiently simple
 279           checkTc (dm /= GenDefMeth || validGenericMethodType op_ty)
 280                   (badGenericMethodType op_name op_ty)
 281         where
 282           op_name = idName sel_id
 283           op_ty   = idType sel_id
 284           (_,theta,tau) = tcSplitSigmaTy op_ty
 285 \end{code}
 286
 287
 288 %************************************************************************
 289 %*                                                                      *
 290 \subsection[Default methods]{Default methods}
 291 %*                                                                      *
 292 %************************************************************************
 293
 294 The default methods for a class are each passed a dictionary for the
 295 class, so that they get access to the other methods at the same type.
 296 So, given the class decl
 297 \begin{verbatim}
 298 class Foo a where
 299         op1 :: a -> Bool
 300         op2 :: Ord b => a -> b -> b -> b
 301
 302         op1 x = True
 303         op2 x y z = if (op1 x) && (y < z) then y else z
 304 \end{verbatim}
 305 we get the default methods:
 306 \begin{verbatim}
 307 defm.Foo.op1 :: forall a. Foo a => a -> Bool
 308 defm.Foo.op1 = /\a -> \dfoo -> \x -> True
 309
 310 defm.Foo.op2 :: forall a. Foo a => forall b. Ord b => a -> b -> b -> b
 311 defm.Foo.op2 = /\ a -> \ dfoo -> /\ b -> \ dord -> \x y z ->
 312                   if (op1 a dfoo x) && (< b dord y z) then y else z
 313 \end{verbatim}
 314
 315 When we come across an instance decl, we may need to use the default
 316 methods:
 317 \begin{verbatim}
 318 instance Foo Int where {}
 319 \end{verbatim}
 320 gives
 321 \begin{verbatim}
 322 const.Foo.Int.op1 :: Int -> Bool
 323 const.Foo.Int.op1 = defm.Foo.op1 Int dfun.Foo.Int
 324
 325 const.Foo.Int.op2 :: forall b. Ord b => Int -> b -> b -> b
 326 const.Foo.Int.op2 = defm.Foo.op2 Int dfun.Foo.Int
 327
 328 dfun.Foo.Int :: Foo Int
 329 dfun.Foo.Int = (const.Foo.Int.op1, const.Foo.Int.op2)
 330 \end{verbatim}
 331 Notice that, as with method selectors above, we assume that dictionary
 332 application is curried, so there's no need to mention the Ord dictionary
 333 in const.Foo.Int.op2 (or the type variable).
 334
 335 \begin{verbatim}
 336 instance Foo a => Foo [a] where {}
 337
 338 dfun.Foo.List :: forall a. Foo a -> Foo [a]
 339 dfun.Foo.List
 340   = /\ a -> \ dfoo_a ->
 341     let rec
 342         op1 = defm.Foo.op1 [a] dfoo_list
 343         op2 = defm.Foo.op2 [a] dfoo_list
 344         dfoo_list = (op1, op2)
 345     in
 346         dfoo_list
 347 \end{verbatim}
 348
 349 The function @tcClassDecls2@ just arranges to apply @tcClassDecl2@ to
 350 each local class decl.
 351
 352 \begin{code}
 353 tcClassDecls2 :: Module -> [RenamedTyClDecl] -> NF_TcM (LIE, TcMonoBinds, [Id])
 354
 355 tcClassDecls2 this_mod decls
 356   = foldr combine
 357           (returnNF_Tc (emptyLIE, EmptyMonoBinds, []))
 358           [tcClassDecl2 cls_decl | cls_decl@(ClassDecl {tcdMeths = Just _}) <- decls]
 359                 -- The 'Just' picks out source ClassDecls
 360   where
 361     combine tc1 tc2 = tc1 `thenNF_Tc` \ (lie1, binds1, ids1) ->
 362                       tc2 `thenNF_Tc` \ (lie2, binds2, ids2) ->
 363                       returnNF_Tc (lie1 `plusLIE` lie2,
 364                                    binds1 `AndMonoBinds` binds2,
 365                                    ids1 ++ ids2)
 366 \end{code}
 367
 368 @tcClassDecl2@ generates bindings for polymorphic default methods
 369 (generic default methods have by now turned into instance declarations)
 370
 371 \begin{code}
 372 tcClassDecl2 :: RenamedTyClDecl         -- The class declaration
 373              -> NF_TcM (LIE, TcMonoBinds, [Id])
 374
 375 tcClassDecl2 (ClassDecl {tcdName = class_name, tcdSigs = sigs,
 376                          tcdMeths = Just default_binds, tcdLoc = src_loc})
 377   =     -- The 'Just' picks out source ClassDecls
 378     recoverNF_Tc (returnNF_Tc (emptyLIE, EmptyMonoBinds, [])) $
 379     tcAddSrcLoc src_loc                                   $
 380     tcLookupClass class_name                              `thenNF_Tc` \ clas ->
 381
 382         -- We make a separate binding for each default method.
 383         -- At one time I used a single AbsBinds for all of them, thus
 384         -- AbsBind [d] [dm1, dm2, dm3] { dm1 = ...; dm2 = ...; dm3 = ... }
 385         -- But that desugars into
 386         --      ds = \d -> (..., ..., ...)
 387         --      dm1 = \d -> case ds d of (a,b,c) -> a
 388         -- And since ds is big, it doesn't get inlined, so we don't get good
 389         -- default methods.  Better to make separate AbsBinds for each
 390     let
 391         (tyvars, _, _, op_items) = classBigSig clas
 392         prags                    = filter isPragSig sigs
 393         tc_dm                    = tcDefMeth clas tyvars default_binds prags
 394     in
 395     mapAndUnzip3Tc tc_dm op_items       `thenTc` \ (defm_binds, const_lies, dm_ids_s) ->
 396
 397     returnTc (plusLIEs const_lies, andMonoBindList defm_binds, concat dm_ids_s)
 398
 399
 400 tcDefMeth clas tyvars binds_in prags (_, NoDefMeth)  = returnTc (EmptyMonoBinds, emptyLIE, [])
 401 tcDefMeth clas tyvars binds_in prags (_, GenDefMeth) = returnTc (EmptyMonoBinds, emptyLIE, [])
 402         -- Generate code for polymorphic default methods only
 403         -- (Generic default methods have turned into instance decls by now.)
 404         -- This is incompatible with Hugs, which expects a polymorphic
 405         -- default method for every class op, regardless of whether or not
 406         -- the programmer supplied an explicit default decl for the class.
 407         -- (If necessary we can fix that, but we don't have a convenient Id to hand.)
 408
 409 tcDefMeth clas tyvars binds_in prags op_item@(sel_id, DefMeth dm_name)
 410   = tcInstTyVars ClsTv tyvars           `thenNF_Tc` \ (clas_tyvars, inst_tys, _) ->
 411     let
 412         dm_ty = idType sel_id   -- Same as dict selector!
 413           -- The default method's type should really come from the
 414           -- iface file, since it could be usage-generalised, but this
 415           -- requires altering the mess of knots in TcModule and I'm
 416           -- too scared to do that.  Instead, I have disabled generalisation
 417           -- of types of default methods (and dict funs) by annotating them
 418           -- TyGenNever (in MkId).  Ugh!  KSW 1999-09.
 419
 420         theta       = [mkClassPred clas inst_tys]
 421         dm_id       = mkDefaultMethodId dm_name dm_ty
 422         local_dm_id = setIdLocalExported dm_id
 423                 -- Reason for setIdLocalExported: see notes with MkId.mkDictFunId
 424         xtve = tyvars `zip` clas_tyvars
 425     in
 426     newDicts origin theta                               `thenNF_Tc` \ [this_dict] ->
 427
 428     mkMethodBind origin clas inst_tys binds_in op_item  `thenTc` \ (dm_inst, meth_info) ->
 429     tcMethodBind xtve clas_tyvars theta
 430                  [this_dict] meth_info                  `thenTc` \ (defm_bind, insts_needed) ->
 431
 432     tcAddErrCtxt (defltMethCtxt clas) $
 433
 434         -- Check the context
 435     tcSimplifyCheck
 436         (ptext SLIT("class") <+> ppr clas)
 437         clas_tyvars
 438         [this_dict]
 439         insts_needed                    `thenTc` \ (const_lie, dict_binds) ->
 440
 441         -- Simplification can do unification
 442     checkSigTyVars clas_tyvars          `thenTc` \ clas_tyvars' ->
 443
 444     let
 445         full_bind = AbsBinds
 446                     clas_tyvars'
 447                     [instToId this_dict]
 448                     [(clas_tyvars', local_dm_id, instToId dm_inst)]
 449                     emptyNameSet        -- No inlines (yet)
 450                     (dict_binds `andMonoBinds` defm_bind)
 451     in
 452     returnTc (full_bind, const_lie, [dm_id])
 453   where
 454     origin = ClassDeclOrigin
 455 \end{code}
 456
 457
 458
 459 %************************************************************************
 460 %*                                                                      *
 461 \subsection{Typechecking a method}
 462 %*                                                                      *
 463 %************************************************************************
 464
 465 @tcMethodBind@ is used to type-check both default-method and
 466 instance-decl method declarations.  We must type-check methods one at a
 467 time, because their signatures may have different contexts and
 468 tyvar sets.
 469
 470 \begin{code}
 471 tcMethodBind
 472         :: [(TyVar,TcTyVar)]    -- Bindings for type environment
 473         -> [TcTyVar]            -- Instantiated type variables for the
 474                                 --      enclosing class/instance decl.
 475                                 --      They'll be signature tyvars, and we
 476                                 --      want to check that they don't get bound
 477                                 -- Always equal the range of the type envt
 478         -> TcThetaType          -- Available theta; it's just used for the error message
 479         -> [Inst]               -- Available from context, used to simplify constraints
 480                                 --      from the method body
 481         -> (Id, TcSigInfo, RenamedMonoBinds)    -- Details of this method
 482         -> TcM (TcMonoBinds, LIE)
 483
 484 tcMethodBind xtve inst_tyvars inst_theta avail_insts
 485              (sel_id, meth_sig, meth_bind)
 486   =
 487         -- Check the bindings; first adding inst_tyvars to the envt
 488         -- so that we don't quantify over them in nested places
 489      tcExtendTyVarEnv2 xtve (
 490         tcAddErrCtxt (methodCtxt sel_id)                $
 491         tcMonoBinds meth_bind [meth_sig] NonRecursive
 492      )                                                  `thenTc` \ (meth_bind, meth_lie, _, _) ->
 493
 494         -- Now do context reduction.   We simplify wrt both the local tyvars
 495         -- and the ones of the class/instance decl, so that there is
 496         -- no problem with
 497         --      class C a where
 498         --        op :: Eq a => a -> b -> a
 499         --
 500         -- We do this for each method independently to localise error messages
 501
 502      let
 503         TySigInfo meth_id meth_tvs meth_theta _ local_meth_id _ _ = meth_sig
 504      in
 505      tcAddErrCtxtM (sigCtxt sel_id inst_tyvars inst_theta (idType meth_id))     $
 506      newDicts SignatureOrigin meth_theta                `thenNF_Tc` \ meth_dicts ->
 507      let
 508         all_tyvars = meth_tvs ++ inst_tyvars
 509         all_insts  = avail_insts ++ meth_dicts
 510      in
 511      tcSimplifyCheck
 512          (ptext SLIT("class or instance method") <+> quotes (ppr sel_id))
 513          all_tyvars all_insts meth_lie                  `thenTc` \ (lie, lie_binds) ->
 514
 515      checkSigTyVars all_tyvars                          `thenTc` \ all_tyvars' ->
 516
 517      let
 518         meth_tvs'      = take (length meth_tvs) all_tyvars'
 519         poly_meth_bind = AbsBinds meth_tvs'
 520                                   (map instToId meth_dicts)
 521                                   [(meth_tvs', meth_id, local_meth_id)]
 522                                   emptyNameSet  -- Inlines?
 523                                   (lie_binds `andMonoBinds` meth_bind)
 524      in
 525      returnTc (poly_meth_bind, lie)
 526
 527
 528 mkMethodBind :: InstOrigin
 529              -> Class -> [TcType]       -- Class and instance types
 530              -> RenamedMonoBinds        -- Method binding (pick the right one from in here)
 531              -> ClassOpItem
 532              -> TcM (Inst,              -- Method inst
 533                      (Id,                       -- Global selector Id
 534                       TcSigInfo,                -- Signature
 535                       RenamedMonoBinds))        -- Binding for the method
 536
 537 mkMethodBind origin clas inst_tys meth_binds (sel_id, dm_info)
 538   = tcGetSrcLoc                         `thenNF_Tc` \ loc ->
 539     newMethod origin sel_id inst_tys    `thenNF_Tc` \ meth_inst ->
 540     let
 541         meth_id    = instToId meth_inst
 542         meth_name  = idName meth_id
 543     in
 544         -- Figure out what method binding to use
 545         -- If the user suppplied one, use it, else construct a default one
 546     (case find_bind (idName sel_id) meth_name meth_binds of
 547         Just user_bind -> returnTc user_bind
 548         Nothing        -> mkDefMethRhs origin clas inst_tys sel_id loc dm_info  `thenTc` \ rhs ->
 549                           returnTc (FunMonoBind meth_name False -- Not infix decl
 550                                                 [mkSimpleMatch [] rhs placeHolderType loc] loc)
 551     )                                                           `thenTc` \ meth_bind ->
 552
 553     mkTcSig meth_id loc                 `thenNF_Tc` \ meth_sig ->
 554
 555     returnTc (meth_inst, (sel_id, meth_sig, meth_bind))
 556
 557
 558      -- The user didn't supply a method binding,
 559      -- so we have to make up a default binding
 560      -- The RHS of a default method depends on the default-method info
 561 mkDefMethRhs origin clas inst_tys sel_id loc (DefMeth dm_name)
 562   =  -- An polymorphic default method
 563     returnTc (HsVar dm_name)
 564
 565 mkDefMethRhs origin clas inst_tys sel_id loc NoDefMeth
 566   =     -- No default method
 567         -- Warn only if -fwarn-missing-methods
 568     doptsTc Opt_WarnMissingMethods              `thenNF_Tc` \ warn ->
 569     warnTc (isInstDecl origin && warn)
 570            (omittedMethodWarn sel_id)           `thenNF_Tc_`
 571     returnTc error_rhs
 572   where
 573     error_rhs = HsApp (HsVar (getName nO_METHOD_BINDING_ERROR_ID))
 574                           (HsLit (HsString (_PK_ error_msg)))
 575     error_msg = showSDoc (hcat [ppr loc, text "|", ppr sel_id ])
 576
 577
 578 mkDefMethRhs origin clas inst_tys sel_id loc GenDefMeth
 579   =     -- A generic default method
 580         -- If the method is defined generically, we can only do the job if the
 581         -- instance declaration is for a single-parameter type class with
 582         -- a type constructor applied to type arguments in the instance decl
 583         --      (checkTc, so False provokes the error)
 584      checkTc (not (isInstDecl origin) || simple_inst)
 585              (badGenericInstance sel_id)                        `thenTc_`
 586
 587      ioToTc (dumpIfSet opt_PprStyle_Debug "Generic RHS" stuff)  `thenNF_Tc_`
 588      returnTc rhs
 589   where
 590     rhs = mkGenericRhs sel_id clas_tyvar tycon
 591
 592     stuff = vcat [ppr clas <+> ppr inst_tys,
 593                   nest 4 (ppr sel_id <+> equals <+> ppr rhs)]
 594
 595           -- The tycon is only used in the generic case, and in that
 596           -- case we require that the instance decl is for a single-parameter
 597           -- type class with type variable arguments:
 598           --    instance (...) => C (T a b)
 599     simple_inst   = maybeToBool maybe_tycon
 600     clas_tyvar    = head (classTyVars clas)
 601     Just tycon    = maybe_tycon
 602     maybe_tycon   = case inst_tys of
 603                         [ty] -> case tcSplitTyConApp_maybe ty of
 604                                   Just (tycon, arg_tys) | all tcIsTyVarTy arg_tys -> Just tycon
 605                                   other                                           -> Nothing
 606                         other -> Nothing
 607
 608 isInstDecl InstanceDeclOrigin = True
 609 isInstDecl ClassDeclOrigin    = False
 610 \end{code}
 611
 612
 613 \begin{code}
 614 -- The renamer just puts the selector ID as the binder in the method binding
 615 -- but we must use the method name; so we substitute it here.  Crude but simple.
 616 find_bind sel_name meth_name (FunMonoBind op_name fix matches loc)
 617     | op_name == sel_name = Just (FunMonoBind meth_name fix matches loc)
 618 find_bind sel_name meth_name (AndMonoBinds b1 b2)
 619     = find_bind sel_name meth_name b1 `seqMaybe` find_bind sel_name meth_name b2
 620 find_bind sel_name meth_name other  = Nothing   -- Default case
 621
 622  -- Find the prags for this method, and replace the
 623  -- selector name with the method name
 624 find_prags sel_name meth_name [] = []
 625 find_prags sel_name meth_name (SpecSig name ty loc : prags)
 626      | name == sel_name = SpecSig meth_name ty loc : find_prags sel_name meth_name prags
 627 find_prags sel_name meth_name (InlineSig sense name phase loc : prags)
 628    | name == sel_name = InlineSig sense meth_name phase loc : find_prags sel_name meth_name prags
 629 find_prags sel_name meth_name (prag:prags) = find_prags sel_name meth_name prags
 630 \end{code}
 631
 632
 633 Contexts and errors
 634 ~~~~~~~~~~~~~~~~~~~
 635 \begin{code}
 636 nullaryClassErr cls
 637   = ptext SLIT("No parameters for class")  <+> quotes (ppr cls)
 638
 639 classArityErr cls
 640   = vcat [ptext SLIT("Too many parameters for class") <+> quotes (ppr cls),
 641           parens (ptext SLIT("Use -fglasgow-exts to allow multi-parameter classes"))]
 642
 643 defltMethCtxt clas
 644   = ptext SLIT("When checking the default methods for class") <+> quotes (ppr clas)
 645
 646 methodCtxt sel_id
 647   = ptext SLIT("In the definition for method") <+> quotes (ppr sel_id)
 648
 649 badMethodErr clas op
 650   = hsep [ptext SLIT("Class"), quotes (ppr clas),
 651           ptext SLIT("does not have a method"), quotes (ppr op)]
 652
 653 omittedMethodWarn sel_id
 654   = ptext SLIT("No explicit method nor default method for") <+> quotes (ppr sel_id)
 655
 656 badGenericMethodType op op_ty
 657   = hang (ptext SLIT("Generic method type is too complex"))
 658        4 (vcat [ppr op <+> dcolon <+> ppr op_ty,
 659                 ptext SLIT("You can only use type variables, arrows, and tuples")])
 660
 661 badGenericInstance sel_id
 662   = sep [ptext SLIT("Can't derive generic code for") <+> quotes (ppr sel_id),
 663          ptext SLIT("because the instance declaration is not for a simple type (T a b c)"),
 664          ptext SLIT("(where T is a derivable type constructor)")]
 665
 666 mixedGenericErr op
 667   = ptext SLIT("Can't mix generic and non-generic equations for class method") <+> quotes (ppr op)
 668
 669 genericMultiParamErr clas
 670   = ptext SLIT("The multi-parameter class") <+> quotes (ppr clas) <+>
 671     ptext SLIT("cannot have generic methods")
 672 \end{code}