ghc/compiler/typecheck/TcMonoType.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[TcMonoType]{Typechecking user-specified @MonoTypes@}
   5
   6 \begin{code}
   7 module TcMonoType ( tcHsSigType, tcHsType, tcIfaceType, tcHsTheta, tcHsPred,
   8                     UserTypeCtxt(..),
   9
  10                         -- Kind checking
  11                     kcHsTyVar, kcHsTyVars, mkTyClTyVars,
  12                     kcHsType, kcHsSigType, kcHsSigTypes,
  13                     kcHsLiftedSigType, kcHsContext,
  14                     tcAddScopedTyVars, tcHsTyVars, mkImmutTyVars,
  15
  16                     TcSigInfo(..), tcTySig, mkTcSig, maybeSig
  17                   ) where
  18
  19 #include "HsVersions.h"
  20
  21 import HsSyn            ( HsType(..), HsTyVarBndr(..),
  22                           Sig(..), HsPred(..), pprParendHsType, HsTupCon(..), hsTyVarNames )
  23 import RnHsSyn          ( RenamedHsType, RenamedHsPred, RenamedContext, RenamedSig, extractHsTyVars )
  24 import TcHsSyn          ( TcId )
  25
  26 import TcMonad
  27 import TcEnv            ( tcExtendTyVarEnv, tcLookup, tcLookupGlobal,
  28                           tcInLocalScope,
  29                           TyThing(..), TcTyThing(..), tcExtendKindEnv
  30                         )
  31 import TcMType          ( newKindVar, zonkKindEnv, tcInstSigType,
  32                           checkValidType, UserTypeCtxt(..), pprUserTypeCtxt
  33                         )
  34 import TcUnify          ( unifyKind, unifyOpenTypeKind )
  35 import TcType           ( Type, Kind, SourceType(..), ThetaType, TyVarDetails(..),
  36                           TcTyVar, TcKind, TcThetaType, TcTauType,
  37                           mkTyVarTy, mkTyVarTys, mkFunTy, mkSynTy,
  38                           hoistForAllTys, zipFunTys,
  39                           mkSigmaTy, mkPredTy, mkTyConApp, mkAppTys,
  40                           liftedTypeKind, unliftedTypeKind, mkArrowKind,
  41                           mkArrowKinds, tcSplitFunTy_maybe
  42                         )
  43 import Inst             ( Inst, InstOrigin(..), newMethodWithGivenTy, instToId )
  44
  45 import Id               ( mkLocalId, idName, idType )
  46 import Var              ( TyVar, mkTyVar, tyVarKind )
  47 import ErrUtils         ( Message )
  48 import TyCon            ( TyCon, isSynTyCon, tyConKind )
  49 import Class            ( classTyCon )
  50 import Name             ( Name )
  51 import NameSet
  52 import TysWiredIn       ( mkListTy, mkTupleTy, genUnitTyCon )
  53 import BasicTypes       ( Boxity(..) )
  54 import SrcLoc           ( SrcLoc )
  55 import Util             ( lengthIs )
  56 import Outputable
  57
  58 \end{code}
  59
  60
  61 %************************************************************************
  62 %*                                                                      *
  63 \subsection{Checking types}
  64 %*                                                                      *
  65 %************************************************************************
  66
  67 Generally speaking we now type-check types in three phases
  68
  69         1.  Kind check the HsType [kcHsType]
  70         2.  Convert from HsType to Type, and hoist the foralls [tcHsType]
  71         3.  Check the validity of the resulting type [checkValidType]
  72
  73 Often these steps are done one after the othe (tcHsSigType).
  74 But in mutually recursive groups of type and class decls we do
  75         1 kind-check the whole group
  76         2 build TyCons/Classes in a knot-tied wa
  77         3 check the validity of types in the now-unknotted TyCons/Classes
  78
  79 \begin{code}
  80 tcHsSigType :: UserTypeCtxt -> RenamedHsType -> TcM Type
  81   -- Do kind checking, and hoist for-alls to the top
  82 tcHsSigType ctxt ty = tcAddErrCtxt (checkTypeCtxt ctxt ty) (
  83                         kcTypeType ty           `thenTc_`
  84                         tcHsType ty
  85                       )                         `thenTc` \ ty' ->
  86                       checkValidType ctxt ty'   `thenTc_`
  87                       returnTc ty'
  88
  89 checkTypeCtxt ctxt ty
  90   = vcat [ptext SLIT("In the type:") <+> ppr ty,
  91           ptext SLIT("While checking") <+> pprUserTypeCtxt ctxt ]
  92
  93 tcHsType    :: RenamedHsType -> TcM Type
  94   -- Don't do kind checking, nor validity checking,
  95   --    but do hoist for-alls to the top
  96   -- This is used in type and class decls, where kinding is
  97   -- done in advance, and validity checking is done later
  98   -- [Validity checking done later because of knot-tying issues.]
  99 tcHsType ty = tc_type ty  `thenTc` \ ty' ->
 100               returnTc (hoistForAllTys ty')
 101
 102 tcHsTheta :: RenamedContext -> TcM ThetaType
 103 -- Used when we are expecting a ClassContext (i.e. no implicit params)
 104 -- Does not do validity checking, like tcHsType
 105 tcHsTheta hs_theta = mapTc tc_pred hs_theta
 106
 107 -- In interface files the type is already kinded,
 108 -- and we definitely don't want to hoist for-alls.
 109 -- Otherwise we'll change
 110 --      dmfail :: forall m:(*->*) Monad m => forall a:* => String -> m a
 111 -- into
 112 --      dmfail :: forall m:(*->*) a:* Monad m => String -> m a
 113 -- which definitely isn't right!
 114 tcIfaceType ty = tc_type ty
 115 \end{code}
 116
 117
 118 %************************************************************************
 119 %*                                                                      *
 120 \subsection{Kind checking}
 121 %*                                                                      *
 122 %************************************************************************
 123
 124 Kind checking
 125 ~~~~~~~~~~~~~
 126 When we come across the binding site for some type variables, we
 127 proceed in two stages
 128
 129 1. Figure out what kind each tyvar has
 130
 131 2. Create suitably-kinded tyvars,
 132    extend the envt,
 133    and typecheck the body
 134
 135 To do step 1, we proceed thus:
 136
 137 1a. Bind each type variable to a kind variable
 138 1b. Apply the kind checker
 139 1c. Zonk the resulting kinds
 140
 141 The kind checker is passed to tcHsTyVars as an argument.
 142
 143 For example, when we find
 144         (forall a m. m a -> m a)
 145 we bind a,m to kind varibles and kind-check (m a -> m a).  This
 146 makes a get kind *, and m get kind *->*.  Now we typecheck (m a -> m a)
 147 in an environment that binds a and m suitably.
 148
 149 The kind checker passed to tcHsTyVars needs to look at enough to
 150 establish the kind of the tyvar:
 151   * For a group of type and class decls, it's just the group, not
 152         the rest of the program
 153   * For a tyvar bound in a pattern type signature, its the types
 154         mentioned in the other type signatures in that bunch of patterns
 155   * For a tyvar bound in a RULE, it's the type signatures on other
 156         universally quantified variables in the rule
 157
 158 Note that this may occasionally give surprising results.  For example:
 159
 160         data T a b = MkT (a b)
 161
 162 Here we deduce                  a::*->*, b::*.
 163 But equally valid would be
 164                                 a::(*->*)-> *, b::*->*
 165
 166 \begin{code}
 167 -- tcHsTyVars is used for type variables in type signatures
 168 --      e.g. forall a. a->a
 169 -- They are immutable, because they scope only over the signature
 170 -- They may or may not be explicitly-kinded
 171 tcHsTyVars :: [HsTyVarBndr Name]
 172            -> TcM a                             -- The kind checker
 173            -> ([TyVar] -> TcM b)
 174            -> TcM b
 175
 176 tcHsTyVars [] kind_check thing_inside = thing_inside []
 177         -- A useful short cut for a common case!
 178
 179 tcHsTyVars tv_names kind_check thing_inside
 180   = kcHsTyVars tv_names                                 `thenNF_Tc` \ tv_names_w_kinds ->
 181     tcExtendKindEnv tv_names_w_kinds kind_check         `thenTc_`
 182     zonkKindEnv tv_names_w_kinds                        `thenNF_Tc` \ tvs_w_kinds ->
 183     let
 184         tyvars = mkImmutTyVars tvs_w_kinds
 185     in
 186     tcExtendTyVarEnv tyvars (thing_inside tyvars)
 187
 188
 189
 190 tcAddScopedTyVars :: [RenamedHsType] -> TcM a -> TcM a
 191 -- tcAddScopedTyVars is used for scoped type variables
 192 -- added by pattern type signatures
 193 --      e.g.  \ (x::a) (y::a) -> x+y
 194 -- They never have explicit kinds (because this is source-code only)
 195 -- They are mutable (because they can get bound to a more specific type)
 196
 197 -- Find the not-already-in-scope signature type variables,
 198 -- kind-check them, and bring them into scope
 199 --
 200 -- We no longer specify that these type variables must be univerally
 201 -- quantified (lots of email on the subject).  If you want to put that
 202 -- back in, you need to
 203 --      a) Do a checkSigTyVars after thing_inside
 204 --      b) More insidiously, don't pass in expected_ty, else
 205 --         we unify with it too early and checkSigTyVars barfs
 206 --         Instead you have to pass in a fresh ty var, and unify
 207 --         it with expected_ty afterwards
 208 tcAddScopedTyVars [] thing_inside
 209   = thing_inside        -- Quick get-out for the empty case
 210
 211 tcAddScopedTyVars sig_tys thing_inside
 212   = tcGetEnv                                    `thenNF_Tc` \ env ->
 213     let
 214         all_sig_tvs     = foldr (unionNameSets . extractHsTyVars) emptyNameSet sig_tys
 215         sig_tvs         = filter not_in_scope (nameSetToList all_sig_tvs)
 216         not_in_scope tv = not (tcInLocalScope env tv)
 217     in
 218     mapNF_Tc newNamedKindVar sig_tvs                    `thenTc` \ kind_env ->
 219     tcExtendKindEnv kind_env (kcHsSigTypes sig_tys)     `thenTc_`
 220     zonkKindEnv kind_env                                `thenNF_Tc` \ tvs_w_kinds ->
 221     listTc [ tcNewMutTyVar name kind PatSigTv
 222            | (name, kind) <- tvs_w_kinds]               `thenNF_Tc` \ tyvars ->
 223     tcExtendTyVarEnv tyvars thing_inside
 224 \end{code}
 225
 226
 227 \begin{code}
 228 kcHsTyVar  :: HsTyVarBndr name   -> NF_TcM (name, TcKind)
 229 kcHsTyVars :: [HsTyVarBndr name] -> NF_TcM [(name, TcKind)]
 230
 231 kcHsTyVar (UserTyVar name)       = newNamedKindVar name
 232 kcHsTyVar (IfaceTyVar name kind) = returnNF_Tc (name, kind)
 233
 234 kcHsTyVars tvs = mapNF_Tc kcHsTyVar tvs
 235
 236 newNamedKindVar name = newKindVar       `thenNF_Tc` \ kind ->
 237                        returnNF_Tc (name, kind)
 238
 239 ---------------------------
 240 kcLiftedType :: RenamedHsType -> TcM ()
 241         -- The type ty must be a *lifted* *type*
 242 kcLiftedType ty
 243   = kcHsType ty                         `thenTc` \ kind ->
 244     tcAddErrCtxt (typeKindCtxt ty)      $
 245     unifyKind liftedTypeKind kind
 246
 247 ---------------------------
 248 kcTypeType :: RenamedHsType -> TcM ()
 249         -- The type ty must be a *type*, but it can be lifted or unlifted.
 250 kcTypeType ty
 251   = kcHsType ty                         `thenTc` \ kind ->
 252     tcAddErrCtxt (typeKindCtxt ty)      $
 253     unifyOpenTypeKind kind
 254
 255 ---------------------------
 256 kcHsSigType, kcHsLiftedSigType :: RenamedHsType -> TcM ()
 257         -- Used for type signatures
 258 kcHsSigType       = kcTypeType
 259 kcHsSigTypes tys  = mapTc_ kcHsSigType tys
 260 kcHsLiftedSigType = kcLiftedType
 261
 262 ---------------------------
 263 kcHsType :: RenamedHsType -> TcM TcKind
 264 kcHsType (HsTyVar name)       = kcTyVar name
 265
 266 kcHsType (HsListTy ty)
 267   = kcLiftedType ty             `thenTc` \ tau_ty ->
 268     returnTc liftedTypeKind
 269
 270 kcHsType (HsTupleTy (HsTupCon _ boxity _) tys)
 271   = mapTc kcTypeType tys        `thenTc_`
 272     returnTc (case boxity of
 273                   Boxed   -> liftedTypeKind
 274                   Unboxed -> unliftedTypeKind)
 275
 276 kcHsType (HsFunTy ty1 ty2)
 277   = kcTypeType ty1      `thenTc_`
 278     kcTypeType ty2      `thenTc_`
 279     returnTc liftedTypeKind
 280
 281 kcHsType (HsNumTy _)            -- The unit type for generics
 282   = returnTc liftedTypeKind
 283
 284 kcHsType ty@(HsOpTy ty1 op ty2)
 285   = kcTyVar op                          `thenTc` \ op_kind ->
 286     kcHsType ty1                        `thenTc` \ ty1_kind ->
 287     kcHsType ty2                        `thenTc` \ ty2_kind ->
 288     tcAddErrCtxt (appKindCtxt (ppr ty)) $
 289     kcAppKind op_kind  ty1_kind         `thenTc` \ op_kind' ->
 290     kcAppKind op_kind' ty2_kind
 291
 292 kcHsType (HsPredTy pred)
 293   = kcHsPred pred               `thenTc_`
 294     returnTc liftedTypeKind
 295
 296 kcHsType ty@(HsAppTy ty1 ty2)
 297   = kcHsType ty1                        `thenTc` \ tc_kind ->
 298     kcHsType ty2                        `thenTc` \ arg_kind ->
 299     tcAddErrCtxt (appKindCtxt (ppr ty)) $
 300     kcAppKind tc_kind arg_kind
 301
 302 kcHsType (HsForAllTy (Just tv_names) context ty)
 303   = kcHsTyVars tv_names         `thenNF_Tc` \ kind_env ->
 304     tcExtendKindEnv kind_env    $
 305     kcHsContext context         `thenTc_`
 306     kcHsType ty                 `thenTc_`
 307     returnTc liftedTypeKind
 308
 309 ---------------------------
 310 kcAppKind fun_kind arg_kind
 311   = case tcSplitFunTy_maybe fun_kind of
 312         Just (arg_kind', res_kind)
 313                 -> unifyKind arg_kind arg_kind' `thenTc_`
 314                    returnTc res_kind
 315
 316         Nothing -> newKindVar                                           `thenNF_Tc` \ res_kind ->
 317                    unifyKind fun_kind (mkArrowKind arg_kind res_kind)   `thenTc_`
 318                    returnTc res_kind
 319
 320
 321 ---------------------------
 322 kc_pred :: RenamedHsPred -> TcM TcKind  -- Does *not* check for a saturated
 323                                         -- application (reason: used from TcDeriv)
 324 kc_pred pred@(HsIParam name ty)
 325   = kcHsType ty
 326
 327 kc_pred pred@(HsClassP cls tys)
 328   = kcClass cls                         `thenTc` \ kind ->
 329     mapTc kcHsType tys                  `thenTc` \ arg_kinds ->
 330     newKindVar                          `thenNF_Tc` \ kv ->
 331     unifyKind kind (mkArrowKinds arg_kinds kv)  `thenTc_`
 332     returnTc kv
 333
 334 ---------------------------
 335 kcHsContext ctxt = mapTc_ kcHsPred ctxt
 336
 337 kcHsPred pred           -- Checks that the result is of kind liftedType
 338   = tcAddErrCtxt (appKindCtxt (ppr pred))       $
 339     kc_pred pred                                `thenTc` \ kind ->
 340     unifyKind liftedTypeKind kind               `thenTc_`
 341     returnTc ()
 342
 343
 344  ---------------------------
 345 kcTyVar name    -- Could be a tyvar or a tycon
 346   = tcLookup name       `thenTc` \ thing ->
 347     case thing of
 348         AThing kind         -> returnTc kind
 349         ATyVar tv           -> returnTc (tyVarKind tv)
 350         AGlobal (ATyCon tc) -> returnTc (tyConKind tc)
 351         other               -> failWithTc (wrongThingErr "type" thing name)
 352
 353 kcClass cls     -- Must be a class
 354   = tcLookup cls                                `thenNF_Tc` \ thing ->
 355     case thing of
 356         AThing kind           -> returnTc kind
 357         AGlobal (AClass cls)  -> returnTc (tyConKind (classTyCon cls))
 358         other                 -> failWithTc (wrongThingErr "class" thing cls)
 359 \end{code}
 360
 361 %************************************************************************
 362 %*                                                                      *
 363 \subsection{tc_type}
 364 %*                                                                      *
 365 %************************************************************************
 366
 367 tc_type, the main work horse
 368 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 369
 370         -------------------
 371         *** BIG WARNING ***
 372         -------------------
 373
 374 tc_type is used to typecheck the types in the RHS of data
 375 constructors.  In the case of recursive data types, that means that
 376 the type constructors themselves are (partly) black holes.  e.g.
 377
 378         data T a = MkT a [T a]
 379
 380 While typechecking the [T a] on the RHS, T itself is not yet fully
 381 defined.  That in turn places restrictions on what you can check in
 382 tcHsType; if you poke on too much you get a black hole.  I keep
 383 forgetting this, hence this warning!
 384
 385 So tc_type does no validity-checking.  Instead that's all done
 386 by TcMType.checkValidType
 387
 388         --------------------------
 389         *** END OF BIG WARNING ***
 390         --------------------------
 391
 392
 393 \begin{code}
 394 tc_type :: RenamedHsType -> TcM Type
 395
 396 tc_type ty@(HsTyVar name)
 397   = tc_app ty []
 398
 399 tc_type (HsListTy ty)
 400   = tc_type ty  `thenTc` \ tau_ty ->
 401     returnTc (mkListTy tau_ty)
 402
 403 tc_type (HsTupleTy (HsTupCon _ boxity arity) tys)
 404   = ASSERT( tys `lengthIs` arity )
 405     tc_types tys        `thenTc` \ tau_tys ->
 406     returnTc (mkTupleTy boxity arity tau_tys)
 407
 408 tc_type (HsFunTy ty1 ty2)
 409   = tc_type ty1                 `thenTc` \ tau_ty1 ->
 410     tc_type ty2                 `thenTc` \ tau_ty2 ->
 411     returnTc (mkFunTy tau_ty1 tau_ty2)
 412
 413 tc_type (HsNumTy n)
 414   = ASSERT(n== 1)
 415     returnTc (mkTyConApp genUnitTyCon [])
 416
 417 tc_type (HsOpTy ty1 op ty2)
 418   = tc_type ty1 `thenTc` \ tau_ty1 ->
 419     tc_type ty2 `thenTc` \ tau_ty2 ->
 420     tc_fun_type op [tau_ty1,tau_ty2]
 421
 422 tc_type (HsAppTy ty1 ty2) = tc_app ty1 [ty2]
 423
 424 tc_type (HsPredTy pred)
 425   = tc_pred pred        `thenTc` \ pred' ->
 426     returnTc (mkPredTy pred')
 427
 428 tc_type full_ty@(HsForAllTy (Just tv_names) ctxt ty)
 429   = let
 430         kind_check = kcHsContext ctxt `thenTc_` kcHsType ty
 431     in
 432     tcHsTyVars tv_names kind_check      $ \ tyvars ->
 433     mapTc tc_pred ctxt                  `thenTc` \ theta ->
 434     tc_type ty                          `thenTc` \ tau ->
 435     returnTc (mkSigmaTy tyvars theta tau)
 436
 437 tc_types arg_tys = mapTc tc_type arg_tys
 438 \end{code}
 439
 440 Help functions for type applications
 441 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 442
 443 \begin{code}
 444 tc_app :: RenamedHsType -> [RenamedHsType] -> TcM Type
 445 tc_app (HsAppTy ty1 ty2) tys
 446   = tc_app ty1 (ty2:tys)
 447
 448 tc_app ty tys
 449   = tcAddErrCtxt (appKindCtxt pp_app)   $
 450     tc_types tys                        `thenTc` \ arg_tys ->
 451     case ty of
 452         HsTyVar fun -> tc_fun_type fun arg_tys
 453         other       -> tc_type ty               `thenTc` \ fun_ty ->
 454                        returnNF_Tc (mkAppTys fun_ty arg_tys)
 455   where
 456     pp_app = ppr ty <+> sep (map pprParendHsType tys)
 457
 458 -- (tc_fun_type ty arg_tys) returns (mkAppTys ty arg_tys)
 459 -- But not quite; for synonyms it checks the correct arity, and builds a SynTy
 460 --      hence the rather strange functionality.
 461
 462 tc_fun_type name arg_tys
 463   = tcLookup name                       `thenTc` \ thing ->
 464     case thing of
 465         ATyVar tv -> returnTc (mkAppTys (mkTyVarTy tv) arg_tys)
 466
 467         AGlobal (ATyCon tc)
 468                 | isSynTyCon tc ->  returnTc (mkSynTy tc arg_tys)
 469                 | otherwise     ->  returnTc (mkTyConApp tc arg_tys)
 470
 471         other -> failWithTc (wrongThingErr "type constructor" thing name)
 472 \end{code}
 473
 474
 475 Contexts
 476 ~~~~~~~~
 477 \begin{code}
 478 tcHsPred pred = kc_pred pred `thenTc_`  tc_pred pred
 479         -- Is happy with a partial application, e.g. (ST s)
 480         -- Used from TcDeriv
 481
 482 tc_pred assn@(HsClassP class_name tys)
 483   = tcAddErrCtxt (appKindCtxt (ppr assn))       $
 484     tc_types tys                        `thenTc` \ arg_tys ->
 485     tcLookupGlobal class_name                   `thenTc` \ thing ->
 486     case thing of
 487         AClass clas -> returnTc (ClassP clas arg_tys)
 488         other       -> failWithTc (wrongThingErr "class" (AGlobal thing) class_name)
 489
 490 tc_pred assn@(HsIParam name ty)
 491   = tcAddErrCtxt (appKindCtxt (ppr assn))       $
 492     tc_type ty                                  `thenTc` \ arg_ty ->
 493     returnTc (IParam name arg_ty)
 494 \end{code}
 495
 496
 497
 498 %************************************************************************
 499 %*                                                                      *
 500 \subsection{Type variables, with knot tying!}
 501 %*                                                                      *
 502 %************************************************************************
 503
 504 \begin{code}
 505 mkImmutTyVars :: [(Name,Kind)] -> [TyVar]
 506 mkImmutTyVars pairs = [mkTyVar name kind | (name, kind) <- pairs]
 507
 508 mkTyClTyVars :: Kind                    -- Kind of the tycon or class
 509              -> [HsTyVarBndr Name]
 510              -> [TyVar]
 511 mkTyClTyVars kind tyvar_names
 512   = mkImmutTyVars tyvars_w_kinds
 513   where
 514     (tyvars_w_kinds, _) = zipFunTys (hsTyVarNames tyvar_names) kind
 515 \end{code}
 516
 517
 518 %************************************************************************
 519 %*                                                                      *
 520 \subsection{Signatures}
 521 %*                                                                      *
 522 %************************************************************************
 523
 524 @tcSigs@ checks the signatures for validity, and returns a list of
 525 {\em freshly-instantiated} signatures.  That is, the types are already
 526 split up, and have fresh type variables installed.  All non-type-signature
 527 "RenamedSigs" are ignored.
 528
 529 The @TcSigInfo@ contains @TcTypes@ because they are unified with
 530 the variable's type, and after that checked to see whether they've
 531 been instantiated.
 532
 533 \begin{code}
 534 data TcSigInfo
 535   = TySigInfo
 536         Name                    -- N, the Name in corresponding binding
 537
 538         TcId                    -- *Polymorphic* binder for this value...
 539                                 -- Has name = N
 540
 541         [TcTyVar]               -- tyvars
 542         TcThetaType             -- theta
 543         TcTauType               -- tau
 544
 545         TcId                    -- *Monomorphic* binder for this value
 546                                 -- Does *not* have name = N
 547                                 -- Has type tau
 548
 549         [Inst]                  -- Empty if theta is null, or
 550                                 -- (method mono_id) otherwise
 551
 552         SrcLoc                  -- Of the signature
 553
 554 instance Outputable TcSigInfo where
 555     ppr (TySigInfo nm id tyvars theta tau _ inst loc) =
 556         ppr nm <+> ptext SLIT("::") <+> ppr tyvars <+> ppr theta <+> ptext SLIT("=>") <+> ppr tau
 557
 558 maybeSig :: [TcSigInfo] -> Name -> Maybe (TcSigInfo)
 559         -- Search for a particular signature
 560 maybeSig [] name = Nothing
 561 maybeSig (sig@(TySigInfo sig_name _ _ _ _ _ _ _) : sigs) name
 562   | name == sig_name = Just sig
 563   | otherwise        = maybeSig sigs name
 564 \end{code}
 565
 566
 567 \begin{code}
 568 tcTySig :: RenamedSig -> TcM TcSigInfo
 569
 570 tcTySig (Sig v ty src_loc)
 571  = tcAddSrcLoc src_loc                          $
 572    tcHsSigType (FunSigCtxt v) ty                `thenTc` \ sigma_tc_ty ->
 573    mkTcSig (mkLocalId v sigma_tc_ty) src_loc    `thenNF_Tc` \ sig ->
 574    returnTc sig
 575
 576 mkTcSig :: TcId -> SrcLoc -> NF_TcM TcSigInfo
 577 mkTcSig poly_id src_loc
 578   =     -- Instantiate this type
 579         -- It's important to do this even though in the error-free case
 580         -- we could just split the sigma_tc_ty (since the tyvars don't
 581         -- unified with anything).  But in the case of an error, when
 582         -- the tyvars *do* get unified with something, we want to carry on
 583         -- typechecking the rest of the program with the function bound
 584         -- to a pristine type, namely sigma_tc_ty
 585    tcInstSigType SigTv (idType poly_id)         `thenNF_Tc` \ (tyvars', theta', tau') ->
 586
 587    newMethodWithGivenTy SignatureOrigin
 588                         poly_id
 589                         (mkTyVarTys tyvars')
 590                         theta' tau'             `thenNF_Tc` \ inst ->
 591         -- We make a Method even if it's not overloaded; no harm
 592
 593    returnNF_Tc (TySigInfo (idName poly_id) poly_id tyvars' theta' tau'
 594                           (instToId inst) [inst] src_loc)
 595 \end{code}
 596
 597
 598
 599 %************************************************************************
 600 %*                                                                      *
 601 \subsection{Errors and contexts}
 602 %*                                                                      *
 603 %************************************************************************
 604
 605 \begin{code}
 606 typeKindCtxt :: RenamedHsType -> Message
 607 typeKindCtxt ty = sep [ptext SLIT("When checking that"),
 608                        nest 2 (quotes (ppr ty)),
 609                        ptext SLIT("is a type")]
 610
 611 appKindCtxt :: SDoc -> Message
 612 appKindCtxt pp = ptext SLIT("When checking kinds in") <+> quotes pp
 613
 614 wrongThingErr expected thing name
 615   = pp_thing thing <+> quotes (ppr name) <+> ptext SLIT("used as a") <+> text expected
 616   where
 617     pp_thing (AGlobal (ATyCon _)) = ptext SLIT("Type constructor")
 618     pp_thing (AGlobal (AClass _)) = ptext SLIT("Class")
 619     pp_thing (AGlobal (AnId   _)) = ptext SLIT("Identifier")
 620     pp_thing (ATyVar _)           = ptext SLIT("Type variable")
 621     pp_thing (ATcId _)            = ptext SLIT("Local identifier")
 622     pp_thing (AThing _)           = ptext SLIT("Utterly bogus")
 623 \end{code}