ghc/compiler/typecheck/TcEnv.lhs

   1 \begin{code}
   2 module TcEnv(
   3         TcId, TcIdSet,
   4         TyThing(..), TyThingDetails(..), TcTyThing(..),
   5
   6         -- Getting stuff from the environment
   7         TcEnv, initTcEnv,
   8         tcEnvTyCons, tcEnvClasses, tcEnvIds, tcEnvTcIds, tcEnvTyVars,
   9         getTcGEnv,
  10
  11         -- Instance environment, and InstInfo type
  12         tcGetInstEnv, tcSetInstEnv,
  13         InstInfo(..), pprInstInfo,
  14         simpleInstInfoTy, simpleInstInfoTyCon,
  15
  16         -- Global environment
  17         tcExtendGlobalEnv, tcExtendGlobalValEnv,
  18         tcLookupTyCon, tcLookupClass, tcLookupGlobalId, tcLookupDataCon,
  19         tcLookupGlobal_maybe, tcLookupGlobal,
  20
  21         -- Local environment
  22         tcExtendKindEnv,
  23         tcExtendTyVarEnv, tcExtendTyVarEnvForMeths,
  24         tcExtendLocalValEnv, tcLookup,
  25
  26         -- Global type variables
  27         tcGetGlobalTyVars, tcExtendGlobalTyVars,
  28
  29         -- Random useful things
  30         tcAddImportedIdInfo, tcInstId,
  31
  32         -- New Ids
  33         newLocalId, newSpecPragmaId,
  34         newDefaultMethodName, newDFunName,
  35
  36         -- Misc
  37         isLocalThing, tcSetEnv, explicitLookupId
  38   ) where
  39
  40 #include "HsVersions.h"
  41
  42 import RnHsSyn          ( RenamedMonoBinds, RenamedSig )
  43 import TcMonad
  44 import TcType           ( TcKind,  TcType, TcTyVar, TcTyVarSet, TcThetaType,
  45                           tcInstTyVars, zonkTcTyVars,
  46                         )
  47 import Id               ( mkUserLocal, isDataConWrapId_maybe )
  48 import IdInfo           ( vanillaIdInfo )
  49 import MkId             ( mkSpecPragmaId )
  50 import Var              ( TyVar, Id, idType, lazySetIdInfo, idInfo )
  51 import VarSet
  52 import Type             ( Type,
  53                           tyVarsOfTypes, splitDFunTy,
  54                           splitForAllTys, splitRhoTy,
  55                           getDFunTyKey, splitTyConApp_maybe
  56                         )
  57 import DataCon          ( DataCon )
  58 import TyCon            ( TyCon )
  59 import Class            ( Class, ClassOpItem, ClassContext )
  60 import Subst            ( substTy )
  61 import Name             ( Name, OccName, NamedThing(..),
  62                           nameOccName, nameModule, getSrcLoc, mkGlobalName,
  63                           isLocalName, nameModule_maybe,
  64                           NameEnv, lookupNameEnv, nameEnvElts,
  65                           extendNameEnvList, emptyNameEnv
  66                         )
  67 import OccName          ( mkDFunOcc, mkDefaultMethodOcc, occNameString )
  68 import HscTypes         ( DFunId, TypeEnv, HomeSymbolTable, PackageTypeEnv )
  69 import Module           ( Module )
  70 import InstEnv          ( InstEnv, emptyInstEnv )
  71 import HscTypes         ( lookupType, TyThing(..) )
  72 import Util             ( zipEqual )
  73 import SrcLoc           ( SrcLoc )
  74 import Outputable
  75
  76 import IOExts           ( newIORef )
  77 \end{code}
  78
  79 %************************************************************************
  80 %*                                                                      *
  81 \subsection{TcEnv}
  82 %*                                                                      *
  83 %************************************************************************
  84
  85 \begin{code}
  86 type TcId    = Id                       -- Type may be a TcType
  87 type TcIdSet = IdSet
  88
  89 data TcEnv
  90   = TcEnv {
  91         tcGST    :: Name -> Maybe TyThing,      -- The type environment at the moment we began this compilation
  92
  93         tcInsts  :: InstEnv,            -- All instances (both imported and in this module)
  94
  95         tcGEnv   :: TypeEnv,            -- The global type environment we've accumulated while
  96                  {- NameEnv TyThing-}   -- compiling this module:
  97                                         --      types and classes (both imported and local)
  98                                         --      imported Ids
  99                                         -- (Ids defined in this module are in the local envt)
 100
 101         tcLEnv   :: NameEnv TcTyThing,  -- The local type environment: Ids and TyVars
 102                                         -- defined in this module
 103
 104         tcTyVars :: TcRef TcTyVarSet    -- The "global tyvars"
 105                                         -- Namely, the in-scope TyVars bound in tcLEnv, plus the tyvars
 106                                         -- mentioned in the types of Ids bound in tcLEnv
 107                                         -- Why mutable? see notes with tcGetGlobalTyVars
 108     }
 109
 110 \end{code}
 111
 112 The Global-Env/Local-Env story
 113 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 114 During type checking, we keep in the GlobalEnv
 115         * All types and classes
 116         * All Ids derived from types and classes (constructors, selectors)
 117         * Imported Ids
 118
 119 At the end of type checking, we zonk the local bindings,
 120 and as we do so we add to the GlobalEnv
 121         * Locally defined top-level Ids
 122
 123 Why?  Because they are now Ids not TcIds.  This final GlobalEnv is
 124 used thus:
 125         a) fed back (via the knot) to typechecking the
 126            unfoldings of interface signatures
 127
 128         b) used to augment the GlobalSymbolTable
 129
 130
 131 \begin{code}
 132 data TcTyThing
 133   = AGlobal TyThing     -- Used only in the return type of a lookup
 134   | ATcId  TcId         -- Ids defined in this module
 135   | ATyVar TyVar        -- Type variables
 136   | AThing TcKind       -- Used temporarily, during kind checking
 137 -- Here's an example of how the AThing guy is used
 138 -- Suppose we are checking (forall a. T a Int):
 139 --      1. We first bind (a -> AThink kv), where kv is a kind variable.
 140 --      2. Then we kind-check the (T a Int) part.
 141 --      3. Then we zonk the kind variable.
 142 --      4. Now we know the kind for 'a', and we add (a -> ATyVar a::K) to the environment
 143
 144 initTcEnv :: HomeSymbolTable -> PackageTypeEnv -> IO TcEnv
 145 initTcEnv hst pte
 146   = do { gtv_var <- newIORef emptyVarSet ;
 147          return (TcEnv { tcGST    = lookup,
 148                          tcGEnv   = emptyNameEnv,
 149                          tcInsts  = emptyInstEnv,
 150                          tcLEnv   = emptyNameEnv,
 151                          tcTyVars = gtv_var
 152          })}
 153   where
 154     lookup name | isLocalName name = Nothing
 155                 | otherwise        = lookupType hst pte name
 156
 157
 158 tcEnvClasses env = [cl | AClass cl <- nameEnvElts (tcGEnv env)]
 159 tcEnvTyCons  env = [tc | ATyCon tc <- nameEnvElts (tcGEnv env)]
 160 tcEnvIds     env = [id | AnId   id <- nameEnvElts (tcGEnv env)]
 161 tcEnvTyVars  env = [tv | ATyVar tv <- nameEnvElts (tcLEnv env)]
 162 tcEnvTcIds   env = [id | ATcId  id <- nameEnvElts (tcLEnv env)]
 163
 164 getTcGEnv (TcEnv { tcGEnv = genv }) = genv
 165
 166 -- This data type is used to help tie the knot
 167 -- when type checking type and class declarations
 168 data TyThingDetails = SynTyDetails Type
 169                     | DataTyDetails ClassContext [DataCon] [Class]
 170                     | ClassDetails ClassContext [Id] [ClassOpItem] DataCon
 171 \end{code}
 172
 173
 174 %************************************************************************
 175 %*                                                                      *
 176 \subsection{Basic lookups}
 177 %*                                                                      *
 178 %************************************************************************
 179
 180 \begin{code}
 181 lookup_global :: TcEnv -> Name -> Maybe TyThing
 182         -- Try the global envt and then the global symbol table
 183 lookup_global env name
 184   = case lookupNameEnv (tcGEnv env) name of
 185         Just thing -> Just thing
 186         Nothing    -> tcGST env name
 187
 188 lookup_local :: TcEnv -> Name -> Maybe TcTyThing
 189         -- Try the local envt and then try the global
 190 lookup_local env name
 191   = case lookupNameEnv (tcLEnv env) name of
 192         Just thing -> Just thing
 193         Nothing    -> case lookup_global env name of
 194                         Just thing -> Just (AGlobal thing)
 195                         Nothing    -> Nothing
 196
 197 explicitLookupId :: TcEnv -> Name -> Maybe Id
 198 explicitLookupId env name = case lookup_global env name of
 199                                 Just (AnId id) -> Just id
 200                                 other          -> Nothing
 201 \end{code}
 202
 203
 204 %************************************************************************
 205 %*                                                                      *
 206 \subsection{Random useful functions}
 207 %*                                                                      *
 208 %************************************************************************
 209
 210
 211 \begin{code}
 212 -- A useful function that takes an occurrence of a global thing
 213 -- and instantiates its type with fresh type variables
 214 tcInstId :: Id
 215          -> NF_TcM ([TcTyVar],  -- It's instantiated type
 216                       TcThetaType,      --
 217                       TcType)           --
 218 tcInstId id
 219   = let
 220       (tyvars, rho) = splitForAllTys (idType id)
 221     in
 222     tcInstTyVars tyvars         `thenNF_Tc` \ (tyvars', arg_tys, tenv) ->
 223     let
 224         rho'           = substTy tenv rho
 225         (theta', tau') = splitRhoTy rho'
 226     in
 227     returnNF_Tc (tyvars', theta', tau')
 228
 229 tcAddImportedIdInfo :: TcEnv -> Id -> Id
 230 tcAddImportedIdInfo unf_env id
 231   | isLocallyDefined id         -- Don't look up locally defined Ids, because they
 232                                 -- have explicit local definitions, so we get a black hole!
 233   = id
 234   | otherwise
 235   = id `lazySetIdInfo` new_info
 236         -- The Id must be returned without a data dependency on maybe_id
 237   where
 238     new_info = case explicitLookupId unf_env (getName id) of
 239                      Nothing          -> vanillaIdInfo
 240                      Just imported_id -> idInfo imported_id
 241                 -- ToDo: could check that types are the same
 242 \end{code}
 243
 244
 245 %************************************************************************
 246 %*                                                                      *
 247 \subsection{Making new Ids}
 248 %*                                                                      *
 249 %************************************************************************
 250
 251 Constructing new Ids
 252
 253 \begin{code}
 254 newLocalId :: OccName -> TcType -> SrcLoc -> NF_TcM TcId
 255 newLocalId name ty loc
 256   = tcGetUnique         `thenNF_Tc` \ uniq ->
 257     returnNF_Tc (mkUserLocal name uniq ty loc)
 258
 259 newSpecPragmaId :: Name -> TcType -> NF_TcM TcId
 260 newSpecPragmaId name ty
 261   = tcGetUnique         `thenNF_Tc` \ uniq ->
 262     returnNF_Tc (mkSpecPragmaId (nameOccName name) uniq ty (getSrcLoc name))
 263 \end{code}
 264
 265 Make a name for the dict fun for an instance decl
 266
 267 \begin{code}
 268 newDFunName :: Module -> Class -> [Type] -> SrcLoc -> NF_TcM Name
 269 newDFunName mod clas (ty:_) loc
 270   = tcGetDFunUniq dfun_string   `thenNF_Tc` \ inst_uniq ->
 271     tcGetUnique                 `thenNF_Tc` \ uniq ->
 272     returnNF_Tc (mkGlobalName uniq mod
 273                               (mkDFunOcc dfun_string inst_uniq)
 274                               loc)
 275   where
 276         -- Any string that is somewhat unique will do
 277     dfun_string = occNameString (getOccName clas) ++ occNameString (getDFunTyKey ty)
 278
 279 newDefaultMethodName :: Name -> SrcLoc -> NF_TcM Name
 280 newDefaultMethodName op_name loc
 281   = tcGetUnique                 `thenNF_Tc` \ uniq ->
 282     returnNF_Tc (mkGlobalName uniq (nameModule op_name)
 283                               (mkDefaultMethodOcc (getOccName op_name))
 284                               loc)
 285 \end{code}
 286
 287 \begin{code}
 288 isLocalThing :: NamedThing a => Module -> a -> Bool
 289   -- True if the thing has a Local name,
 290   -- or a Global name from the specified module
 291 isLocalThing mod thing = case nameModule_maybe (getName thing) of
 292                            Nothing -> True      -- A local name
 293                            Just m  -> m == mod  -- A global thing
 294 \end{code}
 295
 296 %************************************************************************
 297 %*                                                                      *
 298 \subsection{The global environment}
 299 %*                                                                      *
 300 %************************************************************************
 301
 302 \begin{code}
 303 tcExtendGlobalEnv :: [(Name, TyThing)] -> TcM r -> TcM r
 304 tcExtendGlobalEnv bindings thing_inside
 305   = tcGetEnv                            `thenNF_Tc` \ env ->
 306     let
 307         ge' = extendNameEnvList (tcGEnv env) bindings
 308     in
 309     tcSetEnv (env {tcGEnv = ge'}) thing_inside
 310
 311 tcExtendGlobalValEnv :: [Id] -> TcM a -> TcM a
 312 tcExtendGlobalValEnv ids thing_inside
 313   = tcExtendGlobalEnv [(getName id, AnId id) | id <- ids] thing_inside
 314 \end{code}
 315
 316
 317 \begin{code}
 318 tcLookupGlobal_maybe :: Name -> NF_TcM (Maybe TyThing)
 319 tcLookupGlobal_maybe name
 320   = tcGetEnv            `thenNF_Tc` \ env ->
 321     returnNF_Tc (lookup_global env name)
 322 \end{code}
 323
 324 A variety of global lookups, when we know what we are looking for.
 325
 326 \begin{code}
 327 tcLookupGlobal :: Name -> NF_TcM TyThing
 328 tcLookupGlobal name
 329   = tcLookupGlobal_maybe name   `thenNF_Tc` \ maybe_thing ->
 330     case maybe_thing of
 331         Just thing -> returnNF_Tc thing
 332         other      -> notFound "tcLookupGlobal" name
 333
 334 tcLookupGlobalId :: Name -> NF_TcM Id
 335 tcLookupGlobalId name
 336   = tcLookupGlobal_maybe name   `thenNF_Tc` \ maybe_id ->
 337     case maybe_id of
 338         Just (AnId clas) -> returnNF_Tc clas
 339         other            -> notFound "tcLookupGlobalId" name
 340
 341 tcLookupDataCon :: Name -> TcM DataCon
 342 tcLookupDataCon con_name
 343   = tcLookupGlobalId con_name           `thenNF_Tc` \ con_id ->
 344     case isDataConWrapId_maybe con_id of
 345         Just data_con -> returnTc data_con
 346         Nothing       -> failWithTc (badCon con_id)
 347
 348
 349 tcLookupClass :: Name -> NF_TcM Class
 350 tcLookupClass name
 351   = tcLookupGlobal_maybe name   `thenNF_Tc` \ maybe_clas ->
 352     case maybe_clas of
 353         Just (AClass clas) -> returnNF_Tc clas
 354         other              -> notFound "tcLookupClass" name
 355
 356 tcLookupTyCon :: Name -> NF_TcM TyCon
 357 tcLookupTyCon name
 358   = tcLookupGlobal_maybe name   `thenNF_Tc` \ maybe_tc ->
 359     case maybe_tc of
 360         Just (ATyCon tc) -> returnNF_Tc tc
 361         other            -> notFound "tcLookupTyCon" name
 362 \end{code}
 363
 364
 365 %************************************************************************
 366 %*                                                                      *
 367 \subsection{The local environment}
 368 %*                                                                      *
 369 %************************************************************************
 370
 371 \begin{code}
 372 tcLookup_maybe :: Name -> NF_TcM (Maybe TcTyThing)
 373 tcLookup_maybe name
 374   = tcGetEnv            `thenNF_Tc` \ env ->
 375     returnNF_Tc (lookup_local env name)
 376
 377 tcLookup :: Name -> NF_TcM TcTyThing
 378 tcLookup name
 379   = tcLookup_maybe name         `thenNF_Tc` \ maybe_thing ->
 380     case maybe_thing of
 381         Just thing -> returnNF_Tc thing
 382         other      -> notFound "tcLookup" name
 383         -- Extract the IdInfo from an IfaceSig imported from an interface file
 384 \end{code}
 385
 386
 387 \begin{code}
 388 tcExtendKindEnv :: [(Name,TcKind)] -> TcM r -> TcM r
 389 tcExtendKindEnv pairs thing_inside
 390   = tcGetEnv                            `thenNF_Tc` \ env ->
 391     let
 392         le' = extendNameEnvList (tcLEnv env) [(n, AThing k) | (n,k) <- pairs]
 393         -- No need to extend global tyvars for kind checking
 394     in
 395     tcSetEnv (env {tcLEnv = le'}) thing_inside
 396
 397 tcExtendTyVarEnv :: [TyVar] -> TcM r -> TcM r
 398 tcExtendTyVarEnv tyvars thing_inside
 399   = tcGetEnv                    `thenNF_Tc` \ env@(TcEnv {tcLEnv = le, tcTyVars = gtvs}) ->
 400     let
 401         le'        = extendNameEnvList le [ (getName tv, ATyVar tv) | tv <- tyvars]
 402         new_tv_set = mkVarSet tyvars
 403     in
 404         -- It's important to add the in-scope tyvars to the global tyvar set
 405         -- as well.  Consider
 406         --      f (x::r) = let g y = y::r in ...
 407         -- Here, g mustn't be generalised.  This is also important during
 408         -- class and instance decls, when we mustn't generalise the class tyvars
 409         -- when typechecking the methods.
 410     tc_extend_gtvs gtvs new_tv_set              `thenNF_Tc` \ gtvs' ->
 411     tcSetEnv (env {tcLEnv = le', tcTyVars = gtvs'}) thing_inside
 412
 413 -- This variant, tcExtendTyVarEnvForMeths, takes *two* bunches of tyvars:
 414 --      the signature tyvars contain the original names
 415 --      the instance  tyvars are what those names should be mapped to
 416 -- It's needed when typechecking the method bindings of class and instance decls
 417 -- It does *not* extend the global tyvars; tcMethodBind does that for itself
 418
 419 tcExtendTyVarEnvForMeths :: [TyVar] -> [TcTyVar] -> TcM r -> TcM r
 420 tcExtendTyVarEnvForMeths sig_tyvars inst_tyvars thing_inside
 421   = tcGetEnv                                    `thenNF_Tc` \ env ->
 422     let
 423         le'   = extendNameEnvList (tcLEnv env) stuff
 424         stuff = [ (getName sig_tv, ATyVar inst_tv)
 425                 | (sig_tv, inst_tv) <- zipEqual "tcMeth" sig_tyvars inst_tyvars
 426                 ]
 427     in
 428     tcSetEnv (env {tcLEnv = le'}) thing_inside
 429 \end{code}
 430
 431
 432 \begin{code}
 433 tcExtendLocalValEnv :: [(Name,TcId)] -> TcM a -> TcM a
 434 tcExtendLocalValEnv names_w_ids thing_inside
 435   = tcGetEnv            `thenNF_Tc` \ env ->
 436     let
 437         extra_global_tyvars = tyVarsOfTypes [idType id | (name,id) <- names_w_ids]
 438         extra_env           = [(name, ATcId id) | (name,id) <- names_w_ids]
 439         le'                 = extendNameEnvList (tcLEnv env) extra_env
 440     in
 441     tc_extend_gtvs (tcTyVars env) extra_global_tyvars   `thenNF_Tc` \ gtvs' ->
 442     tcSetEnv (env {tcLEnv = le', tcTyVars = gtvs'}) thing_inside
 443 \end{code}
 444
 445
 446 %************************************************************************
 447 %*                                                                      *
 448 \subsection{The global tyvars}
 449 %*                                                                      *
 450 %************************************************************************
 451
 452 \begin{code}
 453 tcExtendGlobalTyVars extra_global_tvs thing_inside
 454   = tcGetEnv                                            `thenNF_Tc` \ env ->
 455     tc_extend_gtvs (tcTyVars env) extra_global_tvs      `thenNF_Tc` \ gtvs' ->
 456     tcSetEnv (env {tcTyVars = gtvs'}) thing_inside
 457
 458 tc_extend_gtvs gtvs extra_global_tvs
 459   = tcReadMutVar gtvs                   `thenNF_Tc` \ global_tvs ->
 460     tcNewMutVar (global_tvs `unionVarSet` extra_global_tvs)
 461 \end{code}
 462
 463 @tcGetGlobalTyVars@ returns a fully-zonked set of tyvars free in the environment.
 464 To improve subsequent calls to the same function it writes the zonked set back into
 465 the environment.
 466
 467 \begin{code}
 468 tcGetGlobalTyVars :: NF_TcM TcTyVarSet
 469 tcGetGlobalTyVars
 470   = tcGetEnv                                    `thenNF_Tc` \ (TcEnv {tcTyVars = gtv_var}) ->
 471     tcReadMutVar gtv_var                        `thenNF_Tc` \ global_tvs ->
 472     zonkTcTyVars (varSetElems global_tvs)       `thenNF_Tc` \ global_tys' ->
 473     let
 474         global_tvs' = (tyVarsOfTypes global_tys')
 475     in
 476     tcWriteMutVar gtv_var global_tvs'           `thenNF_Tc_`
 477     returnNF_Tc global_tvs'
 478 \end{code}
 479
 480
 481 %************************************************************************
 482 %*                                                                      *
 483 \subsection{The instance environment}
 484 %*                                                                      *
 485 %************************************************************************
 486
 487 \begin{code}
 488 tcGetInstEnv :: NF_TcM InstEnv
 489 tcGetInstEnv = tcGetEnv         `thenNF_Tc` \ env ->
 490                returnNF_Tc (tcInsts env)
 491
 492 tcSetInstEnv :: InstEnv -> TcM a -> TcM a
 493 tcSetInstEnv ie thing_inside
 494   = tcGetEnv    `thenNF_Tc` \ env ->
 495     tcSetEnv (env {tcInsts = ie}) thing_inside
 496 \end{code}
 497
 498
 499 %************************************************************************
 500 %*                                                                      *
 501 \subsection{The InstInfo type}
 502 %*                                                                      *
 503 %************************************************************************
 504
 505 The InstInfo type summarises the information in an instance declaration
 506
 507     instance c => k (t tvs) where b
 508
 509 \begin{code}
 510 data InstInfo
 511   = InstInfo {
 512       iLocal  :: Bool,                  -- True <=> it's defined in this module
 513       iDFunId :: DFunId,                -- The dfun id
 514       iBinds  :: RenamedMonoBinds,      -- Bindings, b
 515       iPrags  :: [RenamedSig]           -- User pragmas recorded for generating specialised instances
 516     }
 517
 518 pprInstInfo info = vcat [ptext SLIT("InstInfo:") <+> ppr (idType (iDFunId info)),
 519                          nest 4 (ppr (iBinds info))]
 520
 521 simpleInstInfoTy :: InstInfo -> Type
 522 simpleInstInfoTy info = case splitDFunTy (idType (iDFunId info)) of
 523                           (_, _, _, [ty]) -> ty
 524
 525 simpleInstInfoTyCon :: InstInfo -> TyCon
 526   -- Gets the type constructor for a simple instance declaration,
 527   -- i.e. one of the form       instance (...) => C (T a b c) where ...
 528 simpleInstInfoTyCon inst
 529    = case splitTyConApp_maybe (simpleInstInfoTy inst) of
 530         Just (tycon, _) -> tycon
 531 \end{code}
 532
 533
 534 %************************************************************************
 535 %*                                                                      *
 536 \subsection{Errors}
 537 %*                                                                      *
 538 %************************************************************************
 539
 540 \begin{code}
 541 badCon con_id = quotes (ppr con_id) <+> ptext SLIT("is not a data constructor")
 542
 543 notFound wheRe name = failWithTc (text wheRe <> colon <+> quotes (ppr name) <+>
 544                                   ptext SLIT("is not in scope"))
 545 \end{code}