ghc/compiler/typecheck/TcDeriv.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcDeriv]{Deriving}
   5
   6 Handles @deriving@ clauses on @data@ declarations.
   7
   8 \begin{code}
   9 module TcDeriv ( tcDeriving ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn            ( HsBinds(..), MonoBinds(..), collectMonoBinders )
  14 import RdrHsSyn         ( RdrNameMonoBinds )
  15 import RnHsSyn          ( RenamedHsBinds, RenamedMonoBinds )
  16 import CmdLineOpts      ( opt_D_dump_deriv )
  17
  18 import TcMonad
  19 import Inst             ( InstanceMapper )
  20 import TcEnv            ( getEnvTyCons )
  21 import TcGenDeriv       -- Deriv stuff
  22 import TcInstUtil       ( InstInfo(..), buildInstanceEnvs )
  23 import TcSimplify       ( tcSimplifyThetas )
  24
  25 import RnBinds          ( rnMethodBinds, rnTopMonoBinds )
  26 import RnEnv            ( newDFunName, bindLocatedLocalsRn )
  27 import RnMonad          ( RnNameSupply,
  28                           renameSourceCode, thenRn, mapRn, returnRn )
  29
  30 import Bag              ( Bag, emptyBag, unionBags, listToBag )
  31 import Class            ( classKey, Class )
  32 import ErrUtils         ( dumpIfSet, Message, pprBagOfErrors )
  33 import MkId             ( mkDictFunId )
  34 import Id               ( mkVanillaId )
  35 import DataCon          ( dataConArgTys, isNullaryDataCon, isExistentialDataCon )
  36 import PrelInfo         ( needsDataDeclCtxtClassKeys )
  37 import Maybes           ( maybeToBool, catMaybes )
  38 import Module           ( ModuleName )
  39 import Name             ( isLocallyDefined, getSrcLoc,
  40                           Name, NamedThing(..),
  41                           OccName, nameOccName
  42                         )
  43 import RdrName          ( RdrName )
  44 import RnMonad          ( FixityEnv )
  45 import SrcLoc           ( mkGeneratedSrcLoc, SrcLoc )
  46 import TyCon            ( tyConTyVars, tyConDataCons, tyConDerivings,
  47                           tyConTheta, maybeTyConSingleCon, isDataTyCon,
  48                           isEnumerationTyCon, isAlgTyCon, TyCon
  49                         )
  50 import Type             ( TauType, mkTyVarTys, mkTyConApp,
  51                           mkSigmaTy, mkDictTy, isUnboxedType,
  52                           splitAlgTyConApp, classesToPreds
  53                         )
  54 import PprType          ( {- instance Outputable Type -} )
  55 import TysWiredIn       ( voidTy )
  56 import Var              ( TyVar )
  57 import Unique           -- Keys stuff
  58 import Bag              ( bagToList )
  59 import Util             ( zipWithEqual, sortLt, removeDups,  assoc, thenCmp )
  60 import Outputable
  61 \end{code}
  62
  63 %************************************************************************
  64 %*                                                                      *
  65 \subsection[TcDeriv-intro]{Introduction to how we do deriving}
  66 %*                                                                      *
  67 %************************************************************************
  68
  69 Consider
  70
  71         data T a b = C1 (Foo a) (Bar b)
  72                    | C2 Int (T b a)
  73                    | C3 (T a a)
  74                    deriving (Eq)
  75
  76 [NOTE: See end of these comments for what to do with
  77         data (C a, D b) => T a b = ...
  78 ]
  79
  80 We want to come up with an instance declaration of the form
  81
  82         instance (Ping a, Pong b, ...) => Eq (T a b) where
  83                 x == y = ...
  84
  85 It is pretty easy, albeit tedious, to fill in the code "...".  The
  86 trick is to figure out what the context for the instance decl is,
  87 namely @Ping@, @Pong@ and friends.
  88
  89 Let's call the context reqd for the T instance of class C at types
  90 (a,b, ...)  C (T a b).  Thus:
  91
  92         Eq (T a b) = (Ping a, Pong b, ...)
  93
  94 Now we can get a (recursive) equation from the @data@ decl:
  95
  96         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
  97                    u Eq (T b a) u Eq Int        -- From C2
  98                    u Eq (T a a)                 -- From C3
  99
 100 Foo and Bar may have explicit instances for @Eq@, in which case we can
 101 just substitute for them.  Alternatively, either or both may have
 102 their @Eq@ instances given by @deriving@ clauses, in which case they
 103 form part of the system of equations.
 104
 105 Now all we need do is simplify and solve the equations, iterating to
 106 find the least fixpoint.  Notice that the order of the arguments can
 107 switch around, as here in the recursive calls to T.
 108
 109 Let's suppose Eq (Foo a) = Eq a, and Eq (Bar b) = Ping b.
 110
 111 We start with:
 112
 113         Eq (T a b) = {}         -- The empty set
 114
 115 Next iteration:
 116         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
 117                    u Eq (T b a) u Eq Int        -- From C2
 118                    u Eq (T a a)                 -- From C3
 119
 120         After simplification:
 121                    = Eq a u Ping b u {} u {} u {}
 122                    = Eq a u Ping b
 123
 124 Next iteration:
 125
 126         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
 127                    u Eq (T b a) u Eq Int        -- From C2
 128                    u Eq (T a a)                 -- From C3
 129
 130         After simplification:
 131                    = Eq a u Ping b
 132                    u (Eq b u Ping a)
 133                    u (Eq a u Ping a)
 134
 135                    = Eq a u Ping b u Eq b u Ping a
 136
 137 The next iteration gives the same result, so this is the fixpoint.  We
 138 need to make a canonical form of the RHS to ensure convergence.  We do
 139 this by simplifying the RHS to a form in which
 140
 141         - the classes constrain only tyvars
 142         - the list is sorted by tyvar (major key) and then class (minor key)
 143         - no duplicates, of course
 144
 145 So, here are the synonyms for the ``equation'' structures:
 146
 147 \begin{code}
 148 type DerivEqn = (Class, TyCon, [TyVar], DerivRhs)
 149                          -- The tyvars bind all the variables in the RHS
 150                          -- NEW: it's convenient to re-use InstInfo
 151                          -- We'll "panic" out some fields...
 152
 153 type DerivRhs = [(Class, [TauType])]    -- Same as a ThetaType!
 154
 155 type DerivSoln = DerivRhs
 156 \end{code}
 157
 158
 159 A note about contexts on data decls
 160 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 161 Consider
 162
 163         data (RealFloat a) => Complex a = !a :+ !a deriving( Read )
 164
 165 We will need an instance decl like:
 166
 167         instance (Read a, RealFloat a) => Read (Complex a) where
 168           ...
 169
 170 The RealFloat in the context is because the read method for Complex is bound
 171 to construct a Complex, and doing that requires that the argument type is
 172 in RealFloat.
 173
 174 But this ain't true for Show, Eq, Ord, etc, since they don't construct
 175 a Complex; they only take them apart.
 176
 177 Our approach: identify the offending classes, and add the data type
 178 context to the instance decl.  The "offending classes" are
 179
 180         Read, Enum?
 181
 182
 183 %************************************************************************
 184 %*                                                                      *
 185 \subsection[TcDeriv-driver]{Top-level function for \tr{derivings}}
 186 %*                                                                      *
 187 %************************************************************************
 188
 189 \begin{code}
 190 tcDeriving  :: ModuleName               -- name of module under scrutiny
 191             -> FixityEnv                -- for the deriving code (Show/Read.)
 192             -> RnNameSupply             -- for "renaming" bits of generated code
 193             -> Bag InstInfo             -- What we already know about instances
 194             -> TcM s (Bag InstInfo,     -- The generated "instance decls".
 195                       RenamedHsBinds)   -- Extra generated bindings
 196
 197 tcDeriving modname fixs rn_name_supply inst_decl_infos_in
 198   = recoverTc (returnTc (emptyBag, EmptyBinds)) $
 199
 200         -- Fish the "deriving"-related information out of the TcEnv
 201         -- and make the necessary "equations".
 202     makeDerivEqns                               `thenTc` \ eqns ->
 203     if null eqns then
 204         returnTc (emptyBag, EmptyBinds)
 205     else
 206
 207         -- Take the equation list and solve it, to deliver a list of
 208         -- solutions, a.k.a. the contexts for the instance decls
 209         -- required for the corresponding equations.
 210     solveDerivEqns inst_decl_infos_in eqns      `thenTc` \ new_inst_infos ->
 211
 212         -- Now augment the InstInfos, adding in the rather boring
 213         -- actual-code-to-do-the-methods binds.  We may also need to
 214         -- generate extra not-one-inst-decl-specific binds, notably
 215         -- "con2tag" and/or "tag2con" functions.  We do these
 216         -- separately.
 217
 218     gen_taggery_Names new_inst_infos            `thenTc` \ nm_alist_etc ->
 219
 220
 221     let
 222         extra_mbind_list = map gen_tag_n_con_monobind nm_alist_etc
 223         extra_mbinds     = foldr AndMonoBinds EmptyMonoBinds extra_mbind_list
 224         method_binds_s   = map (gen_bind fixs) new_inst_infos
 225         mbinders         = bagToList (collectMonoBinders extra_mbinds)
 226
 227         -- Rename to get RenamedBinds.
 228         -- The only tricky bit is that the extra_binds must scope over the
 229         -- method bindings for the instances.
 230         (dfun_names_w_method_binds, rn_extra_binds)
 231                 = renameSourceCode modname rn_name_supply (
 232                         bindLocatedLocalsRn (ptext (SLIT("deriving"))) mbinders $ \ _ ->
 233                         rnTopMonoBinds extra_mbinds []          `thenRn` \ (rn_extra_binds, _) ->
 234                         mapRn rn_one method_binds_s             `thenRn` \ dfun_names_w_method_binds ->
 235                         returnRn (dfun_names_w_method_binds, rn_extra_binds)
 236                   )
 237         rn_one (cl_nm, tycon_nm, meth_binds)
 238                 = newDFunName (cl_nm, tycon_nm)
 239                               mkGeneratedSrcLoc         `thenRn` \ dfun_name ->
 240                   rnMethodBinds meth_binds              `thenRn` \ (rn_meth_binds, _) ->
 241                   returnRn (dfun_name, rn_meth_binds)
 242
 243         really_new_inst_infos = zipWith gen_inst_info
 244                                         new_inst_infos
 245                                         dfun_names_w_method_binds
 246
 247         ddump_deriv = ddump_deriving really_new_inst_infos rn_extra_binds
 248     in
 249     ioToTc (dumpIfSet opt_D_dump_deriv "Derived instances" ddump_deriv) `thenTc_`
 250
 251     returnTc (listToBag really_new_inst_infos, rn_extra_binds)
 252   where
 253     ddump_deriving :: [InstInfo] -> RenamedHsBinds -> SDoc
 254     ddump_deriving inst_infos extra_binds
 255       = vcat (map pp_info inst_infos) $$ ppr extra_binds
 256       where
 257         pp_info (InstInfo clas tvs [ty] inst_decl_theta _ mbinds _ _)
 258           = ppr (mkSigmaTy tvs inst_decl_theta' (mkDictTy clas [ty]))
 259             $$
 260             ppr mbinds
 261             where inst_decl_theta' = classesToPreds inst_decl_theta
 262 \end{code}
 263
 264
 265 %************************************************************************
 266 %*                                                                      *
 267 \subsection[TcDeriv-eqns]{Forming the equations}
 268 %*                                                                      *
 269 %************************************************************************
 270
 271 @makeDerivEqns@ fishes around to find the info about needed derived
 272 instances.  Complicating factors:
 273 \begin{itemize}
 274 \item
 275 We can only derive @Enum@ if the data type is an enumeration
 276 type (all nullary data constructors).
 277
 278 \item
 279 We can only derive @Ix@ if the data type is an enumeration {\em
 280 or} has just one data constructor (e.g., tuples).
 281 \end{itemize}
 282
 283 [See Appendix~E in the Haskell~1.2 report.] This code here deals w/
 284 all those.
 285
 286 \begin{code}
 287 makeDerivEqns :: TcM s [DerivEqn]
 288
 289 makeDerivEqns
 290   = tcGetEnv                        `thenNF_Tc` \ env ->
 291     let
 292         local_data_tycons = filter (\tc -> isLocallyDefined tc && isAlgTyCon tc)
 293                                    (getEnvTyCons env)
 294
 295         think_about_deriving = need_deriving local_data_tycons
 296         (derive_these, _)    = removeDups cmp_deriv think_about_deriving
 297         eqns                 = map mk_eqn derive_these
 298     in
 299     if null local_data_tycons then
 300         returnTc []     -- Bale out now
 301     else
 302     mapTc mk_eqn derive_these `thenTc`  \ maybe_eqns ->
 303     returnTc (catMaybes maybe_eqns)
 304   where
 305     ------------------------------------------------------------------
 306     need_deriving :: [TyCon] -> [(Class, TyCon)]
 307         -- find the tycons that have `deriving' clauses;
 308
 309     need_deriving tycons_to_consider
 310       = foldr (\ tycon acc -> [(clas,tycon) | clas <- tyConDerivings tycon] ++ acc)
 311               []
 312               tycons_to_consider
 313
 314     ------------------------------------------------------------------
 315     cmp_deriv :: (Class, TyCon) -> (Class, TyCon) -> Ordering
 316     cmp_deriv (c1, t1) (c2, t2)
 317       = (c1 `compare` c2) `thenCmp` (t1 `compare` t2)
 318
 319     ------------------------------------------------------------------
 320     mk_eqn :: (Class, TyCon) -> NF_TcM s (Maybe DerivEqn)
 321         -- we swizzle the tyvars and datacons out of the tycon
 322         -- to make the rest of the equation
 323
 324     mk_eqn (clas, tycon)
 325       = case chk_out clas tycon of
 326            Just err ->  addErrTc err    `thenNF_Tc_`
 327                         returnNF_Tc Nothing
 328            Nothing  ->  returnNF_Tc (Just (clas, tycon, tyvars, constraints))
 329       where
 330         clas_key  = classKey clas
 331         tyvars    = tyConTyVars tycon   -- ToDo: Do we need new tyvars ???
 332         tyvar_tys = mkTyVarTys tyvars
 333         data_cons = tyConDataCons tycon
 334
 335         constraints = extra_constraints ++ concat (map mk_constraints data_cons)
 336
 337         -- "extra_constraints": see notes above about contexts on data decls
 338         extra_constraints
 339           | offensive_class = tyConTheta tycon
 340           | otherwise       = []
 341            where
 342             offensive_class = clas_key `elem` needsDataDeclCtxtClassKeys
 343
 344         mk_constraints data_con
 345            = [ (clas, [arg_ty])
 346              | arg_ty <- instd_arg_tys,
 347                not (isUnboxedType arg_ty)       -- No constraints for unboxed types?
 348              ]
 349            where
 350              instd_arg_tys  = dataConArgTys data_con tyvar_tys
 351
 352     ------------------------------------------------------------------
 353     chk_out :: Class -> TyCon -> Maybe Message
 354     chk_out clas tycon
 355         | clas `hasKey` enumClassKey    && not is_enumeration         = bog_out nullary_why
 356         | clas `hasKey` boundedClassKey && not is_enumeration_or_single = bog_out single_nullary_why
 357         | clas `hasKey` ixClassKey      && not is_enumeration_or_single = bog_out single_nullary_why
 358         | any isExistentialDataCon (tyConDataCons tycon)              = Just (existentialErr clas tycon)
 359         | otherwise                                                   = Nothing
 360         where
 361             is_enumeration = isEnumerationTyCon tycon
 362             is_single_con  = maybeToBool (maybeTyConSingleCon tycon)
 363             is_enumeration_or_single = is_enumeration || is_single_con
 364
 365             single_nullary_why = SLIT("one constructor data type or type with all nullary constructors expected")
 366             nullary_why        = SLIT("data type with all nullary constructors expected")
 367
 368             bog_out why = Just (derivingThingErr clas tycon why)
 369 \end{code}
 370
 371 %************************************************************************
 372 %*                                                                      *
 373 \subsection[TcDeriv-fixpoint]{Finding the fixed point of \tr{deriving} equations}
 374 %*                                                                      *
 375 %************************************************************************
 376
 377 A ``solution'' (to one of the equations) is a list of (k,TyVarTy tv)
 378 terms, which is the final correct RHS for the corresponding original
 379 equation.
 380 \begin{itemize}
 381 \item
 382 Each (k,TyVarTy tv) in a solution constrains only a type
 383 variable, tv.
 384
 385 \item
 386 The (k,TyVarTy tv) pairs in a solution are canonically
 387 ordered by sorting on type varible, tv, (major key) and then class, k,
 388 (minor key)
 389 \end{itemize}
 390
 391 \begin{code}
 392 solveDerivEqns :: Bag InstInfo
 393                -> [DerivEqn]
 394                -> TcM s [InstInfo]      -- Solns in same order as eqns.
 395                                         -- This bunch is Absolutely minimal...
 396
 397 solveDerivEqns inst_decl_infos_in orig_eqns
 398   = iterateDeriv initial_solutions
 399   where
 400         -- The initial solutions for the equations claim that each
 401         -- instance has an empty context; this solution is certainly
 402         -- in canonical form.
 403     initial_solutions :: [DerivSoln]
 404     initial_solutions = [ [] | _ <- orig_eqns ]
 405
 406     ------------------------------------------------------------------
 407         -- iterateDeriv calculates the next batch of solutions,
 408         -- compares it with the current one; finishes if they are the
 409         -- same, otherwise recurses with the new solutions.
 410         -- It fails if any iteration fails
 411     iterateDeriv :: [DerivSoln] ->TcM s [InstInfo]
 412     iterateDeriv current_solns
 413       = checkNoErrsTc (iterateOnce current_solns)       `thenTc` \ (new_inst_infos, new_solns) ->
 414         if (current_solns == new_solns) then
 415             returnTc new_inst_infos
 416         else
 417             iterateDeriv new_solns
 418
 419     ------------------------------------------------------------------
 420     iterateOnce current_solns
 421       =     -- Extend the inst info from the explicit instance decls
 422             -- with the current set of solutions, giving a
 423
 424         add_solns inst_decl_infos_in orig_eqns current_solns
 425                                 `thenNF_Tc` \ (new_inst_infos, inst_mapper) ->
 426         let
 427            class_to_inst_env cls = inst_mapper cls
 428         in
 429             -- Simplify each RHS
 430
 431         listTc [ tcAddErrCtxt (derivCtxt tc) $
 432                  tcSimplifyThetas class_to_inst_env deriv_rhs
 433                | (_,tc,_,deriv_rhs) <- orig_eqns ]  `thenTc` \ next_solns ->
 434
 435             -- Canonicalise the solutions, so they compare nicely
 436         let canonicalised_next_solns
 437               = [ sortLt (<) next_soln | next_soln <- next_solns ]
 438         in
 439         returnTc (new_inst_infos, canonicalised_next_solns)
 440 \end{code}
 441
 442 \begin{code}
 443 add_solns :: Bag InstInfo                       -- The global, non-derived ones
 444           -> [DerivEqn] -> [DerivSoln]
 445           -> NF_TcM s ([InstInfo],              -- The new, derived ones
 446                        InstanceMapper)
 447     -- the eqns and solns move "in lockstep"; we have the eqns
 448     -- because we need the LHS info for addClassInstance.
 449
 450 add_solns inst_infos_in eqns solns
 451
 452   = discardErrsTc (buildInstanceEnvs all_inst_infos)    `thenNF_Tc` \ inst_mapper ->
 453         -- We do the discard-errs so that we don't get repeated error messages
 454         -- about duplicate instances.
 455         -- They'll appear later, when we do the top-level buildInstanceEnvs.
 456
 457     returnNF_Tc (new_inst_infos, inst_mapper)
 458   where
 459     new_inst_infos = zipWithEqual "add_solns" mk_deriv_inst_info eqns solns
 460
 461     all_inst_infos = inst_infos_in `unionBags` listToBag new_inst_infos
 462
 463     mk_deriv_inst_info (clas, tycon, tyvars, _) theta
 464       = InstInfo clas tyvars [mkTyConApp tycon (mkTyVarTys tyvars)]
 465                  theta
 466                  dummy_dfun_id
 467                  (my_panic "binds") (getSrcLoc tycon)
 468                  (my_panic "upragmas")
 469       where
 470         dummy_dfun_id
 471           = mkVanillaId (getName tycon) dummy_dfun_ty
 472                 -- The name is getSrcLoc'd in an error message
 473
 474         theta' = classesToPreds theta
 475         dummy_dfun_ty = mkSigmaTy tyvars theta' voidTy
 476                 -- All we need from the dfun is its "theta" part, used during
 477                 -- equation simplification (tcSimplifyThetas).  The final
 478                 -- dfun_id will have the superclass dictionaries as arguments too,
 479                 -- but that'll be added after the equations are solved.  For now,
 480                 -- it's enough just to make a dummy dfun with the simple theta part.
 481                 --
 482                 -- The part after the theta is dummied here as voidTy; actually it's
 483                 --      (C (T a b)), but it doesn't seem worth constructing it.
 484                 -- We can't leave it as a panic because to get the theta part we
 485                 -- have to run down the type!
 486
 487         my_panic str = panic "add_soln" -- pprPanic ("add_soln:"++str) (hsep [char ':', ppr clas, ppr tycon])
 488 \end{code}
 489
 490 %************************************************************************
 491 %*                                                                      *
 492 \subsection[TcDeriv-normal-binds]{Bindings for the various classes}
 493 %*                                                                      *
 494 %************************************************************************
 495
 496 After all the trouble to figure out the required context for the
 497 derived instance declarations, all that's left is to chug along to
 498 produce them.  They will then be shoved into @tcInstDecls2@, which
 499 will do all its usual business.
 500
 501 There are lots of possibilities for code to generate.  Here are
 502 various general remarks.
 503
 504 PRINCIPLES:
 505 \begin{itemize}
 506 \item
 507 We want derived instances of @Eq@ and @Ord@ (both v common) to be
 508 ``you-couldn't-do-better-by-hand'' efficient.
 509
 510 \item
 511 Deriving @Show@---also pretty common--- should also be reasonable good code.
 512
 513 \item
 514 Deriving for the other classes isn't that common or that big a deal.
 515 \end{itemize}
 516
 517 PRAGMATICS:
 518
 519 \begin{itemize}
 520 \item
 521 Deriving @Ord@ is done mostly with the 1.3 @compare@ method.
 522
 523 \item
 524 Deriving @Eq@ also uses @compare@, if we're deriving @Ord@, too.
 525
 526 \item
 527 We {\em normally} generate code only for the non-defaulted methods;
 528 there are some exceptions for @Eq@ and (especially) @Ord@...
 529
 530 \item
 531 Sometimes we use a @_con2tag_<tycon>@ function, which returns a data
 532 constructor's numeric (@Int#@) tag.  These are generated by
 533 @gen_tag_n_con_binds@, and the heuristic for deciding if one of
 534 these is around is given by @hasCon2TagFun@.
 535
 536 The examples under the different sections below will make this
 537 clearer.
 538
 539 \item
 540 Much less often (really just for deriving @Ix@), we use a
 541 @_tag2con_<tycon>@ function.  See the examples.
 542
 543 \item
 544 We use the renamer!!!  Reason: we're supposed to be
 545 producing @RenamedMonoBinds@ for the methods, but that means
 546 producing correctly-uniquified code on the fly.  This is entirely
 547 possible (the @TcM@ monad has a @UniqueSupply@), but it is painful.
 548 So, instead, we produce @RdrNameMonoBinds@ then heave 'em through
 549 the renamer.  What a great hack!
 550 \end{itemize}
 551
 552 \begin{code}
 553 -- Generate the method bindings for the required instance
 554 -- (paired with class name, as we need that when generating dict
 555 --  names.)
 556 gen_bind :: FixityEnv -> InstInfo -> ({-class-}OccName, {-tyCon-}OccName, RdrNameMonoBinds)
 557 gen_bind fixities (InstInfo clas _ [ty] _ _ _ _ _)
 558   | not from_here
 559   = (clas_nm, tycon_nm, EmptyMonoBinds)
 560   |  clas `hasKey` showClassKey
 561   = (clas_nm, tycon_nm, gen_Show_binds fixities tycon)
 562   |  clas `hasKey` readClassKey
 563   = (clas_nm, tycon_nm, gen_Read_binds fixities tycon)
 564   | otherwise
 565   = (clas_nm, tycon_nm,
 566      assoc "gen_bind:bad derived class"
 567            [(eqClassKey,      gen_Eq_binds)
 568            ,(ordClassKey,     gen_Ord_binds)
 569            ,(enumClassKey,    gen_Enum_binds)
 570            ,(boundedClassKey, gen_Bounded_binds)
 571            ,(ixClassKey,      gen_Ix_binds)
 572            ]
 573            (classKey clas)
 574            tycon)
 575   where
 576       clas_nm     = nameOccName (getName clas)
 577       tycon_nm    = nameOccName (getName tycon)
 578       from_here   = isLocallyDefined tycon
 579       (tycon,_,_) = splitAlgTyConApp ty
 580
 581 gen_inst_info :: InstInfo
 582               -> (Name, RenamedMonoBinds)
 583               -> InstInfo                               -- the gen'd (filled-in) "instance decl"
 584
 585 gen_inst_info (InstInfo clas tyvars tys@(ty:_) inst_decl_theta _ _ locn _)
 586               (dfun_name, meth_binds)
 587   =
 588         -- Generate the various instance-related Ids
 589     InstInfo clas tyvars tys inst_decl_theta
 590                dfun_id
 591                meth_binds
 592                locn []
 593   where
 594    dfun_id = mkDictFunId dfun_name clas tyvars tys inst_decl_theta
 595
 596    from_here = isLocallyDefined tycon
 597    (tycon,_,_) = splitAlgTyConApp ty
 598 \end{code}
 599
 600
 601 %************************************************************************
 602 %*                                                                      *
 603 \subsection[TcDeriv-taggery-Names]{What con2tag/tag2con functions are available?}
 604 %*                                                                      *
 605 %************************************************************************
 606
 607
 608 data Foo ... = ...
 609
 610 con2tag_Foo :: Foo ... -> Int#
 611 tag2con_Foo :: Int -> Foo ...   -- easier if Int, not Int#
 612 maxtag_Foo  :: Int              -- ditto (NB: not unboxed)
 613
 614
 615 We have a @con2tag@ function for a tycon if:
 616 \begin{itemize}
 617 \item
 618 We're deriving @Eq@ and the tycon has nullary data constructors.
 619
 620 \item
 621 Or: we're deriving @Ord@ (unless single-constructor), @Enum@, @Ix@
 622 (enum type only????)
 623 \end{itemize}
 624
 625 We have a @tag2con@ function for a tycon if:
 626 \begin{itemize}
 627 \item
 628 We're deriving @Enum@, or @Ix@ (enum type only???)
 629 \end{itemize}
 630
 631 If we have a @tag2con@ function, we also generate a @maxtag@ constant.
 632
 633 \begin{code}
 634 gen_taggery_Names :: [InstInfo]
 635                   -> TcM s [(RdrName,   -- for an assoc list
 636                              TyCon,     -- related tycon
 637                              TagThingWanted)]
 638
 639 gen_taggery_Names inst_infos
 640   = --pprTrace "gen_taggery:\n" (vcat [hsep [ppr c, ppr t] | (c,t) <- all_CTs]) $
 641     foldlTc do_con2tag []           tycons_of_interest `thenTc` \ names_so_far ->
 642     foldlTc do_tag2con names_so_far tycons_of_interest
 643   where
 644     all_CTs = [ (c, get_tycon ty) | (InstInfo c _ [ty] _ _ _ _ _) <- inst_infos ]
 645
 646     get_tycon ty = case splitAlgTyConApp ty of { (tc, _, _) -> tc }
 647
 648     all_tycons = map snd all_CTs
 649     (tycons_of_interest, _) = removeDups compare all_tycons
 650
 651     do_con2tag acc_Names tycon
 652       | isDataTyCon tycon &&
 653         ((we_are_deriving eqClassKey tycon
 654             && any isNullaryDataCon (tyConDataCons tycon))
 655          || (we_are_deriving ordClassKey  tycon
 656             && not (maybeToBool (maybeTyConSingleCon tycon)))
 657          || (we_are_deriving enumClassKey tycon)
 658          || (we_are_deriving ixClassKey   tycon))
 659
 660       = returnTc ((con2tag_RDR tycon, tycon, GenCon2Tag)
 661                    : acc_Names)
 662       | otherwise
 663       = returnTc acc_Names
 664
 665     do_tag2con acc_Names tycon
 666       | isDataTyCon tycon &&
 667          (we_are_deriving enumClassKey tycon ||
 668           we_are_deriving ixClassKey   tycon
 669           && isEnumerationTyCon tycon)
 670       = returnTc ( (tag2con_RDR tycon, tycon, GenTag2Con)
 671                  : (maxtag_RDR  tycon, tycon, GenMaxTag)
 672                  : acc_Names)
 673       | otherwise
 674       = returnTc acc_Names
 675
 676     we_are_deriving clas_key tycon
 677       = is_in_eqns clas_key tycon all_CTs
 678       where
 679         is_in_eqns clas_key tycon [] = False
 680         is_in_eqns clas_key tycon ((c,t):cts)
 681           =  (clas_key == classKey c && tycon == t)
 682           || is_in_eqns clas_key tycon cts
 683
 684 \end{code}
 685
 686 \begin{code}
 687 derivingThingErr :: Class -> TyCon -> FAST_STRING -> Message
 688
 689 derivingThingErr clas tycon why
 690   = sep [hsep [ptext SLIT("Can't make a derived instance of"), quotes (ppr clas)],
 691          hsep [ptext SLIT("for the type"), quotes (ppr tycon)],
 692          parens (ptext why)]
 693
 694 existentialErr clas tycon
 695   = sep [ptext SLIT("Can't derive any instances for type") <+> quotes (ppr tycon),
 696          ptext SLIT("because it has existentially-quantified constructor(s)")]
 697
 698 derivCtxt tycon
 699   = ptext SLIT("When deriving classes for") <+> quotes (ppr tycon)
 700 \end{code}