ghc/compiler/typecheck/TcEnv.lhs

   1 \begin{code}
   2 module TcEnv(
   3         TcId, TcIdSet,
   4         TyThing(..), TyThingDetails(..), TcTyThing(..),
   5
   6         -- Getting stuff from the environment
   7         TcEnv, initTcEnv,
   8         tcEnvTyCons, tcEnvClasses, tcEnvIds, tcEnvTcIds, tcEnvTyVars,
   9         getTcGEnv,
  10
  11         -- Instance environment, and InstInfo type
  12         tcGetInstEnv, tcSetInstEnv,
  13         InstInfo(..), pprInstInfo,
  14         simpleInstInfoTy, simpleInstInfoTyCon,
  15
  16         -- Global environment
  17         tcExtendGlobalEnv, tcExtendGlobalValEnv,
  18         tcLookupTyCon, tcLookupClass, tcLookupGlobalId, tcLookupDataCon,
  19         tcLookupGlobal_maybe, tcLookupGlobal, tcLookupSyntaxId, tcLookupSyntaxName,
  20
  21         -- Local environment
  22         tcExtendKindEnv,  tcLookupLocalIds,
  23         tcExtendTyVarEnv, tcExtendTyVarEnvForMeths,
  24         tcExtendLocalValEnv, tcLookup, tcLookup_maybe,
  25
  26         -- Global type variables
  27         tcGetGlobalTyVars, tcExtendGlobalTyVars,
  28
  29         -- Random useful things
  30         RecTcEnv, tcAddImportedIdInfo, tcLookupRecId, tcLookupRecId_maybe,
  31
  32         -- New Ids
  33         newLocalId, newSpecPragmaId,
  34         newDFunName,
  35
  36         -- Misc
  37         isLocalThing, tcSetEnv
  38   ) where
  39
  40 #include "HsVersions.h"
  41
  42 import RnHsSyn          ( RenamedMonoBinds, RenamedSig )
  43 import TcMonad
  44 import TcType           ( TcKind,  TcType, TcTyVar, TcTyVarSet,
  45                           zonkTcTyVarsAndFV
  46                         )
  47 import Id               ( idName, mkUserLocal, isDataConWrapId_maybe )
  48 import IdInfo           ( constantIdInfo )
  49 import MkId             ( mkSpecPragmaId )
  50 import Var              ( TyVar, Id, idType, lazySetIdInfo, idInfo )
  51 import VarSet
  52 import Type             ( Type,
  53                           tyVarsOfTypes, splitDFunTy,
  54                           getDFunTyKey, tyConAppTyCon
  55                         )
  56 import DataCon          ( DataCon )
  57 import TyCon            ( TyCon )
  58 import Class            ( Class, ClassOpItem, ClassContext )
  59 import Name             ( Name, OccName, NamedThing(..),
  60                           nameOccName, getSrcLoc, mkLocalName, isLocalName,
  61                           nameIsLocalOrFrom, nameModule_maybe
  62                         )
  63 import Name             ( NameEnv, lookupNameEnv, nameEnvElts, extendNameEnvList, emptyNameEnv )
  64 import OccName          ( mkDFunOcc, occNameString )
  65 import HscTypes         ( DFunId, TypeEnv, HomeSymbolTable, PackageTypeEnv )
  66 import Module           ( Module )
  67 import InstEnv          ( InstEnv, emptyInstEnv )
  68 import HscTypes         ( lookupType, TyThing(..) )
  69 import Util             ( zipEqual )
  70 import SrcLoc           ( SrcLoc )
  71 import qualified PrelNames
  72 import Outputable
  73
  74 import IOExts           ( newIORef )
  75 \end{code}
  76
  77 %************************************************************************
  78 %*                                                                      *
  79 \subsection{TcEnv}
  80 %*                                                                      *
  81 %************************************************************************
  82
  83 \begin{code}
  84 type TcId    = Id                       -- Type may be a TcType
  85 type TcIdSet = IdSet
  86
  87 data TcEnv
  88   = TcEnv {
  89         tcSyntaxMap :: PrelNames.SyntaxMap,     -- The syntax map (usually the identity)
  90
  91         tcGST    :: Name -> Maybe TyThing,      -- The type environment at the moment we began this compilation
  92
  93         tcInsts  :: InstEnv,            -- All instances (both imported and in this module)
  94
  95         tcGEnv   :: TypeEnv,            -- The global type environment we've accumulated while
  96                  {- NameEnv TyThing-}   -- compiling this module:
  97                                         --      types and classes (both imported and local)
  98                                         --      imported Ids
  99                                         -- (Ids defined in this module are in the local envt)
 100
 101         tcLEnv   :: NameEnv TcTyThing,  -- The local type environment: Ids and TyVars
 102                                         -- defined in this module
 103
 104         tcTyVars :: TcRef TcTyVarSet    -- The "global tyvars"
 105                                         -- Namely, the in-scope TyVars bound in tcLEnv, plus the tyvars
 106                                         -- mentioned in the types of Ids bound in tcLEnv
 107                                         -- Why mutable? see notes with tcGetGlobalTyVars
 108     }
 109
 110 \end{code}
 111
 112 The Global-Env/Local-Env story
 113 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 114 During type checking, we keep in the GlobalEnv
 115         * All types and classes
 116         * All Ids derived from types and classes (constructors, selectors)
 117         * Imported Ids
 118
 119 At the end of type checking, we zonk the local bindings,
 120 and as we do so we add to the GlobalEnv
 121         * Locally defined top-level Ids
 122
 123 Why?  Because they are now Ids not TcIds.  This final GlobalEnv is
 124 used thus:
 125         a) fed back (via the knot) to typechecking the
 126            unfoldings of interface signatures
 127
 128         b) used to augment the GlobalSymbolTable
 129
 130
 131 \begin{code}
 132 data TcTyThing
 133   = AGlobal TyThing     -- Used only in the return type of a lookup
 134   | ATcId  TcId         -- Ids defined in this module
 135   | ATyVar TyVar        -- Type variables
 136   | AThing TcKind       -- Used temporarily, during kind checking
 137 -- Here's an example of how the AThing guy is used
 138 -- Suppose we are checking (forall a. T a Int):
 139 --      1. We first bind (a -> AThink kv), where kv is a kind variable.
 140 --      2. Then we kind-check the (T a Int) part.
 141 --      3. Then we zonk the kind variable.
 142 --      4. Now we know the kind for 'a', and we add (a -> ATyVar a::K) to the environment
 143
 144 initTcEnv :: PrelNames.SyntaxMap -> HomeSymbolTable -> PackageTypeEnv -> IO TcEnv
 145 initTcEnv syntax_map hst pte
 146   = do { gtv_var <- newIORef emptyVarSet ;
 147          return (TcEnv { tcSyntaxMap = syntax_map,
 148                          tcGST    = lookup,
 149                          tcGEnv   = emptyNameEnv,
 150                          tcInsts  = emptyInstEnv,
 151                          tcLEnv   = emptyNameEnv,
 152                          tcTyVars = gtv_var
 153          })}
 154   where
 155     lookup name | isLocalName name = Nothing
 156                 | otherwise        = lookupType hst pte name
 157
 158
 159 tcEnvClasses env = [cl | AClass cl <- nameEnvElts (tcGEnv env)]
 160 tcEnvTyCons  env = [tc | ATyCon tc <- nameEnvElts (tcGEnv env)]
 161 tcEnvIds     env = [id | AnId   id <- nameEnvElts (tcGEnv env)]
 162 tcEnvTyVars  env = [tv | ATyVar tv <- nameEnvElts (tcLEnv env)]
 163 tcEnvTcIds   env = [id | ATcId  id <- nameEnvElts (tcLEnv env)]
 164
 165 getTcGEnv (TcEnv { tcGEnv = genv }) = genv
 166
 167 -- This data type is used to help tie the knot
 168 -- when type checking type and class declarations
 169 data TyThingDetails = SynTyDetails Type
 170                     | DataTyDetails ClassContext [DataCon] [Id]
 171                     | ClassDetails ClassContext [Id] [ClassOpItem] DataCon
 172 \end{code}
 173
 174
 175 %************************************************************************
 176 %*                                                                      *
 177 \subsection{Basic lookups}
 178 %*                                                                      *
 179 %************************************************************************
 180
 181 \begin{code}
 182 lookup_global :: TcEnv -> Name -> Maybe TyThing
 183         -- Try the global envt and then the global symbol table
 184 lookup_global env name
 185   = case lookupNameEnv (tcGEnv env) name of
 186         Just thing -> Just thing
 187         Nothing    -> tcGST env name
 188
 189 lookup_local :: TcEnv -> Name -> Maybe TcTyThing
 190         -- Try the local envt and then try the global
 191 lookup_local env name
 192   = case lookupNameEnv (tcLEnv env) name of
 193         Just thing -> Just thing
 194         Nothing    -> case lookup_global env name of
 195                         Just thing -> Just (AGlobal thing)
 196                         Nothing    -> Nothing
 197 \end{code}
 198
 199 \begin{code}
 200 type RecTcEnv = TcEnv
 201 -- This environment is used for getting the 'right' IdInfo
 202 -- on imported things and for looking up Ids in unfoldings
 203 -- The environment doesn't have any local Ids in it
 204
 205 tcAddImportedIdInfo :: RecTcEnv -> Id -> Id
 206 tcAddImportedIdInfo env id
 207   = id `lazySetIdInfo` new_info
 208         -- The Id must be returned without a data dependency on maybe_id
 209   where
 210     new_info = case tcLookupRecId_maybe env (idName id) of
 211                   Nothing          -> pprTrace "tcAddIdInfo" (ppr id) constantIdInfo
 212                   Just imported_id -> idInfo imported_id
 213                 -- ToDo: could check that types are the same
 214
 215 tcLookupRecId_maybe :: RecTcEnv -> Name -> Maybe Id
 216 tcLookupRecId_maybe env name = case lookup_global env name of
 217                                    Just (AnId id) -> Just id
 218                                    other          -> Nothing
 219
 220 tcLookupRecId ::  RecTcEnv -> Name -> Id
 221 tcLookupRecId env name = case lookup_global env name of
 222                                 Just (AnId id) -> id
 223                                 Nothing        -> pprPanic "tcLookupRecId" (ppr name)
 224 \end{code}
 225
 226 %************************************************************************
 227 %*                                                                      *
 228 \subsection{Making new Ids}
 229 %*                                                                      *
 230 %************************************************************************
 231
 232 Constructing new Ids
 233
 234 \begin{code}
 235 newLocalId :: OccName -> TcType -> SrcLoc -> NF_TcM TcId
 236 newLocalId name ty loc
 237   = tcGetUnique         `thenNF_Tc` \ uniq ->
 238     returnNF_Tc (mkUserLocal name uniq ty loc)
 239
 240 newSpecPragmaId :: Name -> TcType -> NF_TcM TcId
 241 newSpecPragmaId name ty
 242   = tcGetUnique         `thenNF_Tc` \ uniq ->
 243     returnNF_Tc (mkSpecPragmaId (nameOccName name) uniq ty (getSrcLoc name))
 244 \end{code}
 245
 246 Make a name for the dict fun for an instance decl.
 247 It's a *local* name for the moment.  The CoreTidy pass
 248 will globalise it.
 249
 250 \begin{code}
 251 newDFunName :: Class -> [Type] -> SrcLoc -> NF_TcM Name
 252 newDFunName clas (ty:_) loc
 253   = tcGetUnique                 `thenNF_Tc` \ uniq ->
 254     returnNF_Tc (mkLocalName uniq (mkDFunOcc dfun_string) loc)
 255   where
 256         -- Any string that is somewhat unique will do
 257     dfun_string = occNameString (getOccName clas) ++ occNameString (getDFunTyKey ty)
 258
 259 newDFunName clas [] loc = pprPanic "newDFunName" (ppr clas <+> ppr loc)
 260 \end{code}
 261
 262 \begin{code}
 263 isLocalThing :: NamedThing a => Module -> a -> Bool
 264 isLocalThing mod thing = nameIsLocalOrFrom mod (getName thing)
 265 \end{code}
 266
 267 %************************************************************************
 268 %*                                                                      *
 269 \subsection{The global environment}
 270 %*                                                                      *
 271 %************************************************************************
 272
 273 \begin{code}
 274 tcExtendGlobalEnv :: [TyThing] -> TcM r -> TcM r
 275 tcExtendGlobalEnv things thing_inside
 276   = tcGetEnv                            `thenNF_Tc` \ env ->
 277     let
 278         ge' = extendNameEnvList (tcGEnv env) [(getName thing, thing) | thing <- things]
 279     in
 280     tcSetEnv (env {tcGEnv = ge'}) thing_inside
 281
 282 tcExtendGlobalValEnv :: [Id] -> TcM a -> TcM a
 283 tcExtendGlobalValEnv ids thing_inside
 284   = tcGetEnv                            `thenNF_Tc` \ env ->
 285     let
 286         ge' = extendNameEnvList (tcGEnv env) [(getName id, AnId id) | id <- ids]
 287     in
 288     tcSetEnv (env {tcGEnv = ge'}) thing_inside
 289 \end{code}
 290
 291
 292 \begin{code}
 293 tcLookupGlobal_maybe :: Name -> NF_TcM (Maybe TyThing)
 294 tcLookupGlobal_maybe name
 295   = tcGetEnv            `thenNF_Tc` \ env ->
 296     returnNF_Tc (lookup_global env name)
 297 \end{code}
 298
 299 A variety of global lookups, when we know what we are looking for.
 300
 301 \begin{code}
 302 tcLookupGlobal :: Name -> NF_TcM TyThing
 303 tcLookupGlobal name
 304   = tcLookupGlobal_maybe name   `thenNF_Tc` \ maybe_thing ->
 305     case maybe_thing of
 306         Just thing -> returnNF_Tc thing
 307         other      -> notFound "tcLookupGlobal" name
 308
 309 tcLookupGlobalId :: Name -> NF_TcM Id
 310 tcLookupGlobalId name
 311   = tcLookupGlobal_maybe name   `thenNF_Tc` \ maybe_id ->
 312     case maybe_id of
 313         Just (AnId id) -> returnNF_Tc id
 314         other          -> notFound "tcLookupGlobalId" name
 315
 316 tcLookupDataCon :: Name -> TcM DataCon
 317 tcLookupDataCon con_name
 318   = tcLookupGlobalId con_name           `thenNF_Tc` \ con_id ->
 319     case isDataConWrapId_maybe con_id of
 320         Just data_con -> returnTc data_con
 321         Nothing       -> failWithTc (badCon con_id)
 322
 323
 324 tcLookupClass :: Name -> NF_TcM Class
 325 tcLookupClass name
 326   = tcLookupGlobal_maybe name   `thenNF_Tc` \ maybe_clas ->
 327     case maybe_clas of
 328         Just (AClass clas) -> returnNF_Tc clas
 329         other              -> notFound "tcLookupClass" name
 330
 331 tcLookupTyCon :: Name -> NF_TcM TyCon
 332 tcLookupTyCon name
 333   = tcLookupGlobal_maybe name   `thenNF_Tc` \ maybe_tc ->
 334     case maybe_tc of
 335         Just (ATyCon tc) -> returnNF_Tc tc
 336         other            -> notFound "tcLookupTyCon" name
 337
 338 tcLookupLocalIds :: [Name] -> NF_TcM [TcId]
 339 tcLookupLocalIds ns
 340   = tcGetEnv            `thenNF_Tc` \ env ->
 341     returnNF_Tc (map (lookup (tcLEnv env)) ns)
 342   where
 343     lookup lenv name = case lookupNameEnv lenv name of
 344                         Just (ATcId id) -> id
 345                         other           -> pprPanic "tcLookupLocalIds" (ppr name)
 346
 347 tcLookupSyntaxId :: Name -> NF_TcM Id
 348 -- Lookup a name like PrelNum.fromInt, and return the corresponding Id,
 349 -- after mapping through the SyntaxMap.  This may give us the Id for
 350 -- (say) MyPrelude.fromInteger
 351 tcLookupSyntaxId name
 352   = tcGetEnv            `thenNF_Tc` \ env ->
 353     returnNF_Tc (case lookup_global env (tcSyntaxMap env name) of
 354                         Just (AnId id) -> id
 355                         other          -> pprPanic "tcLookupSyntaxId" (ppr name))
 356
 357 tcLookupSyntaxName :: Name -> NF_TcM Name
 358 tcLookupSyntaxName name
 359   = tcGetEnv            `thenNF_Tc` \ env ->
 360     returnNF_Tc (tcSyntaxMap env name)
 361 \end{code}
 362
 363
 364 %************************************************************************
 365 %*                                                                      *
 366 \subsection{The local environment}
 367 %*                                                                      *
 368 %************************************************************************
 369
 370 \begin{code}
 371 tcLookup_maybe :: Name -> NF_TcM (Maybe TcTyThing)
 372 tcLookup_maybe name
 373   = tcGetEnv            `thenNF_Tc` \ env ->
 374     returnNF_Tc (lookup_local env name)
 375
 376 tcLookup :: Name -> NF_TcM TcTyThing
 377 tcLookup name
 378   = tcLookup_maybe name         `thenNF_Tc` \ maybe_thing ->
 379     case maybe_thing of
 380         Just thing -> returnNF_Tc thing
 381         other      -> notFound "tcLookup" name
 382         -- Extract the IdInfo from an IfaceSig imported from an interface file
 383 \end{code}
 384
 385
 386 \begin{code}
 387 tcExtendKindEnv :: [(Name,TcKind)] -> TcM r -> TcM r
 388 tcExtendKindEnv pairs thing_inside
 389   = tcGetEnv                            `thenNF_Tc` \ env ->
 390     let
 391         le' = extendNameEnvList (tcLEnv env) [(n, AThing k) | (n,k) <- pairs]
 392         -- No need to extend global tyvars for kind checking
 393     in
 394     tcSetEnv (env {tcLEnv = le'}) thing_inside
 395
 396 tcExtendTyVarEnv :: [TyVar] -> TcM r -> TcM r
 397 tcExtendTyVarEnv tyvars thing_inside
 398   = tcGetEnv                    `thenNF_Tc` \ env@(TcEnv {tcLEnv = le, tcTyVars = gtvs}) ->
 399     let
 400         le'        = extendNameEnvList le [ (getName tv, ATyVar tv) | tv <- tyvars]
 401         new_tv_set = mkVarSet tyvars
 402     in
 403         -- It's important to add the in-scope tyvars to the global tyvar set
 404         -- as well.  Consider
 405         --      f (x::r) = let g y = y::r in ...
 406         -- Here, g mustn't be generalised.  This is also important during
 407         -- class and instance decls, when we mustn't generalise the class tyvars
 408         -- when typechecking the methods.
 409     tc_extend_gtvs gtvs new_tv_set              `thenNF_Tc` \ gtvs' ->
 410     tcSetEnv (env {tcLEnv = le', tcTyVars = gtvs'}) thing_inside
 411
 412 -- This variant, tcExtendTyVarEnvForMeths, takes *two* bunches of tyvars:
 413 --      the signature tyvars contain the original names
 414 --      the instance  tyvars are what those names should be mapped to
 415 -- It's needed when typechecking the method bindings of class and instance decls
 416 -- It does *not* extend the global tyvars; tcMethodBind does that for itself
 417
 418 tcExtendTyVarEnvForMeths :: [TyVar] -> [TcTyVar] -> TcM r -> TcM r
 419 tcExtendTyVarEnvForMeths sig_tyvars inst_tyvars thing_inside
 420   = tcGetEnv                                    `thenNF_Tc` \ env ->
 421     let
 422         le'   = extendNameEnvList (tcLEnv env) stuff
 423         stuff = [ (getName sig_tv, ATyVar inst_tv)
 424                 | (sig_tv, inst_tv) <- zipEqual "tcMeth" sig_tyvars inst_tyvars
 425                 ]
 426     in
 427     tcSetEnv (env {tcLEnv = le'}) thing_inside
 428 \end{code}
 429
 430
 431 \begin{code}
 432 tcExtendLocalValEnv :: [(Name,TcId)] -> TcM a -> TcM a
 433 tcExtendLocalValEnv names_w_ids thing_inside
 434   = tcGetEnv            `thenNF_Tc` \ env ->
 435     let
 436         extra_global_tyvars = tyVarsOfTypes [idType id | (name,id) <- names_w_ids]
 437         extra_env           = [(name, ATcId id) | (name,id) <- names_w_ids]
 438         le'                 = extendNameEnvList (tcLEnv env) extra_env
 439     in
 440     tc_extend_gtvs (tcTyVars env) extra_global_tyvars   `thenNF_Tc` \ gtvs' ->
 441     tcSetEnv (env {tcLEnv = le', tcTyVars = gtvs'}) thing_inside
 442 \end{code}
 443
 444
 445 %************************************************************************
 446 %*                                                                      *
 447 \subsection{The global tyvars}
 448 %*                                                                      *
 449 %************************************************************************
 450
 451 \begin{code}
 452 tcExtendGlobalTyVars extra_global_tvs thing_inside
 453   = tcGetEnv                                            `thenNF_Tc` \ env ->
 454     tc_extend_gtvs (tcTyVars env) extra_global_tvs      `thenNF_Tc` \ gtvs' ->
 455     tcSetEnv (env {tcTyVars = gtvs'}) thing_inside
 456
 457 tc_extend_gtvs gtvs extra_global_tvs
 458   = tcReadMutVar gtvs                   `thenNF_Tc` \ global_tvs ->
 459     tcNewMutVar (global_tvs `unionVarSet` extra_global_tvs)
 460 \end{code}
 461
 462 @tcGetGlobalTyVars@ returns a fully-zonked set of tyvars free in the environment.
 463 To improve subsequent calls to the same function it writes the zonked set back into
 464 the environment.
 465
 466 \begin{code}
 467 tcGetGlobalTyVars :: NF_TcM TcTyVarSet
 468 tcGetGlobalTyVars
 469   = tcGetEnv                                    `thenNF_Tc` \ (TcEnv {tcTyVars = gtv_var}) ->
 470     tcReadMutVar gtv_var                        `thenNF_Tc` \ gbl_tvs ->
 471     zonkTcTyVarsAndFV (varSetElems gbl_tvs)     `thenNF_Tc` \ gbl_tvs' ->
 472     tcWriteMutVar gtv_var gbl_tvs'              `thenNF_Tc_`
 473     returnNF_Tc gbl_tvs'
 474 \end{code}
 475
 476
 477 %************************************************************************
 478 %*                                                                      *
 479 \subsection{The instance environment}
 480 %*                                                                      *
 481 %************************************************************************
 482
 483 \begin{code}
 484 tcGetInstEnv :: NF_TcM InstEnv
 485 tcGetInstEnv = tcGetEnv         `thenNF_Tc` \ env ->
 486                returnNF_Tc (tcInsts env)
 487
 488 tcSetInstEnv :: InstEnv -> TcM a -> TcM a
 489 tcSetInstEnv ie thing_inside
 490   = tcGetEnv    `thenNF_Tc` \ env ->
 491     tcSetEnv (env {tcInsts = ie}) thing_inside
 492 \end{code}
 493
 494
 495 %************************************************************************
 496 %*                                                                      *
 497 \subsection{The InstInfo type}
 498 %*                                                                      *
 499 %************************************************************************
 500
 501 The InstInfo type summarises the information in an instance declaration
 502
 503     instance c => k (t tvs) where b
 504
 505 \begin{code}
 506 data InstInfo
 507   = InstInfo {
 508       iDFunId :: DFunId,                -- The dfun id
 509       iBinds  :: RenamedMonoBinds,      -- Bindings, b
 510       iPrags  :: [RenamedSig]           -- User pragmas recorded for generating specialised instances
 511     }
 512
 513 pprInstInfo info = vcat [ptext SLIT("InstInfo:") <+> ppr (idType (iDFunId info)),
 514                          nest 4 (ppr (iBinds info))]
 515
 516 simpleInstInfoTy :: InstInfo -> Type
 517 simpleInstInfoTy info = case splitDFunTy (idType (iDFunId info)) of
 518                           (_, _, _, [ty]) -> ty
 519
 520 simpleInstInfoTyCon :: InstInfo -> TyCon
 521   -- Gets the type constructor for a simple instance declaration,
 522   -- i.e. one of the form       instance (...) => C (T a b c) where ...
 523 simpleInstInfoTyCon inst = tyConAppTyCon (simpleInstInfoTy inst)
 524 \end{code}
 525
 526
 527 %************************************************************************
 528 %*                                                                      *
 529 \subsection{Errors}
 530 %*                                                                      *
 531 %************************************************************************
 532
 533 \begin{code}
 534 badCon con_id = quotes (ppr con_id) <+> ptext SLIT("is not a data constructor")
 535
 536 notFound wheRe name = failWithTc (text wheRe <> colon <+> quotes (ppr name) <+>
 537                                   ptext SLIT("is not in scope"))
 538 \end{code}