ghc/compiler/typecheck/TcDeriv.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcDeriv]{Deriving}
   5
   6 Handles @deriving@ clauses on @data@ declarations.
   7
   8 \begin{code}
   9 module TcDeriv ( tcDeriving ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn            ( HsBinds(..), MonoBinds(..), collectMonoBinders )
  14 import RdrHsSyn         ( RdrNameMonoBinds )
  15 import RnHsSyn          ( RenamedHsBinds, RenamedMonoBinds )
  16 import CmdLineOpts      ( opt_D_dump_deriv )
  17
  18 import TcMonad
  19 import Inst             ( InstanceMapper )
  20 import TcEnv            ( getEnvTyCons )
  21 import TcGenDeriv       -- Deriv stuff
  22 import TcInstUtil       ( InstInfo(..), buildInstanceEnvs )
  23 import TcSimplify       ( tcSimplifyThetas )
  24
  25 import RnBinds          ( rnMethodBinds, rnTopMonoBinds )
  26 import RnEnv            ( newDFunName, bindLocatedLocalsRn )
  27 import RnMonad          ( RnNameSupply,
  28                           renameSourceCode, thenRn, mapRn, returnRn )
  29
  30 import Bag              ( Bag, emptyBag, unionBags, listToBag )
  31 import Class            ( classKey, Class )
  32 import ErrUtils         ( dumpIfSet, Message, pprBagOfErrors )
  33 import MkId             ( mkDictFunId )
  34 import Id               ( mkVanillaId )
  35 import DataCon          ( dataConArgTys, isNullaryDataCon, isExistentialDataCon )
  36 import PrelInfo         ( needsDataDeclCtxtClassKeys )
  37 import Maybes           ( maybeToBool, catMaybes )
  38 import Module           ( ModuleName )
  39 import Name             ( isLocallyDefined, getSrcLoc,
  40                           Name, NamedThing(..),
  41                           OccName, nameOccName
  42                         )
  43 import RdrName          ( RdrName )
  44 import RnMonad          ( Fixities )
  45 import SrcLoc           ( mkGeneratedSrcLoc, SrcLoc )
  46 import TyCon            ( tyConTyVars, tyConDataCons, tyConDerivings,
  47                           tyConTheta, maybeTyConSingleCon, isDataTyCon,
  48                           isEnumerationTyCon, isAlgTyCon, TyCon
  49                         )
  50 import Type             ( TauType, mkTyVarTys, mkTyConApp,
  51                           mkSigmaTy, mkDictTy, isUnboxedType,
  52                           splitAlgTyConApp
  53                         )
  54 import TysWiredIn       ( voidTy )
  55 import Var              ( TyVar )
  56 import Unique           -- Keys stuff
  57 import Bag              ( bagToList )
  58 import Util             ( zipWithEqual, sortLt, removeDups,  assoc, thenCmp )
  59 import Outputable
  60 \end{code}
  61
  62 %************************************************************************
  63 %*                                                                      *
  64 \subsection[TcDeriv-intro]{Introduction to how we do deriving}
  65 %*                                                                      *
  66 %************************************************************************
  67
  68 Consider
  69
  70         data T a b = C1 (Foo a) (Bar b)
  71                    | C2 Int (T b a)
  72                    | C3 (T a a)
  73                    deriving (Eq)
  74
  75 [NOTE: See end of these comments for what to do with
  76         data (C a, D b) => T a b = ...
  77 ]
  78
  79 We want to come up with an instance declaration of the form
  80
  81         instance (Ping a, Pong b, ...) => Eq (T a b) where
  82                 x == y = ...
  83
  84 It is pretty easy, albeit tedious, to fill in the code "...".  The
  85 trick is to figure out what the context for the instance decl is,
  86 namely @Ping@, @Pong@ and friends.
  87
  88 Let's call the context reqd for the T instance of class C at types
  89 (a,b, ...)  C (T a b).  Thus:
  90
  91         Eq (T a b) = (Ping a, Pong b, ...)
  92
  93 Now we can get a (recursive) equation from the @data@ decl:
  94
  95         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
  96                    u Eq (T b a) u Eq Int        -- From C2
  97                    u Eq (T a a)                 -- From C3
  98
  99 Foo and Bar may have explicit instances for @Eq@, in which case we can
 100 just substitute for them.  Alternatively, either or both may have
 101 their @Eq@ instances given by @deriving@ clauses, in which case they
 102 form part of the system of equations.
 103
 104 Now all we need do is simplify and solve the equations, iterating to
 105 find the least fixpoint.  Notice that the order of the arguments can
 106 switch around, as here in the recursive calls to T.
 107
 108 Let's suppose Eq (Foo a) = Eq a, and Eq (Bar b) = Ping b.
 109
 110 We start with:
 111
 112         Eq (T a b) = {}         -- The empty set
 113
 114 Next iteration:
 115         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
 116                    u Eq (T b a) u Eq Int        -- From C2
 117                    u Eq (T a a)                 -- From C3
 118
 119         After simplification:
 120                    = Eq a u Ping b u {} u {} u {}
 121                    = Eq a u Ping b
 122
 123 Next iteration:
 124
 125         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
 126                    u Eq (T b a) u Eq Int        -- From C2
 127                    u Eq (T a a)                 -- From C3
 128
 129         After simplification:
 130                    = Eq a u Ping b
 131                    u (Eq b u Ping a)
 132                    u (Eq a u Ping a)
 133
 134                    = Eq a u Ping b u Eq b u Ping a
 135
 136 The next iteration gives the same result, so this is the fixpoint.  We
 137 need to make a canonical form of the RHS to ensure convergence.  We do
 138 this by simplifying the RHS to a form in which
 139
 140         - the classes constrain only tyvars
 141         - the list is sorted by tyvar (major key) and then class (minor key)
 142         - no duplicates, of course
 143
 144 So, here are the synonyms for the ``equation'' structures:
 145
 146 \begin{code}
 147 type DerivEqn = (Class, TyCon, [TyVar], DerivRhs)
 148                          -- The tyvars bind all the variables in the RHS
 149                          -- NEW: it's convenient to re-use InstInfo
 150                          -- We'll "panic" out some fields...
 151
 152 type DerivRhs = [(Class, [TauType])]    -- Same as a ThetaType!
 153
 154 type DerivSoln = DerivRhs
 155 \end{code}
 156
 157
 158 A note about contexts on data decls
 159 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 160 Consider
 161
 162         data (RealFloat a) => Complex a = !a :+ !a deriving( Read )
 163
 164 We will need an instance decl like:
 165
 166         instance (Read a, RealFloat a) => Read (Complex a) where
 167           ...
 168
 169 The RealFloat in the context is because the read method for Complex is bound
 170 to construct a Complex, and doing that requires that the argument type is
 171 in RealFloat.
 172
 173 But this ain't true for Show, Eq, Ord, etc, since they don't construct
 174 a Complex; they only take them apart.
 175
 176 Our approach: identify the offending classes, and add the data type
 177 context to the instance decl.  The "offending classes" are
 178
 179         Read, Enum?
 180
 181
 182 %************************************************************************
 183 %*                                                                      *
 184 \subsection[TcDeriv-driver]{Top-level function for \tr{derivings}}
 185 %*                                                                      *
 186 %************************************************************************
 187
 188 \begin{code}
 189 tcDeriving  :: ModuleName               -- name of module under scrutiny
 190             -> Fixities                 -- for the deriving code (Show/Read.)
 191             -> RnNameSupply             -- for "renaming" bits of generated code
 192             -> Bag InstInfo             -- What we already know about instances
 193             -> TcM s (Bag InstInfo,     -- The generated "instance decls".
 194                       RenamedHsBinds)   -- Extra generated bindings
 195
 196 tcDeriving modname fixs rn_name_supply inst_decl_infos_in
 197   = recoverTc (returnTc (emptyBag, EmptyBinds)) $
 198
 199         -- Fish the "deriving"-related information out of the TcEnv
 200         -- and make the necessary "equations".
 201     makeDerivEqns                               `thenTc` \ eqns ->
 202     if null eqns then
 203         returnTc (emptyBag, EmptyBinds)
 204     else
 205
 206         -- Take the equation list and solve it, to deliver a list of
 207         -- solutions, a.k.a. the contexts for the instance decls
 208         -- required for the corresponding equations.
 209     solveDerivEqns inst_decl_infos_in eqns      `thenTc` \ new_inst_infos ->
 210
 211         -- Now augment the InstInfos, adding in the rather boring
 212         -- actual-code-to-do-the-methods binds.  We may also need to
 213         -- generate extra not-one-inst-decl-specific binds, notably
 214         -- "con2tag" and/or "tag2con" functions.  We do these
 215         -- separately.
 216
 217     gen_taggery_Names new_inst_infos            `thenTc` \ nm_alist_etc ->
 218
 219
 220     let
 221         extra_mbind_list = map gen_tag_n_con_monobind nm_alist_etc
 222         extra_mbinds     = foldr AndMonoBinds EmptyMonoBinds extra_mbind_list
 223         method_binds_s   = map (gen_bind fixs) new_inst_infos
 224         mbinders         = bagToList (collectMonoBinders extra_mbinds)
 225
 226         -- Rename to get RenamedBinds.
 227         -- The only tricky bit is that the extra_binds must scope over the
 228         -- method bindings for the instances.
 229         (dfun_names_w_method_binds, rn_extra_binds)
 230                 = renameSourceCode modname rn_name_supply (
 231                         bindLocatedLocalsRn (ptext (SLIT("deriving"))) mbinders $ \ _ ->
 232                         rnTopMonoBinds extra_mbinds []          `thenRn` \ (rn_extra_binds, _) ->
 233                         mapRn rn_one method_binds_s             `thenRn` \ dfun_names_w_method_binds ->
 234                         returnRn (dfun_names_w_method_binds, rn_extra_binds)
 235                   )
 236         rn_one (cl_nm, tycon_nm, meth_binds)
 237                 = newDFunName (cl_nm, tycon_nm)
 238                               mkGeneratedSrcLoc         `thenRn` \ dfun_name ->
 239                   rnMethodBinds meth_binds              `thenRn` \ (rn_meth_binds, _) ->
 240                   returnRn (dfun_name, rn_meth_binds)
 241
 242         really_new_inst_infos = zipWith gen_inst_info
 243                                         new_inst_infos
 244                                         dfun_names_w_method_binds
 245
 246         ddump_deriv = ddump_deriving really_new_inst_infos rn_extra_binds
 247     in
 248     ioToTc (dumpIfSet opt_D_dump_deriv "Derived instances" ddump_deriv) `thenTc_`
 249
 250     returnTc (listToBag really_new_inst_infos, rn_extra_binds)
 251   where
 252     ddump_deriving :: [InstInfo] -> RenamedHsBinds -> SDoc
 253     ddump_deriving inst_infos extra_binds
 254       = vcat (map pp_info inst_infos) $$ ppr extra_binds
 255       where
 256         pp_info (InstInfo clas tvs [ty] inst_decl_theta _ mbinds _ _)
 257           = ppr (mkSigmaTy tvs inst_decl_theta (mkDictTy clas [ty]))
 258             $$
 259             ppr mbinds
 260 \end{code}
 261
 262
 263 %************************************************************************
 264 %*                                                                      *
 265 \subsection[TcDeriv-eqns]{Forming the equations}
 266 %*                                                                      *
 267 %************************************************************************
 268
 269 @makeDerivEqns@ fishes around to find the info about needed derived
 270 instances.  Complicating factors:
 271 \begin{itemize}
 272 \item
 273 We can only derive @Enum@ if the data type is an enumeration
 274 type (all nullary data constructors).
 275
 276 \item
 277 We can only derive @Ix@ if the data type is an enumeration {\em
 278 or} has just one data constructor (e.g., tuples).
 279 \end{itemize}
 280
 281 [See Appendix~E in the Haskell~1.2 report.] This code here deals w/
 282 all those.
 283
 284 \begin{code}
 285 makeDerivEqns :: TcM s [DerivEqn]
 286
 287 makeDerivEqns
 288   = tcGetEnv                        `thenNF_Tc` \ env ->
 289     let
 290         local_data_tycons = filter (\tc -> isLocallyDefined tc && isAlgTyCon tc)
 291                                    (getEnvTyCons env)
 292
 293         think_about_deriving = need_deriving local_data_tycons
 294         (derive_these, _)    = removeDups cmp_deriv think_about_deriving
 295         eqns                 = map mk_eqn derive_these
 296     in
 297     if null local_data_tycons then
 298         returnTc []     -- Bale out now
 299     else
 300     mapTc mk_eqn derive_these `thenTc`  \ maybe_eqns ->
 301     returnTc (catMaybes maybe_eqns)
 302   where
 303     ------------------------------------------------------------------
 304     need_deriving :: [TyCon] -> [(Class, TyCon)]
 305         -- find the tycons that have `deriving' clauses;
 306
 307     need_deriving tycons_to_consider
 308       = foldr (\ tycon acc -> [(clas,tycon) | clas <- tyConDerivings tycon] ++ acc)
 309               []
 310               tycons_to_consider
 311
 312     ------------------------------------------------------------------
 313     cmp_deriv :: (Class, TyCon) -> (Class, TyCon) -> Ordering
 314     cmp_deriv (c1, t1) (c2, t2)
 315       = (c1 `compare` c2) `thenCmp` (t1 `compare` t2)
 316
 317     ------------------------------------------------------------------
 318     mk_eqn :: (Class, TyCon) -> NF_TcM s (Maybe DerivEqn)
 319         -- we swizzle the tyvars and datacons out of the tycon
 320         -- to make the rest of the equation
 321
 322     mk_eqn (clas, tycon)
 323       = case chk_out clas tycon of
 324            Just err ->  addErrTc err    `thenNF_Tc_`
 325                         returnNF_Tc Nothing
 326            Nothing  ->  returnNF_Tc (Just (clas, tycon, tyvars, constraints))
 327       where
 328         clas_key  = classKey clas
 329         tyvars    = tyConTyVars tycon   -- ToDo: Do we need new tyvars ???
 330         tyvar_tys = mkTyVarTys tyvars
 331         data_cons = tyConDataCons tycon
 332
 333         constraints = extra_constraints ++ concat (map mk_constraints data_cons)
 334
 335         -- "extra_constraints": see notes above about contexts on data decls
 336         extra_constraints
 337           | offensive_class = tyConTheta tycon
 338           | otherwise       = []
 339            where
 340             offensive_class = clas_key `elem` needsDataDeclCtxtClassKeys
 341
 342         mk_constraints data_con
 343            = [ (clas, [arg_ty])
 344              | arg_ty <- instd_arg_tys,
 345                not (isUnboxedType arg_ty)       -- No constraints for unboxed types?
 346              ]
 347            where
 348              instd_arg_tys  = dataConArgTys data_con tyvar_tys
 349
 350     ------------------------------------------------------------------
 351     chk_out :: Class -> TyCon -> Maybe Message
 352     chk_out clas tycon
 353         | clas_key == enumClassKey    && not is_enumeration           = bog_out nullary_why
 354         | clas_key == boundedClassKey && not is_enumeration_or_single = bog_out single_nullary_why
 355         | clas_key == ixClassKey      && not is_enumeration_or_single = bog_out single_nullary_why
 356         | any isExistentialDataCon (tyConDataCons tycon)              = Just (existentialErr clas tycon)
 357         | otherwise                                                   = Nothing
 358         where
 359             clas_key = classKey clas
 360
 361             is_enumeration = isEnumerationTyCon tycon
 362             is_single_con  = maybeToBool (maybeTyConSingleCon tycon)
 363             is_enumeration_or_single = is_enumeration || is_single_con
 364
 365             single_nullary_why = SLIT("one constructor data type or type with all nullary constructors expected")
 366             nullary_why        = SLIT("data type with all nullary constructors expected")
 367
 368             bog_out why = Just (derivingThingErr clas tycon why)
 369 \end{code}
 370
 371 %************************************************************************
 372 %*                                                                      *
 373 \subsection[TcDeriv-fixpoint]{Finding the fixed point of \tr{deriving} equations}
 374 %*                                                                      *
 375 %************************************************************************
 376
 377 A ``solution'' (to one of the equations) is a list of (k,TyVarTy tv)
 378 terms, which is the final correct RHS for the corresponding original
 379 equation.
 380 \begin{itemize}
 381 \item
 382 Each (k,TyVarTy tv) in a solution constrains only a type
 383 variable, tv.
 384
 385 \item
 386 The (k,TyVarTy tv) pairs in a solution are canonically
 387 ordered by sorting on type varible, tv, (major key) and then class, k,
 388 (minor key)
 389 \end{itemize}
 390
 391 \begin{code}
 392 solveDerivEqns :: Bag InstInfo
 393                -> [DerivEqn]
 394                -> TcM s [InstInfo]      -- Solns in same order as eqns.
 395                                         -- This bunch is Absolutely minimal...
 396
 397 solveDerivEqns inst_decl_infos_in orig_eqns
 398   = iterateDeriv initial_solutions
 399   where
 400         -- The initial solutions for the equations claim that each
 401         -- instance has an empty context; this solution is certainly
 402         -- in canonical form.
 403     initial_solutions :: [DerivSoln]
 404     initial_solutions = [ [] | _ <- orig_eqns ]
 405
 406     ------------------------------------------------------------------
 407         -- iterateDeriv calculates the next batch of solutions,
 408         -- compares it with the current one; finishes if they are the
 409         -- same, otherwise recurses with the new solutions.
 410         -- It fails if any iteration fails
 411     iterateDeriv :: [DerivSoln] ->TcM s [InstInfo]
 412     iterateDeriv current_solns
 413       = checkNoErrsTc (iterateOnce current_solns)       `thenTc` \ (new_inst_infos, new_solns) ->
 414         if (current_solns == new_solns) then
 415             returnTc new_inst_infos
 416         else
 417             iterateDeriv new_solns
 418
 419     ------------------------------------------------------------------
 420     iterateOnce current_solns
 421       =     -- Extend the inst info from the explicit instance decls
 422             -- with the current set of solutions, giving a
 423
 424         add_solns inst_decl_infos_in orig_eqns current_solns
 425                                 `thenNF_Tc` \ (new_inst_infos, inst_mapper) ->
 426         let
 427            class_to_inst_env cls = inst_mapper cls
 428         in
 429             -- Simplify each RHS
 430
 431         listTc [ tcAddErrCtxt (derivCtxt tc) $
 432                  tcSimplifyThetas class_to_inst_env deriv_rhs
 433                | (_,tc,_,deriv_rhs) <- orig_eqns ]  `thenTc` \ next_solns ->
 434
 435             -- Canonicalise the solutions, so they compare nicely
 436         let canonicalised_next_solns
 437               = [ sortLt (<) next_soln | next_soln <- next_solns ]
 438         in
 439         returnTc (new_inst_infos, canonicalised_next_solns)
 440 \end{code}
 441
 442 \begin{code}
 443 add_solns :: Bag InstInfo                       -- The global, non-derived ones
 444           -> [DerivEqn] -> [DerivSoln]
 445           -> NF_TcM s ([InstInfo],              -- The new, derived ones
 446                        InstanceMapper)
 447     -- the eqns and solns move "in lockstep"; we have the eqns
 448     -- because we need the LHS info for addClassInstance.
 449
 450 add_solns inst_infos_in eqns solns
 451
 452   = discardErrsTc (buildInstanceEnvs all_inst_infos)    `thenNF_Tc` \ inst_mapper ->
 453         -- We do the discard-errs so that we don't get repeated error messages
 454         -- about duplicate instances.
 455         -- They'll appear later, when we do the top-level buildInstanceEnvs.
 456
 457     returnNF_Tc (new_inst_infos, inst_mapper)
 458   where
 459     new_inst_infos = zipWithEqual "add_solns" mk_deriv_inst_info eqns solns
 460
 461     all_inst_infos = inst_infos_in `unionBags` listToBag new_inst_infos
 462
 463     mk_deriv_inst_info (clas, tycon, tyvars, _) theta
 464       = InstInfo clas tyvars [mkTyConApp tycon (mkTyVarTys tyvars)]
 465                  theta
 466                  dummy_dfun_id
 467                  (my_panic "binds") (getSrcLoc tycon)
 468                  (my_panic "upragmas")
 469       where
 470         dummy_dfun_id
 471           = mkVanillaId (getName tycon) dummy_dfun_ty
 472                 -- The name is getSrcLoc'd in an error message
 473
 474         dummy_dfun_ty = mkSigmaTy tyvars theta voidTy
 475                 -- All we need from the dfun is its "theta" part, used during
 476                 -- equation simplification (tcSimplifyThetas).  The final
 477                 -- dfun_id will have the superclass dictionaries as arguments too,
 478                 -- but that'll be added after the equations are solved.  For now,
 479                 -- it's enough just to make a dummy dfun with the simple theta part.
 480                 --
 481                 -- The part after the theta is dummied here as voidTy; actually it's
 482                 --      (C (T a b)), but it doesn't seem worth constructing it.
 483                 -- We can't leave it as a panic because to get the theta part we
 484                 -- have to run down the type!
 485
 486         my_panic str = panic "add_soln" -- pprPanic ("add_soln:"++str) (hsep [char ':', ppr clas, ppr tycon])
 487 \end{code}
 488
 489 %************************************************************************
 490 %*                                                                      *
 491 \subsection[TcDeriv-normal-binds]{Bindings for the various classes}
 492 %*                                                                      *
 493 %************************************************************************
 494
 495 After all the trouble to figure out the required context for the
 496 derived instance declarations, all that's left is to chug along to
 497 produce them.  They will then be shoved into @tcInstDecls2@, which
 498 will do all its usual business.
 499
 500 There are lots of possibilities for code to generate.  Here are
 501 various general remarks.
 502
 503 PRINCIPLES:
 504 \begin{itemize}
 505 \item
 506 We want derived instances of @Eq@ and @Ord@ (both v common) to be
 507 ``you-couldn't-do-better-by-hand'' efficient.
 508
 509 \item
 510 Deriving @Show@---also pretty common--- should also be reasonable good code.
 511
 512 \item
 513 Deriving for the other classes isn't that common or that big a deal.
 514 \end{itemize}
 515
 516 PRAGMATICS:
 517
 518 \begin{itemize}
 519 \item
 520 Deriving @Ord@ is done mostly with the 1.3 @compare@ method.
 521
 522 \item
 523 Deriving @Eq@ also uses @compare@, if we're deriving @Ord@, too.
 524
 525 \item
 526 We {\em normally} generate code only for the non-defaulted methods;
 527 there are some exceptions for @Eq@ and (especially) @Ord@...
 528
 529 \item
 530 Sometimes we use a @_con2tag_<tycon>@ function, which returns a data
 531 constructor's numeric (@Int#@) tag.  These are generated by
 532 @gen_tag_n_con_binds@, and the heuristic for deciding if one of
 533 these is around is given by @hasCon2TagFun@.
 534
 535 The examples under the different sections below will make this
 536 clearer.
 537
 538 \item
 539 Much less often (really just for deriving @Ix@), we use a
 540 @_tag2con_<tycon>@ function.  See the examples.
 541
 542 \item
 543 We use the renamer!!!  Reason: we're supposed to be
 544 producing @RenamedMonoBinds@ for the methods, but that means
 545 producing correctly-uniquified code on the fly.  This is entirely
 546 possible (the @TcM@ monad has a @UniqueSupply@), but it is painful.
 547 So, instead, we produce @RdrNameMonoBinds@ then heave 'em through
 548 the renamer.  What a great hack!
 549 \end{itemize}
 550
 551 \begin{code}
 552 -- Generate the method bindings for the required instance
 553 -- (paired with class name, as we need that when generating dict
 554 --  names.)
 555 gen_bind :: Fixities -> InstInfo -> ({-class-}OccName, {-tyCon-}OccName, RdrNameMonoBinds)
 556 gen_bind fixities (InstInfo clas _ [ty] _ _ _ _ _)
 557   | not from_here
 558   = (clas_nm, tycon_nm, EmptyMonoBinds)
 559   |  ckey == showClassKey
 560   = (clas_nm, tycon_nm, gen_Show_binds fixities tycon)
 561   |  ckey == readClassKey
 562   = (clas_nm, tycon_nm, gen_Read_binds fixities tycon)
 563   | otherwise
 564   = (clas_nm, tycon_nm,
 565      assoc "gen_bind:bad derived class"
 566            [(eqClassKey,      gen_Eq_binds)
 567            ,(ordClassKey,     gen_Ord_binds)
 568            ,(enumClassKey,    gen_Enum_binds)
 569            ,(boundedClassKey, gen_Bounded_binds)
 570            ,(ixClassKey,      gen_Ix_binds)
 571            ]
 572            ckey
 573            tycon)
 574   where
 575       clas_nm     = nameOccName (getName clas)
 576       tycon_nm    = nameOccName (getName tycon)
 577       from_here   = isLocallyDefined tycon
 578       (tycon,_,_) = splitAlgTyConApp ty
 579       ckey        = classKey clas
 580
 581
 582 gen_inst_info :: InstInfo
 583               -> (Name, RenamedMonoBinds)
 584               -> InstInfo                               -- the gen'd (filled-in) "instance decl"
 585
 586 gen_inst_info (InstInfo clas tyvars tys@(ty:_) inst_decl_theta _ _ locn _)
 587               (dfun_name, meth_binds)
 588   =
 589         -- Generate the various instance-related Ids
 590     InstInfo clas tyvars tys inst_decl_theta
 591                dfun_id
 592                meth_binds
 593                locn []
 594   where
 595    dfun_id = mkDictFunId dfun_name clas tyvars tys inst_decl_theta
 596
 597    from_here = isLocallyDefined tycon
 598    (tycon,_,_) = splitAlgTyConApp ty
 599 \end{code}
 600
 601
 602 %************************************************************************
 603 %*                                                                      *
 604 \subsection[TcDeriv-taggery-Names]{What con2tag/tag2con functions are available?}
 605 %*                                                                      *
 606 %************************************************************************
 607
 608
 609 data Foo ... = ...
 610
 611 con2tag_Foo :: Foo ... -> Int#
 612 tag2con_Foo :: Int -> Foo ...   -- easier if Int, not Int#
 613 maxtag_Foo  :: Int              -- ditto (NB: not unboxed)
 614
 615
 616 We have a @con2tag@ function for a tycon if:
 617 \begin{itemize}
 618 \item
 619 We're deriving @Eq@ and the tycon has nullary data constructors.
 620
 621 \item
 622 Or: we're deriving @Ord@ (unless single-constructor), @Enum@, @Ix@
 623 (enum type only????)
 624 \end{itemize}
 625
 626 We have a @tag2con@ function for a tycon if:
 627 \begin{itemize}
 628 \item
 629 We're deriving @Enum@, or @Ix@ (enum type only???)
 630 \end{itemize}
 631
 632 If we have a @tag2con@ function, we also generate a @maxtag@ constant.
 633
 634 \begin{code}
 635 gen_taggery_Names :: [InstInfo]
 636                   -> TcM s [(RdrName,   -- for an assoc list
 637                              TyCon,     -- related tycon
 638                              TagThingWanted)]
 639
 640 gen_taggery_Names inst_infos
 641   = --pprTrace "gen_taggery:\n" (vcat [hsep [ppr c, ppr t] | (c,t) <- all_CTs]) $
 642     foldlTc do_con2tag []           tycons_of_interest `thenTc` \ names_so_far ->
 643     foldlTc do_tag2con names_so_far tycons_of_interest
 644   where
 645     all_CTs = [ (c, get_tycon ty) | (InstInfo c _ [ty] _ _ _ _ _) <- inst_infos ]
 646
 647     get_tycon ty = case splitAlgTyConApp ty of { (tc, _, _) -> tc }
 648
 649     all_tycons = map snd all_CTs
 650     (tycons_of_interest, _) = removeDups compare all_tycons
 651
 652     do_con2tag acc_Names tycon
 653       | isDataTyCon tycon &&
 654         ((we_are_deriving eqClassKey tycon
 655             && any isNullaryDataCon (tyConDataCons tycon))
 656          || (we_are_deriving ordClassKey  tycon
 657             && not (maybeToBool (maybeTyConSingleCon tycon)))
 658          || (we_are_deriving enumClassKey tycon)
 659          || (we_are_deriving ixClassKey   tycon))
 660
 661       = returnTc ((con2tag_RDR tycon, tycon, GenCon2Tag)
 662                    : acc_Names)
 663       | otherwise
 664       = returnTc acc_Names
 665
 666     do_tag2con acc_Names tycon
 667       | isDataTyCon tycon &&
 668          (we_are_deriving enumClassKey tycon ||
 669           we_are_deriving ixClassKey   tycon
 670           && isEnumerationTyCon tycon)
 671       = returnTc ( (tag2con_RDR tycon, tycon, GenTag2Con)
 672                  : (maxtag_RDR  tycon, tycon, GenMaxTag)
 673                  : acc_Names)
 674       | otherwise
 675       = returnTc acc_Names
 676
 677     we_are_deriving clas_key tycon
 678       = is_in_eqns clas_key tycon all_CTs
 679       where
 680         is_in_eqns clas_key tycon [] = False
 681         is_in_eqns clas_key tycon ((c,t):cts)
 682           =  (clas_key == classKey c && tycon == t)
 683           || is_in_eqns clas_key tycon cts
 684
 685 \end{code}
 686
 687 \begin{code}
 688 derivingThingErr :: Class -> TyCon -> FAST_STRING -> Message
 689
 690 derivingThingErr clas tycon why
 691   = sep [hsep [ptext SLIT("Can't make a derived instance of"), quotes (ppr clas)],
 692          hsep [ptext SLIT("for the type"), quotes (ppr tycon)],
 693          parens (ptext why)]
 694
 695 existentialErr clas tycon
 696   = sep [ptext SLIT("Can't derive any instances for type") <+> quotes (ppr tycon),
 697          ptext SLIT("because it has existentially-quantified constructor(s)")]
 698
 699 derivCtxt tycon
 700   = ptext SLIT("When deriving classes for") <+> quotes (ppr tycon)
 701 \end{code}