ghc/compiler/typecheck/TcMonoType.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcMonoType]{Typechecking user-specified @MonoTypes@}
   5
   6 \begin{code}
   7 module TcMonoType ( tcHsType, tcHsRecType,
   8                     tcHsSigType, tcHsBoxedSigType,
   9                     tcRecClassContext, checkAmbiguity,
  10
  11                         -- Kind checking
  12                     kcHsTyVar, kcHsTyVars, mkTyClTyVars,
  13                     kcHsType, kcHsSigType, kcHsBoxedSigType, kcHsContext,
  14                     tcTyVars, tcHsTyVars, mkImmutTyVars,
  15
  16                     TcSigInfo(..), tcTySig, mkTcSig, maybeSig,
  17                     checkSigTyVars, sigCtxt, sigPatCtxt
  18                   ) where
  19
  20 #include "HsVersions.h"
  21
  22 import HsSyn            ( HsType(..), HsTyVarBndr(..),
  23                           Sig(..), HsPred(..), pprParendHsType, HsTupCon(..), hsTyVarNames )
  24 import RnHsSyn          ( RenamedHsType, RenamedHsPred, RenamedContext, RenamedSig )
  25 import TcHsSyn          ( TcId )
  26
  27 import TcMonad
  28 import TcEnv            ( tcExtendTyVarEnv, tcLookup, tcLookupGlobal,
  29                           tcGetGlobalTyVars, tcEnvTcIds, tcEnvTyVars,
  30                           TyThing(..), TcTyThing(..), tcExtendKindEnv
  31                         )
  32 import TcType           ( TcKind, TcTyVar, TcThetaType, TcTauType,
  33                           newKindVar, tcInstSigVar,
  34                           zonkKindEnv, zonkTcType, zonkTcTyVars, zonkTcTyVar
  35                         )
  36 import Inst             ( Inst, InstOrigin(..), newMethodWithGivenTy, instToIdBndr,
  37                           instFunDeps, instFunDepsOfTheta )
  38 import FunDeps          ( tyVarFunDep, oclose )
  39 import TcUnify          ( unifyKind, unifyOpenTypeKind )
  40 import Type             ( Type, Kind, PredType(..), ThetaType,
  41                           mkTyVarTy, mkTyVarTys, mkFunTy, mkSynTy,
  42                           zipFunTys, hoistForAllTys,
  43                           mkSigmaTy, mkPredTy, mkTyConApp,
  44                           mkAppTys, splitForAllTys, splitRhoTy, mkRhoTy,
  45                           boxedTypeKind, unboxedTypeKind, mkArrowKind,
  46                           mkArrowKinds, getTyVar_maybe, getTyVar, splitFunTy_maybe,
  47                           tidyOpenType, tidyOpenTypes, tidyTyVar, tidyTyVars,
  48                           tyVarsOfType, tyVarsOfPred, mkForAllTys,
  49                           classesOfPreds, isUnboxedTupleType, isForAllTy
  50                         )
  51 import PprType          ( pprType, pprPred )
  52 import Subst            ( mkTopTyVarSubst, substTy )
  53 import CoreFVs          ( idFreeTyVars )
  54 import Id               ( mkVanillaId, idName, idType )
  55 import Var              ( Id, Var, TyVar, mkTyVar, tyVarKind )
  56 import VarEnv
  57 import VarSet
  58 import ErrUtils         ( Message )
  59 import TyCon            ( TyCon, isSynTyCon, tyConArity, tyConKind )
  60 import Class            ( ClassContext, classArity, classTyCon )
  61 import Name             ( Name )
  62 import TysWiredIn       ( mkListTy, mkTupleTy, genUnitTyCon )
  63 import UniqFM           ( elemUFM )
  64 import BasicTypes       ( Boxity(..), RecFlag(..), isRec )
  65 import SrcLoc           ( SrcLoc )
  66 import Util             ( mapAccumL, isSingleton )
  67 import Outputable
  68
  69 \end{code}
  70
  71
  72 %************************************************************************
  73 %*                                                                      *
  74 \subsection{Kind checking}
  75 %*                                                                      *
  76 %************************************************************************
  77
  78 Kind checking
  79 ~~~~~~~~~~~~~
  80 When we come across the binding site for some type variables, we
  81 proceed in two stages
  82
  83 1. Figure out what kind each tyvar has
  84
  85 2. Create suitably-kinded tyvars,
  86    extend the envt,
  87    and typecheck the body
  88
  89 To do step 1, we proceed thus:
  90
  91 1a. Bind each type variable to a kind variable
  92 1b. Apply the kind checker
  93 1c. Zonk the resulting kinds
  94
  95 The kind checker is passed to tcHsTyVars as an argument.
  96
  97 For example, when we find
  98         (forall a m. m a -> m a)
  99 we bind a,m to kind varibles and kind-check (m a -> m a).  This
 100 makes a get kind *, and m get kind *->*.  Now we typecheck (m a -> m a)
 101 in an environment that binds a and m suitably.
 102
 103 The kind checker passed to tcHsTyVars needs to look at enough to
 104 establish the kind of the tyvar:
 105   * For a group of type and class decls, it's just the group, not
 106         the rest of the program
 107   * For a tyvar bound in a pattern type signature, its the types
 108         mentioned in the other type signatures in that bunch of patterns
 109   * For a tyvar bound in a RULE, it's the type signatures on other
 110         universally quantified variables in the rule
 111
 112 Note that this may occasionally give surprising results.  For example:
 113
 114         data T a b = MkT (a b)
 115
 116 Here we deduce                  a::*->*, b::*.
 117 But equally valid would be
 118                                 a::(*->*)-> *, b::*->*
 119
 120 \begin{code}
 121 tcHsTyVars :: [HsTyVarBndr Name]
 122            -> TcM a                             -- The kind checker
 123            -> ([TyVar] -> TcM b)
 124            -> TcM b
 125
 126 tcHsTyVars [] kind_check thing_inside = thing_inside []
 127         -- A useful short cut for a common case!
 128
 129 tcHsTyVars tv_names kind_check thing_inside
 130   = kcHsTyVars tv_names                                 `thenNF_Tc` \ tv_names_w_kinds ->
 131     tcExtendKindEnv tv_names_w_kinds kind_check         `thenTc_`
 132     zonkKindEnv tv_names_w_kinds                        `thenNF_Tc` \ tvs_w_kinds ->
 133     let
 134         tyvars = mkImmutTyVars tvs_w_kinds
 135     in
 136     tcExtendTyVarEnv tyvars (thing_inside tyvars)
 137
 138 tcTyVars :: [Name]
 139              -> TcM a                           -- The kind checker
 140              -> TcM [TyVar]
 141 tcTyVars [] kind_check = returnTc []
 142
 143 tcTyVars tv_names kind_check
 144   = mapNF_Tc newNamedKindVar tv_names           `thenTc` \ kind_env ->
 145     tcExtendKindEnv kind_env kind_check         `thenTc_`
 146     zonkKindEnv kind_env                        `thenNF_Tc` \ tvs_w_kinds ->
 147     listNF_Tc [tcNewSigTyVar name kind | (name,kind) <- tvs_w_kinds]
 148 \end{code}
 149
 150
 151 \begin{code}
 152 kcHsTyVar  :: HsTyVarBndr name   -> NF_TcM (name, TcKind)
 153 kcHsTyVars :: [HsTyVarBndr name] -> NF_TcM [(name, TcKind)]
 154
 155 kcHsTyVar (UserTyVar name)       = newNamedKindVar name
 156 kcHsTyVar (IfaceTyVar name kind) = returnNF_Tc (name, kind)
 157
 158 kcHsTyVars tvs = mapNF_Tc kcHsTyVar tvs
 159
 160 newNamedKindVar name = newKindVar       `thenNF_Tc` \ kind ->
 161                        returnNF_Tc (name, kind)
 162
 163 ---------------------------
 164 kcBoxedType :: RenamedHsType -> TcM ()
 165         -- The type ty must be a *boxed* *type*
 166 kcBoxedType ty
 167   = kcHsType ty                         `thenTc` \ kind ->
 168     tcAddErrCtxt (typeKindCtxt ty)      $
 169     unifyKind boxedTypeKind kind
 170
 171 ---------------------------
 172 kcTypeType :: RenamedHsType -> TcM ()
 173         -- The type ty must be a *type*, but it can be boxed or unboxed.
 174 kcTypeType ty
 175   = kcHsType ty                         `thenTc` \ kind ->
 176     tcAddErrCtxt (typeKindCtxt ty)      $
 177     unifyOpenTypeKind kind
 178
 179 ---------------------------
 180 kcHsSigType, kcHsBoxedSigType :: RenamedHsType -> TcM ()
 181         -- Used for type signatures
 182 kcHsSigType      = kcTypeType
 183 kcHsBoxedSigType = kcBoxedType
 184
 185 ---------------------------
 186 kcHsType :: RenamedHsType -> TcM TcKind
 187 kcHsType (HsTyVar name)       = kcTyVar name
 188
 189 kcHsType (HsListTy ty)
 190   = kcBoxedType ty              `thenTc` \ tau_ty ->
 191     returnTc boxedTypeKind
 192
 193 kcHsType (HsTupleTy (HsTupCon _ boxity) tys)
 194   = mapTc kcTypeType tys        `thenTc_`
 195     returnTc (case boxity of
 196                   Boxed   -> boxedTypeKind
 197                   Unboxed -> unboxedTypeKind)
 198
 199 kcHsType (HsFunTy ty1 ty2)
 200   = kcTypeType ty1      `thenTc_`
 201     kcTypeType ty2      `thenTc_`
 202     returnTc boxedTypeKind
 203
 204 kcHsType ty@(HsOpTy ty1 op ty2)
 205   = kcTyVar op                          `thenTc` \ op_kind ->
 206     kcHsType ty1                        `thenTc` \ ty1_kind ->
 207     kcHsType ty2                        `thenTc` \ ty2_kind ->
 208     tcAddErrCtxt (appKindCtxt (ppr ty)) $
 209     kcAppKind op_kind  ty1_kind         `thenTc` \ op_kind' ->
 210     kcAppKind op_kind' ty2_kind
 211
 212 kcHsType (HsPredTy pred)
 213   = kcHsPred pred               `thenTc_`
 214     returnTc boxedTypeKind
 215
 216 kcHsType ty@(HsAppTy ty1 ty2)
 217   = kcHsType ty1                        `thenTc` \ tc_kind ->
 218     kcHsType ty2                        `thenTc` \ arg_kind ->
 219     tcAddErrCtxt (appKindCtxt (ppr ty)) $
 220     kcAppKind tc_kind arg_kind
 221
 222 kcHsType (HsForAllTy (Just tv_names) context ty)
 223   = kcHsTyVars tv_names         `thenNF_Tc` \ kind_env ->
 224     tcExtendKindEnv kind_env    $
 225     kcHsContext context         `thenTc_`
 226     kcHsType ty                 `thenTc_`
 227     returnTc boxedTypeKind
 228
 229 ---------------------------
 230 kcAppKind fun_kind arg_kind
 231   = case splitFunTy_maybe fun_kind of
 232         Just (arg_kind', res_kind)
 233                 -> unifyKind arg_kind arg_kind' `thenTc_`
 234                    returnTc res_kind
 235
 236         Nothing -> newKindVar                                           `thenNF_Tc` \ res_kind ->
 237                    unifyKind fun_kind (mkArrowKind arg_kind res_kind)   `thenTc_`
 238                    returnTc res_kind
 239
 240
 241 ---------------------------
 242 kcHsContext ctxt = mapTc_ kcHsPred ctxt
 243
 244 kcHsPred :: RenamedHsPred -> TcM ()
 245 kcHsPred pred@(HsPIParam name ty)
 246   = tcAddErrCtxt (appKindCtxt (ppr pred))       $
 247     kcBoxedType ty
 248
 249 kcHsPred pred@(HsPClass cls tys)
 250   = tcAddErrCtxt (appKindCtxt (ppr pred))       $
 251     kcClass cls                                 `thenTc` \ kind ->
 252     mapTc kcHsType tys                          `thenTc` \ arg_kinds ->
 253     unifyKind kind (mkArrowKinds arg_kinds boxedTypeKind)
 254
 255  ---------------------------
 256 kcTyVar name    -- Could be a tyvar or a tycon
 257   = tcLookup name       `thenTc` \ thing ->
 258     case thing of
 259         AThing kind         -> returnTc kind
 260         ATyVar tv           -> returnTc (tyVarKind tv)
 261         AGlobal (ATyCon tc) -> returnTc (tyConKind tc)
 262         other               -> failWithTc (wrongThingErr "type" thing name)
 263
 264 kcClass cls     -- Must be a class
 265   = tcLookup cls                                `thenNF_Tc` \ thing ->
 266     case thing of
 267         AThing kind           -> returnTc kind
 268         AGlobal (AClass cls)  -> returnTc (tyConKind (classTyCon cls))
 269         other                 -> failWithTc (wrongThingErr "class" thing cls)
 270 \end{code}
 271
 272 %************************************************************************
 273 %*                                                                      *
 274 \subsection{Checking types}
 275 %*                                                                      *
 276 %************************************************************************
 277
 278 tcHsSigType and tcHsBoxedSigType
 279 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 280
 281 tcHsSigType and tcHsBoxedSigType are used for type signatures written by the programmer
 282
 283   * We hoist any inner for-alls to the top
 284
 285   * Notice that we kind-check first, because the type-check assumes
 286         that the kinds are already checked.
 287
 288   * They are only called when there are no kind vars in the environment
 289         so the kind returned is indeed a Kind not a TcKind
 290
 291 \begin{code}
 292 tcHsSigType, tcHsBoxedSigType :: RenamedHsType -> TcM Type
 293   -- Do kind checking, and hoist for-alls to the top
 294 tcHsSigType      ty = kcTypeType ty  `thenTc_`  tcHsType ty
 295 tcHsBoxedSigType ty = kcBoxedType ty `thenTc_`  tcHsType ty
 296
 297 tcHsType    ::            RenamedHsType -> TcM Type
 298 tcHsRecType :: RecFlag -> RenamedHsType -> TcM Type
 299   -- Don't do kind checking, but do hoist for-alls to the top
 300 tcHsType             ty = tc_type NonRecursive ty  `thenTc` \ ty' ->  returnTc (hoistForAllTys ty')
 301 tcHsRecType wimp_out ty = tc_type wimp_out     ty  `thenTc` \ ty' ->  returnTc (hoistForAllTys ty')
 302 \end{code}
 303
 304
 305 %************************************************************************
 306 %*                                                                      *
 307 \subsection{tc_type}
 308 %*                                                                      *
 309 %************************************************************************
 310
 311 tc_type, the main work horse
 312 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 313
 314         -------------------
 315         *** BIG WARNING ***
 316         -------------------
 317
 318 tc_type is used to typecheck the types in the RHS of data
 319 constructors.  In the case of recursive data types, that means that
 320 the type constructors themselves are (partly) black holes.  e.g.
 321
 322         data T a = MkT a [T a]
 323
 324 While typechecking the [T a] on the RHS, T itself is not yet fully
 325 defined.  That in turn places restrictions on what you can check in
 326 tcHsType; if you poke on too much you get a black hole.  I keep
 327 forgetting this, hence this warning!
 328
 329 The wimp_out argument tells when we are in a mutually-recursive
 330 group of type declarations, so omit various checks else we
 331 get a black hole.  They'll be done again later, in TcTyClDecls.tcGroup.
 332
 333         --------------------------
 334         *** END OF BIG WARNING ***
 335         --------------------------
 336
 337
 338 \begin{code}
 339 tc_type :: RecFlag -> RenamedHsType -> TcM Type
 340
 341 tc_type wimp_out ty@(HsTyVar name)
 342   = tc_app wimp_out ty []
 343
 344 tc_type wimp_out (HsListTy ty)
 345   = tc_arg_type wimp_out ty     `thenTc` \ tau_ty ->
 346     returnTc (mkListTy tau_ty)
 347
 348 tc_type wimp_out (HsTupleTy (HsTupCon _ boxity) tys)
 349   = mapTc tc_tup_arg tys        `thenTc` \ tau_tys ->
 350     returnTc (mkTupleTy boxity (length tys) tau_tys)
 351   where
 352     tc_tup_arg = case boxity of
 353                    Boxed   -> tc_arg_type wimp_out
 354                    Unboxed -> tc_type     wimp_out
 355         -- Unboxed tuples can have polymorphic or unboxed args.
 356         -- This happens in the workers for functions returning
 357         -- product types with polymorphic components
 358
 359 tc_type wimp_out (HsFunTy ty1 ty2)
 360   = tc_type wimp_out ty1                        `thenTc` \ tau_ty1 ->
 361         -- Function argument can be polymorphic, but
 362         -- must not be an unboxed tuple
 363     checkTc (not (isUnboxedTupleType tau_ty1))
 364             (ubxArgTyErr ty1)                   `thenTc_`
 365     tc_type wimp_out ty2                        `thenTc` \ tau_ty2 ->
 366     returnTc (mkFunTy tau_ty1 tau_ty2)
 367
 368 tc_type wimp_out (HsNumTy n)
 369   = ASSERT(n== 1)
 370     returnTc (mkTyConApp genUnitTyCon [])
 371
 372 tc_type wimp_out (HsOpTy ty1 op ty2) =
 373   tc_arg_type wimp_out ty1 `thenTc` \ tau_ty1 ->
 374   tc_arg_type wimp_out ty2 `thenTc` \ tau_ty2 ->
 375   tc_fun_type op [tau_ty1,tau_ty2]
 376
 377 tc_type wimp_out (HsAppTy ty1 ty2)
 378   = tc_app wimp_out ty1 [ty2]
 379
 380 tc_type wimp_out (HsPredTy pred)
 381   = tc_pred wimp_out pred       `thenTc` \ pred' ->
 382     returnTc (mkPredTy pred')
 383
 384 tc_type wimp_out full_ty@(HsForAllTy (Just tv_names) ctxt ty)
 385   = let
 386         kind_check = kcHsContext ctxt `thenTc_` kcHsType ty
 387     in
 388     tcHsTyVars tv_names kind_check                      $ \ tyvars ->
 389     tc_context wimp_out ctxt                            `thenTc` \ theta ->
 390
 391         -- Context behaves like a function type
 392         -- This matters.  Return-unboxed-tuple analysis can
 393         -- give overloaded functions like
 394         --      f :: forall a. Num a => (# a->a, a->a #)
 395         -- And we want these to get through the type checker
 396     (if null theta then
 397         tc_arg_type wimp_out ty
 398      else
 399         tc_type wimp_out ty
 400     )                                                   `thenTc` \ tau ->
 401
 402     checkAmbiguity wimp_out is_source tyvars theta tau
 403   where
 404     is_source = case tv_names of
 405                    (UserTyVar _ : _) -> True
 406                    other             -> False
 407
 408
 409   -- tc_arg_type checks that the argument of a
 410   -- type appplication isn't a for-all type or an unboxed tuple type
 411   -- For example, we want to reject things like:
 412   --
 413   --    instance Ord a => Ord (forall s. T s a)
 414   -- and
 415   --    g :: T s (forall b.b)
 416   --
 417   -- Other unboxed types are very occasionally allowed as type
 418   -- arguments depending on the kind of the type constructor
 419
 420 tc_arg_type wimp_out arg_ty
 421   | isRec wimp_out
 422   = tc_type wimp_out arg_ty
 423
 424   | otherwise
 425   = tc_type wimp_out arg_ty                                             `thenTc` \ arg_ty' ->
 426     checkTc (not (isForAllTy arg_ty'))         (polyArgTyErr arg_ty)    `thenTc_`
 427     checkTc (not (isUnboxedTupleType arg_ty')) (ubxArgTyErr arg_ty)     `thenTc_`
 428     returnTc arg_ty'
 429
 430 tc_arg_types wimp_out arg_tys = mapTc (tc_arg_type wimp_out) arg_tys
 431 \end{code}
 432
 433 Help functions for type applications
 434 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 435
 436 \begin{code}
 437 tc_app :: RecFlag -> RenamedHsType -> [RenamedHsType] -> TcM Type
 438 tc_app wimp_out (HsAppTy ty1 ty2) tys
 439   = tc_app wimp_out ty1 (ty2:tys)
 440
 441 tc_app wimp_out ty tys
 442   = tcAddErrCtxt (appKindCtxt pp_app)   $
 443     tc_arg_types wimp_out tys           `thenTc` \ arg_tys ->
 444     case ty of
 445         HsTyVar fun -> tc_fun_type fun arg_tys
 446         other       -> tc_type wimp_out ty              `thenTc` \ fun_ty ->
 447                        returnNF_Tc (mkAppTys fun_ty arg_tys)
 448   where
 449     pp_app = ppr ty <+> sep (map pprParendHsType tys)
 450
 451 -- (tc_fun_type ty arg_tys) returns (mkAppTys ty arg_tys)
 452 -- But not quite; for synonyms it checks the correct arity, and builds a SynTy
 453 --      hence the rather strange functionality.
 454
 455 tc_fun_type name arg_tys
 456   = tcLookup name                       `thenTc` \ thing ->
 457     case thing of
 458         ATyVar tv -> returnTc (mkAppTys (mkTyVarTy tv) arg_tys)
 459
 460         AGlobal (ATyCon tc)
 461                 | isSynTyCon tc ->  checkTc arity_ok err_msg    `thenTc_`
 462                                     returnTc (mkAppTys (mkSynTy tc (take arity arg_tys))
 463                                                        (drop arity arg_tys))
 464
 465                 | otherwise       ->  returnTc (mkTyConApp tc arg_tys)
 466                 where
 467
 468                     arity_ok = arity <= n_args
 469                     arity = tyConArity tc
 470                         -- It's OK to have an *over-applied* type synonym
 471                         --      data Tree a b = ...
 472                         --      type Foo a = Tree [a]
 473                         --      f :: Foo a b -> ...
 474                     err_msg = arityErr "Type synonym" name arity n_args
 475                     n_args  = length arg_tys
 476
 477         other -> failWithTc (wrongThingErr "type constructor" thing name)
 478 \end{code}
 479
 480
 481 Contexts
 482 ~~~~~~~~
 483 \begin{code}
 484 tcRecClassContext :: RecFlag -> RenamedContext -> TcM ClassContext
 485         -- Used when we are expecting a ClassContext (i.e. no implicit params)
 486 tcRecClassContext wimp_out context
 487   = tc_context wimp_out context         `thenTc` \ theta ->
 488     returnTc (classesOfPreds theta)
 489
 490 tc_context :: RecFlag -> RenamedContext -> TcM ThetaType
 491 tc_context wimp_out context = mapTc (tc_pred wimp_out) context
 492
 493 tc_pred wimp_out assn@(HsPClass class_name tys)
 494   = tcAddErrCtxt (appKindCtxt (ppr assn))       $
 495     tc_arg_types wimp_out tys                   `thenTc` \ arg_tys ->
 496     tcLookupGlobal class_name                   `thenTc` \ thing ->
 497     case thing of
 498         AClass clas -> checkTc (arity == n_tys) err     `thenTc_`
 499                        returnTc (Class clas arg_tys)
 500             where
 501                 arity = classArity clas
 502                 n_tys = length tys
 503                 err   = arityErr "Class" class_name arity n_tys
 504
 505         other -> failWithTc (wrongThingErr "class" (AGlobal thing) class_name)
 506
 507 tc_pred wimp_out assn@(HsPIParam name ty)
 508   = tcAddErrCtxt (appKindCtxt (ppr assn))       $
 509     tc_arg_type wimp_out ty                     `thenTc` \ arg_ty ->
 510     returnTc (IParam name arg_ty)
 511 \end{code}
 512
 513
 514 Check for ambiguity
 515 ~~~~~~~~~~~~~~~~~~~
 516           forall V. P => tau
 517 is ambiguous if P contains generic variables
 518 (i.e. one of the Vs) that are not mentioned in tau
 519
 520 However, we need to take account of functional dependencies
 521 when we speak of 'mentioned in tau'.  Example:
 522         class C a b | a -> b where ...
 523 Then the type
 524         forall x y. (C x y) => x
 525 is not ambiguous because x is mentioned and x determines y
 526
 527 NOTE: In addition, GHC insists that at least one type variable
 528 in each constraint is in V.  So we disallow a type like
 529         forall a. Eq b => b -> b
 530 even in a scope where b is in scope.
 531 This is the is_free test below.
 532
 533 Notes on the 'is_source_polytype' test above
 534 Check ambiguity only for source-program types, not
 535 for types coming from inteface files.  The latter can
 536 legitimately have ambiguous types. Example
 537    class S a where s :: a -> (Int,Int)
 538    instance S Char where s _ = (1,1)
 539    f:: S a => [a] -> Int -> (Int,Int)
 540    f (_::[a]) x = (a*x,b)
 541         where (a,b) = s (undefined::a)
 542 Here the worker for f gets the type
 543         fw :: forall a. S a => Int -> (# Int, Int #)
 544
 545 If the list of tv_names is empty, we have a monotype,
 546 and then we don't need to check for ambiguity either,
 547 because the test can't fail (see is_ambig).
 548
 549 \begin{code}
 550 checkAmbiguity wimp_out is_source_polytype forall_tyvars theta tau
 551   | isRec wimp_out = returnTc sigma_ty
 552   | otherwise      = mapTc_ check_pred theta    `thenTc_`
 553                      returnTc sigma_ty
 554   where
 555     sigma_ty          = mkSigmaTy forall_tyvars theta tau
 556     tau_vars          = tyVarsOfType tau
 557     fds               = instFunDepsOfTheta theta
 558     tvFundep          = tyVarFunDep fds
 559     extended_tau_vars = oclose tvFundep tau_vars
 560
 561     is_ambig ct_var   = (ct_var `elem` forall_tyvars) &&
 562                         not (ct_var `elemUFM` extended_tau_vars)
 563     is_free ct_var    = not (ct_var `elem` forall_tyvars)
 564
 565     check_pred pred = checkTc (not any_ambig)              (ambigErr pred sigma_ty) `thenTc_`
 566                       checkTc (is_ip pred || not all_free) (freeErr  pred sigma_ty)
 567              where
 568                 ct_vars   = varSetElems (tyVarsOfPred pred)
 569                 all_free  = all is_free ct_vars
 570                 any_ambig = is_source_polytype && any is_ambig ct_vars
 571                 is_ip (IParam _ _) = True
 572                 is_ip _            = False
 573 \end{code}
 574
 575 %************************************************************************
 576 %*                                                                      *
 577 \subsection{Type variables, with knot tying!}
 578 %*                                                                      *
 579 %************************************************************************
 580
 581 \begin{code}
 582 mkImmutTyVars :: [(Name,Kind)] -> [TyVar]
 583 mkImmutTyVars pairs = [mkTyVar name kind | (name, kind) <- pairs]
 584
 585 mkTyClTyVars :: Kind                    -- Kind of the tycon or class
 586              -> [HsTyVarBndr Name]
 587              -> [TyVar]
 588 mkTyClTyVars kind tyvar_names
 589   = mkImmutTyVars tyvars_w_kinds
 590   where
 591     (tyvars_w_kinds, _) = zipFunTys (hsTyVarNames tyvar_names) kind
 592 \end{code}
 593
 594
 595 %************************************************************************
 596 %*                                                                      *
 597 \subsection{Signatures}
 598 %*                                                                      *
 599 %************************************************************************
 600
 601 @tcSigs@ checks the signatures for validity, and returns a list of
 602 {\em freshly-instantiated} signatures.  That is, the types are already
 603 split up, and have fresh type variables installed.  All non-type-signature
 604 "RenamedSigs" are ignored.
 605
 606 The @TcSigInfo@ contains @TcTypes@ because they are unified with
 607 the variable's type, and after that checked to see whether they've
 608 been instantiated.
 609
 610 \begin{code}
 611 data TcSigInfo
 612   = TySigInfo
 613         Name                    -- N, the Name in corresponding binding
 614
 615         TcId                    -- *Polymorphic* binder for this value...
 616                                 -- Has name = N
 617
 618         [TcTyVar]               -- tyvars
 619         TcThetaType             -- theta
 620         TcTauType               -- tau
 621
 622         TcId                    -- *Monomorphic* binder for this value
 623                                 -- Does *not* have name = N
 624                                 -- Has type tau
 625
 626         [Inst]                  -- Empty if theta is null, or
 627                                 -- (method mono_id) otherwise
 628
 629         SrcLoc                  -- Of the signature
 630
 631 instance Outputable TcSigInfo where
 632     ppr (TySigInfo nm id tyvars theta tau _ inst loc) =
 633         ppr nm <+> ptext SLIT("::") <+> ppr tyvars <+> ppr theta <+> ptext SLIT("=>") <+> ppr tau
 634
 635 maybeSig :: [TcSigInfo] -> Name -> Maybe (TcSigInfo)
 636         -- Search for a particular signature
 637 maybeSig [] name = Nothing
 638 maybeSig (sig@(TySigInfo sig_name _ _ _ _ _ _ _) : sigs) name
 639   | name == sig_name = Just sig
 640   | otherwise        = maybeSig sigs name
 641 \end{code}
 642
 643
 644 \begin{code}
 645 tcTySig :: RenamedSig -> TcM TcSigInfo
 646
 647 tcTySig (Sig v ty src_loc)
 648  = tcAddSrcLoc src_loc                          $
 649    tcAddErrCtxt (tcsigCtxt v)                   $
 650    tcHsSigType ty                               `thenTc` \ sigma_tc_ty ->
 651    mkTcSig (mkVanillaId v sigma_tc_ty) src_loc  `thenNF_Tc` \ sig ->
 652    returnTc sig
 653
 654 mkTcSig :: TcId -> SrcLoc -> NF_TcM TcSigInfo
 655 mkTcSig poly_id src_loc
 656   =     -- Instantiate this type
 657         -- It's important to do this even though in the error-free case
 658         -- we could just split the sigma_tc_ty (since the tyvars don't
 659         -- unified with anything).  But in the case of an error, when
 660         -- the tyvars *do* get unified with something, we want to carry on
 661         -- typechecking the rest of the program with the function bound
 662         -- to a pristine type, namely sigma_tc_ty
 663    let
 664         (tyvars, rho) = splitForAllTys (idType poly_id)
 665    in
 666    mapNF_Tc tcInstSigVar tyvars         `thenNF_Tc` \ tyvars' ->
 667         -- Make *signature* type variables
 668
 669    let
 670      tyvar_tys' = mkTyVarTys tyvars'
 671      rho' = substTy (mkTopTyVarSubst tyvars tyvar_tys') rho
 672         -- mkTopTyVarSubst because the tyvars' are fresh
 673      (theta', tau') = splitRhoTy rho'
 674         -- This splitRhoTy tries hard to make sure that tau' is a type synonym
 675         -- wherever possible, which can improve interface files.
 676    in
 677    newMethodWithGivenTy SignatureOrigin
 678                 poly_id
 679                 tyvar_tys'
 680                 theta' tau'                     `thenNF_Tc` \ inst ->
 681         -- We make a Method even if it's not overloaded; no harm
 682    instFunDeps SignatureOrigin theta'           `thenNF_Tc` \ fds ->
 683
 684    returnNF_Tc (TySigInfo name poly_id tyvars' theta' tau' (instToIdBndr inst) (inst : fds) src_loc)
 685   where
 686     name = idName poly_id
 687 \end{code}
 688
 689
 690
 691 %************************************************************************
 692 %*                                                                      *
 693 \subsection{Checking signature type variables}
 694 %*                                                                      *
 695 %************************************************************************
 696
 697 @checkSigTyVars@ is used after the type in a type signature has been unified with
 698 the actual type found.  It then checks that the type variables of the type signature
 699 are
 700         (a) Still all type variables
 701                 eg matching signature [a] against inferred type [(p,q)]
 702                 [then a will be unified to a non-type variable]
 703
 704         (b) Still all distinct
 705                 eg matching signature [(a,b)] against inferred type [(p,p)]
 706                 [then a and b will be unified together]
 707
 708         (c) Not mentioned in the environment
 709                 eg the signature for f in this:
 710
 711                         g x = ... where
 712                                         f :: a->[a]
 713                                         f y = [x,y]
 714
 715                 Here, f is forced to be monorphic by the free occurence of x.
 716
 717         (d) Not (unified with another type variable that is) in scope.
 718                 eg f x :: (r->r) = (\y->y) :: forall a. a->r
 719             when checking the expression type signature, we find that
 720             even though there is nothing in scope whose type mentions r,
 721             nevertheless the type signature for the expression isn't right.
 722
 723             Another example is in a class or instance declaration:
 724                 class C a where
 725                    op :: forall b. a -> b
 726                    op x = x
 727             Here, b gets unified with a
 728
 729 Before doing this, the substitution is applied to the signature type variable.
 730
 731 We used to have the notion of a "DontBind" type variable, which would
 732 only be bound to itself or nothing.  Then points (a) and (b) were
 733 self-checking.  But it gave rise to bogus consequential error messages.
 734 For example:
 735
 736    f = (*)      -- Monomorphic
 737
 738    g :: Num a => a -> a
 739    g x = f x x
 740
 741 Here, we get a complaint when checking the type signature for g,
 742 that g isn't polymorphic enough; but then we get another one when
 743 dealing with the (Num x) context arising from f's definition;
 744 we try to unify x with Int (to default it), but find that x has already
 745 been unified with the DontBind variable "a" from g's signature.
 746 This is really a problem with side-effecting unification; we'd like to
 747 undo g's effects when its type signature fails, but unification is done
 748 by side effect, so we can't (easily).
 749
 750 So we revert to ordinary type variables for signatures, and try to
 751 give a helpful message in checkSigTyVars.
 752
 753 \begin{code}
 754 checkSigTyVars :: [TcTyVar]             -- Universally-quantified type variables in the signature
 755                -> TcTyVarSet            -- Tyvars that are free in the type signature
 756                                         -- These should *already* be in the global-var set, and are
 757                                         -- used here only to improve the error message
 758                -> TcM [TcTyVar] -- Zonked signature type variables
 759
 760 checkSigTyVars [] free = returnTc []
 761
 762 checkSigTyVars sig_tyvars free_tyvars
 763   = zonkTcTyVars sig_tyvars             `thenNF_Tc` \ sig_tys ->
 764     tcGetGlobalTyVars                   `thenNF_Tc` \ globals ->
 765
 766     checkTcM (all_ok sig_tys globals)
 767              (complain sig_tys globals) `thenTc_`
 768
 769     returnTc (map (getTyVar "checkSigTyVars") sig_tys)
 770
 771   where
 772     all_ok []       acc = True
 773     all_ok (ty:tys) acc = case getTyVar_maybe ty of
 774                             Nothing                       -> False      -- Point (a)
 775                             Just tv | tv `elemVarSet` acc -> False      -- Point (b) or (c)
 776                                     | otherwise           -> all_ok tys (acc `extendVarSet` tv)
 777
 778
 779     complain sig_tys globals
 780       = -- For the in-scope ones, zonk them and construct a map
 781         -- from the zonked tyvar to the in-scope one
 782         -- If any of the in-scope tyvars zonk to a type, then ignore them;
 783         -- that'll be caught later when we back up to their type sig
 784         tcGetEnv                                `thenNF_Tc` \ env ->
 785         let
 786            in_scope_tvs = tcEnvTyVars env
 787         in
 788         zonkTcTyVars in_scope_tvs               `thenNF_Tc` \ in_scope_tys ->
 789         let
 790             in_scope_assoc = [ (zonked_tv, in_scope_tv)
 791                              | (z_ty, in_scope_tv) <- in_scope_tys `zip` in_scope_tvs,
 792                                Just zonked_tv <- [getTyVar_maybe z_ty]
 793                              ]
 794             in_scope_env = mkVarEnv in_scope_assoc
 795         in
 796
 797         -- "check" checks each sig tyvar in turn
 798         foldlNF_Tc check
 799                    (env2, in_scope_env, [])
 800                    (tidy_tvs `zip` tidy_tys)    `thenNF_Tc` \ (env3, _, msgs) ->
 801
 802         failWithTcM (env3, main_msg $$ nest 4 (vcat msgs))
 803       where
 804         (env1, tidy_tvs) = mapAccumL tidyTyVar emptyTidyEnv sig_tyvars
 805         (env2, tidy_tys) = tidyOpenTypes env1 sig_tys
 806
 807         main_msg = ptext SLIT("Inferred type is less polymorphic than expected")
 808
 809         check (tidy_env, acc, msgs) (sig_tyvar,ty)
 810                 -- sig_tyvar is from the signature;
 811                 -- ty is what you get if you zonk sig_tyvar and then tidy it
 812                 --
 813                 -- acc maps a zonked type variable back to a signature type variable
 814           = case getTyVar_maybe ty of {
 815               Nothing ->                        -- Error (a)!
 816                         returnNF_Tc (tidy_env, acc, unify_msg sig_tyvar (ppr ty) : msgs) ;
 817
 818               Just tv ->
 819
 820             case lookupVarEnv acc tv of {
 821                 Just sig_tyvar' ->      -- Error (b) or (d)!
 822                         returnNF_Tc (tidy_env, acc, unify_msg sig_tyvar (ppr sig_tyvar') : msgs) ;
 823
 824                 Nothing ->
 825
 826             if tv `elemVarSet` globals  -- Error (c)! Type variable escapes
 827                                         -- The least comprehensible, so put it last
 828                         -- Game plan:
 829                         --    a) get the local TcIds from the environment,
 830                         --       and pass them to find_globals (they might have tv free)
 831                         --    b) similarly, find any free_tyvars that mention tv
 832             then   tcGetEnv                                                     `thenNF_Tc` \ ve ->
 833                    find_globals tv tidy_env  [] (tcEnvTcIds ve)                 `thenNF_Tc` \ (tidy_env1, globs) ->
 834                    find_frees   tv tidy_env1 [] (varSetElems free_tyvars)       `thenNF_Tc` \ (tidy_env2, frees) ->
 835                    returnNF_Tc (tidy_env2, acc, escape_msg sig_tyvar tv globs frees : msgs)
 836
 837             else        -- All OK
 838             returnNF_Tc (tidy_env, extendVarEnv acc tv sig_tyvar, msgs)
 839             }}
 840
 841 -- find_globals looks at the value environment and finds values
 842 -- whose types mention the offending type variable.  It has to be
 843 -- careful to zonk the Id's type first, so it has to be in the monad.
 844 -- We must be careful to pass it a zonked type variable, too.
 845
 846 find_globals :: Var
 847              -> TidyEnv
 848              -> [(Name,Type)]
 849              -> [Id]
 850              -> NF_TcM (TidyEnv,[(Name,Type)])
 851
 852 find_globals tv tidy_env acc []
 853   = returnNF_Tc (tidy_env, acc)
 854
 855 find_globals tv tidy_env acc (id:ids)
 856   | isEmptyVarSet (idFreeTyVars id)
 857   = find_globals tv tidy_env acc ids
 858
 859   | otherwise
 860   = zonkTcType (idType id)      `thenNF_Tc` \ id_ty ->
 861     if tv `elemVarSet` tyVarsOfType id_ty then
 862         let
 863            (tidy_env', id_ty') = tidyOpenType tidy_env id_ty
 864            acc'                = (idName id, id_ty') : acc
 865         in
 866         find_globals tv tidy_env' acc' ids
 867     else
 868         find_globals tv tidy_env  acc  ids
 869
 870 find_frees tv tidy_env acc []
 871   = returnNF_Tc (tidy_env, acc)
 872 find_frees tv tidy_env acc (ftv:ftvs)
 873   = zonkTcTyVar ftv     `thenNF_Tc` \ ty ->
 874     if tv `elemVarSet` tyVarsOfType ty then
 875         let
 876             (tidy_env', ftv') = tidyTyVar tidy_env ftv
 877         in
 878         find_frees tv tidy_env' (ftv':acc) ftvs
 879     else
 880         find_frees tv tidy_env  acc        ftvs
 881
 882
 883 escape_msg sig_tv tv globs frees
 884   = mk_msg sig_tv <+> ptext SLIT("escapes") $$
 885     if not (null globs) then
 886         vcat [pp_it <+> ptext SLIT("is mentioned in the environment"),
 887               ptext SLIT("The following variables in the environment mention") <+> quotes (ppr tv),
 888               nest 2 (vcat_first 10 [ppr name <+> dcolon <+> ppr ty | (name,ty) <- globs])
 889         ]
 890      else if not (null frees) then
 891         vcat [ptext SLIT("It is reachable from the type variable(s)") <+> pprQuotedList frees,
 892               nest 2 (ptext SLIT("which") <+> is_are <+> ptext SLIT("free in the signature"))
 893         ]
 894      else
 895         empty   -- Sigh.  It's really hard to give a good error message
 896                 -- all the time.   One bad case is an existential pattern match
 897   where
 898     is_are | isSingleton frees = ptext SLIT("is")
 899            | otherwise         = ptext SLIT("are")
 900     pp_it | sig_tv /= tv = ptext SLIT("It unifies with") <+> quotes (ppr tv) <> comma <+> ptext SLIT("which")
 901           | otherwise    = ptext SLIT("It")
 902
 903     vcat_first :: Int -> [SDoc] -> SDoc
 904     vcat_first n []     = empty
 905     vcat_first 0 (x:xs) = text "...others omitted..."
 906     vcat_first n (x:xs) = x $$ vcat_first (n-1) xs
 907
 908 unify_msg tv thing = mk_msg tv <+> ptext SLIT("is unified with") <+> quotes thing
 909 mk_msg tv          = ptext SLIT("Quantified type variable") <+> quotes (ppr tv)
 910 \end{code}
 911
 912 These two context are used with checkSigTyVars
 913
 914 \begin{code}
 915 sigCtxt :: Message -> [TcTyVar] -> TcThetaType -> TcTauType
 916         -> TidyEnv -> NF_TcM (TidyEnv, Message)
 917 sigCtxt when sig_tyvars sig_theta sig_tau tidy_env
 918   = zonkTcType sig_tau          `thenNF_Tc` \ actual_tau ->
 919     let
 920         (env1, tidy_sig_tyvars)  = tidyTyVars tidy_env sig_tyvars
 921         (env2, tidy_sig_rho)     = tidyOpenType env1 (mkRhoTy sig_theta sig_tau)
 922         (env3, tidy_actual_tau)  = tidyOpenType env2 actual_tau
 923         msg = vcat [ptext SLIT("Signature type:    ") <+> pprType (mkForAllTys tidy_sig_tyvars tidy_sig_rho),
 924                     ptext SLIT("Type to generalise:") <+> pprType tidy_actual_tau,
 925                     when
 926                    ]
 927     in
 928     returnNF_Tc (env3, msg)
 929
 930 sigPatCtxt bound_tvs bound_ids tidy_env
 931   = returnNF_Tc (env1,
 932                  sep [ptext SLIT("When checking a pattern that binds"),
 933                       nest 4 (vcat (zipWith ppr_id show_ids tidy_tys))])
 934   where
 935     show_ids = filter is_interesting bound_ids
 936     is_interesting id = any (`elemVarSet` idFreeTyVars id) bound_tvs
 937
 938     (env1, tidy_tys) = tidyOpenTypes tidy_env (map idType show_ids)
 939     ppr_id id ty     = ppr id <+> dcolon <+> ppr ty
 940         -- Don't zonk the types so we get the separate, un-unified versions
 941 \end{code}
 942
 943
 944 %************************************************************************
 945 %*                                                                      *
 946 \subsection{Errors and contexts}
 947 %*                                                                      *
 948 %************************************************************************
 949
 950 \begin{code}
 951 tcsigCtxt v   = ptext SLIT("In a type signature for") <+> quotes (ppr v)
 952
 953 typeKindCtxt :: RenamedHsType -> Message
 954 typeKindCtxt ty = sep [ptext SLIT("When checking that"),
 955                        nest 2 (quotes (ppr ty)),
 956                        ptext SLIT("is a type")]
 957
 958 appKindCtxt :: SDoc -> Message
 959 appKindCtxt pp = ptext SLIT("When checking kinds in") <+> quotes pp
 960
 961 wrongThingErr expected thing name
 962   = pp_thing thing <+> quotes (ppr name) <+> ptext SLIT("used as a") <+> text expected
 963   where
 964     pp_thing (AGlobal (ATyCon _)) = ptext SLIT("Type constructor")
 965     pp_thing (AGlobal (AClass _)) = ptext SLIT("Class")
 966     pp_thing (AGlobal (AnId   _)) = ptext SLIT("Identifier")
 967     pp_thing (ATyVar _)           = ptext SLIT("Type variable")
 968     pp_thing (ATcId _)            = ptext SLIT("Local identifier")
 969     pp_thing (AThing _)           = ptext SLIT("Utterly bogus")
 970
 971 ambigErr pred ty
 972   = sep [ptext SLIT("Ambiguous constraint") <+> quotes (pprPred pred),
 973          nest 4 (ptext SLIT("for the type:") <+> ppr ty),
 974          nest 4 (ptext SLIT("Each forall'd type variable mentioned by the constraint must appear after the =>"))]
 975
 976 freeErr pred ty
 977   = sep [ptext SLIT("The constraint") <+> quotes (pprPred pred) <+>
 978                    ptext SLIT("does not mention any of the universally quantified type variables"),
 979          nest 4 (ptext SLIT("in the type") <+> quotes (ppr ty))
 980     ]
 981
 982 polyArgTyErr ty = ptext SLIT("Illegal polymorphic type as argument:")   <+> ppr ty
 983 ubxArgTyErr  ty = ptext SLIT("Illegal unboxed tuple type as argument:") <+> ppr ty
 984 \end{code}