ghc/compiler/typecheck/TcModule.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcModule]{Typechecking a whole module}
   5
   6 \begin{code}
   7 module TcModule (
   8         typecheckModule,
   9         TcResults(..)
  10     ) where
  11
  12 #include "HsVersions.h"
  13
  14 import CmdLineOpts      ( DynFlag(..), DynFlags, opt_PprStyle_Debug )
  15 import HsSyn            ( HsBinds(..), MonoBinds(..), HsDecl(..) )
  16 import HsTypes          ( toHsType )
  17 import RnHsSyn          ( RenamedHsDecl )
  18 import TcHsSyn          ( TypecheckedMonoBinds,
  19                           TypecheckedForeignDecl, TypecheckedRuleDecl,
  20                           zonkTopBinds, zonkForeignExports, zonkRules
  21                         )
  22
  23 import TcMonad
  24 import Inst             ( plusLIE )
  25 import TcBinds          ( tcTopBinds )
  26 import TcClassDcl       ( tcClassDecls2, mkImplicitClassBinds )
  27 import TcDefaults       ( tcDefaults )
  28 import TcEnv            ( TcEnv, InstInfo(iDFunId), tcExtendGlobalValEnv,
  29                           tcEnvTyCons, tcEnvClasses,  isLocalThing,
  30                           RecTcEnv, tcSetEnv, tcSetInstEnv, initTcEnv, getTcGEnv
  31                         )
  32 import TcRules          ( tcRules )
  33 import TcForeign        ( tcForeignImports, tcForeignExports )
  34 import TcIfaceSig       ( tcInterfaceSigs )
  35 import TcInstDcls       ( tcInstDecls1, tcInstDecls2 )
  36 import TcSimplify       ( tcSimplifyTop )
  37 import TcTyClsDecls     ( tcTyAndClassDecls )
  38 import TcTyDecls        ( mkImplicitDataBinds )
  39
  40 import CoreUnfold       ( unfoldingTemplate )
  41 import Type             ( funResultTy, splitForAllTys )
  42 import Bag              ( isEmptyBag )
  43 import ErrUtils         ( printErrorsAndWarnings, dumpIfSet_dyn )
  44 import Id               ( idType, idUnfolding )
  45 import Module           ( Module )
  46 import Name             ( Name, isLocallyDefined, toRdrName )
  47 import Name             ( nameEnvElts, lookupNameEnv )
  48 import TyCon            ( tyConGenInfo )
  49 import Maybes           ( thenMaybe )
  50 import Util
  51 import BasicTypes       ( EP(..), Fixity )
  52 import Bag              ( isEmptyBag )
  53 import Outputable
  54 import HscTypes         ( PersistentCompilerState(..), HomeSymbolTable, HomeIfaceTable,
  55                           PackageTypeEnv, DFunId, ModIface(..),
  56                           TypeEnv, extendTypeEnvList, lookupIface,
  57                           TyThing(..), mkTypeEnv )
  58 import List             ( partition )
  59 \end{code}
  60
  61 Outside-world interface:
  62 \begin{code}
  63
  64 -- Convenient type synonyms first:
  65 data TcResults
  66   = TcResults {
  67         tc_pcs     :: PersistentCompilerState,  -- Augmented with imported information,
  68                                                 -- (but not stuff from this module)
  69
  70         -- All these fields have info *just for this module*
  71         tc_env     :: TypeEnv,                  -- The top level TypeEnv
  72         tc_insts   :: [DFunId],                 -- Instances
  73         tc_binds   :: TypecheckedMonoBinds,     -- Bindings
  74         tc_fords   :: [TypecheckedForeignDecl], -- Foreign import & exports.
  75         tc_rules   :: [TypecheckedRuleDecl]     -- Transformation rules
  76     }
  77
  78 ---------------
  79 typecheckModule
  80         :: DynFlags
  81         -> Module
  82         -> PersistentCompilerState
  83         -> HomeSymbolTable -> HomeIfaceTable
  84         -> [RenamedHsDecl]
  85         -> IO (Maybe TcResults)
  86
  87 typecheckModule dflags this_mod pcs hst hit decls
  88   = do  env <- initTcEnv hst (pcs_PTE pcs)
  89
  90         (maybe_result, (warns,errs)) <- initTc dflags env tc_module
  91
  92         let { maybe_tc_result :: Maybe TcResults ;
  93               maybe_tc_result = case maybe_result of
  94                                   Nothing    -> Nothing
  95                                   Just (_,r) -> Just r }
  96
  97         printErrorsAndWarnings (errs,warns)
  98         printTcDump dflags maybe_tc_result
  99
 100         if isEmptyBag errs then
 101              return maybe_tc_result
 102            else
 103              return Nothing
 104   where
 105     tc_module :: TcM (RecTcEnv, TcResults)
 106     tc_module = fixTc (\ ~(unf_env ,_) -> tcModule pcs hst get_fixity this_mod decls unf_env)
 107
 108     pit = pcs_PIT pcs
 109
 110     get_fixity :: Name -> Maybe Fixity
 111     get_fixity nm = lookupIface hit pit this_mod nm     `thenMaybe` \ iface ->
 112                     lookupNameEnv (mi_fixities iface) nm
 113 \end{code}
 114
 115 The internal monster:
 116 \begin{code}
 117 tcModule :: PersistentCompilerState
 118          -> HomeSymbolTable
 119          -> (Name -> Maybe Fixity)
 120          -> Module
 121          -> [RenamedHsDecl]
 122          -> RecTcEnv            -- The knot-tied environment
 123          -> TcM (TcEnv, TcResults)
 124
 125   -- (unf_env :: RecTcEnv) is used for type-checking interface pragmas
 126   -- which is done lazily [ie failure just drops the pragma
 127   -- without having any global-failure effect].
 128   --
 129   -- unf_env is also used to get the pragama info
 130   -- for imported dfuns and default methods
 131
 132 tcModule pcs hst get_fixity this_mod decls unf_env
 133   =              -- Type-check the type and class decls
 134     tcTyAndClassDecls unf_env decls             `thenTc` \ env ->
 135     tcSetEnv env                                $
 136     let
 137         classes = tcEnvClasses env
 138         tycons  = tcEnvTyCons env       -- INCLUDES tycons derived from classes
 139     in
 140
 141         -- Typecheck the instance decls, includes deriving
 142     tcInstDecls1 (pcs_insts pcs) (pcs_PRS pcs)
 143                  hst unf_env get_fixity this_mod
 144                  tycons decls           `thenTc` \ (new_pcs_insts, inst_env, local_inst_info, deriv_binds) ->
 145     tcSetInstEnv inst_env                       $
 146
 147         -- Default declarations
 148     tcDefaults decls                            `thenTc` \ defaulting_tys ->
 149     tcSetDefaultTys defaulting_tys              $
 150
 151     -- Interface type signatures
 152     -- We tie a knot so that the Ids read out of interfaces are in scope
 153     --   when we read their pragmas.
 154     -- What we rely on is that pragmas are typechecked lazily; if
 155     --   any type errors are found (ie there's an inconsistency)
 156     --   we silently discard the pragma
 157     -- We must do this before mkImplicitDataBinds (which comes next), since
 158     -- the latter looks up unpackCStringId, for example, which is usually
 159     -- imported
 160     tcInterfaceSigs unf_env decls               `thenTc` \ sig_ids ->
 161     tcExtendGlobalValEnv sig_ids                $
 162     tcGetEnv                                    `thenTc` \ unf_env ->
 163
 164     -- Create any necessary record selector Ids and their bindings
 165     -- "Necessary" includes data and newtype declarations
 166     -- We don't create bindings for dictionary constructors;
 167     -- they are always fully applied, and the bindings are just there
 168     -- to support partial applications
 169     mkImplicitDataBinds  this_mod tycons        `thenTc`    \ (data_ids, imp_data_binds) ->
 170     mkImplicitClassBinds this_mod classes       `thenNF_Tc` \ (cls_ids,  imp_cls_binds) ->
 171
 172     -- Extend the global value environment with
 173     --  (a) constructors
 174     --  (b) record selectors
 175     --  (c) class op selectors
 176     --  (d) default-method ids... where? I can't see where these are
 177     --      put into the envt, and I'm worried that the zonking phase
 178     --      will find they aren't there and complain.
 179     tcExtendGlobalValEnv data_ids               $
 180     tcExtendGlobalValEnv cls_ids                $
 181
 182         -- Foreign import declarations next
 183     tcForeignImports decls                      `thenTc`    \ (fo_ids, foi_decls) ->
 184     tcExtendGlobalValEnv fo_ids                 $
 185
 186     -- Value declarations next.
 187     -- We also typecheck any extra binds that came out of the "deriving" process
 188     tcTopBinds (get_binds decls `ThenBinds` deriv_binds)        `thenTc` \ ((val_binds, env), lie_valdecls) ->
 189     tcSetEnv env $
 190
 191         -- Foreign export declarations next
 192     tcForeignExports decls              `thenTc`    \ (lie_fodecls, foe_binds, foe_decls) ->
 193
 194         -- Second pass over class and instance declarations,
 195         -- to compile the bindings themselves.
 196     tcInstDecls2  local_inst_info               `thenNF_Tc` \ (lie_instdecls, inst_binds) ->
 197     tcClassDecls2 this_mod decls                `thenNF_Tc` \ (lie_clasdecls, cls_dm_binds) ->
 198     tcRules (pcs_rules pcs) this_mod decls      `thenNF_Tc` \ (new_pcs_rules, lie_rules, local_rules) ->
 199
 200          -- Deal with constant or ambiguous InstIds.  How could
 201          -- there be ambiguous ones?  They can only arise if a
 202          -- top-level decl falls under the monomorphism
 203          -- restriction, and no subsequent decl instantiates its
 204          -- type.  (Usually, ambiguous type variables are resolved
 205          -- during the generalisation step.)
 206     let
 207         lie_alldecls = lie_valdecls     `plusLIE`
 208                    lie_instdecls        `plusLIE`
 209                    lie_clasdecls        `plusLIE`
 210                    lie_fodecls          `plusLIE`
 211                    lie_rules
 212     in
 213     tcSimplifyTop lie_alldecls                  `thenTc` \ const_inst_binds ->
 214
 215         -- Backsubstitution.    This must be done last.
 216         -- Even tcSimplifyTop may do some unification.
 217     let
 218         all_binds = imp_data_binds      `AndMonoBinds`
 219                     imp_cls_binds       `AndMonoBinds`
 220                     val_binds           `AndMonoBinds`
 221                     inst_binds          `AndMonoBinds`
 222                     cls_dm_binds        `AndMonoBinds`
 223                     const_inst_binds    `AndMonoBinds`
 224                     foe_binds
 225     in
 226     zonkTopBinds all_binds              `thenNF_Tc` \ (all_binds', final_env)  ->
 227     tcSetEnv final_env                  $
 228         -- zonkTopBinds puts all the top-level Ids into the tcGEnv
 229     zonkForeignExports foe_decls        `thenNF_Tc` \ foe_decls' ->
 230     zonkRules local_rules               `thenNF_Tc` \ local_rules' ->
 231
 232
 233     let (local_things, imported_things) = partition (isLocalThing this_mod)
 234                                                     (nameEnvElts (getTcGEnv final_env))
 235
 236         local_type_env :: TypeEnv
 237         local_type_env = mkTypeEnv local_things
 238
 239         new_pte :: PackageTypeEnv
 240         new_pte = extendTypeEnvList (pcs_PTE pcs) imported_things
 241
 242         final_pcs :: PersistentCompilerState
 243         final_pcs = pcs { pcs_PTE   = new_pte,
 244                           pcs_insts = new_pcs_insts,
 245                           pcs_rules = new_pcs_rules
 246                     }
 247     in
 248     returnTc (unf_env,
 249               TcResults { tc_pcs     = final_pcs,
 250                           tc_env     = local_type_env,
 251                           tc_binds   = all_binds',
 252                           tc_insts   = map iDFunId local_inst_info,
 253                           tc_fords   = foi_decls ++ foe_decls',
 254                           tc_rules   = local_rules'
 255                         })
 256     )
 257
 258 get_binds decls = foldr ThenBinds EmptyBinds [binds | ValD binds <- decls]
 259 \end{code}
 260
 261
 262
 263 %************************************************************************
 264 %*                                                                      *
 265 \subsection{Dumping output}
 266 %*                                                                      *
 267 %************************************************************************
 268
 269 \begin{code}
 270 printTcDump dflags Nothing = return ()
 271 printTcDump dflags (Just results)
 272   = do dumpIfSet_dyn dflags Opt_D_dump_types
 273                      "Type signatures" (dump_sigs results)
 274        dumpIfSet_dyn dflags Opt_D_dump_tc
 275                      "Typechecked" (dump_tc results)
 276
 277 dump_tc results
 278   = vcat [ppr (tc_binds results),
 279           pp_rules (tc_rules results),
 280           ppr_gen_tycons [tc | ATyCon tc <- nameEnvElts (tc_env results)]
 281     ]
 282
 283 dump_sigs results       -- Print type signatures
 284   =     -- Convert to HsType so that we get source-language style printing
 285         -- And sort by RdrName
 286     vcat $ map ppr_sig $ sortLt lt_sig $
 287     [(toRdrName id, toHsType (idType id))
 288         | AnId id <- nameEnvElts (tc_env results),
 289           want_sig id
 290     ]
 291   where
 292     lt_sig (n1,_) (n2,_) = n1 < n2
 293     ppr_sig (n,t)        = ppr n <+> dcolon <+> ppr t
 294
 295     want_sig id | opt_PprStyle_Debug = True
 296                 | otherwise          = isLocallyDefined id
 297
 298 ppr_gen_tycons tcs = vcat [ptext SLIT("{-# Generic type constructor details"),
 299                            vcat (map ppr_gen_tycon (filter isLocallyDefined tcs)),
 300                            ptext SLIT("#-}")
 301                      ]
 302
 303 -- x&y are now Id's, not CoreExpr's
 304 ppr_gen_tycon tycon
 305   | Just ep <- tyConGenInfo tycon
 306   = (ppr tycon <> colon) $$ nest 4 (ppr_ep ep)
 307
 308   | otherwise = ppr tycon <> colon <+> ptext SLIT("Not derivable")
 309
 310 ppr_ep (EP from to)
 311   = vcat [ ptext SLIT("Rep type:") <+> ppr (funResultTy from_tau),
 312            ptext SLIT("From:") <+> ppr (unfoldingTemplate (idUnfolding from)),
 313            ptext SLIT("To:")   <+> ppr (unfoldingTemplate (idUnfolding to))
 314     ]
 315   where
 316     (_,from_tau) = splitForAllTys (idType from)
 317
 318 pp_rules [] = empty
 319 pp_rules rs = vcat [ptext SLIT("{-# RULES"),
 320                     nest 4 (vcat (map ppr rs)),
 321                     ptext SLIT("#-}")]
 322 \end{code}