ghc/compiler/typecheck/TcForeign.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1998
   3 %
   4 \section[TcForeign]{Typechecking \tr{foreign} declarations}
   5
   6 A foreign declaration is used to either give an externally
   7 implemented function a Haskell type (and calling interface) or
   8 give a Haskell function an external calling interface. Either way,
   9 the range of argument and result types these functions can accommodate
  10 is restricted to what the outside world understands (read C), and this
  11 module checks to see if a foreign declaration has got a legal type.
  12
  13 \begin{code}
  14 module TcForeign
  15         (
  16           tcForeignImports
  17         , tcForeignExports
  18         ) where
  19
  20 #include "HsVersions.h"
  21
  22 import HsSyn            ( HsDecl(..), ForeignDecl(..), HsExpr(..),
  23                           MonoBinds(..), ForeignImport(..), ForeignExport(..),
  24                           CImportSpec(..)
  25                         )
  26 import RnHsSyn          ( RenamedHsDecl, RenamedForeignDecl )
  27
  28 import TcMonad
  29 import TcMonoType       ( tcHsSigType, UserTypeCtxt(..) )
  30 import TcHsSyn          ( TcMonoBinds, TypecheckedForeignDecl, TcForeignExportDecl )
  31 import TcExpr           ( tcExpr )
  32 import Inst             ( emptyLIE, LIE, plusLIE )
  33
  34 import ErrUtils         ( Message )
  35 import Id               ( Id, mkLocalId, setIdLocalExported )
  36 import PrimRep          ( getPrimRepSize, isFloatingRep )
  37 import Module           ( Module )
  38 import Type             ( typePrimRep )
  39 import OccName          ( mkForeignExportOcc )
  40 import Name             ( NamedThing(..), mkExternalName )
  41 import TcType           ( Type, tcSplitFunTys, tcSplitTyConApp_maybe,
  42                           tcSplitForAllTys,
  43                           isFFIArgumentTy, isFFIImportResultTy,
  44                           isFFIExportResultTy, isFFILabelTy,
  45                           isFFIExternalTy, isFFIDynArgumentTy,
  46                           isFFIDynResultTy, isForeignPtrTy
  47                         )
  48 import ForeignCall      ( CExportSpec(..), CCallTarget(..), CCallConv(..),
  49                           isDynamicTarget, isCasmTarget )
  50 import CStrings         ( CLabelString, isCLabelString )
  51 import PrelNames        ( hasKey, ioTyConKey )
  52 import CmdLineOpts      ( dopt_HscLang, HscLang(..) )
  53 import Outputable
  54
  55 \end{code}
  56
  57 \begin{code}
  58 -- Defines a binding
  59 isForeignImport :: ForeignDecl name -> Bool
  60 isForeignImport (ForeignImport _ _ _ _ _) = True
  61 isForeignImport _                         = False
  62
  63 -- Exports a binding
  64 isForeignExport :: ForeignDecl name -> Bool
  65 isForeignExport (ForeignExport _ _ _ _ _) = True
  66 isForeignExport _                         = False
  67 \end{code}
  68
  69 %************************************************************************
  70 %*                                                                      *
  71 \subsection{Imports}
  72 %*                                                                      *
  73 %************************************************************************
  74
  75 \begin{code}
  76 tcForeignImports :: [RenamedHsDecl] -> TcM ([Id], [TypecheckedForeignDecl])
  77 tcForeignImports decls =
  78   mapAndUnzipTc tcFImport
  79     [ foreign_decl | ForD foreign_decl <- decls, isForeignImport foreign_decl]
  80
  81 tcFImport :: RenamedForeignDecl -> TcM (Id, TypecheckedForeignDecl)
  82 tcFImport fo@(ForeignImport nm hs_ty imp_decl isDeprec src_loc)
  83  = tcAddSrcLoc src_loc                  $
  84    tcAddErrCtxt (foreignDeclCtxt fo)    $
  85    tcHsSigType (ForSigCtxt nm) hs_ty    `thenTc`        \ sig_ty ->
  86    let
  87       -- drop the foralls before inspecting the structure
  88       -- of the foreign type.
  89         (_, t_ty)         = tcSplitForAllTys sig_ty
  90         (arg_tys, res_ty) = tcSplitFunTys t_ty
  91         id                = mkLocalId nm sig_ty
  92    in
  93    tcCheckFIType sig_ty arg_tys res_ty imp_decl         `thenNF_Tc_`
  94    -- can't use sig_ty here because it :: Type and we need HsType Id
  95    -- hence the undefined
  96    returnTc (id, ForeignImport id undefined imp_decl isDeprec src_loc)
  97 \end{code}
  98
  99
 100 ------------ Checking types for foreign import ----------------------
 101 \begin{code}
 102 tcCheckFIType _ _ _ (DNImport _)
 103   = checkCg checkDotNet
 104
 105 tcCheckFIType sig_ty arg_tys res_ty (CImport _ _ _ _ (CLabel _))
 106   = checkCg checkCOrAsm         `thenNF_Tc_`
 107     check (isFFILabelTy sig_ty) (illegalForeignTyErr empty sig_ty)
 108
 109 tcCheckFIType sig_ty arg_tys res_ty (CImport cconv _ _ _ CWrapper)
 110   =     -- Foreign wrapper (former f.e.d.)
 111         -- The type must be of the form ft -> IO (FunPtr ft), where ft is a
 112         -- valid foreign type.  For legacy reasons ft -> IO (Ptr ft) as well
 113         -- as ft -> IO Addr is accepted, too.  The use of the latter two forms
 114         -- is DEPRECATED, though.
 115     checkCg (if cconv == StdCallConv
 116                 then checkC
 117                 else checkCOrAsmOrInterp)               `thenNF_Tc_`
 118         -- the native code gen can't handle foreign import stdcall "wrapper",
 119         -- because it doesn't emit the '@n' suffix on the label of the
 120         -- C stub function.  Infrastructure changes are required to make this
 121         -- happen; MachLabel will need to carry around information about
 122         -- the arity of the foreign call.
 123     case arg_tys of
 124         [arg1_ty] -> checkForeignArgs isFFIExternalTy arg1_tys                  `thenNF_Tc_`
 125                      checkForeignRes nonIOok  isFFIExportResultTy res1_ty       `thenNF_Tc_`
 126                      checkForeignRes mustBeIO isFFIDynResultTy    res_ty        `thenNF_Tc_`
 127                      checkFEDArgs arg1_tys
 128                   where
 129                      (arg1_tys, res1_ty) = tcSplitFunTys arg1_ty
 130         other -> addErrTc (illegalForeignTyErr empty sig_ty)
 131
 132 tcCheckFIType sig_ty arg_tys res_ty (CImport _ safety _ _ (CFunction target))
 133   | isDynamicTarget target      -- Foreign import dynamic
 134   = checkCg checkCOrAsmOrInterp         `thenNF_Tc_`
 135     case arg_tys of             -- The first arg must be Ptr, FunPtr, or Addr
 136       []                -> check False (illegalForeignTyErr empty sig_ty)
 137       (arg1_ty:arg_tys) -> getDOptsTc                                                   `thenNF_Tc` \ dflags ->
 138                            check (isFFIDynArgumentTy arg1_ty)
 139                                  (illegalForeignTyErr argument arg1_ty)                 `thenNF_Tc_`
 140                            checkForeignArgs (isFFIArgumentTy dflags safety) arg_tys     `thenNF_Tc_`
 141                            checkForeignRes nonIOok (isFFIImportResultTy dflags) res_ty
 142
 143   | otherwise           -- Normal foreign import
 144   = checkCg (if isCasmTarget target
 145              then checkC else checkCOrAsmOrDotNetOrInterp)      `thenNF_Tc_`
 146     checkCTarget target                                         `thenNF_Tc_`
 147     getDOptsTc                                                  `thenNF_Tc` \ dflags ->
 148     checkForeignArgs (isFFIArgumentTy dflags safety) arg_tys    `thenNF_Tc_`
 149     checkForeignRes nonIOok (isFFIImportResultTy dflags) res_ty
 150
 151 -- This makes a convenient place to check
 152 -- that the C identifier is valid for C
 153 checkCTarget (StaticTarget str)
 154   = checkCg checkCOrAsmOrDotNetOrInterp         `thenNF_Tc_`
 155     check (isCLabelString str) (badCName str)
 156
 157 checkCTarget (CasmTarget _)
 158   = checkCg checkC
 159 \end{code}
 160
 161 On an Alpha, with foreign export dynamic, due to a giant hack when
 162 building adjustor thunks, we only allow 4 integer arguments with
 163 foreign export dynamic (i.e., 32 bytes of arguments after padding each
 164 argument to a quadword, excluding floating-point arguments).
 165
 166 The check is needed for both via-C and native-code routes
 167
 168 \begin{code}
 169 #include "nativeGen/NCG.h"
 170 #if alpha_TARGET_ARCH
 171 checkFEDArgs arg_tys
 172   = check (integral_args <= 4) err
 173   where
 174     integral_args = sum (map getPrimRepSize $
 175                          filter (not . isFloatingRep) $
 176                          map typePrimRep arg_tys)
 177     err = ptext SLIT("On Alpha, I can only handle 4 non-floating-point arguments to foreign export dynamic")
 178 #else
 179 checkFEDArgs arg_tys = returnNF_Tc ()
 180 #endif
 181 \end{code}
 182
 183
 184 %************************************************************************
 185 %*                                                                      *
 186 \subsection{Exports}
 187 %*                                                                      *
 188 %************************************************************************
 189
 190 \begin{code}
 191 tcForeignExports :: Module -> [RenamedHsDecl]
 192                  -> TcM (LIE, TcMonoBinds, [TcForeignExportDecl])
 193 tcForeignExports mod decls =
 194    foldlTc combine (emptyLIE, EmptyMonoBinds, [])
 195      [foreign_decl | ForD foreign_decl <- decls, isForeignExport foreign_decl]
 196   where
 197    combine (lie, binds, fs) fe =
 198        tcFExport mod fe `thenTc ` \ (a_lie, b, f) ->
 199        returnTc (lie `plusLIE` a_lie, b `AndMonoBinds` binds, f:fs)
 200
 201 tcFExport :: Module -> RenamedForeignDecl -> TcM (LIE, TcMonoBinds, TcForeignExportDecl)
 202 tcFExport mod fo@(ForeignExport nm hs_ty spec isDeprec src_loc) =
 203    tcAddSrcLoc src_loc                  $
 204    tcAddErrCtxt (foreignDeclCtxt fo)    $
 205
 206    tcHsSigType (ForSigCtxt nm) hs_ty    `thenTc` \ sig_ty ->
 207    tcExpr (HsVar nm) sig_ty             `thenTc` \ (rhs, lie) ->
 208
 209    tcCheckFEType sig_ty spec            `thenTc_`
 210
 211           -- we're exporting a function, but at a type possibly more
 212           -- constrained than its declared/inferred type. Hence the need
 213           -- to create a local binding which will call the exported function
 214           -- at a particular type (and, maybe, overloading).
 215
 216    tcGetUnique                          `thenNF_Tc` \ uniq ->
 217    let
 218         gnm  = mkExternalName uniq mod (mkForeignExportOcc (getOccName nm)) src_loc
 219         id   = setIdLocalExported (mkLocalId gnm sig_ty)
 220         bind = VarMonoBind id rhs
 221    in
 222    returnTc (lie, bind, ForeignExport id undefined spec isDeprec src_loc)
 223 \end{code}
 224
 225 ------------ Checking argument types for foreign export ----------------------
 226
 227 \begin{code}
 228 tcCheckFEType sig_ty (CExport (CExportStatic str _))
 229   = check (isCLabelString str) (badCName str)           `thenNF_Tc_`
 230     checkForeignArgs isFFIExternalTy arg_tys            `thenNF_Tc_`
 231     checkForeignRes nonIOok isFFIExportResultTy res_ty
 232   where
 233       -- Drop the foralls before inspecting n
 234       -- the structure of the foreign type.
 235     (_, t_ty) = tcSplitForAllTys sig_ty
 236     (arg_tys, res_ty) = tcSplitFunTys t_ty
 237 \end{code}
 238
 239
 240
 241 %************************************************************************
 242 %*                                                                      *
 243 \subsection{Miscellaneous}
 244 %*                                                                      *
 245 %************************************************************************
 246
 247 \begin{code}
 248 ------------ Checking argument types for foreign import ----------------------
 249 checkForeignArgs :: (Type -> Bool) -> [Type] -> NF_TcM ()
 250 checkForeignArgs pred tys
 251   = mapNF_Tc go tys             `thenNF_Tc_`
 252     returnNF_Tc ()
 253   where
 254     go ty = check (pred ty) (illegalForeignTyErr argument ty)   `thenNF_Tc_`
 255             warnTc (isForeignPtrTy ty) foreignPtrWarn
 256     --
 257     foreignPtrWarn =
 258       text "`ForeignPtr' as argument type in a foreign import is deprecated"
 259
 260 ------------ Checking result types for foreign calls ----------------------
 261 -- Check that the type has the form
 262 --    (IO t) or (t) , and that t satisfies the given predicate.
 263 --
 264 checkForeignRes :: Bool -> (Type -> Bool) -> Type -> NF_TcM ()
 265
 266 nonIOok  = True
 267 mustBeIO = False
 268
 269 checkForeignRes non_io_result_ok pred_res_ty ty
 270  = case tcSplitTyConApp_maybe ty of
 271       Just (io, [res_ty])
 272         | io `hasKey` ioTyConKey && pred_res_ty res_ty
 273         -> returnNF_Tc ()
 274       _
 275         -> check (non_io_result_ok && pred_res_ty ty)
 276                  (illegalForeignTyErr result ty)
 277 \end{code}
 278
 279 \begin{code}
 280 checkDotNet HscILX = Nothing
 281 checkDotNet other  = Just (text "requires .NET code generation (-filx)")
 282
 283 checkC HscC  = Nothing
 284 checkC other = Just (text "requires C code generation (-fvia-C)")
 285
 286 checkCOrAsm HscC   = Nothing
 287 checkCOrAsm HscAsm = Nothing
 288 checkCOrAsm other
 289    = Just (text "requires via-C or native code generation (-fvia-C)")
 290
 291 checkCOrAsmOrInterp HscC           = Nothing
 292 checkCOrAsmOrInterp HscAsm         = Nothing
 293 checkCOrAsmOrInterp HscInterpreted = Nothing
 294 checkCOrAsmOrInterp other
 295    = Just (text "requires interpreted, C or native code generation")
 296
 297 checkCOrAsmOrDotNet HscC   = Nothing
 298 checkCOrAsmOrDotNet HscAsm = Nothing
 299 checkCOrAsmOrDotNet HscILX = Nothing
 300 checkCOrAsmOrDotNet other
 301    = Just (text "requires C, native or .NET ILX code generation")
 302
 303 checkCOrAsmOrDotNetOrInterp HscC           = Nothing
 304 checkCOrAsmOrDotNetOrInterp HscAsm         = Nothing
 305 checkCOrAsmOrDotNetOrInterp HscILX         = Nothing
 306 checkCOrAsmOrDotNetOrInterp HscInterpreted = Nothing
 307 checkCOrAsmOrDotNetOrInterp other
 308    = Just (text "requires interpreted, C, native or .NET ILX code generation")
 309
 310 checkCg check
 311  = getDOptsTc           `thenNF_Tc` \ dflags ->
 312    let hscLang = dopt_HscLang dflags in
 313    case hscLang of
 314      HscNothing -> returnNF_Tc ()
 315      otherwise  ->
 316        case check hscLang of
 317          Nothing  -> returnNF_Tc ()
 318          Just err -> addErrTc (text "Illegal foreign declaration:" <+> err)
 319 \end{code}
 320
 321 Warnings
 322
 323 \begin{code}
 324 check :: Bool -> Message -> NF_TcM ()
 325 check True _       = returnTc ()
 326 check _    the_err = addErrTc the_err
 327
 328 illegalForeignTyErr arg_or_res ty
 329   = hang (hsep [ptext SLIT("Unacceptable"), arg_or_res,
 330                 ptext SLIT("type in foreign declaration:")])
 331          4 (hsep [ppr ty])
 332
 333 -- Used for 'arg_or_res' argument to illegalForeignTyErr
 334 argument = text "argument"
 335 result   = text "result"
 336
 337 badCName :: CLabelString -> Message
 338 badCName target
 339    = sep [quotes (ppr target) <+> ptext SLIT("is not a valid C identifier")]
 340
 341 foreignDeclCtxt fo
 342   = hang (ptext SLIT("When checking declaration:"))
 343          4 (ppr fo)
 344 \end{code}
 345