ghc/compiler/typecheck/TcModule.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcModule]{Typechecking a whole module}
   5
   6 \begin{code}
   7 module TcModule (
   8         typecheckModule, typecheckExpr, TcResults(..)
   9     ) where
  10
  11 #include "HsVersions.h"
  12
  13 import CmdLineOpts      ( DynFlag(..), DynFlags, opt_PprStyle_Debug )
  14 import HsSyn            ( HsBinds(..), MonoBinds(..), HsDecl(..),
  15                           isIfaceRuleDecl, nullBinds, andMonoBindList
  16                         )
  17 import HsTypes          ( toHsType )
  18 import RnHsSyn          ( RenamedHsBinds, RenamedHsDecl, RenamedHsExpr )
  19 import TcHsSyn          ( TypecheckedMonoBinds, TypecheckedHsExpr,
  20                           TypecheckedForeignDecl, TypecheckedRuleDecl,
  21                           zonkTopBinds, zonkForeignExports, zonkRules, mkHsLet
  22                         )
  23
  24
  25 import TcMonad
  26 import TcType           ( newTyVarTy )
  27 import Inst             ( plusLIE )
  28 import TcBinds          ( tcTopBinds )
  29 import TcClassDcl       ( tcClassDecls2 )
  30 import TcDefaults       ( tcDefaults )
  31 import TcExpr           ( tcMonoExpr )
  32 import TcEnv            ( TcEnv, InstInfo(iDFunId), tcExtendGlobalValEnv,
  33                           isLocalThing, tcSetEnv, tcSetInstEnv, initTcEnv, getTcGEnv
  34                         )
  35 import TcRules          ( tcIfaceRules, tcSourceRules )
  36 import TcForeign        ( tcForeignImports, tcForeignExports )
  37 import TcIfaceSig       ( tcInterfaceSigs )
  38 import TcInstDcls       ( tcInstDecls1, tcInstDecls2 )
  39 import TcSimplify       ( tcSimplifyTop )
  40 import TcTyClsDecls     ( tcTyAndClassDecls )
  41
  42 import CoreUnfold       ( unfoldingTemplate, hasUnfolding )
  43 import Type             ( funResultTy, splitForAllTys, openTypeKind )
  44 import Bag              ( isEmptyBag )
  45 import ErrUtils         ( printErrorsAndWarnings, dumpIfSet_dyn, showPass )
  46 import Id               ( idType, idUnfolding )
  47 import Module           ( Module )
  48 import Name             ( Name, toRdrName )
  49 import Name             ( nameEnvElts, lookupNameEnv )
  50 import TyCon            ( tyConGenInfo )
  51 import Util
  52 import BasicTypes       ( EP(..), Fixity )
  53 import Bag              ( isEmptyBag )
  54 import Outputable
  55 import HscTypes         ( PersistentCompilerState(..), HomeSymbolTable,
  56                           PackageTypeEnv, DFunId, ModIface(..),
  57                           TypeEnv, extendTypeEnvList,
  58                           TyThing(..), implicitTyThingIds,
  59                           mkTypeEnv
  60                         )
  61 \end{code}
  62
  63 Outside-world interface:
  64 \begin{code}
  65
  66 -- Convenient type synonyms first:
  67 data TcResults
  68   = TcResults {
  69         -- All these fields have info *just for this module*
  70         tc_env     :: TypeEnv,                  -- The top level TypeEnv
  71         tc_insts   :: [DFunId],                 -- Instances
  72         tc_binds   :: TypecheckedMonoBinds,     -- Bindings
  73         tc_fords   :: [TypecheckedForeignDecl], -- Foreign import & exports.
  74         tc_rules   :: [TypecheckedRuleDecl]     -- Transformation rules
  75     }
  76
  77 ---------------
  78 typecheckModule
  79         :: DynFlags
  80         -> PersistentCompilerState
  81         -> HomeSymbolTable
  82         -> ModIface             -- Iface for this module
  83         -> PrintUnqualified     -- For error printing
  84         -> [RenamedHsDecl]
  85         -> IO (Maybe (PersistentCompilerState, TcResults))
  86                         -- The new PCS is Augmented with imported information,
  87                                                 -- (but not stuff from this module)
  88
  89
  90 typecheckModule dflags pcs hst mod_iface unqual decls
  91   = do  { maybe_tc_result <- typecheck dflags pcs hst unqual $
  92                              tcModule pcs hst get_fixity this_mod decls
  93         ; printTcDump dflags maybe_tc_result
  94         ; return maybe_tc_result }
  95   where
  96     this_mod   = mi_module   mod_iface
  97     fixity_env = mi_fixities mod_iface
  98
  99     get_fixity :: Name -> Maybe Fixity
 100     get_fixity nm = lookupNameEnv fixity_env nm
 101
 102 ---------------
 103 typecheckExpr :: DynFlags
 104               -> PersistentCompilerState
 105               -> HomeSymbolTable
 106               -> PrintUnqualified       -- For error printing
 107               -> Module
 108               -> (RenamedHsExpr,        -- The expression itself
 109                   [RenamedHsDecl])      -- Plus extra decls it sucked in from interface files
 110               -> IO (Maybe (PersistentCompilerState, TypecheckedHsExpr))
 111
 112 typecheckExpr dflags pcs hst unqual this_mod (expr, decls)
 113   = typecheck dflags pcs hst unqual $
 114
 115     tcImports pcs hst get_fixity this_mod decls `thenTc` \ (env, new_pcs, local_inst_info, deriv_binds, local_rules) ->
 116     ASSERT( null local_inst_info && nullBinds deriv_binds && null local_rules )
 117
 118     tcSetEnv env                                $
 119     newTyVarTy openTypeKind     `thenTc` \ ty ->
 120     tcMonoExpr expr ty          `thenTc` \ (expr', lie) ->
 121     tcSimplifyTop lie           `thenTc` \ binds ->
 122     returnTc (new_pcs, mkHsLet binds expr')
 123   where
 124     get_fixity :: Name -> Maybe Fixity
 125     get_fixity n = pprPanic "typecheckExpr" (ppr n)
 126
 127 ---------------
 128 typecheck :: DynFlags
 129           -> PersistentCompilerState
 130           -> HomeSymbolTable
 131           -> PrintUnqualified   -- For error printing
 132           -> TcM r
 133           -> IO (Maybe r)
 134
 135 typecheck dflags pcs hst unqual thing_inside
 136  = do   { showPass dflags "Typechecker";
 137         ; env <- initTcEnv hst (pcs_PTE pcs)
 138
 139         ; (maybe_tc_result, (warns,errs)) <- initTc dflags env thing_inside
 140
 141         ; printErrorsAndWarnings unqual (errs,warns)
 142
 143         ; if isEmptyBag errs then
 144              return maybe_tc_result
 145            else
 146              return Nothing
 147         }
 148 \end{code}
 149
 150 The internal monster:
 151 \begin{code}
 152 tcModule :: PersistentCompilerState
 153          -> HomeSymbolTable
 154          -> (Name -> Maybe Fixity)
 155          -> Module
 156          -> [RenamedHsDecl]
 157          -> TcM (PersistentCompilerState, TcResults)
 158
 159 tcModule pcs hst get_fixity this_mod decls
 160   =     -- Type-check the type and class decls, and all imported decls
 161     tcImports pcs hst get_fixity this_mod decls `thenTc` \ (env, new_pcs, local_inst_info, deriv_binds, local_rules) ->
 162
 163     tcSetEnv env                                $
 164
 165         -- Foreign import declarations next
 166 --  traceTc (text "Tc4")                        `thenNF_Tc_`
 167     tcForeignImports decls                      `thenTc`    \ (fo_ids, foi_decls) ->
 168     tcExtendGlobalValEnv fo_ids                 $
 169
 170         -- Default declarations
 171     tcDefaults decls                            `thenTc` \ defaulting_tys ->
 172     tcSetDefaultTys defaulting_tys              $
 173
 174         -- Value declarations next.
 175         -- We also typecheck any extra binds that came out of the "deriving" process
 176 --  traceTc (text "Tc5")                                `thenNF_Tc_`
 177     tcTopBinds (val_binds `ThenBinds` deriv_binds)      `thenTc` \ ((val_binds, env), lie_valdecls) ->
 178     tcSetEnv env $
 179
 180         -- Foreign export declarations next
 181 --  traceTc (text "Tc6")                `thenNF_Tc_`
 182     tcForeignExports decls              `thenTc`    \ (lie_fodecls, foe_binds, foe_decls) ->
 183
 184         -- Second pass over class and instance declarations,
 185         -- to compile the bindings themselves.
 186     tcInstDecls2  local_inst_info               `thenNF_Tc` \ (lie_instdecls, inst_binds) ->
 187     tcClassDecls2 this_mod tycl_decls           `thenNF_Tc` \ (lie_clasdecls, cls_dm_binds) ->
 188     tcSourceRules source_rules                  `thenNF_Tc` \ (lie_rules,     more_local_rules) ->
 189
 190          -- Deal with constant or ambiguous InstIds.  How could
 191          -- there be ambiguous ones?  They can only arise if a
 192          -- top-level decl falls under the monomorphism
 193          -- restriction, and no subsequent decl instantiates its
 194          -- type.  (Usually, ambiguous type variables are resolved
 195          -- during the generalisation step.)
 196     let
 197         lie_alldecls = lie_valdecls     `plusLIE`
 198                        lie_instdecls    `plusLIE`
 199                        lie_clasdecls    `plusLIE`
 200                        lie_fodecls      `plusLIE`
 201                        lie_rules
 202     in
 203     tcSimplifyTop lie_alldecls                  `thenTc` \ const_inst_binds ->
 204
 205         -- Backsubstitution.    This must be done last.
 206         -- Even tcSimplifyTop may do some unification.
 207     let
 208         all_binds = val_binds           `AndMonoBinds`
 209                     inst_binds          `AndMonoBinds`
 210                     cls_dm_binds        `AndMonoBinds`
 211                     const_inst_binds    `AndMonoBinds`
 212                     foe_binds
 213     in
 214 --  traceTc (text "Tc9")                `thenNF_Tc_`
 215     zonkTopBinds all_binds              `thenNF_Tc` \ (all_binds', final_env)  ->
 216     tcSetEnv final_env                  $
 217         -- zonkTopBinds puts all the top-level Ids into the tcGEnv
 218     zonkForeignExports foe_decls        `thenNF_Tc` \ foe_decls' ->
 219     zonkRules more_local_rules          `thenNF_Tc` \ more_local_rules' ->
 220
 221
 222     let local_things = filter (isLocalThing this_mod) (nameEnvElts (getTcGEnv final_env))
 223
 224         -- Create any necessary "implicit" bindings (data constructors etc)
 225         -- Should we create bindings for dictionary constructors?
 226         -- They are always fully applied, and the bindings are just there
 227         -- to support partial applications. But it's easier to let them through.
 228         implicit_binds = andMonoBindList [ CoreMonoBind id (unfoldingTemplate unf)
 229                                          | id <- implicitTyThingIds local_things
 230                                          , let unf = idUnfolding id
 231                                          , hasUnfolding unf
 232                                          ]
 233
 234         local_type_env :: TypeEnv
 235         local_type_env = mkTypeEnv local_things
 236
 237         all_local_rules = local_rules ++ more_local_rules'
 238     in
 239 --  traceTc (text "Tc10")               `thenNF_Tc_`
 240     returnTc (new_pcs,
 241               TcResults { tc_env     = local_type_env,
 242                           tc_binds   = implicit_binds `AndMonoBinds` all_binds',
 243                           tc_insts   = map iDFunId local_inst_info,
 244                           tc_fords   = foi_decls ++ foe_decls',
 245                           tc_rules   = all_local_rules
 246                         }
 247     )
 248   where
 249     tycl_decls   = [d | TyClD d <- decls]
 250     val_binds    = foldr ThenBinds EmptyBinds [binds | ValD binds <- decls]
 251     source_rules = [d | RuleD d <- decls, not (isIfaceRuleDecl d)]
 252 \end{code}
 253
 254
 255 \begin{code}
 256 tcImports :: PersistentCompilerState
 257           -> HomeSymbolTable
 258           -> (Name -> Maybe Fixity)
 259           -> Module
 260           -> [RenamedHsDecl]
 261           -> TcM (TcEnv, PersistentCompilerState,
 262                   [InstInfo], RenamedHsBinds, [TypecheckedRuleDecl])
 263
 264 -- tcImports is a slight mis-nomer.
 265 -- It deals with everythign that could be an import:
 266 --      type and class decls
 267 --      interface signatures
 268 --      instance decls
 269 --      rule decls
 270 -- These can occur in source code too, of course
 271
 272 tcImports pcs hst get_fixity this_mod decls
 273   = fixTc (\ ~(unf_env, _, _, _, _) ->
 274           -- (unf_env :: RecTcEnv) is used for type-checking interface pragmas
 275           -- which is done lazily [ie failure just drops the pragma
 276           -- without having any global-failure effect].
 277           --
 278           -- unf_env is also used to get the pragama info
 279           -- for imported dfuns and default methods
 280
 281 --      traceTc (text "Tc1")                    `thenNF_Tc_`
 282         tcTyAndClassDecls unf_env tycl_decls    `thenTc` \ env ->
 283         tcSetEnv env                            $
 284
 285                 -- Typecheck the instance decls, includes deriving
 286 --      traceTc (text "Tc2")    `thenNF_Tc_`
 287         tcInstDecls1 (pcs_insts pcs) (pcs_PRS pcs)
 288                      hst unf_env get_fixity this_mod
 289                      decls                      `thenTc` \ (new_pcs_insts, inst_env, local_inst_info, deriv_binds) ->
 290         tcSetInstEnv inst_env                   $
 291
 292         -- Interface type signatures
 293         -- We tie a knot so that the Ids read out of interfaces are in scope
 294         --   when we read their pragmas.
 295         -- What we rely on is that pragmas are typechecked lazily; if
 296         --   any type errors are found (ie there's an inconsistency)
 297         --   we silently discard the pragma
 298 --      traceTc (text "Tc3")                    `thenNF_Tc_`
 299         tcInterfaceSigs unf_env tycl_decls      `thenTc` \ sig_ids ->
 300         tcExtendGlobalValEnv sig_ids            $
 301
 302
 303         tcIfaceRules (pcs_rules pcs) this_mod iface_rules       `thenNF_Tc` \ (new_pcs_rules, local_rules) ->
 304
 305         tcGetEnv                                                `thenTc` \ unf_env ->
 306         let
 307             imported_things = filter (not . isLocalThing this_mod) (nameEnvElts (getTcGEnv unf_env))
 308
 309             new_pte :: PackageTypeEnv
 310             new_pte = extendTypeEnvList (pcs_PTE pcs) imported_things
 311
 312             new_pcs :: PersistentCompilerState
 313             new_pcs = pcs { pcs_PTE   = new_pte,
 314                             pcs_insts = new_pcs_insts,
 315                             pcs_rules = new_pcs_rules
 316                       }
 317         in
 318         returnTc (unf_env, new_pcs, local_inst_info, deriv_binds, local_rules)
 319     )
 320   where
 321     tycl_decls  = [d | TyClD d <- decls]
 322     iface_rules = [d | RuleD d <- decls, isIfaceRuleDecl d]
 323 \end{code}
 324
 325 %************************************************************************
 326 %*                                                                      *
 327 \subsection{Dumping output}
 328 %*                                                                      *
 329 %************************************************************************
 330
 331 \begin{code}
 332 printTcDump dflags Nothing = return ()
 333 printTcDump dflags (Just (_, results))
 334   = do dumpIfSet_dyn dflags Opt_D_dump_types
 335                      "Type signatures" (dump_sigs results)
 336        dumpIfSet_dyn dflags Opt_D_dump_tc
 337                      "Typechecked" (dump_tc results)
 338
 339 dump_tc results
 340   = vcat [ppr (tc_binds results),
 341           pp_rules (tc_rules results),
 342           ppr_gen_tycons [tc | ATyCon tc <- nameEnvElts (tc_env results)]
 343     ]
 344
 345 dump_sigs results       -- Print type signatures
 346   =     -- Convert to HsType so that we get source-language style printing
 347         -- And sort by RdrName
 348     vcat $ map ppr_sig $ sortLt lt_sig $
 349     [ (toRdrName id, toHsType (idType id))
 350     | AnId id <- nameEnvElts (tc_env results),
 351       want_sig id
 352     ]
 353   where
 354     lt_sig (n1,_) (n2,_) = n1 < n2
 355     ppr_sig (n,t)        = ppr n <+> dcolon <+> ppr t
 356
 357     want_sig id | opt_PprStyle_Debug = True
 358                 | otherwise          = True     -- For now
 359
 360 ppr_gen_tycons tcs = vcat [ptext SLIT("{-# Generic type constructor details"),
 361                            vcat (map ppr_gen_tycon tcs),
 362                            ptext SLIT("#-}")
 363                      ]
 364
 365 -- x&y are now Id's, not CoreExpr's
 366 ppr_gen_tycon tycon
 367   | Just ep <- tyConGenInfo tycon
 368   = (ppr tycon <> colon) $$ nest 4 (ppr_ep ep)
 369
 370   | otherwise = ppr tycon <> colon <+> ptext SLIT("Not derivable")
 371
 372 ppr_ep (EP from to)
 373   = vcat [ ptext SLIT("Rep type:") <+> ppr (funResultTy from_tau),
 374            ptext SLIT("From:") <+> ppr (unfoldingTemplate (idUnfolding from)),
 375            ptext SLIT("To:")   <+> ppr (unfoldingTemplate (idUnfolding to))
 376     ]
 377   where
 378     (_,from_tau) = splitForAllTys (idType from)
 379
 380 pp_rules [] = empty
 381 pp_rules rs = vcat [ptext SLIT("{-# RULES"),
 382                     nest 4 (vcat (map ppr rs)),
 383                     ptext SLIT("#-}")]
 384 \end{code}