ghc/compiler/typecheck/TcClassDcl.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcClassDcl]{Typechecking class declarations}
   5
   6 \begin{code}
   7 module TcClassDcl ( kcClassDecl, tcClassDecl1, tcClassDecls2, mkImplicitClassBinds,
   8                     tcMethodBind, checkFromThisClass
   9                   ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn            ( HsDecl(..), TyClDecl(..), Sig(..), MonoBinds(..),
  14                           InPat(..), HsBinds(..), GRHSs(..),
  15                           HsExpr(..), HsLit(..), HsType(..), HsPred(..),
  16                           pprHsClassAssertion, mkSimpleMatch,
  17                           andMonoBinds, andMonoBindList, getTyVarName,
  18                           isClassDecl, isClassOpSig, isPragSig, collectMonoBinders
  19                         )
  20 import HsPragmas        ( ClassPragmas(..) )
  21 import BasicTypes       ( NewOrData(..), TopLevelFlag(..), RecFlag(..) )
  22 import RnHsSyn          ( RenamedTyClDecl, RenamedClassPragmas,
  23                           RenamedClassOpSig, RenamedMonoBinds,
  24                           RenamedContext, RenamedHsDecl, RenamedSig
  25                         )
  26 import TcHsSyn          ( TcMonoBinds, idsToMonoBinds )
  27
  28 import Inst             ( Inst, InstOrigin(..), LIE, emptyLIE, plusLIE, plusLIEs, newDicts, newMethod )
  29 import TcEnv            ( TcId, ValueEnv, TcTyThing(..), tcAddImportedIdInfo,
  30                           tcLookupClass, tcLookupTy, tcExtendTyVarEnvForMeths, tcExtendGlobalTyVars,
  31                           tcExtendLocalValEnv
  32                         )
  33 import TcBinds          ( tcBindWithSigs, tcSpecSigs )
  34 import TcTyDecls        ( mkNewTyConRep )
  35 import TcUnify          ( unifyKinds )
  36 import TcMonad
  37 import TcMonoType       ( kcHsType, tcHsTopType, tcExtendTopTyVarScope,
  38                           tcContext, checkSigTyVars, sigCtxt, mkTcSig
  39                         )
  40 import TcSimplify       ( tcSimplifyAndCheck, bindInstsOfLocalFuns )
  41 import TcType           ( TcType, TcTyVar, tcInstTyVars, zonkTcTyVarBndr, tcGetTyVar )
  42 import TcInstUtil       ( classDataCon )
  43 import PrelInfo         ( nO_METHOD_BINDING_ERROR_ID )
  44 import FieldLabel       ( firstFieldLabelTag )
  45 import Bag              ( unionManyBags, bagToList )
  46 import Class            ( mkClass, classBigSig, classSelIds, Class, ClassOpItem )
  47 import CmdLineOpts      ( opt_GlasgowExts, opt_WarnMissingMethods )
  48 import MkId             ( mkDictSelId, mkDataConId, mkDataConWrapId, mkDefaultMethodId )
  49 import DataCon          ( mkDataCon, dataConId, dataConWrapId, notMarkedStrict )
  50 import Id               ( Id, setInlinePragma, idUnfolding, idType, idName )
  51 import CoreUnfold       ( unfoldingTemplate )
  52 import IdInfo
  53 import Name             ( Name, nameOccName, isLocallyDefined, NamedThing(..) )
  54 import NameSet          ( emptyNameSet )
  55 import Outputable
  56 import Type             ( Type, ThetaType, ClassContext,
  57                           mkFunTy, mkTyVarTy, mkTyVarTys, mkDictTy, mkDictTys,
  58                           mkSigmaTy, mkForAllTys, mkClassPred, classesOfPreds,
  59                           boxedTypeKind, mkArrowKind
  60                         )
  61 import Var              ( tyVarKind, TyVar )
  62 import VarSet           ( mkVarSet, emptyVarSet )
  63 import TyCon            ( AlgTyConFlavour(..), mkClassTyCon )
  64 import Unique           ( Unique, Uniquable(..) )
  65 import Util
  66 import Maybes           ( seqMaybe )
  67 import FiniteMap        ( lookupWithDefaultFM )
  68 \end{code}
  69
  70
  71
  72 Dictionary handling
  73 ~~~~~~~~~~~~~~~~~~~
  74 Every class implicitly declares a new data type, corresponding to dictionaries
  75 of that class. So, for example:
  76
  77         class (D a) => C a where
  78           op1 :: a -> a
  79           op2 :: forall b. Ord b => a -> b -> b
  80
  81 would implicitly declare
  82
  83         data CDict a = CDict (D a)
  84                              (a -> a)
  85                              (forall b. Ord b => a -> b -> b)
  86
  87 (We could use a record decl, but that means changing more of the existing apparatus.
  88 One step at at time!)
  89
  90 For classes with just one superclass+method, we use a newtype decl instead:
  91
  92         class C a where
  93           op :: forallb. a -> b -> b
  94
  95 generates
  96
  97         newtype CDict a = CDict (forall b. a -> b -> b)
  98
  99 Now DictTy in Type is just a form of type synomym:
 100         DictTy c t = TyConTy CDict `AppTy` t
 101
 102 Death to "ExpandingDicts".
 103
 104
 105 %************************************************************************
 106 %*                                                                      *
 107 \subsection{Kind checking}
 108 %*                                                                      *
 109 %************************************************************************
 110
 111 \begin{code}
 112 kcClassDecl (ClassDecl  context class_name
 113                         tyvar_names fundeps class_sigs def_methods pragmas
 114                         _ _ _ _ src_loc)
 115   =         -- CHECK ARITY 1 FOR HASKELL 1.4
 116     checkTc (opt_GlasgowExts || length tyvar_names == 1)
 117             (classArityErr class_name)          `thenTc_`
 118
 119         -- Get the (mutable) class kind
 120     tcLookupTy class_name                       `thenNF_Tc` \ (kind, _, _) ->
 121
 122         -- Make suitable tyvars and do kind checking
 123         -- The net effect is to mutate the class kind
 124     tcExtendTopTyVarScope kind tyvar_names      $ \ _ _ ->
 125     tcContext context                           `thenTc_`
 126     mapTc kc_sig the_class_sigs                 `thenTc_`
 127
 128     returnTc ()
 129   where
 130     the_class_sigs = filter isClassOpSig class_sigs
 131
 132     kc_sig (ClassOpSig _ _ _ op_ty loc) = tcAddSrcLoc loc (kcHsType op_ty)
 133 \end{code}
 134
 135
 136 %************************************************************************
 137 %*                                                                      *
 138 \subsection{Type checking}
 139 %*                                                                      *
 140 %************************************************************************
 141
 142 \begin{code}
 143 tcClassDecl1 rec_env rec_inst_mapper rec_vrcs
 144              (ClassDecl context class_name
 145                         tyvar_names fundeps class_sigs def_methods pragmas
 146                         tycon_name datacon_name datacon_wkr_name sc_sel_names src_loc)
 147   =     -- LOOK THINGS UP IN THE ENVIRONMENT
 148     tcLookupTy class_name                               `thenTc` \ (class_kind, _, AClass rec_class) ->
 149     tcExtendTopTyVarScope class_kind tyvar_names        $ \ tyvars _ ->
 150         -- The class kind is by now immutable
 151
 152         -- CHECK THE CONTEXT
 153 --  traceTc (text "tcClassCtxt" <+> ppr class_name)     `thenTc_`
 154     tcClassContext class_name rec_class tyvars context sc_sel_names
 155                                                 `thenTc` \ (sc_theta, sc_tys, sc_sel_ids) ->
 156 --  traceTc (text "tcClassCtxt done" <+> ppr class_name)        `thenTc_`
 157
 158         -- CHECK THE FUNCTIONAL DEPENDENCIES,
 159     tcFundeps fundeps                           `thenTc` \ fds ->
 160
 161         -- CHECK THE CLASS SIGNATURES,
 162     mapTc (tcClassSig rec_env rec_class tyvars)
 163           (filter isClassOpSig class_sigs)
 164                                                 `thenTc` \ sig_stuff ->
 165
 166         -- MAKE THE CLASS OBJECT ITSELF
 167     let
 168         (op_tys, op_items) = unzip sig_stuff
 169         rec_class_inst_env = rec_inst_mapper rec_class
 170         clas = mkClass class_name tyvars fds
 171                        sc_theta sc_sel_ids op_items
 172                        tycon
 173                        rec_class_inst_env
 174
 175         dict_component_tys = sc_tys ++ op_tys
 176         new_or_data = case dict_component_tys of
 177                         [_]   -> NewTyCon (mkNewTyConRep tycon)
 178                         other -> DataTyCon
 179
 180         dict_con = mkDataCon datacon_name
 181                            [notMarkedStrict | _ <- dict_component_tys]
 182                            [{- No labelled fields -}]
 183                            tyvars
 184                            [{-No context-}]
 185                            [{-No existential tyvars-}] [{-Or context-}]
 186                            dict_component_tys
 187                            tycon dict_con_id dict_wrap_id
 188
 189         dict_con_id  = mkDataConId datacon_wkr_name dict_con
 190         dict_wrap_id = mkDataConWrapId dict_con
 191
 192         argvrcs = lookupWithDefaultFM rec_vrcs (pprPanic "tcClassDecl1: argvrcs:" $
 193                                                          ppr tycon_name)
 194                                       tycon_name
 195
 196         tycon = mkClassTyCon tycon_name
 197                              class_kind
 198                              tyvars
 199                              argvrcs
 200                              dict_con           -- Constructors
 201                              clas               -- Yes!  It's a dictionary
 202                              new_or_data
 203     in
 204     returnTc clas
 205 \end{code}
 206
 207 \begin{code}
 208 tcFundeps = mapTc tc_fundep
 209 tc_fundep (us, vs) =
 210     mapTc tc_fd_tyvar us        `thenTc` \ us' ->
 211     mapTc tc_fd_tyvar vs        `thenTc` \ vs' ->
 212     returnTc (us', vs')
 213 tc_fd_tyvar v =
 214     tcLookupTy v `thenTc` \(_, _, thing) ->
 215     case thing of
 216         ATyVar tv -> returnTc tv
 217         -- ZZ else should fail more gracefully
 218 \end{code}
 219
 220 \begin{code}
 221 tcClassContext :: Name -> Class -> [TyVar]
 222                -> RenamedContext        -- class context
 223                -> [Name]                -- Names for superclass selectors
 224                -> TcM s (ClassContext,  -- the superclass context
 225                          [Type],        -- types of the superclass dictionaries
 226                          [Id])          -- superclass selector Ids
 227
 228 tcClassContext class_name rec_class rec_tyvars context sc_sel_names
 229   =     -- Check the context.
 230         -- The renamer has already checked that the context mentions
 231         -- only the type variable of the class decl.
 232
 233         -- For std Haskell check that the context constrains only tyvars
 234     (if opt_GlasgowExts then
 235         returnTc []
 236      else
 237         mapTc check_constraint context
 238     )                                   `thenTc_`
 239
 240     tcContext context                   `thenTc` \ sc_theta ->
 241
 242     let
 243        sc_theta' = classesOfPreds sc_theta
 244        sc_tys = mkDictTys sc_theta'
 245        sc_sel_ids = [mkDictSelId sc_name rec_class | sc_name <- sc_sel_names]
 246     in
 247         -- Done
 248     returnTc (sc_theta', sc_tys, sc_sel_ids)
 249
 250   where
 251     check_constraint (HsPClass c tys) = checkTc (all is_tyvar tys)
 252                                                 (superClassErr class_name (c, tys))
 253
 254     is_tyvar (MonoTyVar _) = True
 255     is_tyvar other         = False
 256
 257
 258 tcClassSig :: ValueEnv          -- Knot tying only!
 259            -> Class                     -- ...ditto...
 260            -> [TyVar]                   -- The class type variable, used for error check only
 261            -> RenamedClassOpSig
 262            -> TcM s (Type,              -- Type of the method
 263                      ClassOpItem)       -- Selector Id, default-method Id, True if explicit default binding
 264
 265
 266 tcClassSig rec_env rec_clas rec_clas_tyvars
 267            (ClassOpSig op_name dm_name explicit_dm
 268                        op_ty src_loc)
 269   = tcAddSrcLoc src_loc $
 270
 271         -- Check the type signature.  NB that the envt *already has*
 272         -- bindings for the type variables; see comments in TcTyAndClassDcls.
 273
 274     -- NB: Renamer checks that the class type variable is mentioned in local_ty,
 275     -- and that it is not constrained by theta
 276 --  traceTc (text "tcClassSig" <+> ppr op_name) `thenTc_`
 277     tcHsTopType op_ty                           `thenTc` \ local_ty ->
 278     let
 279         global_ty   = mkSigmaTy rec_clas_tyvars
 280                                 [mkClassPred rec_clas (mkTyVarTys rec_clas_tyvars)]
 281                                 local_ty
 282
 283         -- Build the selector id and default method id
 284         sel_id      = mkDictSelId op_name rec_clas
 285         dm_id       = mkDefaultMethodId dm_name rec_clas global_ty
 286         final_dm_id = tcAddImportedIdInfo rec_env dm_id
 287     in
 288 --  traceTc (text "tcClassSig done" <+> ppr op_name)    `thenTc_`
 289     returnTc (local_ty, (sel_id, final_dm_id, explicit_dm))
 290 \end{code}
 291
 292
 293 %************************************************************************
 294 %*                                                                      *
 295 \subsection[ClassDcl-pass2]{Class decls pass 2: default methods}
 296 %*                                                                      *
 297 %************************************************************************
 298
 299 The purpose of pass 2 is
 300 \begin{enumerate}
 301 \item
 302 to beat on the explicitly-provided default-method decls (if any),
 303 using them to produce a complete set of default-method decls.
 304 (Omitted ones elicit an error message.)
 305 \item
 306 to produce a definition for the selector function for each method
 307 and superclass dictionary.
 308 \end{enumerate}
 309
 310 Pass~2 only applies to locally-defined class declarations.
 311
 312 The function @tcClassDecls2@ just arranges to apply @tcClassDecl2@ to
 313 each local class decl.
 314
 315 \begin{code}
 316 tcClassDecls2 :: [RenamedHsDecl]
 317               -> NF_TcM s (LIE, TcMonoBinds)
 318
 319 tcClassDecls2 decls
 320   = foldr combine
 321           (returnNF_Tc (emptyLIE, EmptyMonoBinds))
 322           [tcClassDecl2 cls_decl | TyClD cls_decl <- decls, isClassDecl cls_decl]
 323   where
 324     combine tc1 tc2 = tc1 `thenNF_Tc` \ (lie1, binds1) ->
 325                       tc2 `thenNF_Tc` \ (lie2, binds2) ->
 326                       returnNF_Tc (lie1 `plusLIE` lie2,
 327                                    binds1 `AndMonoBinds` binds2)
 328 \end{code}
 329
 330 @tcClassDecl2@ is the business end of things.
 331
 332 \begin{code}
 333 tcClassDecl2 :: RenamedTyClDecl         -- The class declaration
 334              -> NF_TcM s (LIE, TcMonoBinds)
 335
 336 tcClassDecl2 (ClassDecl context class_name
 337                         tyvar_names _ class_sigs default_binds pragmas _ _ _ _ src_loc)
 338
 339   | not (isLocallyDefined class_name)
 340   = returnNF_Tc (emptyLIE, EmptyMonoBinds)
 341
 342   | otherwise   -- It is locally defined
 343   = recoverNF_Tc (returnNF_Tc (emptyLIE, EmptyMonoBinds)) $
 344     tcAddSrcLoc src_loc                                   $
 345     tcLookupClass class_name                            `thenNF_Tc` \ clas ->
 346     tcDefaultMethodBinds clas default_binds class_sigs
 347 \end{code}
 348
 349 \begin{code}
 350 mkImplicitClassBinds :: [Class] -> NF_TcM s ([Id], TcMonoBinds)
 351 mkImplicitClassBinds classes
 352   = returnNF_Tc (concat cls_ids_s, andMonoBindList binds_s)
 353         -- The selector binds are already in the selector Id's unfoldings
 354   where
 355     (cls_ids_s, binds_s) = unzip (map mk_implicit classes)
 356
 357     mk_implicit clas = (all_cls_ids, binds)
 358                      where
 359                         dict_con    = classDataCon clas
 360                         all_cls_ids = dataConId dict_con : cls_ids
 361                         cls_ids     = dataConWrapId dict_con : classSelIds clas
 362
 363                         -- The wrapper and selectors get bindings, the worker does not
 364                         binds | isLocallyDefined clas = idsToMonoBinds cls_ids
 365                               | otherwise             = EmptyMonoBinds
 366 \end{code}
 367
 368 %************************************************************************
 369 %*                                                                      *
 370 \subsection[Default methods]{Default methods}
 371 %*                                                                      *
 372 %************************************************************************
 373
 374 The default methods for a class are each passed a dictionary for the
 375 class, so that they get access to the other methods at the same type.
 376 So, given the class decl
 377 \begin{verbatim}
 378 class Foo a where
 379         op1 :: a -> Bool
 380         op2 :: Ord b => a -> b -> b -> b
 381
 382         op1 x = True
 383         op2 x y z = if (op1 x) && (y < z) then y else z
 384 \end{verbatim}
 385 we get the default methods:
 386 \begin{verbatim}
 387 defm.Foo.op1 :: forall a. Foo a => a -> Bool
 388 defm.Foo.op1 = /\a -> \dfoo -> \x -> True
 389
 390 defm.Foo.op2 :: forall a. Foo a => forall b. Ord b => a -> b -> b -> b
 391 defm.Foo.op2 = /\ a -> \ dfoo -> /\ b -> \ dord -> \x y z ->
 392                   if (op1 a dfoo x) && (< b dord y z) then y else z
 393 \end{verbatim}
 394
 395 When we come across an instance decl, we may need to use the default
 396 methods:
 397 \begin{verbatim}
 398 instance Foo Int where {}
 399 \end{verbatim}
 400 gives
 401 \begin{verbatim}
 402 const.Foo.Int.op1 :: Int -> Bool
 403 const.Foo.Int.op1 = defm.Foo.op1 Int dfun.Foo.Int
 404
 405 const.Foo.Int.op2 :: forall b. Ord b => Int -> b -> b -> b
 406 const.Foo.Int.op2 = defm.Foo.op2 Int dfun.Foo.Int
 407
 408 dfun.Foo.Int :: Foo Int
 409 dfun.Foo.Int = (const.Foo.Int.op1, const.Foo.Int.op2)
 410 \end{verbatim}
 411 Notice that, as with method selectors above, we assume that dictionary
 412 application is curried, so there's no need to mention the Ord dictionary
 413 in const.Foo.Int.op2 (or the type variable).
 414
 415 \begin{verbatim}
 416 instance Foo a => Foo [a] where {}
 417
 418 dfun.Foo.List :: forall a. Foo a -> Foo [a]
 419 dfun.Foo.List
 420   = /\ a -> \ dfoo_a ->
 421     let rec
 422         op1 = defm.Foo.op1 [a] dfoo_list
 423         op2 = defm.Foo.op2 [a] dfoo_list
 424         dfoo_list = (op1, op2)
 425     in
 426         dfoo_list
 427 \end{verbatim}
 428
 429 \begin{code}
 430 tcDefaultMethodBinds
 431         :: Class
 432         -> RenamedMonoBinds
 433         -> [RenamedSig]
 434         -> TcM s (LIE, TcMonoBinds)
 435
 436 tcDefaultMethodBinds clas default_binds sigs
 437   =     -- Check that the default bindings come from this class
 438     checkFromThisClass clas op_items default_binds      `thenNF_Tc_`
 439
 440         -- Do each default method separately
 441         -- For Hugs compatibility we make a default-method for every
 442         -- class op, regardless of whether or not the programmer supplied an
 443         -- explicit default decl for the class.  GHC will actually never
 444         -- call the default method for such operations, because it'll whip up
 445         -- a more-informative default method at each instance decl.
 446     mapAndUnzipTc tc_dm op_items                `thenTc` \ (defm_binds, const_lies) ->
 447
 448     returnTc (plusLIEs const_lies, andMonoBindList defm_binds)
 449   where
 450     prags = filter isPragSig sigs
 451
 452     (tyvars, _, _, op_items) = classBigSig clas
 453
 454     origin = ClassDeclOrigin
 455
 456     -- We make a separate binding for each default method.
 457     -- At one time I used a single AbsBinds for all of them, thus
 458     --  AbsBind [d] [dm1, dm2, dm3] { dm1 = ...; dm2 = ...; dm3 = ... }
 459     -- But that desugars into
 460     --  ds = \d -> (..., ..., ...)
 461     --  dm1 = \d -> case ds d of (a,b,c) -> a
 462     -- And since ds is big, it doesn't get inlined, so we don't get good
 463     -- default methods.  Better to make separate AbsBinds for each
 464
 465     tc_dm op_item@(_, dm_id, _)
 466       = tcInstTyVars tyvars             `thenNF_Tc` \ (clas_tyvars, inst_tys, _) ->
 467         let
 468             theta = [(mkClassPred clas inst_tys)]
 469         in
 470         newDicts origin theta                   `thenNF_Tc` \ (this_dict, [this_dict_id]) ->
 471         let
 472             avail_insts = this_dict
 473         in
 474         tcExtendTyVarEnvForMeths tyvars clas_tyvars (
 475             tcMethodBind clas origin clas_tyvars inst_tys theta
 476                          default_binds prags False
 477                          op_item
 478         )                                       `thenTc` \ (defm_bind, insts_needed, (_, local_dm_id)) ->
 479
 480         tcAddErrCtxt (defltMethCtxt clas) $
 481
 482             -- tcMethodBind has checked that the class_tyvars havn't
 483             -- been unified with each other or another type, but we must
 484             -- still zonk them before passing them to tcSimplifyAndCheck
 485         mapNF_Tc zonkTcTyVarBndr clas_tyvars    `thenNF_Tc` \ clas_tyvars' ->
 486
 487             -- Check the context
 488         tcSimplifyAndCheck
 489             (ptext SLIT("class") <+> ppr clas)
 490             (mkVarSet clas_tyvars')
 491             avail_insts
 492             insts_needed                        `thenTc` \ (const_lie, dict_binds) ->
 493
 494         let
 495             full_bind = AbsBinds
 496                             clas_tyvars'
 497                             [this_dict_id]
 498                             [(clas_tyvars', dm_id, local_dm_id)]
 499                             emptyNameSet        -- No inlines (yet)
 500                             (dict_binds `andMonoBinds` defm_bind)
 501         in
 502         returnTc (full_bind, const_lie)
 503 \end{code}
 504
 505 \begin{code}
 506 checkFromThisClass :: Class -> [ClassOpItem] -> RenamedMonoBinds -> NF_TcM s ()
 507 checkFromThisClass clas op_items mono_binds
 508   = mapNF_Tc check_from_this_class bndrs        `thenNF_Tc_`
 509     returnNF_Tc ()
 510   where
 511     check_from_this_class (bndr, loc)
 512           | nameOccName bndr `elem` sel_names = returnNF_Tc ()
 513           | otherwise                         = tcAddSrcLoc loc $
 514                                                 addErrTc (badMethodErr bndr clas)
 515     sel_names = [getOccName sel_id | (sel_id,_,_) <- op_items]
 516     bndrs = bagToList (collectMonoBinders mono_binds)
 517 \end{code}
 518
 519
 520 @tcMethodBind@ is used to type-check both default-method and
 521 instance-decl method declarations.  We must type-check methods one at a
 522 time, because their signatures may have different contexts and
 523 tyvar sets.
 524
 525 \begin{code}
 526 tcMethodBind
 527         :: Class
 528         -> InstOrigin
 529         -> [TcTyVar]            -- Instantiated type variables for the
 530                                 --  enclosing class/instance decl.
 531                                 --  They'll be signature tyvars, and we
 532                                 --  want to check that they don't get bound
 533         -> [TcType]             -- Instance types
 534         -> TcThetaType          -- Available theta; this could be used to check
 535                                 --  the method signature, but actually that's done by
 536                                 --  the caller;  here, it's just used for the error message
 537         -> RenamedMonoBinds     -- Method binding (pick the right one from in here)
 538         -> [RenamedSig]         -- Pramgas (just for this one)
 539         -> Bool                 -- True <=> This method is from an instance declaration
 540         -> ClassOpItem          -- The method selector and default-method Id
 541         -> TcM s (TcMonoBinds, LIE, (LIE, TcId))
 542
 543 tcMethodBind clas origin inst_tyvars inst_tys inst_theta
 544              meth_binds prags is_inst_decl
 545              (sel_id, dm_id, explicit_dm)
 546  = tcGetSrcLoc          `thenNF_Tc` \ loc ->
 547
 548    newMethod origin sel_id inst_tys     `thenNF_Tc` \ meth@(_, meth_id) ->
 549    mkTcSig meth_id loc                  `thenNF_Tc` \ sig_info ->
 550
 551    let
 552      meth_name       = idName meth_id
 553      maybe_user_bind = find_bind meth_name meth_binds
 554
 555      no_user_bind    = case maybe_user_bind of {Nothing -> True; other -> False}
 556
 557      meth_bind = case maybe_user_bind of
 558                         Just bind -> bind
 559                         Nothing   -> mk_default_bind meth_name loc
 560
 561      meth_prags = find_prags meth_name prags
 562    in
 563
 564         -- Warn if no method binding, only if -fwarn-missing-methods
 565    warnTc (is_inst_decl && opt_WarnMissingMethods && no_user_bind && not explicit_dm)
 566           (omittedMethodWarn sel_id clas)               `thenNF_Tc_`
 567
 568         -- Check the bindings; first add inst_tyvars to the envt
 569         -- so that we don't quantify over them in nested places
 570         -- The *caller* put the class/inst decl tyvars into the envt
 571    tcExtendGlobalTyVars (mkVarSet inst_tyvars) (
 572      tcAddErrCtxt (methodCtxt sel_id)           $
 573      tcBindWithSigs NotTopLevel meth_bind
 574                     [sig_info] meth_prags NonRecursive
 575    )                                            `thenTc` \ (binds, insts, _) ->
 576
 577
 578    tcExtendLocalValEnv [(meth_name, meth_id)] (
 579         tcSpecSigs meth_prags
 580    )                                            `thenTc` \ (prag_binds1, prag_lie) ->
 581
 582         -- The prag_lie for a SPECIALISE pragma will mention the function
 583         -- itself, so we have to simplify them away right now lest they float
 584         -- outwards!
 585    bindInstsOfLocalFuns prag_lie [meth_id]      `thenTc` \ (prag_lie', prag_binds2) ->
 586
 587
 588         -- Now check that the instance type variables
 589         -- (or, in the case of a class decl, the class tyvars)
 590         -- have not been unified with anything in the environment
 591    tcAddErrCtxtM (sigCtxt sig_msg inst_tyvars inst_theta (idType meth_id))      $
 592    checkSigTyVars inst_tyvars emptyVarSet                                       `thenTc_`
 593
 594    returnTc (binds `AndMonoBinds` prag_binds1 `AndMonoBinds` prag_binds2,
 595              insts `plusLIE` prag_lie',
 596              meth)
 597  where
 598    sig_msg = ptext SLIT("When checking the expected type for class method") <+> ppr sel_name
 599
 600    sel_name = idName sel_id
 601
 602         -- The renamer just puts the selector ID as the binder in the method binding
 603         -- but we must use the method name; so we substitute it here.  Crude but simple.
 604    find_bind meth_name (FunMonoBind op_name fix matches loc)
 605         | op_name == sel_name = Just (FunMonoBind meth_name fix matches loc)
 606    find_bind meth_name (AndMonoBinds b1 b2)
 607                               = find_bind meth_name b1 `seqMaybe` find_bind meth_name b2
 608    find_bind meth_name other  = Nothing -- Default case
 609
 610
 611         -- Find the prags for this method, and replace the
 612         -- selector name with the method name
 613    find_prags meth_name [] = []
 614    find_prags meth_name (SpecSig name ty loc : prags)
 615         | name == sel_name = SpecSig meth_name ty loc : find_prags meth_name prags
 616    find_prags meth_name (InlineSig name phase loc : prags)
 617         | name == sel_name = InlineSig meth_name phase loc : find_prags meth_name prags
 618    find_prags meth_name (NoInlineSig name phase loc : prags)
 619         | name == sel_name = NoInlineSig meth_name phase loc : find_prags meth_name prags
 620    find_prags meth_name (prag:prags) = find_prags meth_name prags
 621
 622    mk_default_bind local_meth_name loc
 623       = FunMonoBind local_meth_name
 624                     False       -- Not infix decl
 625                     [mkSimpleMatch [] (default_expr loc) Nothing loc]
 626                     loc
 627
 628    default_expr loc
 629         | explicit_dm = HsVar (getName dm_id)   -- There's a default method
 630         | otherwise   = error_expr loc          -- No default method
 631
 632    error_expr loc = HsApp (HsVar (getName nO_METHOD_BINDING_ERROR_ID))
 633                           (HsLit (HsString (_PK_ (error_msg loc))))
 634
 635    error_msg loc = showSDoc (hcat [ppr loc, text "|", ppr sel_id ])
 636 \end{code}
 637
 638 Contexts and errors
 639 ~~~~~~~~~~~~~~~~~~~
 640 \begin{code}
 641 classArityErr class_name
 642   = ptext SLIT("Too many parameters for class") <+> quotes (ppr class_name)
 643
 644 superClassErr class_name sc
 645   = ptext SLIT("Illegal superclass constraint") <+> quotes (pprHsClassAssertion sc)
 646     <+> ptext SLIT("in declaration for class") <+> quotes (ppr class_name)
 647
 648 defltMethCtxt class_name
 649   = ptext SLIT("When checking the default methods for class") <+> quotes (ppr class_name)
 650
 651 methodCtxt sel_id
 652   = ptext SLIT("In the definition for method") <+> quotes (ppr sel_id)
 653
 654 badMethodErr bndr clas
 655   = hsep [ptext SLIT("Class"), quotes (ppr clas),
 656           ptext SLIT("does not have a method"), quotes (ppr bndr)]
 657
 658 omittedMethodWarn sel_id clas
 659   = sep [ptext SLIT("No explicit method nor default method for") <+> quotes (ppr sel_id),
 660          ptext SLIT("in an instance declaration for") <+> quotes (ppr clas)]
 661 \end{code}