ghc/compiler/typecheck/TcClassDcl.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcClassDcl]{Typechecking class declarations}
   5
   6 \begin{code}
   7 module TcClassDcl ( tcClassDecl1, tcClassDecls2,
   8                     MethodSpec, tcMethodBind, mkMethodBind, badMethodErr
   9                   ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn            ( TyClDecl(..), Sig(..), MonoBinds(..),
  14                           HsExpr(..), HsLit(..), Pat(WildPat),
  15                           mkSimpleMatch, andMonoBinds, andMonoBindList,
  16                           isClassOpSig, isPragSig,
  17                           placeHolderType
  18                         )
  19 import BasicTypes       ( RecFlag(..), StrictnessMark(..) )
  20 import RnHsSyn          ( RenamedTyClDecl, RenamedSig,
  21                           RenamedClassOpSig, RenamedMonoBinds,
  22                           maybeGenericMatch
  23                         )
  24 import RnEnv            ( lookupSysName )
  25 import TcHsSyn          ( TcMonoBinds )
  26
  27 import Inst             ( Inst, InstOrigin(..), instToId, newDicts, newMethodAtLoc )
  28 import TcEnv            ( TyThingDetails(..),
  29                           tcLookupClass, tcExtendTyVarEnv2,
  30                           tcExtendTyVarEnv
  31                         )
  32 import TcBinds          ( tcMonoBinds )
  33 import TcMonoType       ( TcSigInfo(..), tcHsType, tcHsTheta, mkTcSig )
  34 import TcSimplify       ( tcSimplifyCheck )
  35 import TcUnify          ( checkSigTyVars, sigCtxt )
  36 import TcMType          ( tcInstTyVars )
  37 import TcType           ( Type, TyVarDetails(..), TcType, TcThetaType, TcTyVar,
  38                           mkTyVarTys, mkPredTys, mkClassPred, tcSplitSigmaTy, tcSplitFunTys,
  39                           tcIsTyVarTy, tcSplitTyConApp_maybe
  40                         )
  41 import TcRnMonad
  42 import Generics         ( mkGenericRhs )
  43 import PrelInfo         ( nO_METHOD_BINDING_ERROR_ID )
  44 import Class            ( classTyVars, classBigSig, classTyCon,
  45                           Class, ClassOpItem, DefMeth (..) )
  46 import TyCon            ( tyConGenInfo )
  47 import MkId             ( mkDictSelId, mkDataConId, mkDataConWrapId, mkDefaultMethodId )
  48 import DataCon          ( mkDataCon )
  49 import Id               ( Id, idType, idName, setIdLocalExported, setInlinePragma )
  50 import Name             ( Name, NamedThing(..) )
  51 import NameEnv          ( NameEnv, lookupNameEnv, emptyNameEnv, unitNameEnv, plusNameEnv )
  52 import NameSet          ( emptyNameSet, unitNameSet )
  53 import OccName          ( mkClassTyConOcc, mkClassDataConOcc, mkWorkerOcc, mkSuperDictSelOcc )
  54 import Outputable
  55 import Var              ( TyVar )
  56 import CmdLineOpts
  57 import UnicodeUtil      ( stringToUtf8 )
  58 import ErrUtils         ( dumpIfSet )
  59 import Util             ( count, lengthIs )
  60 import Maybes           ( seqMaybe )
  61 import Maybe            ( isJust )
  62 import FastString
  63 \end{code}
  64
  65
  66
  67 Dictionary handling
  68 ~~~~~~~~~~~~~~~~~~~
  69 Every class implicitly declares a new data type, corresponding to dictionaries
  70 of that class. So, for example:
  71
  72         class (D a) => C a where
  73           op1 :: a -> a
  74           op2 :: forall b. Ord b => a -> b -> b
  75
  76 would implicitly declare
  77
  78         data CDict a = CDict (D a)
  79                              (a -> a)
  80                              (forall b. Ord b => a -> b -> b)
  81
  82 (We could use a record decl, but that means changing more of the existing apparatus.
  83 One step at at time!)
  84
  85 For classes with just one superclass+method, we use a newtype decl instead:
  86
  87         class C a where
  88           op :: forallb. a -> b -> b
  89
  90 generates
  91
  92         newtype CDict a = CDict (forall b. a -> b -> b)
  93
  94 Now DictTy in Type is just a form of type synomym:
  95         DictTy c t = TyConTy CDict `AppTy` t
  96
  97 Death to "ExpandingDicts".
  98
  99
 100 %************************************************************************
 101 %*                                                                      *
 102 \subsection{Type checking}
 103 %*                                                                      *
 104 %************************************************************************
 105
 106 \begin{code}
 107
 108 tcClassDecl1 :: RenamedTyClDecl -> TcM (Name, TyThingDetails)
 109 tcClassDecl1 (ClassDecl {tcdCtxt = context, tcdName = class_name,
 110                          tcdTyVars = tyvar_names, tcdFDs = fundeps,
 111                          tcdSigs = class_sigs, tcdMeths = def_methods,
 112                          tcdLoc = src_loc})
 113   =     -- LOOK THINGS UP IN THE ENVIRONMENT
 114     tcLookupClass class_name                            `thenM` \ clas ->
 115     let
 116         tyvars     = classTyVars clas
 117         op_sigs    = filter isClassOpSig class_sigs
 118         op_names   = [n | ClassOpSig n _ _ _ <- op_sigs]
 119     in
 120     tcExtendTyVarEnv tyvars                             $
 121
 122     checkDefaultBinds clas op_names def_methods   `thenM` \ mb_dm_env ->
 123
 124         -- CHECK THE CONTEXT
 125         -- The renamer has already checked that the context mentions
 126         -- only the type variable of the class decl.
 127         -- Context is already kind-checked
 128     tcHsTheta context                                   `thenM` \ sc_theta ->
 129
 130         -- CHECK THE CLASS SIGNATURES,
 131     mappM (tcClassSig clas tyvars mb_dm_env) op_sigs    `thenM` \ sig_stuff ->
 132
 133         -- MAKE THE CLASS DETAILS
 134     lookupSysName class_name   mkClassDataConOcc        `thenM` \ datacon_name ->
 135     lookupSysName datacon_name mkWorkerOcc              `thenM` \ datacon_wkr_name ->
 136     mapM (lookupSysName class_name . mkSuperDictSelOcc)
 137          [1..length context]                            `thenM` \ sc_sel_names ->
 138       -- We number off the superclass selectors, 1, 2, 3 etc so that we
 139       -- can construct names for the selectors.  Thus
 140       --      class (C a, C b) => D a b where ...
 141       -- gives superclass selectors
 142       --      D_sc1, D_sc2
 143       -- (We used to call them D_C, but now we can have two different
 144       --  superclasses both called C!)
 145     lookupSysName class_name mkClassTyConOcc    `thenM` \ tycon_name ->
 146     let
 147         (op_tys, op_items) = unzip sig_stuff
 148         sc_tys             = mkPredTys sc_theta
 149         dict_component_tys = sc_tys ++ op_tys
 150         sc_sel_ids         = [mkDictSelId sc_name clas | sc_name <- sc_sel_names]
 151
 152         dict_con = mkDataCon datacon_name
 153                              [NotMarkedStrict | _ <- dict_component_tys]
 154                              [{- No labelled fields -}]
 155                              tyvars
 156                              [{-No context-}]
 157                              [{-No existential tyvars-}] [{-Or context-}]
 158                              dict_component_tys
 159                              (classTyCon clas)
 160                              dict_con_id dict_wrap_id
 161
 162         dict_con_id  = mkDataConId datacon_wkr_name dict_con
 163         dict_wrap_id = mkDataConWrapId dict_con
 164     in
 165     returnM (class_name, ClassDetails sc_theta sc_sel_ids op_items dict_con tycon_name)
 166 \end{code}
 167
 168 \begin{code}
 169 checkDefaultBinds :: Class -> [Name] -> Maybe RenamedMonoBinds
 170                   -> TcM (Maybe (NameEnv Bool))
 171         -- The returned environment says
 172         --      x not in env => no default method
 173         --      x -> True    => generic default method
 174         --      x -> False   => polymorphic default method
 175
 176   -- Check default bindings
 177   --    a) must be for a class op for this class
 178   --    b) must be all generic or all non-generic
 179   -- and return a mapping from class-op to DefMeth info
 180
 181   -- But do all this only for source binds
 182
 183 checkDefaultBinds clas ops Nothing
 184   = returnM Nothing
 185
 186 checkDefaultBinds clas ops (Just mbs)
 187   = go mbs      `thenM` \ dm_env ->
 188     returnM (Just dm_env)
 189   where
 190     go EmptyMonoBinds = returnM emptyNameEnv
 191
 192     go (AndMonoBinds b1 b2)
 193       = go b1   `thenM` \ dm_info1 ->
 194         go b2   `thenM` \ dm_info2 ->
 195         returnM (dm_info1 `plusNameEnv` dm_info2)
 196
 197     go (FunMonoBind op _ matches loc)
 198       = addSrcLoc loc                                   $
 199
 200         -- Check that the op is from this class
 201         checkTc (op `elem` ops) (badMethodErr clas op)          `thenM_`
 202
 203         -- Check that all the defns ar generic, or none are
 204         checkTc (all_generic || none_generic) (mixedGenericErr op)      `thenM_`
 205
 206         returnM (unitNameEnv op all_generic)
 207       where
 208         n_generic    = count (isJust . maybeGenericMatch) matches
 209         none_generic = n_generic == 0
 210         all_generic  = matches `lengthIs` n_generic
 211 \end{code}
 212
 213
 214 \begin{code}
 215 tcClassSig :: Class                     -- ...ditto...
 216            -> [TyVar]                   -- The class type variable, used for error check only
 217            -> Maybe (NameEnv Bool)      -- Info about default methods;
 218                                         --      Nothing => imported class defn with no method binds
 219            -> RenamedClassOpSig
 220            -> TcM (Type,                -- Type of the method
 221                      ClassOpItem)       -- Selector Id, default-method Id, True if explicit default binding
 222
 223 -- This warrants an explanation: we need to separate generic
 224 -- default methods and default methods later on in the compiler
 225 -- so we distinguish them in checkDefaultBinds, and pass this knowledge in the
 226 -- Class.DefMeth data structure.
 227
 228 tcClassSig clas clas_tyvars maybe_dm_env
 229            (ClassOpSig op_name sig_dm op_ty src_loc)
 230   = addSrcLoc src_loc $
 231
 232         -- Check the type signature.  NB that the envt *already has*
 233         -- bindings for the type variables; see comments in TcTyAndClassDcls.
 234     tcHsType op_ty                      `thenM` \ local_ty ->
 235
 236     let
 237         theta = [mkClassPred clas (mkTyVarTys clas_tyvars)]
 238
 239         -- Build the selector id and default method id
 240         sel_id = mkDictSelId op_name clas
 241         DefMeth dm_name = sig_dm
 242
 243         dm_info = case maybe_dm_env of
 244                     Nothing     -> sig_dm
 245                     Just dm_env -> mk_src_dm_info dm_env
 246
 247         mk_src_dm_info dm_env = case lookupNameEnv dm_env op_name of
 248                                    Nothing    -> NoDefMeth
 249                                    Just True  -> GenDefMeth
 250                                    Just False -> DefMeth dm_name
 251     in
 252     returnM (local_ty, (sel_id, dm_info))
 253 \end{code}
 254
 255
 256 %************************************************************************
 257 %*                                                                      *
 258 \subsection[Default methods]{Default methods}
 259 %*                                                                      *
 260 %************************************************************************
 261
 262 The default methods for a class are each passed a dictionary for the
 263 class, so that they get access to the other methods at the same type.
 264 So, given the class decl
 265 \begin{verbatim}
 266 class Foo a where
 267         op1 :: a -> Bool
 268         op2 :: Ord b => a -> b -> b -> b
 269
 270         op1 x = True
 271         op2 x y z = if (op1 x) && (y < z) then y else z
 272 \end{verbatim}
 273 we get the default methods:
 274 \begin{verbatim}
 275 defm.Foo.op1 :: forall a. Foo a => a -> Bool
 276 defm.Foo.op1 = /\a -> \dfoo -> \x -> True
 277
 278 defm.Foo.op2 :: forall a. Foo a => forall b. Ord b => a -> b -> b -> b
 279 defm.Foo.op2 = /\ a -> \ dfoo -> /\ b -> \ dord -> \x y z ->
 280                   if (op1 a dfoo x) && (< b dord y z) then y else z
 281 \end{verbatim}
 282
 283 When we come across an instance decl, we may need to use the default
 284 methods:
 285 \begin{verbatim}
 286 instance Foo Int where {}
 287 \end{verbatim}
 288 gives
 289 \begin{verbatim}
 290 const.Foo.Int.op1 :: Int -> Bool
 291 const.Foo.Int.op1 = defm.Foo.op1 Int dfun.Foo.Int
 292
 293 const.Foo.Int.op2 :: forall b. Ord b => Int -> b -> b -> b
 294 const.Foo.Int.op2 = defm.Foo.op2 Int dfun.Foo.Int
 295
 296 dfun.Foo.Int :: Foo Int
 297 dfun.Foo.Int = (const.Foo.Int.op1, const.Foo.Int.op2)
 298 \end{verbatim}
 299 Notice that, as with method selectors above, we assume that dictionary
 300 application is curried, so there's no need to mention the Ord dictionary
 301 in const.Foo.Int.op2 (or the type variable).
 302
 303 \begin{verbatim}
 304 instance Foo a => Foo [a] where {}
 305
 306 dfun.Foo.List :: forall a. Foo a -> Foo [a]
 307 dfun.Foo.List
 308   = /\ a -> \ dfoo_a ->
 309     let rec
 310         op1 = defm.Foo.op1 [a] dfoo_list
 311         op2 = defm.Foo.op2 [a] dfoo_list
 312         dfoo_list = (op1, op2)
 313     in
 314         dfoo_list
 315 \end{verbatim}
 316
 317 The function @tcClassDecls2@ just arranges to apply @tcClassDecl2@ to
 318 each local class decl.
 319
 320 \begin{code}
 321 tcClassDecls2 :: [RenamedTyClDecl] -> TcM (TcMonoBinds, [Id])
 322
 323 tcClassDecls2 decls
 324   = foldr combine
 325           (returnM (EmptyMonoBinds, []))
 326           [tcClassDecl2 cls_decl | cls_decl@(ClassDecl {tcdMeths = Just _}) <- decls]
 327                 -- The 'Just' picks out source ClassDecls
 328   where
 329     combine tc1 tc2 = tc1 `thenM` \ (binds1, ids1) ->
 330                       tc2 `thenM` \ (binds2, ids2) ->
 331                       returnM (binds1 `AndMonoBinds` binds2,
 332                                ids1 ++ ids2)
 333 \end{code}
 334
 335 @tcClassDecl2@ generates bindings for polymorphic default methods
 336 (generic default methods have by now turned into instance declarations)
 337
 338 \begin{code}
 339 tcClassDecl2 :: RenamedTyClDecl         -- The class declaration
 340              -> TcM (TcMonoBinds, [Id])
 341
 342 tcClassDecl2 (ClassDecl {tcdName = class_name, tcdSigs = sigs,
 343                          tcdMeths = Just default_binds, tcdLoc = src_loc})
 344   =     -- The 'Just' picks out source ClassDecls
 345     recoverM (returnM (EmptyMonoBinds, []))     $
 346     addSrcLoc src_loc                                   $
 347     tcLookupClass class_name                            `thenM` \ clas ->
 348
 349         -- We make a separate binding for each default method.
 350         -- At one time I used a single AbsBinds for all of them, thus
 351         -- AbsBind [d] [dm1, dm2, dm3] { dm1 = ...; dm2 = ...; dm3 = ... }
 352         -- But that desugars into
 353         --      ds = \d -> (..., ..., ...)
 354         --      dm1 = \d -> case ds d of (a,b,c) -> a
 355         -- And since ds is big, it doesn't get inlined, so we don't get good
 356         -- default methods.  Better to make separate AbsBinds for each
 357     let
 358         (tyvars, _, _, op_items) = classBigSig clas
 359         prags                    = filter isPragSig sigs
 360         tc_dm                    = tcDefMeth clas tyvars default_binds prags
 361     in
 362     mapAndUnzipM tc_dm op_items `thenM` \ (defm_binds, dm_ids_s) ->
 363
 364     returnM (andMonoBindList defm_binds, concat dm_ids_s)
 365
 366
 367 tcDefMeth clas tyvars binds_in prags (_, NoDefMeth)  = returnM (EmptyMonoBinds, [])
 368 tcDefMeth clas tyvars binds_in prags (_, GenDefMeth) = returnM (EmptyMonoBinds, [])
 369         -- Generate code for polymorphic default methods only
 370         -- (Generic default methods have turned into instance decls by now.)
 371         -- This is incompatible with Hugs, which expects a polymorphic
 372         -- default method for every class op, regardless of whether or not
 373         -- the programmer supplied an explicit default decl for the class.
 374         -- (If necessary we can fix that, but we don't have a convenient Id to hand.)
 375
 376 tcDefMeth clas tyvars binds_in prags op_item@(sel_id, DefMeth dm_name)
 377   = tcInstTyVars ClsTv tyvars           `thenM` \ (clas_tyvars, inst_tys, _) ->
 378     let
 379         dm_ty = idType sel_id   -- Same as dict selector!
 380           -- The default method's type should really come from the
 381           -- iface file, since it could be usage-generalised, but this
 382           -- requires altering the mess of knots in TcModule and I'm
 383           -- too scared to do that.  Instead, I have disabled generalisation
 384           -- of types of default methods (and dict funs) by annotating them
 385           -- TyGenNever (in MkId).  Ugh!  KSW 1999-09.
 386
 387         theta       = [mkClassPred clas inst_tys]
 388         dm_id       = mkDefaultMethodId dm_name dm_ty
 389         local_dm_id = setIdLocalExported dm_id
 390                 -- Reason for setIdLocalExported: see notes with MkId.mkDictFunId
 391         xtve = tyvars `zip` clas_tyvars
 392     in
 393     newDicts origin theta                               `thenM` \ [this_dict] ->
 394
 395     mkMethodBind origin clas inst_tys binds_in op_item  `thenM` \ (dm_inst, meth_info) ->
 396     getLIE (tcMethodBind xtve clas_tyvars theta
 397                          [this_dict] prags meth_info)   `thenM` \ (defm_bind, insts_needed) ->
 398
 399     addErrCtxt (defltMethCtxt clas) $
 400
 401         -- Check the context
 402     tcSimplifyCheck
 403         (ptext SLIT("class") <+> ppr clas)
 404         clas_tyvars
 405         [this_dict]
 406         insts_needed                    `thenM` \ dict_binds ->
 407
 408         -- Simplification can do unification
 409     checkSigTyVars clas_tyvars          `thenM` \ clas_tyvars' ->
 410
 411     let
 412         full_bind = AbsBinds
 413                     clas_tyvars'
 414                     [instToId this_dict]
 415                     [(clas_tyvars', local_dm_id, instToId dm_inst)]
 416                     emptyNameSet        -- No inlines (yet)
 417                     (dict_binds `andMonoBinds` defm_bind)
 418     in
 419     returnM (full_bind, [dm_id])
 420   where
 421     origin = ClassDeclOrigin
 422 \end{code}
 423
 424
 425
 426 %************************************************************************
 427 %*                                                                      *
 428 \subsection{Typechecking a method}
 429 %*                                                                      *
 430 %************************************************************************
 431
 432 @tcMethodBind@ is used to type-check both default-method and
 433 instance-decl method declarations.  We must type-check methods one at a
 434 time, because their signatures may have different contexts and
 435 tyvar sets.
 436
 437 \begin{code}
 438 type MethodSpec = (Id,                  -- Global selector Id
 439                    TcSigInfo,           -- Signature
 440                    RenamedMonoBinds)    -- Binding for the method
 441
 442 tcMethodBind
 443         :: [(TyVar,TcTyVar)]    -- Bindings for type environment
 444         -> [TcTyVar]            -- Instantiated type variables for the
 445                                 --      enclosing class/instance decl.
 446                                 --      They'll be signature tyvars, and we
 447                                 --      want to check that they don't get bound
 448                                 -- Always equal the range of the type envt
 449         -> TcThetaType          -- Available theta; it's just used for the error message
 450         -> [Inst]               -- Available from context, used to simplify constraints
 451                                 --      from the method body
 452         -> [RenamedSig]         -- Pragmas (e.g. inline pragmas)
 453         -> MethodSpec           -- Details of this method
 454         -> TcM TcMonoBinds
 455
 456 tcMethodBind xtve inst_tyvars inst_theta avail_insts prags
 457              (sel_id, meth_sig, meth_bind)
 458   =     -- Check the bindings; first adding inst_tyvars to the envt
 459         -- so that we don't quantify over them in nested places
 460      tcExtendTyVarEnv2 xtve (
 461         addErrCtxt (methodCtxt sel_id)          $
 462         getLIE (tcMonoBinds meth_bind [meth_sig] NonRecursive)
 463      )                                          `thenM` \ ((meth_bind, _, _), meth_lie) ->
 464
 465         -- Now do context reduction.   We simplify wrt both the local tyvars
 466         -- and the ones of the class/instance decl, so that there is
 467         -- no problem with
 468         --      class C a where
 469         --        op :: Eq a => a -> b -> a
 470         --
 471         -- We do this for each method independently to localise error messages
 472
 473      let
 474         TySigInfo meth_id meth_tvs meth_theta _ local_meth_id _ _ = meth_sig
 475      in
 476      addErrCtxtM (sigCtxt sel_id inst_tyvars inst_theta (idType meth_id))       $
 477      newDicts SignatureOrigin meth_theta        `thenM` \ meth_dicts ->
 478      let
 479         all_tyvars = meth_tvs ++ inst_tyvars
 480         all_insts  = avail_insts ++ meth_dicts
 481      in
 482      tcSimplifyCheck
 483          (ptext SLIT("class or instance method") <+> quotes (ppr sel_id))
 484          all_tyvars all_insts meth_lie          `thenM` \ lie_binds ->
 485
 486      checkSigTyVars all_tyvars                  `thenM` \ all_tyvars' ->
 487
 488      let
 489                 -- Attach inline pragmas as appropriate
 490         (final_meth_id, inlines)
 491            | (InlineSig inl _ phase _ : _) <- filter is_inline prags
 492            = (meth_id `setInlinePragma` phase,
 493               if inl then unitNameSet (idName meth_id) else emptyNameSet)
 494            | otherwise
 495            = (meth_id, emptyNameSet)
 496
 497         is_inline (InlineSig _ name _ _) = name == idName sel_id
 498         is_inline other                  = False
 499
 500         meth_tvs'      = take (length meth_tvs) all_tyvars'
 501         poly_meth_bind = AbsBinds meth_tvs'
 502                                   (map instToId meth_dicts)
 503                                   [(meth_tvs', final_meth_id, local_meth_id)]
 504                                   inlines
 505                                   (lie_binds `andMonoBinds` meth_bind)
 506      in
 507      returnM poly_meth_bind
 508
 509
 510 mkMethodBind :: InstOrigin
 511              -> Class -> [TcType]       -- Class and instance types
 512              -> RenamedMonoBinds        -- Method binding (pick the right one from in here)
 513              -> ClassOpItem
 514              -> TcM (Inst,              -- Method inst
 515                      MethodSpec)
 516 -- Find the binding for the specified method, or make
 517 -- up a suitable default method if it isn't there
 518
 519 mkMethodBind origin clas inst_tys meth_binds (sel_id, dm_info)
 520   = getInstLoc origin                           `thenM` \ inst_loc ->
 521     newMethodAtLoc inst_loc sel_id inst_tys     `thenM` \ meth_inst ->
 522         -- Do not dump anything into the LIE
 523     let
 524         meth_id    = instToId meth_inst
 525         meth_name  = idName meth_id
 526     in
 527         -- Figure out what method binding to use
 528         -- If the user suppplied one, use it, else construct a default one
 529     getSrcLocM                                  `thenM` \ loc ->
 530     (case find_bind (idName sel_id) meth_name meth_binds of
 531         Just user_bind -> returnM user_bind
 532         Nothing        -> mkDefMethRhs origin clas inst_tys sel_id loc dm_info  `thenM` \ rhs ->
 533                           returnM (FunMonoBind meth_name False  -- Not infix decl
 534                                                 [mkSimpleMatch [] rhs placeHolderType loc] loc)
 535     )                                                           `thenM` \ meth_bind ->
 536
 537     mkTcSig meth_id loc                 `thenM` \ meth_sig ->
 538
 539     returnM (meth_inst, (sel_id, meth_sig, meth_bind))
 540
 541
 542      -- The user didn't supply a method binding,
 543      -- so we have to make up a default binding
 544      -- The RHS of a default method depends on the default-method info
 545 mkDefMethRhs origin clas inst_tys sel_id loc (DefMeth dm_name)
 546   =  -- An polymorphic default method
 547     traceRn (text "mkDefMeth" <+> ppr dm_name)  `thenM_`
 548     returnM (HsVar dm_name)
 549
 550 mkDefMethRhs origin clas inst_tys sel_id loc NoDefMeth
 551   =     -- No default method
 552         -- Warn only if -fwarn-missing-methods
 553     doptM Opt_WarnMissingMethods                `thenM` \ warn ->
 554     warnTc (isInstDecl origin && warn)
 555            (omittedMethodWarn sel_id)           `thenM_`
 556     returnM error_rhs
 557   where
 558     error_rhs  = HsLam (mkSimpleMatch wild_pats simple_rhs placeHolderType loc)
 559     simple_rhs = HsApp (HsVar (getName nO_METHOD_BINDING_ERROR_ID))
 560                        (HsLit (HsStringPrim (mkFastString (stringToUtf8 error_msg))))
 561     error_msg = showSDoc (hcat [ppr loc, text "|", ppr sel_id ])
 562
 563         -- When the type is of form t1 -> t2 -> t3
 564         -- make a default method like (\ _ _ -> noMethBind "blah")
 565         -- rather than simply        (noMethBind "blah")
 566         -- Reason: if t1 or t2 are higher-ranked types we get n
 567         --         silly ambiguity messages.
 568         -- Example:     f :: (forall a. Eq a => a -> a) -> Int
 569         --              f = error "urk"
 570         -- Here, tcSub tries to force (error "urk") to have the right type,
 571         -- thus:        f = \(x::forall a. Eq a => a->a) -> error "urk" (x t)
 572         -- where 't' is fresh ty var.  This leads directly to "ambiguous t".
 573         --
 574         -- NB: technically this changes the meaning of the default-default
 575         --     method slightly, because `seq` can see the lambdas.  Oh well.
 576     (_,_,tau1)    = tcSplitSigmaTy (idType sel_id)
 577     (_,_,tau2)    = tcSplitSigmaTy tau1
 578         -- Need two splits because the  selector can have a type like
 579         --      forall a. Foo a => forall b. Eq b => ...
 580     (arg_tys, _) = tcSplitFunTys tau2
 581     wild_pats    = [WildPat placeHolderType | ty <- arg_tys]
 582
 583 mkDefMethRhs origin clas inst_tys sel_id loc GenDefMeth
 584   =     -- A generic default method
 585         -- If the method is defined generically, we can only do the job if the
 586         -- instance declaration is for a single-parameter type class with
 587         -- a type constructor applied to type arguments in the instance decl
 588         --      (checkTc, so False provokes the error)
 589      ASSERT( isInstDecl origin )        -- We never get here from a class decl
 590
 591      checkTc (isJust maybe_tycon)
 592              (badGenericInstance sel_id (notSimple inst_tys))           `thenM_`
 593      checkTc (isJust (tyConGenInfo tycon))
 594              (badGenericInstance sel_id (notGeneric tycon))             `thenM_`
 595
 596      ioToTcRn (dumpIfSet opt_PprStyle_Debug "Generic RHS" stuff)        `thenM_`
 597      returnM rhs
 598   where
 599     rhs = mkGenericRhs sel_id clas_tyvar tycon
 600
 601     stuff = vcat [ppr clas <+> ppr inst_tys,
 602                   nest 4 (ppr sel_id <+> equals <+> ppr rhs)]
 603
 604           -- The tycon is only used in the generic case, and in that
 605           -- case we require that the instance decl is for a single-parameter
 606           -- type class with type variable arguments:
 607           --    instance (...) => C (T a b)
 608     clas_tyvar    = head (classTyVars clas)
 609     Just tycon    = maybe_tycon
 610     maybe_tycon   = case inst_tys of
 611                         [ty] -> case tcSplitTyConApp_maybe ty of
 612                                   Just (tycon, arg_tys) | all tcIsTyVarTy arg_tys -> Just tycon
 613                                   other                                           -> Nothing
 614                         other -> Nothing
 615
 616 isInstDecl InstanceDeclOrigin = True
 617 isInstDecl ClassDeclOrigin    = False
 618 \end{code}
 619
 620
 621 \begin{code}
 622 -- The renamer just puts the selector ID as the binder in the method binding
 623 -- but we must use the method name; so we substitute it here.  Crude but simple.
 624 find_bind sel_name meth_name (FunMonoBind op_name fix matches loc)
 625     | op_name == sel_name = Just (FunMonoBind meth_name fix matches loc)
 626 find_bind sel_name meth_name (AndMonoBinds b1 b2)
 627     = find_bind sel_name meth_name b1 `seqMaybe` find_bind sel_name meth_name b2
 628 find_bind sel_name meth_name other  = Nothing   -- Default case
 629
 630  -- Find the prags for this method, and replace the
 631  -- selector name with the method name
 632 find_prags sel_name meth_name [] = []
 633 find_prags sel_name meth_name (SpecSig name ty loc : prags)
 634      | name == sel_name = SpecSig meth_name ty loc : find_prags sel_name meth_name prags
 635 find_prags sel_name meth_name (InlineSig sense name phase loc : prags)
 636    | name == sel_name = InlineSig sense meth_name phase loc : find_prags sel_name meth_name prags
 637 find_prags sel_name meth_name (prag:prags) = find_prags sel_name meth_name prags
 638 \end{code}
 639
 640
 641 Contexts and errors
 642 ~~~~~~~~~~~~~~~~~~~
 643 \begin{code}
 644 defltMethCtxt clas
 645   = ptext SLIT("When checking the default methods for class") <+> quotes (ppr clas)
 646
 647 methodCtxt sel_id
 648   = ptext SLIT("In the definition for method") <+> quotes (ppr sel_id)
 649
 650 badMethodErr clas op
 651   = hsep [ptext SLIT("Class"), quotes (ppr clas),
 652           ptext SLIT("does not have a method"), quotes (ppr op)]
 653
 654 omittedMethodWarn sel_id
 655   = ptext SLIT("No explicit method nor default method for") <+> quotes (ppr sel_id)
 656
 657 badGenericInstance sel_id because
 658   = sep [ptext SLIT("Can't derive generic code for") <+> quotes (ppr sel_id),
 659          because]
 660
 661 notSimple inst_tys
 662   = vcat [ptext SLIT("because the instance type(s)"),
 663           nest 2 (ppr inst_tys),
 664           ptext SLIT("is not a simple type of form (T a b c)")]
 665
 666 notGeneric tycon
 667   = vcat [ptext SLIT("because the instance type constructor") <+> quotes (ppr tycon) <+>
 668           ptext SLIT("was not compiled with -fgenerics")]
 669
 670 mixedGenericErr op
 671   = ptext SLIT("Can't mix generic and non-generic equations for class method") <+> quotes (ppr op)
 672 \end{code}