ghc/compiler/typecheck/TcModule.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcModule]{Typechecking a whole module}
   5
   6 \begin{code}
   7 module TcModule (
   8         typecheckModule, typecheckExpr, TcResults(..)
   9     ) where
  10
  11 #include "HsVersions.h"
  12
  13 import CmdLineOpts      ( DynFlag(..), DynFlags, opt_PprStyle_Debug )
  14 import HsSyn            ( HsBinds(..), MonoBinds(..), HsDecl(..),
  15                           isIfaceRuleDecl, nullBinds, andMonoBindList
  16                         )
  17 import HsTypes          ( toHsType )
  18 import RnHsSyn          ( RenamedHsBinds, RenamedHsDecl, RenamedHsExpr )
  19 import TcHsSyn          ( TypecheckedMonoBinds, TypecheckedHsExpr,
  20                           TypecheckedForeignDecl, TypecheckedRuleDecl,
  21                           zonkTopBinds, zonkForeignExports, zonkRules, mkHsLet
  22                         )
  23
  24
  25 import TcMonad
  26 import TcType           ( newTyVarTy, zonkTcType )
  27 import Inst             ( plusLIE )
  28 import TcBinds          ( tcTopBinds )
  29 import TcClassDcl       ( tcClassDecls2 )
  30 import TcDefaults       ( tcDefaults, defaultDefaultTys )
  31 import TcExpr           ( tcMonoExpr )
  32 import TcEnv            ( TcEnv, InstInfo(iDFunId), tcExtendGlobalValEnv,
  33                           isLocalThing, tcSetEnv, tcSetInstEnv, initTcEnv, getTcGEnv
  34                         )
  35 import TcRules          ( tcIfaceRules, tcSourceRules )
  36 import TcForeign        ( tcForeignImports, tcForeignExports )
  37 import TcIfaceSig       ( tcInterfaceSigs )
  38 import TcInstDcls       ( tcInstDecls1, tcInstDecls2 )
  39 import TcSimplify       ( tcSimplifyTop )
  40 import TcTyClsDecls     ( tcTyAndClassDecls )
  41
  42 import CoreUnfold       ( unfoldingTemplate, hasUnfolding )
  43 import Type             ( funResultTy, splitForAllTys, openTypeKind )
  44 import Bag              ( isEmptyBag )
  45 import ErrUtils         ( printErrorsAndWarnings, dumpIfSet_dyn, showPass )
  46 import Id               ( idType, idUnfolding )
  47 import Module           ( Module )
  48 import Name             ( Name, toRdrName )
  49 import Name             ( nameEnvElts, lookupNameEnv )
  50 import TyCon            ( tyConGenInfo )
  51 import Util
  52 import BasicTypes       ( EP(..), Fixity )
  53 import Bag              ( isEmptyBag )
  54 import Outputable
  55 import HscTypes         ( PersistentCompilerState(..), HomeSymbolTable,
  56                           PackageTypeEnv, DFunId, ModIface(..),
  57                           TypeEnv, extendTypeEnvList,
  58                           TyThing(..), implicitTyThingIds,
  59                           mkTypeEnv
  60                         )
  61 \end{code}
  62
  63 Outside-world interface:
  64 \begin{code}
  65
  66 -- Convenient type synonyms first:
  67 data TcResults
  68   = TcResults {
  69         -- All these fields have info *just for this module*
  70         tc_env     :: TypeEnv,                  -- The top level TypeEnv
  71         tc_insts   :: [DFunId],                 -- Instances
  72         tc_binds   :: TypecheckedMonoBinds,     -- Bindings
  73         tc_fords   :: [TypecheckedForeignDecl], -- Foreign import & exports.
  74         tc_rules   :: [TypecheckedRuleDecl]     -- Transformation rules
  75     }
  76
  77 ---------------
  78 typecheckModule
  79         :: DynFlags
  80         -> PersistentCompilerState
  81         -> HomeSymbolTable
  82         -> ModIface             -- Iface for this module
  83         -> PrintUnqualified     -- For error printing
  84         -> [RenamedHsDecl]
  85         -> IO (Maybe (PersistentCompilerState, TcResults))
  86                         -- The new PCS is Augmented with imported information,
  87                                                 -- (but not stuff from this module)
  88
  89
  90 typecheckModule dflags pcs hst mod_iface unqual decls
  91   = do  { maybe_tc_result <- typecheck dflags pcs hst unqual $
  92                              tcModule pcs hst get_fixity this_mod decls
  93         ; printTcDump dflags maybe_tc_result
  94         ; return maybe_tc_result }
  95   where
  96     this_mod   = mi_module   mod_iface
  97     fixity_env = mi_fixities mod_iface
  98
  99     get_fixity :: Name -> Maybe Fixity
 100     get_fixity nm = lookupNameEnv fixity_env nm
 101
 102 ---------------
 103 typecheckExpr :: DynFlags
 104               -> PersistentCompilerState
 105               -> HomeSymbolTable
 106               -> PrintUnqualified       -- For error printing
 107               -> Module
 108               -> (RenamedHsExpr,        -- The expression itself
 109                   [RenamedHsDecl])      -- Plus extra decls it sucked in from interface files
 110               -> IO (Maybe (PersistentCompilerState, TypecheckedHsExpr, TcType))
 111
 112 typecheckExpr dflags pcs hst unqual this_mod (expr, decls)
 113   = typecheck dflags pcs hst unqual $
 114
 115          -- use the default default settings, i.e. [Integer, Double]
 116     tcSetDefaultTys defaultDefaultTys $
 117     tcImports pcs hst get_fixity this_mod decls `thenTc` \ (env, new_pcs, local_inst_info, deriv_binds, local_rules) ->
 118     ASSERT( null local_inst_info && nullBinds deriv_binds && null local_rules )
 119
 120     tcSetEnv env                                $
 121     newTyVarTy openTypeKind     `thenTc` \ ty ->
 122     tcMonoExpr expr ty          `thenTc` \ (expr', lie) ->
 123     tcSimplifyTop lie           `thenTc` \ binds ->
 124     zonkTcType ty               `thenNF_Tc` \ zonked_ty ->
 125     returnTc (new_pcs, mkHsLet binds expr', zonked_ty)
 126   where
 127     get_fixity :: Name -> Maybe Fixity
 128     get_fixity n = pprPanic "typecheckExpr" (ppr n)
 129
 130 ---------------
 131 typecheck :: DynFlags
 132           -> PersistentCompilerState
 133           -> HomeSymbolTable
 134           -> PrintUnqualified   -- For error printing
 135           -> TcM r
 136           -> IO (Maybe r)
 137
 138 typecheck dflags pcs hst unqual thing_inside
 139  = do   { showPass dflags "Typechecker";
 140         ; env <- initTcEnv hst (pcs_PTE pcs)
 141
 142         ; (maybe_tc_result, (warns,errs)) <- initTc dflags env thing_inside
 143
 144         ; printErrorsAndWarnings unqual (errs,warns)
 145
 146         ; if isEmptyBag errs then
 147              return maybe_tc_result
 148            else
 149              return Nothing
 150         }
 151 \end{code}
 152
 153 The internal monster:
 154 \begin{code}
 155 tcModule :: PersistentCompilerState
 156          -> HomeSymbolTable
 157          -> (Name -> Maybe Fixity)
 158          -> Module
 159          -> [RenamedHsDecl]
 160          -> TcM (PersistentCompilerState, TcResults)
 161
 162 tcModule pcs hst get_fixity this_mod decls
 163   =     -- Type-check the type and class decls, and all imported decls
 164     tcImports pcs hst get_fixity this_mod decls `thenTc` \ (env, new_pcs, local_inst_info, deriv_binds, local_rules) ->
 165
 166     tcSetEnv env                                $
 167
 168         -- Foreign import declarations next
 169 --  traceTc (text "Tc4")                        `thenNF_Tc_`
 170     tcForeignImports decls                      `thenTc`    \ (fo_ids, foi_decls) ->
 171     tcExtendGlobalValEnv fo_ids                 $
 172
 173         -- Default declarations
 174     tcDefaults decls                            `thenTc` \ defaulting_tys ->
 175     tcSetDefaultTys defaulting_tys              $
 176
 177         -- Value declarations next.
 178         -- We also typecheck any extra binds that came out of the "deriving" process
 179 --  traceTc (text "Tc5")                                `thenNF_Tc_`
 180     tcTopBinds (val_binds `ThenBinds` deriv_binds)      `thenTc` \ ((val_binds, env), lie_valdecls) ->
 181     tcSetEnv env $
 182
 183         -- Foreign export declarations next
 184 --  traceTc (text "Tc6")                `thenNF_Tc_`
 185     tcForeignExports decls              `thenTc`    \ (lie_fodecls, foe_binds, foe_decls) ->
 186
 187         -- Second pass over class and instance declarations,
 188         -- to compile the bindings themselves.
 189     tcInstDecls2  local_inst_info               `thenNF_Tc` \ (lie_instdecls, inst_binds) ->
 190     tcClassDecls2 this_mod tycl_decls           `thenNF_Tc` \ (lie_clasdecls, cls_dm_binds) ->
 191     tcSourceRules source_rules                  `thenNF_Tc` \ (lie_rules,     more_local_rules) ->
 192
 193          -- Deal with constant or ambiguous InstIds.  How could
 194          -- there be ambiguous ones?  They can only arise if a
 195          -- top-level decl falls under the monomorphism
 196          -- restriction, and no subsequent decl instantiates its
 197          -- type.  (Usually, ambiguous type variables are resolved
 198          -- during the generalisation step.)
 199     let
 200         lie_alldecls = lie_valdecls     `plusLIE`
 201                        lie_instdecls    `plusLIE`
 202                        lie_clasdecls    `plusLIE`
 203                        lie_fodecls      `plusLIE`
 204                        lie_rules
 205     in
 206     tcSimplifyTop lie_alldecls                  `thenTc` \ const_inst_binds ->
 207
 208         -- Backsubstitution.    This must be done last.
 209         -- Even tcSimplifyTop may do some unification.
 210     let
 211         all_binds = val_binds           `AndMonoBinds`
 212                     inst_binds          `AndMonoBinds`
 213                     cls_dm_binds        `AndMonoBinds`
 214                     const_inst_binds    `AndMonoBinds`
 215                     foe_binds
 216     in
 217 --  traceTc (text "Tc9")                `thenNF_Tc_`
 218     zonkTopBinds all_binds              `thenNF_Tc` \ (all_binds', final_env)  ->
 219     tcSetEnv final_env                  $
 220         -- zonkTopBinds puts all the top-level Ids into the tcGEnv
 221     zonkForeignExports foe_decls        `thenNF_Tc` \ foe_decls' ->
 222     zonkRules more_local_rules          `thenNF_Tc` \ more_local_rules' ->
 223
 224
 225     let local_things = filter (isLocalThing this_mod) (nameEnvElts (getTcGEnv final_env))
 226
 227         -- Create any necessary "implicit" bindings (data constructors etc)
 228         -- Should we create bindings for dictionary constructors?
 229         -- They are always fully applied, and the bindings are just there
 230         -- to support partial applications. But it's easier to let them through.
 231         implicit_binds = andMonoBindList [ CoreMonoBind id (unfoldingTemplate unf)
 232                                          | id <- implicitTyThingIds local_things
 233                                          , let unf = idUnfolding id
 234                                          , hasUnfolding unf
 235                                          ]
 236
 237         local_type_env :: TypeEnv
 238         local_type_env = mkTypeEnv local_things
 239
 240         all_local_rules = local_rules ++ more_local_rules'
 241     in
 242 --  traceTc (text "Tc10")               `thenNF_Tc_`
 243     returnTc (new_pcs,
 244               TcResults { tc_env     = local_type_env,
 245                           tc_binds   = implicit_binds `AndMonoBinds` all_binds',
 246                           tc_insts   = map iDFunId local_inst_info,
 247                           tc_fords   = foi_decls ++ foe_decls',
 248                           tc_rules   = all_local_rules
 249                         }
 250     )
 251   where
 252     tycl_decls   = [d | TyClD d <- decls]
 253     val_binds    = foldr ThenBinds EmptyBinds [binds | ValD binds <- decls]
 254     source_rules = [d | RuleD d <- decls, not (isIfaceRuleDecl d)]
 255 \end{code}
 256
 257
 258 \begin{code}
 259 tcImports :: PersistentCompilerState
 260           -> HomeSymbolTable
 261           -> (Name -> Maybe Fixity)
 262           -> Module
 263           -> [RenamedHsDecl]
 264           -> TcM (TcEnv, PersistentCompilerState,
 265                   [InstInfo], RenamedHsBinds, [TypecheckedRuleDecl])
 266
 267 -- tcImports is a slight mis-nomer.
 268 -- It deals with everythign that could be an import:
 269 --      type and class decls
 270 --      interface signatures
 271 --      instance decls
 272 --      rule decls
 273 -- These can occur in source code too, of course
 274
 275 tcImports pcs hst get_fixity this_mod decls
 276   = fixTc (\ ~(unf_env, _, _, _, _) ->
 277           -- (unf_env :: RecTcEnv) is used for type-checking interface pragmas
 278           -- which is done lazily [ie failure just drops the pragma
 279           -- without having any global-failure effect].
 280           --
 281           -- unf_env is also used to get the pragama info
 282           -- for imported dfuns and default methods
 283
 284 --      traceTc (text "Tc1")                    `thenNF_Tc_`
 285         tcTyAndClassDecls unf_env tycl_decls    `thenTc` \ env ->
 286         tcSetEnv env                            $
 287
 288                 -- Typecheck the instance decls, includes deriving
 289 --      traceTc (text "Tc2")    `thenNF_Tc_`
 290         tcInstDecls1 (pcs_insts pcs) (pcs_PRS pcs)
 291                      hst unf_env get_fixity this_mod
 292                      decls                      `thenTc` \ (new_pcs_insts, inst_env, local_inst_info, deriv_binds) ->
 293         tcSetInstEnv inst_env                   $
 294
 295         -- Interface type signatures
 296         -- We tie a knot so that the Ids read out of interfaces are in scope
 297         --   when we read their pragmas.
 298         -- What we rely on is that pragmas are typechecked lazily; if
 299         --   any type errors are found (ie there's an inconsistency)
 300         --   we silently discard the pragma
 301 --      traceTc (text "Tc3")                    `thenNF_Tc_`
 302         tcInterfaceSigs unf_env tycl_decls      `thenTc` \ sig_ids ->
 303         tcExtendGlobalValEnv sig_ids            $
 304
 305
 306         tcIfaceRules (pcs_rules pcs) this_mod iface_rules       `thenNF_Tc` \ (new_pcs_rules, local_rules) ->
 307
 308         tcGetEnv                                                `thenTc` \ unf_env ->
 309         let
 310             imported_things = filter (not . isLocalThing this_mod) (nameEnvElts (getTcGEnv unf_env))
 311
 312             new_pte :: PackageTypeEnv
 313             new_pte = extendTypeEnvList (pcs_PTE pcs) imported_things
 314
 315             new_pcs :: PersistentCompilerState
 316             new_pcs = pcs { pcs_PTE   = new_pte,
 317                             pcs_insts = new_pcs_insts,
 318                             pcs_rules = new_pcs_rules
 319                       }
 320         in
 321         returnTc (unf_env, new_pcs, local_inst_info, deriv_binds, local_rules)
 322     )
 323   where
 324     tycl_decls  = [d | TyClD d <- decls]
 325     iface_rules = [d | RuleD d <- decls, isIfaceRuleDecl d]
 326 \end{code}
 327
 328 %************************************************************************
 329 %*                                                                      *
 330 \subsection{Dumping output}
 331 %*                                                                      *
 332 %************************************************************************
 333
 334 \begin{code}
 335 printTcDump dflags Nothing = return ()
 336 printTcDump dflags (Just (_, results))
 337   = do dumpIfSet_dyn dflags Opt_D_dump_types
 338                      "Type signatures" (dump_sigs results)
 339        dumpIfSet_dyn dflags Opt_D_dump_tc
 340                      "Typechecked" (dump_tc results)
 341
 342 dump_tc results
 343   = vcat [ppr (tc_binds results),
 344           pp_rules (tc_rules results),
 345           ppr_gen_tycons [tc | ATyCon tc <- nameEnvElts (tc_env results)]
 346     ]
 347
 348 dump_sigs results       -- Print type signatures
 349   =     -- Convert to HsType so that we get source-language style printing
 350         -- And sort by RdrName
 351     vcat $ map ppr_sig $ sortLt lt_sig $
 352     [ (toRdrName id, toHsType (idType id))
 353     | AnId id <- nameEnvElts (tc_env results),
 354       want_sig id
 355     ]
 356   where
 357     lt_sig (n1,_) (n2,_) = n1 < n2
 358     ppr_sig (n,t)        = ppr n <+> dcolon <+> ppr t
 359
 360     want_sig id | opt_PprStyle_Debug = True
 361                 | otherwise          = True     -- For now
 362
 363 ppr_gen_tycons tcs = vcat [ptext SLIT("{-# Generic type constructor details"),
 364                            vcat (map ppr_gen_tycon tcs),
 365                            ptext SLIT("#-}")
 366                      ]
 367
 368 -- x&y are now Id's, not CoreExpr's
 369 ppr_gen_tycon tycon
 370   | Just ep <- tyConGenInfo tycon
 371   = (ppr tycon <> colon) $$ nest 4 (ppr_ep ep)
 372
 373   | otherwise = ppr tycon <> colon <+> ptext SLIT("Not derivable")
 374
 375 ppr_ep (EP from to)
 376   = vcat [ ptext SLIT("Rep type:") <+> ppr (funResultTy from_tau),
 377            ptext SLIT("From:") <+> ppr (unfoldingTemplate (idUnfolding from)),
 378            ptext SLIT("To:")   <+> ppr (unfoldingTemplate (idUnfolding to))
 379     ]
 380   where
 381     (_,from_tau) = splitForAllTys (idType from)
 382
 383 pp_rules [] = empty
 384 pp_rules rs = vcat [ptext SLIT("{-# RULES"),
 385                     nest 4 (vcat (map ppr rs)),
 386                     ptext SLIT("#-}")]
 387 \end{code}