ghc/compiler/typecheck/TcClassDcl.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcClassDcl]{Typechecking class declarations}
   5
   6 \begin{code}
   7 module TcClassDcl ( tcClassDecl1, tcClassDecls2, mkImplicitClassBinds,
   8                     tcMethodBind, badMethodErr
   9                   ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn            ( HsDecl(..), TyClDecl(..), Sig(..), MonoBinds(..),
  14                           HsExpr(..), HsLit(..), HsType(..), HsPred(..),
  15                           mkSimpleMatch, andMonoBinds, andMonoBindList,
  16                           isClassDecl, isClassOpSig, isPragSig,
  17                           fromClassDeclNameList, tyClDeclName
  18                         )
  19 import BasicTypes       ( NewOrData(..), TopLevelFlag(..), RecFlag(..), EP(..) )
  20 import RnHsSyn          ( RenamedTyClDecl,
  21                           RenamedClassOpSig, RenamedMonoBinds,
  22                           RenamedContext, RenamedHsDecl, RenamedSig,
  23                           RenamedHsExpr, maybeGenericMatch
  24                         )
  25 import TcHsSyn          ( TcMonoBinds, idsToMonoBinds )
  26
  27 import Inst             ( InstOrigin(..), LIE, emptyLIE, plusLIE, plusLIEs, newDicts, newMethod )
  28 import TcEnv            ( TcId, TcEnv, TyThing(..), TyThingDetails(..), tcAddImportedIdInfo,
  29                           tcLookupClass, tcExtendTyVarEnvForMeths, tcExtendGlobalTyVars,
  30                           tcExtendLocalValEnv, tcExtendTyVarEnv, newDefaultMethodName
  31                         )
  32 import TcBinds          ( tcBindWithSigs, tcSpecSigs )
  33 import TcMonoType       ( tcHsSigType, tcClassContext, checkSigTyVars, sigCtxt, mkTcSig )
  34 import TcSimplify       ( tcSimplifyAndCheck, bindInstsOfLocalFuns )
  35 import TcType           ( TcType, TcTyVar, tcInstTyVars, zonkTcSigTyVars )
  36 import TcMonad
  37 import Generics         ( mkGenericRhs, validGenericMethodType )
  38 import PrelInfo         ( nO_METHOD_BINDING_ERROR_ID )
  39 import Class            ( classTyVars, classBigSig, classSelIds, classTyCon, Class, ClassOpItem,
  40                           DefMeth (..) )
  41 import Bag              ( bagToList )
  42 import CmdLineOpts      ( dopt_GlasgowExts, opt_WarnMissingMethods, opt_PprStyle_Debug )
  43 import MkId             ( mkDictSelId, mkDataConId, mkDataConWrapId, mkDefaultMethodId )
  44 import DataCon          ( mkDataCon, notMarkedStrict )
  45 import Id               ( Id, idType, idName )
  46 import Name             ( Name, nameOccName, isLocallyDefined, NamedThing(..), mkSysLocalName,
  47                           NameEnv, lookupNameEnv, emptyNameEnv, unitNameEnv, plusNameEnv, nameEnvElts )
  48 import NameSet          ( NameSet, mkNameSet, elemNameSet, emptyNameSet )
  49 import Outputable
  50 import Type             ( Type, ClassContext, mkTyVarTys, mkDictTys, mkSigmaTy, mkClassPred,
  51                           splitTyConApp_maybe, isTyVarTy
  52                         )
  53 import Var              ( TyVar )
  54 import VarSet           ( mkVarSet, emptyVarSet )
  55 import ErrUtils         ( dumpIfSet )
  56 import Util             ( count )
  57 import Maybes           ( seqMaybe, maybeToBool, orElse )
  58 \end{code}
  59
  60
  61
  62 Dictionary handling
  63 ~~~~~~~~~~~~~~~~~~~
  64 Every class implicitly declares a new data type, corresponding to dictionaries
  65 of that class. So, for example:
  66
  67         class (D a) => C a where
  68           op1 :: a -> a
  69           op2 :: forall b. Ord b => a -> b -> b
  70
  71 would implicitly declare
  72
  73         data CDict a = CDict (D a)
  74                              (a -> a)
  75                              (forall b. Ord b => a -> b -> b)
  76
  77 (We could use a record decl, but that means changing more of the existing apparatus.
  78 One step at at time!)
  79
  80 For classes with just one superclass+method, we use a newtype decl instead:
  81
  82         class C a where
  83           op :: forallb. a -> b -> b
  84
  85 generates
  86
  87         newtype CDict a = CDict (forall b. a -> b -> b)
  88
  89 Now DictTy in Type is just a form of type synomym:
  90         DictTy c t = TyConTy CDict `AppTy` t
  91
  92 Death to "ExpandingDicts".
  93
  94
  95 %************************************************************************
  96 %*                                                                      *
  97 \subsection{Type checking}
  98 %*                                                                      *
  99 %************************************************************************
 100
 101 \begin{code}
 102 tcClassDecl1 :: TcEnv -> RenamedTyClDecl -> TcM (Name, TyThingDetails)
 103 tcClassDecl1 rec_env
 104              (ClassDecl context class_name
 105                         tyvar_names fundeps class_sigs def_methods pragmas
 106                         sys_names src_loc)
 107   =     -- CHECK ARITY 1 FOR HASKELL 1.4
 108     doptsTc dopt_GlasgowExts                            `thenTc` \ glaExts ->
 109     checkTc (glaExts || length tyvar_names == 1)
 110             (classArityErr class_name)                  `thenTc_`
 111
 112         -- LOOK THINGS UP IN THE ENVIRONMENT
 113     tcLookupClass class_name                            `thenTc` \ clas ->
 114     let
 115         tyvars   = classTyVars clas
 116         op_sigs  = filter isClassOpSig class_sigs
 117         op_names = [n | ClassOpSig n _ _ _ <- op_sigs]
 118         (_, datacon_name, datacon_wkr_name, sc_sel_names) = fromClassDeclNameList sys_names
 119     in
 120     tcExtendTyVarEnv tyvars                             $
 121
 122         -- CHECK THAT THE DEFAULT BINDINGS ARE LEGAL
 123     checkDefaultBinds clas op_names def_methods         `thenTc` \ dm_info ->
 124     checkGenericClassIsUnary clas dm_info               `thenTc_`
 125
 126         -- CHECK THE CONTEXT
 127     tcSuperClasses clas context sc_sel_names    `thenTc` \ (sc_theta, sc_sel_ids) ->
 128
 129         -- CHECK THE CLASS SIGNATURES,
 130     mapTc (tcClassSig rec_env clas tyvars dm_info) op_sigs      `thenTc` \ sig_stuff ->
 131
 132         -- MAKE THE CLASS DETAILS
 133     let
 134         (op_tys, op_items) = unzip sig_stuff
 135         sc_tys             = mkDictTys sc_theta
 136         dict_component_tys = sc_tys ++ op_tys
 137
 138         dict_con = mkDataCon datacon_name
 139                              [notMarkedStrict | _ <- dict_component_tys]
 140                              [{- No labelled fields -}]
 141                              tyvars
 142                              [{-No context-}]
 143                              [{-No existential tyvars-}] [{-Or context-}]
 144                              dict_component_tys
 145                              (classTyCon clas)
 146                              dict_con_id dict_wrap_id
 147
 148         dict_con_id  = mkDataConId datacon_wkr_name dict_con
 149         dict_wrap_id = mkDataConWrapId dict_con
 150     in
 151     returnTc (class_name, ClassDetails sc_theta sc_sel_ids op_items dict_con)
 152 \end{code}
 153
 154 \begin{code}
 155 checkDefaultBinds :: Class -> [Name] -> RenamedMonoBinds -> TcM (NameEnv (DefMeth Name))
 156   -- Check default bindings
 157   --    a) must be for a class op for this class
 158   --    b) must be all generic or all non-generic
 159   -- and return a mapping from class-op to DefMeth info
 160
 161 checkDefaultBinds clas ops EmptyMonoBinds = returnTc emptyNameEnv
 162
 163 checkDefaultBinds clas ops (AndMonoBinds b1 b2)
 164   = checkDefaultBinds clas ops b1       `thenTc` \ dm_info1 ->
 165     checkDefaultBinds clas ops b2       `thenTc` \ dm_info2 ->
 166     returnTc (dm_info1 `plusNameEnv` dm_info2)
 167
 168 checkDefaultBinds clas ops (FunMonoBind op _ matches loc)
 169   = tcAddSrcLoc loc                                     $
 170
 171         -- Check that the op is from this class
 172     checkTc (op `elem` ops) (badMethodErr clas op)              `thenTc_`
 173
 174         -- Check that all the defns ar generic, or none are
 175     checkTc (all_generic || none_generic) (mixedGenericErr op)  `thenTc_`
 176
 177         -- Make up the right dm_info
 178     if all_generic then
 179         returnTc (unitNameEnv op GenDefMeth)
 180     else
 181         -- An explicit non-generic default method
 182         newDefaultMethodName op loc     `thenNF_Tc` \ dm_name ->
 183         returnTc (unitNameEnv op (DefMeth dm_name))
 184
 185   where
 186     n_generic    = count (maybeToBool . maybeGenericMatch) matches
 187     none_generic = n_generic == 0
 188     all_generic  = n_generic == length matches
 189
 190 checkGenericClassIsUnary clas dm_info
 191   = -- Check that if the class has generic methods, then the
 192     -- class has only one parameter.  We can't do generic
 193     -- multi-parameter type classes!
 194     checkTc (unary || no_generics) (genericMultiParamErr clas)
 195   where
 196     unary       = length (classTyVars clas) == 1
 197     no_generics = null [() | GenDefMeth <- nameEnvElts dm_info]
 198 \end{code}
 199
 200
 201 \begin{code}
 202 tcSuperClasses :: Class
 203                -> RenamedContext        -- class context
 204                -> [Name]                -- Names for superclass selectors
 205                -> TcM (ClassContext,    -- the superclass context
 206                          [Id])          -- superclass selector Ids
 207
 208 tcSuperClasses clas context sc_sel_names
 209   =     -- Check the context.
 210         -- The renamer has already checked that the context mentions
 211         -- only the type variable of the class decl.
 212
 213         -- For std Haskell check that the context constrains only tyvars
 214     doptsTc dopt_GlasgowExts                    `thenTc` \ glaExts ->
 215     (if glaExts then
 216         returnTc ()
 217      else
 218         mapTc_ check_constraint context
 219     )                                           `thenTc_`
 220
 221         -- Context is already kind-checked
 222     tcClassContext context                      `thenTc` \ sc_theta ->
 223     let
 224        sc_sel_ids = [mkDictSelId sc_name clas | sc_name <- sc_sel_names]
 225     in
 226         -- Done
 227     returnTc (sc_theta, sc_sel_ids)
 228
 229   where
 230     check_constraint sc@(HsPClass c tys)
 231         = checkTc (all is_tyvar tys) (superClassErr clas sc)
 232
 233     is_tyvar (HsTyVar _) = True
 234     is_tyvar other       = False
 235
 236
 237 tcClassSig :: TcEnv                     -- Knot tying only!
 238            -> Class                     -- ...ditto...
 239            -> [TyVar]                   -- The class type variable, used for error check only
 240            -> NameEnv (DefMeth Name)    -- Info about default methods
 241            -> RenamedClassOpSig
 242            -> TcM (Type,                -- Type of the method
 243                      ClassOpItem)       -- Selector Id, default-method Id, True if explicit default binding
 244
 245 -- This warrants an explanation: we need to separate generic
 246 -- default methods and default methods later on in the compiler
 247 -- so we distinguish them in checkDefaultBinds, and pass this knowledge in the
 248 -- Class.DefMeth data structure.
 249
 250 tcClassSig rec_env clas clas_tyvars dm_info
 251            (ClassOpSig op_name maybe_dm op_ty src_loc)
 252   = tcAddSrcLoc src_loc $
 253
 254         -- Check the type signature.  NB that the envt *already has*
 255         -- bindings for the type variables; see comments in TcTyAndClassDcls.
 256
 257     -- NB: Renamer checks that the class type variable is mentioned in local_ty,
 258     -- and that it is not constrained by theta
 259     tcHsSigType op_ty                           `thenTc` \ local_ty ->
 260     let
 261         global_ty   = mkSigmaTy clas_tyvars
 262                                 [mkClassPred clas (mkTyVarTys clas_tyvars)]
 263                                 local_ty
 264
 265         -- Build the selector id and default method id
 266         sel_id      = mkDictSelId op_name clas
 267
 268         dm_info_name = maybe_dm `orElse` lookupNameEnv dm_info op_name `orElse` NoDefMeth
 269
 270         dm_info_id = case dm_info_name of
 271                         NoDefMeth       -> NoDefMeth
 272                         GenDefMeth      -> GenDefMeth
 273                         DefMeth dm_name -> DefMeth (tcAddImportedIdInfo rec_env dm_id)
 274                                         where
 275                                            dm_id = mkDefaultMethodId dm_name clas global_ty
 276     in
 277         -- Check that for a generic method, the type of
 278         -- the method is sufficiently simple
 279     checkTc (dm_info_name /= GenDefMeth || validGenericMethodType local_ty)
 280             (badGenericMethodType op_name op_ty)                `thenTc_`
 281
 282     returnTc (local_ty, (sel_id, dm_info_id))
 283 \end{code}
 284
 285
 286 %************************************************************************
 287 %*                                                                      *
 288 \subsection[ClassDcl-pass2]{Class decls pass 2: default methods}
 289 %*                                                                      *
 290 %************************************************************************
 291
 292 @mkImplicitClassBinds@ produces a binding for the selector function for each method
 293 and superclass dictionary.
 294
 295 \begin{code}
 296 mkImplicitClassBinds :: [Class] -> NF_TcM ([Id], TcMonoBinds)
 297 mkImplicitClassBinds classes
 298   = returnNF_Tc (concat cls_ids_s, andMonoBindList binds_s)
 299         -- The selector binds are already in the selector Id's unfoldings
 300         -- We don't return the data constructor etc from the class,
 301         -- because that's done via the class's TyCon
 302   where
 303     (cls_ids_s, binds_s) = unzip (map mk_implicit classes)
 304
 305     mk_implicit clas = (sel_ids, binds)
 306                      where
 307                         sel_ids = classSelIds clas
 308                         binds | isLocallyDefined clas = idsToMonoBinds sel_ids
 309                               | otherwise             = EmptyMonoBinds
 310 \end{code}
 311
 312
 313
 314 %************************************************************************
 315 %*                                                                      *
 316 \subsection[Default methods]{Default methods}
 317 %*                                                                      *
 318 %************************************************************************
 319
 320 The default methods for a class are each passed a dictionary for the
 321 class, so that they get access to the other methods at the same type.
 322 So, given the class decl
 323 \begin{verbatim}
 324 class Foo a where
 325         op1 :: a -> Bool
 326         op2 :: Ord b => a -> b -> b -> b
 327
 328         op1 x = True
 329         op2 x y z = if (op1 x) && (y < z) then y else z
 330 \end{verbatim}
 331 we get the default methods:
 332 \begin{verbatim}
 333 defm.Foo.op1 :: forall a. Foo a => a -> Bool
 334 defm.Foo.op1 = /\a -> \dfoo -> \x -> True
 335
 336 defm.Foo.op2 :: forall a. Foo a => forall b. Ord b => a -> b -> b -> b
 337 defm.Foo.op2 = /\ a -> \ dfoo -> /\ b -> \ dord -> \x y z ->
 338                   if (op1 a dfoo x) && (< b dord y z) then y else z
 339 \end{verbatim}
 340
 341 When we come across an instance decl, we may need to use the default
 342 methods:
 343 \begin{verbatim}
 344 instance Foo Int where {}
 345 \end{verbatim}
 346 gives
 347 \begin{verbatim}
 348 const.Foo.Int.op1 :: Int -> Bool
 349 const.Foo.Int.op1 = defm.Foo.op1 Int dfun.Foo.Int
 350
 351 const.Foo.Int.op2 :: forall b. Ord b => Int -> b -> b -> b
 352 const.Foo.Int.op2 = defm.Foo.op2 Int dfun.Foo.Int
 353
 354 dfun.Foo.Int :: Foo Int
 355 dfun.Foo.Int = (const.Foo.Int.op1, const.Foo.Int.op2)
 356 \end{verbatim}
 357 Notice that, as with method selectors above, we assume that dictionary
 358 application is curried, so there's no need to mention the Ord dictionary
 359 in const.Foo.Int.op2 (or the type variable).
 360
 361 \begin{verbatim}
 362 instance Foo a => Foo [a] where {}
 363
 364 dfun.Foo.List :: forall a. Foo a -> Foo [a]
 365 dfun.Foo.List
 366   = /\ a -> \ dfoo_a ->
 367     let rec
 368         op1 = defm.Foo.op1 [a] dfoo_list
 369         op2 = defm.Foo.op2 [a] dfoo_list
 370         dfoo_list = (op1, op2)
 371     in
 372         dfoo_list
 373 \end{verbatim}
 374
 375 The function @tcClassDecls2@ just arranges to apply @tcClassDecl2@ to
 376 each local class decl.
 377
 378 \begin{code}
 379 tcClassDecls2 :: [RenamedHsDecl] -> NF_TcM (LIE, TcMonoBinds)
 380
 381 tcClassDecls2 decls
 382   = foldr combine
 383           (returnNF_Tc (emptyLIE, EmptyMonoBinds))
 384           [tcClassDecl2 cls_decl | TyClD cls_decl <- decls,
 385                                    isClassDecl cls_decl,
 386                                    isLocallyDefined (tyClDeclName cls_decl)]
 387   where
 388     combine tc1 tc2 = tc1 `thenNF_Tc` \ (lie1, binds1) ->
 389                       tc2 `thenNF_Tc` \ (lie2, binds2) ->
 390                       returnNF_Tc (lie1 `plusLIE` lie2,
 391                                    binds1 `AndMonoBinds` binds2)
 392 \end{code}
 393
 394 @tcClassDecl2@ generates bindings for polymorphic default methods
 395 (generic default methods have by now turned into instance declarations)
 396
 397 \begin{code}
 398 tcClassDecl2 :: RenamedTyClDecl         -- The class declaration
 399              -> NF_TcM (LIE, TcMonoBinds)
 400
 401 tcClassDecl2 (ClassDecl context class_name
 402                         tyvar_names _ sigs default_binds pragmas _ src_loc)
 403   =     -- A locally defined class
 404     recoverNF_Tc (returnNF_Tc (emptyLIE, EmptyMonoBinds)) $
 405     tcAddSrcLoc src_loc                                   $
 406     tcLookupClass class_name                              `thenNF_Tc` \ clas ->
 407
 408         -- We make a separate binding for each default method.
 409         -- At one time I used a single AbsBinds for all of them, thus
 410         -- AbsBind [d] [dm1, dm2, dm3] { dm1 = ...; dm2 = ...; dm3 = ... }
 411         -- But that desugars into
 412         --      ds = \d -> (..., ..., ...)
 413         --      dm1 = \d -> case ds d of (a,b,c) -> a
 414         -- And since ds is big, it doesn't get inlined, so we don't get good
 415         -- default methods.  Better to make separate AbsBinds for each
 416     let
 417         (tyvars, _, _, op_items) = classBigSig clas
 418         prags                    = filter isPragSig sigs
 419         tc_dm                    = tcDefMeth clas tyvars default_binds prags
 420     in
 421     mapAndUnzipTc tc_dm op_items        `thenTc` \ (defm_binds, const_lies) ->
 422
 423     returnTc (plusLIEs const_lies, andMonoBindList defm_binds)
 424
 425
 426 tcDefMeth clas tyvars binds_in prags (_, NoDefMeth)  = returnTc (EmptyMonoBinds, emptyLIE)
 427 tcDefMeth clas tyvars binds_in prags (_, GenDefMeth) = returnTc (EmptyMonoBinds, emptyLIE)
 428         -- Generate code for polymorphic default methods only
 429         -- (Generic default methods have turned into instance decls by now.)
 430         -- This is incompatible with Hugs, which expects a polymorphic
 431         -- default method for every class op, regardless of whether or not
 432         -- the programmer supplied an explicit default decl for the class.
 433         -- (If necessary we can fix that, but we don't have a convenient Id to hand.)
 434
 435 tcDefMeth clas tyvars binds_in prags op_item@(_, DefMeth dm_id)
 436   = tcInstTyVars tyvars                 `thenNF_Tc` \ (clas_tyvars, inst_tys, _) ->
 437     let
 438         theta = [(mkClassPred clas inst_tys)]
 439     in
 440     newDicts origin theta               `thenNF_Tc` \ (this_dict, [this_dict_id]) ->
 441
 442     tcExtendTyVarEnvForMeths tyvars clas_tyvars (
 443         tcMethodBind clas origin clas_tyvars inst_tys theta
 444                      binds_in prags False op_item
 445     )                                   `thenTc` \ (defm_bind, insts_needed, (_, local_dm_id)) ->
 446
 447     tcAddErrCtxt (defltMethCtxt clas) $
 448
 449         -- tcMethodBind has checked that the class_tyvars havn't
 450         -- been unified with each other or another type, but we must
 451         -- still zonk them before passing them to tcSimplifyAndCheck
 452     zonkTcSigTyVars clas_tyvars         `thenNF_Tc` \ clas_tyvars' ->
 453
 454         -- Check the context
 455     tcSimplifyAndCheck
 456         (ptext SLIT("class") <+> ppr clas)
 457         (mkVarSet clas_tyvars')
 458         this_dict
 459         insts_needed                    `thenTc` \ (const_lie, dict_binds) ->
 460
 461     let
 462         full_bind = AbsBinds
 463                     clas_tyvars'
 464                     [this_dict_id]
 465                     [(clas_tyvars', dm_id, local_dm_id)]
 466                     emptyNameSet        -- No inlines (yet)
 467                     (dict_binds `andMonoBinds` defm_bind)
 468     in
 469     returnTc (full_bind, const_lie)
 470   where
 471     origin = ClassDeclOrigin
 472 \end{code}
 473
 474
 475
 476 %************************************************************************
 477 %*                                                                      *
 478 \subsection{Typechecking a method}
 479 %*                                                                      *
 480 %************************************************************************
 481
 482 @tcMethodBind@ is used to type-check both default-method and
 483 instance-decl method declarations.  We must type-check methods one at a
 484 time, because their signatures may have different contexts and
 485 tyvar sets.
 486
 487 \begin{code}
 488 tcMethodBind
 489         :: Class
 490         -> InstOrigin
 491         -> [TcTyVar]            -- Instantiated type variables for the
 492                                 --  enclosing class/instance decl.
 493                                 --  They'll be signature tyvars, and we
 494                                 --  want to check that they don't get bound
 495         -> [TcType]             -- Instance types
 496         -> TcThetaType          -- Available theta; this could be used to check
 497                                 --  the method signature, but actually that's done by
 498                                 --  the caller;  here, it's just used for the error message
 499         -> RenamedMonoBinds     -- Method binding (pick the right one from in here)
 500         -> [RenamedSig]         -- Pramgas (just for this one)
 501         -> Bool                 -- True <=> This method is from an instance declaration
 502         -> ClassOpItem          -- The method selector and default-method Id
 503         -> TcM (TcMonoBinds, LIE, (LIE, TcId))
 504
 505 tcMethodBind clas origin inst_tyvars inst_tys inst_theta
 506              meth_binds prags is_inst_decl (sel_id, dm_info)
 507   = tcGetSrcLoc                         `thenNF_Tc` \ loc ->
 508     newMethod origin sel_id inst_tys    `thenNF_Tc` \ meth@(_, meth_id) ->
 509     mkTcSig meth_id loc                 `thenNF_Tc` \ sig_info ->
 510     let
 511         meth_name  = idName meth_id
 512         sig_msg    = ptext SLIT("When checking the expected type for class method") <+> ppr sel_id
 513         meth_prags = find_prags (idName sel_id) meth_name prags
 514     in
 515         -- Figure out what method binding to use
 516         -- If the user suppplied one, use it, else construct a default one
 517     (case find_bind (idName sel_id) meth_name meth_binds of
 518         Just user_bind -> returnTc user_bind
 519         Nothing        -> mkDefMethRhs is_inst_decl clas inst_tys sel_id loc dm_info    `thenTc` \ rhs ->
 520                           returnTc (FunMonoBind meth_name False -- Not infix decl
 521                                                 [mkSimpleMatch [] rhs Nothing loc] loc)
 522     )                                                           `thenTc` \ meth_bind ->
 523      -- Check the bindings; first add inst_tyvars to the envt
 524      -- so that we don't quantify over them in nested places
 525      -- The *caller* put the class/inst decl tyvars into the envt
 526      tcExtendGlobalTyVars (mkVarSet inst_tyvars)
 527                     (tcAddErrCtxt (methodCtxt sel_id)           $
 528                      tcBindWithSigs NotTopLevel meth_bind
 529                      [sig_info] meth_prags NonRecursive
 530                     )                                           `thenTc` \ (binds, insts, _) ->
 531
 532      tcExtendLocalValEnv [(meth_name, meth_id)]
 533                          (tcSpecSigs meth_prags)                `thenTc` \ (prag_binds1, prag_lie) ->
 534
 535      -- The prag_lie for a SPECIALISE pragma will mention the function
 536      -- itself, so we have to simplify them away right now lest they float
 537      -- outwards!
 538      bindInstsOfLocalFuns prag_lie [meth_id]    `thenTc` \ (prag_lie', prag_binds2) ->
 539
 540      -- Now check that the instance type variables
 541      -- (or, in the case of a class decl, the class tyvars)
 542      -- have not been unified with anything in the environment
 543      --
 544      -- We do this for each method independently to localise error messages
 545      -- ...and this is why the call to tcExtendGlobalTyVars must be here
 546      --    rather than in the caller
 547      tcAddErrCtxtM (sigCtxt sig_msg inst_tyvars inst_theta (idType meth_id))    $
 548      checkSigTyVars inst_tyvars emptyVarSet                                     `thenTc_`
 549
 550      returnTc (binds `AndMonoBinds` prag_binds1 `AndMonoBinds` prag_binds2,
 551                insts `plusLIE` prag_lie',
 552                meth)
 553
 554      -- The user didn't supply a method binding,
 555      -- so we have to make up a default binding
 556      -- The RHS of a default method depends on the default-method info
 557 mkDefMethRhs is_inst_decl clas inst_tys sel_id loc (DefMeth dm_id)
 558   =  -- An polymorphic default method
 559     returnTc (HsVar (idName dm_id))
 560
 561 mkDefMethRhs is_inst_decl clas inst_tys sel_id loc NoDefMeth
 562   =     -- No default method
 563         -- Warn only if -fwarn-missing-methods
 564     warnTc (is_inst_decl && opt_WarnMissingMethods)
 565            (omittedMethodWarn sel_id clas)              `thenNF_Tc_`
 566     returnTc error_rhs
 567   where
 568     error_rhs = HsApp (HsVar (getName nO_METHOD_BINDING_ERROR_ID))
 569                           (HsLit (HsString (_PK_ error_msg)))
 570     error_msg = showSDoc (hcat [ppr loc, text "|", ppr sel_id ])
 571
 572
 573 mkDefMethRhs is_inst_decl clas inst_tys sel_id loc GenDefMeth
 574   =     -- A generic default method
 575         -- If the method is defined generically, we can only do the job if the
 576         -- instance declaration is for a single-parameter type class with
 577         -- a type constructor applied to type arguments in the instance decl
 578         --      (checkTc, so False provokes the error)
 579      checkTc (not is_inst_decl || simple_inst)
 580              (badGenericInstance sel_id clas)                   `thenTc_`
 581
 582      ioToTc (dumpIfSet opt_PprStyle_Debug "Generic RHS" stuff)  `thenNF_Tc_`
 583      returnTc rhs
 584   where
 585     rhs = mkGenericRhs sel_id clas_tyvar tycon
 586
 587     stuff = vcat [ppr clas <+> ppr inst_tys,
 588                   nest 4 (ppr sel_id <+> equals <+> ppr rhs)]
 589
 590           -- The tycon is only used in the generic case, and in that
 591           -- case we require that the instance decl is for a single-parameter
 592           -- type class with type variable arguments:
 593           --    instance (...) => C (T a b)
 594     simple_inst   = maybeToBool maybe_tycon
 595     clas_tyvar    = head (classTyVars clas)
 596     Just tycon    = maybe_tycon
 597     maybe_tycon   = case inst_tys of
 598                         [ty] -> case splitTyConApp_maybe ty of
 599                                   Just (tycon, arg_tys) | all isTyVarTy arg_tys -> Just tycon
 600                                   other                                         -> Nothing
 601                         other -> Nothing
 602 \end{code}
 603
 604
 605 \begin{code}
 606 -- The renamer just puts the selector ID as the binder in the method binding
 607 -- but we must use the method name; so we substitute it here.  Crude but simple.
 608 find_bind sel_name meth_name (FunMonoBind op_name fix matches loc)
 609     | op_name == sel_name = Just (FunMonoBind meth_name fix matches loc)
 610 find_bind sel_name meth_name (AndMonoBinds b1 b2)
 611     = find_bind sel_name meth_name b1 `seqMaybe` find_bind sel_name meth_name b2
 612 find_bind sel_name meth_name other  = Nothing   -- Default case
 613
 614  -- Find the prags for this method, and replace the
 615  -- selector name with the method name
 616 find_prags sel_name meth_name [] = []
 617 find_prags sel_name meth_name (SpecSig name ty loc : prags)
 618      | name == sel_name = SpecSig meth_name ty loc : find_prags sel_name meth_name prags
 619 find_prags sel_name meth_name (InlineSig name phase loc : prags)
 620    | name == sel_name = InlineSig meth_name phase loc : find_prags sel_name meth_name prags
 621 find_prags sel_name meth_name (NoInlineSig name phase loc : prags)
 622    | name == sel_name = NoInlineSig meth_name phase loc : find_prags sel_name meth_name prags
 623 find_prags sel_name meth_name (prag:prags) = find_prags sel_name meth_name prags
 624 \end{code}
 625
 626
 627 Contexts and errors
 628 ~~~~~~~~~~~~~~~~~~~
 629 \begin{code}
 630 classArityErr class_name
 631   = ptext SLIT("Too many parameters for class") <+> quotes (ppr class_name)
 632
 633 superClassErr clas sc
 634   = ptext SLIT("Illegal superclass constraint") <+> quotes (ppr sc)
 635     <+> ptext SLIT("in declaration for class") <+> quotes (ppr clas)
 636
 637 defltMethCtxt clas
 638   = ptext SLIT("When checking the default methods for class") <+> quotes (ppr clas)
 639
 640 methodCtxt sel_id
 641   = ptext SLIT("In the definition for method") <+> quotes (ppr sel_id)
 642
 643 badMethodErr clas op
 644   = hsep [ptext SLIT("Class"), quotes (ppr clas),
 645           ptext SLIT("does not have a method"), quotes (ppr op)]
 646
 647 omittedMethodWarn sel_id clas
 648   = sep [ptext SLIT("No explicit method nor default method for") <+> quotes (ppr sel_id),
 649          ptext SLIT("in an instance declaration for") <+> quotes (ppr clas)]
 650
 651 badGenericMethodType op op_ty
 652   = hang (ptext SLIT("Generic method type is too complex"))
 653        4 (vcat [ppr op <+> dcolon <+> ppr op_ty,
 654                 ptext SLIT("You can only use type variables, arrows, and tuples")])
 655
 656 badGenericInstance sel_id clas
 657   = sep [ptext SLIT("Can't derive generic code for") <+> quotes (ppr sel_id),
 658          ptext SLIT("because the instance declaration is not for a simple type (T a b c)"),
 659          ptext SLIT("(where T is a derivable type constructor)"),
 660          ptext SLIT("in an instance declaration for") <+> quotes (ppr clas)]
 661
 662 mixedGenericErr op
 663   = ptext SLIT("Can't mix generic and non-generic equations for class method") <+> quotes (ppr op)
 664
 665 genericMultiParamErr clas
 666   = ptext SLIT("The multi-parameter class") <+> quotes (ppr clas) <+>
 667     ptext SLIT("cannot have generic methods")
 668 \end{code}