ghc/compiler/typecheck/TcDeriv.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcDeriv]{Deriving}
   5
   6 Handles @deriving@ clauses on @data@ declarations.
   7
   8 \begin{code}
   9 module TcDeriv ( tcDeriving ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn            ( HsBinds(..), MonoBinds(..), TyClDecl(..),
  14                           collectLocatedMonoBinders )
  15 import RdrHsSyn         ( RdrNameMonoBinds )
  16 import RnHsSyn          ( RenamedHsBinds, RenamedMonoBinds, RenamedTyClDecl )
  17 import CmdLineOpts      ( DynFlag(..), DynFlags )
  18
  19 import TcMonad
  20 import TcEnv            ( tcSetInstEnv, newDFunName, InstInfo(..), pprInstInfo,
  21                           tcLookupClass, tcLookupTyCon
  22                         )
  23 import TcGenDeriv       -- Deriv stuff
  24 import InstEnv          ( InstEnv, simpleDFunClassTyCon, extendInstEnv )
  25 import TcSimplify       ( tcSimplifyThetas )
  26
  27 import RnBinds          ( rnMethodBinds, rnTopMonoBinds )
  28 import RnEnv            ( bindLocatedLocalsRn )
  29 import RnMonad          ( renameDerivedCode, thenRn, mapRn, returnRn )
  30 import HscTypes         ( DFunId, PersistentRenamerState )
  31
  32 import BasicTypes       ( Fixity )
  33 import Class            ( classKey, Class )
  34 import ErrUtils         ( dumpIfSet_dyn, Message )
  35 import MkId             ( mkDictFunId )
  36 import DataCon          ( dataConArgTys, isNullaryDataCon, isExistentialDataCon )
  37 import PrelInfo         ( needsDataDeclCtxtClassKeys )
  38 import Maybes           ( maybeToBool, catMaybes )
  39 import Module           ( Module )
  40 import Name             ( Name, getSrcLoc )
  41 import RdrName          ( RdrName )
  42
  43 import TyCon            ( tyConTyVars, tyConDataCons,
  44                           tyConTheta, maybeTyConSingleCon, isDataTyCon,
  45                           isEnumerationTyCon, TyCon
  46                         )
  47 import Type             ( TauType, ThetaType, PredType, mkTyVarTys, mkTyConApp,
  48                           isUnLiftedType, mkClassPred )
  49 import Var              ( TyVar )
  50 import PrelNames
  51 import Util             ( zipWithEqual, sortLt )
  52 import ListSetOps       ( removeDups,  assoc )
  53 import Outputable
  54 import List             ( nub )
  55 \end{code}
  56
  57 %************************************************************************
  58 %*                                                                      *
  59 \subsection[TcDeriv-intro]{Introduction to how we do deriving}
  60 %*                                                                      *
  61 %************************************************************************
  62
  63 Consider
  64
  65         data T a b = C1 (Foo a) (Bar b)
  66                    | C2 Int (T b a)
  67                    | C3 (T a a)
  68                    deriving (Eq)
  69
  70 [NOTE: See end of these comments for what to do with
  71         data (C a, D b) => T a b = ...
  72 ]
  73
  74 We want to come up with an instance declaration of the form
  75
  76         instance (Ping a, Pong b, ...) => Eq (T a b) where
  77                 x == y = ...
  78
  79 It is pretty easy, albeit tedious, to fill in the code "...".  The
  80 trick is to figure out what the context for the instance decl is,
  81 namely @Ping@, @Pong@ and friends.
  82
  83 Let's call the context reqd for the T instance of class C at types
  84 (a,b, ...)  C (T a b).  Thus:
  85
  86         Eq (T a b) = (Ping a, Pong b, ...)
  87
  88 Now we can get a (recursive) equation from the @data@ decl:
  89
  90         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
  91                    u Eq (T b a) u Eq Int        -- From C2
  92                    u Eq (T a a)                 -- From C3
  93
  94 Foo and Bar may have explicit instances for @Eq@, in which case we can
  95 just substitute for them.  Alternatively, either or both may have
  96 their @Eq@ instances given by @deriving@ clauses, in which case they
  97 form part of the system of equations.
  98
  99 Now all we need do is simplify and solve the equations, iterating to
 100 find the least fixpoint.  Notice that the order of the arguments can
 101 switch around, as here in the recursive calls to T.
 102
 103 Let's suppose Eq (Foo a) = Eq a, and Eq (Bar b) = Ping b.
 104
 105 We start with:
 106
 107         Eq (T a b) = {}         -- The empty set
 108
 109 Next iteration:
 110         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
 111                    u Eq (T b a) u Eq Int        -- From C2
 112                    u Eq (T a a)                 -- From C3
 113
 114         After simplification:
 115                    = Eq a u Ping b u {} u {} u {}
 116                    = Eq a u Ping b
 117
 118 Next iteration:
 119
 120         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
 121                    u Eq (T b a) u Eq Int        -- From C2
 122                    u Eq (T a a)                 -- From C3
 123
 124         After simplification:
 125                    = Eq a u Ping b
 126                    u (Eq b u Ping a)
 127                    u (Eq a u Ping a)
 128
 129                    = Eq a u Ping b u Eq b u Ping a
 130
 131 The next iteration gives the same result, so this is the fixpoint.  We
 132 need to make a canonical form of the RHS to ensure convergence.  We do
 133 this by simplifying the RHS to a form in which
 134
 135         - the classes constrain only tyvars
 136         - the list is sorted by tyvar (major key) and then class (minor key)
 137         - no duplicates, of course
 138
 139 So, here are the synonyms for the ``equation'' structures:
 140
 141 \begin{code}
 142 type DerivEqn = (Name, Class, TyCon, [TyVar], DerivRhs)
 143                 -- The Name is the name for the DFun we'll build
 144                 -- The tyvars bind all the variables in the RHS
 145
 146 type DerivRhs  = ThetaType
 147 type DerivSoln = DerivRhs
 148 \end{code}
 149
 150
 151 A note about contexts on data decls
 152 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 153 Consider
 154
 155         data (RealFloat a) => Complex a = !a :+ !a deriving( Read )
 156
 157 We will need an instance decl like:
 158
 159         instance (Read a, RealFloat a) => Read (Complex a) where
 160           ...
 161
 162 The RealFloat in the context is because the read method for Complex is bound
 163 to construct a Complex, and doing that requires that the argument type is
 164 in RealFloat.
 165
 166 But this ain't true for Show, Eq, Ord, etc, since they don't construct
 167 a Complex; they only take them apart.
 168
 169 Our approach: identify the offending classes, and add the data type
 170 context to the instance decl.  The "offending classes" are
 171
 172         Read, Enum?
 173
 174
 175 %************************************************************************
 176 %*                                                                      *
 177 \subsection[TcDeriv-driver]{Top-level function for \tr{derivings}}
 178 %*                                                                      *
 179 %************************************************************************
 180
 181 \begin{code}
 182 tcDeriving  :: PersistentRenamerState
 183             -> Module                   -- name of module under scrutiny
 184             -> InstEnv                  -- What we already know about instances
 185             -> (Name -> Maybe Fixity)   -- used in deriving Show and Read
 186             -> [RenamedTyClDecl]        -- All type constructors
 187             -> TcM ([InstInfo],         -- The generated "instance decls".
 188                     RenamedHsBinds)     -- Extra generated bindings
 189
 190 tcDeriving prs mod inst_env_in get_fixity tycl_decls
 191   = recoverTc (returnTc ([], EmptyBinds)) $
 192
 193         -- Fish the "deriving"-related information out of the TcEnv
 194         -- and make the necessary "equations".
 195     makeDerivEqns tycl_decls            `thenTc` \ eqns ->
 196     if null eqns then
 197         returnTc ([], EmptyBinds)
 198     else
 199
 200         -- Take the equation list and solve it, to deliver a list of
 201         -- solutions, a.k.a. the contexts for the instance decls
 202         -- required for the corresponding equations.
 203     solveDerivEqns inst_env_in eqns             `thenTc` \ new_dfuns ->
 204
 205         -- Now augment the InstInfos, adding in the rather boring
 206         -- actual-code-to-do-the-methods binds.  We may also need to
 207         -- generate extra not-one-inst-decl-specific binds, notably
 208         -- "con2tag" and/or "tag2con" functions.  We do these
 209         -- separately.
 210
 211     gen_taggery_Names new_dfuns                 `thenTc` \ nm_alist_etc ->
 212
 213     tcGetEnv                                    `thenNF_Tc` \ env ->
 214     getDOptsTc                                  `thenTc` \ dflags ->
 215     let
 216         extra_mbind_list = map gen_tag_n_con_monobind nm_alist_etc
 217         extra_mbinds     = foldr AndMonoBinds EmptyMonoBinds extra_mbind_list
 218         method_binds_s   = map (gen_bind get_fixity) new_dfuns
 219         mbinders         = collectLocatedMonoBinders extra_mbinds
 220
 221         -- Rename to get RenamedBinds.
 222         -- The only tricky bit is that the extra_binds must scope over the
 223         -- method bindings for the instances.
 224         (rn_method_binds_s, rn_extra_binds)
 225                 = renameDerivedCode dflags mod prs (
 226                         bindLocatedLocalsRn (ptext (SLIT("deriving"))) mbinders $ \ _ ->
 227                         rnTopMonoBinds extra_mbinds []          `thenRn` \ (rn_extra_binds, _) ->
 228                         mapRn rn_meths method_binds_s           `thenRn` \ rn_method_binds_s ->
 229                         returnRn (rn_method_binds_s, rn_extra_binds)
 230                   )
 231
 232         new_inst_infos = zipWith gen_inst_info new_dfuns rn_method_binds_s
 233     in
 234
 235     ioToTc (dumpIfSet_dyn dflags Opt_D_dump_deriv "Derived instances"
 236               (ddump_deriving new_inst_infos rn_extra_binds))   `thenTc_`
 237
 238     returnTc (new_inst_infos, rn_extra_binds)
 239   where
 240     ddump_deriving :: [InstInfo] -> RenamedHsBinds -> SDoc
 241     ddump_deriving inst_infos extra_binds
 242       = vcat (map pprInstInfo inst_infos) $$ ppr extra_binds
 243       where
 244
 245         -- Make a Real dfun instead of the dummy one we have so far
 246     gen_inst_info :: DFunId -> RenamedMonoBinds -> InstInfo
 247     gen_inst_info dfun binds
 248       = InstInfo { iDFunId = dfun,
 249                    iBinds = binds, iPrags = [] }
 250
 251     rn_meths meths = rnMethodBinds [] meths `thenRn` \ (meths', _) -> returnRn meths'
 252         -- Ignore the free vars returned
 253 \end{code}
 254
 255
 256 %************************************************************************
 257 %*                                                                      *
 258 \subsection[TcDeriv-eqns]{Forming the equations}
 259 %*                                                                      *
 260 %************************************************************************
 261
 262 @makeDerivEqns@ fishes around to find the info about needed derived
 263 instances.  Complicating factors:
 264 \begin{itemize}
 265 \item
 266 We can only derive @Enum@ if the data type is an enumeration
 267 type (all nullary data constructors).
 268
 269 \item
 270 We can only derive @Ix@ if the data type is an enumeration {\em
 271 or} has just one data constructor (e.g., tuples).
 272 \end{itemize}
 273
 274 [See Appendix~E in the Haskell~1.2 report.] This code here deals w/
 275 all those.
 276
 277 \begin{code}
 278 makeDerivEqns :: [RenamedTyClDecl] -> TcM [DerivEqn]
 279
 280 makeDerivEqns tycl_decls
 281   = mapTc mk_eqn derive_these           `thenTc` \ maybe_eqns ->
 282     returnTc (catMaybes maybe_eqns)
 283   where
 284     ------------------------------------------------------------------
 285     derive_these :: [(Name, Name)]
 286         -- Find the (Class,TyCon) pairs that must be `derived'
 287         -- NB: only source-language decls have deriving, no imported ones do
 288     derive_these = [ (clas,tycon)
 289                    | TyData {tcdName = tycon, tcdDerivs = Just classes} <- tycl_decls,
 290                      clas <- nub classes ]
 291
 292     ------------------------------------------------------------------
 293     mk_eqn :: (Name, Name) -> NF_TcM (Maybe DerivEqn)
 294         -- we swizzle the tyvars and datacons out of the tycon
 295         -- to make the rest of the equation
 296
 297     mk_eqn (clas_name, tycon_name)
 298       = tcLookupClass clas_name                                 `thenNF_Tc` \ clas ->
 299         tcLookupTyCon tycon_name                                `thenNF_Tc` \ tycon ->
 300         let
 301             clas_key  = classKey clas
 302             tyvars    = tyConTyVars tycon
 303             tyvar_tys = mkTyVarTys tyvars
 304             ty        = mkTyConApp tycon tyvar_tys
 305             data_cons = tyConDataCons tycon
 306             locn      = getSrcLoc tycon
 307             constraints = extra_constraints ++ concat (map mk_constraints data_cons)
 308
 309             -- "extra_constraints": see notes above about contexts on data decls
 310             extra_constraints
 311               | offensive_class = tyConTheta tycon
 312               | otherwise       = []
 313
 314             offensive_class = clas_key `elem` needsDataDeclCtxtClassKeys
 315
 316             mk_constraints data_con
 317                = [ mkClassPred clas [arg_ty]
 318                  | arg_ty <- dataConArgTys data_con tyvar_tys,
 319                    not (isUnLiftedType arg_ty)  -- No constraints for unlifted types?
 320                  ]
 321         in
 322         case chk_out clas tycon of
 323            Just err ->  addErrTc err                            `thenNF_Tc_`
 324                         returnNF_Tc Nothing
 325            Nothing  ->  newDFunName clas [ty] locn `thenNF_Tc` \ dfun_name ->
 326                         returnNF_Tc (Just (dfun_name, clas, tycon, tyvars, constraints))
 327
 328
 329
 330     ------------------------------------------------------------------
 331     chk_out :: Class -> TyCon -> Maybe Message
 332     chk_out clas tycon
 333         | clas `hasKey` enumClassKey    && not is_enumeration         = bog_out nullary_why
 334         | clas `hasKey` boundedClassKey && not is_enumeration_or_single = bog_out single_nullary_why
 335         | clas `hasKey` ixClassKey      && not is_enumeration_or_single = bog_out single_nullary_why
 336         | any isExistentialDataCon (tyConDataCons tycon)              = Just (existentialErr clas tycon)
 337         | otherwise                                                   = Nothing
 338         where
 339             is_enumeration = isEnumerationTyCon tycon
 340             is_single_con  = maybeToBool (maybeTyConSingleCon tycon)
 341             is_enumeration_or_single = is_enumeration || is_single_con
 342
 343             single_nullary_why = SLIT("one constructor data type or type with all nullary constructors expected")
 344             nullary_why        = SLIT("data type with all nullary constructors expected")
 345
 346             bog_out why = Just (derivingThingErr clas tycon why)
 347 \end{code}
 348
 349 %************************************************************************
 350 %*                                                                      *
 351 \subsection[TcDeriv-fixpoint]{Finding the fixed point of \tr{deriving} equations}
 352 %*                                                                      *
 353 %************************************************************************
 354
 355 A ``solution'' (to one of the equations) is a list of (k,TyVarTy tv)
 356 terms, which is the final correct RHS for the corresponding original
 357 equation.
 358 \begin{itemize}
 359 \item
 360 Each (k,TyVarTy tv) in a solution constrains only a type
 361 variable, tv.
 362
 363 \item
 364 The (k,TyVarTy tv) pairs in a solution are canonically
 365 ordered by sorting on type varible, tv, (major key) and then class, k,
 366 (minor key)
 367 \end{itemize}
 368
 369 \begin{code}
 370 solveDerivEqns :: InstEnv
 371                -> [DerivEqn]
 372                -> TcM [DFunId]  -- Solns in same order as eqns.
 373                                 -- This bunch is Absolutely minimal...
 374
 375 solveDerivEqns inst_env_in orig_eqns
 376   = iterateDeriv initial_solutions
 377   where
 378         -- The initial solutions for the equations claim that each
 379         -- instance has an empty context; this solution is certainly
 380         -- in canonical form.
 381     initial_solutions :: [DerivSoln]
 382     initial_solutions = [ [] | _ <- orig_eqns ]
 383
 384     ------------------------------------------------------------------
 385         -- iterateDeriv calculates the next batch of solutions,
 386         -- compares it with the current one; finishes if they are the
 387         -- same, otherwise recurses with the new solutions.
 388         -- It fails if any iteration fails
 389     iterateDeriv :: [DerivSoln] ->TcM [DFunId]
 390     iterateDeriv current_solns
 391       = checkNoErrsTc (iterateOnce current_solns)
 392                                                 `thenTc` \ (new_dfuns, new_solns) ->
 393         if (current_solns == new_solns) then
 394             returnTc new_dfuns
 395         else
 396             iterateDeriv new_solns
 397
 398     ------------------------------------------------------------------
 399     iterateOnce current_solns
 400       =     -- Extend the inst info from the explicit instance decls
 401             -- with the current set of solutions, giving a
 402         getDOptsTc                              `thenTc` \ dflags ->
 403         let (new_dfuns, inst_env) =
 404                 add_solns dflags inst_env_in orig_eqns current_solns
 405         in
 406             -- Simplify each RHS
 407         tcSetInstEnv inst_env (
 408           listTc [ tcAddErrCtxt (derivCtxt tc) $
 409                    tcSimplifyThetas deriv_rhs
 410                  | (_, _,tc,_,deriv_rhs) <- orig_eqns ]
 411         )                                       `thenTc` \ next_solns ->
 412
 413             -- Canonicalise the solutions, so they compare nicely
 414         let canonicalised_next_solns = [ sortLt (<) next_soln | next_soln <- next_solns ]
 415         in
 416         returnTc (new_dfuns, canonicalised_next_solns)
 417 \end{code}
 418
 419 \begin{code}
 420 add_solns :: DynFlags
 421           -> InstEnv                            -- The global, non-derived ones
 422           -> [DerivEqn] -> [DerivSoln]
 423           -> ([DFunId], InstEnv)
 424     -- the eqns and solns move "in lockstep"; we have the eqns
 425     -- because we need the LHS info for addClassInstance.
 426
 427 add_solns dflags inst_env_in eqns solns
 428   = (new_dfuns, inst_env)
 429     where
 430       new_dfuns     = zipWithEqual "add_solns" mk_deriv_dfun eqns solns
 431       (inst_env, _) = extendInstEnv dflags inst_env_in new_dfuns
 432         -- Ignore the errors about duplicate instances.
 433         -- We don't want repeated error messages
 434         -- They'll appear later, when we do the top-level extendInstEnvs
 435
 436       mk_deriv_dfun (dfun_name, clas, tycon, tyvars, _) theta
 437         = mkDictFunId dfun_name clas tyvars
 438                       [mkTyConApp tycon (mkTyVarTys tyvars)]
 439                       theta
 440 \end{code}
 441
 442 %************************************************************************
 443 %*                                                                      *
 444 \subsection[TcDeriv-normal-binds]{Bindings for the various classes}
 445 %*                                                                      *
 446 %************************************************************************
 447
 448 After all the trouble to figure out the required context for the
 449 derived instance declarations, all that's left is to chug along to
 450 produce them.  They will then be shoved into @tcInstDecls2@, which
 451 will do all its usual business.
 452
 453 There are lots of possibilities for code to generate.  Here are
 454 various general remarks.
 455
 456 PRINCIPLES:
 457 \begin{itemize}
 458 \item
 459 We want derived instances of @Eq@ and @Ord@ (both v common) to be
 460 ``you-couldn't-do-better-by-hand'' efficient.
 461
 462 \item
 463 Deriving @Show@---also pretty common--- should also be reasonable good code.
 464
 465 \item
 466 Deriving for the other classes isn't that common or that big a deal.
 467 \end{itemize}
 468
 469 PRAGMATICS:
 470
 471 \begin{itemize}
 472 \item
 473 Deriving @Ord@ is done mostly with the 1.3 @compare@ method.
 474
 475 \item
 476 Deriving @Eq@ also uses @compare@, if we're deriving @Ord@, too.
 477
 478 \item
 479 We {\em normally} generate code only for the non-defaulted methods;
 480 there are some exceptions for @Eq@ and (especially) @Ord@...
 481
 482 \item
 483 Sometimes we use a @_con2tag_<tycon>@ function, which returns a data
 484 constructor's numeric (@Int#@) tag.  These are generated by
 485 @gen_tag_n_con_binds@, and the heuristic for deciding if one of
 486 these is around is given by @hasCon2TagFun@.
 487
 488 The examples under the different sections below will make this
 489 clearer.
 490
 491 \item
 492 Much less often (really just for deriving @Ix@), we use a
 493 @_tag2con_<tycon>@ function.  See the examples.
 494
 495 \item
 496 We use the renamer!!!  Reason: we're supposed to be
 497 producing @RenamedMonoBinds@ for the methods, but that means
 498 producing correctly-uniquified code on the fly.  This is entirely
 499 possible (the @TcM@ monad has a @UniqueSupply@), but it is painful.
 500 So, instead, we produce @RdrNameMonoBinds@ then heave 'em through
 501 the renamer.  What a great hack!
 502 \end{itemize}
 503
 504 \begin{code}
 505 -- Generate the method bindings for the required instance
 506 -- (paired with class name, as we need that when generating dict
 507 --  names.)
 508 gen_bind :: (Name -> Maybe Fixity) -> DFunId -> RdrNameMonoBinds
 509 gen_bind get_fixity dfun
 510   | clas `hasKey` showClassKey   = gen_Show_binds get_fixity tycon
 511   | clas `hasKey` readClassKey   = gen_Read_binds get_fixity tycon
 512   | otherwise
 513   = assoc "gen_bind:bad derived class"
 514            [(eqClassKey,      gen_Eq_binds)
 515            ,(ordClassKey,     gen_Ord_binds)
 516            ,(enumClassKey,    gen_Enum_binds)
 517            ,(boundedClassKey, gen_Bounded_binds)
 518            ,(ixClassKey,      gen_Ix_binds)
 519            ]
 520            (classKey clas)
 521            tycon
 522   where
 523     (clas, tycon) = simpleDFunClassTyCon dfun
 524 \end{code}
 525
 526
 527 %************************************************************************
 528 %*                                                                      *
 529 \subsection[TcDeriv-taggery-Names]{What con2tag/tag2con functions are available?}
 530 %*                                                                      *
 531 %************************************************************************
 532
 533
 534 data Foo ... = ...
 535
 536 con2tag_Foo :: Foo ... -> Int#
 537 tag2con_Foo :: Int -> Foo ...   -- easier if Int, not Int#
 538 maxtag_Foo  :: Int              -- ditto (NB: not unlifted)
 539
 540
 541 We have a @con2tag@ function for a tycon if:
 542 \begin{itemize}
 543 \item
 544 We're deriving @Eq@ and the tycon has nullary data constructors.
 545
 546 \item
 547 Or: we're deriving @Ord@ (unless single-constructor), @Enum@, @Ix@
 548 (enum type only????)
 549 \end{itemize}
 550
 551 We have a @tag2con@ function for a tycon if:
 552 \begin{itemize}
 553 \item
 554 We're deriving @Enum@, or @Ix@ (enum type only???)
 555 \end{itemize}
 556
 557 If we have a @tag2con@ function, we also generate a @maxtag@ constant.
 558
 559 \begin{code}
 560 gen_taggery_Names :: [DFunId]
 561                   -> TcM [(RdrName,     -- for an assoc list
 562                            TyCon,       -- related tycon
 563                            TagThingWanted)]
 564
 565 gen_taggery_Names dfuns
 566   = foldlTc do_con2tag []           tycons_of_interest `thenTc` \ names_so_far ->
 567     foldlTc do_tag2con names_so_far tycons_of_interest
 568   where
 569     all_CTs = map simpleDFunClassTyCon dfuns
 570     all_tycons              = map snd all_CTs
 571     (tycons_of_interest, _) = removeDups compare all_tycons
 572
 573     do_con2tag acc_Names tycon
 574       | isDataTyCon tycon &&
 575         ((we_are_deriving eqClassKey tycon
 576             && any isNullaryDataCon (tyConDataCons tycon))
 577          || (we_are_deriving ordClassKey  tycon
 578             && not (maybeToBool (maybeTyConSingleCon tycon)))
 579          || (we_are_deriving enumClassKey tycon)
 580          || (we_are_deriving ixClassKey   tycon))
 581
 582       = returnTc ((con2tag_RDR tycon, tycon, GenCon2Tag)
 583                    : acc_Names)
 584       | otherwise
 585       = returnTc acc_Names
 586
 587     do_tag2con acc_Names tycon
 588       | isDataTyCon tycon &&
 589          (we_are_deriving enumClassKey tycon ||
 590           we_are_deriving ixClassKey   tycon
 591           && isEnumerationTyCon tycon)
 592       = returnTc ( (tag2con_RDR tycon, tycon, GenTag2Con)
 593                  : (maxtag_RDR  tycon, tycon, GenMaxTag)
 594                  : acc_Names)
 595       | otherwise
 596       = returnTc acc_Names
 597
 598     we_are_deriving clas_key tycon
 599       = is_in_eqns clas_key tycon all_CTs
 600       where
 601         is_in_eqns clas_key tycon [] = False
 602         is_in_eqns clas_key tycon ((c,t):cts)
 603           =  (clas_key == classKey c && tycon == t)
 604           || is_in_eqns clas_key tycon cts
 605 \end{code}
 606
 607 \begin{code}
 608 derivingThingErr :: Class -> TyCon -> FAST_STRING -> Message
 609
 610 derivingThingErr clas tycon why
 611   = sep [hsep [ptext SLIT("Can't make a derived instance of"), quotes (ppr clas)],
 612          hsep [ptext SLIT("for the type"), quotes (ppr tycon)],
 613          parens (ptext why)]
 614
 615 existentialErr clas tycon
 616   = sep [ptext SLIT("Can't derive any instances for type") <+> quotes (ppr tycon),
 617          ptext SLIT("because it has existentially-quantified constructor(s)")]
 618
 619 derivCtxt tycon
 620   = ptext SLIT("When deriving classes for") <+> quotes (ppr tycon)
 621 \end{code}