ghc/compiler/typecheck/TcEnv.lhs

   1 \begin{code}
   2 module TcEnv(
   3         TcId, TcIdSet,
   4         TyThing(..), TyThingDetails(..), TcTyThing(..),
   5
   6         -- Getting stuff from the environment
   7         TcEnv, initTcEnv,
   8         tcEnvTyCons, tcEnvClasses, tcEnvIds, tcEnvTcIds, tcEnvTyVars,
   9         getTcGEnv,
  10
  11         -- Instance environment, and InstInfo type
  12         tcGetInstEnv, tcSetInstEnv,
  13         InstInfo(..), pprInstInfo,
  14         simpleInstInfoTy, simpleInstInfoTyCon,
  15
  16         -- Global environment
  17         tcExtendGlobalEnv, tcExtendGlobalValEnv,
  18         tcLookupTyCon, tcLookupClass, tcLookupGlobalId, tcLookupDataCon,
  19         tcLookupGlobal_maybe, tcLookupGlobal,
  20
  21         -- Local environment
  22         tcExtendKindEnv,
  23         tcExtendTyVarEnv, tcExtendTyVarEnvForMeths,
  24         tcExtendLocalValEnv, tcLookup,
  25
  26         -- Global type variables
  27         tcGetGlobalTyVars, tcExtendGlobalTyVars,
  28
  29         -- Random useful things
  30         RecTcEnv, tcAddImportedIdInfo, tcLookupRecId, tcInstId,
  31
  32         -- New Ids
  33         newLocalId, newSpecPragmaId,
  34         newDefaultMethodName, newDFunName,
  35
  36         -- Misc
  37         isLocalThing, tcSetEnv
  38   ) where
  39
  40 #include "HsVersions.h"
  41
  42 import RnHsSyn          ( RenamedMonoBinds, RenamedSig )
  43 import TcMonad
  44 import TcType           ( TcKind,  TcType, TcTyVar, TcTyVarSet, TcThetaType,
  45                           tcInstTyVars, zonkTcTyVars,
  46                         )
  47 import Id               ( idName, mkUserLocal, isDataConWrapId_maybe )
  48 import IdInfo           ( vanillaIdInfo )
  49 import MkId             ( mkSpecPragmaId )
  50 import Var              ( TyVar, Id, idType, lazySetIdInfo, idInfo )
  51 import VarSet
  52 import Type             ( Type,
  53                           tyVarsOfTypes, splitDFunTy,
  54                           splitForAllTys, splitRhoTy,
  55                           getDFunTyKey, splitTyConApp_maybe
  56                         )
  57 import DataCon          ( DataCon )
  58 import TyCon            ( TyCon )
  59 import Class            ( Class, ClassOpItem, ClassContext )
  60 import Subst            ( substTy )
  61 import Name             ( Name, OccName, NamedThing(..),
  62                           nameOccName, nameModule, getSrcLoc, mkGlobalName,
  63                           isLocalName, nameModule_maybe,
  64                           NameEnv, lookupNameEnv, nameEnvElts,
  65                           extendNameEnvList, emptyNameEnv
  66                         )
  67 import OccName          ( mkDFunOcc, mkDefaultMethodOcc, occNameString )
  68 import HscTypes         ( DFunId, TypeEnv, HomeSymbolTable, PackageTypeEnv )
  69 import Module           ( Module )
  70 import InstEnv          ( InstEnv, emptyInstEnv )
  71 import HscTypes         ( lookupType, TyThing(..) )
  72 import Util             ( zipEqual )
  73 import SrcLoc           ( SrcLoc )
  74 import Outputable
  75
  76 import IOExts           ( newIORef )
  77 \end{code}
  78
  79 %************************************************************************
  80 %*                                                                      *
  81 \subsection{TcEnv}
  82 %*                                                                      *
  83 %************************************************************************
  84
  85 \begin{code}
  86 type TcId    = Id                       -- Type may be a TcType
  87 type TcIdSet = IdSet
  88
  89 data TcEnv
  90   = TcEnv {
  91         tcGST    :: Name -> Maybe TyThing,      -- The type environment at the moment we began this compilation
  92
  93         tcInsts  :: InstEnv,            -- All instances (both imported and in this module)
  94
  95         tcGEnv   :: TypeEnv,            -- The global type environment we've accumulated while
  96                  {- NameEnv TyThing-}   -- compiling this module:
  97                                         --      types and classes (both imported and local)
  98                                         --      imported Ids
  99                                         -- (Ids defined in this module are in the local envt)
 100
 101         tcLEnv   :: NameEnv TcTyThing,  -- The local type environment: Ids and TyVars
 102                                         -- defined in this module
 103
 104         tcTyVars :: TcRef TcTyVarSet    -- The "global tyvars"
 105                                         -- Namely, the in-scope TyVars bound in tcLEnv, plus the tyvars
 106                                         -- mentioned in the types of Ids bound in tcLEnv
 107                                         -- Why mutable? see notes with tcGetGlobalTyVars
 108     }
 109
 110 \end{code}
 111
 112 The Global-Env/Local-Env story
 113 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 114 During type checking, we keep in the GlobalEnv
 115         * All types and classes
 116         * All Ids derived from types and classes (constructors, selectors)
 117         * Imported Ids
 118
 119 At the end of type checking, we zonk the local bindings,
 120 and as we do so we add to the GlobalEnv
 121         * Locally defined top-level Ids
 122
 123 Why?  Because they are now Ids not TcIds.  This final GlobalEnv is
 124 used thus:
 125         a) fed back (via the knot) to typechecking the
 126            unfoldings of interface signatures
 127
 128         b) used to augment the GlobalSymbolTable
 129
 130
 131 \begin{code}
 132 data TcTyThing
 133   = AGlobal TyThing     -- Used only in the return type of a lookup
 134   | ATcId  TcId         -- Ids defined in this module
 135   | ATyVar TyVar        -- Type variables
 136   | AThing TcKind       -- Used temporarily, during kind checking
 137 -- Here's an example of how the AThing guy is used
 138 -- Suppose we are checking (forall a. T a Int):
 139 --      1. We first bind (a -> AThink kv), where kv is a kind variable.
 140 --      2. Then we kind-check the (T a Int) part.
 141 --      3. Then we zonk the kind variable.
 142 --      4. Now we know the kind for 'a', and we add (a -> ATyVar a::K) to the environment
 143
 144 initTcEnv :: HomeSymbolTable -> PackageTypeEnv -> IO TcEnv
 145 initTcEnv hst pte
 146   = do { gtv_var <- newIORef emptyVarSet ;
 147          return (TcEnv { tcGST    = lookup,
 148                          tcGEnv   = emptyNameEnv,
 149                          tcInsts  = emptyInstEnv,
 150                          tcLEnv   = emptyNameEnv,
 151                          tcTyVars = gtv_var
 152          })}
 153   where
 154     lookup name | isLocalName name = Nothing
 155                 | otherwise        = lookupType hst pte name
 156
 157
 158 tcEnvClasses env = [cl | AClass cl <- nameEnvElts (tcGEnv env)]
 159 tcEnvTyCons  env = [tc | ATyCon tc <- nameEnvElts (tcGEnv env)]
 160 tcEnvIds     env = [id | AnId   id <- nameEnvElts (tcGEnv env)]
 161 tcEnvTyVars  env = [tv | ATyVar tv <- nameEnvElts (tcLEnv env)]
 162 tcEnvTcIds   env = [id | ATcId  id <- nameEnvElts (tcLEnv env)]
 163
 164 getTcGEnv (TcEnv { tcGEnv = genv }) = genv
 165
 166 -- This data type is used to help tie the knot
 167 -- when type checking type and class declarations
 168 data TyThingDetails = SynTyDetails Type
 169                     | DataTyDetails ClassContext [DataCon] [Class]
 170                     | ClassDetails ClassContext [Id] [ClassOpItem] DataCon
 171 \end{code}
 172
 173
 174 %************************************************************************
 175 %*                                                                      *
 176 \subsection{Basic lookups}
 177 %*                                                                      *
 178 %************************************************************************
 179
 180 \begin{code}
 181 lookup_global :: TcEnv -> Name -> Maybe TyThing
 182         -- Try the global envt and then the global symbol table
 183 lookup_global env name
 184   = case lookupNameEnv (tcGEnv env) name of
 185         Just thing -> Just thing
 186         Nothing    -> tcGST env name
 187
 188 lookup_local :: TcEnv -> Name -> Maybe TcTyThing
 189         -- Try the local envt and then try the global
 190 lookup_local env name
 191   = case lookupNameEnv (tcLEnv env) name of
 192         Just thing -> Just thing
 193         Nothing    -> case lookup_global env name of
 194                         Just thing -> Just (AGlobal thing)
 195                         Nothing    -> Nothing
 196 \end{code}
 197
 198 \begin{code}
 199 type RecTcEnv = TcEnv
 200 -- This environment is used for getting the 'right' IdInfo
 201 -- on imported things and for looking up Ids in unfoldings
 202 -- The environment doesn't have any local Ids in it
 203
 204 tcAddImportedIdInfo :: RecTcEnv -> Id -> Id
 205 tcAddImportedIdInfo env id
 206   = id `lazySetIdInfo` new_info
 207         -- The Id must be returned without a data dependency on maybe_id
 208   where
 209     new_info = case tcLookupRecId env (idName id) of
 210                   Nothing          -> vanillaIdInfo
 211                   Just imported_id -> idInfo imported_id
 212                 -- ToDo: could check that types are the same
 213
 214 tcLookupRecId :: RecTcEnv -> Name -> Maybe Id
 215 tcLookupRecId env name = case lookup_global env name of
 216                            Just (AnId id) -> Just id
 217                            other          -> Nothing
 218
 219 \end{code}
 220
 221 %************************************************************************
 222 %*                                                                      *
 223 \subsection{Random useful functions}
 224 %*                                                                      *
 225 %************************************************************************
 226
 227
 228 \begin{code}
 229 -- A useful function that takes an occurrence of a global thing
 230 -- and instantiates its type with fresh type variables
 231 tcInstId :: Id
 232          -> NF_TcM ([TcTyVar],  -- It's instantiated type
 233                       TcThetaType,      --
 234                       TcType)           --
 235 tcInstId id
 236   = let
 237       (tyvars, rho) = splitForAllTys (idType id)
 238     in
 239     tcInstTyVars tyvars         `thenNF_Tc` \ (tyvars', arg_tys, tenv) ->
 240     let
 241         rho'           = substTy tenv rho
 242         (theta', tau') = splitRhoTy rho'
 243     in
 244     returnNF_Tc (tyvars', theta', tau')
 245 \end{code}
 246
 247
 248 %************************************************************************
 249 %*                                                                      *
 250 \subsection{Making new Ids}
 251 %*                                                                      *
 252 %************************************************************************
 253
 254 Constructing new Ids
 255
 256 \begin{code}
 257 newLocalId :: OccName -> TcType -> SrcLoc -> NF_TcM TcId
 258 newLocalId name ty loc
 259   = tcGetUnique         `thenNF_Tc` \ uniq ->
 260     returnNF_Tc (mkUserLocal name uniq ty loc)
 261
 262 newSpecPragmaId :: Name -> TcType -> NF_TcM TcId
 263 newSpecPragmaId name ty
 264   = tcGetUnique         `thenNF_Tc` \ uniq ->
 265     returnNF_Tc (mkSpecPragmaId (nameOccName name) uniq ty (getSrcLoc name))
 266 \end{code}
 267
 268 Make a name for the dict fun for an instance decl
 269
 270 \begin{code}
 271 newDFunName :: Module -> Class -> [Type] -> SrcLoc -> NF_TcM Name
 272 newDFunName mod clas (ty:_) loc
 273   = tcGetDFunUniq dfun_string   `thenNF_Tc` \ inst_uniq ->
 274     tcGetUnique                 `thenNF_Tc` \ uniq ->
 275     returnNF_Tc (mkGlobalName uniq mod
 276                               (mkDFunOcc dfun_string inst_uniq)
 277                               loc)
 278   where
 279         -- Any string that is somewhat unique will do
 280     dfun_string = occNameString (getOccName clas) ++ occNameString (getDFunTyKey ty)
 281
 282 newDFunName mod clas [] loc = pprPanic "newDFunName" (ppr mod <+> ppr clas <+> ppr loc)
 283
 284 newDefaultMethodName :: Name -> SrcLoc -> NF_TcM Name
 285 newDefaultMethodName op_name loc
 286   = tcGetUnique                 `thenNF_Tc` \ uniq ->
 287     returnNF_Tc (mkGlobalName uniq (nameModule op_name)
 288                               (mkDefaultMethodOcc (getOccName op_name))
 289                               loc)
 290 \end{code}
 291
 292 \begin{code}
 293 isLocalThing :: NamedThing a => Module -> a -> Bool
 294   -- True if the thing has a Local name,
 295   -- or a Global name from the specified module
 296 isLocalThing mod thing = case nameModule_maybe (getName thing) of
 297                            Nothing -> True      -- A local name
 298                            Just m  -> m == mod  -- A global thing
 299 \end{code}
 300
 301 %************************************************************************
 302 %*                                                                      *
 303 \subsection{The global environment}
 304 %*                                                                      *
 305 %************************************************************************
 306
 307 \begin{code}
 308 tcExtendGlobalEnv :: [(Name, TyThing)] -> TcM r -> TcM r
 309 tcExtendGlobalEnv bindings thing_inside
 310   = tcGetEnv                            `thenNF_Tc` \ env ->
 311     let
 312         ge' = extendNameEnvList (tcGEnv env) bindings
 313     in
 314     tcSetEnv (env {tcGEnv = ge'}) thing_inside
 315
 316 tcExtendGlobalValEnv :: [Id] -> TcM a -> TcM a
 317 tcExtendGlobalValEnv ids thing_inside
 318   = tcExtendGlobalEnv [(getName id, AnId id) | id <- ids] thing_inside
 319 \end{code}
 320
 321
 322 \begin{code}
 323 tcLookupGlobal_maybe :: Name -> NF_TcM (Maybe TyThing)
 324 tcLookupGlobal_maybe name
 325   = tcGetEnv            `thenNF_Tc` \ env ->
 326     returnNF_Tc (lookup_global env name)
 327 \end{code}
 328
 329 A variety of global lookups, when we know what we are looking for.
 330
 331 \begin{code}
 332 tcLookupGlobal :: Name -> NF_TcM TyThing
 333 tcLookupGlobal name
 334   = tcLookupGlobal_maybe name   `thenNF_Tc` \ maybe_thing ->
 335     case maybe_thing of
 336         Just thing -> returnNF_Tc thing
 337         other      -> notFound "tcLookupGlobal" name
 338
 339 tcLookupGlobalId :: Name -> NF_TcM Id
 340 tcLookupGlobalId name
 341   = tcLookupGlobal_maybe name   `thenNF_Tc` \ maybe_id ->
 342     case maybe_id of
 343         Just (AnId clas) -> returnNF_Tc clas
 344         other            -> notFound "tcLookupGlobalId" name
 345
 346 tcLookupDataCon :: Name -> TcM DataCon
 347 tcLookupDataCon con_name
 348   = tcLookupGlobalId con_name           `thenNF_Tc` \ con_id ->
 349     case isDataConWrapId_maybe con_id of
 350         Just data_con -> returnTc data_con
 351         Nothing       -> failWithTc (badCon con_id)
 352
 353
 354 tcLookupClass :: Name -> NF_TcM Class
 355 tcLookupClass name
 356   = tcLookupGlobal_maybe name   `thenNF_Tc` \ maybe_clas ->
 357     case maybe_clas of
 358         Just (AClass clas) -> returnNF_Tc clas
 359         other              -> notFound "tcLookupClass" name
 360
 361 tcLookupTyCon :: Name -> NF_TcM TyCon
 362 tcLookupTyCon name
 363   = tcLookupGlobal_maybe name   `thenNF_Tc` \ maybe_tc ->
 364     case maybe_tc of
 365         Just (ATyCon tc) -> returnNF_Tc tc
 366         other            -> notFound "tcLookupTyCon" name
 367 \end{code}
 368
 369
 370 %************************************************************************
 371 %*                                                                      *
 372 \subsection{The local environment}
 373 %*                                                                      *
 374 %************************************************************************
 375
 376 \begin{code}
 377 tcLookup_maybe :: Name -> NF_TcM (Maybe TcTyThing)
 378 tcLookup_maybe name
 379   = tcGetEnv            `thenNF_Tc` \ env ->
 380     returnNF_Tc (lookup_local env name)
 381
 382 tcLookup :: Name -> NF_TcM TcTyThing
 383 tcLookup name
 384   = tcLookup_maybe name         `thenNF_Tc` \ maybe_thing ->
 385     case maybe_thing of
 386         Just thing -> returnNF_Tc thing
 387         other      -> notFound "tcLookup" name
 388         -- Extract the IdInfo from an IfaceSig imported from an interface file
 389 \end{code}
 390
 391
 392 \begin{code}
 393 tcExtendKindEnv :: [(Name,TcKind)] -> TcM r -> TcM r
 394 tcExtendKindEnv pairs thing_inside
 395   = tcGetEnv                            `thenNF_Tc` \ env ->
 396     let
 397         le' = extendNameEnvList (tcLEnv env) [(n, AThing k) | (n,k) <- pairs]
 398         -- No need to extend global tyvars for kind checking
 399     in
 400     tcSetEnv (env {tcLEnv = le'}) thing_inside
 401
 402 tcExtendTyVarEnv :: [TyVar] -> TcM r -> TcM r
 403 tcExtendTyVarEnv tyvars thing_inside
 404   = tcGetEnv                    `thenNF_Tc` \ env@(TcEnv {tcLEnv = le, tcTyVars = gtvs}) ->
 405     let
 406         le'        = extendNameEnvList le [ (getName tv, ATyVar tv) | tv <- tyvars]
 407         new_tv_set = mkVarSet tyvars
 408     in
 409         -- It's important to add the in-scope tyvars to the global tyvar set
 410         -- as well.  Consider
 411         --      f (x::r) = let g y = y::r in ...
 412         -- Here, g mustn't be generalised.  This is also important during
 413         -- class and instance decls, when we mustn't generalise the class tyvars
 414         -- when typechecking the methods.
 415     tc_extend_gtvs gtvs new_tv_set              `thenNF_Tc` \ gtvs' ->
 416     tcSetEnv (env {tcLEnv = le', tcTyVars = gtvs'}) thing_inside
 417
 418 -- This variant, tcExtendTyVarEnvForMeths, takes *two* bunches of tyvars:
 419 --      the signature tyvars contain the original names
 420 --      the instance  tyvars are what those names should be mapped to
 421 -- It's needed when typechecking the method bindings of class and instance decls
 422 -- It does *not* extend the global tyvars; tcMethodBind does that for itself
 423
 424 tcExtendTyVarEnvForMeths :: [TyVar] -> [TcTyVar] -> TcM r -> TcM r
 425 tcExtendTyVarEnvForMeths sig_tyvars inst_tyvars thing_inside
 426   = tcGetEnv                                    `thenNF_Tc` \ env ->
 427     let
 428         le'   = extendNameEnvList (tcLEnv env) stuff
 429         stuff = [ (getName sig_tv, ATyVar inst_tv)
 430                 | (sig_tv, inst_tv) <- zipEqual "tcMeth" sig_tyvars inst_tyvars
 431                 ]
 432     in
 433     tcSetEnv (env {tcLEnv = le'}) thing_inside
 434 \end{code}
 435
 436
 437 \begin{code}
 438 tcExtendLocalValEnv :: [(Name,TcId)] -> TcM a -> TcM a
 439 tcExtendLocalValEnv names_w_ids thing_inside
 440   = tcGetEnv            `thenNF_Tc` \ env ->
 441     let
 442         extra_global_tyvars = tyVarsOfTypes [idType id | (name,id) <- names_w_ids]
 443         extra_env           = [(name, ATcId id) | (name,id) <- names_w_ids]
 444         le'                 = extendNameEnvList (tcLEnv env) extra_env
 445     in
 446     tc_extend_gtvs (tcTyVars env) extra_global_tyvars   `thenNF_Tc` \ gtvs' ->
 447     tcSetEnv (env {tcLEnv = le', tcTyVars = gtvs'}) thing_inside
 448 \end{code}
 449
 450
 451 %************************************************************************
 452 %*                                                                      *
 453 \subsection{The global tyvars}
 454 %*                                                                      *
 455 %************************************************************************
 456
 457 \begin{code}
 458 tcExtendGlobalTyVars extra_global_tvs thing_inside
 459   = tcGetEnv                                            `thenNF_Tc` \ env ->
 460     tc_extend_gtvs (tcTyVars env) extra_global_tvs      `thenNF_Tc` \ gtvs' ->
 461     tcSetEnv (env {tcTyVars = gtvs'}) thing_inside
 462
 463 tc_extend_gtvs gtvs extra_global_tvs
 464   = tcReadMutVar gtvs                   `thenNF_Tc` \ global_tvs ->
 465     tcNewMutVar (global_tvs `unionVarSet` extra_global_tvs)
 466 \end{code}
 467
 468 @tcGetGlobalTyVars@ returns a fully-zonked set of tyvars free in the environment.
 469 To improve subsequent calls to the same function it writes the zonked set back into
 470 the environment.
 471
 472 \begin{code}
 473 tcGetGlobalTyVars :: NF_TcM TcTyVarSet
 474 tcGetGlobalTyVars
 475   = tcGetEnv                                    `thenNF_Tc` \ (TcEnv {tcTyVars = gtv_var}) ->
 476     tcReadMutVar gtv_var                        `thenNF_Tc` \ global_tvs ->
 477     zonkTcTyVars (varSetElems global_tvs)       `thenNF_Tc` \ global_tys' ->
 478     let
 479         global_tvs' = (tyVarsOfTypes global_tys')
 480     in
 481     tcWriteMutVar gtv_var global_tvs'           `thenNF_Tc_`
 482     returnNF_Tc global_tvs'
 483 \end{code}
 484
 485
 486 %************************************************************************
 487 %*                                                                      *
 488 \subsection{The instance environment}
 489 %*                                                                      *
 490 %************************************************************************
 491
 492 \begin{code}
 493 tcGetInstEnv :: NF_TcM InstEnv
 494 tcGetInstEnv = tcGetEnv         `thenNF_Tc` \ env ->
 495                returnNF_Tc (tcInsts env)
 496
 497 tcSetInstEnv :: InstEnv -> TcM a -> TcM a
 498 tcSetInstEnv ie thing_inside
 499   = tcGetEnv    `thenNF_Tc` \ env ->
 500     tcSetEnv (env {tcInsts = ie}) thing_inside
 501 \end{code}
 502
 503
 504 %************************************************************************
 505 %*                                                                      *
 506 \subsection{The InstInfo type}
 507 %*                                                                      *
 508 %************************************************************************
 509
 510 The InstInfo type summarises the information in an instance declaration
 511
 512     instance c => k (t tvs) where b
 513
 514 \begin{code}
 515 data InstInfo
 516   = InstInfo {
 517       iLocal  :: Bool,                  -- True <=> it's defined in this module
 518       iDFunId :: DFunId,                -- The dfun id
 519       iBinds  :: RenamedMonoBinds,      -- Bindings, b
 520       iPrags  :: [RenamedSig]           -- User pragmas recorded for generating specialised instances
 521     }
 522
 523 pprInstInfo info = vcat [ptext SLIT("InstInfo:") <+> ppr (idType (iDFunId info)),
 524                          nest 4 (ppr (iBinds info))]
 525
 526 simpleInstInfoTy :: InstInfo -> Type
 527 simpleInstInfoTy info = case splitDFunTy (idType (iDFunId info)) of
 528                           (_, _, _, [ty]) -> ty
 529
 530 simpleInstInfoTyCon :: InstInfo -> TyCon
 531   -- Gets the type constructor for a simple instance declaration,
 532   -- i.e. one of the form       instance (...) => C (T a b c) where ...
 533 simpleInstInfoTyCon inst
 534    = case splitTyConApp_maybe (simpleInstInfoTy inst) of
 535         Just (tycon, _) -> tycon
 536 \end{code}
 537
 538
 539 %************************************************************************
 540 %*                                                                      *
 541 \subsection{Errors}
 542 %*                                                                      *
 543 %************************************************************************
 544
 545 \begin{code}
 546 badCon con_id = quotes (ppr con_id) <+> ptext SLIT("is not a data constructor")
 547
 548 notFound wheRe name = failWithTc (text wheRe <> colon <+> quotes (ppr name) <+>
 549                                   ptext SLIT("is not in scope"))
 550 \end{code}