ghc/compiler/typecheck/TcDeriv.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcDeriv]{Deriving}
   5
   6 Handles @deriving@ clauses on @data@ declarations.
   7
   8 \begin{code}
   9 module TcDeriv ( tcDeriving ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn            ( HsBinds(..), MonoBinds(..), collectMonoBinders )
  14 import RdrHsSyn         ( RdrNameMonoBinds )
  15 import RnHsSyn          ( RenamedHsBinds, RenamedMonoBinds )
  16 import CmdLineOpts      ( opt_D_dump_deriv )
  17
  18 import TcMonad
  19 import TcEnv            ( InstEnv, getEnvTyCons, tcSetInstEnv )
  20 import TcGenDeriv       -- Deriv stuff
  21 import TcInstUtil       ( InstInfo(..), buildInstanceEnv )
  22 import TcSimplify       ( tcSimplifyThetas )
  23
  24 import RnBinds          ( rnMethodBinds, rnTopMonoBinds )
  25 import RnEnv            ( newDFunName, bindLocatedLocalsRn )
  26 import RnMonad          ( RnNameSupply,
  27                           renameSourceCode, thenRn, mapRn, returnRn )
  28
  29 import Bag              ( Bag, emptyBag, unionBags, listToBag )
  30 import Class            ( classKey, Class )
  31 import ErrUtils         ( dumpIfSet, Message, pprBagOfErrors )
  32 import MkId             ( mkDictFunId )
  33 import Id               ( mkVanillaId )
  34 import DataCon          ( dataConArgTys, isNullaryDataCon, isExistentialDataCon )
  35 import PrelInfo         ( needsDataDeclCtxtClassKeys )
  36 import Maybes           ( maybeToBool, catMaybes )
  37 import Module           ( ModuleName )
  38 import Name             ( isLocallyDefined, getSrcLoc,
  39                           Name, NamedThing(..),
  40                           OccName, nameOccName
  41                         )
  42 import RdrName          ( RdrName )
  43 import RnMonad          ( FixityEnv )
  44 import SrcLoc           ( mkGeneratedSrcLoc, SrcLoc )
  45 import TyCon            ( tyConTyVars, tyConDataCons, tyConDerivings,
  46                           tyConTheta, maybeTyConSingleCon, isDataTyCon,
  47                           isEnumerationTyCon, isAlgTyCon, TyCon
  48                         )
  49 import Type             ( TauType, mkTyVarTys, mkTyConApp,
  50                           mkSigmaTy, mkDictTy, isUnboxedType,
  51                           splitAlgTyConApp, classesToPreds
  52                         )
  53 import PprType          ( {- instance Outputable Type -} )
  54 import TysWiredIn       ( voidTy )
  55 import Var              ( TyVar )
  56 import Unique           -- Keys stuff
  57 import Bag              ( bagToList )
  58 import Util             ( zipWithEqual, sortLt, removeDups,  assoc, thenCmp )
  59 import Outputable
  60 \end{code}
  61
  62 %************************************************************************
  63 %*                                                                      *
  64 \subsection[TcDeriv-intro]{Introduction to how we do deriving}
  65 %*                                                                      *
  66 %************************************************************************
  67
  68 Consider
  69
  70         data T a b = C1 (Foo a) (Bar b)
  71                    | C2 Int (T b a)
  72                    | C3 (T a a)
  73                    deriving (Eq)
  74
  75 [NOTE: See end of these comments for what to do with
  76         data (C a, D b) => T a b = ...
  77 ]
  78
  79 We want to come up with an instance declaration of the form
  80
  81         instance (Ping a, Pong b, ...) => Eq (T a b) where
  82                 x == y = ...
  83
  84 It is pretty easy, albeit tedious, to fill in the code "...".  The
  85 trick is to figure out what the context for the instance decl is,
  86 namely @Ping@, @Pong@ and friends.
  87
  88 Let's call the context reqd for the T instance of class C at types
  89 (a,b, ...)  C (T a b).  Thus:
  90
  91         Eq (T a b) = (Ping a, Pong b, ...)
  92
  93 Now we can get a (recursive) equation from the @data@ decl:
  94
  95         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
  96                    u Eq (T b a) u Eq Int        -- From C2
  97                    u Eq (T a a)                 -- From C3
  98
  99 Foo and Bar may have explicit instances for @Eq@, in which case we can
 100 just substitute for them.  Alternatively, either or both may have
 101 their @Eq@ instances given by @deriving@ clauses, in which case they
 102 form part of the system of equations.
 103
 104 Now all we need do is simplify and solve the equations, iterating to
 105 find the least fixpoint.  Notice that the order of the arguments can
 106 switch around, as here in the recursive calls to T.
 107
 108 Let's suppose Eq (Foo a) = Eq a, and Eq (Bar b) = Ping b.
 109
 110 We start with:
 111
 112         Eq (T a b) = {}         -- The empty set
 113
 114 Next iteration:
 115         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
 116                    u Eq (T b a) u Eq Int        -- From C2
 117                    u Eq (T a a)                 -- From C3
 118
 119         After simplification:
 120                    = Eq a u Ping b u {} u {} u {}
 121                    = Eq a u Ping b
 122
 123 Next iteration:
 124
 125         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
 126                    u Eq (T b a) u Eq Int        -- From C2
 127                    u Eq (T a a)                 -- From C3
 128
 129         After simplification:
 130                    = Eq a u Ping b
 131                    u (Eq b u Ping a)
 132                    u (Eq a u Ping a)
 133
 134                    = Eq a u Ping b u Eq b u Ping a
 135
 136 The next iteration gives the same result, so this is the fixpoint.  We
 137 need to make a canonical form of the RHS to ensure convergence.  We do
 138 this by simplifying the RHS to a form in which
 139
 140         - the classes constrain only tyvars
 141         - the list is sorted by tyvar (major key) and then class (minor key)
 142         - no duplicates, of course
 143
 144 So, here are the synonyms for the ``equation'' structures:
 145
 146 \begin{code}
 147 type DerivEqn = (Class, TyCon, [TyVar], DerivRhs)
 148                          -- The tyvars bind all the variables in the RHS
 149                          -- NEW: it's convenient to re-use InstInfo
 150                          -- We'll "panic" out some fields...
 151
 152 type DerivRhs = [(Class, [TauType])]    -- Same as a ThetaType!
 153
 154 type DerivSoln = DerivRhs
 155 \end{code}
 156
 157
 158 A note about contexts on data decls
 159 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 160 Consider
 161
 162         data (RealFloat a) => Complex a = !a :+ !a deriving( Read )
 163
 164 We will need an instance decl like:
 165
 166         instance (Read a, RealFloat a) => Read (Complex a) where
 167           ...
 168
 169 The RealFloat in the context is because the read method for Complex is bound
 170 to construct a Complex, and doing that requires that the argument type is
 171 in RealFloat.
 172
 173 But this ain't true for Show, Eq, Ord, etc, since they don't construct
 174 a Complex; they only take them apart.
 175
 176 Our approach: identify the offending classes, and add the data type
 177 context to the instance decl.  The "offending classes" are
 178
 179         Read, Enum?
 180
 181
 182 %************************************************************************
 183 %*                                                                      *
 184 \subsection[TcDeriv-driver]{Top-level function for \tr{derivings}}
 185 %*                                                                      *
 186 %************************************************************************
 187
 188 \begin{code}
 189 tcDeriving  :: ModuleName               -- name of module under scrutiny
 190             -> FixityEnv                -- for the deriving code (Show/Read.)
 191             -> RnNameSupply             -- for "renaming" bits of generated code
 192             -> Bag InstInfo             -- What we already know about instances
 193             -> TcM s (Bag InstInfo,     -- The generated "instance decls".
 194                       RenamedHsBinds)   -- Extra generated bindings
 195
 196 tcDeriving modname fixs rn_name_supply inst_decl_infos_in
 197   = recoverTc (returnTc (emptyBag, EmptyBinds)) $
 198
 199         -- Fish the "deriving"-related information out of the TcEnv
 200         -- and make the necessary "equations".
 201     makeDerivEqns                               `thenTc` \ eqns ->
 202     if null eqns then
 203         returnTc (emptyBag, EmptyBinds)
 204     else
 205
 206         -- Take the equation list and solve it, to deliver a list of
 207         -- solutions, a.k.a. the contexts for the instance decls
 208         -- required for the corresponding equations.
 209     solveDerivEqns inst_decl_infos_in eqns      `thenTc` \ new_inst_infos ->
 210
 211         -- Now augment the InstInfos, adding in the rather boring
 212         -- actual-code-to-do-the-methods binds.  We may also need to
 213         -- generate extra not-one-inst-decl-specific binds, notably
 214         -- "con2tag" and/or "tag2con" functions.  We do these
 215         -- separately.
 216
 217     gen_taggery_Names new_inst_infos            `thenTc` \ nm_alist_etc ->
 218
 219
 220     let
 221         extra_mbind_list = map gen_tag_n_con_monobind nm_alist_etc
 222         extra_mbinds     = foldr AndMonoBinds EmptyMonoBinds extra_mbind_list
 223         method_binds_s   = map (gen_bind fixs) new_inst_infos
 224         mbinders         = bagToList (collectMonoBinders extra_mbinds)
 225
 226         -- Rename to get RenamedBinds.
 227         -- The only tricky bit is that the extra_binds must scope over the
 228         -- method bindings for the instances.
 229         (dfun_names_w_method_binds, rn_extra_binds)
 230                 = renameSourceCode modname rn_name_supply (
 231                         bindLocatedLocalsRn (ptext (SLIT("deriving"))) mbinders $ \ _ ->
 232                         rnTopMonoBinds extra_mbinds []          `thenRn` \ (rn_extra_binds, _) ->
 233                         mapRn rn_one method_binds_s             `thenRn` \ dfun_names_w_method_binds ->
 234                         returnRn (dfun_names_w_method_binds, rn_extra_binds)
 235                   )
 236         rn_one (cl_nm, tycon_nm, meth_binds)
 237                 = newDFunName (cl_nm, tycon_nm)
 238                               mkGeneratedSrcLoc         `thenRn` \ dfun_name ->
 239                   rnMethodBinds meth_binds              `thenRn` \ (rn_meth_binds, _) ->
 240                   returnRn (dfun_name, rn_meth_binds)
 241
 242         really_new_inst_infos = zipWith gen_inst_info
 243                                         new_inst_infos
 244                                         dfun_names_w_method_binds
 245
 246         ddump_deriv = ddump_deriving really_new_inst_infos rn_extra_binds
 247     in
 248     ioToTc (dumpIfSet opt_D_dump_deriv "Derived instances" ddump_deriv) `thenTc_`
 249
 250     returnTc (listToBag really_new_inst_infos, rn_extra_binds)
 251   where
 252     ddump_deriving :: [InstInfo] -> RenamedHsBinds -> SDoc
 253     ddump_deriving inst_infos extra_binds
 254       = vcat (map pp_info inst_infos) $$ ppr extra_binds
 255       where
 256         pp_info (InstInfo clas tvs [ty] inst_decl_theta _ mbinds _ _)
 257           = ppr (mkSigmaTy tvs inst_decl_theta' (mkDictTy clas [ty]))
 258             $$
 259             ppr mbinds
 260             where inst_decl_theta' = classesToPreds inst_decl_theta
 261 \end{code}
 262
 263
 264 %************************************************************************
 265 %*                                                                      *
 266 \subsection[TcDeriv-eqns]{Forming the equations}
 267 %*                                                                      *
 268 %************************************************************************
 269
 270 @makeDerivEqns@ fishes around to find the info about needed derived
 271 instances.  Complicating factors:
 272 \begin{itemize}
 273 \item
 274 We can only derive @Enum@ if the data type is an enumeration
 275 type (all nullary data constructors).
 276
 277 \item
 278 We can only derive @Ix@ if the data type is an enumeration {\em
 279 or} has just one data constructor (e.g., tuples).
 280 \end{itemize}
 281
 282 [See Appendix~E in the Haskell~1.2 report.] This code here deals w/
 283 all those.
 284
 285 \begin{code}
 286 makeDerivEqns :: TcM s [DerivEqn]
 287
 288 makeDerivEqns
 289   = tcGetEnv                        `thenNF_Tc` \ env ->
 290     let
 291         local_data_tycons = filter (\tc -> isLocallyDefined tc && isAlgTyCon tc)
 292                                    (getEnvTyCons env)
 293
 294         think_about_deriving = need_deriving local_data_tycons
 295         (derive_these, _)    = removeDups cmp_deriv think_about_deriving
 296         eqns                 = map mk_eqn derive_these
 297     in
 298     if null local_data_tycons then
 299         returnTc []     -- Bale out now
 300     else
 301     mapTc mk_eqn derive_these `thenTc`  \ maybe_eqns ->
 302     returnTc (catMaybes maybe_eqns)
 303   where
 304     ------------------------------------------------------------------
 305     need_deriving :: [TyCon] -> [(Class, TyCon)]
 306         -- find the tycons that have `deriving' clauses;
 307
 308     need_deriving tycons_to_consider
 309       = foldr (\ tycon acc -> [(clas,tycon) | clas <- tyConDerivings tycon] ++ acc)
 310               []
 311               tycons_to_consider
 312
 313     ------------------------------------------------------------------
 314     cmp_deriv :: (Class, TyCon) -> (Class, TyCon) -> Ordering
 315     cmp_deriv (c1, t1) (c2, t2)
 316       = (c1 `compare` c2) `thenCmp` (t1 `compare` t2)
 317
 318     ------------------------------------------------------------------
 319     mk_eqn :: (Class, TyCon) -> NF_TcM s (Maybe DerivEqn)
 320         -- we swizzle the tyvars and datacons out of the tycon
 321         -- to make the rest of the equation
 322
 323     mk_eqn (clas, tycon)
 324       = case chk_out clas tycon of
 325            Just err ->  addErrTc err    `thenNF_Tc_`
 326                         returnNF_Tc Nothing
 327            Nothing  ->  returnNF_Tc (Just (clas, tycon, tyvars, constraints))
 328       where
 329         clas_key  = classKey clas
 330         tyvars    = tyConTyVars tycon   -- ToDo: Do we need new tyvars ???
 331         tyvar_tys = mkTyVarTys tyvars
 332         data_cons = tyConDataCons tycon
 333
 334         constraints = extra_constraints ++ concat (map mk_constraints data_cons)
 335
 336         -- "extra_constraints": see notes above about contexts on data decls
 337         extra_constraints
 338           | offensive_class = tyConTheta tycon
 339           | otherwise       = []
 340            where
 341             offensive_class = clas_key `elem` needsDataDeclCtxtClassKeys
 342
 343         mk_constraints data_con
 344            = [ (clas, [arg_ty])
 345              | arg_ty <- instd_arg_tys,
 346                not (isUnboxedType arg_ty)       -- No constraints for unboxed types?
 347              ]
 348            where
 349              instd_arg_tys  = dataConArgTys data_con tyvar_tys
 350
 351     ------------------------------------------------------------------
 352     chk_out :: Class -> TyCon -> Maybe Message
 353     chk_out clas tycon
 354         | clas `hasKey` enumClassKey    && not is_enumeration         = bog_out nullary_why
 355         | clas `hasKey` boundedClassKey && not is_enumeration_or_single = bog_out single_nullary_why
 356         | clas `hasKey` ixClassKey      && not is_enumeration_or_single = bog_out single_nullary_why
 357         | any isExistentialDataCon (tyConDataCons tycon)              = Just (existentialErr clas tycon)
 358         | otherwise                                                   = Nothing
 359         where
 360             is_enumeration = isEnumerationTyCon tycon
 361             is_single_con  = maybeToBool (maybeTyConSingleCon tycon)
 362             is_enumeration_or_single = is_enumeration || is_single_con
 363
 364             single_nullary_why = SLIT("one constructor data type or type with all nullary constructors expected")
 365             nullary_why        = SLIT("data type with all nullary constructors expected")
 366
 367             bog_out why = Just (derivingThingErr clas tycon why)
 368 \end{code}
 369
 370 %************************************************************************
 371 %*                                                                      *
 372 \subsection[TcDeriv-fixpoint]{Finding the fixed point of \tr{deriving} equations}
 373 %*                                                                      *
 374 %************************************************************************
 375
 376 A ``solution'' (to one of the equations) is a list of (k,TyVarTy tv)
 377 terms, which is the final correct RHS for the corresponding original
 378 equation.
 379 \begin{itemize}
 380 \item
 381 Each (k,TyVarTy tv) in a solution constrains only a type
 382 variable, tv.
 383
 384 \item
 385 The (k,TyVarTy tv) pairs in a solution are canonically
 386 ordered by sorting on type varible, tv, (major key) and then class, k,
 387 (minor key)
 388 \end{itemize}
 389
 390 \begin{code}
 391 solveDerivEqns :: Bag InstInfo
 392                -> [DerivEqn]
 393                -> TcM s [InstInfo]      -- Solns in same order as eqns.
 394                                         -- This bunch is Absolutely minimal...
 395
 396 solveDerivEqns inst_decl_infos_in orig_eqns
 397   = iterateDeriv initial_solutions
 398   where
 399         -- The initial solutions for the equations claim that each
 400         -- instance has an empty context; this solution is certainly
 401         -- in canonical form.
 402     initial_solutions :: [DerivSoln]
 403     initial_solutions = [ [] | _ <- orig_eqns ]
 404
 405     ------------------------------------------------------------------
 406         -- iterateDeriv calculates the next batch of solutions,
 407         -- compares it with the current one; finishes if they are the
 408         -- same, otherwise recurses with the new solutions.
 409         -- It fails if any iteration fails
 410     iterateDeriv :: [DerivSoln] ->TcM s [InstInfo]
 411     iterateDeriv current_solns
 412       = checkNoErrsTc (iterateOnce current_solns)       `thenTc` \ (new_inst_infos, new_solns) ->
 413         if (current_solns == new_solns) then
 414             returnTc new_inst_infos
 415         else
 416             iterateDeriv new_solns
 417
 418     ------------------------------------------------------------------
 419     iterateOnce current_solns
 420       =     -- Extend the inst info from the explicit instance decls
 421             -- with the current set of solutions, giving a
 422
 423         add_solns inst_decl_infos_in orig_eqns current_solns
 424                                 `thenNF_Tc` \ (new_inst_infos, inst_env) ->
 425
 426             -- Simplify each RHS
 427
 428         tcSetInstEnv inst_env (
 429           listTc [ tcAddErrCtxt (derivCtxt tc) $
 430                    tcSimplifyThetas deriv_rhs
 431                  | (_,tc,_,deriv_rhs) <- orig_eqns ]
 432         )                                               `thenTc` \ next_solns ->
 433
 434             -- Canonicalise the solutions, so they compare nicely
 435         let canonicalised_next_solns
 436               = [ sortLt (<) next_soln | next_soln <- next_solns ]
 437         in
 438         returnTc (new_inst_infos, canonicalised_next_solns)
 439 \end{code}
 440
 441 \begin{code}
 442 add_solns :: Bag InstInfo                       -- The global, non-derived ones
 443           -> [DerivEqn] -> [DerivSoln]
 444           -> NF_TcM s ([InstInfo],              -- The new, derived ones
 445                        InstEnv)
 446     -- the eqns and solns move "in lockstep"; we have the eqns
 447     -- because we need the LHS info for addClassInstance.
 448
 449 add_solns inst_infos_in eqns solns
 450
 451   = discardErrsTc (buildInstanceEnv all_inst_infos)     `thenNF_Tc` \ inst_env ->
 452         -- We do the discard-errs so that we don't get repeated error messages
 453         -- about duplicate instances.
 454         -- They'll appear later, when we do the top-level buildInstanceEnv.
 455
 456     returnNF_Tc (new_inst_infos, inst_env)
 457   where
 458     new_inst_infos = zipWithEqual "add_solns" mk_deriv_inst_info eqns solns
 459
 460     all_inst_infos = inst_infos_in `unionBags` listToBag new_inst_infos
 461
 462     mk_deriv_inst_info (clas, tycon, tyvars, _) theta
 463       = InstInfo clas tyvars [mkTyConApp tycon (mkTyVarTys tyvars)]
 464                  theta
 465                  dummy_dfun_id
 466                  (my_panic "binds") (getSrcLoc tycon)
 467                  (my_panic "upragmas")
 468       where
 469         dummy_dfun_id
 470           = mkVanillaId (getName tycon) dummy_dfun_ty
 471                 -- The name is getSrcLoc'd in an error message
 472
 473         theta' = classesToPreds theta
 474         dummy_dfun_ty = mkSigmaTy tyvars theta' voidTy
 475                 -- All we need from the dfun is its "theta" part, used during
 476                 -- equation simplification (tcSimplifyThetas).  The final
 477                 -- dfun_id will have the superclass dictionaries as arguments too,
 478                 -- but that'll be added after the equations are solved.  For now,
 479                 -- it's enough just to make a dummy dfun with the simple theta part.
 480                 --
 481                 -- The part after the theta is dummied here as voidTy; actually it's
 482                 --      (C (T a b)), but it doesn't seem worth constructing it.
 483                 -- We can't leave it as a panic because to get the theta part we
 484                 -- have to run down the type!
 485
 486         my_panic str = panic "add_soln" -- pprPanic ("add_soln:"++str) (hsep [char ':', ppr clas, ppr tycon])
 487 \end{code}
 488
 489 %************************************************************************
 490 %*                                                                      *
 491 \subsection[TcDeriv-normal-binds]{Bindings for the various classes}
 492 %*                                                                      *
 493 %************************************************************************
 494
 495 After all the trouble to figure out the required context for the
 496 derived instance declarations, all that's left is to chug along to
 497 produce them.  They will then be shoved into @tcInstDecls2@, which
 498 will do all its usual business.
 499
 500 There are lots of possibilities for code to generate.  Here are
 501 various general remarks.
 502
 503 PRINCIPLES:
 504 \begin{itemize}
 505 \item
 506 We want derived instances of @Eq@ and @Ord@ (both v common) to be
 507 ``you-couldn't-do-better-by-hand'' efficient.
 508
 509 \item
 510 Deriving @Show@---also pretty common--- should also be reasonable good code.
 511
 512 \item
 513 Deriving for the other classes isn't that common or that big a deal.
 514 \end{itemize}
 515
 516 PRAGMATICS:
 517
 518 \begin{itemize}
 519 \item
 520 Deriving @Ord@ is done mostly with the 1.3 @compare@ method.
 521
 522 \item
 523 Deriving @Eq@ also uses @compare@, if we're deriving @Ord@, too.
 524
 525 \item
 526 We {\em normally} generate code only for the non-defaulted methods;
 527 there are some exceptions for @Eq@ and (especially) @Ord@...
 528
 529 \item
 530 Sometimes we use a @_con2tag_<tycon>@ function, which returns a data
 531 constructor's numeric (@Int#@) tag.  These are generated by
 532 @gen_tag_n_con_binds@, and the heuristic for deciding if one of
 533 these is around is given by @hasCon2TagFun@.
 534
 535 The examples under the different sections below will make this
 536 clearer.
 537
 538 \item
 539 Much less often (really just for deriving @Ix@), we use a
 540 @_tag2con_<tycon>@ function.  See the examples.
 541
 542 \item
 543 We use the renamer!!!  Reason: we're supposed to be
 544 producing @RenamedMonoBinds@ for the methods, but that means
 545 producing correctly-uniquified code on the fly.  This is entirely
 546 possible (the @TcM@ monad has a @UniqueSupply@), but it is painful.
 547 So, instead, we produce @RdrNameMonoBinds@ then heave 'em through
 548 the renamer.  What a great hack!
 549 \end{itemize}
 550
 551 \begin{code}
 552 -- Generate the method bindings for the required instance
 553 -- (paired with class name, as we need that when generating dict
 554 --  names.)
 555 gen_bind :: FixityEnv -> InstInfo -> ({-class-}OccName, {-tyCon-}OccName, RdrNameMonoBinds)
 556 gen_bind fixities (InstInfo clas _ [ty] _ _ _ _ _)
 557   | not from_here
 558   = (clas_nm, tycon_nm, EmptyMonoBinds)
 559   |  clas `hasKey` showClassKey
 560   = (clas_nm, tycon_nm, gen_Show_binds fixities tycon)
 561   |  clas `hasKey` readClassKey
 562   = (clas_nm, tycon_nm, gen_Read_binds fixities tycon)
 563   | otherwise
 564   = (clas_nm, tycon_nm,
 565      assoc "gen_bind:bad derived class"
 566            [(eqClassKey,      gen_Eq_binds)
 567            ,(ordClassKey,     gen_Ord_binds)
 568            ,(enumClassKey,    gen_Enum_binds)
 569            ,(boundedClassKey, gen_Bounded_binds)
 570            ,(ixClassKey,      gen_Ix_binds)
 571            ]
 572            (classKey clas)
 573            tycon)
 574   where
 575       clas_nm     = nameOccName (getName clas)
 576       tycon_nm    = nameOccName (getName tycon)
 577       from_here   = isLocallyDefined tycon
 578       (tycon,_,_) = splitAlgTyConApp ty
 579
 580 gen_inst_info :: InstInfo
 581               -> (Name, RenamedMonoBinds)
 582               -> InstInfo                               -- the gen'd (filled-in) "instance decl"
 583
 584 gen_inst_info (InstInfo clas tyvars tys@(ty:_) inst_decl_theta _ _ locn _)
 585               (dfun_name, meth_binds)
 586   =
 587         -- Generate the various instance-related Ids
 588     InstInfo clas tyvars tys inst_decl_theta
 589                dfun_id
 590                meth_binds
 591                locn []
 592   where
 593    dfun_id = mkDictFunId dfun_name clas tyvars tys inst_decl_theta
 594
 595    from_here = isLocallyDefined tycon
 596    (tycon,_,_) = splitAlgTyConApp ty
 597 \end{code}
 598
 599
 600 %************************************************************************
 601 %*                                                                      *
 602 \subsection[TcDeriv-taggery-Names]{What con2tag/tag2con functions are available?}
 603 %*                                                                      *
 604 %************************************************************************
 605
 606
 607 data Foo ... = ...
 608
 609 con2tag_Foo :: Foo ... -> Int#
 610 tag2con_Foo :: Int -> Foo ...   -- easier if Int, not Int#
 611 maxtag_Foo  :: Int              -- ditto (NB: not unboxed)
 612
 613
 614 We have a @con2tag@ function for a tycon if:
 615 \begin{itemize}
 616 \item
 617 We're deriving @Eq@ and the tycon has nullary data constructors.
 618
 619 \item
 620 Or: we're deriving @Ord@ (unless single-constructor), @Enum@, @Ix@
 621 (enum type only????)
 622 \end{itemize}
 623
 624 We have a @tag2con@ function for a tycon if:
 625 \begin{itemize}
 626 \item
 627 We're deriving @Enum@, or @Ix@ (enum type only???)
 628 \end{itemize}
 629
 630 If we have a @tag2con@ function, we also generate a @maxtag@ constant.
 631
 632 \begin{code}
 633 gen_taggery_Names :: [InstInfo]
 634                   -> TcM s [(RdrName,   -- for an assoc list
 635                              TyCon,     -- related tycon
 636                              TagThingWanted)]
 637
 638 gen_taggery_Names inst_infos
 639   = --pprTrace "gen_taggery:\n" (vcat [hsep [ppr c, ppr t] | (c,t) <- all_CTs]) $
 640     foldlTc do_con2tag []           tycons_of_interest `thenTc` \ names_so_far ->
 641     foldlTc do_tag2con names_so_far tycons_of_interest
 642   where
 643     all_CTs = [ (c, get_tycon ty) | (InstInfo c _ [ty] _ _ _ _ _) <- inst_infos ]
 644
 645     get_tycon ty = case splitAlgTyConApp ty of { (tc, _, _) -> tc }
 646
 647     all_tycons = map snd all_CTs
 648     (tycons_of_interest, _) = removeDups compare all_tycons
 649
 650     do_con2tag acc_Names tycon
 651       | isDataTyCon tycon &&
 652         ((we_are_deriving eqClassKey tycon
 653             && any isNullaryDataCon (tyConDataCons tycon))
 654          || (we_are_deriving ordClassKey  tycon
 655             && not (maybeToBool (maybeTyConSingleCon tycon)))
 656          || (we_are_deriving enumClassKey tycon)
 657          || (we_are_deriving ixClassKey   tycon))
 658
 659       = returnTc ((con2tag_RDR tycon, tycon, GenCon2Tag)
 660                    : acc_Names)
 661       | otherwise
 662       = returnTc acc_Names
 663
 664     do_tag2con acc_Names tycon
 665       | isDataTyCon tycon &&
 666          (we_are_deriving enumClassKey tycon ||
 667           we_are_deriving ixClassKey   tycon
 668           && isEnumerationTyCon tycon)
 669       = returnTc ( (tag2con_RDR tycon, tycon, GenTag2Con)
 670                  : (maxtag_RDR  tycon, tycon, GenMaxTag)
 671                  : acc_Names)
 672       | otherwise
 673       = returnTc acc_Names
 674
 675     we_are_deriving clas_key tycon
 676       = is_in_eqns clas_key tycon all_CTs
 677       where
 678         is_in_eqns clas_key tycon [] = False
 679         is_in_eqns clas_key tycon ((c,t):cts)
 680           =  (clas_key == classKey c && tycon == t)
 681           || is_in_eqns clas_key tycon cts
 682
 683 \end{code}
 684
 685 \begin{code}
 686 derivingThingErr :: Class -> TyCon -> FAST_STRING -> Message
 687
 688 derivingThingErr clas tycon why
 689   = sep [hsep [ptext SLIT("Can't make a derived instance of"), quotes (ppr clas)],
 690          hsep [ptext SLIT("for the type"), quotes (ppr tycon)],
 691          parens (ptext why)]
 692
 693 existentialErr clas tycon
 694   = sep [ptext SLIT("Can't derive any instances for type") <+> quotes (ppr tycon),
 695          ptext SLIT("because it has existentially-quantified constructor(s)")]
 696
 697 derivCtxt tycon
 698   = ptext SLIT("When deriving classes for") <+> quotes (ppr tycon)
 699 \end{code}