ghc/compiler/typecheck/TcClassDcl.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcClassDcl]{Typechecking class declarations}
   5
   6 \begin{code}
   7 module TcClassDcl ( tcClassDecl1, checkValidClass, tcClassDecls2,
   8                     tcMethodBind, badMethodErr
   9                   ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn            ( TyClDecl(..), Sig(..), MonoBinds(..),
  14                           HsExpr(..), HsLit(..),
  15                           mkSimpleMatch, andMonoBinds, andMonoBindList,
  16                           isClassOpSig, isPragSig,
  17                           getClassDeclSysNames, placeHolderType
  18                         )
  19 import BasicTypes       ( TopLevelFlag(..), RecFlag(..), StrictnessMark(..) )
  20 import RnHsSyn          ( RenamedTyClDecl,
  21                           RenamedClassOpSig, RenamedMonoBinds,
  22                           RenamedSig, maybeGenericMatch
  23                         )
  24 import TcHsSyn          ( TcMonoBinds )
  25
  26 import Inst             ( Inst, InstOrigin(..), LIE, emptyLIE, plusLIE, plusLIEs,
  27                           instToId, newDicts, newMethod )
  28 import TcEnv            ( RecTcEnv, TyThingDetails(..), tcAddImportedIdInfo,
  29                           tcLookupClass, tcExtendTyVarEnvForMeths, tcExtendGlobalTyVars,
  30                           tcExtendLocalValEnv, tcExtendTyVarEnv
  31                         )
  32 import TcBinds          ( tcBindWithSigs, tcSpecSigs )
  33 import TcMonoType       ( tcHsType, tcHsTheta, checkSigTyVars, sigCtxt, mkTcSig )
  34 import TcSimplify       ( tcSimplifyCheck, bindInstsOfLocalFuns )
  35 import TcMType          ( tcInstSigTyVars, checkValidTheta, checkValidType, SourceTyCtxt(..), UserTypeCtxt(..) )
  36 import TcType           ( Type, TyVarDetails(..), TcType, TcThetaType, TcTyVar,
  37                           mkSigmaTy, mkTyVarTys, mkPredTys, mkClassPred,
  38                           tcIsTyVarTy, tcSplitTyConApp_maybe, tcSplitSigmaTy
  39                         )
  40 import TcMonad
  41 import Generics         ( mkGenericRhs, validGenericMethodType )
  42 import PrelInfo         ( nO_METHOD_BINDING_ERROR_ID )
  43 import Class            ( classTyVars, classBigSig, classTyCon, className,
  44                           Class, ClassOpItem, DefMeth (..) )
  45 import MkId             ( mkDictSelId, mkDataConId, mkDataConWrapId, mkDefaultMethodId )
  46 import DataCon          ( mkDataCon )
  47 import Id               ( Id, idType, idName, setIdLocalExported )
  48 import Module           ( Module )
  49 import Name             ( Name, NamedThing(..) )
  50 import NameEnv          ( NameEnv, lookupNameEnv, emptyNameEnv, unitNameEnv, plusNameEnv )
  51 import NameSet          ( emptyNameSet )
  52 import Outputable
  53 import Var              ( TyVar )
  54 import VarSet           ( mkVarSet, emptyVarSet )
  55 import CmdLineOpts
  56 import ErrUtils         ( dumpIfSet )
  57 import Util             ( count, isSingleton, lengthIs, equalLength )
  58 import Maybes           ( seqMaybe, maybeToBool )
  59 \end{code}
  60
  61
  62
  63 Dictionary handling
  64 ~~~~~~~~~~~~~~~~~~~
  65 Every class implicitly declares a new data type, corresponding to dictionaries
  66 of that class. So, for example:
  67
  68         class (D a) => C a where
  69           op1 :: a -> a
  70           op2 :: forall b. Ord b => a -> b -> b
  71
  72 would implicitly declare
  73
  74         data CDict a = CDict (D a)
  75                              (a -> a)
  76                              (forall b. Ord b => a -> b -> b)
  77
  78 (We could use a record decl, but that means changing more of the existing apparatus.
  79 One step at at time!)
  80
  81 For classes with just one superclass+method, we use a newtype decl instead:
  82
  83         class C a where
  84           op :: forallb. a -> b -> b
  85
  86 generates
  87
  88         newtype CDict a = CDict (forall b. a -> b -> b)
  89
  90 Now DictTy in Type is just a form of type synomym:
  91         DictTy c t = TyConTy CDict `AppTy` t
  92
  93 Death to "ExpandingDicts".
  94
  95
  96 %************************************************************************
  97 %*                                                                      *
  98 \subsection{Type checking}
  99 %*                                                                      *
 100 %************************************************************************
 101
 102 \begin{code}
 103
 104 tcClassDecl1 :: RecTcEnv -> RenamedTyClDecl -> TcM (Name, TyThingDetails)
 105 tcClassDecl1 rec_env
 106              (ClassDecl {tcdCtxt = context, tcdName = class_name,
 107                          tcdTyVars = tyvar_names, tcdFDs = fundeps,
 108                          tcdSigs = class_sigs, tcdMeths = def_methods,
 109                          tcdSysNames = sys_names, tcdLoc = src_loc})
 110   =     -- LOOK THINGS UP IN THE ENVIRONMENT
 111     tcLookupClass class_name                            `thenTc` \ clas ->
 112     let
 113         tyvars   = classTyVars clas
 114         op_sigs  = filter isClassOpSig class_sigs
 115         op_names = [n | ClassOpSig n _ _ _ <- op_sigs]
 116         (_, datacon_name, datacon_wkr_name, sc_sel_names) = getClassDeclSysNames sys_names
 117     in
 118     tcExtendTyVarEnv tyvars                             $
 119
 120     checkDefaultBinds clas op_names def_methods   `thenTc` \ mb_dm_env ->
 121
 122         -- CHECK THE CONTEXT
 123         -- The renamer has already checked that the context mentions
 124         -- only the type variable of the class decl.
 125         -- Context is already kind-checked
 126     ASSERT( equalLength context sc_sel_names )
 127     tcHsTheta context                                           `thenTc` \ sc_theta ->
 128
 129         -- CHECK THE CLASS SIGNATURES,
 130     mapTc (tcClassSig rec_env clas tyvars mb_dm_env) op_sigs    `thenTc` \ sig_stuff ->
 131
 132         -- MAKE THE CLASS DETAILS
 133     let
 134         (op_tys, op_items) = unzip sig_stuff
 135         sc_tys             = mkPredTys sc_theta
 136         dict_component_tys = sc_tys ++ op_tys
 137         sc_sel_ids         = [mkDictSelId sc_name clas | sc_name <- sc_sel_names]
 138
 139         dict_con = mkDataCon datacon_name
 140                              [NotMarkedStrict | _ <- dict_component_tys]
 141                              [{- No labelled fields -}]
 142                              tyvars
 143                              [{-No context-}]
 144                              [{-No existential tyvars-}] [{-Or context-}]
 145                              dict_component_tys
 146                              (classTyCon clas)
 147                              dict_con_id dict_wrap_id
 148
 149         dict_con_id  = mkDataConId datacon_wkr_name dict_con
 150         dict_wrap_id = mkDataConWrapId dict_con
 151     in
 152     returnTc (class_name, ClassDetails sc_theta sc_sel_ids op_items dict_con)
 153 \end{code}
 154
 155 \begin{code}
 156 checkDefaultBinds :: Class -> [Name] -> Maybe RenamedMonoBinds
 157                   -> TcM (Maybe (NameEnv Bool))
 158         -- The returned environment says
 159         --      x not in env => no default method
 160         --      x -> True    => generic default method
 161         --      x -> False   => polymorphic default method
 162
 163   -- Check default bindings
 164   --    a) must be for a class op for this class
 165   --    b) must be all generic or all non-generic
 166   -- and return a mapping from class-op to DefMeth info
 167
 168   -- But do all this only for source binds
 169
 170 checkDefaultBinds clas ops Nothing
 171   = returnTc Nothing
 172
 173 checkDefaultBinds clas ops (Just mbs)
 174   = go mbs      `thenTc` \ dm_env ->
 175     returnTc (Just dm_env)
 176   where
 177     go EmptyMonoBinds = returnTc emptyNameEnv
 178
 179     go (AndMonoBinds b1 b2)
 180       = go b1   `thenTc` \ dm_info1 ->
 181         go b2   `thenTc` \ dm_info2 ->
 182         returnTc (dm_info1 `plusNameEnv` dm_info2)
 183
 184     go (FunMonoBind op _ matches loc)
 185       = tcAddSrcLoc loc                                 $
 186
 187         -- Check that the op is from this class
 188         checkTc (op `elem` ops) (badMethodErr clas op)          `thenTc_`
 189
 190         -- Check that all the defns ar generic, or none are
 191         checkTc (all_generic || none_generic) (mixedGenericErr op)      `thenTc_`
 192
 193         returnTc (unitNameEnv op all_generic)
 194       where
 195         n_generic    = count (maybeToBool . maybeGenericMatch) matches
 196         none_generic = n_generic == 0
 197         all_generic  = matches `lengthIs` n_generic
 198 \end{code}
 199
 200
 201 \begin{code}
 202 tcClassSig :: RecTcEnv                  -- Knot tying only!
 203            -> Class                     -- ...ditto...
 204            -> [TyVar]                   -- The class type variable, used for error check only
 205            -> Maybe (NameEnv Bool)      -- Info about default methods;
 206                                         --      Nothing => imported class defn with no method binds
 207            -> RenamedClassOpSig
 208            -> TcM (Type,                -- Type of the method
 209                      ClassOpItem)       -- Selector Id, default-method Id, True if explicit default binding
 210
 211 -- This warrants an explanation: we need to separate generic
 212 -- default methods and default methods later on in the compiler
 213 -- so we distinguish them in checkDefaultBinds, and pass this knowledge in the
 214 -- Class.DefMeth data structure.
 215
 216 tcClassSig unf_env clas clas_tyvars maybe_dm_env
 217            (ClassOpSig op_name sig_dm op_ty src_loc)
 218   = tcAddSrcLoc src_loc $
 219
 220         -- Check the type signature.  NB that the envt *already has*
 221         -- bindings for the type variables; see comments in TcTyAndClassDcls.
 222     tcHsType op_ty                      `thenTc` \ local_ty ->
 223
 224     let
 225         theta = [mkClassPred clas (mkTyVarTys clas_tyvars)]
 226
 227         -- Build the selector id and default method id
 228         sel_id = mkDictSelId op_name clas
 229         DefMeth dm_name = sig_dm
 230
 231         dm_info = case maybe_dm_env of
 232                     Nothing     -> sig_dm
 233                     Just dm_env -> mk_src_dm_info dm_env
 234
 235         mk_src_dm_info dm_env = case lookupNameEnv dm_env op_name of
 236                                    Nothing    -> NoDefMeth
 237                                    Just True  -> GenDefMeth
 238                                    Just False -> DefMeth dm_name
 239     in
 240     returnTc (local_ty, (sel_id, dm_info))
 241 \end{code}
 242
 243 checkValidClass is called once the mutually-recursive knot has been
 244 tied, so we can look at things freely.
 245
 246 \begin{code}
 247 checkValidClass :: Class -> TcM ()
 248 checkValidClass cls
 249   =     -- CHECK ARITY 1 FOR HASKELL 1.4
 250     doptsTc Opt_GlasgowExts                             `thenTc` \ gla_exts ->
 251
 252         -- Check that the class is unary, unless GlaExs
 253     checkTc (not (null tyvars))         (nullaryClassErr cls)   `thenTc_`
 254     checkTc (gla_exts || unary) (classArityErr cls)     `thenTc_`
 255
 256         -- Check the super-classes
 257     checkValidTheta (ClassSCCtxt (className cls)) theta `thenTc_`
 258
 259         -- Check the class operations
 260     mapTc_ check_op op_stuff            `thenTc_`
 261
 262         -- Check that if the class has generic methods, then the
 263         -- class has only one parameter.  We can't do generic
 264         -- multi-parameter type classes!
 265     checkTc (unary || no_generics) (genericMultiParamErr cls)
 266
 267   where
 268     (tyvars, theta, _, op_stuff) = classBigSig cls
 269     unary       = isSingleton tyvars
 270     no_generics = null [() | (_, GenDefMeth) <- op_stuff]
 271
 272     check_op (sel_id, dm)
 273         = checkValidTheta SigmaCtxt (tail theta)        `thenTc_`
 274                 -- The 'tail' removes the initial (C a) from the
 275                 -- class itself, leaving just the method type
 276
 277           checkValidType (FunSigCtxt op_name) tau       `thenTc_`
 278
 279                 -- Check that for a generic method, the type of
 280                 -- the method is sufficiently simple
 281           checkTc (dm /= GenDefMeth || validGenericMethodType op_ty)
 282                   (badGenericMethodType op_name op_ty)
 283         where
 284           op_name = idName sel_id
 285           op_ty   = idType sel_id
 286           (_,theta,tau) = tcSplitSigmaTy op_ty
 287 \end{code}
 288
 289
 290 %************************************************************************
 291 %*                                                                      *
 292 \subsection[Default methods]{Default methods}
 293 %*                                                                      *
 294 %************************************************************************
 295
 296 The default methods for a class are each passed a dictionary for the
 297 class, so that they get access to the other methods at the same type.
 298 So, given the class decl
 299 \begin{verbatim}
 300 class Foo a where
 301         op1 :: a -> Bool
 302         op2 :: Ord b => a -> b -> b -> b
 303
 304         op1 x = True
 305         op2 x y z = if (op1 x) && (y < z) then y else z
 306 \end{verbatim}
 307 we get the default methods:
 308 \begin{verbatim}
 309 defm.Foo.op1 :: forall a. Foo a => a -> Bool
 310 defm.Foo.op1 = /\a -> \dfoo -> \x -> True
 311
 312 defm.Foo.op2 :: forall a. Foo a => forall b. Ord b => a -> b -> b -> b
 313 defm.Foo.op2 = /\ a -> \ dfoo -> /\ b -> \ dord -> \x y z ->
 314                   if (op1 a dfoo x) && (< b dord y z) then y else z
 315 \end{verbatim}
 316
 317 When we come across an instance decl, we may need to use the default
 318 methods:
 319 \begin{verbatim}
 320 instance Foo Int where {}
 321 \end{verbatim}
 322 gives
 323 \begin{verbatim}
 324 const.Foo.Int.op1 :: Int -> Bool
 325 const.Foo.Int.op1 = defm.Foo.op1 Int dfun.Foo.Int
 326
 327 const.Foo.Int.op2 :: forall b. Ord b => Int -> b -> b -> b
 328 const.Foo.Int.op2 = defm.Foo.op2 Int dfun.Foo.Int
 329
 330 dfun.Foo.Int :: Foo Int
 331 dfun.Foo.Int = (const.Foo.Int.op1, const.Foo.Int.op2)
 332 \end{verbatim}
 333 Notice that, as with method selectors above, we assume that dictionary
 334 application is curried, so there's no need to mention the Ord dictionary
 335 in const.Foo.Int.op2 (or the type variable).
 336
 337 \begin{verbatim}
 338 instance Foo a => Foo [a] where {}
 339
 340 dfun.Foo.List :: forall a. Foo a -> Foo [a]
 341 dfun.Foo.List
 342   = /\ a -> \ dfoo_a ->
 343     let rec
 344         op1 = defm.Foo.op1 [a] dfoo_list
 345         op2 = defm.Foo.op2 [a] dfoo_list
 346         dfoo_list = (op1, op2)
 347     in
 348         dfoo_list
 349 \end{verbatim}
 350
 351 The function @tcClassDecls2@ just arranges to apply @tcClassDecl2@ to
 352 each local class decl.
 353
 354 \begin{code}
 355 tcClassDecls2 :: Module -> [RenamedTyClDecl] -> NF_TcM (LIE, TcMonoBinds, [Id])
 356
 357 tcClassDecls2 this_mod decls
 358   = foldr combine
 359           (returnNF_Tc (emptyLIE, EmptyMonoBinds, []))
 360           [tcClassDecl2 cls_decl | cls_decl@(ClassDecl {tcdMeths = Just _}) <- decls]
 361                 -- The 'Just' picks out source ClassDecls
 362   where
 363     combine tc1 tc2 = tc1 `thenNF_Tc` \ (lie1, binds1, ids1) ->
 364                       tc2 `thenNF_Tc` \ (lie2, binds2, ids2) ->
 365                       returnNF_Tc (lie1 `plusLIE` lie2,
 366                                    binds1 `AndMonoBinds` binds2,
 367                                    ids1 ++ ids2)
 368 \end{code}
 369
 370 @tcClassDecl2@ generates bindings for polymorphic default methods
 371 (generic default methods have by now turned into instance declarations)
 372
 373 \begin{code}
 374 tcClassDecl2 :: RenamedTyClDecl         -- The class declaration
 375              -> NF_TcM (LIE, TcMonoBinds, [Id])
 376
 377 tcClassDecl2 (ClassDecl {tcdName = class_name, tcdSigs = sigs,
 378                          tcdMeths = Just default_binds, tcdLoc = src_loc})
 379   =     -- The 'Just' picks out source ClassDecls
 380     recoverNF_Tc (returnNF_Tc (emptyLIE, EmptyMonoBinds, [])) $
 381     tcAddSrcLoc src_loc                                   $
 382     tcLookupClass class_name                              `thenNF_Tc` \ clas ->
 383
 384         -- We make a separate binding for each default method.
 385         -- At one time I used a single AbsBinds for all of them, thus
 386         -- AbsBind [d] [dm1, dm2, dm3] { dm1 = ...; dm2 = ...; dm3 = ... }
 387         -- But that desugars into
 388         --      ds = \d -> (..., ..., ...)
 389         --      dm1 = \d -> case ds d of (a,b,c) -> a
 390         -- And since ds is big, it doesn't get inlined, so we don't get good
 391         -- default methods.  Better to make separate AbsBinds for each
 392     let
 393         (tyvars, _, _, op_items) = classBigSig clas
 394         prags                    = filter isPragSig sigs
 395         tc_dm                    = tcDefMeth clas tyvars default_binds prags
 396     in
 397     mapAndUnzip3Tc tc_dm op_items       `thenTc` \ (defm_binds, const_lies, dm_ids_s) ->
 398
 399     returnTc (plusLIEs const_lies, andMonoBindList defm_binds, concat dm_ids_s)
 400
 401
 402 tcDefMeth clas tyvars binds_in prags (_, NoDefMeth)  = returnTc (EmptyMonoBinds, emptyLIE, [])
 403 tcDefMeth clas tyvars binds_in prags (_, GenDefMeth) = returnTc (EmptyMonoBinds, emptyLIE, [])
 404         -- Generate code for polymorphic default methods only
 405         -- (Generic default methods have turned into instance decls by now.)
 406         -- This is incompatible with Hugs, which expects a polymorphic
 407         -- default method for every class op, regardless of whether or not
 408         -- the programmer supplied an explicit default decl for the class.
 409         -- (If necessary we can fix that, but we don't have a convenient Id to hand.)
 410
 411 tcDefMeth clas tyvars binds_in prags op_item@(sel_id, DefMeth dm_name)
 412   = tcInstSigTyVars ClsTv tyvars                        `thenNF_Tc` \ clas_tyvars ->
 413     let
 414         dm_ty = idType sel_id   -- Same as dict selector!
 415           -- The default method's type should really come from the
 416           -- iface file, since it could be usage-generalised, but this
 417           -- requires altering the mess of knots in TcModule and I'm
 418           -- too scared to do that.  Instead, I have disabled generalisation
 419           -- of types of default methods (and dict funs) by annotating them
 420           -- TyGenNever (in MkId).  Ugh!  KSW 1999-09.
 421
 422         inst_tys    = mkTyVarTys clas_tyvars
 423         theta       = [mkClassPred clas inst_tys]
 424         dm_id       = mkDefaultMethodId dm_name dm_ty
 425         local_dm_id = setIdLocalExported dm_id
 426                 -- Reason for setIdLocalExported: see notes with MkId.mkDictFunId
 427     in
 428     newDicts origin theta               `thenNF_Tc` \ [this_dict] ->
 429
 430     tcExtendTyVarEnvForMeths tyvars clas_tyvars (
 431         tcMethodBind clas origin clas_tyvars inst_tys theta
 432                      binds_in prags False op_item
 433     )                                   `thenTc` \ (defm_bind, insts_needed, local_dm_inst) ->
 434
 435     tcAddErrCtxt (defltMethCtxt clas) $
 436
 437         -- Check the context
 438     tcSimplifyCheck
 439         (ptext SLIT("class") <+> ppr clas)
 440         clas_tyvars
 441         [this_dict]
 442         insts_needed                            `thenTc` \ (const_lie, dict_binds) ->
 443
 444         -- Simplification can do unification
 445     checkSigTyVars clas_tyvars emptyVarSet      `thenTc` \ clas_tyvars' ->
 446
 447     let
 448         full_bind = AbsBinds
 449                     clas_tyvars'
 450                     [instToId this_dict]
 451                     [(clas_tyvars', local_dm_id, instToId local_dm_inst)]
 452                     emptyNameSet        -- No inlines (yet)
 453                     (dict_binds `andMonoBinds` defm_bind)
 454     in
 455     returnTc (full_bind, const_lie, [dm_id])
 456   where
 457     origin = ClassDeclOrigin
 458 \end{code}
 459
 460
 461
 462 %************************************************************************
 463 %*                                                                      *
 464 \subsection{Typechecking a method}
 465 %*                                                                      *
 466 %************************************************************************
 467
 468 @tcMethodBind@ is used to type-check both default-method and
 469 instance-decl method declarations.  We must type-check methods one at a
 470 time, because their signatures may have different contexts and
 471 tyvar sets.
 472
 473 \begin{code}
 474 tcMethodBind
 475         :: Class
 476         -> InstOrigin
 477         -> [TcTyVar]            -- Instantiated type variables for the
 478                                 --  enclosing class/instance decl.
 479                                 --  They'll be signature tyvars, and we
 480                                 --  want to check that they don't get bound
 481         -> [TcType]             -- Instance types
 482         -> TcThetaType          -- Available theta; this could be used to check
 483                                 --  the method signature, but actually that's done by
 484                                 --  the caller;  here, it's just used for the error message
 485         -> RenamedMonoBinds     -- Method binding (pick the right one from in here)
 486         -> [RenamedSig]         -- Pramgas (just for this one)
 487         -> Bool                 -- True <=> This method is from an instance declaration
 488         -> ClassOpItem          -- The method selector and default-method Id
 489         -> TcM (TcMonoBinds, LIE, Inst)
 490
 491 tcMethodBind clas origin inst_tyvars inst_tys inst_theta
 492              meth_binds prags is_inst_decl (sel_id, dm_info)
 493   = tcGetSrcLoc                         `thenNF_Tc` \ loc ->
 494     newMethod origin sel_id inst_tys    `thenNF_Tc` \ meth ->
 495     let
 496         meth_id    = instToId meth
 497         meth_name  = idName meth_id
 498         sig_msg    = ptext SLIT("When checking the expected type for class method") <+> ppr sel_id
 499         meth_prags = find_prags (idName sel_id) meth_name prags
 500     in
 501     mkTcSig meth_id loc                 `thenNF_Tc` \ sig_info ->
 502
 503         -- Figure out what method binding to use
 504         -- If the user suppplied one, use it, else construct a default one
 505     (case find_bind (idName sel_id) meth_name meth_binds of
 506         Just user_bind -> returnTc user_bind
 507         Nothing        -> mkDefMethRhs is_inst_decl clas inst_tys sel_id loc dm_info    `thenTc` \ rhs ->
 508                           returnTc (FunMonoBind meth_name False -- Not infix decl
 509                                                 [mkSimpleMatch [] rhs placeHolderType loc] loc)
 510     )                                                           `thenTc` \ meth_bind ->
 511      -- Check the bindings; first add inst_tyvars to the envt
 512      -- so that we don't quantify over them in nested places
 513      -- The *caller* put the class/inst decl tyvars into the envt
 514      tcExtendGlobalTyVars (mkVarSet inst_tyvars)
 515                     (tcAddErrCtxt (methodCtxt sel_id)           $
 516                      tcBindWithSigs NotTopLevel meth_bind
 517                                     [sig_info] meth_prags NonRecursive
 518                     )                                           `thenTc` \ (binds, insts, _) ->
 519
 520      tcExtendLocalValEnv [(meth_name, meth_id)]
 521                          (tcSpecSigs meth_prags)                `thenTc` \ (prag_binds1, prag_lie) ->
 522
 523      -- The prag_lie for a SPECIALISE pragma will mention the function
 524      -- itself, so we have to simplify them away right now lest they float
 525      -- outwards!
 526      bindInstsOfLocalFuns prag_lie [meth_id]    `thenTc` \ (prag_lie', prag_binds2) ->
 527
 528      -- Now check that the instance type variables
 529      -- (or, in the case of a class decl, the class tyvars)
 530      -- have not been unified with anything in the environment
 531      --
 532      -- We do this for each method independently to localise error messages
 533      -- ...and this is why the call to tcExtendGlobalTyVars must be here
 534      --    rather than in the caller
 535      tcAddErrCtxtM (sigCtxt sig_msg inst_tyvars inst_theta (idType meth_id))    $
 536      checkSigTyVars inst_tyvars emptyVarSet                                     `thenTc_`
 537
 538      returnTc (binds `AndMonoBinds` prag_binds1 `AndMonoBinds` prag_binds2,
 539                insts `plusLIE` prag_lie',
 540                meth)
 541
 542      -- The user didn't supply a method binding,
 543      -- so we have to make up a default binding
 544      -- The RHS of a default method depends on the default-method info
 545 mkDefMethRhs is_inst_decl clas inst_tys sel_id loc (DefMeth dm_name)
 546   =  -- An polymorphic default method
 547     returnTc (HsVar dm_name)
 548
 549 mkDefMethRhs is_inst_decl clas inst_tys sel_id loc NoDefMeth
 550   =     -- No default method
 551         -- Warn only if -fwarn-missing-methods
 552     doptsTc Opt_WarnMissingMethods              `thenNF_Tc` \ warn ->
 553     warnTc (is_inst_decl && warn)
 554            (omittedMethodWarn sel_id)           `thenNF_Tc_`
 555     returnTc error_rhs
 556   where
 557     error_rhs = HsApp (HsVar (getName nO_METHOD_BINDING_ERROR_ID))
 558                           (HsLit (HsString (_PK_ error_msg)))
 559     error_msg = showSDoc (hcat [ppr loc, text "|", ppr sel_id ])
 560
 561
 562 mkDefMethRhs is_inst_decl clas inst_tys sel_id loc GenDefMeth
 563   =     -- A generic default method
 564         -- If the method is defined generically, we can only do the job if the
 565         -- instance declaration is for a single-parameter type class with
 566         -- a type constructor applied to type arguments in the instance decl
 567         --      (checkTc, so False provokes the error)
 568      checkTc (not is_inst_decl || simple_inst)
 569              (badGenericInstance sel_id)                        `thenTc_`
 570
 571      ioToTc (dumpIfSet opt_PprStyle_Debug "Generic RHS" stuff)  `thenNF_Tc_`
 572      returnTc rhs
 573   where
 574     rhs = mkGenericRhs sel_id clas_tyvar tycon
 575
 576     stuff = vcat [ppr clas <+> ppr inst_tys,
 577                   nest 4 (ppr sel_id <+> equals <+> ppr rhs)]
 578
 579           -- The tycon is only used in the generic case, and in that
 580           -- case we require that the instance decl is for a single-parameter
 581           -- type class with type variable arguments:
 582           --    instance (...) => C (T a b)
 583     simple_inst   = maybeToBool maybe_tycon
 584     clas_tyvar    = head (classTyVars clas)
 585     Just tycon    = maybe_tycon
 586     maybe_tycon   = case inst_tys of
 587                         [ty] -> case tcSplitTyConApp_maybe ty of
 588                                   Just (tycon, arg_tys) | all tcIsTyVarTy arg_tys -> Just tycon
 589                                   other                                           -> Nothing
 590                         other -> Nothing
 591 \end{code}
 592
 593
 594 \begin{code}
 595 -- The renamer just puts the selector ID as the binder in the method binding
 596 -- but we must use the method name; so we substitute it here.  Crude but simple.
 597 find_bind sel_name meth_name (FunMonoBind op_name fix matches loc)
 598     | op_name == sel_name = Just (FunMonoBind meth_name fix matches loc)
 599 find_bind sel_name meth_name (AndMonoBinds b1 b2)
 600     = find_bind sel_name meth_name b1 `seqMaybe` find_bind sel_name meth_name b2
 601 find_bind sel_name meth_name other  = Nothing   -- Default case
 602
 603  -- Find the prags for this method, and replace the
 604  -- selector name with the method name
 605 find_prags sel_name meth_name [] = []
 606 find_prags sel_name meth_name (SpecSig name ty loc : prags)
 607      | name == sel_name = SpecSig meth_name ty loc : find_prags sel_name meth_name prags
 608 find_prags sel_name meth_name (InlineSig sense name phase loc : prags)
 609    | name == sel_name = InlineSig sense meth_name phase loc : find_prags sel_name meth_name prags
 610 find_prags sel_name meth_name (prag:prags) = find_prags sel_name meth_name prags
 611 \end{code}
 612
 613
 614 Contexts and errors
 615 ~~~~~~~~~~~~~~~~~~~
 616 \begin{code}
 617 nullaryClassErr cls
 618   = ptext SLIT("No parameters for class")  <+> quotes (ppr cls)
 619
 620 classArityErr cls
 621   = vcat [ptext SLIT("Too many parameters for class") <+> quotes (ppr cls),
 622           parens (ptext SLIT("Use -fglasgow-exts to allow multi-parameter classes"))]
 623
 624 defltMethCtxt clas
 625   = ptext SLIT("When checking the default methods for class") <+> quotes (ppr clas)
 626
 627 methodCtxt sel_id
 628   = ptext SLIT("In the definition for method") <+> quotes (ppr sel_id)
 629
 630 badMethodErr clas op
 631   = hsep [ptext SLIT("Class"), quotes (ppr clas),
 632           ptext SLIT("does not have a method"), quotes (ppr op)]
 633
 634 omittedMethodWarn sel_id
 635   = ptext SLIT("No explicit method nor default method for") <+> quotes (ppr sel_id)
 636
 637 badGenericMethodType op op_ty
 638   = hang (ptext SLIT("Generic method type is too complex"))
 639        4 (vcat [ppr op <+> dcolon <+> ppr op_ty,
 640                 ptext SLIT("You can only use type variables, arrows, and tuples")])
 641
 642 badGenericInstance sel_id
 643   = sep [ptext SLIT("Can't derive generic code for") <+> quotes (ppr sel_id),
 644          ptext SLIT("because the instance declaration is not for a simple type (T a b c)"),
 645          ptext SLIT("(where T is a derivable type constructor)")]
 646
 647 mixedGenericErr op
 648   = ptext SLIT("Can't mix generic and non-generic equations for class method") <+> quotes (ppr op)
 649
 650 genericMultiParamErr clas
 651   = ptext SLIT("The multi-parameter class") <+> quotes (ppr clas) <+>
 652     ptext SLIT("cannot have generic methods")
 653 \end{code}