ghc/compiler/typecheck/TcDeriv.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcDeriv]{Deriving}
   5
   6 Handles @deriving@ clauses on @data@ declarations.
   7
   8 \begin{code}
   9 module TcDeriv ( tcDeriving ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn            ( HsBinds(..), MonoBinds(..), collectLocatedMonoBinders )
  14 import RdrHsSyn         ( RdrNameMonoBinds )
  15 import RnHsSyn          ( RenamedHsBinds, RenamedMonoBinds )
  16 import CmdLineOpts      ( DynFlag(..), DynFlags )
  17
  18 import TcMonad
  19 import TcEnv            ( TcEnv, tcSetInstEnv, getTcGST, newDFunName )
  20 import TcGenDeriv       -- Deriv stuff
  21 import InstEnv          ( InstInfo(..), InstEnv,
  22                           pprInstInfo, simpleDFunClassTyCon, extendInstEnv )
  23 import TcSimplify       ( tcSimplifyThetas )
  24
  25 import RnBinds          ( rnMethodBinds, rnTopMonoBinds )
  26 import RnEnv            ( bindLocatedLocalsRn )
  27 import RnMonad          ( --RnNameSupply,
  28                           renameSourceCode, thenRn, mapRn, returnRn )
  29 import HscTypes         ( DFunId, GlobalSymbolTable, PersistentRenamerState )
  30
  31 import BasicTypes       ( Fixity )
  32 import Bag              ( Bag, emptyBag, unionBags, listToBag )
  33 import Class            ( classKey, Class )
  34 import ErrUtils         ( dumpIfSet_dyn, Message )
  35 import MkId             ( mkDictFunId )
  36 import Id               ( mkVanillaId, idType )
  37 import DataCon          ( dataConArgTys, isNullaryDataCon, isExistentialDataCon )
  38 import PrelInfo         ( needsDataDeclCtxtClassKeys )
  39 import Maybes           ( maybeToBool, catMaybes )
  40 import Module           ( Module )
  41 import Name             ( Name, isLocallyDefined, getSrcLoc, NamedThing(..) )
  42 import RdrName          ( RdrName )
  43
  44 import TyCon            ( tyConTyVars, tyConDataCons, tyConDerivings,
  45                           tyConTheta, maybeTyConSingleCon, isDataTyCon,
  46                           isEnumerationTyCon, isAlgTyCon, TyCon
  47                         )
  48 import Type             ( TauType, PredType(..), mkTyVarTys, mkTyConApp,
  49                           mkSigmaTy, splitDFunTy, mkDictTy,
  50                           isUnboxedType, splitAlgTyConApp, classesToPreds
  51                         )
  52 import TysWiredIn       ( voidTy )
  53 import Var              ( TyVar )
  54 import PrelNames
  55 import Bag              ( bagToList )
  56 import Util             ( zipWithEqual, sortLt, thenCmp )
  57 import ListSetOps       ( removeDups,  assoc )
  58 import Outputable
  59 \end{code}
  60
  61 %************************************************************************
  62 %*                                                                      *
  63 \subsection[TcDeriv-intro]{Introduction to how we do deriving}
  64 %*                                                                      *
  65 %************************************************************************
  66
  67 Consider
  68
  69         data T a b = C1 (Foo a) (Bar b)
  70                    | C2 Int (T b a)
  71                    | C3 (T a a)
  72                    deriving (Eq)
  73
  74 [NOTE: See end of these comments for what to do with
  75         data (C a, D b) => T a b = ...
  76 ]
  77
  78 We want to come up with an instance declaration of the form
  79
  80         instance (Ping a, Pong b, ...) => Eq (T a b) where
  81                 x == y = ...
  82
  83 It is pretty easy, albeit tedious, to fill in the code "...".  The
  84 trick is to figure out what the context for the instance decl is,
  85 namely @Ping@, @Pong@ and friends.
  86
  87 Let's call the context reqd for the T instance of class C at types
  88 (a,b, ...)  C (T a b).  Thus:
  89
  90         Eq (T a b) = (Ping a, Pong b, ...)
  91
  92 Now we can get a (recursive) equation from the @data@ decl:
  93
  94         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
  95                    u Eq (T b a) u Eq Int        -- From C2
  96                    u Eq (T a a)                 -- From C3
  97
  98 Foo and Bar may have explicit instances for @Eq@, in which case we can
  99 just substitute for them.  Alternatively, either or both may have
 100 their @Eq@ instances given by @deriving@ clauses, in which case they
 101 form part of the system of equations.
 102
 103 Now all we need do is simplify and solve the equations, iterating to
 104 find the least fixpoint.  Notice that the order of the arguments can
 105 switch around, as here in the recursive calls to T.
 106
 107 Let's suppose Eq (Foo a) = Eq a, and Eq (Bar b) = Ping b.
 108
 109 We start with:
 110
 111         Eq (T a b) = {}         -- The empty set
 112
 113 Next iteration:
 114         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
 115                    u Eq (T b a) u Eq Int        -- From C2
 116                    u Eq (T a a)                 -- From C3
 117
 118         After simplification:
 119                    = Eq a u Ping b u {} u {} u {}
 120                    = Eq a u Ping b
 121
 122 Next iteration:
 123
 124         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
 125                    u Eq (T b a) u Eq Int        -- From C2
 126                    u Eq (T a a)                 -- From C3
 127
 128         After simplification:
 129                    = Eq a u Ping b
 130                    u (Eq b u Ping a)
 131                    u (Eq a u Ping a)
 132
 133                    = Eq a u Ping b u Eq b u Ping a
 134
 135 The next iteration gives the same result, so this is the fixpoint.  We
 136 need to make a canonical form of the RHS to ensure convergence.  We do
 137 this by simplifying the RHS to a form in which
 138
 139         - the classes constrain only tyvars
 140         - the list is sorted by tyvar (major key) and then class (minor key)
 141         - no duplicates, of course
 142
 143 So, here are the synonyms for the ``equation'' structures:
 144
 145 \begin{code}
 146 type DerivEqn = (Name, Class, TyCon, [TyVar], DerivRhs)
 147                 -- The Name is the name for the DFun we'll build
 148                 -- The tyvars bind all the variables in the RHS
 149
 150 type DerivRhs = [(Class, [TauType])]    -- Same as a ThetaType!
 151                 --[PredType]   -- ... | Class Class [Type==TauType]
 152
 153 type DerivSoln = DerivRhs
 154 \end{code}
 155
 156
 157 A note about contexts on data decls
 158 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 159 Consider
 160
 161         data (RealFloat a) => Complex a = !a :+ !a deriving( Read )
 162
 163 We will need an instance decl like:
 164
 165         instance (Read a, RealFloat a) => Read (Complex a) where
 166           ...
 167
 168 The RealFloat in the context is because the read method for Complex is bound
 169 to construct a Complex, and doing that requires that the argument type is
 170 in RealFloat.
 171
 172 But this ain't true for Show, Eq, Ord, etc, since they don't construct
 173 a Complex; they only take them apart.
 174
 175 Our approach: identify the offending classes, and add the data type
 176 context to the instance decl.  The "offending classes" are
 177
 178         Read, Enum?
 179
 180
 181 %************************************************************************
 182 %*                                                                      *
 183 \subsection[TcDeriv-driver]{Top-level function for \tr{derivings}}
 184 %*                                                                      *
 185 %************************************************************************
 186
 187 \begin{code}
 188 tcDeriving  :: PersistentRenamerState
 189             -> Module                   -- name of module under scrutiny
 190             -> InstEnv                  -- What we already know about instances
 191             -> (Name -> Maybe Fixity)   -- used in deriving Show and Read
 192             -> [TyCon]                  -- "local_tycons" ???
 193             -> TcM ([InstInfo],         -- The generated "instance decls".
 194                     RenamedHsBinds)     -- Extra generated bindings
 195
 196 tcDeriving prs mod inst_env_in get_fixity local_tycons
 197   = recoverTc (returnTc ([], EmptyBinds)) $
 198
 199         -- Fish the "deriving"-related information out of the TcEnv
 200         -- and make the necessary "equations".
 201     makeDerivEqns mod local_tycons              `thenTc` \ eqns ->
 202     if null eqns then
 203         returnTc ([], EmptyBinds)
 204     else
 205
 206         -- Take the equation list and solve it, to deliver a list of
 207         -- solutions, a.k.a. the contexts for the instance decls
 208         -- required for the corresponding equations.
 209     solveDerivEqns inst_env_in eqns             `thenTc` \ new_dfuns ->
 210
 211         -- Now augment the InstInfos, adding in the rather boring
 212         -- actual-code-to-do-the-methods binds.  We may also need to
 213         -- generate extra not-one-inst-decl-specific binds, notably
 214         -- "con2tag" and/or "tag2con" functions.  We do these
 215         -- separately.
 216
 217     gen_taggery_Names new_dfuns                 `thenTc` \ nm_alist_etc ->
 218
 219     tcGetEnv                                    `thenNF_Tc` \ env ->
 220     getDOptsTc                                  `thenTc` \ dflags ->
 221     let
 222         extra_mbind_list = map gen_tag_n_con_monobind nm_alist_etc
 223         extra_mbinds     = foldr AndMonoBinds EmptyMonoBinds extra_mbind_list
 224         method_binds_s   = map (gen_bind get_fixity) new_dfuns
 225         mbinders         = collectLocatedMonoBinders extra_mbinds
 226
 227         -- Rename to get RenamedBinds.
 228         -- The only tricky bit is that the extra_binds must scope over the
 229         -- method bindings for the instances.
 230         (rn_method_binds_s, rn_extra_binds)
 231                 = renameSourceCode dflags mod prs (
 232                         bindLocatedLocalsRn (ptext (SLIT("deriving"))) mbinders $ \ _ ->
 233                         rnTopMonoBinds extra_mbinds []          `thenRn` \ (rn_extra_binds, _) ->
 234                         mapRn rn_meths method_binds_s           `thenRn` \ rn_method_binds_s ->
 235                         returnRn (rn_method_binds_s, rn_extra_binds)
 236                   )
 237
 238         new_inst_infos = map gen_inst_info (new_dfuns `zip` rn_method_binds_s)
 239     in
 240
 241     ioToTc (dumpIfSet_dyn dflags Opt_D_dump_deriv "Derived instances"
 242               (ddump_deriving new_inst_infos rn_extra_binds))   `thenTc_`
 243
 244     returnTc (new_inst_infos, rn_extra_binds)
 245   where
 246     ddump_deriving :: [InstInfo] -> RenamedHsBinds -> SDoc
 247     ddump_deriving inst_infos extra_binds
 248       = vcat (map pprInstInfo inst_infos) $$ ppr extra_binds
 249       where
 250
 251         -- Make a Real dfun instead of the dummy one we have so far
 252     gen_inst_info :: (DFunId, RenamedMonoBinds) -> InstInfo
 253     gen_inst_info (dfun, binds)
 254       = InstInfo { iLocal = True,
 255                    iClass = clas, iTyVars = tyvars,
 256                    iTys = tys, iTheta = theta,
 257                    iDFunId = dfun,
 258                    iBinds = binds,
 259                    iLoc = getSrcLoc dfun, iPrags = [] }
 260         where
 261          (tyvars, theta, clas, tys) = splitDFunTy (idType dfun)
 262
 263     rn_meths meths = rnMethodBinds [] meths `thenRn` \ (meths', _) -> returnRn meths'
 264         -- Ignore the free vars returned
 265 \end{code}
 266
 267
 268 %************************************************************************
 269 %*                                                                      *
 270 \subsection[TcDeriv-eqns]{Forming the equations}
 271 %*                                                                      *
 272 %************************************************************************
 273
 274 @makeDerivEqns@ fishes around to find the info about needed derived
 275 instances.  Complicating factors:
 276 \begin{itemize}
 277 \item
 278 We can only derive @Enum@ if the data type is an enumeration
 279 type (all nullary data constructors).
 280
 281 \item
 282 We can only derive @Ix@ if the data type is an enumeration {\em
 283 or} has just one data constructor (e.g., tuples).
 284 \end{itemize}
 285
 286 [See Appendix~E in the Haskell~1.2 report.] This code here deals w/
 287 all those.
 288
 289 \begin{code}
 290 makeDerivEqns :: Module -> [TyCon] -> TcM [DerivEqn]
 291
 292 makeDerivEqns this_mod local_tycons
 293   = let
 294         think_about_deriving = need_deriving local_tycons
 295         (derive_these, _)    = removeDups cmp_deriv think_about_deriving
 296     in
 297     if null local_tycons then
 298         returnTc []     -- Bale out now
 299     else
 300     mapTc mk_eqn derive_these `thenTc`  \ maybe_eqns ->
 301     returnTc (catMaybes maybe_eqns)
 302   where
 303     ------------------------------------------------------------------
 304     need_deriving :: [TyCon] -> [(Class, TyCon)]
 305         -- find the tycons that have `deriving' clauses;
 306
 307     need_deriving tycons_to_consider
 308       = foldr (\ tycon acc -> [(clas,tycon) | clas <- tyConDerivings tycon] ++ acc)
 309               []
 310               tycons_to_consider
 311
 312     ------------------------------------------------------------------
 313     cmp_deriv :: (Class, TyCon) -> (Class, TyCon) -> Ordering
 314     cmp_deriv (c1, t1) (c2, t2)
 315       = (c1 `compare` c2) `thenCmp` (t1 `compare` t2)
 316
 317     ------------------------------------------------------------------
 318     mk_eqn :: (Class, TyCon) -> NF_TcM (Maybe DerivEqn)
 319         -- we swizzle the tyvars and datacons out of the tycon
 320         -- to make the rest of the equation
 321
 322     mk_eqn (clas, tycon)
 323       = case chk_out clas tycon of
 324            Just err ->  addErrTc err                            `thenNF_Tc_`
 325                         returnNF_Tc Nothing
 326            Nothing  ->  newDFunName this_mod clas tyvar_tys locn `thenNF_Tc` \ dfun_name ->
 327                         returnNF_Tc (Just (dfun_name, clas, tycon, tyvars, constraints))
 328       where
 329         clas_key  = classKey clas
 330         tyvars    = tyConTyVars tycon   -- ToDo: Do we need new tyvars ???
 331         tyvar_tys = mkTyVarTys tyvars
 332         data_cons = tyConDataCons tycon
 333         locn      = getSrcLoc tycon
 334
 335         constraints = extra_constraints ++ concat (map mk_constraints data_cons)
 336
 337         -- "extra_constraints": see notes above about contexts on data decls
 338         extra_constraints
 339           | offensive_class = tyConTheta tycon
 340           | otherwise       = []
 341            where
 342             offensive_class = clas_key `elem` needsDataDeclCtxtClassKeys
 343
 344         mk_constraints data_con
 345            = [ (clas, [arg_ty])
 346              | arg_ty <- instd_arg_tys,
 347                not (isUnboxedType arg_ty)       -- No constraints for unboxed types?
 348              ]
 349            where
 350              instd_arg_tys  = dataConArgTys data_con tyvar_tys
 351
 352     ------------------------------------------------------------------
 353     chk_out :: Class -> TyCon -> Maybe Message
 354     chk_out clas tycon
 355         | clas `hasKey` enumClassKey    && not is_enumeration         = bog_out nullary_why
 356         | clas `hasKey` boundedClassKey && not is_enumeration_or_single = bog_out single_nullary_why
 357         | clas `hasKey` ixClassKey      && not is_enumeration_or_single = bog_out single_nullary_why
 358         | any isExistentialDataCon (tyConDataCons tycon)              = Just (existentialErr clas tycon)
 359         | otherwise                                                   = Nothing
 360         where
 361             is_enumeration = isEnumerationTyCon tycon
 362             is_single_con  = maybeToBool (maybeTyConSingleCon tycon)
 363             is_enumeration_or_single = is_enumeration || is_single_con
 364
 365             single_nullary_why = SLIT("one constructor data type or type with all nullary constructors expected")
 366             nullary_why        = SLIT("data type with all nullary constructors expected")
 367
 368             bog_out why = Just (derivingThingErr clas tycon why)
 369 \end{code}
 370
 371 %************************************************************************
 372 %*                                                                      *
 373 \subsection[TcDeriv-fixpoint]{Finding the fixed point of \tr{deriving} equations}
 374 %*                                                                      *
 375 %************************************************************************
 376
 377 A ``solution'' (to one of the equations) is a list of (k,TyVarTy tv)
 378 terms, which is the final correct RHS for the corresponding original
 379 equation.
 380 \begin{itemize}
 381 \item
 382 Each (k,TyVarTy tv) in a solution constrains only a type
 383 variable, tv.
 384
 385 \item
 386 The (k,TyVarTy tv) pairs in a solution are canonically
 387 ordered by sorting on type varible, tv, (major key) and then class, k,
 388 (minor key)
 389 \end{itemize}
 390
 391 \begin{code}
 392 solveDerivEqns :: InstEnv
 393                -> [DerivEqn]
 394                -> TcM [DFunId]  -- Solns in same order as eqns.
 395                                 -- This bunch is Absolutely minimal...
 396
 397 solveDerivEqns inst_env_in orig_eqns
 398   = iterateDeriv initial_solutions
 399   where
 400         -- The initial solutions for the equations claim that each
 401         -- instance has an empty context; this solution is certainly
 402         -- in canonical form.
 403     initial_solutions :: [DerivSoln]
 404     initial_solutions = [ [] | _ <- orig_eqns ]
 405
 406     ------------------------------------------------------------------
 407         -- iterateDeriv calculates the next batch of solutions,
 408         -- compares it with the current one; finishes if they are the
 409         -- same, otherwise recurses with the new solutions.
 410         -- It fails if any iteration fails
 411     iterateDeriv :: [DerivSoln] ->TcM [DFunId]
 412     iterateDeriv current_solns
 413       = checkNoErrsTc (iterateOnce current_solns)
 414                                                 `thenTc` \ (new_dfuns, new_solns) ->
 415         if (current_solns == new_solns) then
 416             returnTc new_dfuns
 417         else
 418             iterateDeriv new_solns
 419
 420     ------------------------------------------------------------------
 421     iterateOnce current_solns
 422       =     -- Extend the inst info from the explicit instance decls
 423             -- with the current set of solutions, giving a
 424         getDOptsTc                              `thenTc` \ dflags ->
 425         let (new_dfuns, inst_env) =
 426                 add_solns dflags inst_env_in orig_eqns current_solns
 427         in
 428             -- Simplify each RHS
 429         tcSetInstEnv inst_env (
 430           listTc [ tcAddErrCtxt (derivCtxt tc) $
 431                    tcSimplifyThetas deriv_rhs
 432                  | (_, _,tc,_,deriv_rhs) <- orig_eqns ]
 433         )                                       `thenTc` \ next_solns ->
 434
 435             -- Canonicalise the solutions, so they compare nicely
 436         let canonicalised_next_solns = [ sortLt (<) next_soln | next_soln <- next_solns ]
 437         in
 438         returnTc (new_dfuns, canonicalised_next_solns)
 439 \end{code}
 440
 441 \begin{code}
 442 add_solns :: DynFlags
 443           -> InstEnv                            -- The global, non-derived ones
 444           -> [DerivEqn] -> [DerivSoln]
 445           -> ([DFunId], InstEnv)
 446     -- the eqns and solns move "in lockstep"; we have the eqns
 447     -- because we need the LHS info for addClassInstance.
 448
 449 add_solns dflags inst_env_in eqns solns
 450   = (new_dfuns, inst_env)
 451     where
 452       new_dfuns     = zipWithEqual "add_solns" mk_deriv_dfun eqns solns
 453       (inst_env, _) = extendInstEnv dflags inst_env_in new_dfuns
 454         -- Ignore the errors about duplicate instances.
 455         -- We don't want repeated error messages
 456         -- They'll appear later, when we do the top-level extendInstEnvs
 457
 458       mk_deriv_dfun (dfun_name, clas, tycon, tyvars, _) theta
 459         = mkDictFunId dfun_name clas tyvars [mkTyConApp tycon (mkTyVarTys tyvars)]
 460                       (map pair2PredType theta)
 461
 462       pair2PredType (clas, tautypes) = Class clas tautypes
 463 \end{code}
 464
 465 %************************************************************************
 466 %*                                                                      *
 467 \subsection[TcDeriv-normal-binds]{Bindings for the various classes}
 468 %*                                                                      *
 469 %************************************************************************
 470
 471 After all the trouble to figure out the required context for the
 472 derived instance declarations, all that's left is to chug along to
 473 produce them.  They will then be shoved into @tcInstDecls2@, which
 474 will do all its usual business.
 475
 476 There are lots of possibilities for code to generate.  Here are
 477 various general remarks.
 478
 479 PRINCIPLES:
 480 \begin{itemize}
 481 \item
 482 We want derived instances of @Eq@ and @Ord@ (both v common) to be
 483 ``you-couldn't-do-better-by-hand'' efficient.
 484
 485 \item
 486 Deriving @Show@---also pretty common--- should also be reasonable good code.
 487
 488 \item
 489 Deriving for the other classes isn't that common or that big a deal.
 490 \end{itemize}
 491
 492 PRAGMATICS:
 493
 494 \begin{itemize}
 495 \item
 496 Deriving @Ord@ is done mostly with the 1.3 @compare@ method.
 497
 498 \item
 499 Deriving @Eq@ also uses @compare@, if we're deriving @Ord@, too.
 500
 501 \item
 502 We {\em normally} generate code only for the non-defaulted methods;
 503 there are some exceptions for @Eq@ and (especially) @Ord@...
 504
 505 \item
 506 Sometimes we use a @_con2tag_<tycon>@ function, which returns a data
 507 constructor's numeric (@Int#@) tag.  These are generated by
 508 @gen_tag_n_con_binds@, and the heuristic for deciding if one of
 509 these is around is given by @hasCon2TagFun@.
 510
 511 The examples under the different sections below will make this
 512 clearer.
 513
 514 \item
 515 Much less often (really just for deriving @Ix@), we use a
 516 @_tag2con_<tycon>@ function.  See the examples.
 517
 518 \item
 519 We use the renamer!!!  Reason: we're supposed to be
 520 producing @RenamedMonoBinds@ for the methods, but that means
 521 producing correctly-uniquified code on the fly.  This is entirely
 522 possible (the @TcM@ monad has a @UniqueSupply@), but it is painful.
 523 So, instead, we produce @RdrNameMonoBinds@ then heave 'em through
 524 the renamer.  What a great hack!
 525 \end{itemize}
 526
 527 \begin{code}
 528 -- Generate the method bindings for the required instance
 529 -- (paired with class name, as we need that when generating dict
 530 --  names.)
 531 gen_bind :: (Name -> Maybe Fixity) -> DFunId -> RdrNameMonoBinds
 532 gen_bind get_fixity dfun
 533   | not (isLocallyDefined tycon) = EmptyMonoBinds
 534   | clas `hasKey` showClassKey   = gen_Show_binds get_fixity tycon
 535   | clas `hasKey` readClassKey   = gen_Read_binds get_fixity tycon
 536   | otherwise
 537   = assoc "gen_bind:bad derived class"
 538            [(eqClassKey,      gen_Eq_binds)
 539            ,(ordClassKey,     gen_Ord_binds)
 540            ,(enumClassKey,    gen_Enum_binds)
 541            ,(boundedClassKey, gen_Bounded_binds)
 542            ,(ixClassKey,      gen_Ix_binds)
 543            ]
 544            (classKey clas)
 545            tycon
 546   where
 547     (clas, tycon) = simpleDFunClassTyCon dfun
 548 \end{code}
 549
 550
 551 %************************************************************************
 552 %*                                                                      *
 553 \subsection[TcDeriv-taggery-Names]{What con2tag/tag2con functions are available?}
 554 %*                                                                      *
 555 %************************************************************************
 556
 557
 558 data Foo ... = ...
 559
 560 con2tag_Foo :: Foo ... -> Int#
 561 tag2con_Foo :: Int -> Foo ...   -- easier if Int, not Int#
 562 maxtag_Foo  :: Int              -- ditto (NB: not unboxed)
 563
 564
 565 We have a @con2tag@ function for a tycon if:
 566 \begin{itemize}
 567 \item
 568 We're deriving @Eq@ and the tycon has nullary data constructors.
 569
 570 \item
 571 Or: we're deriving @Ord@ (unless single-constructor), @Enum@, @Ix@
 572 (enum type only????)
 573 \end{itemize}
 574
 575 We have a @tag2con@ function for a tycon if:
 576 \begin{itemize}
 577 \item
 578 We're deriving @Enum@, or @Ix@ (enum type only???)
 579 \end{itemize}
 580
 581 If we have a @tag2con@ function, we also generate a @maxtag@ constant.
 582
 583 \begin{code}
 584 gen_taggery_Names :: [DFunId]
 585                   -> TcM [(RdrName,     -- for an assoc list
 586                            TyCon,       -- related tycon
 587                            TagThingWanted)]
 588
 589 gen_taggery_Names dfuns
 590   = foldlTc do_con2tag []           tycons_of_interest `thenTc` \ names_so_far ->
 591     foldlTc do_tag2con names_so_far tycons_of_interest
 592   where
 593     all_CTs = map simpleDFunClassTyCon dfuns
 594     all_tycons              = map snd all_CTs
 595     (tycons_of_interest, _) = removeDups compare all_tycons
 596
 597     do_con2tag acc_Names tycon
 598       | isDataTyCon tycon &&
 599         ((we_are_deriving eqClassKey tycon
 600             && any isNullaryDataCon (tyConDataCons tycon))
 601          || (we_are_deriving ordClassKey  tycon
 602             && not (maybeToBool (maybeTyConSingleCon tycon)))
 603          || (we_are_deriving enumClassKey tycon)
 604          || (we_are_deriving ixClassKey   tycon))
 605
 606       = returnTc ((con2tag_RDR tycon, tycon, GenCon2Tag)
 607                    : acc_Names)
 608       | otherwise
 609       = returnTc acc_Names
 610
 611     do_tag2con acc_Names tycon
 612       | isDataTyCon tycon &&
 613          (we_are_deriving enumClassKey tycon ||
 614           we_are_deriving ixClassKey   tycon
 615           && isEnumerationTyCon tycon)
 616       = returnTc ( (tag2con_RDR tycon, tycon, GenTag2Con)
 617                  : (maxtag_RDR  tycon, tycon, GenMaxTag)
 618                  : acc_Names)
 619       | otherwise
 620       = returnTc acc_Names
 621
 622     we_are_deriving clas_key tycon
 623       = is_in_eqns clas_key tycon all_CTs
 624       where
 625         is_in_eqns clas_key tycon [] = False
 626         is_in_eqns clas_key tycon ((c,t):cts)
 627           =  (clas_key == classKey c && tycon == t)
 628           || is_in_eqns clas_key tycon cts
 629 \end{code}
 630
 631 \begin{code}
 632 derivingThingErr :: Class -> TyCon -> FAST_STRING -> Message
 633
 634 derivingThingErr clas tycon why
 635   = sep [hsep [ptext SLIT("Can't make a derived instance of"), quotes (ppr clas)],
 636          hsep [ptext SLIT("for the type"), quotes (ppr tycon)],
 637          parens (ptext why)]
 638
 639 existentialErr clas tycon
 640   = sep [ptext SLIT("Can't derive any instances for type") <+> quotes (ppr tycon),
 641          ptext SLIT("because it has existentially-quantified constructor(s)")]
 642
 643 derivCtxt tycon
 644   = ptext SLIT("When deriving classes for") <+> quotes (ppr tycon)
 645 \end{code}